qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255 #ifndef NO_LEGACY_NETWORKING
 256         if(!self.iscsqcmodel)
 257                 animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 258 #endif
 259
 260         if (self.weaponentity)
 261         {
 262                 updateanim(self.weaponentity);
 263                 if (!self.weaponentity.animstate_override)
 264                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 265         }
 266 }
 267
 268 void SpawnThrownWeapon (vector org, float w)
 269 {
 270         if(g_minstagib)
 271         if(self.ammo_cells <= 0)
 272                 return;
 273
 274         if(g_pinata)
 275         {
 276                 float j;
 277                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 278                 {
 279                         if(WEPSET_CONTAINS_EW(self, j))
 280                                 if(W_IsWeaponThrowable(j))
 281                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 282                 }
 283         }
 284         else
 285         {
 286                 if(W_IsWeaponThrowable(self.weapon))
 287                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 288         }
 289 }
 290
 291 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 292 {
 293         float take, save;
 294         vector v;
 295         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 296
 297         // damage resistance (ignore most of the damage from a bullet or similar)
 298         damage = max(damage - 5, 1);
 299
 300         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 301         take = v_x;
 302         save = v_y;
 303
 304         if(sound_allowed(MSG_BROADCAST, attacker))
 305         {
 306                 if (save > 10)
 307                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 308                 else if (take > 30)
 309                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 310                 else if (take > 10)
 311                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 312         }
 313
 314         if (take > 50)
 315                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 316         if (take > 100)
 317                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 318
 319         if (!(self.flags & FL_GODMODE))
 320         {
 321                 self.armorvalue = self.armorvalue - save;
 322                 self.health = self.health - take;
 323                 // pause regeneration for 5 seconds
 324                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 325         }
 326         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 327         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 328         self.dmg_inflictor = inflictor;
 329
 330         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 331         {
 332                 // don't use any animations as a gib
 333                 self.frame = 0;
 334                 // view just above the floor
 335                 self.view_ofs = '0 0 4';
 336
 337                 Violence_GibSplash(self, 1, 1, attacker);
 338                 self.alpha = -1;
 339                 self.solid = SOLID_NOT; // restore later
 340                 self.takedamage = DAMAGE_NO; // restore later
 341                 self.damagedbycontents = FALSE;
 342         }
 343 }
 344
 345 void ClientKill_Now_TeamChange();
 346
 347 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 348 {
 349         float take, save, waves, sdelay, dh, da, j;
 350         vector v;
 351         float valid_damage_for_weaponstats;
 352         float excess;
 353
 354         dh = max(self.health, 0);
 355         da = max(self.armorvalue, 0);
 356
 357         if(!DEATH_ISSPECIAL(deathtype))
 358         {
 359                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 360                 if(self != attacker)
 361                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 362         }
 363
 364         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 365         {
 366                 // tuba causes blood to come out of the ears
 367                 vector ear1, ear2;
 368                 vector d;
 369                 float f;
 370                 ear1 = self.origin;
 371                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 372                 ear2 = ear1;
 373                 makevectors(self.angles);
 374                 ear1 += v_right * -10;
 375                 ear2 += v_right * +10;
 376                 d = inflictor.origin - self.origin;
 377                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 378                 force = v_right * vlen(force);
 379                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 380                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 381                 if(f > 0)
 382                 {
 383                         hitloc = ear1;
 384                         force = force * -1;
 385                 }
 386                 else
 387                 {
 388                         hitloc = ear2;
 389                         // force is already good
 390                 }
 391         }
 392         else
 393                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 394
 395         if (!g_minstagib)
 396         {
 397                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 398                 take = v_x;
 399                 save = v_y;
 400         }
 401         else
 402         {
 403                 save = 0;
 404                 take = damage;
 405         }
 406
 407         if(attacker == self)
 408         {
 409                 // don't reset pushltime for self damage as it may be an attempt to
 410                 // escape a lava pit or similar
 411                 //self.pushltime = 0;
 412                 self.istypefrag = 0;
 413         }
 414         else if(attacker.classname == "player")
 415         {
 416                 self.pusher = attacker;
 417                 self.pushltime = time + autocvar_g_maxpushtime;
 418                 self.istypefrag = self.BUTTON_CHAT;
 419         }
 420         else if(time < self.pushltime)
 421         {
 422                 attacker = self.pusher;
 423                 self.pushltime = max(self.pushltime, time + 0.6);
 424         }
 425         else
 426         {
 427                 self.pushltime = 0;
 428                 self.istypefrag = 0;
 429         }
 430
 431         frag_inflictor = inflictor;
 432         frag_attacker = attacker;
 433         frag_target = self;
 434         damage_take = take;
 435         damage_save = save;
 436         damage_force = force;
 437         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 438         take = bound(0, damage_take, self.health);
 439         save = bound(0, damage_save, self.armorvalue);
 440         excess = max(0, damage - take - save);
 441
 442         if(sound_allowed(MSG_BROADCAST, attacker))
 443         {
 444                 if (save > 10)
 445                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 446                 else if (take > 30)
 447                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 448                 else if (take > 10)
 449                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 450         }
 451
 452         if (take > 50)
 453                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 454         if (take > 100)
 455                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 456
 457         if (time >= self.spawnshieldtime)
 458         {
 459                 if (!(self.flags & FL_GODMODE))
 460                 {
 461                         self.armorvalue = self.armorvalue - save;
 462                         self.health = self.health - take;
 463                         // pause regeneration for 5 seconds
 464                         if(take)
 465                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 466
 467                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 468                         {
 469                                 self.pain_finished = time + 0.5;        //Supajoe
 470
 471                                 if(sv_gentle < 1) {
 472                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 473                                         {
 474                                                 if (!self.animstate_override)
 475                                                 {
 476                                                         if (random() > 0.5)
 477                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 478                                                         else
 479                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 480                                                 }
 481                                         }
 482
 483                                         if(sound_allowed(MSG_BROADCAST, attacker))
 484                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 485                                         if(self.health > 1)
 486                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 487                                         {
 488                                                 if(deathtype == DEATH_FALL)
 489                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 490                                                 else if(self.health > 75) // TODO make a "gentle" version?
 491                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 492                                                 else if(self.health > 50)
 493                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 494                                                 else if(self.health > 25)
 495                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 496                                                 else
 497                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 498                                         }
 499                                 }
 500
 501                                 // throw off bot aim temporarily
 502                                 float shake;
 503                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 504                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 505                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 506                         }
 507                 }
 508                 else
 509                         self.max_armorvalue += (save + take);
 510         }
 511         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 512         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 513         self.dmg_inflictor = inflictor;
 514
 515         if(g_ca && self != attacker && attacker.classname == "player")
 516                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 517
 518         float abot, vbot, awep;
 519         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 520         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 521
 522         valid_damage_for_weaponstats = 0;
 523         awep = 0;
 524
 525         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 526         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 527         if(attacker && self != attacker)
 528         if(IsDifferentTeam(self, attacker))
 529         {
 530                 if(DEATH_ISSPECIAL(deathtype))
 531                         awep = attacker.weapon;
 532                 else
 533                         awep = DEATH_WEAPONOF(deathtype);
 534                 valid_damage_for_weaponstats = 1;
 535         }
 536
 537         if(valid_damage_for_weaponstats)
 538         {
 539                 dh = dh - max(self.health, 0);
 540                 da = da - max(self.armorvalue, 0);
 541                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 542         }
 543
 544         if (self.health < 1)
 545         {
 546                 float defer_ClientKill_Now_TeamChange;
 547                 defer_ClientKill_Now_TeamChange = FALSE;
 548
 549                 if(self.alivetime)
 550                 {
 551                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 552                         self.alivetime = 0;
 553                 }
 554
 555                 if(valid_damage_for_weaponstats)
 556                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 557
 558                 if(sv_gentle < 1) // TODO make a "gentle" version?
 559                 if(sound_allowed(MSG_BROADCAST, attacker))
 560                 {
 561                         if(deathtype == DEATH_DROWN)
 562                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                         else
 564                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 565                 }
 566
 567                 // get rid of kill indicator
 568                 if(self.killindicator)
 569                 {
 570                         remove(self.killindicator);
 571                         self.killindicator = world;
 572                         if(self.killindicator_teamchange)
 573                                 defer_ClientKill_Now_TeamChange = TRUE;
 574
 575                         if(self.classname == "body")
 576                         if(deathtype == DEATH_KILL)
 577                         {
 578                                 // for the lemmings fans, a small harmless explosion
 579                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 580                         }
 581                 }
 582
 583                 // print an obituary message
 584                 Obituary (attacker, inflictor, self, deathtype);
 585                 race_PreDie();
 586                 DropAllRunes(self);
 587
 588         // increment frag counter for used weapon type
 589         float w;
 590         w = DEATH_WEAPONOF(deathtype);
 591         if(WEP_VALID(w))
 592         if(accuracy_isgooddamage(attacker, self))
 593         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 594
 595                 frag_attacker = attacker;
 596                 frag_inflictor = inflictor;
 597                 frag_target = self;
 598                 frag_deathtype = deathtype;
 599                 MUTATOR_CALLHOOK(PlayerDies);
 600
 601                 weapon_action(self.weapon, WR_PLAYERDEATH);
 602
 603                 RemoveGrapplingHook(self);
 604
 605                 Portal_ClearAllLater(self);
 606
 607                 if(clienttype(self) == CLIENTTYPE_REAL)
 608                 {
 609                         stuffcmd(self, "-zoom\n");
 610                         self.fixangle = TRUE;
 611                         //msg_entity = self;
 612                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 613                         //WriteAngle (MSG_ONE, self.v_angle_x);
 614                         //WriteAngle (MSG_ONE, self.v_angle_y);
 615                         //WriteAngle (MSG_ONE, 80);
 616                 }
 617
 618                 if(defer_ClientKill_Now_TeamChange)
 619                         ClientKill_Now_TeamChange(); // can turn player into spectator
 620
 621                 // player could have been miraculously resuscitated ;)
 622                 // e.g. players in freezetag get frozen, they don't really die
 623                 if(self.health >= 1 || self.classname != "player")
 624                         return;
 625
 626                 // when we get here, player actually dies
 627
 628                 // clear waypoints
 629                 WaypointSprite_PlayerDead();
 630                 // throw a weapon
 631                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 632
 633                 // become fully visible
 634                 self.alpha = default_player_alpha;
 635                 // make the corpse upright (not tilted)
 636                 self.angles_x = 0;
 637                 self.angles_z = 0;
 638                 // don't spin
 639                 self.avelocity = '0 0 0';
 640                 // view from the floor
 641                 self.view_ofs = '0 0 -8';
 642                 // toss the corpse
 643                 self.movetype = MOVETYPE_TOSS;
 644                 // shootable corpse
 645                 self.solid = SOLID_CORPSE;
 646                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 647                 // don't stick to the floor
 648                 self.flags &~= FL_ONGROUND;
 649                 // dying animation
 650                 self.deadflag = DEAD_DYING;
 651                 // when to allow respawn
 652                 sdelay = 0;
 653                 waves = 0;
 654                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 655                 if(!sdelay)
 656                 {
 657                         if(g_cts)
 658                                 sdelay = 0; // no respawn delay in CTS
 659                         else
 660                                 sdelay = autocvar_g_respawn_delay;
 661                 }
 662                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 663                 if(!waves)
 664                         waves = autocvar_g_respawn_waves;
 665                 if(waves)
 666                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 667                 else
 668                         self.respawn_time = time + sdelay;
 669                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 670                         self.respawn_countdown = 10; // first number to count down from is 10
 671                 else
 672                         self.respawn_countdown = -1; // do not count down
 673                 self.death_time = time;
 674                 if (random() < 0.5)
 675                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 676                 else
 677                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 678                 if (self.maxs_z > 5)
 679                 {
 680                         self.maxs_z = 5;
 681                         setsize(self, self.mins, self.maxs);
 682                 }
 683                 // set damage function to corpse damage
 684                 self.event_damage = PlayerCorpseDamage;
 685                 // call the corpse damage function just in case it wants to gib
 686                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 687                 // set up to fade out later
 688                 SUB_SetFade (self, time + 6 + random (), 1);
 689
 690                 if(sv_gentle > 0 || autocvar_ekg) {
 691                         // remove corpse
 692                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 693                 }
 694
 695                 // reset fields the weapons may use just in case
 696                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 697                 {
 698                         weapon_action(j, WR_RESETPLAYER);
 699                         ATTACK_FINISHED_FOR(self, j) = 0;
 700                 }
 701         }
 702 }
 703
 704 .float muted; // to be used by prvm_edictset server playernumber muted 1
 705 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 706 // message "": do not say, just test flood control
 707 // return value:
 708 //   1 = accept
 709 //   0 = reject
 710 //  -1 = fake accept
 711 {
 712         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 713         float flood;
 714         var .float flood_field;
 715         entity head;
 716         float ret;
 717         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 718
 719         if(!teamsay && !privatesay)
 720                 if(substring(msgin, 0, 1) == " ")
 721                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 722
 723         msgin = formatmessage(msgin);
 724
 725         if(source.classname != "player")
 726                 colorstr = "^0"; // black for spectators
 727         else if(teamplay)
 728                 colorstr = Team_ColorCode(source.team);
 729         else
 730         {
 731                 colorstr = "";
 732                 teamsay = FALSE;
 733         }
 734
 735         if(intermission_running)
 736                 teamsay = FALSE;
 737
 738         if(msgin != "")
 739                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 740
 741         /*
 742          * using bprint solves this... me stupid
 743         // how can we prevent the message from appearing in a listen server?
 744         // for now, just give "say" back and only handle say_team
 745         if(!teamsay)
 746         {
 747                 clientcommand(self, strcat("say ", msgin));
 748                 return;
 749         }
 750         */
 751
 752         if(autocvar_g_chat_teamcolors)
 753                 namestr = playername(source);
 754         else
 755                 namestr = source.netname;
 756
 757         if(msgin != "")
 758         {
 759                 if(privatesay)
 760                 {
 761                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 762                         privatemsgprefixlen = strlen(msgstr);
 763                         msgstr = strcat(msgstr, msgin);
 764                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 765                         if(autocvar_g_chat_teamcolors)
 766                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 767                         else
 768                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 769                 }
 770                 else if(teamsay)
 771                 {
 772                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 773                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 774                 }
 775                 else
 776                 {
 777                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 778                         cmsgstr = "";
 779                 }
 780                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 781         }
 782         else
 783         {
 784                 msgstr = cmsgstr = "";
 785         }
 786
 787         fullmsgstr = msgstr;
 788         fullcmsgstr = cmsgstr;
 789
 790         // FLOOD CONTROL
 791         flood = 0;
 792         flood_field = floodcontrol_chat;
 793         if(floodcontrol)
 794         {
 795                 float flood_spl;
 796                 float flood_burst;
 797                 float flood_lmax;
 798                 float lines;
 799                 if(privatesay)
 800                 {
 801                         flood_spl = autocvar_g_chat_flood_spl_tell;
 802                         flood_burst = autocvar_g_chat_flood_burst_tell;
 803                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 804                         flood_field = floodcontrol_chattell;
 805                 }
 806                 else if(teamsay)
 807                 {
 808                         flood_spl = autocvar_g_chat_flood_spl_team;
 809                         flood_burst = autocvar_g_chat_flood_burst_team;
 810                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 811                         flood_field = floodcontrol_chatteam;
 812                 }
 813                 else
 814                 {
 815                         flood_spl = autocvar_g_chat_flood_spl;
 816                         flood_burst = autocvar_g_chat_flood_burst;
 817                         flood_lmax = autocvar_g_chat_flood_lmax;
 818                         flood_field = floodcontrol_chat;
 819                 }
 820                 flood_burst = max(0, flood_burst - 1);
 821                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 822
 823                 // do flood control for the default line size
 824                 if(msgstr != "")
 825                 {
 826                         getWrappedLine_remaining = msgstr;
 827                         msgstr = "";
 828                         lines = 0;
 829                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 830                         {
 831                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 832                                 ++lines;
 833                         }
 834                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 835
 836                         if(getWrappedLine_remaining != "")
 837                         {
 838                                 msgstr = strcat(msgstr, "\n");
 839                                 flood = 2;
 840                         }
 841
 842                         if(time >= source.flood_field)
 843                         {
 844                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 845                         }
 846                         else
 847                         {
 848                                 flood = 1;
 849                                 msgstr = fullmsgstr;
 850                         }
 851                 }
 852                 else
 853                 {
 854                         if(time >= source.flood_field)
 855                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 856                         else
 857                                 flood = 1;
 858                 }
 859
 860                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 861                         source.flood_field = flood = 0;
 862         }
 863
 864         if(flood == 2) // cannot happen for empty msgstr
 865         {
 866                 if(autocvar_g_chat_flood_notify_flooder)
 867                 {
 868                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 869                         sourcecmsgstr = "";
 870                 }
 871                 else
 872                 {
 873                         sourcemsgstr = fullmsgstr;
 874                         sourcecmsgstr = fullcmsgstr;
 875                 }
 876                 cmsgstr = "";
 877         }
 878         else
 879         {
 880                 sourcemsgstr = msgstr;
 881                 sourcecmsgstr = cmsgstr;
 882         }
 883
 884         if(!privatesay)
 885         if(source.classname != "player")
 886         {
 887                 if not(intermission_running)
 888                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 889                                 teamsay = -1; // spectators
 890         }
 891
 892         if(flood)
 893                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 894
 895         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 896         if(privatesay)
 897                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 898
 899         if(source.muted)
 900         {
 901                 // always fake the message
 902                 ret = -1;
 903         }
 904         else if(flood == 1)
 905         {
 906                 if(autocvar_g_chat_flood_notify_flooder)
 907                 {
 908                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 909                         ret = 0;
 910                 }
 911                 else
 912                         ret = -1;
 913         }
 914         else
 915         {
 916                 ret = 1;
 917         }
 918
 919         if(sourcemsgstr != "" && ret != 0)
 920         {
 921                 if(ret < 0) // faked message, because the player is muted
 922                 {
 923                         sprint(source, sourcemsgstr);
 924                         if(sourcecmsgstr != "" && !privatesay)
 925                                 centerprint(source, sourcecmsgstr);
 926                 }
 927                 else if(privatesay) // private message, between 2 people only, not sent to server console
 928                 {
 929                         sprint(source, sourcemsgstr);
 930                         sprint(privatesay, msgstr);
 931                         if(cmsgstr != "")
 932                                 centerprint(privatesay, cmsgstr);
 933                 }
 934                 else if(teamsay > 0) // team message, only sent to team mates
 935                 {
 936                         sprint(source, sourcemsgstr);
 937                         //print(msgstr); // send to server console too
 938                         if(sourcecmsgstr != "")
 939                                 centerprint(source, sourcecmsgstr);
 940                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 941                                 if(head != source)
 942                                 {
 943                                         sprint(head, msgstr);
 944                                         if(cmsgstr != "")
 945                                                 centerprint(head, cmsgstr);
 946                                 }
 947                 }
 948                 else if(teamsay < 0) // spectator message, only sent to spectators
 949                 {
 950                         sprint(source, sourcemsgstr);
 951                         //print(msgstr); // send to server console too
 952                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 953                                 if(head != source)
 954                                         sprint(head, msgstr);
 955                 }
 956                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 957                 {
 958                         sprint(source, sourcemsgstr);
 959                         //print(msgstr); // send to server console too
 960                         FOR_EACH_REALCLIENT(head)
 961                                 if(head != source)
 962                                         sprint(head, msgstr);
 963                 }
 964                 else
 965                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 966         }
 967
 968         return ret;
 969 }
 970
 971 float GetVoiceMessageVoiceType(string type)
 972 {
 973         if(type == "taunt")
 974                 return VOICETYPE_TAUNT;
 975         if(type == "teamshoot")
 976                 return VOICETYPE_LASTATTACKER;
 977         return VOICETYPE_TEAMRADIO;
 978 }
 979
 980 string allvoicesamples;
 981 .string GetVoiceMessageSampleField(string type)
 982 {
 983         GetPlayerSoundSampleField_notFound = 0;
 984         switch(type)
 985         {
 986 #define _VOICEMSG(m) case #m: return playersound_##m;
 987                 ALLVOICEMSGS
 988 #undef _VOICEMSG
 989         }
 990         GetPlayerSoundSampleField_notFound = 1;
 991         return playersound_taunt;
 992 }
 993
 994 .string GetPlayerSoundSampleField(string type)
 995 {
 996         GetPlayerSoundSampleField_notFound = 0;
 997         switch(type)
 998         {
 999 #define _VOICEMSG(m) case #m: return playersound_##m;
1000                 ALLPLAYERSOUNDS
1001 #undef _VOICEMSG
1002         }
1003         GetPlayerSoundSampleField_notFound = 1;
1004         return playersound_taunt;
1005 }
1006
1007 void PrecacheGlobalSound(string samplestring)
1008 {
1009         float n, i;
1010         tokenize_console(samplestring);
1011         n = stof(argv(1));
1012         if(n > 0)
1013         {
1014                 for(i = 1; i <= n; ++i)
1015                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1016         }
1017         else
1018         {
1019                 precache_sound(strcat(argv(0), ".wav"));
1020         }
1021 }
1022
1023 void PrecachePlayerSounds(string f)
1024 {
1025         float fh;
1026         string s;
1027         fh = fopen(f, FILE_READ);
1028         if(fh < 0)
1029                 return;
1030         while((s = fgets(fh)))
1031         {
1032                 if(tokenize_console(s) != 3)
1033                 {
1034                         dprint("Invalid sound info line: ", s, "\n");
1035                         continue;
1036                 }
1037                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1038         }
1039         fclose(fh);
1040
1041         if not(allvoicesamples)
1042         {
1043 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1044                 ALLVOICEMSGS
1045 #undef _VOICEMSG
1046                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1047         }
1048 }
1049
1050 void ClearPlayerSounds()
1051 {
1052 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1053         ALLPLAYERSOUNDS
1054         ALLVOICEMSGS
1055 #undef _VOICEMSG
1056 }
1057
1058 float LoadPlayerSounds(string f, float first)
1059 {
1060         float fh;
1061         string s;
1062         var .string field;
1063         fh = fopen(f, FILE_READ);
1064         if(fh < 0)
1065         {
1066                 dprint("Player sound file not found: ", f, "\n");
1067                 return 0;
1068         }
1069         while((s = fgets(fh)))
1070         {
1071                 if(tokenize_console(s) != 3)
1072                         continue;
1073                 field = GetPlayerSoundSampleField(argv(0));
1074                 if(GetPlayerSoundSampleField_notFound)
1075                         field = GetVoiceMessageSampleField(argv(0));
1076                 if(GetPlayerSoundSampleField_notFound)
1077                         continue;
1078                 if(self.field)
1079                         strunzone(self.field);
1080                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1081         }
1082         fclose(fh);
1083         return 1;
1084 }
1085
1086 .float modelindex_for_playersound;
1087 .float skin_for_playersound;
1088 void UpdatePlayerSounds()
1089 {
1090         if(self.modelindex == self.modelindex_for_playersound)
1091         if(self.skin == self.skin_for_playersound)
1092                 return;
1093         self.modelindex_for_playersound = self.modelindex;
1094         self.skin_for_playersound = self.skin;
1095         ClearPlayerSounds();
1096         LoadPlayerSounds("sound/player/default.sounds", 1);
1097         if(!autocvar_g_debug_defaultsounds)
1098                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1099                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1100 }
1101
1102 void FakeGlobalSound(string sample, float chan, float voicetype)
1103 {
1104         float n;
1105         float tauntrand;
1106
1107         if(sample == "")
1108                 return;
1109
1110         tokenize_console(sample);
1111         n = stof(argv(1));
1112         if(n > 0)
1113                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1114         else
1115                 sample = strcat(argv(0), ".wav"); // randomization
1116
1117         switch(voicetype)
1118         {
1119                 case VOICETYPE_LASTATTACKER_ONLY:
1120                         break;
1121                 case VOICETYPE_LASTATTACKER:
1122                         if(self.pusher)
1123                         {
1124                                 msg_entity = self;
1125                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1126                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1127                         }
1128                         break;
1129                 case VOICETYPE_TEAMRADIO:
1130                         msg_entity = self;
1131                         if(msg_entity.cvar_cl_voice_directional == 1)
1132                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1133                         else
1134                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1135                         break;
1136                 case VOICETYPE_AUTOTAUNT:
1137                         if(!sv_autotaunt)
1138                                 break;
1139                         if(!sv_taunt)
1140                                 break;
1141                         if(sv_gentle)
1142                                 break;
1143                         tauntrand = random();
1144                         msg_entity = self;
1145                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1146                         {
1147                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1148                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1149                                 else
1150                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1151                         }
1152                         break;
1153                 case VOICETYPE_TAUNT:
1154                         if(self.classname == "player")
1155                                 if(self.deadflag == DEAD_NO)
1156                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1157                         if(!sv_taunt)
1158                                 break;
1159                         if(sv_gentle)
1160                                 break;
1161                         msg_entity = self;
1162                         if (msg_entity.cvar_cl_voice_directional >= 1)
1163                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1164                         else
1165                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1166                         break;
1167                 case VOICETYPE_PLAYERSOUND:
1168                         msg_entity = self;
1169                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1170                         break;
1171                 default:
1172                         backtrace("Invalid voice type!");
1173                         break;
1174         }
1175 }
1176
1177 void GlobalSound(string sample, float chan, float voicetype)
1178 {
1179         float n;
1180         float tauntrand;
1181
1182         if(sample == "")
1183                 return;
1184
1185         tokenize_console(sample);
1186         n = stof(argv(1));
1187         if(n > 0)
1188                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1189         else
1190                 sample = strcat(argv(0), ".wav"); // randomization
1191
1192         switch(voicetype)
1193         {
1194                 case VOICETYPE_LASTATTACKER_ONLY:
1195                         if(self.pusher)
1196                         {
1197                                 msg_entity = self.pusher;
1198                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1199                                 {
1200                                         if(msg_entity.cvar_cl_voice_directional == 1)
1201                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1202                                         else
1203                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1204                                 }
1205                         }
1206                         break;
1207                 case VOICETYPE_LASTATTACKER:
1208                         if(self.pusher)
1209                         {
1210                                 msg_entity = self.pusher;
1211                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1212                                 {
1213                                         if(msg_entity.cvar_cl_voice_directional == 1)
1214                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1215                                         else
1216                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1217                                 }
1218                                 msg_entity = self;
1219                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1220                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1221                         }
1222                         break;
1223                 case VOICETYPE_TEAMRADIO:
1224                         FOR_EACH_REALCLIENT(msg_entity)
1225                                 if(!teamplay || msg_entity.team == self.team)
1226                                 {
1227                                         if(msg_entity.cvar_cl_voice_directional == 1)
1228                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1229                                         else
1230                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1231                                 }
1232                         break;
1233                 case VOICETYPE_AUTOTAUNT:
1234                         if(!sv_autotaunt)
1235                                 break;
1236                         if(!sv_taunt)
1237                                 break;
1238                         if(sv_gentle)
1239                                 break;
1240                         tauntrand = random();
1241                         FOR_EACH_REALCLIENT(msg_entity)
1242                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1243                                 {
1244                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1245                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1246                                         else
1247                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1248                                 }
1249                         break;
1250                 case VOICETYPE_TAUNT:
1251                         if(self.classname == "player")
1252                                 if(self.deadflag == DEAD_NO)
1253                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1254                         if(!sv_taunt)
1255                                 break;
1256                         if(sv_gentle)
1257                                 break;
1258                         FOR_EACH_REALCLIENT(msg_entity)
1259                         {
1260                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1261                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1262                                 else
1263                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1264                         }
1265                         break;
1266                 case VOICETYPE_PLAYERSOUND:
1267                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1268                         break;
1269                 default:
1270                         backtrace("Invalid voice type!");
1271                         break;
1272         }
1273 }
1274
1275 void PlayerSound(.string samplefield, float chan, float voicetype)
1276 {
1277         GlobalSound(self.samplefield, chan, voicetype);
1278 }
1279
1280 void VoiceMessage(string type, string msg)
1281 {
1282         var .string sample;
1283         float voicetype, ownteam;
1284         float flood;
1285         sample = GetVoiceMessageSampleField(type);
1286
1287         if(GetPlayerSoundSampleField_notFound)
1288         {
1289                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1290                 return;
1291         }
1292
1293         voicetype = GetVoiceMessageVoiceType(type);
1294         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1295
1296         flood = Say(self, ownteam, world, msg, 1);
1297
1298         if (flood > 0)
1299                 GlobalSound(self.sample, CH_VOICE, voicetype);
1300         else if (flood < 0)
1301                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1302 }
1303
1304 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1305 {
1306 //      show_message
1307 //      0 (00) automove centerprint, admin message
1308 //      1 (01) automove centerprint, no admin message
1309 //      2 (10) no centerprint, admin message
1310 //      3 (11) no centerprint, no admin message
1311
1312         float lockteams_backup;
1313
1314         lockteams_backup = lockteams;  // backup any team lock
1315
1316         lockteams = 0;  // disable locked teams
1317
1318         TeamchangeFrags(client);  // move the players frags
1319         SetPlayerColors(client, team_colour - 1);  // set the players colour
1320         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1321
1322         lockteams = lockteams_backup;  // restore the team lock
1323
1324         LogTeamchange(client.playerid, client.team, type);
1325
1326         if not(show_message & 1) // admin message
1327                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1328
1329         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1330 }