qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.animstate_startframe = oldself.animstate_startframe;
 165         self.animstate_numframes = oldself.animstate_numframes;
 166         self.animstate_framerate = oldself.animstate_framerate;
 167         self.animstate_starttime = oldself.animstate_starttime;
 168         self.animstate_endtime = oldself.animstate_endtime;
 169         self.animstate_override = oldself.animstate_override;
 170         self.animstate_looping = oldself.animstate_looping;
 171         self.dphitcontentsmask = oldself.dphitcontentsmask;
 172         self.death_time = oldself.death_time;
 173         self.frame = oldself.frame;
 174         self.pain_finished = oldself.pain_finished;
 175         self.health = oldself.health;
 176         self.armorvalue = oldself.armorvalue;
 177         self.armortype = oldself.armortype;
 178         self.model = oldself.model;
 179         self.modelindex = oldself.modelindex;
 180         self.skin = oldself.skin;
 181         self.species = oldself.species;
 182         self.movetype = oldself.movetype;
 183         self.solid = oldself.solid;
 184         self.ballistics_density = oldself.ballistics_density;
 185         self.takedamage = oldself.takedamage;
 186         self.customizeentityforclient = oldself.customizeentityforclient;
 187         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 188         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 189         if (keepvelocity == 1)
 190                 self.velocity = oldself.velocity;
 191         self.oldvelocity = self.velocity;
 192         self.alpha = oldself.alpha;
 193         self.fade_time = oldself.fade_time;
 194         self.fade_rate = oldself.fade_rate;
 195         //self.weapon = oldself.weapon;
 196         setorigin(self, oldself.origin);
 197         setsize(self, oldself.mins, oldself.maxs);
 198         self.prevorigin = oldself.origin;
 199         self.reset = SUB_Remove;
 200
 201         Drag_MoveDrag(oldself, self);
 202
 203         if(self.colormap <= maxclients && self.colormap > 0)
 204                 self.colormap = 1024 + oldself.clientcolors;
 205
 206         CSQCMODEL_AUTOINIT();
 207         self.CopyBody_nextthink = oldself.nextthink;
 208         self.CopyBody_think = oldself.think;
 209         self.nextthink = time;
 210         self.think = CopyBody_Think;
 211
 212         self = oldself;
 213 }
 214
 215 float player_getspecies()
 216 {
 217         float s;
 218         get_model_parameters(self.model, self.skin);
 219         s = get_model_parameters_species;
 220         get_model_parameters(string_null, 0);
 221         if(s < 0)
 222                 return SPECIES_HUMAN;
 223         return s;
 224 }
 225
 226 void player_setupanimsformodel()
 227 {
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 230         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 231         self.anim_draw = animfixfps(self, '2 1 3');
 232         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 233         self.anim_duckwalk = animfixfps(self, '4 1 1');
 234         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = animfixfps(self, '6 1 1');
 236         self.anim_idle = animfixfps(self, '7 1 1');
 237         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 239         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 240         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 241         self.anim_taunt = animfixfps(self, '12 1 0.33');
 242         self.anim_run = animfixfps(self, '13 1 1');
 243         self.anim_runbackwards = animfixfps(self, '14 1 1');
 244         self.anim_strafeleft = animfixfps(self, '15 1 1');
 245         self.anim_straferight = animfixfps(self, '16 1 1');
 246         //self.anim_dead1 = animfixfps(self, '17 1 1');
 247         //self.anim_dead2 = animfixfps(self, '18 1 1');
 248         self.anim_forwardright = animfixfps(self, '19 1 1');
 249         self.anim_forwardleft = animfixfps(self, '20 1 1');
 250         self.anim_backright = animfixfps(self, '21 1 1');
 251         self.anim_backleft  = animfixfps(self, '22 1 1');
 252         self.anim_melee = animfixfps(self, '23 1 1');
 253         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 254         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 255         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 256         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 257         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 258         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 259         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 260         // TODO introspect models for finding right "fps" value (1/duration)
 261         // reset animstate now
 262         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 263 }
 264
 265 void player_anim (void)
 266 {
 267         updateanim(self);
 268         if (self.weaponentity)
 269                 updateanim(self.weaponentity);
 270
 271         if (self.deadflag != DEAD_NO)
 272                 return;
 273
 274         if (!self.animstate_override)
 275         {
 276                 if (self.freezetag_frozen)
 277                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 278                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 279                 {
 280                         if (self.crouch)
 281                         {
 282                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 283                                 {
 284                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 285                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 286                                         {
 287                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 288                                                 self.restart_jump = FALSE;
 289                                         }
 290                                 }
 291                         }
 292                         else
 293                         {
 294                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 295                 {
 296                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 297                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 298                     {
 299                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 300                         self.restart_jump = FALSE;
 301                     }
 302                 }
 303                         }
 304                 }
 305                 else if (self.crouch)
 306                 {
 307                         if (self.movement_x > 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y == 0)
 310                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x == 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x > 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x < 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_pinata)
 359         {
 360                 float j;
 361                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 362                 {
 363                         if(WEPSET_CONTAINS_EW(self, j))
 364                                 if(W_IsWeaponThrowable(j))
 365                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 366                 }
 367         }
 368         else
 369         {
 370                 if(W_IsWeaponThrowable(self.weapon))
 371                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 372         }
 373 }
 374
 375 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 376 {
 377         float take, save;
 378         vector v;
 379         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 380
 381         // damage resistance (ignore most of the damage from a bullet or similar)
 382         damage = max(damage - 5, 1);
 383
 384         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 385         take = v_x;
 386         save = v_y;
 387
 388         if(sound_allowed(MSG_BROADCAST, attacker))
 389         {
 390                 if (save > 10)
 391                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 392                 else if (take > 30)
 393                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 10)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 396         }
 397
 398         if (take > 50)
 399                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 400         if (take > 100)
 401                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 402
 403         if (!(self.flags & FL_GODMODE))
 404         {
 405                 self.armorvalue = self.armorvalue - save;
 406                 self.health = self.health - take;
 407                 // pause regeneration for 5 seconds
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409         }
 410         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 411         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 412         self.dmg_inflictor = inflictor;
 413
 414         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 415         {
 416                 // don't use any animations as a gib
 417                 self.frame = 0;
 418                 // view just above the floor
 419                 self.view_ofs = '0 0 4';
 420
 421                 Violence_GibSplash(self, 1, 1, attacker);
 422                 self.alpha = -1;
 423                 self.solid = SOLID_NOT; // restore later
 424                 self.takedamage = DAMAGE_NO; // restore later
 425                 self.damagedbycontents = FALSE;
 426         }
 427 }
 428
 429 void ClientKill_Now_TeamChange();
 430 void freezetag_CheckWinner();
 431
 432 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 433 {
 434         float take, save, waves, sdelay, dh, da, j;
 435         vector v;
 436         float valid_damage_for_weaponstats;
 437         float excess;
 438
 439         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 440                 return;
 441
 442         dh = max(self.health, 0);
 443         da = max(self.armorvalue, 0);
 444
 445         if(!DEATH_ISSPECIAL(deathtype))
 446         {
 447                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 448                 if(self != attacker)
 449                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 450         }
 451
 452         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 453         {
 454                 // tuba causes blood to come out of the ears
 455                 vector ear1, ear2;
 456                 vector d;
 457                 float f;
 458                 ear1 = self.origin;
 459                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 460                 ear2 = ear1;
 461                 makevectors(self.angles);
 462                 ear1 += v_right * -10;
 463                 ear2 += v_right * +10;
 464                 d = inflictor.origin - self.origin;
 465                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 466                 force = v_right * vlen(force);
 467                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 468                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 469                 if(f > 0)
 470                 {
 471                         hitloc = ear1;
 472                         force = force * -1;
 473                 }
 474                 else
 475                 {
 476                         hitloc = ear2;
 477                         // force is already good
 478                 }
 479         }
 480         else
 481                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 482
 483
 484         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 485         take = v_x;
 486         save = v_y;
 487
 488         if(attacker == self)
 489         {
 490                 // don't reset pushltime for self damage as it may be an attempt to
 491                 // escape a lava pit or similar
 492                 //self.pushltime = 0;
 493                 self.istypefrag = 0;
 494         }
 495         else if(attacker.classname == "player")
 496         {
 497                 self.pusher = attacker;
 498                 self.pushltime = time + autocvar_g_maxpushtime;
 499                 self.istypefrag = self.BUTTON_CHAT;
 500         }
 501         else if(time < self.pushltime)
 502         {
 503                 attacker = self.pusher;
 504                 self.pushltime = max(self.pushltime, time + 0.6);
 505         }
 506         else
 507         {
 508                 self.pushltime = 0;
 509                 self.istypefrag = 0;
 510         }
 511
 512         frag_inflictor = inflictor;
 513         frag_attacker = attacker;
 514         frag_target = self;
 515         damage_take = take;
 516         damage_save = save;
 517         damage_force = force;
 518         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 519         take = bound(0, damage_take, self.health);
 520         save = bound(0, damage_save, self.armorvalue);
 521         excess = max(0, damage - take - save);
 522
 523         if(sound_allowed(MSG_BROADCAST, attacker))
 524         {
 525                 if (save > 10)
 526                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 527                 else if (take > 30)
 528                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 529                 else if (take > 10)
 530                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 531         }
 532
 533         if (take > 50)
 534                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 535         if (take > 100)
 536                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 537
 538         if (time >= self.spawnshieldtime)
 539         {
 540                 if (!(self.flags & FL_GODMODE))
 541                 {
 542                         self.armorvalue = self.armorvalue - save;
 543                         self.health = self.health - take;
 544                         // pause regeneration for 5 seconds
 545                         if(take)
 546                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 547
 548                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 549                         {
 550                                 self.pain_finished = time + 0.5;        //Supajoe
 551
 552                                 if(sv_gentle < 1) {
 553                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 554                                         {
 555                                                 if (!self.animstate_override)
 556                                                 {
 557                                                         if (random() > 0.5)
 558                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 559                                                         else
 560                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 561                                                 }
 562                                         }
 563
 564                                         if(sound_allowed(MSG_BROADCAST, attacker))
 565                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 566                                         if(self.health > 1)
 567                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 568                                         {
 569                                                 if(deathtype == DEATH_FALL)
 570                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 571                                                 else if(self.health > 75) // TODO make a "gentle" version?
 572                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 573                                                 else if(self.health > 50)
 574                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 575                                                 else if(self.health > 25)
 576                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 577                                                 else
 578                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 579                                         }
 580                                 }
 581
 582                                 // throw off bot aim temporarily
 583                                 float shake;
 584                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 585                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 586                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 587                         }
 588                 }
 589                 else
 590                         self.max_armorvalue += (save + take);
 591         }
 592         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 593         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 594         self.dmg_inflictor = inflictor;
 595
 596         if(g_ca && self != attacker && attacker.classname == "player")
 597                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 598
 599         float abot, vbot, awep;
 600         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 601         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 602
 603         valid_damage_for_weaponstats = 0;
 604         awep = 0;
 605
 606         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 607         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 608         if(attacker && self != attacker)
 609         if(IsDifferentTeam(self, attacker))
 610         {
 611                 if(DEATH_ISSPECIAL(deathtype))
 612                         awep = attacker.weapon;
 613                 else
 614                         awep = DEATH_WEAPONOF(deathtype);
 615                 valid_damage_for_weaponstats = 1;
 616         }
 617
 618         if(valid_damage_for_weaponstats)
 619         {
 620                 dh = dh - max(self.health, 0);
 621                 da = da - max(self.armorvalue, 0);
 622                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 623         }
 624
 625         if (self.health < 1)
 626         {
 627                 float defer_ClientKill_Now_TeamChange;
 628                 defer_ClientKill_Now_TeamChange = FALSE;
 629
 630                 if(self.alivetime)
 631                 {
 632                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 633                         self.alivetime = 0;
 634                 }
 635
 636                 if(valid_damage_for_weaponstats)
 637                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 638
 639                 if(sv_gentle < 1) // TODO make a "gentle" version?
 640                 if(sound_allowed(MSG_BROADCAST, attacker))
 641                 {
 642                         if(deathtype == DEATH_DROWN)
 643                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 644                         else
 645                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 646                 }
 647
 648                 // get rid of kill indicator
 649                 if(self.killindicator)
 650                 {
 651                         remove(self.killindicator);
 652                         self.killindicator = world;
 653                         if(self.killindicator_teamchange)
 654                                 defer_ClientKill_Now_TeamChange = TRUE;
 655
 656                         if(self.classname == "body")
 657                         if(deathtype == DEATH_KILL)
 658                         {
 659                                 // for the lemmings fans, a small harmless explosion
 660                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 661                         }
 662                 }
 663
 664                 if(!g_freezetag)
 665                 {
 666                         // become fully visible
 667                         self.alpha = default_player_alpha;
 668                         // throw a weapon
 669                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 670                 }
 671
 672                 // print an obituary message
 673                 Obituary (attacker, inflictor, self, deathtype);
 674                 race_PreDie();
 675                 DropAllRunes(self);
 676
 677         // increment frag counter for used weapon type
 678         float w;
 679         w = DEATH_WEAPONOF(deathtype);
 680         if(WEP_VALID(w))
 681         if(accuracy_isgooddamage(attacker, self))
 682         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 683
 684                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 685                 {
 686                         PutClientInServer();
 687                         count_alive_players(); // re-count players
 688                         freezetag_CheckWinner();
 689                         return;
 690                 }
 691
 692                 frag_attacker = attacker;
 693                 frag_inflictor = inflictor;
 694                 frag_target = self;
 695                 MUTATOR_CALLHOOK(PlayerDies);
 696                 weapon_action(self.weapon, WR_PLAYERDEATH);
 697
 698                 RemoveGrapplingHook(self);
 699
 700                 Portal_ClearAllLater(self);
 701
 702                 if(clienttype(self) == CLIENTTYPE_REAL)
 703                 {
 704                         stuffcmd(self, "-zoom\n");
 705                         self.fixangle = TRUE;
 706                         //msg_entity = self;
 707                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 708                         //WriteAngle (MSG_ONE, self.v_angle_x);
 709                         //WriteAngle (MSG_ONE, self.v_angle_y);
 710                         //WriteAngle (MSG_ONE, 80);
 711                 }
 712
 713                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 714                         ClientKill_Now_TeamChange();
 715
 716                 if(g_arena)
 717                         Spawnqueue_Unmark(self);
 718
 719                 if(g_freezetag)
 720                         return;
 721
 722                 // when we get here, player actually dies
 723                 // clear waypoints (do this AFTER FreezeTag)
 724                 WaypointSprite_PlayerDead();
 725
 726                 // make the corpse upright (not tilted)
 727                 self.angles_x = 0;
 728                 self.angles_z = 0;
 729                 // don't spin
 730                 self.avelocity = '0 0 0';
 731                 // view from the floor
 732                 self.view_ofs = '0 0 -8';
 733                 // toss the corpse
 734                 self.movetype = MOVETYPE_TOSS;
 735                 // shootable corpse
 736                 self.solid = SOLID_CORPSE;
 737                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 738                 // don't stick to the floor
 739                 self.flags &~= FL_ONGROUND;
 740                 // dying animation
 741                 self.deadflag = DEAD_DYING;
 742                 // when to allow respawn
 743                 sdelay = 0;
 744                 waves = 0;
 745                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 746                 if(!sdelay)
 747                 {
 748                         if(g_cts)
 749                                 sdelay = 0; // no respawn delay in CTS
 750                         else
 751                                 sdelay = autocvar_g_respawn_delay;
 752                 }
 753                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 754                 if(!waves)
 755                         waves = autocvar_g_respawn_waves;
 756                 if(waves)
 757                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 758                 else
 759                         self.respawn_time = time + sdelay;
 760                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 761                         self.respawn_countdown = 10; // first number to count down from is 10
 762                 else
 763                         self.respawn_countdown = -1; // do not count down
 764                 self.death_time = time;
 765                 if (random() < 0.5)
 766                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 767                 else
 768                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 769                 if (self.maxs_z > 5)
 770                 {
 771                         self.maxs_z = 5;
 772                         setsize(self, self.mins, self.maxs);
 773                 }
 774                 // set damage function to corpse damage
 775                 self.event_damage = PlayerCorpseDamage;
 776                 // call the corpse damage function just in case it wants to gib
 777                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 778                 // set up to fade out later
 779                 SUB_SetFade (self, time + 6 + random (), 1);
 780
 781                 if(sv_gentle > 0 || autocvar_ekg) {
 782                         // remove corpse
 783                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 784                 }
 785
 786                 // reset fields the weapons may use just in case
 787                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 788                 {
 789                         weapon_action(j, WR_RESETPLAYER);
 790                         ATTACK_FINISHED_FOR(self, j) = 0;
 791                 }
 792         }
 793 }
 794
 795 .float muted; // to be used by prvm_edictset server playernumber muted 1
 796 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 797 // message "": do not say, just test flood control
 798 // return value:
 799 //   1 = accept
 800 //   0 = reject
 801 //  -1 = fake accept
 802 {
 803         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 804         float flood;
 805         var .float flood_field;
 806         entity head;
 807         float ret;
 808         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 809
 810         if(!teamsay && !privatesay)
 811                 if(substring(msgin, 0, 1) == " ")
 812                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 813
 814         msgin = formatmessage(msgin);
 815
 816         if(source.classname != "player")
 817                 colorstr = "^0"; // black for spectators
 818         else if(teamplay)
 819                 colorstr = Team_ColorCode(source.team);
 820         else
 821         {
 822                 colorstr = "";
 823                 teamsay = FALSE;
 824         }
 825
 826         if(intermission_running)
 827                 teamsay = FALSE;
 828
 829         if(msgin != "")
 830                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 831
 832         /*
 833          * using bprint solves this... me stupid
 834         // how can we prevent the message from appearing in a listen server?
 835         // for now, just give "say" back and only handle say_team
 836         if(!teamsay)
 837         {
 838                 clientcommand(self, strcat("say ", msgin));
 839                 return;
 840         }
 841         */
 842
 843         if(autocvar_g_chat_teamcolors)
 844                 namestr = playername(source);
 845         else
 846                 namestr = source.netname;
 847
 848         if(msgin != "")
 849         {
 850                 if(privatesay)
 851                 {
 852                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 853                         privatemsgprefixlen = strlen(msgstr);
 854                         msgstr = strcat(msgstr, msgin);
 855                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 856                         if(autocvar_g_chat_teamcolors)
 857                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 858                         else
 859                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 860                 }
 861                 else if(teamsay)
 862                 {
 863                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 864                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 865                 }
 866                 else
 867                 {
 868                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 869                         cmsgstr = "";
 870                 }
 871                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 872         }
 873         else
 874         {
 875                 msgstr = cmsgstr = "";
 876         }
 877
 878         fullmsgstr = msgstr;
 879         fullcmsgstr = cmsgstr;
 880
 881         // FLOOD CONTROL
 882         flood = 0;
 883         flood_field = floodcontrol_chat;
 884         if(floodcontrol)
 885         {
 886                 float flood_spl;
 887                 float flood_burst;
 888                 float flood_lmax;
 889                 float lines;
 890                 if(privatesay)
 891                 {
 892                         flood_spl = autocvar_g_chat_flood_spl_tell;
 893                         flood_burst = autocvar_g_chat_flood_burst_tell;
 894                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 895                         flood_field = floodcontrol_chattell;
 896                 }
 897                 else if(teamsay)
 898                 {
 899                         flood_spl = autocvar_g_chat_flood_spl_team;
 900                         flood_burst = autocvar_g_chat_flood_burst_team;
 901                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 902                         flood_field = floodcontrol_chatteam;
 903                 }
 904                 else
 905                 {
 906                         flood_spl = autocvar_g_chat_flood_spl;
 907                         flood_burst = autocvar_g_chat_flood_burst;
 908                         flood_lmax = autocvar_g_chat_flood_lmax;
 909                         flood_field = floodcontrol_chat;
 910                 }
 911                 flood_burst = max(0, flood_burst - 1);
 912                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 913
 914                 // do flood control for the default line size
 915                 if(msgstr != "")
 916                 {
 917                         getWrappedLine_remaining = msgstr;
 918                         msgstr = "";
 919                         lines = 0;
 920                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 921                         {
 922                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 923                                 ++lines;
 924                         }
 925                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 926
 927                         if(getWrappedLine_remaining != "")
 928                         {
 929                                 msgstr = strcat(msgstr, "\n");
 930                                 flood = 2;
 931                         }
 932
 933                         if(time >= source.flood_field)
 934                         {
 935                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 936                         }
 937                         else
 938                         {
 939                                 flood = 1;
 940                                 msgstr = fullmsgstr;
 941                         }
 942                 }
 943                 else
 944                 {
 945                         if(time >= source.flood_field)
 946                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 947                         else
 948                                 flood = 1;
 949                 }
 950
 951                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 952                         source.flood_field = flood = 0;
 953         }
 954
 955         if(flood == 2) // cannot happen for empty msgstr
 956         {
 957                 if(autocvar_g_chat_flood_notify_flooder)
 958                 {
 959                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 960                         sourcecmsgstr = "";
 961                 }
 962                 else
 963                 {
 964                         sourcemsgstr = fullmsgstr;
 965                         sourcecmsgstr = fullcmsgstr;
 966                 }
 967                 cmsgstr = "";
 968         }
 969         else
 970         {
 971                 sourcemsgstr = msgstr;
 972                 sourcecmsgstr = cmsgstr;
 973         }
 974
 975         if(!privatesay)
 976         if(source.classname != "player")
 977         {
 978                 if not(intermission_running)
 979                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 980                                 teamsay = -1; // spectators
 981         }
 982
 983         if(flood)
 984                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 985
 986         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 987         if(privatesay)
 988                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 989
 990         if(source.muted)
 991         {
 992                 // always fake the message
 993                 ret = -1;
 994         }
 995         else if(flood == 1)
 996         {
 997                 if(autocvar_g_chat_flood_notify_flooder)
 998                 {
 999                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1000                         ret = 0;
1001                 }
1002                 else
1003                         ret = -1;
1004         }
1005         else
1006         {
1007                 ret = 1;
1008         }
1009
1010         if(sourcemsgstr != "" && ret != 0)
1011         {
1012                 if(ret < 0) // faked message, because the player is muted
1013                 {
1014                         sprint(source, sourcemsgstr);
1015                         if(sourcecmsgstr != "" && !privatesay)
1016                                 centerprint(source, sourcecmsgstr);
1017                 }
1018                 else if(privatesay) // private message, between 2 people only, not sent to server console
1019                 {
1020                         sprint(source, sourcemsgstr);
1021                         sprint(privatesay, msgstr);
1022                         if(cmsgstr != "")
1023                                 centerprint(privatesay, cmsgstr);
1024                 }
1025                 else if(teamsay > 0) // team message, only sent to team mates
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         //print(msgstr); // send to server console too
1029                         if(sourcecmsgstr != "")
1030                                 centerprint(source, sourcecmsgstr);
1031                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1032                                 if(head != source)
1033                                 {
1034                                         sprint(head, msgstr);
1035                                         if(cmsgstr != "")
1036                                                 centerprint(head, cmsgstr);
1037                                 }
1038                 }
1039                 else if(teamsay < 0) // spectator message, only sent to spectators
1040                 {
1041                         sprint(source, sourcemsgstr);
1042                         //print(msgstr); // send to server console too
1043                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1044                                 if(head != source)
1045                                         sprint(head, msgstr);
1046                 }
1047                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1048                 {
1049                         sprint(source, sourcemsgstr);
1050                         //print(msgstr); // send to server console too
1051                         FOR_EACH_REALCLIENT(head)
1052                                 if(head != source)
1053                                         sprint(head, msgstr);
1054                 }
1055                 else
1056                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1057         }
1058
1059         return ret;
1060 }
1061
1062 float GetVoiceMessageVoiceType(string type)
1063 {
1064         if(type == "taunt")
1065                 return VOICETYPE_TAUNT;
1066         if(type == "teamshoot")
1067                 return VOICETYPE_LASTATTACKER;
1068         return VOICETYPE_TEAMRADIO;
1069 }
1070
1071 string allvoicesamples;
1072 .string GetVoiceMessageSampleField(string type)
1073 {
1074         GetPlayerSoundSampleField_notFound = 0;
1075         switch(type)
1076         {
1077 #define _VOICEMSG(m) case #m: return playersound_##m;
1078                 ALLVOICEMSGS
1079 #undef _VOICEMSG
1080         }
1081         GetPlayerSoundSampleField_notFound = 1;
1082         return playersound_taunt;
1083 }
1084
1085 .string GetPlayerSoundSampleField(string type)
1086 {
1087         GetPlayerSoundSampleField_notFound = 0;
1088         switch(type)
1089         {
1090 #define _VOICEMSG(m) case #m: return playersound_##m;
1091                 ALLPLAYERSOUNDS
1092 #undef _VOICEMSG
1093         }
1094         GetPlayerSoundSampleField_notFound = 1;
1095         return playersound_taunt;
1096 }
1097
1098 void PrecacheGlobalSound(string samplestring)
1099 {
1100         float n, i;
1101         tokenize_console(samplestring);
1102         n = stof(argv(1));
1103         if(n > 0)
1104         {
1105                 for(i = 1; i <= n; ++i)
1106                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1107         }
1108         else
1109         {
1110                 precache_sound(strcat(argv(0), ".wav"));
1111         }
1112 }
1113
1114 void PrecachePlayerSounds(string f)
1115 {
1116         float fh;
1117         string s;
1118         fh = fopen(f, FILE_READ);
1119         if(fh < 0)
1120                 return;
1121         while((s = fgets(fh)))
1122         {
1123                 if(tokenize_console(s) != 3)
1124                 {
1125                         dprint("Invalid sound info line: ", s, "\n");
1126                         continue;
1127                 }
1128                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1129         }
1130         fclose(fh);
1131
1132         if not(allvoicesamples)
1133         {
1134 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1135                 ALLVOICEMSGS
1136 #undef _VOICEMSG
1137                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1138         }
1139 }
1140
1141 void ClearPlayerSounds()
1142 {
1143 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1144         ALLPLAYERSOUNDS
1145         ALLVOICEMSGS
1146 #undef _VOICEMSG
1147 }
1148
1149 float LoadPlayerSounds(string f, float first)
1150 {
1151         float fh;
1152         string s;
1153         var .string field;
1154         fh = fopen(f, FILE_READ);
1155         if(fh < 0)
1156         {
1157                 dprint("Player sound file not found: ", f, "\n");
1158                 return 0;
1159         }
1160         while((s = fgets(fh)))
1161         {
1162                 if(tokenize_console(s) != 3)
1163                         continue;
1164                 field = GetPlayerSoundSampleField(argv(0));
1165                 if(GetPlayerSoundSampleField_notFound)
1166                         field = GetVoiceMessageSampleField(argv(0));
1167                 if(GetPlayerSoundSampleField_notFound)
1168                         continue;
1169                 if(self.field)
1170                         strunzone(self.field);
1171                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1172         }
1173         fclose(fh);
1174         return 1;
1175 }
1176
1177 .float modelindex_for_playersound;
1178 .float skin_for_playersound;
1179 void UpdatePlayerSounds()
1180 {
1181         if(self.modelindex == self.modelindex_for_playersound)
1182         if(self.skin == self.skin_for_playersound)
1183                 return;
1184         self.modelindex_for_playersound = self.modelindex;
1185         self.skin_for_playersound = self.skin;
1186         ClearPlayerSounds();
1187         LoadPlayerSounds("sound/player/default.sounds", 1);
1188         if(!autocvar_g_debug_defaultsounds)
1189                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1190                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1191 }
1192
1193 void FakeGlobalSound(string sample, float chan, float voicetype)
1194 {
1195         float n;
1196         float tauntrand;
1197
1198         if(sample == "")
1199                 return;
1200
1201         tokenize_console(sample);
1202         n = stof(argv(1));
1203         if(n > 0)
1204                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1205         else
1206                 sample = strcat(argv(0), ".wav"); // randomization
1207
1208         switch(voicetype)
1209         {
1210                 case VOICETYPE_LASTATTACKER_ONLY:
1211                         break;
1212                 case VOICETYPE_LASTATTACKER:
1213                         if(self.pusher)
1214                         {
1215                                 msg_entity = self;
1216                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1217                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1218                         }
1219                         break;
1220                 case VOICETYPE_TEAMRADIO:
1221                         msg_entity = self;
1222                         if(msg_entity.cvar_cl_voice_directional == 1)
1223                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1224                         else
1225                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1226                         break;
1227                 case VOICETYPE_AUTOTAUNT:
1228                         if(!sv_autotaunt)
1229                                 break;
1230                         if(!sv_taunt)
1231                                 break;
1232                         if(sv_gentle)
1233                                 break;
1234                         tauntrand = random();
1235                         msg_entity = self;
1236                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1237                         {
1238                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1239                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1240                                 else
1241                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1242                         }
1243                         break;
1244                 case VOICETYPE_TAUNT:
1245                         if(self.classname == "player")
1246                                 if(self.deadflag == DEAD_NO)
1247                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1248                         if(!sv_taunt)
1249                                 break;
1250                         if(sv_gentle)
1251                                 break;
1252                         msg_entity = self;
1253                         if (msg_entity.cvar_cl_voice_directional >= 1)
1254                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1255                         else
1256                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1257                         break;
1258                 case VOICETYPE_PLAYERSOUND:
1259                         msg_entity = self;
1260                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1261                         break;
1262                 default:
1263                         backtrace("Invalid voice type!");
1264                         break;
1265         }
1266 }
1267
1268 void GlobalSound(string sample, float chan, float voicetype)
1269 {
1270         float n;
1271         float tauntrand;
1272
1273         if(sample == "")
1274                 return;
1275
1276         tokenize_console(sample);
1277         n = stof(argv(1));
1278         if(n > 0)
1279                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1280         else
1281                 sample = strcat(argv(0), ".wav"); // randomization
1282
1283         switch(voicetype)
1284         {
1285                 case VOICETYPE_LASTATTACKER_ONLY:
1286                         if(self.pusher)
1287                         {
1288                                 msg_entity = self.pusher;
1289                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1290                                 {
1291                                         if(msg_entity.cvar_cl_voice_directional == 1)
1292                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1293                                         else
1294                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1295                                 }
1296                         }
1297                         break;
1298                 case VOICETYPE_LASTATTACKER:
1299                         if(self.pusher)
1300                         {
1301                                 msg_entity = self.pusher;
1302                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1303                                 {
1304                                         if(msg_entity.cvar_cl_voice_directional == 1)
1305                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1306                                         else
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1308                                 }
1309                                 msg_entity = self;
1310                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1311                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1312                         }
1313                         break;
1314                 case VOICETYPE_TEAMRADIO:
1315                         FOR_EACH_REALCLIENT(msg_entity)
1316                                 if(!teamplay || msg_entity.team == self.team)
1317                                 {
1318                                         if(msg_entity.cvar_cl_voice_directional == 1)
1319                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1320                                         else
1321                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1322                                 }
1323                         break;
1324                 case VOICETYPE_AUTOTAUNT:
1325                         if(!sv_autotaunt)
1326                                 break;
1327                         if(!sv_taunt)
1328                                 break;
1329                         if(sv_gentle)
1330                                 break;
1331                         tauntrand = random();
1332                         FOR_EACH_REALCLIENT(msg_entity)
1333                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1334                                 {
1335                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1336                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1337                                         else
1338                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1339                                 }
1340                         break;
1341                 case VOICETYPE_TAUNT:
1342                         if(self.classname == "player")
1343                                 if(self.deadflag == DEAD_NO)
1344                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1345                         if(!sv_taunt)
1346                                 break;
1347                         if(sv_gentle)
1348                                 break;
1349                         FOR_EACH_REALCLIENT(msg_entity)
1350                         {
1351                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1352                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1353                                 else
1354                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1355                         }
1356                         break;
1357                 case VOICETYPE_PLAYERSOUND:
1358                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1359                         break;
1360                 default:
1361                         backtrace("Invalid voice type!");
1362                         break;
1363         }
1364 }
1365
1366 void PlayerSound(.string samplefield, float chan, float voicetype)
1367 {
1368         GlobalSound(self.samplefield, chan, voicetype);
1369 }
1370
1371 void VoiceMessage(string type, string msg)
1372 {
1373         var .string sample;
1374         float voicetype, ownteam;
1375         float flood;
1376         sample = GetVoiceMessageSampleField(type);
1377
1378         if(GetPlayerSoundSampleField_notFound)
1379         {
1380                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1381                 return;
1382         }
1383
1384         voicetype = GetVoiceMessageVoiceType(type);
1385         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1386
1387         flood = Say(self, ownteam, world, msg, 1);
1388
1389         if (flood > 0)
1390                 GlobalSound(self.sample, CH_VOICE, voicetype);
1391         else if (flood < 0)
1392                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1393 }
1394
1395 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1396 {
1397 //      show_message
1398 //      0 (00) automove centerprint, admin message
1399 //      1 (01) automove centerprint, no admin message
1400 //      2 (10) no centerprint, admin message
1401 //      3 (11) no centerprint, no admin message
1402
1403         float lockteams_backup;
1404
1405         lockteams_backup = lockteams;  // backup any team lock
1406
1407         lockteams = 0;  // disable locked teams
1408
1409         TeamchangeFrags(client);  // move the players frags
1410         SetPlayerColors(client, team_colour - 1);  // set the players colour
1411         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1412
1413         lockteams = lockteams_backup;  // restore the team lock
1414
1415         LogTeamchange(client.playerid, client.team, type);
1416
1417         if not(show_message & 1) // admin message
1418                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1419
1420         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1421 }