qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_pinata)
 266         {
 267                 float j;
 268                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 269                 {
 270                         if(WEPSET_CONTAINS_EW(self, j))
 271                                 if(W_IsWeaponThrowable(j))
 272                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 273                 }
 274         }
 275         else
 276         {
 277                 if(WEPSET_CONTAINS_EW(self, self.weapon))
 278                         if(W_IsWeaponThrowable(self.weapon))
 279                                 W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 280         }
 281 }
 282
 283 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 284 {
 285         float take, save;
 286         vector v;
 287         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 288
 289         // damage resistance (ignore most of the damage from a bullet or similar)
 290         damage = max(damage - 5, 1);
 291
 292         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 293         take = v_x;
 294         save = v_y;
 295
 296         if(sound_allowed(MSG_BROADCAST, attacker))
 297         {
 298                 if (save > 10)
 299                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 300                 else if (take > 30)
 301                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 302                 else if (take > 10)
 303                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 304         }
 305
 306         if (take > 50)
 307                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 308         if (take > 100)
 309                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 310
 311         if (!(self.flags & FL_GODMODE))
 312         {
 313                 self.armorvalue = self.armorvalue - save;
 314                 self.health = self.health - take;
 315                 // pause regeneration for 5 seconds
 316                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 317         }
 318         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 319         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 320         self.dmg_inflictor = inflictor;
 321
 322         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 323         {
 324                 // don't use any animations as a gib
 325                 self.frame = 0;
 326                 // view just above the floor
 327                 self.view_ofs = '0 0 4';
 328
 329                 Violence_GibSplash(self, 1, 1, attacker);
 330                 self.alpha = -1;
 331                 self.solid = SOLID_NOT; // restore later
 332                 self.takedamage = DAMAGE_NO; // restore later
 333                 self.damagedbycontents = FALSE;
 334         }
 335 }
 336
 337 void ClientKill_Now_TeamChange();
 338
 339 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 340 {
 341         float take, save, waves, sdelay, dh, da, j;
 342         vector v;
 343         float valid_damage_for_weaponstats;
 344         float excess;
 345
 346         dh = max(self.health, 0);
 347         da = max(self.armorvalue, 0);
 348
 349         if(!DEATH_ISSPECIAL(deathtype))
 350         {
 351                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 352                 if(self != attacker)
 353                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 354         }
 355
 356         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 357         {
 358                 // tuba causes blood to come out of the ears
 359                 vector ear1, ear2;
 360                 vector d;
 361                 float f;
 362                 ear1 = self.origin;
 363                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 364                 ear2 = ear1;
 365                 makevectors(self.angles);
 366                 ear1 += v_right * -10;
 367                 ear2 += v_right * +10;
 368                 d = inflictor.origin - self.origin;
 369                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 370                 force = v_right * vlen(force);
 371                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 372                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 373                 if(f > 0)
 374                 {
 375                         hitloc = ear1;
 376                         force = force * -1;
 377                 }
 378                 else
 379                 {
 380                         hitloc = ear2;
 381                         // force is already good
 382                 }
 383         }
 384         else
 385                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 386
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(attacker == self)
 393         {
 394                 // don't reset pushltime for self damage as it may be an attempt to
 395                 // escape a lava pit or similar
 396                 //self.pushltime = 0;
 397                 self.istypefrag = 0;
 398         }
 399         else if(IS_PLAYER(attacker))
 400         {
 401                 self.pusher = attacker;
 402                 self.pushltime = time + autocvar_g_maxpushtime;
 403                 self.istypefrag = self.BUTTON_CHAT;
 404         }
 405         else if(time < self.pushltime)
 406         {
 407                 attacker = self.pusher;
 408                 self.pushltime = max(self.pushltime, time + 0.6);
 409         }
 410         else
 411         {
 412                 self.pushltime = 0;
 413                 self.istypefrag = 0;
 414         }
 415
 416         frag_inflictor = inflictor;
 417         frag_attacker = attacker;
 418         frag_target = self;
 419         frag_damage = damage;
 420         damage_take = take;
 421         damage_save = save;
 422         damage_force = force;
 423         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 424         take = bound(0, damage_take, self.health);
 425         save = bound(0, damage_save, self.armorvalue);
 426         excess = max(0, damage - take - save);
 427
 428         if(sound_allowed(MSG_BROADCAST, attacker))
 429         {
 430                 if (save > 10)
 431                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 432                 else if (take > 30)
 433                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 434                 else if (take > 10)
 435                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 436         }
 437
 438         if (take > 50)
 439                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 440         if (take > 100)
 441                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 442
 443         if (time >= self.spawnshieldtime)
 444         {
 445                 if (!(self.flags & FL_GODMODE))
 446                 {
 447                         self.armorvalue = self.armorvalue - save;
 448                         self.health = self.health - take;
 449                         // pause regeneration for 5 seconds
 450                         if(take)
 451                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 452
 453                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 454                         {
 455                                 self.pain_finished = time + 0.5;        //Supajoe
 456
 457                                 if(autocvar_sv_gentle < 1) {
 458                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 459                                         {
 460                                                 if (!self.animstate_override)
 461                                                 {
 462                                                         if (random() > 0.5)
 463                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 464                                                         else
 465                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 466                                                 }
 467                                         }
 468
 469                                         if(sound_allowed(MSG_BROADCAST, attacker))
 470                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 471                                         if(self.health > 1)
 472                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 473                                         {
 474                                                 if(deathtype == DEATH_FALL)
 475                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 476                                                 else if(self.health > 75) // TODO make a "gentle" version?
 477                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 478                                                 else if(self.health > 50)
 479                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 480                                                 else if(self.health > 25)
 481                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 482                                                 else
 483                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 484                                         }
 485                                 }
 486
 487                                 // throw off bot aim temporarily
 488                                 float shake;
 489                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 490                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 491                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 492                         }
 493                 }
 494                 else
 495                         self.max_armorvalue += (save + take);
 496         }
 497         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 498         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 499         self.dmg_inflictor = inflictor;
 500
 501         if(g_ca && self != attacker && IS_PLAYER(attacker))
 502                 PlayerTeamScore_Add(attacker, SP_SCORE, ST_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 503
 504         float abot, vbot, awep;
 505         abot = (IS_BOT_CLIENT(attacker));
 506         vbot = (IS_BOT_CLIENT(self));
 507
 508         valid_damage_for_weaponstats = 0;
 509         awep = 0;
 510
 511         if(vbot || IS_REAL_CLIENT(self))
 512         if(abot || IS_REAL_CLIENT(attacker))
 513         if(attacker && self != attacker)
 514         if(IsDifferentTeam(self, attacker))
 515         {
 516                 if(DEATH_ISSPECIAL(deathtype))
 517                         awep = attacker.weapon;
 518                 else
 519                         awep = DEATH_WEAPONOF(deathtype);
 520                 valid_damage_for_weaponstats = 1;
 521         }
 522
 523         if(valid_damage_for_weaponstats)
 524         {
 525                 dh = dh - max(self.health, 0);
 526                 da = da - max(self.armorvalue, 0);
 527                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 528         }
 529
 530         if (self.health < 1)
 531         {
 532                 float defer_ClientKill_Now_TeamChange;
 533                 defer_ClientKill_Now_TeamChange = FALSE;
 534
 535                 if(self.alivetime)
 536                 {
 537                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 538                         self.alivetime = 0;
 539                 }
 540
 541                 if(valid_damage_for_weaponstats)
 542                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 543
 544                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 545                 if(sound_allowed(MSG_BROADCAST, attacker))
 546                 {
 547                         if(deathtype == DEATH_DROWN)
 548                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 549                         else
 550                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 551                 }
 552
 553                 // get rid of kill indicator
 554                 if(self.killindicator)
 555                 {
 556                         remove(self.killindicator);
 557                         self.killindicator = world;
 558                         if(self.killindicator_teamchange)
 559                                 defer_ClientKill_Now_TeamChange = TRUE;
 560
 561                         if(self.classname == "body")
 562                         if(deathtype == DEATH_KILL)
 563                         {
 564                                 // for the lemmings fans, a small harmless explosion
 565                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 566                         }
 567                 }
 568
 569                 // print an obituary message
 570                 Obituary (attacker, inflictor, self, deathtype);
 571                 race_PreDie();
 572
 573         // increment frag counter for used weapon type
 574         float w;
 575         w = DEATH_WEAPONOF(deathtype);
 576         if(WEP_VALID(w))
 577         if(accuracy_isgooddamage(attacker, self))
 578         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 579
 580                 frag_attacker = attacker;
 581                 frag_inflictor = inflictor;
 582                 frag_target = self;
 583                 frag_deathtype = deathtype;
 584                 MUTATOR_CALLHOOK(PlayerDies);
 585
 586                 weapon_action(self.weapon, WR_PLAYERDEATH);
 587
 588                 RemoveGrapplingHook(self);
 589
 590                 Portal_ClearAllLater(self);
 591
 592                 if(IS_REAL_CLIENT(self))
 593                 {
 594                         self.fixangle = TRUE;
 595                         //msg_entity = self;
 596                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 597                         //WriteAngle (MSG_ONE, self.v_angle_x);
 598                         //WriteAngle (MSG_ONE, self.v_angle_y);
 599                         //WriteAngle (MSG_ONE, 80);
 600                 }
 601
 602                 if(defer_ClientKill_Now_TeamChange)
 603                         ClientKill_Now_TeamChange(); // can turn player into spectator
 604
 605                 // player could have been miraculously resuscitated ;)
 606                 // e.g. players in freezetag get frozen, they don't really die
 607                 if(self.health >= 1 || !IS_PLAYER(self))
 608                         return;
 609
 610                 // when we get here, player actually dies
 611
 612                 // clear waypoints
 613                 WaypointSprite_PlayerDead();
 614                 // throw a weapon
 615                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 616
 617                 // become fully visible
 618                 self.alpha = default_player_alpha;
 619                 // make the corpse upright (not tilted)
 620                 self.angles_x = 0;
 621                 self.angles_z = 0;
 622                 // don't spin
 623                 self.avelocity = '0 0 0';
 624                 // view from the floor
 625                 self.view_ofs = '0 0 -8';
 626                 // toss the corpse
 627                 self.movetype = MOVETYPE_TOSS;
 628                 // shootable corpse
 629                 self.solid = SOLID_CORPSE;
 630                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 631                 // don't stick to the floor
 632                 self.flags &~= FL_ONGROUND;
 633                 // dying animation
 634                 self.deadflag = DEAD_DYING;
 635                 // when to allow respawn
 636                 sdelay = 0;
 637                 waves = 0;
 638                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 639                 if(!sdelay)
 640                 {
 641                         if(g_cts)
 642                                 sdelay = 0; // no respawn delay in CTS
 643                         else
 644                                 sdelay = autocvar_g_respawn_delay;
 645                 }
 646                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 647                 if(!waves)
 648                         waves = autocvar_g_respawn_waves;
 649                 if(waves)
 650                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 651                 else
 652                         self.respawn_time = time + sdelay;
 653                 if(autocvar_g_respawn_delay_max > self.respawn_time)
 654                         self.respawn_time_max = time + autocvar_g_respawn_delay_max;
 655                 else
 656                         self.respawn_time_max = self.respawn_time;
 657                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 658                         self.respawn_countdown = 10; // first number to count down from is 10
 659                 else
 660                         self.respawn_countdown = -1; // do not count down
 661
 662                 if(g_cts || autocvar_g_forced_respawn)
 663                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 664
 665                 self.death_time = time;
 666                 if (random() < 0.5)
 667                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 668                 else
 669                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 670                 if (self.maxs_z > 5)
 671                 {
 672                         self.maxs_z = 5;
 673                         setsize(self, self.mins, self.maxs);
 674                 }
 675                 // set damage function to corpse damage
 676                 self.event_damage = PlayerCorpseDamage;
 677                 // call the corpse damage function just in case it wants to gib
 678                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 679                 // set up to fade out later
 680                 SUB_SetFade (self, time + 6 + random (), 1);
 681
 682                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 683                         // remove corpse
 684                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 685                 }
 686
 687                 // reset fields the weapons may use just in case
 688                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 689                 {
 690                         weapon_action(j, WR_RESETPLAYER);
 691                         ATTACK_FINISHED_FOR(self, j) = 0;
 692                 }
 693         }
 694 }
 695
 696 .float muted; // to be used by prvm_edictset server playernumber muted 1
 697 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 698 // message "": do not say, just test flood control
 699 // return value:
 700 //   1 = accept
 701 //   0 = reject
 702 //  -1 = fake accept
 703 {
 704         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 705         float flood;
 706         var .float flood_field;
 707         entity head;
 708         float ret;
 709         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 710
 711         if(!teamsay && !privatesay)
 712                 if(substring(msgin, 0, 1) == " ")
 713                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 714
 715         msgin = formatmessage(msgin);
 716
 717         if not(IS_PLAYER(source))
 718                 colorstr = "^0"; // black for spectators
 719         else if(teamplay)
 720                 colorstr = Team_ColorCode(source.team);
 721         else
 722         {
 723                 colorstr = "";
 724                 teamsay = FALSE;
 725         }
 726
 727         if(intermission_running)
 728                 teamsay = FALSE;
 729
 730         if(msgin != "")
 731                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 732
 733         /*
 734          * using bprint solves this... me stupid
 735         // how can we prevent the message from appearing in a listen server?
 736         // for now, just give "say" back and only handle say_team
 737         if(!teamsay)
 738         {
 739                 clientcommand(self, strcat("say ", msgin));
 740                 return;
 741         }
 742         */
 743
 744         if(autocvar_g_chat_teamcolors)
 745                 namestr = playername(source);
 746         else
 747                 namestr = source.netname;
 748
 749         if(msgin != "")
 750         {
 751                 if(privatesay)
 752                 {
 753                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 754                         privatemsgprefixlen = strlen(msgstr);
 755                         msgstr = strcat(msgstr, msgin);
 756                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 757                         if(autocvar_g_chat_teamcolors)
 758                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 759                         else
 760                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 761                 }
 762                 else if(teamsay)
 763                 {
 764                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 765                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 766                 }
 767                 else
 768                 {
 769                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 770                         cmsgstr = "";
 771                 }
 772                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 773         }
 774         else
 775         {
 776                 msgstr = cmsgstr = "";
 777         }
 778
 779         fullmsgstr = msgstr;
 780         fullcmsgstr = cmsgstr;
 781
 782         // FLOOD CONTROL
 783         flood = 0;
 784         flood_field = floodcontrol_chat;
 785         if(floodcontrol)
 786         {
 787                 float flood_spl;
 788                 float flood_burst;
 789                 float flood_lmax;
 790                 float lines;
 791                 if(privatesay)
 792                 {
 793                         flood_spl = autocvar_g_chat_flood_spl_tell;
 794                         flood_burst = autocvar_g_chat_flood_burst_tell;
 795                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 796                         flood_field = floodcontrol_chattell;
 797                 }
 798                 else if(teamsay)
 799                 {
 800                         flood_spl = autocvar_g_chat_flood_spl_team;
 801                         flood_burst = autocvar_g_chat_flood_burst_team;
 802                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 803                         flood_field = floodcontrol_chatteam;
 804                 }
 805                 else
 806                 {
 807                         flood_spl = autocvar_g_chat_flood_spl;
 808                         flood_burst = autocvar_g_chat_flood_burst;
 809                         flood_lmax = autocvar_g_chat_flood_lmax;
 810                         flood_field = floodcontrol_chat;
 811                 }
 812                 flood_burst = max(0, flood_burst - 1);
 813                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 814
 815                 // do flood control for the default line size
 816                 if(msgstr != "")
 817                 {
 818                         getWrappedLine_remaining = msgstr;
 819                         msgstr = "";
 820                         lines = 0;
 821                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 822                         {
 823                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 824                                 ++lines;
 825                         }
 826                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 827
 828                         if(getWrappedLine_remaining != "")
 829                         {
 830                                 msgstr = strcat(msgstr, "\n");
 831                                 flood = 2;
 832                         }
 833
 834                         if(time >= source.flood_field)
 835                         {
 836                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 837                         }
 838                         else
 839                         {
 840                                 flood = 1;
 841                                 msgstr = fullmsgstr;
 842                         }
 843                 }
 844                 else
 845                 {
 846                         if(time >= source.flood_field)
 847                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 848                         else
 849                                 flood = 1;
 850                 }
 851
 852                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 853                         source.flood_field = flood = 0;
 854         }
 855
 856         if(flood == 2) // cannot happen for empty msgstr
 857         {
 858                 if(autocvar_g_chat_flood_notify_flooder)
 859                 {
 860                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 861                         sourcecmsgstr = "";
 862                 }
 863                 else
 864                 {
 865                         sourcemsgstr = fullmsgstr;
 866                         sourcecmsgstr = fullcmsgstr;
 867                 }
 868                 cmsgstr = "";
 869         }
 870         else
 871         {
 872                 sourcemsgstr = msgstr;
 873                 sourcecmsgstr = cmsgstr;
 874         }
 875
 876         if(!privatesay)
 877         if not(IS_PLAYER(source))
 878         {
 879                 if not(intermission_running)
 880                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 881                                 teamsay = -1; // spectators
 882         }
 883
 884         if(flood)
 885                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 886
 887         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 888         if(privatesay)
 889                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 890
 891         if(source.muted)
 892         {
 893                 // always fake the message
 894                 ret = -1;
 895         }
 896         else if(flood == 1)
 897         {
 898                 if(autocvar_g_chat_flood_notify_flooder)
 899                 {
 900                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 901                         ret = 0;
 902                 }
 903                 else
 904                         ret = -1;
 905         }
 906         else
 907         {
 908                 ret = 1;
 909         }
 910
 911         if(sourcemsgstr != "" && ret != 0)
 912         {
 913                 if(ret < 0) // faked message, because the player is muted
 914                 {
 915                         sprint(source, sourcemsgstr);
 916                         if(sourcecmsgstr != "" && !privatesay)
 917                                 centerprint(source, sourcecmsgstr);
 918                 }
 919                 else if(privatesay) // private message, between 2 people only
 920                 {
 921                         sprint(source, sourcemsgstr);
 922                         sprint(privatesay, msgstr);
 923                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 924                         if(cmsgstr != "")
 925                                 centerprint(privatesay, cmsgstr);
 926                 }
 927                 else if(teamsay > 0) // team message, only sent to team mates
 928                 {
 929                         sprint(source, sourcemsgstr);
 930                         dedicated_print(msgstr); // send to server console too
 931                         if(sourcecmsgstr != "")
 932                                 centerprint(source, sourcecmsgstr);
 933                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 934                                 if(head != source)
 935                                 {
 936                                         sprint(head, msgstr);
 937                                         if(cmsgstr != "")
 938                                                 centerprint(head, cmsgstr);
 939                                 }
 940                 }
 941                 else if(teamsay < 0) // spectator message, only sent to spectators
 942                 {
 943                         sprint(source, sourcemsgstr);
 944                         dedicated_print(msgstr); // send to server console too
 945                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 946                                 if(head != source)
 947                                         sprint(head, msgstr);
 948                 }
 949                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 950                 {
 951                         sprint(source, sourcemsgstr);
 952                         dedicated_print(msgstr); // send to server console too
 953                         FOR_EACH_REALCLIENT(head)
 954                                 if(head != source)
 955                                         sprint(head, msgstr);
 956                 }
 957                 else
 958                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 959         }
 960
 961         return ret;
 962 }
 963
 964 float GetVoiceMessageVoiceType(string type)
 965 {
 966         if(type == "taunt")
 967                 return VOICETYPE_TAUNT;
 968         if(type == "teamshoot")
 969                 return VOICETYPE_LASTATTACKER;
 970         return VOICETYPE_TEAMRADIO;
 971 }
 972
 973 string allvoicesamples;
 974 .string GetVoiceMessageSampleField(string type)
 975 {
 976         GetPlayerSoundSampleField_notFound = 0;
 977         switch(type)
 978         {
 979 #define _VOICEMSG(m) case #m: return playersound_##m;
 980                 ALLVOICEMSGS
 981 #undef _VOICEMSG
 982         }
 983         GetPlayerSoundSampleField_notFound = 1;
 984         return playersound_taunt;
 985 }
 986
 987 .string GetPlayerSoundSampleField(string type)
 988 {
 989         GetPlayerSoundSampleField_notFound = 0;
 990         switch(type)
 991         {
 992 #define _VOICEMSG(m) case #m: return playersound_##m;
 993                 ALLPLAYERSOUNDS
 994 #undef _VOICEMSG
 995         }
 996         GetPlayerSoundSampleField_notFound = 1;
 997         return playersound_taunt;
 998 }
 999
