qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 218
 219         self = oldself;
 220 }
 221
 222 float player_getspecies()
 223 {
 224         float s;
 225         get_model_parameters(self.model, self.skin);
 226         s = get_model_parameters_species;
 227         get_model_parameters(string_null, 0);
 228         if(s < 0)
 229                 return SPECIES_HUMAN;
 230         return s;
 231 }
 232
 233 void player_setupanimsformodel()
 234 {
 235         // load animation info
 236         animdecide_init(self);
 237         animdecide_setstate(self, 0, FALSE);
 238 }
 239
 240 void player_anim (void)
 241 {
 242         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 243         if(self.deadflag && !deadbits)
 244                 if(random() < 0.5)
 245                         deadbits = ANIMSTATE_DEAD1;
 246                 else
 247                         deadbits = ANIMSTATE_DEAD2;
 248         float animbits = deadbits;
 249         if(self.freezetag_frozen)
 250                 animbits |= ANIMSTATE_FROZEN;
 251         if(self.crouch)
 252                 animbits |= ANIMSTATE_DUCK;
 253         animdecide_setstate(self, animbits, FALSE);
 254         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 255
 256         if (self.weaponentity)
 257         {
 258                 updateanim(self.weaponentity);
 259                 if (!self.weaponentity.animstate_override)
 260                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 261         }
 262 }
 263
 264 void SpawnThrownWeapon (vector org, float w)
 265 {
 266         if(self.weapons & WepSet_FromWeapon(self.weapon))
 267                 if(W_IsWeaponThrowable(self.weapon))
 268                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 269 }
 270
 271 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 272 {
 273         float take, save;
 274         vector v;
 275         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 276
 277         // damage resistance (ignore most of the damage from a bullet or similar)
 278         damage = max(damage - 5, 1);
 279
 280         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 281         take = v_x;
 282         save = v_y;
 283
 284         if(sound_allowed(MSG_BROADCAST, attacker))
 285         {
 286                 if (save > 10)
 287                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 288                 else if (take > 30)
 289                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 290                 else if (take > 10)
 291                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 292         }
 293
 294         if (take > 50)
 295                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 296         if (take > 100)
 297                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 298
 299         if (!(self.flags & FL_GODMODE))
 300         {
 301                 self.armorvalue = self.armorvalue - save;
 302                 self.health = self.health - take;
 303                 // pause regeneration for 5 seconds
 304                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 305         }
 306         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 307         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 308         self.dmg_inflictor = inflictor;
 309
 310         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 311         {
 312                 // don't use any animations as a gib
 313                 self.frame = 0;
 314                 // view just above the floor
 315                 self.view_ofs = '0 0 4';
 316
 317                 Violence_GibSplash(self, 1, 1, attacker);
 318                 self.alpha = -1;
 319                 self.solid = SOLID_NOT; // restore later
 320                 self.takedamage = DAMAGE_NO; // restore later
 321                 self.damagedbycontents = FALSE;
 322         }
 323 }
 324
 325 // g_<gametype>_str:
 326 // If 0, default is used.
 327 // If <0, 0 is used.
 328 // Otherwise, g_str (default value) is used.
 329 // For consistency, negative values there are mapped to zero too.
 330 #define GAMETYPE_DEFAULTED_SETTING(str) \
 331         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 332          (gametype_setting_tmp < 0) ? 0 : \
 333          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 334          gametype_setting_tmp)
 335
 336
 337 void calculate_player_respawn_time()
 338 {
 339         float gametype_setting_tmp;
 340         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 341         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 342         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 343         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 344         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 345         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 346
 347         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 348         entity pl;
 349         if (teamplay)
 350         {
 351                 FOR_EACH_PLAYER(pl)
 352                         if (pl != self)
 353                                 if (pl.team == self.team)
 354                                         ++pcount;
 355                 if (sdelay_small_count == 0)
 356                         sdelay_small_count = 1;
 357                 if (sdelay_large_count == 0)
 358                         sdelay_large_count = 1;
 359         }
 360         else
 361         {
 362                 FOR_EACH_PLAYER(pl)
 363                         if (pl != self)
 364                                 ++pcount;
 365                 if (sdelay_small_count == 0)
 366                 {
 367                         if (g_cts)
 368                         {
 369                                 // Players play independently. No point in requiring enemies.
 370                                 sdelay_small_count = 1;
 371                         }
 372                         else
 373                         {
 374                                 // Players play AGAINST each other. Enemies required.
 375                                 sdelay_small_count = 2;
 376                         }
 377                 }
 378                 if (sdelay_large_count == 0)
 379                 {
 380                         if (g_cts)
 381                         {
 382                                 // Players play independently. No point in requiring enemies.
 383                                 sdelay_large_count = 1;
 384                         }
 385                         else
 386                         {
 387                                 // Players play AGAINST each other. Enemies required.
 388                                 sdelay_large_count = 2;
 389                         }
 390                 }
 391         }
 392
 393         float sdelay;
 394
 395         if (pcount <= sdelay_small_count)
 396                 sdelay = sdelay_small;
 397         else if (pcount >= sdelay_large_count)
 398                 sdelay = sdelay_large;
 399         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 400                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 401
 402         if(waves)
 403                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 404         else
 405                 self.respawn_time = time + sdelay;
 406
 407         if(sdelay < sdelay_max)
 408                 self.respawn_time_max = time + sdelay_max;
 409         else
 410                 self.respawn_time_max = self.respawn_time;
 411
 412         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 413                 self.respawn_countdown = 10; // first number to count down from is 10
 414         else
 415                 self.respawn_countdown = -1; // do not count down
 416
 417         if(g_cts || autocvar_g_forced_respawn)
 418                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 419 }
 420
 421 void ClientKill_Now_TeamChange();
 422
 423 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 424 {
 425         float take, save, dh, da, j;
 426         vector v;
 427         float valid_damage_for_weaponstats;
 428         float excess;
 429
 430         dh = max(self.health, 0);
 431         da = max(self.armorvalue, 0);
 432
 433         if(!DEATH_ISSPECIAL(deathtype))
 434         {
 435                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 436                 if(self != attacker)
 437                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 438         }
 439
 440         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 441         {
 442                 // tuba causes blood to come out of the ears
 443                 vector ear1, ear2;
 444                 vector d;
 445                 float f;
 446                 ear1 = self.origin;
 447                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 448                 ear2 = ear1;
 449                 makevectors(self.angles);
 450                 ear1 += v_right * -10;
 451                 ear2 += v_right * +10;
 452                 d = inflictor.origin - self.origin;
 453                 if (d)
 454                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 455                 else
 456                         f = 0;  // Assum ecenter.
 457                 force = v_right * vlen(force);
 458                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 459                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 460                 if(f > 0)
 461                 {
 462                         hitloc = ear1;
 463                         force = force * -1;
 464                 }
 465                 else
 466                 {
 467                         hitloc = ear2;
 468                         // force is already good
 469                 }
 470         }
 471         else
 472                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 473
 474
 475         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 476         take = v_x;
 477         save = v_y;
 478
 479         if(attacker == self)
 480         {
 481                 // don't reset pushltime for self damage as it may be an attempt to
 482                 // escape a lava pit or similar
 483                 //self.pushltime = 0;
 484                 self.istypefrag = 0;
 485         }
 486         else if(IS_PLAYER(attacker))
 487         {
 488                 self.pusher = attacker;
 489                 self.pushltime = time + autocvar_g_maxpushtime;
 490                 self.istypefrag = self.BUTTON_CHAT;
 491         }
 492         else if(time < self.pushltime)
 493         {
 494                 attacker = self.pusher;
 495                 self.pushltime = max(self.pushltime, time + 0.6);
 496         }
 497         else
 498         {
 499                 self.pushltime = 0;
 500                 self.istypefrag = 0;
 501         }
 502
 503         frag_inflictor = inflictor;
 504         frag_attacker = attacker;
 505         frag_target = self;
 506         frag_damage = damage;
 507         damage_take = take;
 508         damage_save = save;
 509         damage_force = force;
 510         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 511         take = bound(0, damage_take, self.health);
 512         save = bound(0, damage_save, self.armorvalue);
 513         excess = max(0, damage - take - save);
 514
 515         if(sound_allowed(MSG_BROADCAST, attacker))
 516         {
 517                 if (save > 10)
 518                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 519                 else if (take > 30)
 520                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 521                 else if (take > 10)
 522                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 523         }
 524
 525         if (take > 50)
 526                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 527         if (take > 100)
 528                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 529
 530         if (time >= self.spawnshieldtime)
 531         {
 532                 if (!(self.flags & FL_GODMODE))
 533                 {
 534                         self.armorvalue = self.armorvalue - save;
 535                         self.health = self.health - take;
 536                         // pause regeneration for 5 seconds
 537                         if(take)
 538                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 539
 540                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 541                         {
 542                                 self.pain_finished = time + 0.5;        //Supajoe
 543
 544                                 if(autocvar_sv_gentle < 1) {
 545                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 546                                         {
 547                                                 if (!self.animstate_override)
 548                                                 {
 549                                                         if (random() > 0.5)
 550                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 551                                                         else
 552                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 553                                                 }
 554                                         }
 555
 556                                         if(sound_allowed(MSG_BROADCAST, attacker))
 557                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 558                                         if(self.health > 1)
 559                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 560                                         {
 561                                                 if(deathtype == DEATH_FALL)
 562                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                                                 else if(self.health > 75) // TODO make a "gentle" version?
 564                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 565                                                 else if(self.health > 50)
 566                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 567                                                 else if(self.health > 25)
 568                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 569                                                 else
 570                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 571                                         }
 572                                 }
 573
 574                                 // throw off bot aim temporarily
 575                                 float shake;
 576                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 577                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 578                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 579                         }
 580                 }
 581                 else
 582                         self.max_armorvalue += (save + take);
 583         }
 584         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 585         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 586         self.dmg_inflictor = inflictor;
 587
 588         float abot, vbot, awep;
 589         abot = (IS_BOT_CLIENT(attacker));
 590         vbot = (IS_BOT_CLIENT(self));
 591
 592         valid_damage_for_weaponstats = 0;
 593         awep = 0;
 594
 595         if(vbot || IS_REAL_CLIENT(self))
 596         if(abot || IS_REAL_CLIENT(attacker))
 597         if(attacker && self != attacker)
 598         if(DIFF_TEAM(self, attacker))
 599         {
 600                 if(DEATH_ISSPECIAL(deathtype))
 601                         awep = attacker.weapon;
 602                 else
 603                         awep = DEATH_WEAPONOF(deathtype);
 604                 valid_damage_for_weaponstats = 1;
 605         }
 606
 607         if(valid_damage_for_weaponstats)
 608         {
 609                 dh = dh - max(self.health, 0);
 610                 da = da - max(self.armorvalue, 0);
 611                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 612         }
 613
 614         if (self.health < 1)
 615         {
 616                 float defer_ClientKill_Now_TeamChange;
 617                 defer_ClientKill_Now_TeamChange = FALSE;
 618
 619                 if(self.alivetime)
 620                 {
 621                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                         self.alivetime = 0;
 623                 }
 624
 625                 if(valid_damage_for_weaponstats)
 626                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 627
 628                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 629                 if(sound_allowed(MSG_BROADCAST, attacker))
 630                 {
 631                         if(deathtype == DEATH_DROWN)
 632                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 633                         else
 634                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 635                 }
 636
 637                 // get rid of kill indicator
 638                 if(self.killindicator)
 639                 {
 640                         remove(self.killindicator);
 641                         self.killindicator = world;
 642                         if(self.killindicator_teamchange)
 643                                 defer_ClientKill_Now_TeamChange = TRUE;
 644
 645                         if(self.classname == "body")
 646                         if(deathtype == DEATH_KILL)
 647                         {
 648                                 // for the lemmings fans, a small harmless explosion
 649                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 650                         }
 651                 }
 652
 653                 // print an obituary message
 654                 Obituary (attacker, inflictor, self, deathtype);
 655                 race_PreDie();
 656
 657         // increment frag counter for used weapon type
 658         float w;
 659         w = DEATH_WEAPONOF(deathtype);
 660         if(WEP_VALID(w))
 661         if(accuracy_isgooddamage(attacker, self))
 662         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 663
 664                 frag_attacker = attacker;
 665                 frag_inflictor = inflictor;
 666                 frag_target = self;
 667                 frag_deathtype = deathtype;
 668                 MUTATOR_CALLHOOK(PlayerDies);
 669
 670                 weapon_action(self.weapon, WR_PLAYERDEATH);
 671
 672                 RemoveGrapplingHook(self);
 673
 674                 Portal_ClearAllLater(self);
 675
 676                 if(IS_REAL_CLIENT(self))
 677                 {
 678                         self.fixangle = TRUE;
 679                         //msg_entity = self;
 680                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 681                         //WriteAngle (MSG_ONE, self.v_angle_x);
 682                         //WriteAngle (MSG_ONE, self.v_angle_y);
 683                         //WriteAngle (MSG_ONE, 80);
 684                 }
 685
 686                 if(defer_ClientKill_Now_TeamChange)
 687                         ClientKill_Now_TeamChange(); // can turn player into spectator
 688
 689                 // player could have been miraculously resuscitated ;)
 690                 // e.g. players in freezetag get frozen, they don't really die
 691                 if(self.health >= 1 || !IS_PLAYER(self))
 692                         return;
 693
 694                 // when we get here, player actually dies
 695
 696                 // clear waypoints
 697                 WaypointSprite_PlayerDead();
 698                 // throw a weapon
 699                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 700
 701                 // become fully visible
 702                 self.alpha = default_player_alpha;
 703                 // make the corpse upright (not tilted)
 704                 self.angles_x = 0;
 705                 self.angles_z = 0;
 706                 // don't spin
 707                 self.avelocity = '0 0 0';
 708                 // view from the floor
 709                 self.view_ofs = '0 0 -8';
 710                 // toss the corpse
 711                 self.movetype = MOVETYPE_TOSS;
 712                 // shootable corpse
 713                 self.solid = SOLID_CORPSE;
 714                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 715                 // don't stick to the floor
 716                 self.flags &= ~FL_ONGROUND;
 717                 // dying animation
 718                 self.deadflag = DEAD_DYING;
 719
 720                 // when to allow respawn
 721                 calculate_player_respawn_time();
 722
 723                 self.death_time = time;
 724                 if (random() < 0.5)
 725                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 726                 else
 727                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 728                 if (self.maxs_z > 5)
 729                 {
 730                         self.maxs_z = 5;
 731                         setsize(self, self.mins, self.maxs);
 732                 }
 733                 // set damage function to corpse damage
 734                 self.event_damage = PlayerCorpseDamage;
 735                 // call the corpse damage function just in case it wants to gib
 736                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 737                 // set up to fade out later
 738                 SUB_SetFade (self, time + 6 + random (), 1);
 739
 740                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 741                         // remove corpse
 742                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 743                 }
 744
 745                 // reset fields the weapons may use just in case
 746                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 747                 {
 748                         weapon_action(j, WR_RESETPLAYER);
 749                         ATTACK_FINISHED_FOR(self, j) = 0;
 750                 }
 751         }
 752 }
 753
 754 .float muted; // to be used by prvm_edictset server playernumber muted 1
 755 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 756 // message "": do not say, just test flood control
 757 // return value:
 758 //   1 = accept
 759 //   0 = reject
 760 //  -1 = fake accept
 761 {
 762         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 763         float flood;
 764         var .float flood_field;
 765         entity head;
 766         float ret;
 767         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 768
 769         if(!teamsay && !privatesay)
 770                 if(substring(msgin, 0, 1) == " ")
 771                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 772
 773         msgin = formatmessage(msgin);
 774
 775         if (!IS_PLAYER(source))
 776                 colorstr = "^0"; // black for spectators
 777         else if(teamplay)
 778                 colorstr = Team_ColorCode(source.team);
 779         else
 780         {
 781                 colorstr = "";
 782                 teamsay = FALSE;
 783         }
 784
 785         if(intermission_running)
 786                 teamsay = FALSE;
 787
 788         if(msgin != "")
 789                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 790
 791         /*
 792          * using bprint solves this... me stupid
 793         // how can we prevent the message from appearing in a listen server?
 794         // for now, just give "say" back and only handle say_team
 795         if(!teamsay)
 796         {
 797                 clientcommand(self, strcat("say ", msgin));
 798                 return;
 799         }
 800         */
 801
 802         if(autocvar_g_chat_teamcolors)
 803                 namestr = playername(source);
 804         else
 805                 namestr = source.netname;
 806
 807         if(msgin != "")
 808         {
 809                 if(privatesay)
 810                 {
 811                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 812                         privatemsgprefixlen = strlen(msgstr);
 813                         msgstr = strcat(msgstr, msgin);
 814                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 815                         if(autocvar_g_chat_teamcolors)
 816                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 817                         else
 818                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 819                 }
 820                 else if(teamsay)
 821                 {
 822                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 823                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 824                 }
 825                 else
 826                 {
 827                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 828                         cmsgstr = "";
 829                 }
 830                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 831         }
 832         else
 833         {
 834                 msgstr = cmsgstr = "";
 835         }
 836
 837         fullmsgstr = msgstr;
 838         fullcmsgstr = cmsgstr;
 839
 840         // FLOOD CONTROL
 841         flood = 0;
 842         flood_field = floodcontrol_chat;
 843         if(floodcontrol)
 844         {
 845                 float flood_spl;
 846                 float flood_burst;
 847                 float flood_lmax;
 848                 float lines;
 849                 if(privatesay)
 850                 {
 851                         flood_spl = autocvar_g_chat_flood_spl_tell;
 852                         flood_burst = autocvar_g_chat_flood_burst_tell;
 853                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 854                         flood_field = floodcontrol_chattell;
 855                 }
 856                 else if(teamsay)
 857                 {
 858                         flood_spl = autocvar_g_chat_flood_spl_team;
 859                         flood_burst = autocvar_g_chat_flood_burst_team;
 860                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 861                         flood_field = floodcontrol_chatteam;
 862                 }
 863                 else
 864                 {
 865                         flood_spl = autocvar_g_chat_flood_spl;
 866                         flood_burst = autocvar_g_chat_flood_burst;
 867                         flood_lmax = autocvar_g_chat_flood_lmax;
 868                         flood_field = floodcontrol_chat;
 869                 }
 870                 flood_burst = max(0, flood_burst - 1);
 871                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 872
 873                 // do flood control for the default line size
 874                 if(msgstr != "")
 875                 {
 876                         getWrappedLine_remaining = msgstr;
 877                         msgstr = "";
 878                         lines = 0;
 879                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 880                         {
 881                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 882                                 ++lines;
 883                         }
 884                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 885
 886                         if(getWrappedLine_remaining != "")
 887                         {
 888                                 msgstr = strcat(msgstr, "\n");
 889                                 flood = 2;
 890                         }
 891
 892                         if(time >= source.flood_field)
 893                         {
 894                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 895                         }
 896                         else
 897                         {
 898                                 flood = 1;
 899                                 msgstr = fullmsgstr;
 900                         }
 901                 }
 902                 else
 903                 {
 904                         if(time >= source.flood_field)
 905                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 906                         else
 907                                 flood = 1;
 908                 }
 909
 910                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 911                         source.flood_field = flood = 0;
 912         }
 913
 914         if(flood == 2) // cannot happen for empty msgstr
 915         {
 916                 if(autocvar_g_chat_flood_notify_flooder)
 917                 {
 918                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 919                         sourcecmsgstr = "";
 920                 }
 921                 else
 922                 {
 923                         sourcemsgstr = fullmsgstr;
 924                         sourcecmsgstr = fullcmsgstr;
 925                 }
 926                 cmsgstr = "";
 927         }
 928         else
 929         {
 930                 sourcemsgstr = msgstr;
 931                 sourcecmsgstr = cmsgstr;
 932         }
 933
 934         if(!privatesay)
 935         if (!IS_PLAYER(source))
 936         {
 937                 if (!intermission_running)
 938                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 939                                 teamsay = -1; // spectators
 940         }
 941
 942         if(flood)
 943                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 944
 945         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 946         if(privatesay)
 947                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 948
 949         if(source.muted)
 950         {
 951                 // always fake the message
 952                 ret = -1;
 953         }
 954         else if(flood == 1)
 955         {
 956                 if(autocvar_g_chat_flood_notify_flooder)
 957                 {
 958                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 959                         ret = 0;
 960                 }
 961                 else
 962                         ret = -1;
 963         }
 964         else
 965         {
 966                 ret = 1;
 967         }
 968
 969         if(sourcemsgstr != "" && ret != 0)
 970         {
 971                 if(ret < 0) // faked message, because the player is muted
 972                 {
 973                         sprint(source, sourcemsgstr);
 974                         if(sourcecmsgstr != "" && !privatesay)
 975                                 centerprint(source, sourcecmsgstr);
 976                 }
 977                 else if(privatesay) // private message, between 2 people only
 978                 {
 979                         sprint(source, sourcemsgstr);
 980                         sprint(privatesay, msgstr);
 981                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 982                         if(cmsgstr != "")
 983                                 centerprint(privatesay, cmsgstr);
 984                 }
 985                 else if(teamsay > 0) // team message, only sent to team mates
 986                 {
 987                         sprint(source, sourcemsgstr);
 988                         dedicated_print(msgstr); // send to server console too
 989                         if(sourcecmsgstr != "")
 990                                 centerprint(source, sourcecmsgstr);
 991                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 992                                 if(head != source)
 993                                 {
 994                                         sprint(head, msgstr);
 995                                         if(cmsgstr != "")
 996                                                 centerprint(head, cmsgstr);
 997                                 }
 998                 }
 999                 else if(teamsay < 0) // spectator message, only sent to spectators
1000                 {
1001                         sprint(source, sourcemsgstr);
1002                         dedicated_print(msgstr); // send to server console too
1003                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
1004                                 if(head != source)
1005                                         sprint(head, msgstr);
1006                 }
1007                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1008                 {
1009                         sprint(source, sourcemsgstr);
1010                         dedicated_print(msgstr); // send to server console too
1011                         FOR_EACH_REALCLIENT(head)
1012                                 if(head != source)
1013                                         sprint(head, msgstr);
1014                 }
1015                 else
1016                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1017         }
1018
1019         return ret;
1020 }
1021
1022 float GetVoiceMessageVoiceType(string type)
1023 {
1024         if(type == "taunt")
1025                 return VOICETYPE_TAUNT;
1026         if(type == "teamshoot")
1027                 return VOICETYPE_LASTATTACKER;
1028         return VOICETYPE_TEAMRADIO;
1029 }
1030
1031 string allvoicesamples;
1032 .string GetVoiceMessageSampleField(string type)
1033 {
1034         GetPlayerSoundSampleField_notFound = 0;
1035         switch(type)
1036         {
1037 #define _VOICEMSG(m) case #m: return playersound_##m;
1038                 ALLVOICEMSGS
1039 #undef _VOICEMSG
1040         }
1041         GetPlayerSoundSampleField_notFound = 1;
1042         return playersound_taunt;
1043 }
1044
1045 .string GetPlayerSoundSampleField(string type)
1046 {
1047         GetPlayerSoundSampleField_notFound = 0;
1048         switch(type)
1049         {
1050 #define _VOICEMSG(m) case #m: return playersound_##m;
1051                 ALLPLAYERSOUNDS
1052 #undef _VOICEMSG
1053         }
1054         GetPlayerSoundSampleField_notFound = 1;
1055         return playersound_taunt;
1056 }
1057
1058 void PrecacheGlobalSound(string samplestring)
1059 {
1060         float n, i;
1061         tokenize_console(samplestring);
1062         n = stof(argv(1));
1063         if(n > 0)
1064         {
1065                 for(i = 1; i <= n; ++i)
1066                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1067         }
1068         else
1069         {
1070                 precache_sound(strcat(argv(0), ".wav"));
1071         }
1072 }
1073
1074 void PrecachePlayerSounds(string f)
1075 {
1076         float fh;
1077         string s;
1078         fh = fopen(f, FILE_READ);
1079         if(fh < 0)
1080                 return;
1081         while((s = fgets(fh)))
1082         {
1083                 if(tokenize_console(s) != 3)
1084                 {
1085                         dprint("Invalid sound info line: ", s, "\n");
1086                         continue;
1087                 }
1088                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1089         }
1090         fclose(fh);
1091
1092         if (!allvoicesamples)
1093         {
1094 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1095                 ALLVOICEMSGS
1096 #undef _VOICEMSG
1097                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1098         }
1099 }
1100
1101 void ClearPlayerSounds()
1102 {
1103 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1104         ALLPLAYERSOUNDS
1105         ALLVOICEMSGS
1106 #undef _VOICEMSG
1107 }
1108
1109 float LoadPlayerSounds(string f, float first)
1110 {
1111         float fh;
1112         string s;
1113         var .string field;
1114         fh = fopen(f, FILE_READ);
1115         if(fh < 0)
1116         {
1117                 dprint("Player sound file not found: ", f, "\n");
1118                 return 0;
1119         }
1120         while((s = fgets(fh)))
1121         {
1122                 if(tokenize_console(s) != 3)
1123                         continue;
1124                 field = GetPlayerSoundSampleField(argv(0));
1125                 if(GetPlayerSoundSampleField_notFound)
1126                         field = GetVoiceMessageSampleField(argv(0));
1127                 if(GetPlayerSoundSampleField_notFound)
1128                         continue;
1129                 if(self.field)
1130                         strunzone(self.field);
1131                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1132         }
1133         fclose(fh);
1134         return 1;
1135 }
1136
1137 .float modelindex_for_playersound;
1138 .float skin_for_playersound;
1139 void UpdatePlayerSounds()
1140 {
1141         if(self.modelindex == self.modelindex_for_playersound)
1142         if(self.skin == self.skin_for_playersound)
1143                 return;
1144         self.modelindex_for_playersound = self.modelindex;
1145         self.skin_for_playersound = self.skin;
1146         ClearPlayerSounds();
1147         LoadPlayerSounds("sound/player/default.sounds", 1);
1148         if(!autocvar_g_debug_defaultsounds)
1149                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1150                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1151 }
1152
1153 void FakeGlobalSound(string sample, float chan, float voicetype)
1154 {
1155         float n;
1156         float tauntrand;
1157
1158         if(sample == "")
1159                 return;
1160
1161         tokenize_console(sample);
1162         n = stof(argv(1));
1163         if(n > 0)
1164                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1165         else
1166                 sample = strcat(argv(0), ".wav"); // randomization
1167
1168         switch(voicetype)
1169         {
1170                 case VOICETYPE_LASTATTACKER_ONLY:
1171                         break;
1172                 case VOICETYPE_LASTATTACKER:
1173                         if(self.pusher)
1174                         {
1175                                 msg_entity = self;
1176                                 if(IS_REAL_CLIENT(msg_entity))
1177                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1178                         }
1179                         break;
1180                 case VOICETYPE_TEAMRADIO:
1181                         msg_entity = self;
1182                         if(msg_entity.cvar_cl_voice_directional == 1)
1183                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1184                         else
1185                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1186                         break;
1187                 case VOICETYPE_AUTOTAUNT:
1188                         if(!sv_autotaunt)
1189                                 break;
1190                         if(!sv_taunt)
1191                                 break;
1192                         if(autocvar_sv_gentle)
1193                                 break;
1194                         tauntrand = random();
1195                         msg_entity = self;
1196                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1197                         {
1198                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1199                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1200                                 else
1201                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1202                         }
1203                         break;
1204                 case VOICETYPE_TAUNT:
1205                         if(IS_PLAYER(self))
1206                                 if(self.deadflag == DEAD_NO)
1207                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1208                         if(!sv_taunt)
1209                                 break;
1210                         if(autocvar_sv_gentle)
1211                                 break;
1212                         msg_entity = self;
1213                         if (msg_entity.cvar_cl_voice_directional >= 1)
1214                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1215                         else
1216                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1217                         break;
1218                 case VOICETYPE_PLAYERSOUND:
1219                         msg_entity = self;
1220                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1221                         break;
1222                 default:
1223                         backtrace("Invalid voice type!");
1224                         break;
1225         }
1226 }
1227
1228 void GlobalSound(string sample, float chan, float voicetype)
1229 {
1230         float n;
1231         float tauntrand;
1232
1233         if(sample == "")
1234                 return;
1235
1236         tokenize_console(sample);
1237         n = stof(argv(1));
1238         if(n > 0)
1239                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1240         else
1241                 sample = strcat(argv(0), ".wav"); // randomization
1242
1243         switch(voicetype)
1244         {
1245                 case VOICETYPE_LASTATTACKER_ONLY:
1246                         if(self.pusher)
1247                         {
1248                                 msg_entity = self.pusher;
1249                                 if(IS_REAL_CLIENT(msg_entity))
1250                                 {
1251                                         if(msg_entity.cvar_cl_voice_directional == 1)
1252                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1253                                         else
1254                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1255                                 }
1256                         }
1257                         break;
1258                 case VOICETYPE_LASTATTACKER:
1259                         if(self.pusher)
1260                         {
1261                                 msg_entity = self.pusher;
1262                                 if(IS_REAL_CLIENT(msg_entity))
1263                                 {
1264                                         if(msg_entity.cvar_cl_voice_directional == 1)
1265                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1266                                         else
1267                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1268                                 }
1269                                 msg_entity = self;
1270                                 if(IS_REAL_CLIENT(msg_entity))
1271                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1272                         }
1273                         break;
1274                 case VOICETYPE_TEAMRADIO:
1275                         FOR_EACH_REALCLIENT(msg_entity)
1276                                 if(!teamplay || msg_entity.team == self.team)
1277                                 {
1278                                         if(msg_entity.cvar_cl_voice_directional == 1)
1279                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1280                                         else
1281                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1282                                 }
1283                         break;
1284                 case VOICETYPE_AUTOTAUNT:
1285                         if(!sv_autotaunt)
1286                                 break;
1287                         if(!sv_taunt)
1288                                 break;
1289                         if(autocvar_sv_gentle)
1290                                 break;
1291                         tauntrand = random();
1292                         FOR_EACH_REALCLIENT(msg_entity)
1293                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1294                                 {
1295                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1296                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1297                                         else
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1299                                 }
1300                         break;
1301                 case VOICETYPE_TAUNT:
1302                         if(IS_PLAYER(self))
1303                                 if(self.deadflag == DEAD_NO)
1304                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1305                         if(!sv_taunt)
1306                                 break;
1307                         if(autocvar_sv_gentle)
1308                                 break;
1309                         FOR_EACH_REALCLIENT(msg_entity)
1310                         {
1311                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1312                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1313                                 else
1314                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1315                         }
1316                         break;
1317                 case VOICETYPE_PLAYERSOUND:
1318                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1319                         break;
1320                 default:
1321                         backtrace("Invalid voice type!");
1322                         break;
1323         }
1324 }
1325
1326 void PlayerSound(.string samplefield, float chan, float voicetype)
1327 {
1328         GlobalSound(self.samplefield, chan, voicetype);
1329 }
1330
1331 void VoiceMessage(string type, string msg)
1332 {
1333         var .string sample;
1334         float voicetype, ownteam;
1335         float flood;
1336         sample = GetVoiceMessageSampleField(type);
1337
1338         if(GetPlayerSoundSampleField_notFound)
1339         {
1340                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1341                 return;
1342         }
1343
1344         voicetype = GetVoiceMessageVoiceType(type);
1345         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1346
1347         flood = Say(self, ownteam, world, msg, 1);
1348
1349         if (flood > 0)
1350                 GlobalSound(self.sample, CH_VOICE, voicetype);
1351         else if (flood < 0)
1352                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1353 }
1354
1355 void MoveToTeam(entity client, float team_colour, float type)
1356 {
1357         float lockteams_backup;
1358
1359         lockteams_backup = lockteams;  // backup any team lock
1360
1361         lockteams = 0;  // disable locked teams
1362
1363         TeamchangeFrags(client);  // move the players frags
1364         SetPlayerColors(client, team_colour - 1);  // set the players colour
1365         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1366
1367         lockteams = lockteams_backup;  // restore the team lock
1368
1369         LogTeamchange(client.playerid, client.team, type);
1370 }