qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_minstagib)
 266         if(self.ammo_cells <= 0)
 267                 return;
 268
 269         if(g_pinata)
 270         {
 271                 float j;
 272                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 273                 {
 274                         if(WEPSET_CONTAINS_EW(self, j))
 275                                 if(W_IsWeaponThrowable(j))
 276                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 277                 }
 278         }
 279         else
 280         {
 281                 if(W_IsWeaponThrowable(self.weapon))
 282                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 283         }
 284 }
 285
 286 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 287 {
 288         float take, save;
 289         vector v;
 290         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 291
 292         // damage resistance (ignore most of the damage from a bullet or similar)
 293         damage = max(damage - 5, 1);
 294
 295         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 296         take = v_x;
 297         save = v_y;
 298
 299         if(sound_allowed(MSG_BROADCAST, attacker))
 300         {
 301                 if (save > 10)
 302                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 303                 else if (take > 30)
 304                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 305                 else if (take > 10)
 306                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 307         }
 308
 309         if (take > 50)
 310                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 311         if (take > 100)
 312                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 313
 314         if (!(self.flags & FL_GODMODE))
 315         {
 316                 self.armorvalue = self.armorvalue - save;
 317                 self.health = self.health - take;
 318                 // pause regeneration for 5 seconds
 319                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 320         }
 321         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 322         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 323         self.dmg_inflictor = inflictor;
 324
 325         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 326         {
 327                 // don't use any animations as a gib
 328                 self.frame = 0;
 329                 // view just above the floor
 330                 self.view_ofs = '0 0 4';
 331
 332                 Violence_GibSplash(self, 1, 1, attacker);
 333                 self.alpha = -1;
 334                 self.solid = SOLID_NOT; // restore later
 335                 self.takedamage = DAMAGE_NO; // restore later
 336                 self.damagedbycontents = FALSE;
 337         }
 338 }
 339
 340 void ClientKill_Now_TeamChange();
 341
 342 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 343 {
 344         float take, save, waves, sdelay, dh, da, j;
 345         vector v;
 346         float valid_damage_for_weaponstats;
 347         float excess;
 348
 349         dh = max(self.health, 0);
 350         da = max(self.armorvalue, 0);
 351
 352         if(!DEATH_ISSPECIAL(deathtype))
 353         {
 354                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 355                 if(self != attacker)
 356                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 357         }
 358
 359         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 360         {
 361                 // tuba causes blood to come out of the ears
 362                 vector ear1, ear2;
 363                 vector d;
 364                 float f;
 365                 ear1 = self.origin;
 366                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 367                 ear2 = ear1;
 368                 makevectors(self.angles);
 369                 ear1 += v_right * -10;
 370                 ear2 += v_right * +10;
 371                 d = inflictor.origin - self.origin;
 372                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 373                 force = v_right * vlen(force);
 374                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 375                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 376                 if(f > 0)
 377                 {
 378                         hitloc = ear1;
 379                         force = force * -1;
 380                 }
 381                 else
 382                 {
 383                         hitloc = ear2;
 384                         // force is already good
 385                 }
 386         }
 387         else
 388                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 389
 390         if (!g_minstagib)
 391         {
 392                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 393                 take = v_x;
 394                 save = v_y;
 395         }
 396         else
 397         {
 398                 save = 0;
 399                 take = damage;
 400         }
 401
 402         if(attacker == self)
 403         {
 404                 // don't reset pushltime for self damage as it may be an attempt to
 405                 // escape a lava pit or similar
 406                 //self.pushltime = 0;
 407                 self.istypefrag = 0;
 408         }
 409         else if(attacker.classname == "player")
 410         {
 411                 self.pusher = attacker;
 412                 self.pushltime = time + autocvar_g_maxpushtime;
 413                 self.istypefrag = self.BUTTON_CHAT;
 414         }
 415         else if(time < self.pushltime)
 416         {
 417                 attacker = self.pusher;
 418                 self.pushltime = max(self.pushltime, time + 0.6);
 419         }
 420         else
 421         {
 422                 self.pushltime = 0;
 423                 self.istypefrag = 0;
 424         }
 425
 426         frag_inflictor = inflictor;
 427         frag_attacker = attacker;
 428         frag_target = self;
 429         damage_take = take;
 430         damage_save = save;
 431         damage_force = force;
 432         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 433         take = bound(0, damage_take, self.health);
 434         save = bound(0, damage_save, self.armorvalue);
 435         excess = max(0, damage - take - save);
 436
 437         if(sound_allowed(MSG_BROADCAST, attacker))
 438         {
 439                 if (save > 10)
 440                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 441                 else if (take > 30)
 442                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 443                 else if (take > 10)
 444                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 445         }
 446
 447         if (take > 50)
 448                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 449         if (take > 100)
 450                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 451
 452         if (time >= self.spawnshieldtime)
 453         {
 454                 if (!(self.flags & FL_GODMODE))
 455                 {
 456                         self.armorvalue = self.armorvalue - save;
 457                         self.health = self.health - take;
 458                         // pause regeneration for 5 seconds
 459                         if(take)
 460                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 461
 462                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 463                         {
 464                                 self.pain_finished = time + 0.5;        //Supajoe
 465
 466                                 if(autocvar_sv_gentle < 1) {
 467                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 468                                         {
 469                                                 if (!self.animstate_override)
 470                                                 {
 471                                                         if (random() > 0.5)
 472                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 473                                                         else
 474                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 475                                                 }
 476                                         }
 477
 478                                         if(sound_allowed(MSG_BROADCAST, attacker))
 479                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 480                                         if(self.health > 1)
 481                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 482                                         {
 483                                                 if(deathtype == DEATH_FALL)
 484                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 485                                                 else if(self.health > 75) // TODO make a "gentle" version?
 486                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 487                                                 else if(self.health > 50)
 488                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 489                                                 else if(self.health > 25)
 490                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 491                                                 else
 492                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 493                                         }
 494                                 }
 495
 496                                 // throw off bot aim temporarily
 497                                 float shake;
 498                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 499                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 500                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 501                         }
 502                 }
 503                 else
 504                         self.max_armorvalue += (save + take);
 505         }
 506         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 507         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 508         self.dmg_inflictor = inflictor;
 509
 510         if(g_ca && self != attacker && attacker.classname == "player")
 511                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 512
 513         float abot, vbot, awep;
 514         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 515         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 516
 517         valid_damage_for_weaponstats = 0;
 518         awep = 0;
 519
 520         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 521         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 522         if(attacker && self != attacker)
 523         if(IsDifferentTeam(self, attacker))
 524         {
 525                 if(DEATH_ISSPECIAL(deathtype))
 526                         awep = attacker.weapon;
 527                 else
 528                         awep = DEATH_WEAPONOF(deathtype);
 529                 valid_damage_for_weaponstats = 1;
 530         }
 531
 532         if(valid_damage_for_weaponstats)
 533         {
 534                 dh = dh - max(self.health, 0);
 535                 da = da - max(self.armorvalue, 0);
 536                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 537         }
 538
 539         if (self.health < 1)
 540         {
 541                 float defer_ClientKill_Now_TeamChange;
 542                 defer_ClientKill_Now_TeamChange = FALSE;
 543
 544                 if(self.alivetime)
 545                 {
 546                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 547                         self.alivetime = 0;
 548                 }
 549
 550                 if(valid_damage_for_weaponstats)
 551                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 552
 553                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 554                 if(sound_allowed(MSG_BROADCAST, attacker))
 555                 {
 556                         if(deathtype == DEATH_DROWN)
 557                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 558                         else
 559                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 560                 }
 561
 562                 // get rid of kill indicator
 563                 if(self.killindicator)
 564                 {
 565                         remove(self.killindicator);
 566                         self.killindicator = world;
 567                         if(self.killindicator_teamchange)
 568                                 defer_ClientKill_Now_TeamChange = TRUE;
 569
 570                         if(self.classname == "body")
 571                         if(deathtype == DEATH_KILL)
 572                         {
 573                                 // for the lemmings fans, a small harmless explosion
 574                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 575                         }
 576                 }
 577
 578                 // print an obituary message
 579                 Obituary (attacker, inflictor, self, deathtype);
 580                 race_PreDie();
 581
 582         // increment frag counter for used weapon type
 583         float w;
 584         w = DEATH_WEAPONOF(deathtype);
 585         if(WEP_VALID(w))
 586         if(accuracy_isgooddamage(attacker, self))
 587         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 588
 589                 frag_attacker = attacker;
 590                 frag_inflictor = inflictor;
 591                 frag_target = self;
 592                 frag_deathtype = deathtype;
 593                 MUTATOR_CALLHOOK(PlayerDies);
 594
 595                 weapon_action(self.weapon, WR_PLAYERDEATH);
 596
 597                 RemoveGrapplingHook(self);
 598
 599                 Portal_ClearAllLater(self);
 600
 601                 if(clienttype(self) == CLIENTTYPE_REAL)
 602                 {
 603                         self.fixangle = TRUE;
 604                         //msg_entity = self;
 605                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 606                         //WriteAngle (MSG_ONE, self.v_angle_x);
 607                         //WriteAngle (MSG_ONE, self.v_angle_y);
 608                         //WriteAngle (MSG_ONE, 80);
 609                 }
 610
 611                 if(defer_ClientKill_Now_TeamChange)
 612                         ClientKill_Now_TeamChange(); // can turn player into spectator
 613
 614                 // player could have been miraculously resuscitated ;)
 615                 // e.g. players in freezetag get frozen, they don't really die
 616                 if(self.health >= 1 || self.classname != "player")
 617                         return;
 618
 619                 // when we get here, player actually dies
 620
 621                 // clear waypoints
 622                 WaypointSprite_PlayerDead();
 623                 // throw a weapon
 624                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 625
 626                 // become fully visible
 627                 self.alpha = default_player_alpha;
 628                 // make the corpse upright (not tilted)
 629                 self.angles_x = 0;
 630                 self.angles_z = 0;
 631                 // don't spin
 632                 self.avelocity = '0 0 0';
 633                 // view from the floor
 634                 self.view_ofs = '0 0 -8';
 635                 // toss the corpse
 636                 self.movetype = MOVETYPE_TOSS;
 637                 // shootable corpse
 638                 self.solid = SOLID_CORPSE;
 639                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 640                 // don't stick to the floor
 641                 self.flags &~= FL_ONGROUND;
 642                 // dying animation
 643                 self.deadflag = DEAD_DYING;
 644                 // when to allow respawn
 645                 sdelay = 0;
 646                 waves = 0;
 647                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 648                 if(!sdelay)
 649                 {
 650                         if(g_cts)
 651                                 sdelay = 0; // no respawn delay in CTS
 652                         else
 653                                 sdelay = autocvar_g_respawn_delay;
 654                 }
 655                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 656                 if(!waves)
 657                         waves = autocvar_g_respawn_waves;
 658                 if(waves)
 659                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 660                 else
 661                         self.respawn_time = time + sdelay;
 662                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 663                         self.respawn_countdown = 10; // first number to count down from is 10
 664                 else
 665                         self.respawn_countdown = -1; // do not count down
 666
 667                 if(g_lms || g_cts || autocvar_g_forced_respawn)
 668                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 669
 670                 self.death_time = time;
 671                 if (random() < 0.5)
 672                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 673                 else
 674                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 675                 if (self.maxs_z > 5)
 676                 {
 677                         self.maxs_z = 5;
 678                         setsize(self, self.mins, self.maxs);
 679                 }
 680                 // set damage function to corpse damage
 681                 self.event_damage = PlayerCorpseDamage;
 682                 // call the corpse damage function just in case it wants to gib
 683                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 684                 // set up to fade out later
 685                 SUB_SetFade (self, time + 6 + random (), 1);
 686
 687                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 688                         // remove corpse
 689                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 690                 }
 691
 692                 // reset fields the weapons may use just in case
 693                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 694                 {
 695                         weapon_action(j, WR_RESETPLAYER);
 696                         ATTACK_FINISHED_FOR(self, j) = 0;
 697                 }
 698         }
 699 }
 700
 701 .float muted; // to be used by prvm_edictset server playernumber muted 1
 702 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 703 // message "": do not say, just test flood control
 704 // return value:
 705 //   1 = accept
 706 //   0 = reject
 707 //  -1 = fake accept
 708 {
 709         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 710         float flood;
 711         var .float flood_field;
 712         entity head;
 713         float ret;
 714         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 715
 716         if(!teamsay && !privatesay)
 717                 if(substring(msgin, 0, 1) == " ")
 718                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 719
 720         msgin = formatmessage(msgin);
 721
 722         if(source.classname != "player")
 723                 colorstr = "^0"; // black for spectators
 724         else if(teamplay)
 725                 colorstr = Team_ColorCode(source.team);
 726         else
 727         {
 728                 colorstr = "";
 729                 teamsay = FALSE;
 730         }
 731
 732         if(intermission_running)
 733                 teamsay = FALSE;
 734
 735         if(msgin != "")
 736                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 737
 738         /*
 739          * using bprint solves this... me stupid
 740         // how can we prevent the message from appearing in a listen server?
 741         // for now, just give "say" back and only handle say_team
 742         if(!teamsay)
 743         {
 744                 clientcommand(self, strcat("say ", msgin));
 745                 return;
 746         }
 747         */
 748
 749         if(autocvar_g_chat_teamcolors)
 750                 namestr = playername(source);
 751         else
 752                 namestr = source.netname;
 753
 754         if(msgin != "")
 755         {
 756                 if(privatesay)
 757                 {
 758                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 759                         privatemsgprefixlen = strlen(msgstr);
 760                         msgstr = strcat(msgstr, msgin);
 761                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 762                         if(autocvar_g_chat_teamcolors)
 763                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 764                         else
 765                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 766                 }
 767                 else if(teamsay)
 768                 {
 769                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 770                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 771                 }
 772                 else
 773                 {
 774                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 775                         cmsgstr = "";
 776                 }
 777                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 778         }
 779         else
 780         {
 781                 msgstr = cmsgstr = "";
 782         }
 783
 784         fullmsgstr = msgstr;
 785         fullcmsgstr = cmsgstr;
 786
 787         // FLOOD CONTROL
 788         flood = 0;
 789         flood_field = floodcontrol_chat;
 790         if(floodcontrol)
 791         {
 792                 float flood_spl;
 793                 float flood_burst;
 794                 float flood_lmax;
 795                 float lines;
 796                 if(privatesay)
 797                 {
 798                         flood_spl = autocvar_g_chat_flood_spl_tell;
 799                         flood_burst = autocvar_g_chat_flood_burst_tell;
 800                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 801                         flood_field = floodcontrol_chattell;
 802                 }
 803                 else if(teamsay)
 804                 {
 805                         flood_spl = autocvar_g_chat_flood_spl_team;
 806                         flood_burst = autocvar_g_chat_flood_burst_team;
 807                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 808                         flood_field = floodcontrol_chatteam;
 809                 }
 810                 else
 811                 {
 812                         flood_spl = autocvar_g_chat_flood_spl;
 813                         flood_burst = autocvar_g_chat_flood_burst;
 814                         flood_lmax = autocvar_g_chat_flood_lmax;
 815                         flood_field = floodcontrol_chat;
 816                 }
 817                 flood_burst = max(0, flood_burst - 1);
 818                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 819
 820                 // do flood control for the default line size
 821                 if(msgstr != "")
 822                 {
 823                         getWrappedLine_remaining = msgstr;
 824                         msgstr = "";
 825                         lines = 0;
 826                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 827                         {
 828                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 829                                 ++lines;
 830                         }
 831                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 832
 833                         if(getWrappedLine_remaining != "")
 834                         {
 835                                 msgstr = strcat(msgstr, "\n");
 836                                 flood = 2;
 837                         }
 838
 839                         if(time >= source.flood_field)
 840                         {
 841                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 842                         }
 843                         else
 844                         {
 845                                 flood = 1;
 846                                 msgstr = fullmsgstr;
 847                         }
 848                 }
 849                 else
 850                 {
 851                         if(time >= source.flood_field)
 852                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 853                         else
 854                                 flood = 1;
 855                 }
 856
 857                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 858                         source.flood_field = flood = 0;
 859         }
 860
 861         if(flood == 2) // cannot happen for empty msgstr
 862         {
 863                 if(autocvar_g_chat_flood_notify_flooder)
 864                 {
 865                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 866                         sourcecmsgstr = "";
 867                 }
 868                 else
 869                 {
 870                         sourcemsgstr = fullmsgstr;
 871                         sourcecmsgstr = fullcmsgstr;
 872                 }
 873                 cmsgstr = "";
 874         }
 875         else
 876         {
 877                 sourcemsgstr = msgstr;
 878                 sourcecmsgstr = cmsgstr;
 879         }
 880
 881         if(!privatesay)
 882         if(source.classname != "player")
 883         {
 884                 if not(intermission_running)
 885                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 886                                 teamsay = -1; // spectators
 887         }
 888
 889         if(flood)
 890                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 891
 892         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 893         if(privatesay)
 894                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 895
 896         if(source.muted)
 897         {
 898                 // always fake the message
 899                 ret = -1;
 900         }
 901         else if(flood == 1)
 902         {
 903                 if(autocvar_g_chat_flood_notify_flooder)
 904                 {
 905                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 906                         ret = 0;
 907                 }
 908                 else
 909                         ret = -1;
 910         }
 911         else
 912         {
 913                 ret = 1;
 914         }
 915
 916         if(sourcemsgstr != "" && ret != 0)
 917         {
 918                 if(ret < 0) // faked message, because the player is muted
 919                 {
 920                         sprint(source, sourcemsgstr);
 921                         if(sourcecmsgstr != "" && !privatesay)
 922                                 centerprint(source, sourcecmsgstr);
 923                 }
 924                 else if(privatesay) // private message, between 2 people only
 925                 {
 926                         sprint(source, sourcemsgstr);
 927                         sprint(privatesay, msgstr);
 928                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 929                         if(cmsgstr != "")
 930                                 centerprint(privatesay, cmsgstr);
 931                 }
 932                 else if(teamsay > 0) // team message, only sent to team mates
 933                 {
 934                         sprint(source, sourcemsgstr);
 935                         dedicated_print(msgstr); // send to server console too
 936                         if(sourcecmsgstr != "")
 937                                 centerprint(source, sourcecmsgstr);
 938                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 939                                 if(head != source)
 940                                 {
 941                                         sprint(head, msgstr);
 942                                         if(cmsgstr != "")
 943                                                 centerprint(head, cmsgstr);
 944                                 }
 945                 }
 946                 else if(teamsay < 0) // spectator message, only sent to spectators
 947                 {
 948                         sprint(source, sourcemsgstr);
 949                         dedicated_print(msgstr); // send to server console too
 950                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 951                                 if(head != source)
 952                                         sprint(head, msgstr);
 953                 }
 954                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 955                 {
 956                         sprint(source, sourcemsgstr);
 957                         dedicated_print(msgstr); // send to server console too
 958                         FOR_EACH_REALCLIENT(head)
 959                                 if(head != source)
 960                                         sprint(head, msgstr);
 961                 }
 962                 else
 963                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 964         }
 965
 966         return ret;
 967 }
 968
 969 float GetVoiceMessageVoiceType(string type)
 970 {
 971         if(type == "taunt")
 972                 return VOICETYPE_TAUNT;
 973         if(type == "teamshoot")
 974                 return VOICETYPE_LASTATTACKER;
 975         return VOICETYPE_TEAMRADIO;
 976 }
 977
 978 string allvoicesamples;
 979 .string GetVoiceMessageSampleField(string type)
 980 {
 981         GetPlayerSoundSampleField_notFound = 0;
 982         switch(type)
 983         {
 984 #define _VOICEMSG(m) case #m: return playersound_##m;
 985                 ALLVOICEMSGS
 986 #undef _VOICEMSG
 987         }
 988         GetPlayerSoundSampleField_notFound = 1;
 989         return playersound_taunt;
 990 }
 991
 992 .string GetPlayerSoundSampleField(string type)
 993 {
 994         GetPlayerSoundSampleField_notFound = 0;
 995         switch(type)
 996         {
 997 #define _VOICEMSG(m) case #m: return playersound_##m;
 998                 ALLPLAYERSOUNDS
 999 #undef _VOICEMSG
1000         }
1001         GetPlayerSoundSampleField_notFound = 1;
1002         return playersound_taunt;
1003 }
1004
1005 void PrecacheGlobalSound(string samplestring)
1006 {
1007         float n, i;
1008         tokenize_console(samplestring);
1009         n = stof(argv(1));
1010         if(n > 0)
1011         {
1012                 for(i = 1; i <= n; ++i)
1013                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1014         }
1015         else
1016         {
1017                 precache_sound(strcat(argv(0), ".wav"));
1018         }
1019 }
1020
1021 void PrecachePlayerSounds(string f)
1022 {
1023         float fh;
1024         string s;
1025         fh = fopen(f, FILE_READ);
1026         if(fh < 0)
1027                 return;
1028         while((s = fgets(fh)))
1029         {
1030                 if(tokenize_console(s) != 3)
1031                 {
1032                         dprint("Invalid sound info line: ", s, "\n");
1033                         continue;
1034                 }
1035                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1036         }
1037         fclose(fh);
1038
1039         if not(allvoicesamples)
1040         {
1041 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1042                 ALLVOICEMSGS
1043 #undef _VOICEMSG
1044                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1045         }
1046 }
1047
1048 void ClearPlayerSounds()
1049 {
1050 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1051         ALLPLAYERSOUNDS
1052         ALLVOICEMSGS
1053 #undef _VOICEMSG
1054 }
1055
1056 float LoadPlayerSounds(string f, float first)
1057 {
1058         float fh;
1059         string s;
1060         var .string field;
1061         fh = fopen(f, FILE_READ);
1062         if(fh < 0)
1063         {
1064                 dprint("Player sound file not found: ", f, "\n");
1065                 return 0;
1066         }
1067         while((s = fgets(fh)))
1068         {
1069                 if(tokenize_console(s) != 3)
1070                         continue;
1071                 field = GetPlayerSoundSampleField(argv(0));
1072                 if(GetPlayerSoundSampleField_notFound)
1073                         field = GetVoiceMessageSampleField(argv(0));
1074                 if(GetPlayerSoundSampleField_notFound)
1075                         continue;
1076                 if(self.field)
1077                         strunzone(self.field);
1078                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1079         }
1080         fclose(fh);
1081         return 1;
1082 }
1083
1084 .float modelindex_for_playersound;
1085 .float skin_for_playersound;
1086 void UpdatePlayerSounds()
1087 {
1088         if(self.modelindex == self.modelindex_for_playersound)
1089         if(self.skin == self.skin_for_playersound)
1090                 return;
1091         self.modelindex_for_playersound = self.modelindex;
1092         self.skin_for_playersound = self.skin;
1093         ClearPlayerSounds();
1094         LoadPlayerSounds("sound/player/default.sounds", 1);
1095         if(!autocvar_g_debug_defaultsounds)
1096                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1097                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1098 }
1099
1100 void FakeGlobalSound(string sample, float chan, float voicetype)
1101 {
1102         float n;
1103         float tauntrand;
1104
1105         if(sample == "")
1106                 return;
1107
1108         tokenize_console(sample);
1109         n = stof(argv(1));
1110         if(n > 0)
1111                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1112         else
1113                 sample = strcat(argv(0), ".wav"); // randomization
1114
1115         switch(voicetype)
1116         {
1117                 case VOICETYPE_LASTATTACKER_ONLY:
1118                         break;
1119                 case VOICETYPE_LASTATTACKER:
1120                         if(self.pusher)
1121                         {
1122                                 msg_entity = self;
1123                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1124                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1125                         }
1126                         break;
1127                 case VOICETYPE_TEAMRADIO:
1128                         msg_entity = self;
1129                         if(msg_entity.cvar_cl_voice_directional == 1)
1130                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1131                         else
1132                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1133                         break;
1134                 case VOICETYPE_AUTOTAUNT:
1135                         if(!sv_autotaunt)
1136                                 break;
1137                         if(!sv_taunt)
1138                                 break;
1139                         if(autocvar_sv_gentle)
1140                                 break;
1141                         tauntrand = random();
1142                         msg_entity = self;
1143                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1144                         {
1145                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1146                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1147                                 else
1148                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1149                         }
1150                         break;
1151                 case VOICETYPE_TAUNT:
1152                         if(self.classname == "player")
1153                                 if(self.deadflag == DEAD_NO)
1154                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1155                         if(!sv_taunt)
1156                                 break;
1157                         if(autocvar_sv_gentle)
1158                                 break;
1159                         msg_entity = self;
1160                         if (msg_entity.cvar_cl_voice_directional >= 1)
1161                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1162                         else
1163                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1164                         break;
1165                 case VOICETYPE_PLAYERSOUND:
1166                         msg_entity = self;
1167                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1168                         break;
1169                 default:
1170                         backtrace("Invalid voice type!");
1171                         break;
1172         }
1173 }
1174
1175 void GlobalSound(string sample, float chan, float voicetype)
1176 {
1177         float n;
1178         float tauntrand;
1179
1180         if(sample == "")
1181                 return;
1182
1183         tokenize_console(sample);
1184         n = stof(argv(1));
1185         if(n > 0)
1186                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1187         else
1188                 sample = strcat(argv(0), ".wav"); // randomization
1189
1190         switch(voicetype)
1191         {
1192                 case VOICETYPE_LASTATTACKER_ONLY:
1193                         if(self.pusher)
1194                         {
1195                                 msg_entity = self.pusher;
1196                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1197                                 {
1198                                         if(msg_entity.cvar_cl_voice_directional == 1)
1199                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1200                                         else
1201                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1202                                 }
1203                         }
1204                         break;
1205                 case VOICETYPE_LASTATTACKER:
1206                         if(self.pusher)
1207                         {
1208                                 msg_entity = self.pusher;
1209                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1210                                 {
1211                                         if(msg_entity.cvar_cl_voice_directional == 1)
1212                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1213                                         else
1214                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1215                                 }
1216                                 msg_entity = self;
1217                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1218                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1219                         }
1220                         break;
1221                 case VOICETYPE_TEAMRADIO:
1222                         FOR_EACH_REALCLIENT(msg_entity)
1223                                 if(!teamplay || msg_entity.team == self.team)
1224                                 {
1225                                         if(msg_entity.cvar_cl_voice_directional == 1)
1226                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1227                                         else
1228                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1229                                 }
1230                         break;
1231                 case VOICETYPE_AUTOTAUNT:
1232                         if(!sv_autotaunt)
1233                                 break;
1234                         if(!sv_taunt)
1235                                 break;
1236                         if(autocvar_sv_gentle)
1237                                 break;
1238                         tauntrand = random();
1239                         FOR_EACH_REALCLIENT(msg_entity)
1240                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1241                                 {
1242                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1243                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1244                                         else
1245                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1246                                 }
1247                         break;
1248                 case VOICETYPE_TAUNT:
1249                         if(self.classname == "player")
1250                                 if(self.deadflag == DEAD_NO)
1251                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1252                         if(!sv_taunt)
1253                                 break;
1254                         if(autocvar_sv_gentle)
1255                                 break;
1256                         FOR_EACH_REALCLIENT(msg_entity)
1257                         {
1258                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1259                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1260                                 else
1261                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1262                         }
1263                         break;
1264                 case VOICETYPE_PLAYERSOUND:
1265                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1266                         break;
1267                 default:
1268                         backtrace("Invalid voice type!");
1269                         break;
1270         }
1271 }
1272
1273 void PlayerSound(.string samplefield, float chan, float voicetype)
1274 {
1275         GlobalSound(self.samplefield, chan, voicetype);
1276 }
1277
1278 void VoiceMessage(string type, string msg)
1279 {
1280         var .string sample;
1281         float voicetype, ownteam;
1282         float flood;
1283         sample = GetVoiceMessageSampleField(type);
1284
1285         if(GetPlayerSoundSampleField_notFound)
1286         {
1287                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1288                 return;
1289         }
1290
1291         voicetype = GetVoiceMessageVoiceType(type);
1292         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1293
1294         flood = Say(self, ownteam, world, msg, 1);
1295
1296         if (flood > 0)
1297                 GlobalSound(self.sample, CH_VOICE, voicetype);
1298         else if (flood < 0)
1299                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1300 }
1301
1302 void MoveToTeam(entity client, float team_colour, float type)
1303 {
1304         float lockteams_backup;
1305
1306         lockteams_backup = lockteams;  // backup any team lock
1307
1308         lockteams = 0;  // disable locked teams
1309
1310         TeamchangeFrags(client);  // move the players frags
1311         SetPlayerColors(client, team_colour - 1);  // set the players colour
1312         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1313
1314         lockteams = lockteams_backup;  // restore the team lock
1315
1316         LogTeamchange(client.playerid, client.team, type);
1317 }