1000 void PrecacheGlobalSound(string samplestring)
1001 {
1002         float n, i;
1003         tokenize_console(samplestring);
1004         n = stof(argv(1));
1005         if(n > 0)
1006         {
1007                 for(i = 1; i <= n; ++i)
1008                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1009         }
1010         else
1011         {
1012                 precache_sound(strcat(argv(0), ".wav"));
1013         }
1014 }
1015
1016 void PrecachePlayerSounds(string f)
1017 {
1018         float fh;
1019         string s;
1020         fh = fopen(f, FILE_READ);
1021         if(fh < 0)
1022                 return;
1023         while((s = fgets(fh)))
1024         {
1025                 if(tokenize_console(s) != 3)
1026                 {
1027                         dprint("Invalid sound info line: ", s, "\n");
1028                         continue;
1029                 }
1030                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1031         }
1032         fclose(fh);
1033
1034         if not(allvoicesamples)
1035         {
1036 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1037                 ALLVOICEMSGS
1038 #undef _VOICEMSG
1039                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1040         }
1041 }
1042
1043 void ClearPlayerSounds()
1044 {
1045 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1046         ALLPLAYERSOUNDS
1047         ALLVOICEMSGS
1048 #undef _VOICEMSG
1049 }
1050
1051 float LoadPlayerSounds(string f, float first)
1052 {
1053         float fh;
1054         string s;
1055         var .string field;
1056         fh = fopen(f, FILE_READ);
1057         if(fh < 0)
1058         {
1059                 dprint("Player sound file not found: ", f, "\n");
1060                 return 0;
1061         }
1062         while((s = fgets(fh)))
1063         {
1064                 if(tokenize_console(s) != 3)
1065                         continue;
1066                 field = GetPlayerSoundSampleField(argv(0));
1067                 if(GetPlayerSoundSampleField_notFound)
1068                         field = GetVoiceMessageSampleField(argv(0));
1069                 if(GetPlayerSoundSampleField_notFound)
1070                         continue;
1071                 if(self.field)
1072                         strunzone(self.field);
1073                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1074         }
1075         fclose(fh);
1076         return 1;
1077 }
1078
1079 .float modelindex_for_playersound;
1080 .float skin_for_playersound;
1081 void UpdatePlayerSounds()
1082 {
1083         if(self.modelindex == self.modelindex_for_playersound)
1084         if(self.skin == self.skin_for_playersound)
1085                 return;
1086         self.modelindex_for_playersound = self.modelindex;
1087         self.skin_for_playersound = self.skin;
1088         ClearPlayerSounds();
1089         LoadPlayerSounds("sound/player/default.sounds", 1);
1090         if(!autocvar_g_debug_defaultsounds)
1091                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1092                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1093 }
1094
1095 void FakeGlobalSound(string sample, float chan, float voicetype)
1096 {
1097         float n;
1098         float tauntrand;
1099
1100         if(sample == "")
1101                 return;
1102
1103         tokenize_console(sample);
1104         n = stof(argv(1));
1105         if(n > 0)
1106                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1107         else
1108                 sample = strcat(argv(0), ".wav"); // randomization
1109
1110         switch(voicetype)
1111         {
1112                 case VOICETYPE_LASTATTACKER_ONLY:
1113                         break;
1114                 case VOICETYPE_LASTATTACKER:
1115                         if(self.pusher)
1116                         {
1117                                 msg_entity = self;
1118                                 if(IS_REAL_CLIENT(msg_entity))
1119                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1120                         }
1121                         break;
1122                 case VOICETYPE_TEAMRADIO:
1123                         msg_entity = self;
1124                         if(msg_entity.cvar_cl_voice_directional == 1)
1125                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1126                         else
1127                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1128                         break;
1129                 case VOICETYPE_AUTOTAUNT:
1130                         if(!sv_autotaunt)
1131                                 break;
1132                         if(!sv_taunt)
1133                                 break;
1134                         if(autocvar_sv_gentle)
1135                                 break;
1136                         tauntrand = random();
1137                         msg_entity = self;
1138                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1139                         {
1140                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1141                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1142                                 else
1143                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1144                         }
1145                         break;
1146                 case VOICETYPE_TAUNT:
1147                         if(IS_PLAYER(self))
1148                                 if(self.deadflag == DEAD_NO)
1149                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1150                         if(!sv_taunt)
1151                                 break;
1152                         if(autocvar_sv_gentle)
1153                                 break;
1154                         msg_entity = self;
1155                         if (msg_entity.cvar_cl_voice_directional >= 1)
1156                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1157                         else
1158                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1159                         break;
1160                 case VOICETYPE_PLAYERSOUND:
1161                         msg_entity = self;
1162                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1163                         break;
1164                 default:
1165                         backtrace("Invalid voice type!");
1166                         break;
1167         }
1168 }
1169
1170 void GlobalSound(string sample, float chan, float voicetype)
1171 {
1172         float n;
1173         float tauntrand;
1174
1175         if(sample == "")
1176                 return;
1177
1178         tokenize_console(sample);
1179         n = stof(argv(1));
1180         if(n > 0)
1181                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1182         else
1183                 sample = strcat(argv(0), ".wav"); // randomization
1184
1185         switch(voicetype)
1186         {
1187                 case VOICETYPE_LASTATTACKER_ONLY:
1188                         if(self.pusher)
1189                         {
1190                                 msg_entity = self.pusher;
1191                                 if(IS_REAL_CLIENT(msg_entity))
1192                                 {
1193                                         if(msg_entity.cvar_cl_voice_directional == 1)
1194                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1195                                         else
1196                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1197                                 }
1198                         }
1199                         break;
1200                 case VOICETYPE_LASTATTACKER:
1201                         if(self.pusher)
1202                         {
1203                                 msg_entity = self.pusher;
1204                                 if(IS_REAL_CLIENT(msg_entity))
1205                                 {
1206                                         if(msg_entity.cvar_cl_voice_directional == 1)
1207                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1208                                         else
1209                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1210                                 }
1211                                 msg_entity = self;
1212                                 if(IS_REAL_CLIENT(msg_entity))
1213                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1214                         }
1215                         break;
1216                 case VOICETYPE_TEAMRADIO:
1217                         FOR_EACH_REALCLIENT(msg_entity)
1218                                 if(!teamplay || msg_entity.team == self.team)
1219                                 {
1220                                         if(msg_entity.cvar_cl_voice_directional == 1)
1221                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1222                                         else
1223                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1224                                 }
1225                         break;
1226                 case VOICETYPE_AUTOTAUNT:
1227                         if(!sv_autotaunt)
1228                                 break;
1229                         if(!sv_taunt)
1230                                 break;
1231                         if(autocvar_sv_gentle)
1232                                 break;
1233                         tauntrand = random();
1234                         FOR_EACH_REALCLIENT(msg_entity)
1235                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1236                                 {
1237                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1238                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1239                                         else
1240                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1241                                 }
1242                         break;
1243                 case VOICETYPE_TAUNT:
1244                         if(IS_PLAYER(self))
1245                                 if(self.deadflag == DEAD_NO)
1246                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1247                         if(!sv_taunt)
1248                                 break;
1249                         if(autocvar_sv_gentle)
1250                                 break;
1251                         FOR_EACH_REALCLIENT(msg_entity)
1252                         {
1253                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1254                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1255                                 else
1256                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1257                         }
1258                         break;
1259                 case VOICETYPE_PLAYERSOUND:
1260                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1261                         break;
1262                 default:
1263                         backtrace("Invalid voice type!");
1264                         break;
1265         }
1266 }
1267
1268 void PlayerSound(.string samplefield, float chan, float voicetype)
1269 {
1270         GlobalSound(self.samplefield, chan, voicetype);
1271 }
1272
1273 void VoiceMessage(string type, string msg)
1274 {
1275         var .string sample;
1276         float voicetype, ownteam;
1277         float flood;
1278         sample = GetVoiceMessageSampleField(type);
1279
1280         if(GetPlayerSoundSampleField_notFound)
1281         {
1282                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1283                 return;
1284         }
1285
1286         voicetype = GetVoiceMessageVoiceType(type);
1287         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1288
1289         flood = Say(self, ownteam, world, msg, 1);
1290
1291         if (flood > 0)
1292                 GlobalSound(self.sample, CH_VOICE, voicetype);
1293         else if (flood < 0)
1294                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1295 }
1296
1297 void MoveToTeam(entity client, float team_colour, float type)
1298 {
1299         float lockteams_backup;
1300
1301         lockteams_backup = lockteams;  // backup any team lock
1302
1303         lockteams = 0;  // disable locked teams
1304
1305         TeamchangeFrags(client);  // move the players frags
1306         SetPlayerColors(client, team_colour - 1);  // set the players colour
1307         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1308
1309         lockteams = lockteams_backup;  // restore the team lock
1310
1311         LogTeamchange(client.playerid, client.team, type);
1312 }