qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_pinata)
 266         {
 267                 float j;
 268                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 269                 {
 270                         if(WEPSET_CONTAINS_EW(self, j))
 271                                 if(W_IsWeaponThrowable(j))
 272                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 273                 }
 274         }
 275         else
 276         {
 277                 if(W_IsWeaponThrowable(self.weapon))
 278                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 279         }
 280 }
 281
 282 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 283 {
 284         float take, save;
 285         vector v;
 286         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 287
 288         // damage resistance (ignore most of the damage from a bullet or similar)
 289         damage = max(damage - 5, 1);
 290
 291         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 292         take = v_x;
 293         save = v_y;
 294
 295         if(sound_allowed(MSG_BROADCAST, attacker))
 296         {
 297                 if (save > 10)
 298                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 299                 else if (take > 30)
 300                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 301                 else if (take > 10)
 302                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 303         }
 304
 305         if (take > 50)
 306                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 307         if (take > 100)
 308                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 309
 310         if (!(self.flags & FL_GODMODE))
 311         {
 312                 self.armorvalue = self.armorvalue - save;
 313                 self.health = self.health - take;
 314                 // pause regeneration for 5 seconds
 315                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 316         }
 317         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 318         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 319         self.dmg_inflictor = inflictor;
 320
 321         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 322         {
 323                 // don't use any animations as a gib
 324                 self.frame = 0;
 325                 // view just above the floor
 326                 self.view_ofs = '0 0 4';
 327
 328                 Violence_GibSplash(self, 1, 1, attacker);
 329                 self.alpha = -1;
 330                 self.solid = SOLID_NOT; // restore later
 331                 self.takedamage = DAMAGE_NO; // restore later
 332                 self.damagedbycontents = FALSE;
 333         }
 334 }
 335
 336 void ClientKill_Now_TeamChange();
 337 void freezetag_CheckWinner();
 338
 339 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 340 {
 341         float take, save, waves, sdelay, dh, da, j;
 342         vector v;
 343         float valid_damage_for_weaponstats;
 344         float excess;
 345
 346         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 347                 return;
 348
 349         dh = max(self.health, 0);
 350         da = max(self.armorvalue, 0);
 351
 352         if(!DEATH_ISSPECIAL(deathtype))
 353         {
 354                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 355                 if(self != attacker)
 356                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 357         }
 358
 359         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 360         {
 361                 // tuba causes blood to come out of the ears
 362                 vector ear1, ear2;
 363                 vector d;
 364                 float f;
 365                 ear1 = self.origin;
 366                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 367                 ear2 = ear1;
 368                 makevectors(self.angles);
 369                 ear1 += v_right * -10;
 370                 ear2 += v_right * +10;
 371                 d = inflictor.origin - self.origin;
 372                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 373                 force = v_right * vlen(force);
 374                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 375                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 376                 if(f > 0)
 377                 {
 378                         hitloc = ear1;
 379                         force = force * -1;
 380                 }
 381                 else
 382                 {
 383                         hitloc = ear2;
 384                         // force is already good
 385                 }
 386         }
 387         else
 388                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 389
 390
 391         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 392         take = v_x;
 393         save = v_y;
 394
 395         if(attacker == self)
 396         {
 397                 // don't reset pushltime for self damage as it may be an attempt to
 398                 // escape a lava pit or similar
 399                 //self.pushltime = 0;
 400                 self.istypefrag = 0;
 401         }
 402         else if(attacker.classname == "player")
 403         {
 404                 self.pusher = attacker;
 405                 self.pushltime = time + autocvar_g_maxpushtime;
 406                 self.istypefrag = self.BUTTON_CHAT;
 407         }
 408         else if(time < self.pushltime)
 409         {
 410                 attacker = self.pusher;
 411                 self.pushltime = max(self.pushltime, time + 0.6);
 412         }
 413         else
 414         {
 415                 self.pushltime = 0;
 416                 self.istypefrag = 0;
 417         }
 418
 419         frag_inflictor = inflictor;
 420         frag_attacker = attacker;
 421         frag_target = self;
 422         damage_take = take;
 423         damage_save = save;
 424         damage_force = force;
 425         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 426         take = bound(0, damage_take, self.health);
 427         save = bound(0, damage_save, self.armorvalue);
 428         excess = max(0, damage - take - save);
 429
 430         if(sound_allowed(MSG_BROADCAST, attacker))
 431         {
 432                 if (save > 10)
 433                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 434                 else if (take > 30)
 435                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 436                 else if (take > 10)
 437                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 438         }
 439
 440         if (take > 50)
 441                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 442         if (take > 100)
 443                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 444
 445         if (time >= self.spawnshieldtime)
 446         {
 447                 if (!(self.flags & FL_GODMODE))
 448                 {
 449                         self.armorvalue = self.armorvalue - save;
 450                         self.health = self.health - take;
 451                         // pause regeneration for 5 seconds
 452                         if(take)
 453                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 454
 455                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 456                         {
 457                                 self.pain_finished = time + 0.5;        //Supajoe
 458
 459                                 if(autocvar_sv_gentle < 1) {
 460                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 461                                         {
 462                                                 if (!self.animstate_override)
 463                                                 {
 464                                                         if (random() > 0.5)
 465                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 466                                                         else
 467                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 468                                                 }
 469                                         }
 470
 471                                         if(sound_allowed(MSG_BROADCAST, attacker))
 472                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 473                                         if(self.health > 1)
 474                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 475                                         {
 476                                                 if(deathtype == DEATH_FALL)
 477                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 478                                                 else if(self.health > 75) // TODO make a "gentle" version?
 479                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 480                                                 else if(self.health > 50)
 481                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 482                                                 else if(self.health > 25)
 483                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 484                                                 else
 485                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 486                                         }
 487                                 }
 488
 489                                 // throw off bot aim temporarily
 490                                 float shake;
 491                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 492                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 493                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 494                         }
 495                 }
 496                 else
 497                         self.max_armorvalue += (save + take);
 498         }
 499         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 500         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 501         self.dmg_inflictor = inflictor;
 502
 503         if(g_ca && self != attacker && attacker.classname == "player")
 504                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 505
 506         float abot, vbot, awep;
 507         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 508         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 509
 510         valid_damage_for_weaponstats = 0;
 511         awep = 0;
 512
 513         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 514         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 515         if(attacker && self != attacker)
 516         if(IsDifferentTeam(self, attacker))
 517         {
 518                 if(DEATH_ISSPECIAL(deathtype))
 519                         awep = attacker.weapon;
 520                 else
 521                         awep = DEATH_WEAPONOF(deathtype);
 522                 valid_damage_for_weaponstats = 1;
 523         }
 524
 525         if(valid_damage_for_weaponstats)
 526         {
 527                 dh = dh - max(self.health, 0);
 528                 da = da - max(self.armorvalue, 0);
 529                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 530         }
 531
 532         if (self.health < 1)
 533         {
 534                 float defer_ClientKill_Now_TeamChange;
 535                 defer_ClientKill_Now_TeamChange = FALSE;
 536
 537                 if(self.alivetime)
 538                 {
 539                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 540                         self.alivetime = 0;
 541                 }
 542
 543                 if(valid_damage_for_weaponstats)
 544                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 545
 546                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 547                 if(sound_allowed(MSG_BROADCAST, attacker))
 548                 {
 549                         if(deathtype == DEATH_DROWN)
 550                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 551                         else
 552                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 553                 }
 554
 555                 // get rid of kill indicator
 556                 if(self.killindicator)
 557                 {
 558                         remove(self.killindicator);
 559                         self.killindicator = world;
 560                         if(self.killindicator_teamchange)
 561                                 defer_ClientKill_Now_TeamChange = TRUE;
 562
 563                         if(self.classname == "body")
 564                         if(deathtype == DEATH_KILL)
 565                         {
 566                                 // for the lemmings fans, a small harmless explosion
 567                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 568                         }
 569                 }
 570
 571                 if(!g_freezetag)
 572                 {
 573                         // become fully visible
 574                         self.alpha = default_player_alpha;
 575                         // throw a weapon
 576                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 577                 }
 578
 579                 // print an obituary message
 580                 Obituary (attacker, inflictor, self, deathtype);
 581                 race_PreDie();
 582
 583         // increment frag counter for used weapon type
 584         float w;
 585         w = DEATH_WEAPONOF(deathtype);
 586         if(WEP_VALID(w))
 587         if(accuracy_isgooddamage(attacker, self))
 588         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 589
 590                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 591                 {
 592                         PutClientInServer();
 593                         count_alive_players(); // re-count players
 594                         freezetag_CheckWinner();
 595                         return;
 596                 }
 597
 598                 frag_attacker = attacker;
 599                 frag_inflictor = inflictor;
 600                 frag_target = self;
 601                 MUTATOR_CALLHOOK(PlayerDies);
 602                 weapon_action(self.weapon, WR_PLAYERDEATH);
 603
 604                 RemoveGrapplingHook(self);
 605
 606                 Portal_ClearAllLater(self);
 607
 608                 if(clienttype(self) == CLIENTTYPE_REAL)
 609                 {
 610                         self.fixangle = TRUE;
 611                         //msg_entity = self;
 612                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 613                         //WriteAngle (MSG_ONE, self.v_angle_x);
 614                         //WriteAngle (MSG_ONE, self.v_angle_y);
 615                         //WriteAngle (MSG_ONE, 80);
 616                 }
 617
 618                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 619                         ClientKill_Now_TeamChange();
 620
 621                 if(g_arena)
 622                         Spawnqueue_Unmark(self);
 623
 624                 if(g_freezetag)
 625                         return;
 626
 627                 // when we get here, player actually dies
 628                 // clear waypoints (do this AFTER FreezeTag)
 629                 WaypointSprite_PlayerDead();
 630
 631                 // make the corpse upright (not tilted)
 632                 self.angles_x = 0;
 633                 self.angles_z = 0;
 634                 // don't spin
 635                 self.avelocity = '0 0 0';
 636                 // view from the floor
 637                 self.view_ofs = '0 0 -8';
 638                 // toss the corpse
 639                 self.movetype = MOVETYPE_TOSS;
 640                 // shootable corpse
 641                 self.solid = SOLID_CORPSE;
 642                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 643                 // don't stick to the floor
 644                 self.flags &~= FL_ONGROUND;
 645                 // dying animation
 646                 self.deadflag = DEAD_DYING;
 647                 // when to allow respawn
 648                 sdelay = 0;
 649                 waves = 0;
 650                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 651                 if(!sdelay)
 652                 {
 653                         if(g_cts)
 654                                 sdelay = 0; // no respawn delay in CTS
 655                         else
 656                                 sdelay = autocvar_g_respawn_delay;
 657                 }
 658                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 659                 if(!waves)
 660                         waves = autocvar_g_respawn_waves;
 661                 if(waves)
 662                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 663                 else
 664                         self.respawn_time = time + sdelay;
 665                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 666                         self.respawn_countdown = 10; // first number to count down from is 10
 667                 else
 668                         self.respawn_countdown = -1; // do not count down
 669                 self.death_time = time;
 670                 if (random() < 0.5)
 671                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 672                 else
 673                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 674                 if (self.maxs_z > 5)
 675                 {
 676                         self.maxs_z = 5;
 677                         setsize(self, self.mins, self.maxs);
 678                 }
 679                 // set damage function to corpse damage
 680                 self.event_damage = PlayerCorpseDamage;
 681                 // call the corpse damage function just in case it wants to gib
 682                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 683                 // set up to fade out later
 684                 SUB_SetFade (self, time + 6 + random (), 1);
 685
 686                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 687                         // remove corpse
 688                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 689                 }
 690
 691                 // reset fields the weapons may use just in case
 692                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 693                 {
 694                         weapon_action(j, WR_RESETPLAYER);
 695                         ATTACK_FINISHED_FOR(self, j) = 0;
 696                 }
 697         }
 698 }
 699
 700 .float muted; // to be used by prvm_edictset server playernumber muted 1
 701 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 702 // message "": do not say, just test flood control
 703 // return value:
 704 //   1 = accept
 705 //   0 = reject
 706 //  -1 = fake accept
 707 {
 708         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 709         float flood;
 710         var .float flood_field;
 711         entity head;
 712         float ret;
 713         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 714
 715         if(!teamsay && !privatesay)
 716                 if(substring(msgin, 0, 1) == " ")
 717                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 718
 719         msgin = formatmessage(msgin);
 720
 721         if(source.classname != "player")
 722                 colorstr = "^0"; // black for spectators
 723         else if(teamplay)
 724                 colorstr = Team_ColorCode(source.team);
 725         else
 726         {
 727                 colorstr = "";
 728                 teamsay = FALSE;
 729         }
 730
 731         if(intermission_running)
 732                 teamsay = FALSE;
 733
 734         if(msgin != "")
 735                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 736
 737         /*
 738          * using bprint solves this... me stupid
 739         // how can we prevent the message from appearing in a listen server?
 740         // for now, just give "say" back and only handle say_team
 741         if(!teamsay)
 742         {
 743                 clientcommand(self, strcat("say ", msgin));
 744                 return;
 745         }
 746         */
 747
 748         if(autocvar_g_chat_teamcolors)
 749                 namestr = playername(source);
 750         else
 751                 namestr = source.netname;
 752
 753         if(msgin != "")
 754         {
 755                 if(privatesay)
 756                 {
 757                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 758                         privatemsgprefixlen = strlen(msgstr);
 759                         msgstr = strcat(msgstr, msgin);
 760                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 761                         if(autocvar_g_chat_teamcolors)
 762                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 763                         else
 764                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 765                 }
 766                 else if(teamsay)
 767                 {
 768                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 769                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 770                 }
 771                 else
 772                 {
 773                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 774                         cmsgstr = "";
 775                 }
 776                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 777         }
 778         else
 779         {
 780                 msgstr = cmsgstr = "";
 781         }
 782
 783         fullmsgstr = msgstr;
 784         fullcmsgstr = cmsgstr;
 785
 786         // FLOOD CONTROL
 787         flood = 0;
 788         flood_field = floodcontrol_chat;
 789         if(floodcontrol)
 790         {
 791                 float flood_spl;
 792                 float flood_burst;
 793                 float flood_lmax;
 794                 float lines;
 795                 if(privatesay)
 796                 {
 797                         flood_spl = autocvar_g_chat_flood_spl_tell;
 798                         flood_burst = autocvar_g_chat_flood_burst_tell;
 799                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 800                         flood_field = floodcontrol_chattell;
 801                 }
 802                 else if(teamsay)
 803                 {
 804                         flood_spl = autocvar_g_chat_flood_spl_team;
 805                         flood_burst = autocvar_g_chat_flood_burst_team;
 806                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 807                         flood_field = floodcontrol_chatteam;
 808                 }
 809                 else
 810                 {
 811                         flood_spl = autocvar_g_chat_flood_spl;
 812                         flood_burst = autocvar_g_chat_flood_burst;
 813                         flood_lmax = autocvar_g_chat_flood_lmax;
 814                         flood_field = floodcontrol_chat;
 815                 }
 816                 flood_burst = max(0, flood_burst - 1);
 817                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 818
 819                 // do flood control for the default line size
 820                 if(msgstr != "")
 821                 {
 822                         getWrappedLine_remaining = msgstr;
 823                         msgstr = "";
 824                         lines = 0;
 825                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 826                         {
 827                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 828                                 ++lines;
 829                         }
 830                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 831
 832                         if(getWrappedLine_remaining != "")
 833                         {
 834                                 msgstr = strcat(msgstr, "\n");
 835                                 flood = 2;
 836                         }
 837
 838                         if(time >= source.flood_field)
 839                         {
 840                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 841                         }
 842                         else
 843                         {
 844                                 flood = 1;
 845                                 msgstr = fullmsgstr;
 846                         }
 847                 }
 848                 else
 849                 {
 850                         if(time >= source.flood_field)
 851                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 852                         else
 853                                 flood = 1;
 854                 }
 855
 856                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 857                         source.flood_field = flood = 0;
 858         }
 859
 860         if(flood == 2) // cannot happen for empty msgstr
 861         {
 862                 if(autocvar_g_chat_flood_notify_flooder)
 863                 {
 864                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 865                         sourcecmsgstr = "";
 866                 }
 867                 else
 868                 {
 869                         sourcemsgstr = fullmsgstr;
 870                         sourcecmsgstr = fullcmsgstr;
 871                 }
 872                 cmsgstr = "";
 873         }
 874         else
 875         {
 876                 sourcemsgstr = msgstr;
 877                 sourcecmsgstr = cmsgstr;
 878         }
 879
 880         if(!privatesay)
 881         if(source.classname != "player")
 882         {
 883                 if not(intermission_running)
 884                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 885                                 teamsay = -1; // spectators
 886         }
 887
 888         if(flood)
 889                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 890
 891         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 892         if(privatesay)
 893                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 894
 895         if(source.muted)
 896         {
 897                 // always fake the message
 898                 ret = -1;
 899         }
 900         else if(flood == 1)
 901         {
 902                 if(autocvar_g_chat_flood_notify_flooder)
 903                 {
 904                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 905                         ret = 0;
 906                 }
 907                 else
 908                         ret = -1;
 909         }
 910         else
 911         {
 912                 ret = 1;
 913         }
 914
 915         if(sourcemsgstr != "" && ret != 0)
 916         {
 917                 if(ret < 0) // faked message, because the player is muted
 918                 {
 919                         sprint(source, sourcemsgstr);
 920                         if(sourcecmsgstr != "" && !privatesay)
 921                                 centerprint(source, sourcecmsgstr);
 922                 }
 923                 else if(privatesay) // private message, between 2 people only
 924                 {
 925                         sprint(source, sourcemsgstr);
 926                         sprint(privatesay, msgstr);
 927                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 928                         if(cmsgstr != "")
 929                                 centerprint(privatesay, cmsgstr);
 930                 }
 931                 else if(teamsay > 0) // team message, only sent to team mates
 932                 {
 933                         sprint(source, sourcemsgstr);
 934                         dedicated_print(msgstr); // send to server console too
 935                         if(sourcecmsgstr != "")
 936                                 centerprint(source, sourcecmsgstr);
 937                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 938                                 if(head != source)
 939                                 {
 940                                         sprint(head, msgstr);
 941                                         if(cmsgstr != "")
 942                                                 centerprint(head, cmsgstr);
 943                                 }
 944                 }
 945                 else if(teamsay < 0) // spectator message, only sent to spectators
 946                 {
 947                         sprint(source, sourcemsgstr);
 948                         dedicated_print(msgstr); // send to server console too
 949                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 950                                 if(head != source)
 951                                         sprint(head, msgstr);
 952                 }
 953                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 954                 {
 955                         sprint(source, sourcemsgstr);
 956                         dedicated_print(msgstr); // send to server console too
 957                         FOR_EACH_REALCLIENT(head)
 958                                 if(head != source)
 959                                         sprint(head, msgstr);
 960                 }
 961                 else
 962                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 963         }
 964
 965         return ret;
 966 }
 967
 968 float GetVoiceMessageVoiceType(string type)
 969 {
 970         if(type == "taunt")
 971                 return VOICETYPE_TAUNT;
 972         if(type == "teamshoot")
 973                 return VOICETYPE_LASTATTACKER;
 974         return VOICETYPE_TEAMRADIO;
 975 }
 976
 977 string allvoicesamples;
 978 .string GetVoiceMessageSampleField(string type)
 979 {
 980         GetPlayerSoundSampleField_notFound = 0;
 981         switch(type)
 982         {
 983 #define _VOICEMSG(m) case #m: return playersound_##m;
 984                 ALLVOICEMSGS
 985 #undef _VOICEMSG
 986         }
 987         GetPlayerSoundSampleField_notFound = 1;
 988         return playersound_taunt;
 989 }
 990
 991 .string GetPlayerSoundSampleField(string type)
 992 {
 993         GetPlayerSoundSampleField_notFound = 0;
 994         switch(type)
 995         {
 996 #define _VOICEMSG(m) case #m: return playersound_##m;
 997                 ALLPLAYERSOUNDS
 998 #undef _VOICEMSG
 999         }
1000         GetPlayerSoundSampleField_notFound = 1;
1001         return playersound_taunt;
1002 }
1003
1004 void PrecacheGlobalSound(string samplestring)
1005 {
1006         float n, i;
1007         tokenize_console(samplestring);
1008         n = stof(argv(1));
1009         if(n > 0)
1010         {
1011                 for(i = 1; i <= n; ++i)
1012                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1013         }
1014         else
1015         {
1016                 precache_sound(strcat(argv(0), ".wav"));
1017         }
1018 }
1019
1020 void PrecachePlayerSounds(string f)
1021 {
1022         float fh;
1023         string s;
1024         fh = fopen(f, FILE_READ);
1025         if(fh < 0)
1026                 return;
1027         while((s = fgets(fh)))
1028         {
1029                 if(tokenize_console(s) != 3)
1030                 {
1031                         dprint("Invalid sound info line: ", s, "\n");
1032                         continue;
1033                 }
1034                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1035         }
1036         fclose(fh);
1037
1038         if not(allvoicesamples)
1039         {
1040 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1041                 ALLVOICEMSGS
1042 #undef _VOICEMSG
1043                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1044         }
1045 }
1046
1047 void ClearPlayerSounds()
1048 {
1049 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1050         ALLPLAYERSOUNDS
1051         ALLVOICEMSGS
1052 #undef _VOICEMSG
1053 }
1054
1055 float LoadPlayerSounds(string f, float first)
1056 {
1057         float fh;
1058         string s;
1059         var .string field;
1060         fh = fopen(f, FILE_READ);
1061         if(fh < 0)
1062         {
1063                 dprint("Player sound file not found: ", f, "\n");
1064                 return 0;
1065         }
1066         while((s = fgets(fh)))
1067         {
1068                 if(tokenize_console(s) != 3)
1069                         continue;
1070                 field = GetPlayerSoundSampleField(argv(0));
1071                 if(GetPlayerSoundSampleField_notFound)
1072                         field = GetVoiceMessageSampleField(argv(0));
1073                 if(GetPlayerSoundSampleField_notFound)
1074                         continue;
1075                 if(self.field)
1076                         strunzone(self.field);
1077                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1078         }
1079         fclose(fh);
1080         return 1;
1081 }
1082
1083 .float modelindex_for_playersound;
1084 .float skin_for_playersound;
1085 void UpdatePlayerSounds()
1086 {
1087         if(self.modelindex == self.modelindex_for_playersound)
1088         if(self.skin == self.skin_for_playersound)
1089                 return;
1090         self.modelindex_for_playersound = self.modelindex;
1091         self.skin_for_playersound = self.skin;
1092         ClearPlayerSounds();
1093         LoadPlayerSounds("sound/player/default.sounds", 1);
1094         if(!autocvar_g_debug_defaultsounds)
1095                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1096                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1097 }
1098
1099 void FakeGlobalSound(string sample, float chan, float voicetype)
1100 {
1101         float n;
1102         float tauntrand;
1103
1104         if(sample == "")
1105                 return;
1106
1107         tokenize_console(sample);
1108         n = stof(argv(1));
1109         if(n > 0)
1110                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1111         else
1112                 sample = strcat(argv(0), ".wav"); // randomization
1113
1114         switch(voicetype)
1115         {
1116                 case VOICETYPE_LASTATTACKER_ONLY:
1117                         break;
1118                 case VOICETYPE_LASTATTACKER:
1119                         if(self.pusher)
1120                         {
1121                                 msg_entity = self;
1122                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1123                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1124                         }
1125                         break;
1126                 case VOICETYPE_TEAMRADIO:
1127                         msg_entity = self;
1128                         if(msg_entity.cvar_cl_voice_directional == 1)
1129                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1130                         else
1131                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1132                         break;
1133                 case VOICETYPE_AUTOTAUNT:
1134                         if(!sv_autotaunt)
1135                                 break;
1136                         if(!sv_taunt)
1137                                 break;
1138                         if(autocvar_sv_gentle)
1139                                 break;
1140                         tauntrand = random();
1141                         msg_entity = self;
1142                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1143                         {
1144                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1145                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1146                                 else
1147                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1148                         }
1149                         break;
1150                 case VOICETYPE_TAUNT:
1151                         if(self.classname == "player")
1152                                 if(self.deadflag == DEAD_NO)
1153                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1154                         if(!sv_taunt)
1155                                 break;
1156                         if(autocvar_sv_gentle)
1157                                 break;
1158                         msg_entity = self;
1159                         if (msg_entity.cvar_cl_voice_directional >= 1)
1160                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1161                         else
1162                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1163                         break;
1164                 case VOICETYPE_PLAYERSOUND:
1165                         msg_entity = self;
1166                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1167                         break;
1168                 default:
1169                         backtrace("Invalid voice type!");
1170                         break;
1171         }
1172 }
1173
1174 void GlobalSound(string sample, float chan, float voicetype)
1175 {
1176         float n;
1177         float tauntrand;
1178
1179         if(sample == "")
1180                 return;
1181
1182         tokenize_console(sample);
1183         n = stof(argv(1));
1184         if(n > 0)
1185                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1186         else
1187                 sample = strcat(argv(0), ".wav"); // randomization
1188
1189         switch(voicetype)
1190         {
1191                 case VOICETYPE_LASTATTACKER_ONLY:
1192                         if(self.pusher)
1193                         {
1194                                 msg_entity = self.pusher;
1195                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1196                                 {
1197                                         if(msg_entity.cvar_cl_voice_directional == 1)
1198                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1199                                         else
1200                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1201                                 }
1202                         }
1203                         break;
1204                 case VOICETYPE_LASTATTACKER:
1205                         if(self.pusher)
1206                         {
1207                                 msg_entity = self.pusher;
1208                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1209                                 {
1210                                         if(msg_entity.cvar_cl_voice_directional == 1)
1211                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1212                                         else
1213                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1214                                 }
1215                                 msg_entity = self;
1216                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1217                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1218                         }
1219                         break;
1220                 case VOICETYPE_TEAMRADIO:
1221                         FOR_EACH_REALCLIENT(msg_entity)
1222                                 if(!teamplay || msg_entity.team == self.team)
1223                                 {
1224                                         if(msg_entity.cvar_cl_voice_directional == 1)
1225                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1226                                         else
1227                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1228                                 }
1229                         break;
1230                 case VOICETYPE_AUTOTAUNT:
1231                         if(!sv_autotaunt)
1232                                 break;
1233                         if(!sv_taunt)
1234                                 break;
1235                         if(autocvar_sv_gentle)
1236                                 break;
1237                         tauntrand = random();
1238                         FOR_EACH_REALCLIENT(msg_entity)
1239                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1240                                 {
1241                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1242                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1243                                         else
1244                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1245                                 }
1246                         break;
1247                 case VOICETYPE_TAUNT:
1248                         if(self.classname == "player")
1249                                 if(self.deadflag == DEAD_NO)
1250                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1251                         if(!sv_taunt)
1252                                 break;
1253                         if(autocvar_sv_gentle)
1254                                 break;
1255                         FOR_EACH_REALCLIENT(msg_entity)
1256                         {
1257                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1258                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1259                                 else
1260                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1261                         }
1262                         break;
1263                 case VOICETYPE_PLAYERSOUND:
1264                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1265                         break;
1266                 default:
1267                         backtrace("Invalid voice type!");
1268                         break;
1269         }
1270 }
1271
1272 void PlayerSound(.string samplefield, float chan, float voicetype)
1273 {
1274         GlobalSound(self.samplefield, chan, voicetype);
1275 }
1276
1277 void VoiceMessage(string type, string msg)
1278 {
1279         var .string sample;
1280         float voicetype, ownteam;
1281         float flood;
1282         sample = GetVoiceMessageSampleField(type);
1283
1284         if(GetPlayerSoundSampleField_notFound)
1285         {
1286                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1287                 return;
1288         }
1289
1290         voicetype = GetVoiceMessageVoiceType(type);
1291         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1292
1293         flood = Say(self, ownteam, world, msg, 1);
1294
1295         if (flood > 0)
1296                 GlobalSound(self.sample, CH_VOICE, voicetype);
1297         else if (flood < 0)
1298                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1299 }
1300
1301 void MoveToTeam(entity client, float team_colour, float type)
1302 {
1303         float lockteams_backup;
1304
1305         lockteams_backup = lockteams;  // backup any team lock
1306
1307         lockteams = 0;  // disable locked teams
1308
1309         TeamchangeFrags(client);  // move the players frags
1310         SetPlayerColors(client, team_colour - 1);  // set the players colour
1311         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1312
1313         lockteams = lockteams_backup;  // restore the team lock
1314
1315         LogTeamchange(client.playerid, client.team, type);
1316 }