qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_ready(entity fh, entity pass, float status)
  14 {
  15         float i, j, n, ibot, jbot, idx;
  16         vector v;
  17         string prefix, s;
  18         switch(status)
  19         {
  20                 case URL_READY_CANWRITE:
  21                         // we can write
  22                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  23                         url_fputs(fh, "#begin statsfile\n");
  24                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  25 #ifdef WATERMARK
  26                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  27 #endif
  28                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  29                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  30                         n = tokenizebyseparator(cvar_purechanges, "\n");
  31                         for(i = 0; i < n; ++i)
  32                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  33                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  34                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  35                                 {
  36                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  37                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  38                                         if(v != '0 0 0')
  39                                         {
  40                                                 //vector is: kills hits damage
  41                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  42                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  43                                         }
  44                                 }
  45                         url_fputs(fh, "#end\n\n");
  46                         url_fclose(fh);
  47                         break;
  48                 case URL_READY_CANREAD:
  49                         // url_fclose is processing, we got a response for writing the data
  50                         // this must come from HTTP
  51                         print("Got response from weapon stats server:\n");
  52                         while((s = url_fgets(fh)))
  53                                 print("  ", s, "\n");
  54                         print("End of response.\n");
  55                         url_fclose(fh);
  56                         break;
  57                 case URL_READY_CLOSED:
  58                         // url_fclose has finished
  59                         print("Weapon stats written\n");
  60                         buf_del(weaponstats_buffer);
  61                         weaponstats_buffer = -1;
  62                         break;
  63                 case URL_READY_ERROR:
  64                 default:
  65                         print("Weapon stats writing failed: ", ftos(status), "\n");
  66                         buf_del(weaponstats_buffer);
  67                         weaponstats_buffer = -1;
  68                         break;
  69         }
  70 }
  71
  72 void WeaponStats_Shutdown()
  73 {
  74         if(weaponstats_buffer < 0)
  75                 return;
  76         if(autocvar_sv_weaponstats_file != "")
  77         {
  78                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  79         }
  80         else
  81         {
  82                 buf_del(weaponstats_buffer);
  83                 weaponstats_buffer = -1;
  84         }
  85 }
  86
  87 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  88 {
  89         float idx;
  90         if(weaponstats_buffer < 0)
  91                 return;
  92         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  93                 return;
  94         if(awep > WEP_LAST || vwep > WEP_LAST)
  95                 return;
  96         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  97         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  98 }
  99 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 100 {
 101         if(damage < 0)
 102                 error("negative damage?");
 103         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 104 }
 105 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 106 {
 107         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 108 }
 109
 110 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 111 // merged player_run and player_stand to player_anim
 112 // added death animations to player_anim
 113 // can now spawn thrown weapons from anywhere, not just from players
 114 // thrown weapons now fade out after 20 seconds
 115 // created PlayerGib function
 116 // PlayerDie no longer uses hitloc or damage
 117 // PlayerDie now supports dying animations as well as gibbing
 118 // cleaned up PlayerDie a lot
 119 // added CopyBody
 120
 121 .entity pusher;
 122 .float pushltime;
 123 .float istypefrag;
 124
 125 .float CopyBody_nextthink;
 126 .void(void) CopyBody_think;
 127 void CopyBody_Think(void)
 128 {
 129         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 130         {
 131                 self.CopyBody_think();
 132                 if(wasfreed(self))
 133                         return;
 134                 self.CopyBody_nextthink = self.nextthink;
 135                 self.CopyBody_think = self.think;
 136                 self.think = CopyBody_Think;
 137         }
 138         CSQCMODEL_AUTOUPDATE();
 139         self.nextthink = time;
 140 }
 141 void CopyBody(float keepvelocity)
 142 {
 143         entity oldself;
 144         if (self.effects & EF_NODRAW)
 145                 return;
 146         oldself = self;
 147         self = spawn();
 148         self.enemy = oldself;
 149         self.lip = oldself.lip;
 150         self.colormap = oldself.colormap;
 151         self.iscreature = oldself.iscreature;
 152         self.teleportable = oldself.teleportable;
 153         self.damagedbycontents = oldself.damagedbycontents;
 154         self.angles = oldself.angles;
 155         self.avelocity = oldself.avelocity;
 156         self.classname = "body";
 157         self.damageforcescale = oldself.damageforcescale;
 158         self.effects = oldself.effects;
 159         self.glowmod = oldself.glowmod;
 160         self.event_damage = oldself.event_damage;
 161         self.anim_state = oldself.anim_state;
 162         self.anim_time = oldself.anim_time;
 163         self.anim_lower_action = oldself.anim_lower_action;
 164         self.anim_lower_time = oldself.anim_lower_time;
 165         self.anim_upper_action = oldself.anim_upper_action;
 166         self.anim_upper_time = oldself.anim_upper_time;
 167         self.anim_implicit_state = oldself.anim_implicit_state;
 168         self.anim_implicit_time = oldself.anim_implicit_time;
 169         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 170         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 171         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 172         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 173         self.dphitcontentsmask = oldself.dphitcontentsmask;
 174         self.death_time = oldself.death_time;
 175         self.pain_finished = oldself.pain_finished;
 176         self.health = oldself.health;
 177         self.armorvalue = oldself.armorvalue;
 178         self.armortype = oldself.armortype;
 179         self.model = oldself.model;
 180         self.modelindex = oldself.modelindex;
 181         self.skin = oldself.skin;
 182         self.species = oldself.species;
 183         self.movetype = oldself.movetype;
 184         self.solid = oldself.solid;
 185         self.ballistics_density = oldself.ballistics_density;
 186         self.takedamage = oldself.takedamage;
 187         self.customizeentityforclient = oldself.customizeentityforclient;
 188         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 189         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 190         if (keepvelocity == 1)
 191                 self.velocity = oldself.velocity;
 192         self.oldvelocity = self.velocity;
 193         self.alpha = oldself.alpha;
 194         self.fade_time = oldself.fade_time;
 195         self.fade_rate = oldself.fade_rate;
 196         //self.weapon = oldself.weapon;
 197         setorigin(self, oldself.origin);
 198         setsize(self, oldself.mins, oldself.maxs);
 199         self.prevorigin = oldself.origin;
 200         self.reset = SUB_Remove;
 201
 202         Drag_MoveDrag(oldself, self);
 203
 204         if(self.colormap <= maxclients && self.colormap > 0)
 205                 self.colormap = 1024 + oldself.clientcolors;
 206
 207         CSQCMODEL_AUTOINIT();
 208         self.CopyBody_nextthink = oldself.nextthink;
 209         self.CopyBody_think = oldself.think;
 210         self.nextthink = time;
 211         self.think = CopyBody_Think;
 212         // "bake" the current animation frame for clones (they don't get clientside animation)
 213         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 214
 215         self = oldself;
 216 }
 217
 218 float player_getspecies()
 219 {
 220         float s;
 221         get_model_parameters(self.model, self.skin);
 222         s = get_model_parameters_species;
 223         get_model_parameters(string_null, 0);
 224         if(s < 0)
 225                 return SPECIES_HUMAN;
 226         return s;
 227 }
 228
 229 void player_setupanimsformodel()
 230 {
 231         // load animation info
 232         animdecide_init(self);
 233         animdecide_setstate(self, 0, FALSE);
 234 }
 235
 236 void player_anim (void)
 237 {
 238         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 239         if(self.deadflag && !deadbits)
 240                 if(random() < 0.5)
 241                         deadbits = ANIMSTATE_DEAD1;
 242                 else
 243                         deadbits = ANIMSTATE_DEAD2;
 244         float animbits = deadbits;
 245         if(self.freezetag_frozen)
 246                 animbits |= ANIMSTATE_FROZEN;
 247         if(self.crouch)
 248                 animbits |= ANIMSTATE_DUCK;
 249         animdecide_setstate(self, animbits, FALSE);
 250         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 251
 252         if (self.weaponentity)
 253         {
 254                 updateanim(self.weaponentity);
 255                 if (!self.weaponentity.animstate_override)
 256                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 257         }
 258 }
 259
 260 void SpawnThrownWeapon (vector org, float w)
 261 {
 262         if(self.weapons & WepSet_FromWeapon(self.weapon))
 263                 if(W_IsWeaponThrowable(self.weapon))
 264                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 265 }
 266
 267 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 268 {
 269         float take, save;
 270         vector v;
 271         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 272
 273         // damage resistance (ignore most of the damage from a bullet or similar)
 274         damage = max(damage - 5, 1);
 275
 276         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 277         take = v_x;
 278         save = v_y;
 279
 280         if(sound_allowed(MSG_BROADCAST, attacker))
 281         {
 282                 if (save > 10)
 283                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 284                 else if (take > 30)
 285                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 286                 else if (take > 10)
 287                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 288         }
 289
 290         if (take > 50)
 291                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 292         if (take > 100)
 293                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 294
 295         if (!(self.flags & FL_GODMODE))
 296         {
 297                 self.armorvalue = self.armorvalue - save;
 298                 self.health = self.health - take;
 299                 // pause regeneration for 5 seconds
 300                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 301         }
 302         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 303         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 304         self.dmg_inflictor = inflictor;
 305
 306         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 307         {
 308                 // don't use any animations as a gib
 309                 self.frame = 0;
 310                 // view just above the floor
 311                 self.view_ofs = '0 0 4';
 312
 313                 Violence_GibSplash(self, 1, 1, attacker);
 314                 self.alpha = -1;
 315                 self.solid = SOLID_NOT; // restore later
 316                 self.takedamage = DAMAGE_NO; // restore later
 317                 self.damagedbycontents = FALSE;
 318         }
 319 }
 320
 321 void ClientKill_Now_TeamChange();
 322
 323 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 324 {
 325         float take, save, waves, sdelay, dh, da, j;
 326         vector v;
 327         float valid_damage_for_weaponstats;
 328         float excess;
 329
 330         dh = max(self.health, 0);
 331         da = max(self.armorvalue, 0);
 332
 333         if(!DEATH_ISSPECIAL(deathtype))
 334         {
 335                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 336                 if(self != attacker)
 337                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 338         }
 339
 340         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 341         {
 342                 // tuba causes blood to come out of the ears
 343                 vector ear1, ear2;
 344                 vector d;
 345                 float f;
 346                 ear1 = self.origin;
 347                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 348                 ear2 = ear1;
 349                 makevectors(self.angles);
 350                 ear1 += v_right * -10;
 351                 ear2 += v_right * +10;
 352                 d = inflictor.origin - self.origin;
 353                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 354                 force = v_right * vlen(force);
 355                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 356                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 357                 if(f > 0)
 358                 {
 359                         hitloc = ear1;
 360                         force = force * -1;
 361                 }
 362                 else
 363                 {
 364                         hitloc = ear2;
 365                         // force is already good
 366                 }
 367         }
 368         else
 369                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 370
 371
 372         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 373         take = v_x;
 374         save = v_y;
 375
 376         if(attacker == self)
 377         {
 378                 // don't reset pushltime for self damage as it may be an attempt to
 379                 // escape a lava pit or similar
 380                 //self.pushltime = 0;
 381                 self.istypefrag = 0;
 382         }
 383         else if(IS_PLAYER(attacker))
 384         {
 385                 self.pusher = attacker;
 386                 self.pushltime = time + autocvar_g_maxpushtime;
 387                 self.istypefrag = self.BUTTON_CHAT;
 388         }
 389         else if(time < self.pushltime)
 390         {
 391                 attacker = self.pusher;
 392                 self.pushltime = max(self.pushltime, time + 0.6);
 393         }
 394         else
 395         {
 396                 self.pushltime = 0;
 397                 self.istypefrag = 0;
 398         }
 399
 400         frag_inflictor = inflictor;
 401         frag_attacker = attacker;
 402         frag_target = self;
 403         frag_damage = damage;
 404         damage_take = take;
 405         damage_save = save;
 406         damage_force = force;
 407         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 408         take = bound(0, damage_take, self.health);
 409         save = bound(0, damage_save, self.armorvalue);
 410         excess = max(0, damage - take - save);
 411
 412         if(sound_allowed(MSG_BROADCAST, attacker))
 413         {
 414                 if (save > 10)
 415                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 416                 else if (take > 30)
 417                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 418                 else if (take > 10)
 419                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 420         }
 421
 422         if (take > 50)
 423                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 424         if (take > 100)
 425                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 426
 427         if (time >= self.spawnshieldtime)
 428         {
 429                 if (!(self.flags & FL_GODMODE))
 430                 {
 431                         self.armorvalue = self.armorvalue - save;
 432                         self.health = self.health - take;
 433                         // pause regeneration for 5 seconds
 434                         if(take)
 435                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 436
 437                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 438                         {
 439                                 self.pain_finished = time + 0.5;        //Supajoe
 440
 441                                 if(autocvar_sv_gentle < 1) {
 442                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 443                                         {
 444                                                 if (!self.animstate_override)
 445                                                 {
 446                                                         if (random() > 0.5)
 447                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 448                                                         else
 449                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 450                                                 }
 451                                         }
 452
 453                                         if(sound_allowed(MSG_BROADCAST, attacker))
 454                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 455                                         if(self.health > 1)
 456                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 457                                         {
 458                                                 if(deathtype == DEATH_FALL)
 459                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 460                                                 else if(self.health > 75) // TODO make a "gentle" version?
 461                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 462                                                 else if(self.health > 50)
 463                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 464                                                 else if(self.health > 25)
 465                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 466                                                 else
 467                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 468                                         }
 469                                 }
 470
 471                                 // throw off bot aim temporarily
 472                                 float shake;
 473                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 474                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 475                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 476                         }
 477                 }
 478                 else
 479                         self.max_armorvalue += (save + take);
 480         }
 481         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 482         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 483         self.dmg_inflictor = inflictor;
 484
 485         float abot, vbot, awep;
 486         abot = (IS_BOT_CLIENT(attacker));
 487         vbot = (IS_BOT_CLIENT(self));
 488
 489         valid_damage_for_weaponstats = 0;
 490         awep = 0;
 491
 492         if(vbot || IS_REAL_CLIENT(self))
 493         if(abot || IS_REAL_CLIENT(attacker))
 494         if(attacker && self != attacker)
 495         if(IsDifferentTeam(self, attacker))
 496         {
 497                 if(DEATH_ISSPECIAL(deathtype))
 498                         awep = attacker.weapon;
 499                 else
 500                         awep = DEATH_WEAPONOF(deathtype);
 501                 valid_damage_for_weaponstats = 1;
 502         }
 503
 504         if(valid_damage_for_weaponstats)
 505         {
 506                 dh = dh - max(self.health, 0);
 507                 da = da - max(self.armorvalue, 0);
 508                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 509         }
 510
 511         if (self.health < 1)
 512         {
 513                 float defer_ClientKill_Now_TeamChange;
 514                 defer_ClientKill_Now_TeamChange = FALSE;
 515
 516                 if(self.alivetime)
 517                 {
 518                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 519                         self.alivetime = 0;
 520                 }
 521
 522                 if(valid_damage_for_weaponstats)
 523                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 524
 525                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 526                 if(sound_allowed(MSG_BROADCAST, attacker))
 527                 {
 528                         if(deathtype == DEATH_DROWN)
 529                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 530                         else
 531                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 532                 }
 533
 534                 // get rid of kill indicator
 535                 if(self.killindicator)
 536                 {
 537                         remove(self.killindicator);
 538                         self.killindicator = world;
 539                         if(self.killindicator_teamchange)
 540                                 defer_ClientKill_Now_TeamChange = TRUE;
 541
 542                         if(self.classname == "body")
 543                         if(deathtype == DEATH_KILL)
 544                         {
 545                                 // for the lemmings fans, a small harmless explosion
 546                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 547                         }
 548                 }
 549
 550                 // print an obituary message
 551                 Obituary (attacker, inflictor, self, deathtype);
 552                 race_PreDie();
 553
 554         // increment frag counter for used weapon type
 555         float w;
 556         w = DEATH_WEAPONOF(deathtype);
 557         if(WEP_VALID(w))
 558         if(accuracy_isgooddamage(attacker, self))
 559         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 560
 561                 frag_attacker = attacker;
 562                 frag_inflictor = inflictor;
 563                 frag_target = self;
 564                 frag_deathtype = deathtype;
 565                 MUTATOR_CALLHOOK(PlayerDies);
 566
 567                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 568
 569                 RemoveGrapplingHook(self);
 570
 571                 Portal_ClearAllLater(self);
 572
 573                 if(IS_REAL_CLIENT(self))
 574                 {
 575                         self.fixangle = TRUE;
 576                         //msg_entity = self;
 577                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 578                         //WriteAngle (MSG_ONE, self.v_angle_x);
 579                         //WriteAngle (MSG_ONE, self.v_angle_y);
 580                         //WriteAngle (MSG_ONE, 80);
 581                 }
 582
 583                 if(defer_ClientKill_Now_TeamChange)
 584                         ClientKill_Now_TeamChange(); // can turn player into spectator
 585
 586                 // player could have been miraculously resuscitated ;)
 587                 // e.g. players in freezetag get frozen, they don't really die
 588                 if(self.health >= 1 || !IS_PLAYER(self))
 589                         return;
 590
 591                 // when we get here, player actually dies
 592
 593                 // clear waypoints
 594                 WaypointSprite_PlayerDead();
 595                 // throw a weapon
 596                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 597
 598                 // become fully visible
 599                 self.alpha = default_player_alpha;
 600                 // make the corpse upright (not tilted)
 601                 self.angles_x = 0;
 602                 self.angles_z = 0;
 603                 // don't spin
 604                 self.avelocity = '0 0 0';
 605                 // view from the floor
 606                 self.view_ofs = '0 0 -8';
 607                 // toss the corpse
 608                 self.movetype = MOVETYPE_TOSS;
 609                 // shootable corpse
 610                 self.solid = SOLID_CORPSE;
 611                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 612                 // don't stick to the floor
 613                 self.flags &= ~FL_ONGROUND;
 614                 // dying animation
 615                 self.deadflag = DEAD_DYING;
 616                 // when to allow respawn
 617                 sdelay = 0;
 618                 waves = 0;
 619                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 620                 if(!sdelay)
 621                 {
 622                         if(g_cts)
 623                                 sdelay = 0; // no respawn delay in CTS
 624                         else
 625                                 sdelay = autocvar_g_respawn_delay;
 626                 }
 627                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 628                 if(!waves)
 629                         waves = autocvar_g_respawn_waves;
 630                 if(waves)
 631                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 632                 else
 633                         self.respawn_time = time + sdelay;
 634                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 635                         self.respawn_countdown = 10; // first number to count down from is 10
 636                 else
 637                         self.respawn_countdown = -1; // do not count down
 638
 639                 if(g_cts || autocvar_g_forced_respawn)
 640                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 641
 642                 self.death_time = time;
 643                 if (random() < 0.5)
 644                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 645                 else
 646                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 647                 if (self.maxs_z > 5)
 648                 {
 649                         self.maxs_z = 5;
 650                         setsize(self, self.mins, self.maxs);
 651                 }
 652                 // set damage function to corpse damage
 653                 self.event_damage = PlayerCorpseDamage;
 654                 // call the corpse damage function just in case it wants to gib
 655                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 656                 // set up to fade out later
 657                 SUB_SetFade (self, time + 6 + random (), 1);
 658
 659                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 660                         // remove corpse
 661                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 662                 }
 663
 664                 // reset fields the weapons may use just in case
 665                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 666                 {
 667                         WEP_ACTION(j, WR_RESETPLAYER);
 668                         ATTACK_FINISHED_FOR(self, j) = 0;
 669                 }
 670         }
 671 }
 672
 673 .float muted; // to be used by prvm_edictset server playernumber muted 1
 674 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 675 // message "": do not say, just test flood control
 676 // return value:
 677 //   1 = accept
 678 //   0 = reject
 679 //  -1 = fake accept
 680 {
 681         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 682         float flood;
 683         var .float flood_field;
 684         entity head;
 685         float ret;
 686         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 687
 688         if(!teamsay && !privatesay)
 689                 if(substring(msgin, 0, 1) == " ")
 690                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 691
 692         msgin = formatmessage(msgin);
 693
 694         if not(IS_PLAYER(source))
 695                 colorstr = "^0"; // black for spectators
 696         else if(teamplay)
 697                 colorstr = Team_ColorCode(source.team);
 698         else
 699         {
 700                 colorstr = "";
 701                 teamsay = FALSE;
 702         }
 703
 704         if(intermission_running)
 705                 teamsay = FALSE;
 706
 707         if(msgin != "")
 708                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 709
 710         /*
 711          * using bprint solves this... me stupid
 712         // how can we prevent the message from appearing in a listen server?
 713         // for now, just give "say" back and only handle say_team
 714         if(!teamsay)
 715         {
 716                 clientcommand(self, strcat("say ", msgin));
 717                 return;
 718         }
 719         */
 720
 721         if(autocvar_g_chat_teamcolors)
 722                 namestr = playername(source);
 723         else
 724                 namestr = source.netname;
 725
 726         if(msgin != "")
 727         {
 728                 if(privatesay)
 729                 {
 730                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 731                         privatemsgprefixlen = strlen(msgstr);
 732                         msgstr = strcat(msgstr, msgin);
 733                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 734                         if(autocvar_g_chat_teamcolors)
 735                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 736                         else
 737                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 738                 }
 739                 else if(teamsay)
 740                 {
 741                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 742                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 743                 }
 744                 else
 745                 {
 746                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 747                         cmsgstr = "";
 748                 }
 749                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 750         }
 751         else
 752         {
 753                 msgstr = cmsgstr = "";
 754         }
 755
 756         fullmsgstr = msgstr;
 757         fullcmsgstr = cmsgstr;
 758
 759         // FLOOD CONTROL
 760         flood = 0;
 761         flood_field = floodcontrol_chat;
 762         if(floodcontrol)
 763         {
 764                 float flood_spl;
 765                 float flood_burst;
 766                 float flood_lmax;
 767                 float lines;
 768                 if(privatesay)
 769                 {
 770                         flood_spl = autocvar_g_chat_flood_spl_tell;
 771                         flood_burst = autocvar_g_chat_flood_burst_tell;
 772                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 773                         flood_field = floodcontrol_chattell;
 774                 }
 775                 else if(teamsay)
 776                 {
 777                         flood_spl = autocvar_g_chat_flood_spl_team;
 778                         flood_burst = autocvar_g_chat_flood_burst_team;
 779                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 780                         flood_field = floodcontrol_chatteam;
 781                 }
 782                 else
 783                 {
 784                         flood_spl = autocvar_g_chat_flood_spl;
 785                         flood_burst = autocvar_g_chat_flood_burst;
 786                         flood_lmax = autocvar_g_chat_flood_lmax;
 787                         flood_field = floodcontrol_chat;
 788                 }
 789                 flood_burst = max(0, flood_burst - 1);
 790                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 791
 792                 // do flood control for the default line size
 793                 if(msgstr != "")
 794                 {
 795                         getWrappedLine_remaining = msgstr;
 796                         msgstr = "";
 797                         lines = 0;
 798                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 799                         {
 800                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 801                                 ++lines;
 802                         }
 803                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 804
 805                         if(getWrappedLine_remaining != "")
 806                         {
 807                                 msgstr = strcat(msgstr, "\n");
 808                                 flood = 2;
 809                         }
 810
 811                         if(time >= source.flood_field)
 812                         {
 813                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 814                         }
 815                         else
 816                         {
 817                                 flood = 1;
 818                                 msgstr = fullmsgstr;
 819                         }
 820                 }
 821                 else
 822                 {
 823                         if(time >= source.flood_field)
 824                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 825                         else
 826                                 flood = 1;
 827                 }
 828
 829                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 830                         source.flood_field = flood = 0;
 831         }
 832
 833         if(flood == 2) // cannot happen for empty msgstr
 834         {
 835                 if(autocvar_g_chat_flood_notify_flooder)
 836                 {
 837                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 838                         sourcecmsgstr = "";
 839                 }
 840                 else
 841                 {
 842                         sourcemsgstr = fullmsgstr;
 843                         sourcecmsgstr = fullcmsgstr;
 844                 }
 845                 cmsgstr = "";
 846         }
 847         else
 848         {
 849                 sourcemsgstr = msgstr;
 850                 sourcecmsgstr = cmsgstr;
 851         }
 852
 853         if(!privatesay)
 854         if not(IS_PLAYER(source))
 855         {
 856                 if not(intermission_running)
 857                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 858                                 teamsay = -1; // spectators
 859         }
 860
 861         if(flood)
 862                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 863
 864         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 865         if(privatesay)
 866                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 867
 868         if(source.muted)
 869         {
 870                 // always fake the message
 871                 ret = -1;
 872         }
 873         else if(flood == 1)
 874         {
 875                 if(autocvar_g_chat_flood_notify_flooder)
 876                 {
 877                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 878                         ret = 0;
 879                 }
 880                 else
 881                         ret = -1;
 882         }
 883         else
 884         {
 885                 ret = 1;
 886         }
 887
 888         if(sourcemsgstr != "" && ret != 0)
 889         {
 890                 if(ret < 0) // faked message, because the player is muted
 891                 {
 892                         sprint(source, sourcemsgstr);
 893                         if(sourcecmsgstr != "" && !privatesay)
 894                                 centerprint(source, sourcecmsgstr);
 895                 }
 896                 else if(privatesay) // private message, between 2 people only
 897                 {
 898                         sprint(source, sourcemsgstr);
 899                         sprint(privatesay, msgstr);
 900                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 901                         if(cmsgstr != "")
 902                                 centerprint(privatesay, cmsgstr);
 903                 }
 904                 else if(teamsay > 0) // team message, only sent to team mates
 905                 {
 906                         sprint(source, sourcemsgstr);
 907                         dedicated_print(msgstr); // send to server console too
 908                         if(sourcecmsgstr != "")
 909                                 centerprint(source, sourcecmsgstr);
 910                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 911                                 if(head != source)
 912                                 {
 913                                         sprint(head, msgstr);
 914                                         if(cmsgstr != "")
 915                                                 centerprint(head, cmsgstr);
 916                                 }
 917                 }
 918                 else if(teamsay < 0) // spectator message, only sent to spectators
 919                 {
 920                         sprint(source, sourcemsgstr);
 921                         dedicated_print(msgstr); // send to server console too
 922                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 923                                 if(head != source)
 924                                         sprint(head, msgstr);
 925                 }
 926                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 927                 {
 928                         sprint(source, sourcemsgstr);
 929                         dedicated_print(msgstr); // send to server console too
 930                         FOR_EACH_REALCLIENT(head)
 931                                 if(head != source)
 932                                         sprint(head, msgstr);
 933                 }
 934                 else
 935                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 936         }
 937
 938         return ret;
 939 }
 940
 941 float GetVoiceMessageVoiceType(string type)
 942 {
 943         if(type == "taunt")
 944                 return VOICETYPE_TAUNT;
 945         if(type == "teamshoot")
 946                 return VOICETYPE_LASTATTACKER;
 947         return VOICETYPE_TEAMRADIO;
 948 }
 949
 950 string allvoicesamples;
 951 .string GetVoiceMessageSampleField(string type)
 952 {
 953         GetPlayerSoundSampleField_notFound = 0;
 954         switch(type)
 955         {
 956 #define _VOICEMSG(m) case #m: return playersound_##m;
 957                 ALLVOICEMSGS
 958 #undef _VOICEMSG
 959         }
 960         GetPlayerSoundSampleField_notFound = 1;
 961         return playersound_taunt;
 962 }
 963
 964 .string GetPlayerSoundSampleField(string type)
 965 {
 966         GetPlayerSoundSampleField_notFound = 0;
 967         switch(type)
 968         {
 969 #define _VOICEMSG(m) case #m: return playersound_##m;
 970                 ALLPLAYERSOUNDS
 971 #undef _VOICEMSG
 972         }
 973         GetPlayerSoundSampleField_notFound = 1;
 974         return playersound_taunt;
 975 }
 976
 977 void PrecacheGlobalSound(string samplestring)
 978 {
 979         float n, i;
 980         tokenize_console(samplestring);
 981         n = stof(argv(1));
 982         if(n > 0)
 983         {
 984                 for(i = 1; i <= n; ++i)
 985                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 986         }
 987         else
 988         {
 989                 precache_sound(strcat(argv(0), ".wav"));
 990         }
 991 }
 992
 993 void PrecachePlayerSounds(string f)
 994 {
 995         float fh;
 996         string s;
 997         fh = fopen(f, FILE_READ);
 998         if(fh < 0)
 999                 return;
1000         while((s = fgets(fh)))
1001         {
1002                 if(tokenize_console(s) != 3)
1003                 {
1004                         dprint("Invalid sound info line: ", s, "\n");
1005                         continue;
1006                 }
1007                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1008         }
1009         fclose(fh);
1010
1011         if not(allvoicesamples)
1012         {
1013 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1014                 ALLVOICEMSGS
1015 #undef _VOICEMSG
1016                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1017         }
1018 }
1019
1020 void ClearPlayerSounds()
1021 {
1022 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1023         ALLPLAYERSOUNDS
1024         ALLVOICEMSGS
1025 #undef _VOICEMSG
1026 }
1027
1028 float LoadPlayerSounds(string f, float first)
1029 {
1030         float fh;
1031         string s;
1032         var .string field;
1033         fh = fopen(f, FILE_READ);
1034         if(fh < 0)
1035         {
1036                 dprint("Player sound file not found: ", f, "\n");
1037                 return 0;
1038         }
1039         while((s = fgets(fh)))
1040         {
1041                 if(tokenize_console(s) != 3)
1042                         continue;
1043                 field = GetPlayerSoundSampleField(argv(0));
1044                 if(GetPlayerSoundSampleField_notFound)
1045                         field = GetVoiceMessageSampleField(argv(0));
1046                 if(GetPlayerSoundSampleField_notFound)
1047                         continue;
1048                 if(self.field)
1049                         strunzone(self.field);
1050                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1051         }
1052         fclose(fh);
1053         return 1;
1054 }
1055
1056 .float modelindex_for_playersound;
1057 .float skin_for_playersound;
1058 void UpdatePlayerSounds()
1059 {
1060         if(self.modelindex == self.modelindex_for_playersound)
1061         if(self.skin == self.skin_for_playersound)
1062                 return;
1063         self.modelindex_for_playersound = self.modelindex;
1064         self.skin_for_playersound = self.skin;
1065         ClearPlayerSounds();
1066         LoadPlayerSounds("sound/player/default.sounds", 1);
1067         if(!autocvar_g_debug_defaultsounds)
1068                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1069                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1070 }
1071
1072 void FakeGlobalSound(string sample, float chan, float voicetype)
1073 {
1074         float n;
1075         float tauntrand;
1076
1077         if(sample == "")
1078                 return;
1079
1080         tokenize_console(sample);
1081         n = stof(argv(1));
1082         if(n > 0)
1083                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1084         else
1085                 sample = strcat(argv(0), ".wav"); // randomization
1086
1087         switch(voicetype)
1088         {
1089                 case VOICETYPE_LASTATTACKER_ONLY:
1090                         break;
1091                 case VOICETYPE_LASTATTACKER:
1092                         if(self.pusher)
1093                         {
1094                                 msg_entity = self;
1095                                 if(IS_REAL_CLIENT(msg_entity))
1096                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1097                         }
1098                         break;
1099                 case VOICETYPE_TEAMRADIO:
1100                         msg_entity = self;
1101                         if(msg_entity.cvar_cl_voice_directional == 1)
1102                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1103                         else
1104                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1105                         break;
1106                 case VOICETYPE_AUTOTAUNT:
1107                         if(!sv_autotaunt)
1108                                 break;
1109                         if(!sv_taunt)
1110                                 break;
1111                         if(autocvar_sv_gentle)
1112                                 break;
1113                         tauntrand = random();
1114                         msg_entity = self;
1115                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1116                         {
1117                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1118                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1119                                 else
1120                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1121                         }
1122                         break;
1123                 case VOICETYPE_TAUNT:
1124                         if(IS_PLAYER(self))
1125                                 if(self.deadflag == DEAD_NO)
1126                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1127                         if(!sv_taunt)
1128                                 break;
1129                         if(autocvar_sv_gentle)
1130                                 break;
1131                         msg_entity = self;
1132                         if (msg_entity.cvar_cl_voice_directional >= 1)
1133                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1134                         else
1135                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1136                         break;
1137                 case VOICETYPE_PLAYERSOUND:
1138                         msg_entity = self;
1139                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1140                         break;
1141                 default:
1142                         backtrace("Invalid voice type!");
1143                         break;
1144         }
1145 }
1146
1147 void GlobalSound(string sample, float chan, float voicetype)
1148 {
1149         float n;
1150         float tauntrand;
1151
1152         if(sample == "")
1153                 return;
1154
1155         tokenize_console(sample);
1156         n = stof(argv(1));
1157         if(n > 0)
1158                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1159         else
1160                 sample = strcat(argv(0), ".wav"); // randomization
1161
1162         switch(voicetype)
1163         {
1164                 case VOICETYPE_LASTATTACKER_ONLY:
1165                         if(self.pusher)
1166                         {
1167                                 msg_entity = self.pusher;
1168                                 if(IS_REAL_CLIENT(msg_entity))
1169                                 {
1170                                         if(msg_entity.cvar_cl_voice_directional == 1)
1171                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1172                                         else
1173                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1174                                 }
1175                         }
1176                         break;
1177                 case VOICETYPE_LASTATTACKER:
1178                         if(self.pusher)
1179                         {
1180                                 msg_entity = self.pusher;
1181                                 if(IS_REAL_CLIENT(msg_entity))
1182                                 {
1183                                         if(msg_entity.cvar_cl_voice_directional == 1)
1184                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1185                                         else
1186                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1187                                 }
1188                                 msg_entity = self;
1189                                 if(IS_REAL_CLIENT(msg_entity))
1190                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1191                         }
1192                         break;
1193                 case VOICETYPE_TEAMRADIO:
1194                         FOR_EACH_REALCLIENT(msg_entity)
1195                                 if(!teamplay || msg_entity.team == self.team)
1196                                 {
1197                                         if(msg_entity.cvar_cl_voice_directional == 1)
1198                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1199                                         else
1200                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1201                                 }
1202                         break;
1203                 case VOICETYPE_AUTOTAUNT:
1204                         if(!sv_autotaunt)
1205                                 break;
1206                         if(!sv_taunt)
1207                                 break;
1208                         if(autocvar_sv_gentle)
1209                                 break;
1210                         tauntrand = random();
1211                         FOR_EACH_REALCLIENT(msg_entity)
1212                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1213                                 {
1214                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1215                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1216                                         else
1217                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1218                                 }
1219                         break;
1220                 case VOICETYPE_TAUNT:
1221                         if(IS_PLAYER(self))
1222                                 if(self.deadflag == DEAD_NO)
1223                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1224                         if(!sv_taunt)
1225                                 break;
1226                         if(autocvar_sv_gentle)
1227                                 break;
1228                         FOR_EACH_REALCLIENT(msg_entity)
1229                         {
1230                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1231                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1232                                 else
1233                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1234                         }
1235                         break;
1236                 case VOICETYPE_PLAYERSOUND:
1237                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1238                         break;
1239                 default:
1240                         backtrace("Invalid voice type!");
1241                         break;
1242         }
1243 }
1244
1245 void PlayerSound(.string samplefield, float chan, float voicetype)
1246 {
1247         GlobalSound(self.samplefield, chan, voicetype);
1248 }
1249
1250 void VoiceMessage(string type, string msg)
1251 {
1252         var .string sample;
1253         float voicetype, ownteam;
1254         float flood;
1255         sample = GetVoiceMessageSampleField(type);
1256
1257         if(GetPlayerSoundSampleField_notFound)
1258         {
1259                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1260                 return;
1261         }
1262
1263         voicetype = GetVoiceMessageVoiceType(type);
1264         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1265
1266         flood = Say(self, ownteam, world, msg, 1);
1267
1268         if (flood > 0)
1269                 GlobalSound(self.sample, CH_VOICE, voicetype);
1270         else if (flood < 0)
1271                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1272 }
1273
1274 void MoveToTeam(entity client, float team_colour, float type)
1275 {
1276         float lockteams_backup;
1277
1278         lockteams_backup = lockteams;  // backup any team lock
1279
1280         lockteams = 0;  // disable locked teams
1281
1282         TeamchangeFrags(client);  // move the players frags
1283         SetPlayerColors(client, team_colour - 1);  // set the players colour
1284         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1285
1286         lockteams = lockteams_backup;  // restore the team lock
1287
1288         LogTeamchange(client.playerid, client.team, type);
1289 }