Merge branch 'master' into terencehill/menu_dialogs_cleanups
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_player.qc
1 float weaponstats_buffer;
2
3 void WeaponStats_Init()
4 {
5         if(autocvar_sv_weaponstats_file != "")
6                 weaponstats_buffer = buf_create();
7         else
8                 weaponstats_buffer = -1;
9 }
10
11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
12
13 void WeaponStats_Shutdown()
14 {
15         float i, j, ibot, jbot, idx;
16         float fh;
17         vector v;
18         string prefix;
19         if(weaponstats_buffer < 0)
20                 return;
21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
22         if(autocvar_sv_weaponstats_file != "")
23         {
24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
25                 if(fh >= 0)
26                 {
27                         fputs(fh, "#begin statsfile\n");
28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
32                                 {
33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
35                                         if(v != '0 0 0')
36                                         {
37                                                 //vector is: kills hits damage
38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
40                                         }
41                                 }
42                         fputs(fh, "#end\n\n");
43                         fclose(fh);
44                         print("Weapon stats written\n");
45                 }
46         }
47         buf_del(weaponstats_buffer);
48         weaponstats_buffer = -1;
49 }
50
51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
52 {
53         float idx;
54         if(weaponstats_buffer < 0)
55                 return;
56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
57                 return;
58         if(awep > WEP_LAST || vwep > WEP_LAST)
59                 return;
60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
62 }
63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
64 {
65         if(damage < 0)
66                 error("negative damage?");
67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
68 }
69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
70 {
71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
72 }
73
74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
75 // merged player_run and player_stand to player_anim
76 // added death animations to player_anim
77 // can now spawn thrown weapons from anywhere, not just from players
78 // thrown weapons now fade out after 20 seconds
79 // created PlayerGib function
80 // PlayerDie no longer uses hitloc or damage
81 // PlayerDie now supports dying animations as well as gibbing
82 // cleaned up PlayerDie a lot
83 // added CopyBody
84
85 .entity pusher;
86 .float pushltime;
87
88 void CopyBody(float keepvelocity)
89 {
90         local entity oldself;
91         if (self.effects & EF_NODRAW)
92                 return;
93         oldself = self;
94         self = spawn();
95         self.enemy = oldself;
96         self.lip = oldself.lip;
97         self.colormap = oldself.colormap;
98         self.glowmod = oldself.glowmod;
99         self.iscreature = oldself.iscreature;
100         self.angles = oldself.angles;
101         self.avelocity = oldself.avelocity;
102         self.classname = "body";
103         self.damageforcescale = oldself.damageforcescale;
104         self.effects = oldself.effects;
105         self.event_damage = oldself.event_damage;
106         self.animstate_startframe = oldself.animstate_startframe;
107         self.animstate_numframes = oldself.animstate_numframes;
108         self.animstate_framerate = oldself.animstate_framerate;
109         self.animstate_starttime = oldself.animstate_starttime;
110         self.animstate_endtime = oldself.animstate_endtime;
111         self.animstate_override = oldself.animstate_override;
112         self.animstate_looping = oldself.animstate_looping;
113         self.frame = oldself.frame;
114         self.dead_frame = oldself.dead_frame;
115         self.pain_finished = oldself.pain_finished;
116         self.health = oldself.health;
117         self.armorvalue = oldself.armorvalue;
118         self.armortype = oldself.armortype;
119         self.model = oldself.model;
120         self.modelindex = oldself.modelindex;
121         self.modelindex_lod0 = oldself.modelindex_lod0;
122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
123         self.modelindex_lod1 = oldself.modelindex_lod1;
124         self.modelindex_lod2 = oldself.modelindex_lod2;
125         self.skinindex = oldself.skinindex;
126         self.species = oldself.species;
127         self.movetype = oldself.movetype;
128         self.nextthink = oldself.nextthink;
129         self.solid = oldself.solid;
130         self.ballistics_density = oldself.ballistics_density;
131         self.takedamage = oldself.takedamage;
132         self.think = oldself.think;
133         self.customizeentityforclient = oldself.customizeentityforclient;
134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
136         if (keepvelocity == 1)
137                 self.velocity = oldself.velocity;
138         self.oldvelocity = self.velocity;
139         self.fade_time = oldself.fade_time;
140         self.fade_rate = oldself.fade_rate;
141         //self.weapon = oldself.weapon;
142         setorigin(self, oldself.origin);
143         setsize(self, oldself.mins, oldself.maxs);
144         self.prevorigin = oldself.origin;
145         self.reset = SUB_Remove;
146
147         Drag_MoveDrag(oldself, self);
148
149         self = oldself;
150 }
151
152 float player_getspecies()
153 {
154         float s;
155         get_model_parameters(self.model, self.skinindex);
156         s = get_model_parameters_species;
157         get_model_parameters(string_null, 0);
158         if(s < 0)
159                 return SPECIES_HUMAN;
160         return s;
161 }
162
163 void player_setupanimsformodel()
164 {
165         local string animfilename;
166         local float animfile;
167         // defaults for legacy .zym models without animinfo files
168         self.anim_die1 = '0 1 0.5'; // 2 seconds
169         self.anim_die2 = '1 1 0.5'; // 2 seconds
170         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
171         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
172         self.anim_duckwalk = '4 1 1';
173         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
174         self.anim_duckidle = '6 1 1';
175         self.anim_idle = '7 1 1';
176         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
177         self.anim_pain1 = '9 1 2'; // 0.5 seconds
178         self.anim_pain2 = '10 1 2'; // 0.5 seconds
179         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
180         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
181         self.anim_run = '13 1 1';
182         self.anim_runbackwards = '14 1 1';
183         self.anim_strafeleft = '15 1 1';
184         self.anim_straferight = '16 1 1';
185         self.anim_dead1 = '17 1 1';
186         self.anim_dead2 = '18 1 1';
187         self.anim_forwardright = '19 1 1';
188         self.anim_forwardleft = '20 1 1';
189         self.anim_backright = '21 1 1';
190         self.anim_backleft  = '22 1 1';
191         animparseerror = FALSE;
192         animfilename = strcat(self.model, ".animinfo");
193         animfile = fopen(animfilename, FILE_READ);
194         if (animfile >= 0)
195         {
196                 self.anim_die1         = animparseline(animfile);
197                 self.anim_die2         = animparseline(animfile);
198                 self.anim_draw         = animparseline(animfile);
199                 self.anim_duck         = animparseline(animfile);
200                 self.anim_duckwalk     = animparseline(animfile);
201                 self.anim_duckjump     = animparseline(animfile);
202                 self.anim_duckidle     = animparseline(animfile);
203                 self.anim_idle         = animparseline(animfile);
204                 self.anim_jump         = animparseline(animfile);
205                 self.anim_pain1        = animparseline(animfile);
206                 self.anim_pain2        = animparseline(animfile);
207                 self.anim_shoot        = animparseline(animfile);
208                 self.anim_taunt        = animparseline(animfile);
209                 self.anim_run          = animparseline(animfile);
210                 self.anim_runbackwards = animparseline(animfile);
211                 self.anim_strafeleft   = animparseline(animfile);
212                 self.anim_straferight  = animparseline(animfile);
213                 self.anim_forwardright = animparseline(animfile);
214                 self.anim_forwardleft  = animparseline(animfile);
215                 self.anim_backright    = animparseline(animfile);
216                 self.anim_backleft     = animparseline(animfile);
217                 fclose(animfile);
218
219                 // derived anims
220                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
221                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
222
223                 if (animparseerror)
224                         print("Parse error in ", animfilename, ", some player animations are broken\n");
225         }
226         else
227                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
228         // reset animstate now
229         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
230 };
231
232 void player_anim (void)
233 {
234         updateanim(self);
235         if (self.weaponentity)
236                 updateanim(self.weaponentity);
237
238         if (self.deadflag != DEAD_NO)
239         {
240                 if (time > self.animstate_endtime)
241                 {
242                         if (self.maxs_z > 5)
243                         {
244                                 self.maxs_z = 5;
245                                 setsize(self, self.mins, self.maxs);
246                         }
247                         self.frame = self.dead_frame;
248                 }
249                 return;
250         }
251
252         if (!self.animstate_override)
253         {
254                 if (!(self.flags & FL_ONGROUND))
255                 {
256                         if (self.crouch)
257                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
258                         else
259                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
260                         self.restart_jump = FALSE;
261                 }
262                 else if (self.crouch)
263                 {
264                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
265                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
266                         else
267                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
268                 }
269                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
270                 {
271                         if (self.movement_x > 0 && self.movement_y == 0)
272                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
273                         else if (self.movement_x < 0 && self.movement_y == 0)
274                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
275                         else if (self.movement_x == 0 && self.movement_y > 0)
276                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
277                         else if (self.movement_x == 0 && self.movement_y < 0)
278                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
279                         else if (self.movement_x > 0 && self.movement_y > 0)
280                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
281                         else if (self.movement_x > 0 && self.movement_y < 0)
282                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
283                         else if (self.movement_x < 0 && self.movement_y > 0)
284                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
285                         else if (self.movement_x < 0 && self.movement_y < 0)
286                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
287                         else
288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
289                 }
290                 else
291                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
292         }
293
294         if (self.weaponentity)
295         if (!self.weaponentity.animstate_override)
296                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
297 }
298
299 void SpawnThrownWeapon (vector org, float w)
300 {
301         if(g_minstagib)
302         if(self.ammo_cells <= 0)
303                 return;
304
305         if(g_pinata)
306         {
307                 float j;
308                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
309                 {
310                         if(self.weapons & W_WeaponBit(j))
311                                 if(W_IsWeaponThrowable(j))
312                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
313                 }
314         }
315         else
316         {
317                 if(W_IsWeaponThrowable(self.weapon))
318                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
319         }
320 }
321
322 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
323 {
324         local float take, save;
325         vector v;
326         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
327
328         // damage resistance (ignore most of the damage from a bullet or similar)
329         damage = max(damage - 5, 1);
330
331         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
332         take = v_x;
333         save = v_y;
334
335         if(sound_allowed(MSG_BROADCAST, attacker))
336         {
337                 if (save > 10)
338                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
339                 else if (take > 30)
340                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
341                 else if (take > 10)
342                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
343         }
344
345         if (take > 50)
346                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
347         if (take > 100)
348                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
349
350         if (!(self.flags & FL_GODMODE))
351         {
352                 self.armorvalue = self.armorvalue - save;
353                 self.health = self.health - take;
354                 // pause regeneration for 5 seconds
355                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
356         }
357         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
358         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
359         self.dmg_inflictor = inflictor;
360
361         if (self.health <= -150 && self.modelindex != 0)
362         {
363                 // don't use any animations as a gib
364                 self.frame = 0;
365                 self.dead_frame = 0;
366                 // view just above the floor
367                 self.view_ofs = '0 0 4';
368
369                 Violence_GibSplash(self, 1, 1, attacker);
370                 self.modelindex = 0; // restore later
371                 self.solid = SOLID_NOT; // restore later
372         }
373 }
374
375 void ClientKill_Now_TeamChange();
376 void freezetag_CheckWinner();
377
378 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
379 {
380         local float take, save, waves, sdelay, dh, da, j;
381         vector v;
382         float valid_damage_for_weaponstats;
383         float excess;
384
385         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
386                 return;
387
388         dh = max(self.health, 0);
389         da = max(self.armorvalue, 0);
390
391         if(!DEATH_ISSPECIAL(deathtype))
392         {
393                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
394                 if(self != attacker)
395                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
396         }
397
398         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
399         {
400                 // tuba causes blood to come out of the ears
401                 vector ear1, ear2;
402                 vector d;
403                 float f;
404                 ear1 = self.origin;
405                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
406                 ear2 = ear1;
407                 makevectors(self.angles);
408                 ear1 += v_right * -10;
409                 ear2 += v_right * +10;
410                 d = inflictor.origin - self.origin;
411                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
412                 force = v_right * vlen(force);
413                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
414                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
415                 if(f > 0)
416                 {
417                         hitloc = ear1;
418                         force = force * -1;
419                 }
420                 else
421                 {
422                         hitloc = ear2;
423                         // force is already good
424                 }
425         }
426         else
427                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
428
429         if (!g_minstagib)
430         {
431                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
432                 take = v_x;
433                 save = v_y;
434         }
435         else
436         {
437                 save = 0;
438                 take = damage;
439         }
440
441         frag_inflictor = inflictor;
442         frag_attacker = attacker;
443         frag_target = self;
444         damage_take = take;
445         damage_save = save;
446         damage_force = force;
447         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
448         take = bound(0, damage_take, self.health);
449         save = bound(0, damage_save, self.armorvalue);
450         excess = max(0, damage - take - save);
451
452         if(sound_allowed(MSG_BROADCAST, attacker))
453         {
454                 if (save > 10)
455                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
456                 else if (take > 30)
457                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
458                 else if (take > 10)
459                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
460         }
461
462         if (take > 50)
463                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
464         if (take > 100)
465                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
466
467         if (time >= self.spawnshieldtime)
468         {
469                 if (!(self.flags & FL_GODMODE))
470                 {
471                         self.armorvalue = self.armorvalue - save;
472                         self.health = self.health - take;
473                         // pause regeneration for 5 seconds
474                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
475
476                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
477                         {
478                                 self.pain_finished = time + 0.5;        //Supajoe
479
480                                 if(sv_gentle < 1) {
481                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
482                                         {
483                                                 if (random() > 0.5)
484                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
485                                                 else
486                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
487                                         }
488
489                                         if(sound_allowed(MSG_BROADCAST, attacker))
490                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
491                                         if(self.health > 1)
492                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
493                                         {
494                                                 if(deathtype == DEATH_FALL)
495                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
496                                                 else if(self.health > 75) // TODO make a "gentle" version?
497                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
498                                                 else if(self.health > 50)
499                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
500                                                 else if(self.health > 25)
501                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
502                                                 else
503                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
504                                         }
505                                 }
506
507                                 // throw off bot aim temporarily
508                                 local float shake;
509                                 shake = damage * 5 / (bound(0,skill,100) + 1);
510                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
511                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
512                         }
513                 }
514                 else
515                         self.max_armorvalue += (save + take);
516         }
517         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
518         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
519         self.dmg_inflictor = inflictor;
520
521         if(attacker == self)
522         {
523                 // don't reset pushltime for self damage as it may be an attempt to
524                 // escape a lava pit or similar
525                 //self.pushltime = 0;
526         }
527         else if(attacker.classname == "player" || attacker.classname == "gib")
528         {
529                 self.pusher = attacker;
530                 self.pushltime = time + autocvar_g_maxpushtime;
531         }
532         else if(time < self.pushltime)
533         {
534                 attacker = self.pusher;
535                 self.pushltime = max(self.pushltime, time + 0.6);
536         }
537         else
538                 self.pushltime = 0;
539
540         float abot, vbot, awep;
541         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
542         vbot = (clienttype(self) == CLIENTTYPE_BOT);
543
544         valid_damage_for_weaponstats = 0;
545         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
546         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
547         if(attacker && self != attacker)
548         if(IsDifferentTeam(self, attacker))
549         {
550                 if(DEATH_ISSPECIAL(deathtype))
551                         awep = attacker.weapon;
552                 else
553                         awep = DEATH_WEAPONOF(deathtype);
554                 valid_damage_for_weaponstats = 1;
555         }
556         
557         if(valid_damage_for_weaponstats)
558         {
559                 dh = dh - max(self.health, 0);
560                 da = da - max(self.armorvalue, 0);
561                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
562         }
563
564         if (self.health < 1)
565         {
566                 float defer_ClientKill_Now_TeamChange;
567                 defer_ClientKill_Now_TeamChange = FALSE;
568
569                 if(self.alivetime)
570                 {
571                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
572                         self.alivetime = 0;
573                 }
574
575                 if(valid_damage_for_weaponstats)
576                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
577
578                 if(sv_gentle < 1) // TODO make a "gentle" version?
579                 if(sound_allowed(MSG_BROADCAST, attacker))
580                 {
581                         if(deathtype == DEATH_DROWN)
582                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
583                         else
584                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
585                 }
586
587                 // get rid of kill indicator
588                 if(self.killindicator)
589                 {
590                         remove(self.killindicator);
591                         self.killindicator = world;
592                         if(self.killindicator_teamchange)
593                                 defer_ClientKill_Now_TeamChange = TRUE;
594
595                         if(self.classname == "body")
596                         if(deathtype == DEATH_KILL)
597                         {
598                                 // for the lemmings fans, a small harmless explosion
599                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
600                         }
601                 }
602
603                 if(!g_freezetag)
604                 {
605                         // become fully visible
606                         self.alpha = 1;
607                         // clear selected player display
608                         ClearSelectedPlayer();
609                         // throw a weapon
610                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
611                 }
612
613                 // print an obituary message
614                 Obituary (attacker, inflictor, self, deathtype);
615                 race_PreDie();
616                 DropAllRunes(self);
617
618                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
619                 {
620                         PutClientInServer();
621                         count_alive_players(); // re-count players
622                         freezetag_CheckWinner();
623                         return;
624                 }
625
626                 frag_attacker = attacker;
627                 frag_inflictor = inflictor;
628                 frag_target = self;
629                 MUTATOR_CALLHOOK(PlayerDies);
630
631                 if(self.flagcarried)
632                 {
633                         if(attacker.classname != "player" && attacker.classname != "gib")
634                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
635                         else if(attacker.team == self.team)
636                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
637                         else
638                                 DropFlag(self.flagcarried, world, attacker);
639                 }
640                 if(self.ballcarried && g_nexball)
641                         DropBall(self.ballcarried, self.origin, self.velocity);
642                 Portal_ClearAllLater(self);
643
644                 if(clienttype(self) == CLIENTTYPE_REAL)
645                 {
646                         stuffcmd(self, "-zoom\n");
647                         self.fixangle = TRUE;
648                         //msg_entity = self;
649                         //WriteByte (MSG_ONE, SVC_SETANGLE);
650                         //WriteAngle (MSG_ONE, self.v_angle_x);
651                         //WriteAngle (MSG_ONE, self.v_angle_y);
652                         //WriteAngle (MSG_ONE, 80);
653                 }
654
655                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
656                         ClientKill_Now_TeamChange();
657
658                 if(g_arena)
659                         Spawnqueue_Unmark(self);
660
661                 if(g_freezetag)
662                         return;
663
664                 // when we get here, player actually dies
665                 // clear waypoints (do this AFTER FreezeTag)
666                 WaypointSprite_PlayerDead();
667
668                 // make the corpse upright (not tilted)
669                 self.angles_x = 0;
670                 self.angles_z = 0;
671                 // don't spin
672                 self.avelocity = '0 0 0';
673                 // view from the floor
674                 self.view_ofs = '0 0 -8';
675                 // toss the corpse
676                 self.movetype = MOVETYPE_TOSS;
677                 // shootable corpse
678                 self.solid = SOLID_CORPSE;
679                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
680                 // don't stick to the floor
681                 self.flags &~= FL_ONGROUND;
682                 // dying animation
683                 self.deadflag = DEAD_DYING;
684                 // when to allow respawn
685                 sdelay = 0;
686                 waves = 0;
687                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
688                 if(!sdelay)
689                 {
690                         if(g_cts)
691                                 sdelay = 0; // no respawn delay in CTS
692                         else
693                                 sdelay = autocvar_g_respawn_delay;
694                 }
695                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
696                 if(!waves)
697                         waves = autocvar_g_respawn_waves;
698                 if(waves)
699                         self.death_time = ceil((time + sdelay) / waves) * waves;
700                 else
701                         self.death_time = time + sdelay;
702                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
703                         self.respawn_countdown = 10; // first number to count down from is 10
704                 else
705                         self.respawn_countdown = -1; // do not count down
706                 if (random() < 0.5)
707                 {
708                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
709                         self.dead_frame = self.anim_dead1_x;
710                 }
711                 else
712                 {
713                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
714                         self.dead_frame = self.anim_dead2_x;
715                 }
716                 // set damage function to corpse damage
717                 self.event_damage = PlayerCorpseDamage;
718                 // call the corpse damage function just in case it wants to gib
719                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
720                 // set up to fade out later
721                 SUB_SetFade (self, time + 6 + random (), 1);
722
723                 if(sv_gentle > 0 || autocvar_ekg) {
724                         // remove corpse
725                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
726                 }
727
728                 // reset fields the weapons may use just in case
729                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
730                 {
731                         weapon_action(j, WR_RESETPLAYER);
732                         ATTACK_FINISHED_FOR(self, j) = 0;
733                 }
734         }
735 }
736
737 float UpdateSelectedPlayer_countvalue(float v)
738 {
739         return max(0, (v - 1.0) / 0.5);
740 }
741
742 // returns: -2 if no hit, otherwise cos of the angle
743 // uses the global v_angle
744 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
745 {
746         vector so, d;
747         float c;
748
749         if(p == self)
750                 return -2;
751
752         if(p.deadflag)
753                 return -2;
754
755         so = self.origin + self.view_ofs;
756         d = p.origin - so;
757
758         // misaimed?
759         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
760                 return -2;
761
762         // now find the cos of the angle...
763         c = normalize(d) * v_forward;
764
765         if(c <= mincosangle)
766                 return -2;
767
768         // not visible in any way? forget it
769         if(!checkpvs(so, p))
770                 return -2;
771
772         traceline(so, p.origin, MOVE_NOMONSTERS, self);
773         if(trace_fraction < 1)
774                 return -2;
775
776         return c;
777 }
778
779 void ClearSelectedPlayer()
780 {
781         if(self.selected_player)
782         {
783                 centerprint_expire(self, CENTERPRIO_POINT);
784                 self.selected_player = world;
785                 self.selected_player_display_needs_update = FALSE;
786         }
787 }
788
789 void UpdateSelectedPlayer()
790 {
791         entity selected;
792         float selected_score;
793         selected = world;
794         selected_score = 0.95; // 18 degrees
795
796         if(!autocvar_sv_allow_shownames)
797                 return;
798
799         if(clienttype(self) != CLIENTTYPE_REAL)
800                 return;
801
802         if(self.cvar_cl_shownames == 0)
803                 return;
804
805         if(self.cvar_cl_shownames == 1 && !teams_matter)
806                 return;
807
808         makevectors(self.v_angle); // sets v_forward
809
810         // 1. cursor trace is always right
811         WarpZone_crosshair_trace(self);
812         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
813         {
814                 selected = trace_ent;
815         }
816         else
817         {
818                 // 2. if we don't have a cursor trace, find the player which is least
819                 //    mis-aimed at
820                 entity p;
821                 FOR_EACH_PLAYER(p)
822                 {
823                         float c;
824                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
825                         if(c >= -1)
826                         {
827                                 selected = p;
828                                 selected_score = c;
829                         }
830                 }
831         }
832
833         if(selected)
834         {
835                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
836         }
837         else
838         {
839                 if(time < self.selected_player_display_timeout)
840                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
841                                 selected = self.selected_player;
842         }
843
844         if(selected)
845         {
846                 if(selected == self.selected_player)
847                 {
848                         float save;
849                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
850                         self.selected_player_count = self.selected_player_count + frametime;
851                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
852                         {
853                                 string namestr, healthstr;
854                                 namestr = playername(selected);
855                                 if(teams_matter)
856                                 {
857                                         healthstr = ftos(floor(selected.health));
858                                         if(self.team == selected.team)
859                                         {
860                                                 namestr = strcat(namestr, " (", healthstr, "%)");
861                                                 self.selected_player_display_needs_update = TRUE;
862                                         }
863                                 }
864                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
865                         }
866                 }
867                 else
868                 {
869                         ClearSelectedPlayer();
870                         self.selected_player = selected;
871                         self.selected_player_time = time;
872                         self.selected_player_count = 0;
873                         self.selected_player_display_needs_update = FALSE;
874                 }
875         }
876         else
877         {
878                 ClearSelectedPlayer();
879         }
880
881         if(self.selected_player)
882                 self.last_selected_player = self.selected_player;
883 }
884
885 .float muted; // to be used by prvm_edictset server playernumber muted 1
886 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
887 // message "": do not say, just test flood control
888 // return value:
889 //   1 = accept
890 //   0 = reject
891 //  -1 = fake accept
892 {
893         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
894         float flood, privatemsgprefixlen;
895         var .float flood_field;
896         entity head;
897         float ret;
898
899         if(Ban_MaybeEnforceBan(source))
900                 return 0;
901
902         if(!teamsay && !privatesay)
903                 if(substring(msgin, 0, 1) == " ")
904                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
905
906         msgin = formatmessage(msgin);
907
908         if(source.classname != "player")
909                 colorstr = "^0"; // black for spectators
910         else if(teams_matter)
911                 colorstr = Team_ColorCode(source.team);
912         else
913                 teamsay = FALSE;
914
915         if(intermission_running)
916                 teamsay = FALSE;
917
918         if(msgin != "")
919                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
920
921         /*
922          * using bprint solves this... me stupid
923         // how can we prevent the message from appearing in a listen server?
924         // for now, just give "say" back and only handle say_team
925         if(!teamsay)
926         {
927                 clientcommand(self, strcat("say ", msgin));
928                 return;
929         }
930         */
931
932         if(autocvar_g_chat_teamcolors)
933                 namestr = playername(source);
934         else
935                 namestr = source.netname;
936
937         if(msgin != "")
938         {
939                 if(privatesay)
940                 {
941                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
942                         privatemsgprefixlen = strlen(msgstr);
943                         msgstr = strcat(msgstr, msgin);
944                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
945                         if(autocvar_g_chat_teamcolors)
946                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
947                         else
948                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
949                 }
950                 else if(teamsay)
951                 {
952                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
953                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
954                 }
955                 else
956                 {
957                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
958                         cmsgstr = "";
959                 }
960                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
961         }
962         else
963         {
964                 msgstr = cmsgstr = "";
965         }
966
967         fullmsgstr = msgstr;
968         fullcmsgstr = cmsgstr;
969
970         // FLOOD CONTROL
971         flood = 0;
972         if(floodcontrol)
973         {
974                 float flood_spl;
975                 float flood_burst;
976                 float flood_lmax;
977                 float lines;
978                 if(privatesay)
979                 {
980                         flood_spl = autocvar_g_chat_flood_spl_tell;
981                         flood_burst = autocvar_g_chat_flood_burst_tell;
982                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
983                         flood_field = floodcontrol_chattell;
984                 }
985                 else if(teamsay)
986                 {
987                         flood_spl = autocvar_g_chat_flood_spl_team;
988                         flood_burst = autocvar_g_chat_flood_burst_team;
989                         flood_lmax = autocvar_g_chat_flood_lmax_team;
990                         flood_field = floodcontrol_chatteam;
991                 }
992                 else
993                 {
994                         flood_spl = autocvar_g_chat_flood_spl;
995                         flood_burst = autocvar_g_chat_flood_burst;
996                         flood_lmax = autocvar_g_chat_flood_lmax;
997                         flood_field = floodcontrol_chat;
998                 }
999                 flood_burst = max(0, flood_burst - 1);
1000                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1001
1002                 // do flood control for the default line size
1003                 if(msgstr != "")
1004                 {
1005                         getWrappedLine_remaining = msgstr;
1006                         msgstr = "";
1007                         lines = 0;
1008                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1009                         {
1010                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1011                                 ++lines;
1012                         }
1013                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1014
1015                         if(getWrappedLine_remaining != "")
1016                         {
1017                                 msgstr = strcat(msgstr, "\n");
1018                                 flood = 2;
1019                         }
1020
1021                         if(time >= source.flood_field)
1022                         {
1023                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1024                         }
1025                         else
1026                         {
1027                                 flood = 1;
1028                                 msgstr = fullmsgstr;
1029                         }
1030                 }
1031                 else
1032                 {
1033                         if(time >= source.flood_field)
1034                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1035                         else
1036                                 flood = 1;
1037                 }
1038
1039                 if (timeoutStatus == 2) //when game is paused, no flood protection
1040                         source.flood_field = flood = 0;
1041         }
1042
1043         if(flood == 2) // cannot happen for empty msgstr
1044         {
1045                 if(autocvar_g_chat_flood_notify_flooder)
1046                 {
1047                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1048                         sourcecmsgstr = "";
1049                 }
1050                 else
1051                 {
1052                         sourcemsgstr = fullmsgstr;
1053                         sourcecmsgstr = fullcmsgstr;
1054                 }
1055                 cmsgstr = "";
1056         }
1057         else
1058         {
1059                 sourcemsgstr = msgstr;
1060                 sourcecmsgstr = cmsgstr;
1061         }
1062
1063         if(!privatesay)
1064         if(source.classname != "player")
1065         {
1066                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1067                         teamsay = -1; // spectators
1068         }
1069
1070         if(flood)
1071                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1072
1073         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1074         if(privatesay)
1075                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1076
1077         if(source.muted)
1078         {
1079                 // always fake the message
1080                 ret = -1;
1081         }
1082         else if(flood == 1)
1083         {
1084                 if(autocvar_g_chat_flood_notify_flooder)
1085                 {
1086                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1087                         ret = 0;
1088                 }
1089                 else
1090                         ret = -1;
1091         }
1092         else
1093         {
1094                 ret = 1;
1095         }
1096
1097         if(sourcemsgstr != "" && ret != 0)
1098         {
1099                 if(ret < 0) // fake
1100                 {
1101                         sprint(source, sourcemsgstr);
1102                         if(sourcecmsgstr != "" && !privatesay)
1103                                 centerprint(source, sourcecmsgstr);
1104                 }
1105                 else if(privatesay)
1106                 {
1107                         sprint(source, sourcemsgstr);
1108                         sprint(privatesay, msgstr);
1109                         if(cmsgstr != "")
1110                                 centerprint(privatesay, cmsgstr);
1111                 }
1112                 else if(teamsay > 0)
1113                 {
1114                         sprint(source, sourcemsgstr);
1115                         if(sourcecmsgstr != "")
1116                                 centerprint(source, sourcecmsgstr);
1117                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1118                                 if(head != source)
1119                                 {
1120                                         sprint(head, msgstr);
1121                                         if(cmsgstr != "")
1122                                                 centerprint(head, cmsgstr);
1123                                 }
1124                 }
1125                 else if(teamsay < 0)
1126                 {
1127                         sprint(source, sourcemsgstr);
1128                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1129                                 if(head != source)
1130                                         sprint(head, msgstr);
1131                 }
1132                 else if(sourcemsgstr != msgstr)
1133                 {
1134                         sprint(source, sourcemsgstr);
1135                         FOR_EACH_REALCLIENT(head)
1136                                 if(head != source)
1137                                         sprint(head, msgstr);
1138                 }
1139                 else
1140                         bprint(msgstr);
1141         }
1142
1143         return ret;
1144 }
1145
1146 float GetVoiceMessageVoiceType(string type)
1147 {
1148         if(type == "taunt")
1149                 return VOICETYPE_TAUNT;
1150         if(type == "teamshoot")
1151                 return VOICETYPE_LASTATTACKER;
1152         return VOICETYPE_TEAMRADIO;
1153 }
1154
1155 string allvoicesamples;
1156 .string GetVoiceMessageSampleField(string type)
1157 {
1158         GetPlayerSoundSampleField_notFound = 0;
1159         switch(type)
1160         {
1161 #define _VOICEMSG(m) case #m: return playersound_##m;
1162                 ALLVOICEMSGS
1163 #undef _VOICEMSG
1164         }
1165         GetPlayerSoundSampleField_notFound = 1;
1166         return playersound_taunt;
1167 }
1168
1169 .string GetPlayerSoundSampleField(string type)
1170 {
1171         GetPlayerSoundSampleField_notFound = 0;
1172         switch(type)
1173         {
1174 #define _VOICEMSG(m) case #m: return playersound_##m;
1175                 ALLPLAYERSOUNDS
1176 #undef _VOICEMSG
1177         }
1178         GetPlayerSoundSampleField_notFound = 1;
1179         return playersound_taunt;
1180 }
1181
1182 void PrecacheGlobalSound(string samplestring)
1183 {
1184         float n, i;
1185         tokenize_console(samplestring);
1186         n = stof(argv(1));
1187         if(n > 0)
1188         {
1189                 for(i = 1; i <= n; ++i)
1190                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1191         }
1192         else
1193         {
1194                 precache_sound(strcat(argv(0), ".wav"));
1195         }
1196 }
1197
1198 void PrecachePlayerSounds(string f)
1199 {
1200         float fh;
1201         string s;
1202         fh = fopen(f, FILE_READ);
1203         if(fh < 0)
1204                 return;
1205         while((s = fgets(fh)))
1206         {
1207                 if(tokenize_console(s) != 3)
1208                 {
1209                         dprint("Invalid sound info line: ", s, "\n");
1210                         continue;
1211                 }
1212                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1213         }
1214         fclose(fh);
1215
1216         if not(allvoicesamples)
1217         {
1218 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1219                 ALLVOICEMSGS
1220 #undef _VOICEMSG
1221                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1222         }
1223 }
1224
1225 void ClearPlayerSounds()
1226 {
1227 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1228         ALLPLAYERSOUNDS
1229         ALLVOICEMSGS
1230 #undef _VOICEMSG
1231 }
1232
1233 float LoadPlayerSounds(string f, float first)
1234 {
1235         float fh;
1236         string s;
1237         var .string field;
1238         fh = fopen(f, FILE_READ);
1239         if(fh < 0)
1240         {
1241                 dprint("Player sound file not found: ", f, "\n");
1242                 return 0;
1243         }
1244         while((s = fgets(fh)))
1245         {
1246                 if(tokenize_console(s) != 3)
1247                         continue;
1248                 field = GetPlayerSoundSampleField(argv(0));
1249                 if(GetPlayerSoundSampleField_notFound)
1250                         field = GetVoiceMessageSampleField(argv(0));
1251                 if(GetPlayerSoundSampleField_notFound)
1252                         continue;
1253                 if(self.field)
1254                         strunzone(self.field);
1255                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1256         }
1257         fclose(fh);
1258         return 1;
1259 }
1260
1261 .float modelindex_for_playersound;
1262 .float skinindex_for_playersound;
1263 void UpdatePlayerSounds()
1264 {
1265         if(self.modelindex == self.modelindex_for_playersound)
1266         if(self.skinindex == self.skinindex_for_playersound)
1267                 return;
1268         self.modelindex_for_playersound = self.modelindex;
1269         self.skinindex_for_playersound = self.skinindex;
1270         ClearPlayerSounds();
1271         LoadPlayerSounds("sound/player/default.sounds", 1);
1272         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1273                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1274 }
1275
1276 void FakeGlobalSound(string sample, float chan, float voicetype)
1277 {
1278         float n;
1279         float tauntrand;
1280
1281         if(sample == "")
1282                 return;
1283
1284         tokenize_console(sample);
1285         n = stof(argv(1));
1286         if(n > 0)
1287                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1288         else
1289                 sample = strcat(argv(0), ".wav"); // randomization
1290
1291         switch(voicetype)
1292         {
1293                 case VOICETYPE_LASTATTACKER_ONLY:
1294                         break;
1295                 case VOICETYPE_LASTATTACKER:
1296                         if(self.pusher)
1297                         {
1298                                 msg_entity = self;
1299                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1300                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1301                         }
1302                         break;
1303                 case VOICETYPE_TEAMRADIO:
1304                         msg_entity = self;
1305                         if(msg_entity.cvar_cl_voice_directional == 1)
1306                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1307                         else
1308                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1309                         break;
1310                 case VOICETYPE_AUTOTAUNT:
1311                         if(!sv_autotaunt)
1312                                 break;
1313                         if(!sv_taunt)
1314                                 break;
1315                         if(sv_gentle)
1316                                 break;
1317                         tauntrand = random();
1318                         msg_entity = self;
1319                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1320                         {
1321                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1322                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1323                                 else
1324                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1325                         }
1326                         break;
1327                 case VOICETYPE_TAUNT:
1328                         if(self.classname == "player")
1329                                 if(self.deadflag == DEAD_NO)
1330                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1331                         if(!sv_taunt)
1332                                 break;
1333                         if(sv_gentle)
1334                                 break;
1335                         msg_entity = self;
1336                         if (msg_entity.cvar_cl_voice_directional >= 1)
1337                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1338                         else
1339                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1340                         break;
1341                 case VOICETYPE_PLAYERSOUND:
1342                         msg_entity = self;
1343                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1344                         break;
1345                 default:
1346                         backtrace("Invalid voice type!");
1347                         break;
1348         }
1349 }
1350
1351 void GlobalSound(string sample, float chan, float voicetype)
1352 {
1353         float n;
1354         float tauntrand;
1355
1356         if(sample == "")
1357                 return;
1358
1359         tokenize_console(sample);
1360         n = stof(argv(1));
1361         if(n > 0)
1362                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1363         else
1364                 sample = strcat(argv(0), ".wav"); // randomization
1365
1366         switch(voicetype)
1367         {
1368                 case VOICETYPE_LASTATTACKER_ONLY:
1369                         if(self.pusher)
1370                         {
1371                                 msg_entity = self.pusher;
1372                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1373                                 {
1374                                         if(msg_entity.cvar_cl_voice_directional == 1)
1375                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1376                                         else
1377                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1378                                 }
1379                         }
1380                         break;
1381                 case VOICETYPE_LASTATTACKER:
1382                         if(self.pusher)
1383                         {
1384                                 msg_entity = self.pusher;
1385                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1386                                 {
1387                                         if(msg_entity.cvar_cl_voice_directional == 1)
1388                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1389                                         else
1390                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1391                                 }
1392                                 msg_entity = self;
1393                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1394                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1395                         }
1396                         break;
1397                 case VOICETYPE_TEAMRADIO:
1398                         FOR_EACH_REALCLIENT(msg_entity)
1399                                 if(!teams_matter || msg_entity.team == self.team)
1400                                 {
1401                                         if(msg_entity.cvar_cl_voice_directional == 1)
1402                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1403                                         else
1404                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1405                                 }
1406                         break;
1407                 case VOICETYPE_AUTOTAUNT:
1408                         if(!sv_autotaunt)
1409                                 break;
1410                         if(!sv_taunt)
1411                                 break;
1412                         if(sv_gentle)
1413                                 break;
1414                         tauntrand = random();
1415                         FOR_EACH_REALCLIENT(msg_entity)
1416                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1417                                 {
1418                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1419                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1420                                         else
1421                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1422                                 }
1423                         break;
1424                 case VOICETYPE_TAUNT:
1425                         if(self.classname == "player")
1426                                 if(self.deadflag == DEAD_NO)
1427                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1428                         if(!sv_taunt)
1429                                 break;
1430                         if(sv_gentle)
1431                                 break;
1432                         FOR_EACH_REALCLIENT(msg_entity)
1433                         {
1434                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1435                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1436                                 else
1437                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1438                         }
1439                         break;
1440                 case VOICETYPE_PLAYERSOUND:
1441                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1442                         break;
1443                 default:
1444                         backtrace("Invalid voice type!");
1445                         break;
1446         }
1447 }
1448
1449 void PlayerSound(.string samplefield, float chan, float voicetype)
1450 {
1451         GlobalSound(self.samplefield, chan, voicetype);
1452 }
1453
1454 void VoiceMessage(string type, string msg)
1455 {
1456         var .string sample;
1457         float voicetype, ownteam;
1458         float flood;
1459         sample = GetVoiceMessageSampleField(type);
1460
1461         if(GetPlayerSoundSampleField_notFound)
1462         {
1463                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1464                 return;
1465         }
1466
1467         voicetype = GetVoiceMessageVoiceType(type);
1468         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1469
1470         flood = Say(self, ownteam, world, msg, 1);
1471
1472         if (flood > 0)
1473                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1474         else if (flood < 0)
1475                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1476 }
1477
1478 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1479 {
1480 //      show_message
1481 //      0 (00) automove centerprint, admin message
1482 //      1 (01) automove centerprint, no admin message
1483 //      2 (10) no centerprint, admin message
1484 //      3 (11) no centerprint, no admin message
1485
1486         float lockteams_backup;
1487
1488         lockteams_backup = lockteams;  // backup any team lock
1489
1490         lockteams = 0;  // disable locked teams
1491
1492         TeamchangeFrags(client);  // move the players frags
1493         SetPlayerColors(client, team_colour - 1);  // set the players colour
1494         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1495
1496         lockteams = lockteams_backup;  // restore the team lock
1497
1498         LogTeamchange(client.playerid, client.team, type);
1499
1500         if not(show_message & 1) // admin message
1501                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1502
1503         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1504 }