qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         local entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.glowmod = oldself.glowmod;
 138         self.iscreature = oldself.iscreature;
 139         self.damagedbycontents = oldself.damagedbycontents;
 140         self.angles = oldself.angles;
 141         self.avelocity = oldself.avelocity;
 142         self.classname = "body";
 143         self.damageforcescale = oldself.damageforcescale;
 144         self.effects = oldself.effects;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.modelindex_lod0 = oldself.modelindex_lod0;
 162         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 163         self.modelindex_lod1 = oldself.modelindex_lod1;
 164         self.modelindex_lod2 = oldself.modelindex_lod2;
 165         self.skinindex = oldself.skinindex;
 166         self.species = oldself.species;
 167         self.movetype = oldself.movetype;
 168         self.nextthink = oldself.nextthink;
 169         self.solid = oldself.solid;
 170         self.ballistics_density = oldself.ballistics_density;
 171         self.takedamage = oldself.takedamage;
 172         self.think = oldself.think;
 173         self.customizeentityforclient = oldself.customizeentityforclient;
 174         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 175         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 176         if (keepvelocity == 1)
 177                 self.velocity = oldself.velocity;
 178         self.oldvelocity = self.velocity;
 179         self.fade_time = oldself.fade_time;
 180         self.fade_rate = oldself.fade_rate;
 181         //self.weapon = oldself.weapon;
 182         setorigin(self, oldself.origin);
 183         setsize(self, oldself.mins, oldself.maxs);
 184         self.prevorigin = oldself.origin;
 185         self.reset = SUB_Remove;
 186
 187         Drag_MoveDrag(oldself, self);
 188
 189         self = oldself;
 190 }
 191
 192 float player_getspecies()
 193 {
 194         float s;
 195         get_model_parameters(self.model, self.skinindex);
 196         s = get_model_parameters_species;
 197         get_model_parameters(string_null, 0);
 198         if(s < 0)
 199                 return SPECIES_HUMAN;
 200         return s;
 201 }
 202
 203 void player_setupanimsformodel()
 204 {
 205         local string animfilename;
 206         local float animfile;
 207         // defaults for legacy .zym models without animinfo files
 208         self.anim_die1 = '0 1 0.5'; // 2 seconds
 209         self.anim_die2 = '1 1 0.5'; // 2 seconds
 210         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 211         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 212         self.anim_duckwalk = '4 1 1';
 213         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 214         self.anim_duckidle = '6 1 1';
 215         self.anim_idle = '7 1 1';
 216         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 217         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 218         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 219         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 220         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 221         self.anim_run = '13 1 1';
 222         self.anim_runbackwards = '14 1 1';
 223         self.anim_strafeleft = '15 1 1';
 224         self.anim_straferight = '16 1 1';
 225         self.anim_dead1 = '17 1 1';
 226         self.anim_dead2 = '18 1 1';
 227         self.anim_forwardright = '19 1 1';
 228         self.anim_forwardleft = '20 1 1';
 229         self.anim_backright = '21 1 1';
 230         self.anim_backleft  = '22 1 1';
 231         self.anim_melee = '23 1 1';
 232         animparseerror = FALSE;
 233         animfilename = strcat(self.model, ".animinfo");
 234         animfile = fopen(animfilename, FILE_READ);
 235         if (animfile >= 0)
 236         {
 237                 self.anim_die1         = animparseline(animfile);
 238                 self.anim_die2         = animparseline(animfile);
 239                 self.anim_draw         = animparseline(animfile);
 240                 self.anim_duck         = animparseline(animfile);
 241                 self.anim_duckwalk     = animparseline(animfile);
 242                 self.anim_duckjump     = animparseline(animfile);
 243                 self.anim_duckidle     = animparseline(animfile);
 244                 self.anim_idle         = animparseline(animfile);
 245                 self.anim_jump         = animparseline(animfile);
 246                 self.anim_pain1        = animparseline(animfile);
 247                 self.anim_pain2        = animparseline(animfile);
 248                 self.anim_shoot        = animparseline(animfile);
 249                 self.anim_taunt        = animparseline(animfile);
 250                 self.anim_run          = animparseline(animfile);
 251                 self.anim_runbackwards = animparseline(animfile);
 252                 self.anim_strafeleft   = animparseline(animfile);
 253                 self.anim_straferight  = animparseline(animfile);
 254                 self.anim_forwardright = animparseline(animfile);
 255                 self.anim_forwardleft  = animparseline(animfile);
 256                 self.anim_backright    = animparseline(animfile);
 257                 self.anim_backleft     = animparseline(animfile);
 258                 self.anim_melee        = animparseline(animfile);
 259                 fclose(animfile);
 260
 261                 // derived anims
 262                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 263                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 264
 265                 if (animparseerror)
 266                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 267         }
 268         else
 269                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 270         // reset animstate now
 271         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 272 };
 273
 274 void player_anim (void)
 275 {
 276         updateanim(self);
 277         if (self.weaponentity)
 278                 updateanim(self.weaponentity);
 279
 280         if (self.deadflag != DEAD_NO)
 281         {
 282                 if (time > self.animstate_endtime)
 283                 {
 284                         if (self.maxs_z > 5)
 285                         {
 286                                 self.maxs_z = 5;
 287                                 setsize(self, self.mins, self.maxs);
 288                         }
 289                         self.frame = self.dead_frame;
 290                 }
 291                 return;
 292         }
 293
 294         if (!self.animstate_override)
 295         {
 296                 if (!(self.flags & FL_ONGROUND))
 297                 {
 298                         if (self.crouch)
 299                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 300                         else
 301                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 302                         self.restart_jump = FALSE;
 303                 }
 304                 else if (self.crouch)
 305                 {
 306                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 307                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 308                         else
 309                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 310                 }
 311                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 312                 {
 313                         if (self.movement_x > 0 && self.movement_y == 0)
 314                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x < 0 && self.movement_y == 0)
 316                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x == 0 && self.movement_y > 0)
 318                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x == 0 && self.movement_y < 0)
 320                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x > 0 && self.movement_y > 0)
 322                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 323                         else if (self.movement_x > 0 && self.movement_y < 0)
 324                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 325                         else if (self.movement_x < 0 && self.movement_y > 0)
 326                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 327                         else if (self.movement_x < 0 && self.movement_y < 0)
 328                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 329                         else
 330                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 331                 }
 332                 else
 333                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 334         }
 335
 336         if (self.weaponentity)
 337         if (!self.weaponentity.animstate_override)
 338                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 339 }
 340
 341 void SpawnThrownWeapon (vector org, float w)
 342 {
 343         if(g_minstagib)
 344         if(self.ammo_cells <= 0)
 345                 return;
 346
 347         if(g_pinata)
 348         {
 349                 float j;
 350                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 351                 {
 352                         if(self.weapons & W_WeaponBit(j))
 353                                 if(W_IsWeaponThrowable(j))
 354                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 355                 }
 356         }
 357         else
 358         {
 359                 if(W_IsWeaponThrowable(self.weapon))
 360                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 361         }
 362 }
 363
 364 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 365 {
 366         local float take, save;
 367         vector v;
 368         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 369
 370         // damage resistance (ignore most of the damage from a bullet or similar)
 371         damage = max(damage - 5, 1);
 372
 373         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 374         take = v_x;
 375         save = v_y;
 376
 377         if(sound_allowed(MSG_BROADCAST, attacker))
 378         {
 379                 if (save > 10)
 380                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 381                 else if (take > 30)
 382                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 383                 else if (take > 10)
 384                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 385         }
 386
 387         if (take > 50)
 388                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 389         if (take > 100)
 390                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 391
 392         if (!(self.flags & FL_GODMODE))
 393         {
 394                 self.armorvalue = self.armorvalue - save;
 395                 self.health = self.health - take;
 396                 // pause regeneration for 5 seconds
 397                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 398         }
 399         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 400         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 401         self.dmg_inflictor = inflictor;
 402
 403         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 404         {
 405                 // don't use any animations as a gib
 406                 self.frame = 0;
 407                 self.dead_frame = 0;
 408                 // view just above the floor
 409                 self.view_ofs = '0 0 4';
 410
 411                 Violence_GibSplash(self, 1, 1, attacker);
 412                 self.modelindex = 0; // restore later
 413                 self.solid = SOLID_NOT; // restore later
 414         }
 415 }
 416
 417 void ClientKill_Now_TeamChange();
 418 void freezetag_CheckWinner();
 419
 420 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 421 {
 422         local float take, save, waves, sdelay, dh, da, j;
 423         vector v;
 424         float valid_damage_for_weaponstats;
 425         float excess;
 426
 427         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 428                 return;
 429
 430         dh = max(self.health, 0);
 431         da = max(self.armorvalue, 0);
 432
 433         if(!DEATH_ISSPECIAL(deathtype))
 434         {
 435                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 436                 if(self != attacker)
 437                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 438         }
 439
 440         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 441         {
 442                 // tuba causes blood to come out of the ears
 443                 vector ear1, ear2;
 444                 vector d;
 445                 float f;
 446                 ear1 = self.origin;
 447                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 448                 ear2 = ear1;
 449                 makevectors(self.angles);
 450                 ear1 += v_right * -10;
 451                 ear2 += v_right * +10;
 452                 d = inflictor.origin - self.origin;
 453                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 454                 force = v_right * vlen(force);
 455                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 456                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 457                 if(f > 0)
 458                 {
 459                         hitloc = ear1;
 460                         force = force * -1;
 461                 }
 462                 else
 463                 {
 464                         hitloc = ear2;
 465                         // force is already good
 466                 }
 467         }
 468         else
 469                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 470
 471         if (!g_minstagib)
 472         {
 473                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 474                 take = v_x;
 475                 save = v_y;
 476         }
 477         else
 478         {
 479                 save = 0;
 480                 take = damage;
 481         }
 482
 483         frag_inflictor = inflictor;
 484         frag_attacker = attacker;
 485         frag_target = self;
 486         damage_take = take;
 487         damage_save = save;
 488         damage_force = force;
 489         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 490         take = bound(0, damage_take, self.health);
 491         save = bound(0, damage_save, self.armorvalue);
 492         excess = max(0, damage - take - save);
 493
 494         if(sound_allowed(MSG_BROADCAST, attacker))
 495         {
 496                 if (save > 10)
 497                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 498                 else if (take > 30)
 499                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 500                 else if (take > 10)
 501                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 502         }
 503
 504         if (take > 50)
 505                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 506         if (take > 100)
 507                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 508
 509         if (time >= self.spawnshieldtime)
 510         {
 511                 if (!(self.flags & FL_GODMODE))
 512                 {
 513                         self.armorvalue = self.armorvalue - save;
 514                         self.health = self.health - take;
 515                         // pause regeneration for 5 seconds
 516                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 517
 518                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 519                         {
 520                                 self.pain_finished = time + 0.5;        //Supajoe
 521
 522                                 if(sv_gentle < 1) {
 523                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 524                                         {
 525                                                 if (random() > 0.5)
 526                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 527                                                 else
 528                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 529                                         }
 530
 531                                         if(sound_allowed(MSG_BROADCAST, attacker))
 532                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 533                                         if(self.health > 1)
 534                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 535                                         {
 536                                                 if(deathtype == DEATH_FALL)
 537                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 538                                                 else if(self.health > 75) // TODO make a "gentle" version?
 539                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 540                                                 else if(self.health > 50)
 541                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 542                                                 else if(self.health > 25)
 543                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 544                                                 else
 545                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 546                                         }
 547                                 }
 548
 549                                 // throw off bot aim temporarily
 550                                 local float shake;
 551                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 552                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 553                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 554                         }
 555                 }
 556                 else
 557                         self.max_armorvalue += (save + take);
 558         }
 559         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 560         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 561         self.dmg_inflictor = inflictor;
 562
 563         if(attacker == self)
 564         {
 565                 // don't reset pushltime for self damage as it may be an attempt to
 566                 // escape a lava pit or similar
 567                 //self.pushltime = 0;
 568         }
 569         else if(attacker.classname == "player")
 570         {
 571                 self.pusher = attacker;
 572                 self.pushltime = time + autocvar_g_maxpushtime;
 573         }
 574         else if(time < self.pushltime)
 575         {
 576                 attacker = self.pusher;
 577                 self.pushltime = max(self.pushltime, time + 0.6);
 578         }
 579         else
 580                 self.pushltime = 0;
 581
 582         float abot, vbot, awep;
 583         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 584         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 585
 586         valid_damage_for_weaponstats = 0;
 587         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 588         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 589         if(attacker && self != attacker)
 590         if(IsDifferentTeam(self, attacker))
 591         {
 592                 if(DEATH_ISSPECIAL(deathtype))
 593                         awep = attacker.weapon;
 594                 else
 595                         awep = DEATH_WEAPONOF(deathtype);
 596                 valid_damage_for_weaponstats = 1;
 597         }
 598
 599         if(valid_damage_for_weaponstats)
 600         {
 601                 dh = dh - max(self.health, 0);
 602                 da = da - max(self.armorvalue, 0);
 603                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 604         }
 605
 606         if (self.health < 1)
 607         {
 608                 float defer_ClientKill_Now_TeamChange;
 609                 defer_ClientKill_Now_TeamChange = FALSE;
 610
 611                 if(self.alivetime)
 612                 {
 613                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 614                         self.alivetime = 0;
 615                 }
 616
 617                 if(valid_damage_for_weaponstats)
 618                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 619
 620                 if(sv_gentle < 1) // TODO make a "gentle" version?
 621                 if(sound_allowed(MSG_BROADCAST, attacker))
 622                 {
 623                         if(deathtype == DEATH_DROWN)
 624                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 625                         else
 626                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 627                 }
 628
 629                 // get rid of kill indicator
 630                 if(self.killindicator)
 631                 {
 632                         remove(self.killindicator);
 633                         self.killindicator = world;
 634                         if(self.killindicator_teamchange)
 635                                 defer_ClientKill_Now_TeamChange = TRUE;
 636
 637                         if(self.classname == "body")
 638                         if(deathtype == DEATH_KILL)
 639                         {
 640                                 // for the lemmings fans, a small harmless explosion
 641                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 642                         }
 643                 }
 644
 645                 if(!g_freezetag)
 646                 {
 647                         // become fully visible
 648                         self.alpha = 1;
 649                         // throw a weapon
 650                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 651                 }
 652
 653                 // print an obituary message
 654                 Obituary (attacker, inflictor, self, deathtype);
 655                 race_PreDie();
 656                 DropAllRunes(self);
 657
 658         // increment frag counter for used weapon type
 659         float w;
 660         w = DEATH_WEAPONOF(deathtype);
 661         if(WEP_VALID(w))
 662         if(self.classname == "player")
 663         if(self != attacker)
 664         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 665
 666                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 667                 {
 668                         PutClientInServer();
 669                         count_alive_players(); // re-count players
 670                         freezetag_CheckWinner();
 671                         return;
 672                 }
 673
 674                 frag_attacker = attacker;
 675                 frag_inflictor = inflictor;
 676                 frag_target = self;
 677                 MUTATOR_CALLHOOK(PlayerDies);
 678                 weapon_action(self.weapon, WR_PLAYERDEATH);
 679
 680                 if(self.flagcarried)
 681                 {
 682                         if(attacker.classname != "player")
 683                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 684                         else if(attacker.team == self.team)
 685                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 686                         else
 687                                 DropFlag(self.flagcarried, world, attacker);
 688                 }
 689                 if(self.ballcarried && g_nexball)
 690                         DropBall(self.ballcarried, self.origin, self.velocity);
 691                 Portal_ClearAllLater(self);
 692
 693                 if(clienttype(self) == CLIENTTYPE_REAL)
 694                 {
 695                         stuffcmd(self, "-zoom\n");
 696                         self.fixangle = TRUE;
 697                         //msg_entity = self;
 698                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 699                         //WriteAngle (MSG_ONE, self.v_angle_x);
 700                         //WriteAngle (MSG_ONE, self.v_angle_y);
 701                         //WriteAngle (MSG_ONE, 80);
 702                 }
 703
 704                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 705                         ClientKill_Now_TeamChange();
 706
 707                 if(g_arena)
 708                         Spawnqueue_Unmark(self);
 709
 710                 if(g_freezetag)
 711                         return;
 712
 713                 // when we get here, player actually dies
 714                 // clear waypoints (do this AFTER FreezeTag)
 715                 WaypointSprite_PlayerDead();
 716
 717                 // make the corpse upright (not tilted)
 718                 self.angles_x = 0;
 719                 self.angles_z = 0;
 720                 // don't spin
 721                 self.avelocity = '0 0 0';
 722                 // view from the floor
 723                 self.view_ofs = '0 0 -8';
 724                 // toss the corpse
 725                 self.movetype = MOVETYPE_TOSS;
 726                 // shootable corpse
 727                 self.solid = SOLID_CORPSE;
 728                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 729                 // don't stick to the floor
 730                 self.flags &~= FL_ONGROUND;
 731                 // dying animation
 732                 self.deadflag = DEAD_DYING;
 733                 // when to allow respawn
 734                 sdelay = 0;
 735                 waves = 0;
 736                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 737                 if(!sdelay)
 738                 {
 739                         if(g_cts)
 740                                 sdelay = 0; // no respawn delay in CTS
 741                         else
 742                                 sdelay = autocvar_g_respawn_delay;
 743                 }
 744                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 745                 if(!waves)
 746                         waves = autocvar_g_respawn_waves;
 747                 if(waves)
 748                         self.death_time = ceil((time + sdelay) / waves) * waves;
 749                 else
 750                         self.death_time = time + sdelay;
 751                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 752                         self.respawn_countdown = 10; // first number to count down from is 10
 753                 else
 754                         self.respawn_countdown = -1; // do not count down
 755                 if (random() < 0.5)
 756                 {
 757                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 758                         self.dead_frame = self.anim_dead1_x;
 759                 }
 760                 else
 761                 {
 762                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 763                         self.dead_frame = self.anim_dead2_x;
 764                 }
 765                 // set damage function to corpse damage
 766                 self.event_damage = PlayerCorpseDamage;
 767                 // call the corpse damage function just in case it wants to gib
 768                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 769                 // set up to fade out later
 770                 SUB_SetFade (self, time + 6 + random (), 1);
 771
 772                 if(sv_gentle > 0 || autocvar_ekg) {
 773                         // remove corpse
 774                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 775                 }
 776
 777                 // reset fields the weapons may use just in case
 778                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 779                 {
 780                         weapon_action(j, WR_RESETPLAYER);
 781                         ATTACK_FINISHED_FOR(self, j) = 0;
 782                 }
 783         }
 784 }
 785
 786 .float muted; // to be used by prvm_edictset server playernumber muted 1
 787 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 788 // message "": do not say, just test flood control
 789 // return value:
 790 //   1 = accept
 791 //   0 = reject
 792 //  -1 = fake accept
 793 {
 794         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 795         float flood, privatemsgprefixlen;
 796         var .float flood_field;
 797         entity head;
 798         float ret;
 799
 800         if(Ban_MaybeEnforceBan(source))
 801                 return 0;
 802
 803         if(!teamsay && !privatesay)
 804                 if(substring(msgin, 0, 1) == " ")
 805                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 806
 807         msgin = formatmessage(msgin);
 808
 809         if(source.classname != "player")
 810                 colorstr = "^0"; // black for spectators
 811         else if(teamplay)
 812                 colorstr = Team_ColorCode(source.team);
 813         else
 814                 teamsay = FALSE;
 815
 816         if(intermission_running)
 817                 teamsay = FALSE;
 818
 819         if(msgin != "")
 820                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 821
 822         /*
 823          * using bprint solves this... me stupid
 824         // how can we prevent the message from appearing in a listen server?
 825         // for now, just give "say" back and only handle say_team
 826         if(!teamsay)
 827         {
 828                 clientcommand(self, strcat("say ", msgin));
 829                 return;
 830         }
 831         */
 832
 833         if(autocvar_g_chat_teamcolors)
 834                 namestr = playername(source);
 835         else
 836                 namestr = source.netname;
 837
 838         if(msgin != "")
 839         {
 840                 if(privatesay)
 841                 {
 842                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 843                         privatemsgprefixlen = strlen(msgstr);
 844                         msgstr = strcat(msgstr, msgin);
 845                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 846                         if(autocvar_g_chat_teamcolors)
 847                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 848                         else
 849                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 850                 }
 851                 else if(teamsay)
 852                 {
 853                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 854                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 855                 }
 856                 else
 857                 {
 858                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 859                         cmsgstr = "";
 860                 }
 861                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 862         }
 863         else
 864         {
 865                 msgstr = cmsgstr = "";
 866         }
 867
 868         fullmsgstr = msgstr;
 869         fullcmsgstr = cmsgstr;
 870
 871         // FLOOD CONTROL
 872         flood = 0;
 873         if(floodcontrol)
 874         {
 875                 float flood_spl;
 876                 float flood_burst;
 877                 float flood_lmax;
 878                 float lines;
 879                 if(privatesay)
 880                 {
 881                         flood_spl = autocvar_g_chat_flood_spl_tell;
 882                         flood_burst = autocvar_g_chat_flood_burst_tell;
 883                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 884                         flood_field = floodcontrol_chattell;
 885                 }
 886                 else if(teamsay)
 887                 {
 888                         flood_spl = autocvar_g_chat_flood_spl_team;
 889                         flood_burst = autocvar_g_chat_flood_burst_team;
 890                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 891                         flood_field = floodcontrol_chatteam;
 892                 }
 893                 else
 894                 {
 895                         flood_spl = autocvar_g_chat_flood_spl;
 896                         flood_burst = autocvar_g_chat_flood_burst;
 897                         flood_lmax = autocvar_g_chat_flood_lmax;
 898                         flood_field = floodcontrol_chat;
 899                 }
 900                 flood_burst = max(0, flood_burst - 1);
 901                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 902
 903                 // do flood control for the default line size
 904                 if(msgstr != "")
 905                 {
 906                         getWrappedLine_remaining = msgstr;
 907                         msgstr = "";
 908                         lines = 0;
 909                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 910                         {
 911                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 912                                 ++lines;
 913                         }
 914                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 915
 916                         if(getWrappedLine_remaining != "")
 917                         {
 918                                 msgstr = strcat(msgstr, "\n");
 919                                 flood = 2;
 920                         }
 921
 922                         if(time >= source.flood_field)
 923                         {
 924                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 925                         }
 926                         else
 927                         {
 928                                 flood = 1;
 929                                 msgstr = fullmsgstr;
 930                         }
 931                 }
 932                 else
 933                 {
 934                         if(time >= source.flood_field)
 935                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 936                         else
 937                                 flood = 1;
 938                 }
 939
 940                 if (timeoutStatus == 2) //when game is paused, no flood protection
 941                         source.flood_field = flood = 0;
 942         }
 943
 944         if(flood == 2) // cannot happen for empty msgstr
 945         {
 946                 if(autocvar_g_chat_flood_notify_flooder)
 947                 {
 948                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 949                         sourcecmsgstr = "";
 950                 }
 951                 else
 952                 {
 953                         sourcemsgstr = fullmsgstr;
 954                         sourcecmsgstr = fullcmsgstr;
 955                 }
 956                 cmsgstr = "";
 957         }
 958         else
 959         {
 960                 sourcemsgstr = msgstr;
 961                 sourcecmsgstr = cmsgstr;
 962         }
 963
 964         if(!privatesay)
 965         if(source.classname != "player")
 966         {
 967                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 968                         teamsay = -1; // spectators
 969         }
 970
 971         if(flood)
 972                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 973
 974         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 975         if(privatesay)
 976                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 977
 978         if(source.muted)
 979         {
 980                 // always fake the message
 981                 ret = -1;
 982         }
 983         else if(flood == 1)
 984         {
 985                 if(autocvar_g_chat_flood_notify_flooder)
 986                 {
 987                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 988                         ret = 0;
 989                 }
 990                 else
 991                         ret = -1;
 992         }
 993         else
 994         {
 995                 ret = 1;
 996         }
 997
 998         if(sourcemsgstr != "" && ret != 0)
 999         {
1000                 if(ret < 0) // fake
1001                 {
1002                         sprint(source, sourcemsgstr);
1003                         if(sourcecmsgstr != "" && !privatesay)
1004                                 centerprint(source, sourcecmsgstr);
1005                 }
1006                 else if(privatesay)
1007                 {
1008                         sprint(source, sourcemsgstr);
1009                         sprint(privatesay, msgstr);
1010                         if(cmsgstr != "")
1011                                 centerprint(privatesay, cmsgstr);
1012                 }
1013                 else if(teamsay > 0)
1014                 {
1015                         sprint(source, sourcemsgstr);
1016                         if(sourcecmsgstr != "")
1017                                 centerprint(source, sourcecmsgstr);
1018                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1019                                 if(head != source)
1020                                 {
1021                                         sprint(head, msgstr);
1022                                         if(cmsgstr != "")
1023                                                 centerprint(head, cmsgstr);
1024                                 }
1025                 }
1026                 else if(teamsay < 0)
1027                 {
1028                         sprint(source, sourcemsgstr);
1029                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1030                                 if(head != source)
1031                                         sprint(head, msgstr);
1032                 }
1033                 else if(sourcemsgstr != msgstr)
1034                 {
1035                         sprint(source, sourcemsgstr);
1036                         FOR_EACH_REALCLIENT(head)
1037                                 if(head != source)
1038                                         sprint(head, msgstr);
1039                 }
1040                 else
1041                         bprint(msgstr);
1042         }
1043
1044         return ret;
1045 }
1046
1047 float GetVoiceMessageVoiceType(string type)
1048 {
1049         if(type == "taunt")
1050                 return VOICETYPE_TAUNT;
1051         if(type == "teamshoot")
1052                 return VOICETYPE_LASTATTACKER;
1053         return VOICETYPE_TEAMRADIO;
1054 }
1055
1056 string allvoicesamples;
1057 .string GetVoiceMessageSampleField(string type)
1058 {
1059         GetPlayerSoundSampleField_notFound = 0;
1060         switch(type)
1061         {
1062 #define _VOICEMSG(m) case #m: return playersound_##m;
1063                 ALLVOICEMSGS
1064 #undef _VOICEMSG
1065         }
1066         GetPlayerSoundSampleField_notFound = 1;
1067         return playersound_taunt;
1068 }
1069
1070 .string GetPlayerSoundSampleField(string type)
1071 {
1072         GetPlayerSoundSampleField_notFound = 0;
1073         switch(type)
1074         {
1075 #define _VOICEMSG(m) case #m: return playersound_##m;
1076                 ALLPLAYERSOUNDS
1077 #undef _VOICEMSG
1078         }
1079         GetPlayerSoundSampleField_notFound = 1;
1080         return playersound_taunt;
1081 }
1082
1083 void PrecacheGlobalSound(string samplestring)
1084 {
1085         float n, i;
1086         tokenize_console(samplestring);
1087         n = stof(argv(1));
1088         if(n > 0)
1089         {
1090                 for(i = 1; i <= n; ++i)
1091                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1092         }
1093         else
1094         {
1095                 precache_sound(strcat(argv(0), ".wav"));
1096         }
1097 }
1098
1099 void PrecachePlayerSounds(string f)
1100 {
1101         float fh;
1102         string s;
1103         fh = fopen(f, FILE_READ);
1104         if(fh < 0)
1105                 return;
1106         while((s = fgets(fh)))
1107         {
1108                 if(tokenize_console(s) != 3)
1109                 {
1110                         dprint("Invalid sound info line: ", s, "\n");
1111                         continue;
1112                 }
1113                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1114         }
1115         fclose(fh);
1116
1117         if not(allvoicesamples)
1118         {
1119 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1120                 ALLVOICEMSGS
1121 #undef _VOICEMSG
1122                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1123         }
1124 }
1125
1126 void ClearPlayerSounds()
1127 {
1128 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1129         ALLPLAYERSOUNDS
1130         ALLVOICEMSGS
1131 #undef _VOICEMSG
1132 }
1133
1134 float LoadPlayerSounds(string f, float first)
1135 {
1136         float fh;
1137         string s;
1138         var .string field;
1139         fh = fopen(f, FILE_READ);
1140         if(fh < 0)
1141         {
1142                 dprint("Player sound file not found: ", f, "\n");
1143                 return 0;
1144         }
1145         while((s = fgets(fh)))
1146         {
1147                 if(tokenize_console(s) != 3)
1148                         continue;
1149                 field = GetPlayerSoundSampleField(argv(0));
1150                 if(GetPlayerSoundSampleField_notFound)
1151                         field = GetVoiceMessageSampleField(argv(0));
1152                 if(GetPlayerSoundSampleField_notFound)
1153                         continue;
1154                 if(self.field)
1155                         strunzone(self.field);
1156                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1157         }
1158         fclose(fh);
1159         return 1;
1160 }
1161
1162 .float modelindex_for_playersound;
1163 .float skinindex_for_playersound;
1164 void UpdatePlayerSounds()
1165 {
1166         if(self.modelindex == self.modelindex_for_playersound)
1167         if(self.skinindex == self.skinindex_for_playersound)
1168                 return;
1169         self.modelindex_for_playersound = self.modelindex;
1170         self.skinindex_for_playersound = self.skinindex;
1171         ClearPlayerSounds();
1172         LoadPlayerSounds("sound/player/default.sounds", 1);
1173         if(!autocvar_g_debug_defaultsounds)
1174                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1175                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1176 }
1177
1178 void FakeGlobalSound(string sample, float chan, float voicetype)
1179 {
1180         float n;
1181         float tauntrand;
1182
1183         if(sample == "")
1184                 return;
1185
1186         tokenize_console(sample);
1187         n = stof(argv(1));
1188         if(n > 0)
1189                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1190         else
1191                 sample = strcat(argv(0), ".wav"); // randomization
1192
1193         switch(voicetype)
1194         {
1195                 case VOICETYPE_LASTATTACKER_ONLY:
1196                         break;
1197                 case VOICETYPE_LASTATTACKER:
1198                         if(self.pusher)
1199                         {
1200                                 msg_entity = self;
1201                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1202                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1203                         }
1204                         break;
1205                 case VOICETYPE_TEAMRADIO:
1206                         msg_entity = self;
1207                         if(msg_entity.cvar_cl_voice_directional == 1)
1208                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1209                         else
1210                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1211                         break;
1212                 case VOICETYPE_AUTOTAUNT:
1213                         if(!sv_autotaunt)
1214                                 break;
1215                         if(!sv_taunt)
1216                                 break;
1217                         if(sv_gentle)
1218                                 break;
1219                         tauntrand = random();
1220                         msg_entity = self;
1221                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1222                         {
1223                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1224                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1225                                 else
1226                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1227                         }
1228                         break;
1229                 case VOICETYPE_TAUNT:
1230                         if(self.classname == "player")
1231                                 if(self.deadflag == DEAD_NO)
1232                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1233                         if(!sv_taunt)
1234                                 break;
1235                         if(sv_gentle)
1236                                 break;
1237                         msg_entity = self;
1238                         if (msg_entity.cvar_cl_voice_directional >= 1)
1239                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1240                         else
1241                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1242                         break;
1243                 case VOICETYPE_PLAYERSOUND:
1244                         msg_entity = self;
1245                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1246                         break;
1247                 default:
1248                         backtrace("Invalid voice type!");
1249                         break;
1250         }
1251 }
1252
1253 void GlobalSound(string sample, float chan, float voicetype)
1254 {
1255         float n;
1256         float tauntrand;
1257
1258         if(sample == "")
1259                 return;
1260
1261         tokenize_console(sample);
1262         n = stof(argv(1));
1263         if(n > 0)
1264                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1265         else
1266                 sample = strcat(argv(0), ".wav"); // randomization
1267
1268         switch(voicetype)
1269         {
1270                 case VOICETYPE_LASTATTACKER_ONLY:
1271                         if(self.pusher)
1272                         {
1273                                 msg_entity = self.pusher;
1274                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1275                                 {
1276                                         if(msg_entity.cvar_cl_voice_directional == 1)
1277                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1278                                         else
1279                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1280                                 }
1281                         }
1282                         break;
1283                 case VOICETYPE_LASTATTACKER:
1284                         if(self.pusher)
1285                         {
1286                                 msg_entity = self.pusher;
1287                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1288                                 {
1289                                         if(msg_entity.cvar_cl_voice_directional == 1)
1290                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1291                                         else
1292                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1293                                 }
1294                                 msg_entity = self;
1295                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1296                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1297                         }
1298                         break;
1299                 case VOICETYPE_TEAMRADIO:
1300                         FOR_EACH_REALCLIENT(msg_entity)
1301                                 if(!teamplay || msg_entity.team == self.team)
1302                                 {
1303                                         if(msg_entity.cvar_cl_voice_directional == 1)
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1305                                         else
1306                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1307                                 }
1308                         break;
1309                 case VOICETYPE_AUTOTAUNT:
1310                         if(!sv_autotaunt)
1311                                 break;
1312                         if(!sv_taunt)
1313                                 break;
1314                         if(sv_gentle)
1315                                 break;
1316                         tauntrand = random();
1317                         FOR_EACH_REALCLIENT(msg_entity)
1318                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1319                                 {
1320                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1321                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1322                                         else
1323                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1324                                 }
1325                         break;
1326                 case VOICETYPE_TAUNT:
1327                         if(self.classname == "player")
1328                                 if(self.deadflag == DEAD_NO)
1329                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1330                         if(!sv_taunt)
1331                                 break;
1332                         if(sv_gentle)
1333                                 break;
1334                         FOR_EACH_REALCLIENT(msg_entity)
1335                         {
1336                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1337                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1338                                 else
1339                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1340                         }
1341                         break;
1342                 case VOICETYPE_PLAYERSOUND:
1343                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1344                         break;
1345                 default:
1346                         backtrace("Invalid voice type!");
1347                         break;
1348         }
1349 }
1350
1351 void PlayerSound(.string samplefield, float chan, float voicetype)
1352 {
1353         GlobalSound(self.samplefield, chan, voicetype);
1354 }
1355
1356 void VoiceMessage(string type, string msg)
1357 {
1358         var .string sample;
1359         float voicetype, ownteam;
1360         float flood;
1361         sample = GetVoiceMessageSampleField(type);
1362
1363         if(GetPlayerSoundSampleField_notFound)
1364         {
1365                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1366                 return;
1367         }
1368
1369         voicetype = GetVoiceMessageVoiceType(type);
1370         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1371
1372         flood = Say(self, ownteam, world, msg, 1);
1373
1374         if (flood > 0)
1375                 GlobalSound(self.sample, CH_VOICE, voicetype);
1376         else if (flood < 0)
1377                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1378 }
1379
1380 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1381 {
1382 //      show_message
1383 //      0 (00) automove centerprint, admin message
1384 //      1 (01) automove centerprint, no admin message
1385 //      2 (10) no centerprint, admin message
1386 //      3 (11) no centerprint, no admin message
1387
1388         float lockteams_backup;
1389
1390         lockteams_backup = lockteams;  // backup any team lock
1391
1392         lockteams = 0;  // disable locked teams
1393
1394         TeamchangeFrags(client);  // move the players frags
1395         SetPlayerColors(client, team_colour - 1);  // set the players colour
1396         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1397
1398         lockteams = lockteams_backup;  // restore the team lock
1399
1400         LogTeamchange(client.playerid, client.team, type);
1401
1402         if not(show_message & 1) // admin message
1403                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1404
1405         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1406 }