qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.takedamage = oldself.takedamage;
 146         self.think = oldself.think;
 147         self.customizeentityforclient = oldself.customizeentityforclient;
 148         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 149         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 150         if (keepvelocity == 1)
 151                 self.velocity = oldself.velocity;
 152         self.oldvelocity = self.velocity;
 153         self.fade_time = oldself.fade_time;
 154         self.fade_rate = oldself.fade_rate;
 155         //self.weapon = oldself.weapon;
 156         setorigin(self, oldself.origin);
 157         setsize(self, oldself.mins, oldself.maxs);
 158         self.prevorigin = oldself.origin;
 159         self.reset = SUB_Remove;
 160
 161         Drag_MoveDrag(oldself, self);
 162
 163         self = oldself;
 164 }
 165
 166 float player_getspecies()
 167 {
 168         local float glob, i, j, fh, len, s, sk;
 169         local string fn, l, file;
 170         local float tokens;
 171
 172         file = strcat(substring(self.model, 0, -5), ftos(self.skinindex)); // remove the extension at the end
 173         PrecachePlayerSounds(file);
 174         UpdatePlayerSounds(file);
 175
 176         s = -1;
 177
 178         glob = search_begin("models/player/*.txt", TRUE, TRUE);
 179         if(glob < 0)
 180                 return s;
 181         for(j = 0; j <= 1; ++j)
 182         {
 183                 for(i = 0; i < search_getsize(glob); ++i)
 184                 {
 185                         fn = search_getfilename(glob, i);
 186                         fh = fopen(fn, FILE_READ);
 187                         if(fh < 0)
 188                                 continue;
 189                         fgets(fh); fgets(fh);
 190                         sk = stof(fgets(fh));
 191                         if(sk == (j ? 0 : self.skinindex)) // 2nd pass skips the skin test
 192                         if(fgets(fh) == self.model)
 193                         {
 194                                 tokens = tokenizebyseparator(fn, ".");
 195
 196                                 l = fgets(fh);
 197                                 len = tokenize_console(l);
 198                                 if (len != 2)
 199                                         goto nospecies;
 200                                 if (argv(0) != "species")
 201                                         goto nospecies;
 202                                 switch(argv(1))
 203                                 {
 204                                         case "human":       s = SPECIES_HUMAN;       break;
 205                                         case "alien":       s = SPECIES_ALIEN;       break;
 206                                         case "robot_shiny": s = SPECIES_ROBOT_SHINY; break;
 207                                         case "robot_rusty": s = SPECIES_ROBOT_RUSTY; break;
 208                                         case "robot_solid": s = SPECIES_ROBOT_SOLID; break;
 209                                         case "animal":      s = SPECIES_ANIMAL;      break;
 210                                         case "reserved":    s = SPECIES_RESERVED;    break;
 211                                 }
 212                         }
 213 :nospecies
 214                         fclose(fh);
 215                 }
 216                 if (s >= 0)
 217                         break;
 218         }
 219         search_end(glob);
 220
 221         if (s < 0)
 222                 s = SPECIES_HUMAN;
 223
 224         return s;
 225 }
 226
 227 void player_setupanimsformodel()
 228 {
 229         local string animfilename;
 230         local float animfile;
 231         // defaults for legacy .zym models without animinfo files
 232         self.anim_die1 = '0 1 0.5'; // 2 seconds
 233         self.anim_die2 = '1 1 0.5'; // 2 seconds
 234         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 235         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 236         self.anim_duckwalk = '4 1 1';
 237         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_duckidle = '6 1 1';
 239         self.anim_idle = '7 1 1';
 240         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 241         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 242         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 243         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 244         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 245         self.anim_run = '13 1 1';
 246         self.anim_runbackwards = '14 1 1';
 247         self.anim_strafeleft = '15 1 1';
 248         self.anim_straferight = '16 1 1';
 249         self.anim_dead1 = '17 1 1';
 250         self.anim_dead2 = '18 1 1';
 251         self.anim_forwardright = '19 1 1';
 252         self.anim_forwardleft = '20 1 1';
 253         self.anim_backright = '21 1 1';
 254         self.anim_backleft  = '22 1 1';
 255         animparseerror = FALSE;
 256         animfilename = strcat(self.model, ".animinfo");
 257         animfile = fopen(animfilename, FILE_READ);
 258         if (animfile >= 0)
 259         {
 260                 self.anim_die1         = animparseline(animfile);
 261                 self.anim_die2         = animparseline(animfile);
 262                 self.anim_draw         = animparseline(animfile);
 263                 self.anim_duck         = animparseline(animfile);
 264                 self.anim_duckwalk     = animparseline(animfile);
 265                 self.anim_duckjump     = animparseline(animfile);
 266                 self.anim_duckidle     = animparseline(animfile);
 267                 self.anim_idle         = animparseline(animfile);
 268                 self.anim_jump         = animparseline(animfile);
 269                 self.anim_pain1        = animparseline(animfile);
 270                 self.anim_pain2        = animparseline(animfile);
 271                 self.anim_shoot        = animparseline(animfile);
 272                 self.anim_taunt        = animparseline(animfile);
 273                 self.anim_run          = animparseline(animfile);
 274                 self.anim_runbackwards = animparseline(animfile);
 275                 self.anim_strafeleft   = animparseline(animfile);
 276                 self.anim_straferight  = animparseline(animfile);
 277                 self.anim_forwardright = animparseline(animfile);
 278                 self.anim_forwardleft  = animparseline(animfile);
 279                 self.anim_backright    = animparseline(animfile);
 280                 self.anim_backleft     = animparseline(animfile);
 281                 fclose(animfile);
 282
 283                 // derived anims
 284                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 285                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 286
 287                 if (animparseerror)
 288                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 289         }
 290         else
 291                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 292         // reset animstate now
 293         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 294 };
 295
 296 void player_anim (void)
 297 {
 298         updateanim(self);
 299         if (self.weaponentity)
 300                 updateanim(self.weaponentity);
 301
 302         if (self.deadflag != DEAD_NO)
 303         {
 304                 if (time > self.animstate_endtime)
 305                 {
 306                         if (self.maxs_z > 5)
 307                         {
 308                                 self.maxs_z = 5;
 309                                 setsize(self, self.mins, self.maxs);
 310                         }
 311                         self.frame = self.dead_frame;
 312                 }
 313                 return;
 314         }
 315
 316         if (!self.animstate_override)
 317         {
 318                 if (!(self.flags & FL_ONGROUND))
 319                 {
 320                         if (self.crouch)
 321                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 322                         else
 323                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 324                         self.restart_jump = FALSE;
 325                 }
 326                 else if (self.crouch)
 327                 {
 328                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 329                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 330                         else
 331                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 332                 }
 333                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 334                 {
 335                         if (self.movement_x > 0 && self.movement_y == 0)
 336                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 337                         else if (self.movement_x < 0 && self.movement_y == 0)
 338                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 339                         else if (self.movement_x == 0 && self.movement_y > 0)
 340                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 341                         else if (self.movement_x == 0 && self.movement_y < 0)
 342                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 343                         else if (self.movement_x > 0 && self.movement_y > 0)
 344                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 345                         else if (self.movement_x > 0 && self.movement_y < 0)
 346                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 347                         else if (self.movement_x < 0 && self.movement_y > 0)
 348                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 349                         else if (self.movement_x < 0 && self.movement_y < 0)
 350                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 351                         else
 352                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 353                 }
 354                 else
 355                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 356         }
 357
 358         if (self.weaponentity)
 359         if (!self.weaponentity.animstate_override)
 360                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 361 }
 362
 363 void SpawnThrownWeapon (vector org, float w)
 364 {
 365         if(g_minstagib)
 366         if(self.ammo_cells <= 0)
 367                 return;
 368
 369         if(g_pinata)
 370         {
 371                 float j;
 372                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 373                 {
 374                         if(self.weapons & W_WeaponBit(j))
 375                                 if(W_IsWeaponThrowable(j))
 376                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 377                 }
 378         }
 379         else
 380                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 381 }
 382
 383 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 384 {
 385         local float take, save;
 386         vector v;
 387         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 388
 389         // damage resistance (ignore most of the damage from a bullet or similar)
 390         damage = max(damage - 5, 1);
 391
 392         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 393         take = v_x;
 394         save = v_y;
 395
 396         if(sound_allowed(MSG_BROADCAST, attacker))
 397         {
 398                 if (save > 10)
 399                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 400                 else if (take > 30)
 401                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 402                 else if (take > 10)
 403                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 404         }
 405
 406         if (take > 50)
 407                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 408         if (take > 100)
 409                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 410
 411         if (!(self.flags & FL_GODMODE))
 412         {
 413                 self.armorvalue = self.armorvalue - save;
 414                 self.health = self.health - take;
 415                 // pause regeneration for 5 seconds
 416                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 417         }
 418         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 419         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 420         self.dmg_inflictor = inflictor;
 421
 422         if (self.health <= -100 && self.modelindex != 0)
 423         {
 424                 // don't use any animations as a gib
 425                 self.frame = 0;
 426                 self.dead_frame = 0;
 427                 // view just above the floor
 428                 self.view_ofs = '0 0 4';
 429
 430                 Violence_GibSplash(self, 1, 1, attacker);
 431                 self.modelindex = 0; // restore later
 432                 self.solid = SOLID_NOT; // restore later
 433         }
 434 }
 435
 436 void ClientKill_Now_TeamChange();
 437
 438 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 439 {
 440         local float take, save, waves, sdelay, dh, da, j;
 441         vector v;
 442         float valid_damage_for_weaponstats;
 443
 444         dh = max(self.health, 0);
 445         da = max(self.armorvalue, 0);
 446
 447         if(!DEATH_ISSPECIAL(deathtype))
 448         {
 449                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 450                 if(self != attacker)
 451                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 452         }
 453
 454         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 455         {
 456                 // tuba causes blood to come out of the ears
 457                 vector ear1, ear2;
 458                 vector d;
 459                 float f;
 460                 ear1 = self.origin;
 461                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 462                 ear2 = ear1;
 463                 makevectors(self.angles);
 464                 ear1 += v_right * -10;
 465                 ear2 += v_right * +10;
 466                 d = inflictor.origin - self.origin;
 467                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 468                 force = v_right * vlen(force);
 469                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 470                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 471                 if(f > 0)
 472                 {
 473                         hitloc = ear1;
 474                         force = force * -1;
 475                 }
 476                 else
 477                 {
 478                         hitloc = ear2;
 479                         // force is already good
 480                 }
 481         }
 482         else
 483                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 484
 485         if((g_arena && numspawned < 2) || (g_ca && player_cnt < 2) && !inWarmupStage)
 486                 return;
 487
 488         if (!g_minstagib)
 489         {
 490                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 491                 take = v_x;
 492                 save = v_y;
 493         }
 494         else
 495         {
 496                 save = 0;
 497                 take = damage;
 498         }
 499
 500         if(sound_allowed(MSG_BROADCAST, attacker))
 501         {
 502                 if (save > 10)
 503                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 504                 else if (take > 30)
 505                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 506                 else if (take > 10)
 507                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 508         }
 509
 510         if (take > 50)
 511                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 512         if (take > 100)
 513                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 514
 515         if (time >= self.spawnshieldtime)
 516         {
 517                 if (!(self.flags & FL_GODMODE))
 518                 {
 519                         self.armorvalue = self.armorvalue - save;
 520                         self.health = self.health - take;
 521                         // pause regeneration for 5 seconds
 522                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 523
 524                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 525                         {
 526                                 self.pain_finished = time + 0.5;        //Supajoe
 527
 528                                 if(sv_gentle < 1) {
 529                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 530                                         {
 531                                                 if (random() > 0.5)
 532                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 533                                                 else
 534                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 535                                         }
 536
 537                                         if(sound_allowed(MSG_BROADCAST, attacker))
 538                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 539                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 540                                         {
 541                                                 if(self.health > 75) // TODO make a "gentle" version?
 542                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 543                                                 else if(self.health > 50)
 544                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 545                                                 else if(self.health > 25)
 546                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 547                                                 else if(self.health > 1)
 548                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 549                                         }
 550                                 }
 551
 552                                 // throw off bot aim temporarily
 553                                 local float shake;
 554                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 555                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 556                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 557                         }
 558                 }
 559                 else
 560                         self.max_armorvalue += (save + take);
 561         }
 562         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 563         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 564         self.dmg_inflictor = inflictor;
 565
 566         if(attacker == self)
 567         {
 568                 // don't reset pushltime for self damage as it may be an attempt to
 569                 // escape a lava pit or similar
 570                 //self.pushltime = 0;
 571         }
 572         else if(attacker.classname == "player" || attacker.classname == "gib")
 573         {
 574                 self.pusher = attacker;
 575                 self.pushltime = time + cvar("g_maxpushtime");
 576         }
 577         else if(time < self.pushltime)
 578         {
 579                 attacker = self.pusher;
 580                 self.pushltime = max(self.pushltime, time + 0.6);
 581         }
 582         else
 583                 self.pushltime = 0;
 584
 585         valid_damage_for_weaponstats = 0;
 586         if(clienttype(self) == CLIENTTYPE_REAL)
 587         if(clienttype(attacker) == CLIENTTYPE_REAL)
 588         if(self != attacker)
 589         if(!DEATH_ISSPECIAL(deathtype))
 590         if(IsDifferentTeam(self, attacker))
 591                 valid_damage_for_weaponstats = 1;
 592
 593         if(valid_damage_for_weaponstats)
 594         {
 595                 dh = dh - max(self.health, 0);
 596                 da = da - max(self.armorvalue, 0);
 597                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 598         }
 599
 600         if (self.health < 1)
 601         {
 602                 float defer_ClientKill_Now_TeamChange;
 603                 defer_ClientKill_Now_TeamChange = FALSE;
 604
 605                 if(valid_damage_for_weaponstats)
 606                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 607
 608                 if(sv_gentle < 1) // TODO make a "gentle" version?
 609                 if(sound_allowed(MSG_BROADCAST, attacker))
 610                 {
 611                         if(deathtype == DEATH_DROWN)
 612                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 613                         else
 614                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 615                 }
 616
 617                 // get rid of kill indicator
 618                 if(self.killindicator)
 619                 {
 620                         remove(self.killindicator);
 621                         self.killindicator = world;
 622                         if(self.killindicator_teamchange)
 623                                 defer_ClientKill_Now_TeamChange = TRUE;
 624
 625                         if(self.classname == "body")
 626                         if(deathtype == DEATH_KILL)
 627                         {
 628                                 // for the lemmings fans, a small harmless explosion
 629                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 630                         }
 631                 }
 632
 633                 // become fully visible
 634                 self.alpha = 1;
 635                 // clear selected player display
 636                 ClearSelectedPlayer();
 637                 // throw a weapon
 638                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 639                 // print an obituary message
 640                 Obituary (attacker, inflictor, self, deathtype);
 641                 race_PreDie();
 642                 DropAllRunes(self);
 643
 644                 frag_attacker = attacker;
 645                 frag_inflictor = inflictor;
 646                 MUTATOR_CALLHOOK(PlayerDies);
 647
 648                 if(self.flagcarried)
 649                 {
 650                         if(attacker.classname != "player" && attacker.classname != "gib")
 651                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 652                         else if(attacker.team == self.team)
 653                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 654                         else
 655                                 DropFlag(self.flagcarried, world, attacker);
 656                 }
 657                 if(self.ballcarried)
 658                         DropBall(self.ballcarried, self.origin, self.velocity);
 659                 Portal_ClearAllLater(self);
 660                 // clear waypoints
 661                 WaypointSprite_PlayerDead();
 662                 // make the corpse upright (not tilted)
 663                 self.angles_x = 0;
 664                 self.angles_z = 0;
 665                 // don't spin
 666                 self.avelocity = '0 0 0';
 667                 // view from the floor
 668                 self.view_ofs = '0 0 -8';
 669                 // toss the corpse
 670                 self.movetype = MOVETYPE_TOSS;
 671                 // shootable corpse
 672                 self.solid = SOLID_CORPSE;
 673                 // don't stick to the floor
 674                 self.flags &~= FL_ONGROUND;
 675                 // dying animation
 676                 self.deadflag = DEAD_DYING;
 677                 // when to allow respawn
 678                 sdelay = 0;
 679                 waves = 0;
 680                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 681                 if(!sdelay)
 682                         sdelay = cvar("g_respawn_delay");
 683                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 684                 if(!waves)
 685                         waves = cvar("g_respawn_waves");
 686                 if(waves)
 687                         self.death_time = ceil((time + sdelay) / waves) * waves;
 688                 else
 689                         self.death_time = time + sdelay;
 690                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 691                         self.respawn_countdown = 10; // first number to count down from is 10
 692                 else
 693                         self.respawn_countdown = -1; // do not count down
 694                 if (random() < 0.5)
 695                 {
 696                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 697                         self.dead_frame = self.anim_dead1_x;
 698                 }
 699                 else
 700                 {
 701                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 702                         self.dead_frame = self.anim_dead2_x;
 703                 }
 704                 // set damage function to corpse damage
 705                 self.event_damage = PlayerCorpseDamage;
 706                 // call the corpse damage function just in case it wants to gib
 707                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 708                 // set up to fade out later
 709                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 710
 711                 // remove laserdot
 712                 if(self.weaponentity)
 713                         if(self.weaponentity.lasertarget)
 714                                 remove(self.weaponentity.lasertarget);
 715
 716                 if(clienttype(self) == CLIENTTYPE_REAL)
 717                 {
 718                         self.fixangle = TRUE;
 719                         //msg_entity = self;
 720                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 721                         //WriteAngle (MSG_ONE, self.v_angle_x);
 722                         //WriteAngle (MSG_ONE, self.v_angle_y);
 723                         //WriteAngle (MSG_ONE, 80);
 724                 }
 725
 726                 if(g_arena)
 727                         Spawnqueue_Unmark(self);
 728
 729                 if(defer_ClientKill_Now_TeamChange)
 730                         ClientKill_Now_TeamChange();
 731
 732                 if(sv_gentle > 0 || cvar("ekg")) {
 733                         // remove corpse
 734                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 735                 }
 736
 737                 // reset fields the weapons may use just in case
 738         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 739                 {
 740             weapon_action(j, WR_RESETPLAYER);
 741                         ATTACK_FINISHED_FOR(self, j) = 0;
 742                 }
 743         }
 744 }
 745
 746 float UpdateSelectedPlayer_countvalue(float v)
 747 {
 748         return max(0, (v - 1.0) / 0.5);
 749 }
 750
 751 // returns: -2 if no hit, otherwise cos of the angle
 752 // uses the global v_angle
 753 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 754 {
 755         vector so, d;
 756         float c;
 757
 758         if(p == self)
 759                 return -2;
 760
 761         if(p.deadflag)
 762                 return -2;
 763
 764         so = self.origin + self.view_ofs;
 765         d = p.origin - so;
 766
 767         // misaimed?
 768         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 769                 return -2;
 770
 771         // now find the cos of the angle...
 772         c = normalize(d) * v_forward;
 773
 774         if(c <= mincosangle)
 775                 return -2;
 776
 777         // not visible in any way? forget it
 778         if(!checkpvs(so, p))
 779                 return -2;
 780
 781         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 782         if(trace_fraction < 1)
 783                 return -2;
 784
 785         return c;
 786 }
 787
 788 void ClearSelectedPlayer()
 789 {
 790         if(self.selected_player)
 791         {
 792                 centerprint_expire(self, CENTERPRIO_POINT);
 793                 self.selected_player = world;
 794                 self.selected_player_display_needs_update = FALSE;
 795         }
 796 }
 797
 798 void UpdateSelectedPlayer()
 799 {
 800         entity selected;
 801         float selected_score;
 802         selected = world;
 803         selected_score = 0.95; // 18 degrees
 804
 805         if(!cvar("sv_allow_shownames"))
 806                 return;
 807
 808         if(clienttype(self) != CLIENTTYPE_REAL)
 809                 return;
 810
 811         if(self.cvar_cl_shownames == 0)
 812                 return;
 813
 814         if(self.cvar_cl_shownames == 1 && !teams_matter)
 815                 return;
 816
 817         makevectors(self.v_angle); // sets v_forward
 818
 819         // 1. cursor trace is always right
 820         WarpZone_crosshair_trace(self);
 821         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 822         {
 823                 selected = trace_ent;
 824         }
 825         else
 826         {
 827                 // 2. if we don't have a cursor trace, find the player which is least
 828                 //    mis-aimed at
 829                 entity p;
 830                 FOR_EACH_PLAYER(p)
 831                 {
 832                         float c;
 833                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 834                         if(c >= -1)
 835                         {
 836                                 selected = p;
 837                                 selected_score = c;
 838                         }
 839                 }
 840         }
 841
 842         if(selected)
 843         {
 844                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 845         }
 846         else
 847         {
 848                 if(time < self.selected_player_display_timeout)
 849                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 850                                 selected = self.selected_player;
 851         }
 852
 853         if(selected)
 854         {
 855                 if(selected == self.selected_player)
 856                 {
 857                         float save;
 858                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 859                         self.selected_player_count = self.selected_player_count + frametime;
 860                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 861                         {
 862                                 string namestr, healthstr;
 863                                 namestr = playername(selected);
 864                                 if(teams_matter)
 865                                 {
 866                                         healthstr = ftos(floor(selected.health));
 867                                         if(self.team == selected.team)
 868                                         {
 869                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 870                                                 self.selected_player_display_needs_update = TRUE;
 871                                         }
 872                                 }
 873                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 874                         }
 875                 }
 876                 else
 877                 {
 878                         ClearSelectedPlayer();
 879                         self.selected_player = selected;
 880                         self.selected_player_time = time;
 881                         self.selected_player_count = 0;
 882                         self.selected_player_display_needs_update = FALSE;
 883                 }
 884         }
 885         else
 886         {
 887                 ClearSelectedPlayer();
 888         }
 889
 890         if(self.selected_player)
 891                 self.last_selected_player = self.selected_player;
 892 }
 893
 894 .float muted; // to be used by prvm_edictset server playernumber muted 1
 895 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 896 // message "": do not say, just test flood control
 897 // return value:
 898 //   1 = accept
 899 //   0 = reject
 900 //  -1 = fake accept
 901 {
 902         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 903         float flood, privatemsgprefixlen;
 904         entity head;
 905         float ret;
 906
 907         if(Ban_MaybeEnforceBan(source))
 908                 return 0;
 909
 910         if(!teamsay && !privatesay)
 911                 if(substring(msgin, 0, 1) == " ")
 912                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 913
 914         msgin = formatmessage(msgin);
 915
 916         if(source.classname != "player")
 917                 colorstr = "^0"; // black for spectators
 918         else if(teams_matter)
 919                 colorstr = Team_ColorCode(source.team);
 920         else
 921                 teamsay = FALSE;
 922
 923         if(intermission_running)
 924                 teamsay = FALSE;
 925
 926         if(msgin != "")
 927                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 928
 929         /*
 930          * using bprint solves this... me stupid
 931         // how can we prevent the message from appearing in a listen server?
 932         // for now, just give "say" back and only handle say_team
 933         if(!teamsay)
 934         {
 935                 clientcommand(self, strcat("say ", msgin));
 936                 return;
 937         }
 938         */
 939
 940         if(cvar("g_chat_teamcolors"))
 941                 namestr = playername(source);
 942         else
 943                 namestr = source.netname;
 944
 945         if(msgin != "")
 946         {
 947                 if(privatesay)
 948                 {
 949                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 950                         privatemsgprefixlen = strlen(msgstr);
 951                         msgstr = strcat(msgstr, msgin);
 952                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 953                         if(cvar("g_chat_teamcolors"))
 954                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 955                         else
 956                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 957                 }
 958                 else if(teamsay)
 959                 {
 960                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 961                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 962                 }
 963                 else
 964                 {
 965                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 966                         cmsgstr = "";
 967                 }
 968                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 969         }
 970         else
 971         {
 972                 msgstr = cmsgstr = "";
 973         }
 974
 975         fullmsgstr = msgstr;
 976         fullcmsgstr = cmsgstr;
 977
 978         // FLOOD CONTROL
 979         flood = 0;
 980         if(floodcontrol)
 981         {
 982                 float flood_spl;
 983                 float flood_burst;
 984                 float flood_lmax;
 985                 var .float flood_field;
 986                 float lines;
 987                 if(privatesay)
 988                 {
 989                         flood_spl = cvar("g_chat_flood_spl_tell");
 990                         flood_burst = cvar("g_chat_flood_burst_tell");
 991                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 992                         flood_field = floodcontrol_chattell;
 993                 }
 994                 else if(teamsay)
 995                 {
 996                         flood_spl = cvar("g_chat_flood_spl_team");
 997                         flood_burst = cvar("g_chat_flood_burst_team");
 998                         flood_lmax = cvar("g_chat_flood_lmax_team");
 999                         flood_field = floodcontrol_chatteam;
1000                 }
1001                 else
1002                 {
1003                         flood_spl = cvar("g_chat_flood_spl");
1004                         flood_burst = cvar("g_chat_flood_burst");
1005                         flood_lmax = cvar("g_chat_flood_lmax");
1006                         flood_field = floodcontrol_chat;
1007                 }
1008                 flood_burst = max(0, flood_burst - 1);
1009                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1010
1011                 // do flood control for the default line size
1012                 if(msgstr != "")
1013                 {
1014                         getWrappedLine_remaining = msgstr;
1015                         msgstr = "";
1016                         lines = 0;
1017                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1018                         {
1019                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1020                                 ++lines;
1021                         }
1022                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1023
1024                         if(getWrappedLine_remaining != "")
1025                         {
1026                                 msgstr = strcat(msgstr, "\n");
1027                                 flood = 2;
1028                         }
1029
1030                         if(time >= source.flood_field)
1031                         {
1032                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1033                         }
1034                         else
1035                         {
1036                                 flood = 1;
1037                                 msgstr = fullmsgstr;
1038                         }
1039                 }
1040                 else
1041                 {
1042                         if(time >= source.flood_field)
1043                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1044                         else
1045                                 flood = 1;
1046                 }
1047         }
1048
1049         if (timeoutStatus == 2) //when game is paused, no flood protection
1050                 source.flood_field = flood = 0;
1051
1052         if(flood == 2) // cannot happen for empty msgstr
1053         {
1054                 if(cvar("g_chat_flood_notify_flooder"))
1055                 {
1056                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1057                         sourcecmsgstr = "";
1058                 }
1059                 else
1060                 {
1061                         sourcemsgstr = fullmsgstr;
1062                         sourcecmsgstr = fullcmsgstr;
1063                 }
1064                 cmsgstr = "";
1065         }
1066         else
1067         {
1068                 sourcemsgstr = msgstr;
1069                 sourcecmsgstr = cmsgstr;
1070         }
1071
1072         if(!privatesay)
1073         if(source.classname != "player")
1074         {
1075                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1076                         teamsay = -1; // spectators
1077         }
1078
1079         if(flood)
1080                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1081
1082         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1083         if(privatesay)
1084                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1085
1086         if(source.muted)
1087         {
1088                 // always fake the message
1089                 ret = -1;
1090         }
1091         else if(flood == 1)
1092         {
1093                 if(cvar("g_chat_flood_notify_flooder"))
1094                 {
1095                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1096                         ret = 0;
1097                 }
1098                 else
1099                         ret = -1;
1100         }
1101         else
1102         {
1103                 ret = 1;
1104         }
1105
1106         if(sourcemsgstr != "" && ret != 0)
1107         {
1108                 if(ret < 0) // fake
1109                 {
1110                         sprint(source, sourcemsgstr);
1111                         if(sourcecmsgstr != "" && !privatesay)
1112                                 centerprint(source, sourcecmsgstr);
1113                 }
1114                 else if(privatesay)
1115                 {
1116                         sprint(source, sourcemsgstr);
1117                         sprint(privatesay, msgstr);
1118                         if(cmsgstr != "")
1119                                 centerprint(privatesay, cmsgstr);
1120                 }
1121                 else if(teamsay > 0)
1122                 {
1123                         sprint(source, sourcemsgstr);
1124                         if(sourcecmsgstr != "")
1125                                 centerprint(source, sourcecmsgstr);
1126                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1127                                 if(head != source)
1128                                 {
1129                                         sprint(head, msgstr);
1130                                         if(cmsgstr != "")
1131                                                 centerprint(head, cmsgstr);
1132                                 }
1133                 }
1134                 else if(teamsay < 0)
1135                 {
1136                         sprint(source, sourcemsgstr);
1137                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1138                                 if(head != source)
1139                                         sprint(head, msgstr);
1140                 }
1141                 else if(sourcemsgstr != msgstr)
1142                 {
1143                         sprint(source, sourcemsgstr);
1144                         FOR_EACH_REALCLIENT(head)
1145                                 if(head != source)
1146                                         sprint(head, msgstr);
1147                 }
1148                 else
1149                         bprint(msgstr);
1150         }
1151
1152         return ret;
1153 }
1154
1155 float GetVoiceMessageVoiceType(string type)
1156 {
1157         if(type == "taunt")
1158                 return VOICETYPE_TAUNT;
1159         if(type == "teamshoot")
1160                 return VOICETYPE_LASTATTACKER;
1161         return VOICETYPE_TEAMRADIO;
1162 }
1163
1164 string allvoicesamples;
1165 float GetPlayerSoundSampleField_notFound;
1166 float GetPlayerSoundSampleField_fixed;
1167 .string GetVoiceMessageSampleField(string type)
1168 {
1169         GetPlayerSoundSampleField_notFound = 0;
1170         GetPlayerSoundSampleField_fixed = 0;
1171         switch(type)
1172         {
1173 #define _VOICEMSG(m) case #m: return playersound_##m;
1174                 ALLVOICEMSGS
1175 #undef _VOICEMSG
1176         }
1177         GetPlayerSoundSampleField_notFound = 1;
1178         return playersound_taunt;
1179 }
1180
1181 .string GetPlayerSoundSampleField(string type)
1182 {
1183         GetPlayerSoundSampleField_notFound = 0;
1184         GetPlayerSoundSampleField_fixed = 0;
1185         switch(type)
1186         {
1187 #define _VOICEMSG(m) case #m: return playersound_##m;
1188                 ALLPLAYERSOUNDS
1189 #undef _VOICEMSG
1190         }
1191         GetPlayerSoundSampleField_notFound = 1;
1192         return playersound_taunt;
1193 }
1194
1195 void PrecacheGlobalSound(string samplestring)
1196 {
1197         float n, i;
1198         tokenize_console(samplestring);
1199         n = stof(argv(1));
1200         if(n > 0)
1201         {
1202                 for(i = 1; i <= n; ++i)
1203                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1204         }
1205         else
1206         {
1207                 precache_sound(strcat(argv(0), ".wav"));
1208         }
1209 }
1210
1211 void PrecachePlayerSounds(string f)
1212 {
1213         float fh;
1214         string s;
1215         fh = fopen(f, FILE_READ);
1216         if(fh < 0)
1217                 return;
1218         while((s = fgets(fh)))
1219         {
1220                 if(tokenize_console(s) != 3)
1221                 {
1222                         dprint("Invalid sound info line: ", s, "\n");
1223                         continue;
1224                 }
1225                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1226         }
1227         fclose(fh);
1228
1229         if not(allvoicesamples)
1230         {
1231 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1232                 ALLVOICEMSGS
1233 #undef _VOICEMSG
1234                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1235         }
1236 }
1237
1238 void ClearPlayerSounds()
1239 {
1240 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1241         ALLPLAYERSOUNDS
1242         ALLVOICEMSGS
1243 #undef _VOICEMSG
1244 }
1245
1246 void LoadPlayerSounds(string f, float first)
1247 {
1248         float fh;
1249         string s;
1250         var .string field;
1251         fh = fopen(f, FILE_READ);
1252         if(fh < 0)
1253                 return;
1254         while((s = fgets(fh)))
1255         {
1256                 if(tokenize_console(s) != 3)
1257                         continue;
1258                 field = GetPlayerSoundSampleField(argv(0));
1259                 if(GetPlayerSoundSampleField_notFound)
1260                         field = GetVoiceMessageSampleField(argv(0));
1261                 if(GetPlayerSoundSampleField_notFound)
1262                         continue;
1263                 if(GetPlayerSoundSampleField_fixed)
1264                         if not(first)
1265                                 continue;
1266                 if(self.field)
1267                         strunzone(self.field);
1268                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1269         }
1270         fclose(fh);
1271 }
1272
1273 .float modelindex_for_playersound;
1274 void UpdatePlayerSounds(string filename)
1275 {
1276         if(self.modelindex == self.modelindex_for_playersound)
1277                 return;
1278         self.modelindex_for_playersound = self.modelindex;
1279         ClearPlayerSounds();
1280         LoadPlayerSounds("sound/player/default.sounds", 1);
1281         if(filename != "")
1282                 LoadPlayerSounds(strcat(filename, ".sounds"), 0);
1283         else
1284                 LoadPlayerSounds(strcat(self.model, ".sounds"), 0); // backwards compatibility
1285 }
1286
1287 void FakeGlobalSound(string sample, float chan, float voicetype)
1288 {
1289         float n;
1290         float tauntrand;
1291
1292         if(sample == "")
1293                 return;
1294
1295         tokenize_console(sample);
1296         n = stof(argv(1));
1297         if(n > 0)
1298                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1299         else
1300                 sample = strcat(argv(0), ".wav"); // randomization
1301
1302         switch(voicetype)
1303         {
1304                 case VOICETYPE_LASTATTACKER_ONLY:
1305                         break;
1306                 case VOICETYPE_LASTATTACKER:
1307                         if(self.pusher)
1308                         {
1309                                 msg_entity = self;
1310                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1311                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1312                         }
1313                         break;
1314                 case VOICETYPE_TEAMRADIO:
1315                         msg_entity = self;
1316                         if(msg_entity.cvar_cl_voice_directional == 1)
1317                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1318                         else
1319                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1320                         break;
1321                 case VOICETYPE_AUTOTAUNT:
1322                         if(!sv_autotaunt)
1323                                 break;
1324                         if(!sv_taunt)
1325                                 break;
1326                         if(sv_gentle)
1327                                 break;
1328                         tauntrand = random();
1329                         msg_entity = self;
1330                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1331                         {
1332                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1333                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1334                                 else
1335                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1336                         }
1337                         break;
1338                 case VOICETYPE_TAUNT:
1339                         if(self.classname == "player")
1340                                 if(self.deadflag == DEAD_NO)
1341                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1342                         if(!sv_taunt)
1343                                 break;
1344                         if(sv_gentle)
1345                                 break;
1346                         msg_entity = self;
1347                         if (msg_entity.cvar_cl_voice_directional >= 1)
1348                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1349                         else
1350                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1351                         break;
1352                 case VOICETYPE_PLAYERSOUND:
1353                         msg_entity = self;
1354                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1355                         break;
1356                 default:
1357                         backtrace("Invalid voice type!");
1358                         break;
1359         }
1360 }
1361
1362 void GlobalSound(string sample, float chan, float voicetype)
1363 {
1364         float n;
1365         float tauntrand;
1366
1367         if(sample == "")
1368                 return;
1369
1370         tokenize_console(sample);
1371         n = stof(argv(1));
1372         if(n > 0)
1373                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1374         else
1375                 sample = strcat(argv(0), ".wav"); // randomization
1376
1377         switch(voicetype)
1378         {
1379                 case VOICETYPE_LASTATTACKER_ONLY:
1380                         if(self.pusher)
1381                         {
1382                                 msg_entity = self.pusher;
1383                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1384                                 {
1385                                         if(msg_entity.cvar_cl_voice_directional == 1)
1386                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1387                                         else
1388                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1389                                 }
1390                         }
1391                         break;
1392                 case VOICETYPE_LASTATTACKER:
1393                         if(self.pusher)
1394                         {
1395                                 msg_entity = self.pusher;
1396                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1397                                 {
1398                                         if(msg_entity.cvar_cl_voice_directional == 1)
1399                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1400                                         else
1401                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1402                                 }
1403                                 msg_entity = self;
1404                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1405                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1406                         }
1407                         break;
1408                 case VOICETYPE_TEAMRADIO:
1409                         FOR_EACH_REALCLIENT(msg_entity)
1410                                 if(!teams_matter || msg_entity.team == self.team)
1411                                 {
1412                                         if(msg_entity.cvar_cl_voice_directional == 1)
1413                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1414                                         else
1415                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1416                                 }
1417                         break;
1418                 case VOICETYPE_AUTOTAUNT:
1419                         if(!sv_autotaunt)
1420                                 break;
1421                         if(!sv_taunt)
1422                                 break;
1423                         if(sv_gentle)
1424                                 break;
1425                         tauntrand = random();
1426                         FOR_EACH_REALCLIENT(msg_entity)
1427                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1428                                 {
1429                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1430                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1431                                         else
1432                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1433                                 }
1434                         break;
1435                 case VOICETYPE_TAUNT:
1436                         if(self.classname == "player")
1437                                 if(self.deadflag == DEAD_NO)
1438                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1439                         if(!sv_taunt)
1440                                 break;
1441                         if(sv_gentle)
1442                                 break;
1443                         FOR_EACH_REALCLIENT(msg_entity)
1444                         {
1445                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1446                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1447                                 else
1448                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1449                         }
1450                         break;
1451                 case VOICETYPE_PLAYERSOUND:
1452                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1453                         break;
1454                 default:
1455                         backtrace("Invalid voice type!");
1456                         break;
1457         }
1458 }
1459
1460 void PlayerSound(.string samplefield, float chan, float voicetype)
1461 {
1462         GlobalSound(self.samplefield, chan, voicetype);
1463 }
1464
1465 void VoiceMessage(string type, string msg)
1466 {
1467         var .string sample;
1468         float voicetype, ownteam;
1469         float flood;
1470         sample = GetVoiceMessageSampleField(type);
1471
1472         if(GetPlayerSoundSampleField_notFound)
1473         {
1474                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1475                 return;
1476         }
1477
1478         voicetype = GetVoiceMessageVoiceType(type);
1479         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1480
1481         flood = Say(self, ownteam, world, msg, 1);
1482
1483         if (flood > 0)
1484                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1485         else if (flood < 0)
1486                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1487 }
1488
1489 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1490 {
1491 //      show_message
1492 //      0 (00) automove centerprint, admin message
1493 //      1 (01) automove centerprint, no admin message
1494 //      2 (10) no centerprint, admin message
1495 //      3 (11) no centerprint, no admin message
1496
1497         float lockteams_backup;
1498
1499         lockteams_backup = lockteams;  // backup any team lock
1500
1501         lockteams = 0;  // disable locked teams
1502
1503         TeamchangeFrags(client);  // move the players frags
1504         SetPlayerColors(client, team_colour - 1);  // set the players colour
1505         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1506
1507         lockteams = lockteams_backup;  // restore the team lock
1508
1509         LogTeamchange(client.playerid, client.team, type);
1510
1511         if not(show_message & 1) // admin message
1512                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1513
1514         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1515 }