qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.iscreature = oldself.iscreature;
 138         self.damagedbycontents = oldself.damagedbycontents;
 139         self.angles = oldself.angles;
 140         self.avelocity = oldself.avelocity;
 141         self.classname = "body";
 142         self.damageforcescale = oldself.damageforcescale;
 143         self.effects = oldself.effects;
 144         self.glowmod = oldself.glowmod;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.skin = oldself.skin;
 162         self.species = oldself.species;
 163         self.movetype = oldself.movetype;
 164         self.nextthink = oldself.nextthink;
 165         self.solid = oldself.solid;
 166         self.ballistics_density = oldself.ballistics_density;
 167         self.takedamage = oldself.takedamage;
 168         self.think = oldself.think;
 169         self.customizeentityforclient = oldself.customizeentityforclient;
 170         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 171         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 172         if (keepvelocity == 1)
 173                 self.velocity = oldself.velocity;
 174         self.oldvelocity = self.velocity;
 175         self.fade_time = oldself.fade_time;
 176         self.fade_rate = oldself.fade_rate;
 177         //self.weapon = oldself.weapon;
 178         setorigin(self, oldself.origin);
 179         setsize(self, oldself.mins, oldself.maxs);
 180         self.prevorigin = oldself.origin;
 181         self.reset = SUB_Remove;
 182
 183         Drag_MoveDrag(oldself, self);
 184
 185         if(self.colormap <= maxclients && self.colormap > 0)
 186                 self.colormap = 1024 + self.clientcolors;
 187
 188         self = oldself;
 189 }
 190
 191 float player_getspecies()
 192 {
 193         float s;
 194         get_model_parameters(self.model, self.skin);
 195         s = get_model_parameters_species;
 196         get_model_parameters(string_null, 0);
 197         if(s < 0)
 198                 return SPECIES_HUMAN;
 199         return s;
 200 }
 201
 202 void player_setupanimsformodel()
 203 {
 204         // defaults for legacy .zym models without animinfo files
 205         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 206         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 207         self.anim_draw = animfixfps(self, '2 1 3');
 208         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 209         self.anim_duckwalk = animfixfps(self, '4 1 1');
 210         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 211         self.anim_duckidle = animfixfps(self, '6 1 1');
 212         self.anim_idle = animfixfps(self, '7 1 1');
 213         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 214         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 215         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 216         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 217         self.anim_taunt = animfixfps(self, '12 1 0.33');
 218         self.anim_run = animfixfps(self, '13 1 1');
 219         self.anim_runbackwards = animfixfps(self, '14 1 1');
 220         self.anim_strafeleft = animfixfps(self, '15 1 1');
 221         self.anim_straferight = animfixfps(self, '16 1 1');
 222         self.anim_dead1 = animfixfps(self, '17 1 1');
 223         self.anim_dead2 = animfixfps(self, '18 1 1');
 224         self.anim_forwardright = animfixfps(self, '19 1 1');
 225         self.anim_forwardleft = animfixfps(self, '20 1 1');
 226         self.anim_backright = animfixfps(self, '21 1 1');
 227         self.anim_backleft  = animfixfps(self, '22 1 1');
 228         self.anim_melee = animfixfps2(self, '23 1 1', '11 1 5');
 229         self.anim_duckwalkbackwards = animfixfps2(self, '24 1 1', '4 1 1');
 230         self.anim_duckwalkstrafeleft = animfixfps2(self, '25 1 1', '4 1 1');
 231         self.anim_duckwalkstraferight = animfixfps2(self, '26 1 1', '4 1 1');
 232         self.anim_duckwalkforwardright = animfixfps2(self, '27 1 1', '4 1 1');
 233         self.anim_duckwalkforwardleft = animfixfps2(self, '28 1 1', '4 1 1');
 234         self.anim_duckwalkbackright = animfixfps2(self, '29 1 1', '4 1 1');
 235         self.anim_duckwalkbackleft  = animfixfps2(self, '30 1 1', '4 1 1');
 236         // TODO introspect models for finding right "fps" value (1/duration)
 237         // reset animstate now
 238         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 239 }
 240
 241 void player_anim (void)
 242 {
 243         updateanim(self);
 244         if (self.weaponentity)
 245                 updateanim(self.weaponentity);
 246
 247         if (self.deadflag != DEAD_NO)
 248         {
 249                 if (time > self.animstate_endtime)
 250                 {
 251                         if (self.maxs_z > 5)
 252                         {
 253                                 self.maxs_z = 5;
 254                                 setsize(self, self.mins, self.maxs);
 255                         }
 256                         self.frame = self.dead_frame;
 257                 }
 258                 return;
 259         }
 260
 261         if (!self.animstate_override)
 262         {
 263                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 264                 {
 265                         if (self.crouch)
 266                         {
 267                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 268                                 {
 269                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 270                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 271                                         {
 272                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 273                                                 self.restart_jump = FALSE;
 274                                         }
 275                                 }
 276                         }
 277                         else
 278                         {
 279                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 280                 {
 281                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 282                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 283                     {
 284                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 285                         self.restart_jump = FALSE;
 286                     }
 287                 }
 288                         }
 289                 }
 290                 else if (self.crouch)
 291                 {
 292                         if (self.movement_x > 0 && self.movement_y == 0)
 293                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 294                         else if (self.movement_x < 0 && self.movement_y == 0)
 295                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 296                         else if (self.movement_x == 0 && self.movement_y > 0)
 297                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 298                         else if (self.movement_x == 0 && self.movement_y < 0)
 299                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x > 0 && self.movement_y > 0)
 301                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x > 0 && self.movement_y < 0)
 303                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x < 0 && self.movement_y > 0)
 305                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x < 0 && self.movement_y < 0)
 307                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 308                         else
 309                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 310                 }
 311                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 312                 {
 313                         if (self.movement_x > 0 && self.movement_y == 0)
 314                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x < 0 && self.movement_y == 0)
 316                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x == 0 && self.movement_y > 0)
 318                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x == 0 && self.movement_y < 0)
 320                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x > 0 && self.movement_y > 0)
 322                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 323                         else if (self.movement_x > 0 && self.movement_y < 0)
 324                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 325                         else if (self.movement_x < 0 && self.movement_y > 0)
 326                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 327                         else if (self.movement_x < 0 && self.movement_y < 0)
 328                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 329                         else
 330                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 331                 }
 332                 else
 333                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 334         }
 335
 336         if (self.weaponentity)
 337         if (!self.weaponentity.animstate_override)
 338                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 339 }
 340
 341 void SpawnThrownWeapon (vector org, float w)
 342 {
 343         if(g_minstagib)
 344         if(self.ammo_cells <= 0)
 345                 return;
 346
 347         if(g_pinata)
 348         {
 349                 float j;
 350                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 351                 {
 352                         if(self.weapons & W_WeaponBit(j))
 353                                 if(W_IsWeaponThrowable(j))
 354                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 355                 }
 356         }
 357         else
 358         {
 359                 if(W_IsWeaponThrowable(self.weapon))
 360                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 361         }
 362 }
 363
 364 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 365 {
 366         float take, save;
 367         vector v;
 368         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 369
 370         // damage resistance (ignore most of the damage from a bullet or similar)
 371         damage = max(damage - 5, 1);
 372
 373         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 374         take = v_x;
 375         save = v_y;
 376
 377         if(sound_allowed(MSG_BROADCAST, attacker))
 378         {
 379                 if (save > 10)
 380                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 381                 else if (take > 30)
 382                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 383                 else if (take > 10)
 384                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 385         }
 386
 387         if (take > 50)
 388                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 389         if (take > 100)
 390                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 391
 392         if (!(self.flags & FL_GODMODE))
 393         {
 394                 self.armorvalue = self.armorvalue - save;
 395                 self.health = self.health - take;
 396                 // pause regeneration for 5 seconds
 397                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 398         }
 399         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 400         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 401         self.dmg_inflictor = inflictor;
 402
 403         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 404         {
 405                 // don't use any animations as a gib
 406                 self.frame = 0;
 407                 self.dead_frame = 0;
 408                 // view just above the floor
 409                 self.view_ofs = '0 0 4';
 410
 411                 Violence_GibSplash(self, 1, 1, attacker);
 412                 self.modelindex = 0; // restore later
 413                 self.solid = SOLID_NOT; // restore later
 414         }
 415 }
 416
 417 void ClientKill_Now_TeamChange();
 418 void freezetag_CheckWinner();
 419
 420 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 421 {
 422         float take, save, waves, sdelay, dh, da, j;
 423         vector v;
 424         float valid_damage_for_weaponstats;
 425         float excess;
 426
 427         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 428                 return;
 429
 430         dh = max(self.health, 0);
 431         da = max(self.armorvalue, 0);
 432
 433         if(!DEATH_ISSPECIAL(deathtype))
 434         {
 435                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 436                 if(self != attacker)
 437                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 438         }
 439
 440         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 441         {
 442                 // tuba causes blood to come out of the ears
 443                 vector ear1, ear2;
 444                 vector d;
 445                 float f;
 446                 ear1 = self.origin;
 447                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 448                 ear2 = ear1;
 449                 makevectors(self.angles);
 450                 ear1 += v_right * -10;
 451                 ear2 += v_right * +10;
 452                 d = inflictor.origin - self.origin;
 453                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 454                 force = v_right * vlen(force);
 455                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 456                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 457                 if(f > 0)
 458                 {
 459                         hitloc = ear1;
 460                         force = force * -1;
 461                 }
 462                 else
 463                 {
 464                         hitloc = ear2;
 465                         // force is already good
 466                 }
 467         }
 468         else
 469                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 470
 471         if (!g_minstagib)
 472         {
 473                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 474                 take = v_x;
 475                 save = v_y;
 476         }
 477         else
 478         {
 479                 save = 0;
 480                 take = damage;
 481         }
 482
 483         frag_inflictor = inflictor;
 484         frag_attacker = attacker;
 485         frag_target = self;
 486         damage_take = take;
 487         damage_save = save;
 488         damage_force = force;
 489         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 490         take = bound(0, damage_take, self.health);
 491         save = bound(0, damage_save, self.armorvalue);
 492         excess = max(0, damage - take - save);
 493
 494         if(sound_allowed(MSG_BROADCAST, attacker))
 495         {
 496                 if (save > 10)
 497                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 498                 else if (take > 30)
 499                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 500                 else if (take > 10)
 501                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 502         }
 503
 504         if (take > 50)
 505                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 506         if (take > 100)
 507                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 508
 509         if (time >= self.spawnshieldtime)
 510         {
 511                 if (!(self.flags & FL_GODMODE))
 512                 {
 513                         self.armorvalue = self.armorvalue - save;
 514                         self.health = self.health - take;
 515                         // pause regeneration for 5 seconds
 516                         if(take)
 517                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 518
 519                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 520                         {
 521                                 self.pain_finished = time + 0.5;        //Supajoe
 522
 523                                 if(sv_gentle < 1) {
 524                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 525                                         {
 526                                                 if (!self.animstate_override)
 527                                                 {
 528                                                         if (random() > 0.5)
 529                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 530                                                         else
 531                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 532                                                 }
 533                                         }
 534
 535                                         if(sound_allowed(MSG_BROADCAST, attacker))
 536                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 537                                         if(self.health > 1)
 538                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 539                                         {
 540                                                 if(deathtype == DEATH_FALL)
 541                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 542                                                 else if(self.health > 75) // TODO make a "gentle" version?
 543                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 544                                                 else if(self.health > 50)
 545                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 546                                                 else if(self.health > 25)
 547                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 548                                                 else
 549                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 550                                         }
 551                                 }
 552
 553                                 // throw off bot aim temporarily
 554                                 float shake;
 555                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 556                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 557                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 558                         }
 559                 }
 560                 else
 561                         self.max_armorvalue += (save + take);
 562         }
 563         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 564         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 565         self.dmg_inflictor = inflictor;
 566
 567         if(attacker == self)
 568         {
 569                 // don't reset pushltime for self damage as it may be an attempt to
 570                 // escape a lava pit or similar
 571                 //self.pushltime = 0;
 572         }
 573         else if(attacker.classname == "player")
 574         {
 575                 self.pusher = attacker;
 576                 self.pushltime = time + autocvar_g_maxpushtime;
 577         }
 578         else if(time < self.pushltime)
 579         {
 580                 attacker = self.pusher;
 581                 self.pushltime = max(self.pushltime, time + 0.6);
 582         }
 583         else
 584                 self.pushltime = 0;
 585
 586         float abot, vbot, awep;
 587         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 588         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 589
 590         valid_damage_for_weaponstats = 0;
 591         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 592         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 593         if(attacker && self != attacker)
 594         if(IsDifferentTeam(self, attacker))
 595         {
 596                 if(DEATH_ISSPECIAL(deathtype))
 597                         awep = attacker.weapon;
 598                 else
 599                         awep = DEATH_WEAPONOF(deathtype);
 600                 valid_damage_for_weaponstats = 1;
 601         }
 602
 603         if(valid_damage_for_weaponstats)
 604         {
 605                 dh = dh - max(self.health, 0);
 606                 da = da - max(self.armorvalue, 0);
 607                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 608         }
 609
 610         if (self.health < 1)
 611         {
 612                 float defer_ClientKill_Now_TeamChange;
 613                 defer_ClientKill_Now_TeamChange = FALSE;
 614
 615                 if(self.alivetime)
 616                 {
 617                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 618                         self.alivetime = 0;
 619                 }
 620
 621                 if(valid_damage_for_weaponstats)
 622                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 623
 624                 if(sv_gentle < 1) // TODO make a "gentle" version?
 625                 if(sound_allowed(MSG_BROADCAST, attacker))
 626                 {
 627                         if(deathtype == DEATH_DROWN)
 628                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 629                         else
 630                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 631                 }
 632
 633                 // get rid of kill indicator
 634                 if(self.killindicator)
 635                 {
 636                         remove(self.killindicator);
 637                         self.killindicator = world;
 638                         if(self.killindicator_teamchange)
 639                                 defer_ClientKill_Now_TeamChange = TRUE;
 640
 641                         if(self.classname == "body")
 642                         if(deathtype == DEATH_KILL)
 643                         {
 644                                 // for the lemmings fans, a small harmless explosion
 645                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 646                         }
 647                 }
 648
 649                 if(!g_freezetag)
 650                 {
 651                         // become fully visible
 652                         self.alpha = 1;
 653                         // throw a weapon
 654                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 655                 }
 656
 657                 // print an obituary message
 658                 Obituary (attacker, inflictor, self, deathtype);
 659                 race_PreDie();
 660                 DropAllRunes(self);
 661
 662         // increment frag counter for used weapon type
 663         float w;
 664         w = DEATH_WEAPONOF(deathtype);
 665         if(WEP_VALID(w))
 666         if(self.classname == "player")
 667         if(self != attacker)
 668         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 669
 670                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 671                 {
 672                         PutClientInServer();
 673                         count_alive_players(); // re-count players
 674                         freezetag_CheckWinner();
 675                         return;
 676                 }
 677
 678                 frag_attacker = attacker;
 679                 frag_inflictor = inflictor;
 680                 frag_target = self;
 681                 MUTATOR_CALLHOOK(PlayerDies);
 682                 weapon_action(self.weapon, WR_PLAYERDEATH);
 683
 684                 RemoveGrapplingHook(self);
 685
 686                 if(self.flagcarried)
 687                 {
 688                         if(attacker.classname != "player")
 689                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 690                         else if(attacker.team == self.team)
 691                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 692                         else
 693                                 DropFlag(self.flagcarried, world, attacker);
 694                 }
 695                 if(self.ballcarried && g_nexball)
 696                         DropBall(self.ballcarried, self.origin, self.velocity);
 697                 Portal_ClearAllLater(self);
 698
 699                 if(clienttype(self) == CLIENTTYPE_REAL)
 700                 {
 701                         stuffcmd(self, "-zoom\n");
 702                         self.fixangle = TRUE;
 703                         //msg_entity = self;
 704                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 705                         //WriteAngle (MSG_ONE, self.v_angle_x);
 706                         //WriteAngle (MSG_ONE, self.v_angle_y);
 707                         //WriteAngle (MSG_ONE, 80);
 708                 }
 709
 710                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 711                         ClientKill_Now_TeamChange();
 712
 713                 if(g_arena)
 714                         Spawnqueue_Unmark(self);
 715
 716                 if(g_freezetag)
 717                         return;
 718
 719                 // when we get here, player actually dies
 720                 // clear waypoints (do this AFTER FreezeTag)
 721                 WaypointSprite_PlayerDead();
 722
 723                 // make the corpse upright (not tilted)
 724                 self.angles_x = 0;
 725                 self.angles_z = 0;
 726                 // don't spin
 727                 self.avelocity = '0 0 0';
 728                 // view from the floor
 729                 self.view_ofs = '0 0 -8';
 730                 // toss the corpse
 731                 self.movetype = MOVETYPE_TOSS;
 732                 // shootable corpse
 733                 self.solid = SOLID_CORPSE;
 734                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 735                 // don't stick to the floor
 736                 self.flags &~= FL_ONGROUND;
 737                 // dying animation
 738                 self.deadflag = DEAD_DYING;
 739                 // when to allow respawn
 740                 sdelay = 0;
 741                 waves = 0;
 742                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 743                 if(!sdelay)
 744                 {
 745                         if(g_cts)
 746                                 sdelay = 0; // no respawn delay in CTS
 747                         else
 748                                 sdelay = autocvar_g_respawn_delay;
 749                 }
 750                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 751                 if(!waves)
 752                         waves = autocvar_g_respawn_waves;
 753                 if(waves)
 754                         self.death_time = ceil((time + sdelay) / waves) * waves;
 755                 else
 756                         self.death_time = time + sdelay;
 757                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 758                         self.respawn_countdown = 10; // first number to count down from is 10
 759                 else
 760                         self.respawn_countdown = -1; // do not count down
 761                 if (random() < 0.5)
 762                 {
 763                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 764                         self.dead_frame = self.anim_dead1_x;
 765                 }
 766                 else
 767                 {
 768                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 769                         self.dead_frame = self.anim_dead2_x;
 770                 }
 771                 // set damage function to corpse damage
 772                 self.event_damage = PlayerCorpseDamage;
 773                 // call the corpse damage function just in case it wants to gib
 774                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 775                 // set up to fade out later
 776                 SUB_SetFade (self, time + 6 + random (), 1);
 777
 778                 if(sv_gentle > 0 || autocvar_ekg) {
 779                         // remove corpse
 780                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 781                 }
 782
 783                 // reset fields the weapons may use just in case
 784                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 785                 {
 786                         weapon_action(j, WR_RESETPLAYER);
 787                         ATTACK_FINISHED_FOR(self, j) = 0;
 788                 }
 789         }
 790 }
 791
 792 .float muted; // to be used by prvm_edictset server playernumber muted 1
 793 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 794 // message "": do not say, just test flood control
 795 // return value:
 796 //   1 = accept
 797 //   0 = reject
 798 //  -1 = fake accept
 799 {
 800         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 801         float flood, privatemsgprefixlen;
 802         var .float flood_field;
 803         entity head;
 804         float ret;
 805
 806         if(Ban_MaybeEnforceBan(source))
 807                 return 0;
 808
 809         if(!teamsay && !privatesay)
 810                 if(substring(msgin, 0, 1) == " ")
 811                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 812
 813         msgin = formatmessage(msgin);
 814
 815         if(source.classname != "player")
 816                 colorstr = "^0"; // black for spectators
 817         else if(teamplay)
 818                 colorstr = Team_ColorCode(source.team);
 819         else
 820                 teamsay = FALSE;
 821
 822         if(intermission_running)
 823                 teamsay = FALSE;
 824
 825         if(msgin != "")
 826                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 827
 828         /*
 829          * using bprint solves this... me stupid
 830         // how can we prevent the message from appearing in a listen server?
 831         // for now, just give "say" back and only handle say_team
 832         if(!teamsay)
 833         {
 834                 clientcommand(self, strcat("say ", msgin));
 835                 return;
 836         }
 837         */
 838
 839         if(autocvar_g_chat_teamcolors)
 840                 namestr = playername(source);
 841         else
 842                 namestr = source.netname;
 843
 844         if(msgin != "")
 845         {
 846                 if(privatesay)
 847                 {
 848                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 849                         privatemsgprefixlen = strlen(msgstr);
 850                         msgstr = strcat(msgstr, msgin);
 851                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 852                         if(autocvar_g_chat_teamcolors)
 853                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 854                         else
 855                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 856                 }
 857                 else if(teamsay)
 858                 {
 859                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 860                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 861                 }
 862                 else
 863                 {
 864                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 865                         cmsgstr = "";
 866                 }
 867                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 868         }
 869         else
 870         {
 871                 msgstr = cmsgstr = "";
 872         }
 873
 874         fullmsgstr = msgstr;
 875         fullcmsgstr = cmsgstr;
 876
 877         // FLOOD CONTROL
 878         flood = 0;
 879         if(floodcontrol)
 880         {
 881                 float flood_spl;
 882                 float flood_burst;
 883                 float flood_lmax;
 884                 float lines;
 885                 if(privatesay)
 886                 {
 887                         flood_spl = autocvar_g_chat_flood_spl_tell;
 888                         flood_burst = autocvar_g_chat_flood_burst_tell;
 889                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 890                         flood_field = floodcontrol_chattell;
 891                 }
 892                 else if(teamsay)
 893                 {
 894                         flood_spl = autocvar_g_chat_flood_spl_team;
 895                         flood_burst = autocvar_g_chat_flood_burst_team;
 896                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 897                         flood_field = floodcontrol_chatteam;
 898                 }
 899                 else
 900                 {
 901                         flood_spl = autocvar_g_chat_flood_spl;
 902                         flood_burst = autocvar_g_chat_flood_burst;
 903                         flood_lmax = autocvar_g_chat_flood_lmax;
 904                         flood_field = floodcontrol_chat;
 905                 }
 906                 flood_burst = max(0, flood_burst - 1);
 907                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 908
 909                 // do flood control for the default line size
 910                 if(msgstr != "")
 911                 {
 912                         getWrappedLine_remaining = msgstr;
 913                         msgstr = "";
 914                         lines = 0;
 915                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 916                         {
 917                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 918                                 ++lines;
 919                         }
 920                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 921
 922                         if(getWrappedLine_remaining != "")
 923                         {
 924                                 msgstr = strcat(msgstr, "\n");
 925                                 flood = 2;
 926                         }
 927
 928                         if(time >= source.flood_field)
 929                         {
 930                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 931                         }
 932                         else
 933                         {
 934                                 flood = 1;
 935                                 msgstr = fullmsgstr;
 936                         }
 937                 }
 938                 else
 939                 {
 940                         if(time >= source.flood_field)
 941                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 942                         else
 943                                 flood = 1;
 944                 }
 945
 946                 if (timeoutStatus == 2) //when game is paused, no flood protection
 947                         source.flood_field = flood = 0;
 948         }
 949
 950         if(flood == 2) // cannot happen for empty msgstr
 951         {
 952                 if(autocvar_g_chat_flood_notify_flooder)
 953                 {
 954                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 955                         sourcecmsgstr = "";
 956                 }
 957                 else
 958                 {
 959                         sourcemsgstr = fullmsgstr;
 960                         sourcecmsgstr = fullcmsgstr;
 961                 }
 962                 cmsgstr = "";
 963         }
 964         else
 965         {
 966                 sourcemsgstr = msgstr;
 967                 sourcecmsgstr = cmsgstr;
 968         }
 969
 970         if(!privatesay)
 971         if(source.classname != "player")
 972         {
 973                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 974                         teamsay = -1; // spectators
 975         }
 976
 977         if(flood)
 978                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 979
 980         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 981         if(privatesay)
 982                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 983
 984         if(source.muted)
 985         {
 986                 // always fake the message
 987                 ret = -1;
 988         }
 989         else if(flood == 1)
 990         {
 991                 if(autocvar_g_chat_flood_notify_flooder)
 992                 {
 993                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 994                         ret = 0;
 995                 }
 996                 else
 997                         ret = -1;
 998         }
 999         else
1000         {
1001                 ret = 1;
1002         }
1003
1004         if(sourcemsgstr != "" && ret != 0)
1005         {
1006                 if(ret < 0) // fake
1007                 {
1008                         sprint(source, sourcemsgstr);
1009                         if(sourcecmsgstr != "" && !privatesay)
1010                                 centerprint(source, sourcecmsgstr);
1011                 }
1012                 else if(privatesay)
1013                 {
1014                         sprint(source, sourcemsgstr);
1015                         sprint(privatesay, msgstr);
1016                         if(cmsgstr != "")
1017                                 centerprint(privatesay, cmsgstr);
1018                 }
1019                 else if(teamsay > 0)
1020                 {
1021                         sprint(source, sourcemsgstr);
1022                         if(sourcecmsgstr != "")
1023                                 centerprint(source, sourcecmsgstr);
1024                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1025                                 if(head != source)
1026                                 {
1027                                         sprint(head, msgstr);
1028                                         if(cmsgstr != "")
1029                                                 centerprint(head, cmsgstr);
1030                                 }
1031                 }
1032                 else if(teamsay < 0)
1033                 {
1034                         sprint(source, sourcemsgstr);
1035                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1036                                 if(head != source)
1037                                         sprint(head, msgstr);
1038                 }
1039                 else if(sourcemsgstr != msgstr)
1040                 {
1041                         sprint(source, sourcemsgstr);
1042                         FOR_EACH_REALCLIENT(head)
1043                                 if(head != source)
1044                                         sprint(head, msgstr);
1045                 }
1046                 else
1047                         bprint(msgstr);
1048         }
1049
1050         return ret;
1051 }
1052
1053 float GetVoiceMessageVoiceType(string type)
1054 {
1055         if(type == "taunt")
1056                 return VOICETYPE_TAUNT;
1057         if(type == "teamshoot")
1058                 return VOICETYPE_LASTATTACKER;
1059         return VOICETYPE_TEAMRADIO;
1060 }
1061
1062 string allvoicesamples;
1063 .string GetVoiceMessageSampleField(string type)
1064 {
1065         GetPlayerSoundSampleField_notFound = 0;
1066         switch(type)
1067         {
1068 #define _VOICEMSG(m) case #m: return playersound_##m;
1069                 ALLVOICEMSGS
1070 #undef _VOICEMSG
1071         }
1072         GetPlayerSoundSampleField_notFound = 1;
1073         return playersound_taunt;
1074 }
1075
1076 .string GetPlayerSoundSampleField(string type)
1077 {
1078         GetPlayerSoundSampleField_notFound = 0;
1079         switch(type)
1080         {
1081 #define _VOICEMSG(m) case #m: return playersound_##m;
1082                 ALLPLAYERSOUNDS
1083 #undef _VOICEMSG
1084         }
1085         GetPlayerSoundSampleField_notFound = 1;
1086         return playersound_taunt;
1087 }
1088
1089 void PrecacheGlobalSound(string samplestring)
1090 {
1091         float n, i;
1092         tokenize_console(samplestring);
1093         n = stof(argv(1));
1094         if(n > 0)
1095         {
1096                 for(i = 1; i <= n; ++i)
1097                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1098         }
1099         else
1100         {
1101                 precache_sound(strcat(argv(0), ".wav"));
1102         }
1103 }
1104
1105 void PrecachePlayerSounds(string f)
1106 {
1107         float fh;
1108         string s;
1109         fh = fopen(f, FILE_READ);
1110         if(fh < 0)
1111                 return;
1112         while((s = fgets(fh)))
1113         {
1114                 if(tokenize_console(s) != 3)
1115                 {
1116                         dprint("Invalid sound info line: ", s, "\n");
1117                         continue;
1118                 }
1119                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1120         }
1121         fclose(fh);
1122
1123         if not(allvoicesamples)
1124         {
1125 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1126                 ALLVOICEMSGS
1127 #undef _VOICEMSG
1128                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1129         }
1130 }
1131
1132 void ClearPlayerSounds()
1133 {
1134 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1135         ALLPLAYERSOUNDS
1136         ALLVOICEMSGS
1137 #undef _VOICEMSG
1138 }
1139
1140 float LoadPlayerSounds(string f, float first)
1141 {
1142         float fh;
1143         string s;
1144         var .string field;
1145         fh = fopen(f, FILE_READ);
1146         if(fh < 0)
1147         {
1148                 dprint("Player sound file not found: ", f, "\n");
1149                 return 0;
1150         }
1151         while((s = fgets(fh)))
1152         {
1153                 if(tokenize_console(s) != 3)
1154                         continue;
1155                 field = GetPlayerSoundSampleField(argv(0));
1156                 if(GetPlayerSoundSampleField_notFound)
1157                         field = GetVoiceMessageSampleField(argv(0));
1158                 if(GetPlayerSoundSampleField_notFound)
1159                         continue;
1160                 if(self.field)
1161                         strunzone(self.field);
1162                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1163         }
1164         fclose(fh);
1165         return 1;
1166 }
1167
1168 .float modelindex_for_playersound;
1169 .float skin_for_playersound;
1170 void UpdatePlayerSounds()
1171 {
1172         if(self.modelindex == self.modelindex_for_playersound)
1173         if(self.skin == self.skin_for_playersound)
1174                 return;
1175         self.modelindex_for_playersound = self.modelindex;
1176         self.skin_for_playersound = self.skin;
1177         ClearPlayerSounds();
1178         LoadPlayerSounds("sound/player/default.sounds", 1);
1179         if(!autocvar_g_debug_defaultsounds)
1180                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1181                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1182 }
1183
1184 void FakeGlobalSound(string sample, float chan, float voicetype)
1185 {
1186         float n;
1187         float tauntrand;
1188
1189         if(sample == "")
1190                 return;
1191
1192         tokenize_console(sample);
1193         n = stof(argv(1));
1194         if(n > 0)
1195                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1196         else
1197                 sample = strcat(argv(0), ".wav"); // randomization
1198
1199         switch(voicetype)
1200         {
1201                 case VOICETYPE_LASTATTACKER_ONLY:
1202                         break;
1203                 case VOICETYPE_LASTATTACKER:
1204                         if(self.pusher)
1205                         {
1206                                 msg_entity = self;
1207                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1208                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1209                         }
1210                         break;
1211                 case VOICETYPE_TEAMRADIO:
1212                         msg_entity = self;
1213                         if(msg_entity.cvar_cl_voice_directional == 1)
1214                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1215                         else
1216                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1217                         break;
1218                 case VOICETYPE_AUTOTAUNT:
1219                         if(!sv_autotaunt)
1220                                 break;
1221                         if(!sv_taunt)
1222                                 break;
1223                         if(sv_gentle)
1224                                 break;
1225                         tauntrand = random();
1226                         msg_entity = self;
1227                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1228                         {
1229                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1230                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1231                                 else
1232                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1233                         }
1234                         break;
1235                 case VOICETYPE_TAUNT:
1236                         if(self.classname == "player")
1237                                 if(self.deadflag == DEAD_NO)
1238                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1239                         if(!sv_taunt)
1240                                 break;
1241                         if(sv_gentle)
1242                                 break;
1243                         msg_entity = self;
1244                         if (msg_entity.cvar_cl_voice_directional >= 1)
1245                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1246                         else
1247                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1248                         break;
1249                 case VOICETYPE_PLAYERSOUND:
1250                         msg_entity = self;
1251                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1252                         break;
1253                 default:
1254                         backtrace("Invalid voice type!");
1255                         break;
1256         }
1257 }
1258
1259 void GlobalSound(string sample, float chan, float voicetype)
1260 {
1261         float n;
1262         float tauntrand;
1263
1264         if(sample == "")
1265                 return;
1266
1267         tokenize_console(sample);
1268         n = stof(argv(1));
1269         if(n > 0)
1270                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1271         else
1272                 sample = strcat(argv(0), ".wav"); // randomization
1273
1274         switch(voicetype)
1275         {
1276                 case VOICETYPE_LASTATTACKER_ONLY:
1277                         if(self.pusher)
1278                         {
1279                                 msg_entity = self.pusher;
1280                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1281                                 {
1282                                         if(msg_entity.cvar_cl_voice_directional == 1)
1283                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1284                                         else
1285                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1286                                 }
1287                         }
1288                         break;
1289                 case VOICETYPE_LASTATTACKER:
1290                         if(self.pusher)
1291                         {
1292                                 msg_entity = self.pusher;
1293                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1294                                 {
1295                                         if(msg_entity.cvar_cl_voice_directional == 1)
1296                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1297                                         else
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1299                                 }
1300                                 msg_entity = self;
1301                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1302                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1303                         }
1304                         break;
1305                 case VOICETYPE_TEAMRADIO:
1306                         FOR_EACH_REALCLIENT(msg_entity)
1307                                 if(!teamplay || msg_entity.team == self.team)
1308                                 {
1309                                         if(msg_entity.cvar_cl_voice_directional == 1)
1310                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1311                                         else
1312                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1313                                 }
1314                         break;
1315                 case VOICETYPE_AUTOTAUNT:
1316                         if(!sv_autotaunt)
1317                                 break;
1318                         if(!sv_taunt)
1319                                 break;
1320                         if(sv_gentle)
1321                                 break;
1322                         tauntrand = random();
1323                         FOR_EACH_REALCLIENT(msg_entity)
1324                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1325                                 {
1326                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1327                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1328                                         else
1329                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1330                                 }
1331                         break;
1332                 case VOICETYPE_TAUNT:
1333                         if(self.classname == "player")
1334                                 if(self.deadflag == DEAD_NO)
1335                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1336                         if(!sv_taunt)
1337                                 break;
1338                         if(sv_gentle)
1339                                 break;
1340                         FOR_EACH_REALCLIENT(msg_entity)
1341                         {
1342                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1343                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1344                                 else
1345                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1346                         }
1347                         break;
1348                 case VOICETYPE_PLAYERSOUND:
1349                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1350                         break;
1351                 default:
1352                         backtrace("Invalid voice type!");
1353                         break;
1354         }
1355 }
1356
1357 void PlayerSound(.string samplefield, float chan, float voicetype)
1358 {
1359         GlobalSound(self.samplefield, chan, voicetype);
1360 }
1361
1362 void VoiceMessage(string type, string msg)
1363 {
1364         var .string sample;
1365         float voicetype, ownteam;
1366         float flood;
1367         sample = GetVoiceMessageSampleField(type);
1368
1369         if(GetPlayerSoundSampleField_notFound)
1370         {
1371                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1372                 return;
1373         }
1374
1375         voicetype = GetVoiceMessageVoiceType(type);
1376         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1377
1378         flood = Say(self, ownteam, world, msg, 1);
1379
1380         if (flood > 0)
1381                 GlobalSound(self.sample, CH_VOICE, voicetype);
1382         else if (flood < 0)
1383                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1384 }
1385
1386 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1387 {
1388 //      show_message
1389 //      0 (00) automove centerprint, admin message
1390 //      1 (01) automove centerprint, no admin message
1391 //      2 (10) no centerprint, admin message
1392 //      3 (11) no centerprint, no admin message
1393
1394         float lockteams_backup;
1395
1396         lockteams_backup = lockteams;  // backup any team lock
1397
1398         lockteams = 0;  // disable locked teams
1399
1400         TeamchangeFrags(client);  // move the players frags
1401         SetPlayerColors(client, team_colour - 1);  // set the players colour
1402         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1403
1404         lockteams = lockteams_backup;  // restore the team lock
1405
1406         LogTeamchange(client.playerid, client.team, type);
1407
1408         if not(show_message & 1) // admin message
1409                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1410
1411         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1412 }