qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.glowmod = oldself.glowmod;
 138         self.iscreature = oldself.iscreature;
 139         self.damagedbycontents = oldself.damagedbycontents;
 140         self.angles = oldself.angles;
 141         self.avelocity = oldself.avelocity;
 142         self.classname = "body";
 143         self.damageforcescale = oldself.damageforcescale;
 144         self.effects = oldself.effects;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.modelindex_lod0 = oldself.modelindex_lod0;
 162         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 163         self.modelindex_lod1 = oldself.modelindex_lod1;
 164         self.modelindex_lod2 = oldself.modelindex_lod2;
 165         self.skinindex = oldself.skinindex;
 166         self.species = oldself.species;
 167         self.movetype = oldself.movetype;
 168         self.nextthink = oldself.nextthink;
 169         self.solid = oldself.solid;
 170         self.ballistics_density = oldself.ballistics_density;
 171         self.takedamage = oldself.takedamage;
 172         self.think = oldself.think;
 173         self.customizeentityforclient = oldself.customizeentityforclient;
 174         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 175         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 176         if (keepvelocity == 1)
 177                 self.velocity = oldself.velocity;
 178         self.oldvelocity = self.velocity;
 179         self.fade_time = oldself.fade_time;
 180         self.fade_rate = oldself.fade_rate;
 181         //self.weapon = oldself.weapon;
 182         setorigin(self, oldself.origin);
 183         setsize(self, oldself.mins, oldself.maxs);
 184         self.prevorigin = oldself.origin;
 185         self.reset = SUB_Remove;
 186
 187         Drag_MoveDrag(oldself, self);
 188
 189         if(self.colormap <= maxclients && self.colormap > 0)
 190                 self.colormap = 1024 + self.clientcolors;
 191
 192         self = oldself;
 193 }
 194
 195 float player_getspecies()
 196 {
 197         float s;
 198         get_model_parameters(self.model, self.skinindex);
 199         s = get_model_parameters_species;
 200         get_model_parameters(string_null, 0);
 201         if(s < 0)
 202                 return SPECIES_HUMAN;
 203         return s;
 204 }
 205
 206 void player_setupanimsformodel()
 207 {
 208         // defaults for legacy .zym models without animinfo files
 209         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 210         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 211         self.anim_draw = animfixfps(self, '2 1 3');
 212         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 213         self.anim_duckwalk = animfixfps(self, '4 1 1');
 214         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 215         self.anim_duckidle = animfixfps(self, '6 1 1');
 216         self.anim_idle = animfixfps(self, '7 1 1');
 217         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 218         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 219         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 220         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 221         self.anim_taunt = animfixfps(self, '12 1 0.33');
 222         self.anim_run = animfixfps(self, '13 1 1');
 223         self.anim_runbackwards = animfixfps(self, '14 1 1');
 224         self.anim_strafeleft = animfixfps(self, '15 1 1');
 225         self.anim_straferight = animfixfps(self, '16 1 1');
 226         self.anim_dead1 = animfixfps(self, '17 1 1');
 227         self.anim_dead2 = animfixfps(self, '18 1 1');
 228         self.anim_forwardright = animfixfps(self, '19 1 1');
 229         self.anim_forwardleft = animfixfps(self, '20 1 1');
 230         self.anim_backright = animfixfps(self, '21 1 1');
 231         self.anim_backleft  = animfixfps(self, '22 1 1');
 232         self.anim_melee = animfixfps(self, '23 1 1');
 233         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 234         // TODO introspect models for finding right "fps" value (1/duration)
 235         // reset animstate now
 236         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         updateanim(self);
 242         if (self.weaponentity)
 243                 updateanim(self.weaponentity);
 244
 245         if (self.deadflag != DEAD_NO)
 246         {
 247                 if (time > self.animstate_endtime)
 248                 {
 249                         if (self.maxs_z > 5)
 250                         {
 251                                 self.maxs_z = 5;
 252                                 setsize(self, self.mins, self.maxs);
 253                         }
 254                         self.frame = self.dead_frame;
 255                 }
 256                 return;
 257         }
 258
 259         if (!self.animstate_override)
 260         {
 261                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 262                 {
 263                         if (self.crouch)
 264                         {
 265                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 266                                 {
 267                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 268                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 269                                         {
 270                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 271                                                 self.restart_jump = FALSE;
 272                                         }
 273                                 }
 274                         }
 275                         else
 276                         {
 277                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 278                 {
 279                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 280                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 281                     {
 282                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 283                         self.restart_jump = FALSE;
 284                     }
 285                 }
 286                         }
 287                 }
 288                 else if (self.crouch)
 289                 {
 290                         if (self.movement_x < 0)
 291                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 292                         else if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 293                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 294                         else
 295                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 296                 }
 297                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 298                 {
 299                         if (self.movement_x > 0 && self.movement_y == 0)
 300                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y == 0)
 302                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 303                         else if (self.movement_x == 0 && self.movement_y > 0)
 304                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x == 0 && self.movement_y < 0)
 306                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x > 0 && self.movement_y > 0)
 308                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x > 0 && self.movement_y < 0)
 310                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x < 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x < 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 315                         else
 316                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 317                 }
 318                 else
 319                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 320         }
 321
 322         if (self.weaponentity)
 323         if (!self.weaponentity.animstate_override)
 324                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 325 }
 326
 327 void SpawnThrownWeapon (vector org, float w)
 328 {
 329         if(g_minstagib)
 330         if(self.ammo_cells <= 0)
 331                 return;
 332
 333         if(g_pinata)
 334         {
 335                 float j;
 336                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 337                 {
 338                         if(self.weapons & W_WeaponBit(j))
 339                                 if(W_IsWeaponThrowable(j))
 340                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 341                 }
 342         }
 343         else
 344         {
 345                 if(W_IsWeaponThrowable(self.weapon))
 346                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 347         }
 348 }
 349
 350 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 351 {
 352         float take, save;
 353         vector v;
 354         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 355
 356         // damage resistance (ignore most of the damage from a bullet or similar)
 357         damage = max(damage - 5, 1);
 358
 359         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 360         take = v_x;
 361         save = v_y;
 362
 363         if(sound_allowed(MSG_BROADCAST, attacker))
 364         {
 365                 if (save > 10)
 366                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 367                 else if (take > 30)
 368                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 369                 else if (take > 10)
 370                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 371         }
 372
 373         if (take > 50)
 374                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 375         if (take > 100)
 376                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 377
 378         if (!(self.flags & FL_GODMODE))
 379         {
 380                 self.armorvalue = self.armorvalue - save;
 381                 self.health = self.health - take;
 382                 // pause regeneration for 5 seconds
 383                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 384         }
 385         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 386         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 387         self.dmg_inflictor = inflictor;
 388
 389         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 390         {
 391                 // don't use any animations as a gib
 392                 self.frame = 0;
 393                 self.dead_frame = 0;
 394                 // view just above the floor
 395                 self.view_ofs = '0 0 4';
 396
 397                 Violence_GibSplash(self, 1, 1, attacker);
 398                 self.modelindex = 0; // restore later
 399                 self.solid = SOLID_NOT; // restore later
 400         }
 401 }
 402
 403 void ClientKill_Now_TeamChange();
 404 void freezetag_CheckWinner();
 405
 406 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 407 {
 408         float take, save, waves, sdelay, dh, da, j;
 409         vector v;
 410         float valid_damage_for_weaponstats;
 411         float excess;
 412
 413         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 414                 return;
 415
 416         dh = max(self.health, 0);
 417         da = max(self.armorvalue, 0);
 418
 419         if(!DEATH_ISSPECIAL(deathtype))
 420         {
 421                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 422                 if(self != attacker)
 423                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 424         }
 425
 426         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 427         {
 428                 // tuba causes blood to come out of the ears
 429                 vector ear1, ear2;
 430                 vector d;
 431                 float f;
 432                 ear1 = self.origin;
 433                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 434                 ear2 = ear1;
 435                 makevectors(self.angles);
 436                 ear1 += v_right * -10;
 437                 ear2 += v_right * +10;
 438                 d = inflictor.origin - self.origin;
 439                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 440                 force = v_right * vlen(force);
 441                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 442                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 443                 if(f > 0)
 444                 {
 445                         hitloc = ear1;
 446                         force = force * -1;
 447                 }
 448                 else
 449                 {
 450                         hitloc = ear2;
 451                         // force is already good
 452                 }
 453         }
 454         else
 455                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 456
 457         if (!g_minstagib)
 458         {
 459                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 460                 take = v_x;
 461                 save = v_y;
 462         }
 463         else
 464         {
 465                 save = 0;
 466                 take = damage;
 467         }
 468
 469         frag_inflictor = inflictor;
 470         frag_attacker = attacker;
 471         frag_target = self;
 472         damage_take = take;
 473         damage_save = save;
 474         damage_force = force;
 475         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 476         take = bound(0, damage_take, self.health);
 477         save = bound(0, damage_save, self.armorvalue);
 478         excess = max(0, damage - take - save);
 479
 480         if(sound_allowed(MSG_BROADCAST, attacker))
 481         {
 482                 if (save > 10)
 483                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 484                 else if (take > 30)
 485                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 486                 else if (take > 10)
 487                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 488         }
 489
 490         if (take > 50)
 491                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 492         if (take > 100)
 493                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 494
 495         if (time >= self.spawnshieldtime)
 496         {
 497                 if (!(self.flags & FL_GODMODE))
 498                 {
 499                         self.armorvalue = self.armorvalue - save;
 500                         self.health = self.health - take;
 501                         // pause regeneration for 5 seconds
 502                         if(take)
 503                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 504
 505                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 506                         {
 507                                 self.pain_finished = time + 0.5;        //Supajoe
 508
 509                                 if(sv_gentle < 1) {
 510                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 511                                         {
 512                                                 if (!self.animstate_override)
 513                                                 {
 514                                                         if (random() > 0.5)
 515                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 516                                                         else
 517                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 518                                                 }
 519                                         }
 520
 521                                         if(sound_allowed(MSG_BROADCAST, attacker))
 522                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 523                                         if(self.health > 1)
 524                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 525                                         {
 526                                                 if(deathtype == DEATH_FALL)
 527                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 528                                                 else if(self.health > 75) // TODO make a "gentle" version?
 529                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 530                                                 else if(self.health > 50)
 531                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 532                                                 else if(self.health > 25)
 533                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 534                                                 else
 535                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 536                                         }
 537                                 }
 538
 539                                 // throw off bot aim temporarily
 540                                 float shake;
 541                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 542                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 543                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 544                         }
 545                 }
 546                 else
 547                         self.max_armorvalue += (save + take);
 548         }
 549         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 550         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 551         self.dmg_inflictor = inflictor;
 552
 553         if(attacker == self)
 554         {
 555                 // don't reset pushltime for self damage as it may be an attempt to
 556                 // escape a lava pit or similar
 557                 //self.pushltime = 0;
 558         }
 559         else if(attacker.classname == "player")
 560         {
 561                 self.pusher = attacker;
 562                 self.pushltime = time + autocvar_g_maxpushtime;
 563         }
 564         else if(time < self.pushltime)
 565         {
 566                 attacker = self.pusher;
 567                 self.pushltime = max(self.pushltime, time + 0.6);
 568         }
 569         else
 570                 self.pushltime = 0;
 571
 572         float abot, vbot, awep;
 573         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 574         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 575
 576         valid_damage_for_weaponstats = 0;
 577         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 578         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 579         if(attacker && self != attacker)
 580         if(IsDifferentTeam(self, attacker))
 581         {
 582                 if(DEATH_ISSPECIAL(deathtype))
 583                         awep = attacker.weapon;
 584                 else
 585                         awep = DEATH_WEAPONOF(deathtype);
 586                 valid_damage_for_weaponstats = 1;
 587         }
 588
 589         if(valid_damage_for_weaponstats)
 590         {
 591                 dh = dh - max(self.health, 0);
 592                 da = da - max(self.armorvalue, 0);
 593                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 594         }
 595
 596         if (self.health < 1)
 597         {
 598                 float defer_ClientKill_Now_TeamChange;
 599                 defer_ClientKill_Now_TeamChange = FALSE;
 600
 601                 if(self.alivetime)
 602                 {
 603                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 604                         self.alivetime = 0;
 605                 }
 606
 607                 if(valid_damage_for_weaponstats)
 608                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 609
 610                 if(sv_gentle < 1) // TODO make a "gentle" version?
 611                 if(sound_allowed(MSG_BROADCAST, attacker))
 612                 {
 613                         if(deathtype == DEATH_DROWN)
 614                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 615                         else
 616                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 617                 }
 618
 619                 // get rid of kill indicator
 620                 if(self.killindicator)
 621                 {
 622                         remove(self.killindicator);
 623                         self.killindicator = world;
 624                         if(self.killindicator_teamchange)
 625                                 defer_ClientKill_Now_TeamChange = TRUE;
 626
 627                         if(self.classname == "body")
 628                         if(deathtype == DEATH_KILL)
 629                         {
 630                                 // for the lemmings fans, a small harmless explosion
 631                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 632                         }
 633                 }
 634
 635                 if(!g_freezetag)
 636                 {
 637                         // become fully visible
 638                         self.alpha = 1;
 639                         // throw a weapon
 640                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 641                 }
 642
 643                 // print an obituary message
 644                 Obituary (attacker, inflictor, self, deathtype);
 645                 race_PreDie();
 646                 DropAllRunes(self);
 647
 648         // increment frag counter for used weapon type
 649         float w;
 650         w = DEATH_WEAPONOF(deathtype);
 651         if(WEP_VALID(w))
 652         if(self.classname == "player")
 653         if(self != attacker)
 654         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 655
 656                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 657                 {
 658                         PutClientInServer();
 659                         count_alive_players(); // re-count players
 660                         freezetag_CheckWinner();
 661                         return;
 662                 }
 663
 664                 frag_attacker = attacker;
 665                 frag_inflictor = inflictor;
 666                 frag_target = self;
 667                 MUTATOR_CALLHOOK(PlayerDies);
 668                 weapon_action(self.weapon, WR_PLAYERDEATH);
 669
 670                 RemoveGrapplingHook(self);
 671
 672                 if(self.flagcarried)
 673                 {
 674                         if(attacker.classname != "player")
 675                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 676                         else if(attacker.team == self.team)
 677                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 678                         else
 679                                 DropFlag(self.flagcarried, world, attacker);
 680                 }
 681                 if(self.ballcarried && g_nexball)
 682                         DropBall(self.ballcarried, self.origin, self.velocity);
 683                 Portal_ClearAllLater(self);
 684
 685                 if(clienttype(self) == CLIENTTYPE_REAL)
 686                 {
 687                         stuffcmd(self, "-zoom\n");
 688                         self.fixangle = TRUE;
 689                         //msg_entity = self;
 690                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 691                         //WriteAngle (MSG_ONE, self.v_angle_x);
 692                         //WriteAngle (MSG_ONE, self.v_angle_y);
 693                         //WriteAngle (MSG_ONE, 80);
 694                 }
 695
 696                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 697                         ClientKill_Now_TeamChange();
 698
 699                 if(g_arena)
 700                         Spawnqueue_Unmark(self);
 701
 702                 if(g_freezetag)
 703                         return;
 704
 705                 // when we get here, player actually dies
 706                 // clear waypoints (do this AFTER FreezeTag)
 707                 WaypointSprite_PlayerDead();
 708
 709                 // make the corpse upright (not tilted)
 710                 self.angles_x = 0;
 711                 self.angles_z = 0;
 712                 // don't spin
 713                 self.avelocity = '0 0 0';
 714                 // view from the floor
 715                 self.view_ofs = '0 0 -8';
 716                 // toss the corpse
 717                 self.movetype = MOVETYPE_TOSS;
 718                 // shootable corpse
 719                 self.solid = SOLID_CORPSE;
 720                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 721                 // don't stick to the floor
 722                 self.flags &~= FL_ONGROUND;
 723                 // dying animation
 724                 self.deadflag = DEAD_DYING;
 725                 // when to allow respawn
 726                 sdelay = 0;
 727                 waves = 0;
 728                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 729                 if(!sdelay)
 730                 {
 731                         if(g_cts)
 732                                 sdelay = 0; // no respawn delay in CTS
 733                         else
 734                                 sdelay = autocvar_g_respawn_delay;
 735                 }
 736                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 737                 if(!waves)
 738                         waves = autocvar_g_respawn_waves;
 739                 if(waves)
 740                         self.death_time = ceil((time + sdelay) / waves) * waves;
 741                 else
 742                         self.death_time = time + sdelay;
 743                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 744                         self.respawn_countdown = 10; // first number to count down from is 10
 745                 else
 746                         self.respawn_countdown = -1; // do not count down
 747                 if (random() < 0.5)
 748                 {
 749                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 750                         self.dead_frame = self.anim_dead1_x;
 751                 }
 752                 else
 753                 {
 754                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 755                         self.dead_frame = self.anim_dead2_x;
 756                 }
 757                 // set damage function to corpse damage
 758                 self.event_damage = PlayerCorpseDamage;
 759                 // call the corpse damage function just in case it wants to gib
 760                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 761                 // set up to fade out later
 762                 SUB_SetFade (self, time + 6 + random (), 1);
 763
 764                 if(sv_gentle > 0 || autocvar_ekg) {
 765                         // remove corpse
 766                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 767                 }
 768
 769                 // reset fields the weapons may use just in case
 770                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 771                 {
 772                         weapon_action(j, WR_RESETPLAYER);
 773                         ATTACK_FINISHED_FOR(self, j) = 0;
 774                 }
 775         }
 776 }
 777
 778 .float muted; // to be used by prvm_edictset server playernumber muted 1
 779 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 780 // message "": do not say, just test flood control
 781 // return value:
 782 //   1 = accept
 783 //   0 = reject
 784 //  -1 = fake accept
 785 {
 786         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 787         float flood, privatemsgprefixlen;
 788         var .float flood_field;
 789         entity head;
 790         float ret;
 791
 792         if(Ban_MaybeEnforceBan(source))
 793                 return 0;
 794
 795         if(!teamsay && !privatesay)
 796                 if(substring(msgin, 0, 1) == " ")
 797                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 798
 799         msgin = formatmessage(msgin);
 800
 801         if(source.classname != "player")
 802                 colorstr = "^0"; // black for spectators
 803         else if(teamplay)
 804                 colorstr = Team_ColorCode(source.team);
 805         else
 806                 teamsay = FALSE;
 807
 808         if(intermission_running)
 809                 teamsay = FALSE;
 810
 811         if(msgin != "")
 812                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 813
 814         /*
 815          * using bprint solves this... me stupid
 816         // how can we prevent the message from appearing in a listen server?
 817         // for now, just give "say" back and only handle say_team
 818         if(!teamsay)
 819         {
 820                 clientcommand(self, strcat("say ", msgin));
 821                 return;
 822         }
 823         */
 824
 825         if(autocvar_g_chat_teamcolors)
 826                 namestr = playername(source);
 827         else
 828                 namestr = source.netname;
 829
 830         if(msgin != "")
 831         {
 832                 if(privatesay)
 833                 {
 834                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 835                         privatemsgprefixlen = strlen(msgstr);
 836                         msgstr = strcat(msgstr, msgin);
 837                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 838                         if(autocvar_g_chat_teamcolors)
 839                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 840                         else
 841                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 842                 }
 843                 else if(teamsay)
 844                 {
 845                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 846                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 847                 }
 848                 else
 849                 {
 850                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 851                         cmsgstr = "";
 852                 }
 853                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 854         }
 855         else
 856         {
 857                 msgstr = cmsgstr = "";
 858         }
 859
 860         fullmsgstr = msgstr;
 861         fullcmsgstr = cmsgstr;
 862
 863         // FLOOD CONTROL
 864         flood = 0;
 865         if(floodcontrol)
 866         {
 867                 float flood_spl;
 868                 float flood_burst;
 869                 float flood_lmax;
 870                 float lines;
 871                 if(privatesay)
 872                 {
 873                         flood_spl = autocvar_g_chat_flood_spl_tell;
 874                         flood_burst = autocvar_g_chat_flood_burst_tell;
 875                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 876                         flood_field = floodcontrol_chattell;
 877                 }
 878                 else if(teamsay)
 879                 {
 880                         flood_spl = autocvar_g_chat_flood_spl_team;
 881                         flood_burst = autocvar_g_chat_flood_burst_team;
 882                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 883                         flood_field = floodcontrol_chatteam;
 884                 }
 885                 else
 886                 {
 887                         flood_spl = autocvar_g_chat_flood_spl;
 888                         flood_burst = autocvar_g_chat_flood_burst;
 889                         flood_lmax = autocvar_g_chat_flood_lmax;
 890                         flood_field = floodcontrol_chat;
 891                 }
 892                 flood_burst = max(0, flood_burst - 1);
 893                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 894
 895                 // do flood control for the default line size
 896                 if(msgstr != "")
 897                 {
 898                         getWrappedLine_remaining = msgstr;
 899                         msgstr = "";
 900                         lines = 0;
 901                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 902                         {
 903                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 904                                 ++lines;
 905                         }
 906                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 907
 908                         if(getWrappedLine_remaining != "")
 909                         {
 910                                 msgstr = strcat(msgstr, "\n");
 911                                 flood = 2;
 912                         }
 913
 914                         if(time >= source.flood_field)
 915                         {
 916                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 917                         }
 918                         else
 919                         {
 920                                 flood = 1;
 921                                 msgstr = fullmsgstr;
 922                         }
 923                 }
 924                 else
 925                 {
 926                         if(time >= source.flood_field)
 927                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 928                         else
 929                                 flood = 1;
 930                 }
 931
 932                 if (timeoutStatus == 2) //when game is paused, no flood protection
 933                         source.flood_field = flood = 0;
 934         }
 935
 936         if(flood == 2) // cannot happen for empty msgstr
 937         {
 938                 if(autocvar_g_chat_flood_notify_flooder)
 939                 {
 940                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 941                         sourcecmsgstr = "";
 942                 }
 943                 else
 944                 {
 945                         sourcemsgstr = fullmsgstr;
 946                         sourcecmsgstr = fullcmsgstr;
 947                 }
 948                 cmsgstr = "";
 949         }
 950         else
 951         {
 952                 sourcemsgstr = msgstr;
 953                 sourcecmsgstr = cmsgstr;
 954         }
 955
 956         if(!privatesay)
 957         if(source.classname != "player")
 958         {
 959                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 960                         teamsay = -1; // spectators
 961         }
 962
 963         if(flood)
 964                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 965
 966         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 967         if(privatesay)
 968                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 969
 970         if(source.muted)
 971         {
 972                 // always fake the message
 973                 ret = -1;
 974         }
 975         else if(flood == 1)
 976         {
 977                 if(autocvar_g_chat_flood_notify_flooder)
 978                 {
 979                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 980                         ret = 0;
 981                 }
 982                 else
 983                         ret = -1;
 984         }
 985         else
 986         {
 987                 ret = 1;
 988         }
 989
 990         if(sourcemsgstr != "" && ret != 0)
 991         {
 992                 if(ret < 0) // fake
 993                 {
 994                         sprint(source, sourcemsgstr);
 995                         if(sourcecmsgstr != "" && !privatesay)
 996                                 centerprint(source, sourcecmsgstr);
 997                 }
 998                 else if(privatesay)
 999                 {
1000                         sprint(source, sourcemsgstr);
1001                         sprint(privatesay, msgstr);
1002                         if(cmsgstr != "")
1003                                 centerprint(privatesay, cmsgstr);
1004                 }
1005                 else if(teamsay > 0)
1006                 {
1007                         sprint(source, sourcemsgstr);
1008                         if(sourcecmsgstr != "")
1009                                 centerprint(source, sourcecmsgstr);
1010                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1011                                 if(head != source)
1012                                 {
1013                                         sprint(head, msgstr);
1014                                         if(cmsgstr != "")
1015                                                 centerprint(head, cmsgstr);
1016                                 }
1017                 }
1018                 else if(teamsay < 0)
1019                 {
1020                         sprint(source, sourcemsgstr);
1021                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1022                                 if(head != source)
1023                                         sprint(head, msgstr);
1024                 }
1025                 else if(sourcemsgstr != msgstr)
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         FOR_EACH_REALCLIENT(head)
1029                                 if(head != source)
1030                                         sprint(head, msgstr);
1031                 }
1032                 else
1033                         bprint(msgstr);
1034         }
1035
1036         return ret;
1037 }
1038
1039 float GetVoiceMessageVoiceType(string type)
1040 {
1041         if(type == "taunt")
1042                 return VOICETYPE_TAUNT;
1043         if(type == "teamshoot")
1044                 return VOICETYPE_LASTATTACKER;
1045         return VOICETYPE_TEAMRADIO;
1046 }
1047
1048 string allvoicesamples;
1049 .string GetVoiceMessageSampleField(string type)
1050 {
1051         GetPlayerSoundSampleField_notFound = 0;
1052         switch(type)
1053         {
1054 #define _VOICEMSG(m) case #m: return playersound_##m;
1055                 ALLVOICEMSGS
1056 #undef _VOICEMSG
1057         }
1058         GetPlayerSoundSampleField_notFound = 1;
1059         return playersound_taunt;
1060 }
1061
1062 .string GetPlayerSoundSampleField(string type)
1063 {
1064         GetPlayerSoundSampleField_notFound = 0;
1065         switch(type)
1066         {
1067 #define _VOICEMSG(m) case #m: return playersound_##m;
1068                 ALLPLAYERSOUNDS
1069 #undef _VOICEMSG
1070         }
1071         GetPlayerSoundSampleField_notFound = 1;
1072         return playersound_taunt;
1073 }
1074
1075 void PrecacheGlobalSound(string samplestring)
1076 {
1077         float n, i;
1078         tokenize_console(samplestring);
1079         n = stof(argv(1));
1080         if(n > 0)
1081         {
1082                 for(i = 1; i <= n; ++i)
1083                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1084         }
1085         else
1086         {
1087                 precache_sound(strcat(argv(0), ".wav"));
1088         }
1089 }
1090
1091 void PrecachePlayerSounds(string f)
1092 {
1093         float fh;
1094         string s;
1095         fh = fopen(f, FILE_READ);
1096         if(fh < 0)
1097                 return;
1098         while((s = fgets(fh)))
1099         {
1100                 if(tokenize_console(s) != 3)
1101                 {
1102                         dprint("Invalid sound info line: ", s, "\n");
1103                         continue;
1104                 }
1105                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1106         }
1107         fclose(fh);
1108
1109         if not(allvoicesamples)
1110         {
1111 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1112                 ALLVOICEMSGS
1113 #undef _VOICEMSG
1114                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1115         }
1116 }
1117
1118 void ClearPlayerSounds()
1119 {
1120 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1121         ALLPLAYERSOUNDS
1122         ALLVOICEMSGS
1123 #undef _VOICEMSG
1124 }
1125
1126 float LoadPlayerSounds(string f, float first)
1127 {
1128         float fh;
1129         string s;
1130         var .string field;
1131         fh = fopen(f, FILE_READ);
1132         if(fh < 0)
1133         {
1134                 dprint("Player sound file not found: ", f, "\n");
1135                 return 0;
1136         }
1137         while((s = fgets(fh)))
1138         {
1139                 if(tokenize_console(s) != 3)
1140                         continue;
1141                 field = GetPlayerSoundSampleField(argv(0));
1142                 if(GetPlayerSoundSampleField_notFound)
1143                         field = GetVoiceMessageSampleField(argv(0));
1144                 if(GetPlayerSoundSampleField_notFound)
1145                         continue;
1146                 if(self.field)
1147                         strunzone(self.field);
1148                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1149         }
1150         fclose(fh);
1151         return 1;
1152 }
1153
1154 .float modelindex_for_playersound;
1155 .float skinindex_for_playersound;
1156 void UpdatePlayerSounds()
1157 {
1158         if(self.modelindex == self.modelindex_for_playersound)
1159         if(self.skinindex == self.skinindex_for_playersound)
1160                 return;
1161         self.modelindex_for_playersound = self.modelindex;
1162         self.skinindex_for_playersound = self.skinindex;
1163         ClearPlayerSounds();
1164         LoadPlayerSounds("sound/player/default.sounds", 1);
1165         if(!autocvar_g_debug_defaultsounds)
1166                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1167                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1168 }
1169
1170 void FakeGlobalSound(string sample, float chan, float voicetype)
1171 {
1172         float n;
1173         float tauntrand;
1174
1175         if(sample == "")
1176                 return;
1177
1178         tokenize_console(sample);
1179         n = stof(argv(1));
1180         if(n > 0)
1181                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1182         else
1183                 sample = strcat(argv(0), ".wav"); // randomization
1184
1185         switch(voicetype)
1186         {
1187                 case VOICETYPE_LASTATTACKER_ONLY:
1188                         break;
1189                 case VOICETYPE_LASTATTACKER:
1190                         if(self.pusher)
1191                         {
1192                                 msg_entity = self;
1193                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1194                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1195                         }
1196                         break;
1197                 case VOICETYPE_TEAMRADIO:
1198                         msg_entity = self;
1199                         if(msg_entity.cvar_cl_voice_directional == 1)
1200                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1201                         else
1202                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1203                         break;
1204                 case VOICETYPE_AUTOTAUNT:
1205                         if(!sv_autotaunt)
1206                                 break;
1207                         if(!sv_taunt)
1208                                 break;
1209                         if(sv_gentle)
1210                                 break;
1211                         tauntrand = random();
1212                         msg_entity = self;
1213                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1214                         {
1215                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1216                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1217                                 else
1218                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1219                         }
1220                         break;
1221                 case VOICETYPE_TAUNT:
1222                         if(self.classname == "player")
1223                                 if(self.deadflag == DEAD_NO)
1224                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1225                         if(!sv_taunt)
1226                                 break;
1227                         if(sv_gentle)
1228                                 break;
1229                         msg_entity = self;
1230                         if (msg_entity.cvar_cl_voice_directional >= 1)
1231                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1232                         else
1233                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1234                         break;
1235                 case VOICETYPE_PLAYERSOUND:
1236                         msg_entity = self;
1237                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1238                         break;
1239                 default:
1240                         backtrace("Invalid voice type!");
1241                         break;
1242         }
1243 }
1244
1245 void GlobalSound(string sample, float chan, float voicetype)
1246 {
1247         float n;
1248         float tauntrand;
1249
1250         if(sample == "")
1251                 return;
1252
1253         tokenize_console(sample);
1254         n = stof(argv(1));
1255         if(n > 0)
1256                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1257         else
1258                 sample = strcat(argv(0), ".wav"); // randomization
1259
1260         switch(voicetype)
1261         {
1262                 case VOICETYPE_LASTATTACKER_ONLY:
1263                         if(self.pusher)
1264                         {
1265                                 msg_entity = self.pusher;
1266                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1267                                 {
1268                                         if(msg_entity.cvar_cl_voice_directional == 1)
1269                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1270                                         else
1271                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1272                                 }
1273                         }
1274                         break;
1275                 case VOICETYPE_LASTATTACKER:
1276                         if(self.pusher)
1277                         {
1278                                 msg_entity = self.pusher;
1279                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1280                                 {
1281                                         if(msg_entity.cvar_cl_voice_directional == 1)
1282                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1283                                         else
1284                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1285                                 }
1286                                 msg_entity = self;
1287                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1288                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1289                         }
1290                         break;
1291                 case VOICETYPE_TEAMRADIO:
1292                         FOR_EACH_REALCLIENT(msg_entity)
1293                                 if(!teamplay || msg_entity.team == self.team)
1294                                 {
1295                                         if(msg_entity.cvar_cl_voice_directional == 1)
1296                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1297                                         else
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1299                                 }
1300                         break;
1301                 case VOICETYPE_AUTOTAUNT:
1302                         if(!sv_autotaunt)
1303                                 break;
1304                         if(!sv_taunt)
1305                                 break;
1306                         if(sv_gentle)
1307                                 break;
1308                         tauntrand = random();
1309                         FOR_EACH_REALCLIENT(msg_entity)
1310                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1311                                 {
1312                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1313                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1314                                         else
1315                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1316                                 }
1317                         break;
1318                 case VOICETYPE_TAUNT:
1319                         if(self.classname == "player")
1320                                 if(self.deadflag == DEAD_NO)
1321                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1322                         if(!sv_taunt)
1323                                 break;
1324                         if(sv_gentle)
1325                                 break;
1326                         FOR_EACH_REALCLIENT(msg_entity)
1327                         {
1328                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1329                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1330                                 else
1331                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1332                         }
1333                         break;
1334                 case VOICETYPE_PLAYERSOUND:
1335                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1336                         break;
1337                 default:
1338                         backtrace("Invalid voice type!");
1339                         break;
1340         }
1341 }
1342
1343 void PlayerSound(.string samplefield, float chan, float voicetype)
1344 {
1345         GlobalSound(self.samplefield, chan, voicetype);
1346 }
1347
1348 void VoiceMessage(string type, string msg)
1349 {
1350         var .string sample;
1351         float voicetype, ownteam;
1352         float flood;
1353         sample = GetVoiceMessageSampleField(type);
1354
1355         if(GetPlayerSoundSampleField_notFound)
1356         {
1357                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1358                 return;
1359         }
1360
1361         voicetype = GetVoiceMessageVoiceType(type);
1362         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1363
1364         flood = Say(self, ownteam, world, msg, 1);
1365
1366         if (flood > 0)
1367                 GlobalSound(self.sample, CH_VOICE, voicetype);
1368         else if (flood < 0)
1369                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1370 }
1371
1372 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1373 {
1374 //      show_message
1375 //      0 (00) automove centerprint, admin message
1376 //      1 (01) automove centerprint, no admin message
1377 //      2 (10) no centerprint, admin message
1378 //      3 (11) no centerprint, no admin message
1379
1380         float lockteams_backup;
1381
1382         lockteams_backup = lockteams;  // backup any team lock
1383
1384         lockteams = 0;  // disable locked teams
1385
1386         TeamchangeFrags(client);  // move the players frags
1387         SetPlayerColors(client, team_colour - 1);  // set the players colour
1388         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1389
1390         lockteams = lockteams_backup;  // restore the team lock
1391
1392         LogTeamchange(client.playerid, client.team, type);
1393
1394         if not(show_message & 1) // admin message
1395                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1396
1397         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1398 }