qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.glowmod = oldself.glowmod;
 138         self.iscreature = oldself.iscreature;
 139         self.damagedbycontents = oldself.damagedbycontents;
 140         self.angles = oldself.angles;
 141         self.avelocity = oldself.avelocity;
 142         self.classname = "body";
 143         self.damageforcescale = oldself.damageforcescale;
 144         self.effects = oldself.effects;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.modelindex_lod0 = oldself.modelindex_lod0;
 162         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 163         self.modelindex_lod1 = oldself.modelindex_lod1;
 164         self.modelindex_lod2 = oldself.modelindex_lod2;
 165         self.skinindex = oldself.skinindex;
 166         self.species = oldself.species;
 167         self.movetype = oldself.movetype;
 168         self.nextthink = oldself.nextthink;
 169         self.solid = oldself.solid;
 170         self.ballistics_density = oldself.ballistics_density;
 171         self.takedamage = oldself.takedamage;
 172         self.think = oldself.think;
 173         self.customizeentityforclient = oldself.customizeentityforclient;
 174         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 175         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 176         if (keepvelocity == 1)
 177                 self.velocity = oldself.velocity;
 178         self.oldvelocity = self.velocity;
 179         self.fade_time = oldself.fade_time;
 180         self.fade_rate = oldself.fade_rate;
 181         //self.weapon = oldself.weapon;
 182         setorigin(self, oldself.origin);
 183         setsize(self, oldself.mins, oldself.maxs);
 184         self.prevorigin = oldself.origin;
 185         self.reset = SUB_Remove;
 186
 187         Drag_MoveDrag(oldself, self);
 188
 189         self = oldself;
 190 }
 191
 192 float player_getspecies()
 193 {
 194         float s;
 195         get_model_parameters(self.model, self.skinindex);
 196         s = get_model_parameters_species;
 197         get_model_parameters(string_null, 0);
 198         if(s < 0)
 199                 return SPECIES_HUMAN;
 200         return s;
 201 }
 202
 203 void player_setupanimsformodel()
 204 {
 205         // defaults for legacy .zym models without animinfo files
 206         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 207         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 208         self.anim_draw = animfixfps(self, '2 1 3');
 209         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 210         self.anim_duckwalk = animfixfps(self, '4 1 1');
 211         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 212         self.anim_duckidle = animfixfps(self, '6 1 1');
 213         self.anim_idle = animfixfps(self, '7 1 1');
 214         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 215         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 216         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 217         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 218         self.anim_taunt = animfixfps(self, '12 1 0.33');
 219         self.anim_run = animfixfps(self, '13 1 1');
 220         self.anim_runbackwards = animfixfps(self, '14 1 1');
 221         self.anim_strafeleft = animfixfps(self, '15 1 1');
 222         self.anim_straferight = animfixfps(self, '16 1 1');
 223         self.anim_dead1 = animfixfps(self, '17 1 1');
 224         self.anim_dead2 = animfixfps(self, '18 1 1');
 225         self.anim_forwardright = animfixfps(self, '19 1 1');
 226         self.anim_forwardleft = animfixfps(self, '20 1 1');
 227         self.anim_backright = animfixfps(self, '21 1 1');
 228         self.anim_backleft  = animfixfps(self, '22 1 1');
 229         self.anim_melee = animfixfps(self, '23 1 1');
 230         // TODO introspect models for finding right "fps" value (1/duration)
 231         // reset animstate now
 232         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 233 }
 234
 235 void player_anim (void)
 236 {
 237         updateanim(self);
 238         if (self.weaponentity)
 239                 updateanim(self.weaponentity);
 240
 241         if (self.deadflag != DEAD_NO)
 242         {
 243                 if (time > self.animstate_endtime)
 244                 {
 245                         if (self.maxs_z > 5)
 246                         {
 247                                 self.maxs_z = 5;
 248                                 setsize(self, self.mins, self.maxs);
 249                         }
 250                         self.frame = self.dead_frame;
 251                 }
 252                 return;
 253         }
 254
 255         if (!self.animstate_override)
 256         {
 257                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 258                 {
 259                         if (self.crouch)
 260                         {
 261                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 262                                 {
 263                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 264                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 265                                         {
 266                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 267                                                 self.restart_jump = FALSE;
 268                                         }
 269                                 }
 270                         }
 271                         else
 272                         {
 273                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 274                 {
 275                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 276                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 277                     {
 278                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 279                         self.restart_jump = FALSE;
 280                     }
 281                 }
 282                         }
 283                 }
 284                 else if (self.crouch)
 285                 {
 286                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 287                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 288                         else
 289                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 290                 }
 291                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 292                 {
 293                         if (self.movement_x > 0 && self.movement_y == 0)
 294                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x < 0 && self.movement_y == 0)
 296                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x == 0 && self.movement_y > 0)
 298                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x == 0 && self.movement_y < 0)
 300                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x > 0 && self.movement_y > 0)
 302                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 303                         else if (self.movement_x > 0 && self.movement_y < 0)
 304                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x < 0 && self.movement_y > 0)
 306                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x < 0 && self.movement_y < 0)
 308                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 309                         else
 310                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 311                 }
 312                 else
 313                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 314         }
 315
 316         if (self.weaponentity)
 317         if (!self.weaponentity.animstate_override)
 318                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 319 }
 320
 321 void SpawnThrownWeapon (vector org, float w)
 322 {
 323         if(g_minstagib)
 324         if(self.ammo_cells <= 0)
 325                 return;
 326
 327         if(g_pinata)
 328         {
 329                 float j;
 330                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 331                 {
 332                         if(self.weapons & W_WeaponBit(j))
 333                                 if(W_IsWeaponThrowable(j))
 334                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 335                 }
 336         }
 337         else
 338         {
 339                 if(W_IsWeaponThrowable(self.weapon))
 340                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 341         }
 342 }
 343
 344 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 345 {
 346         float take, save;
 347         vector v;
 348         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 349
 350         // damage resistance (ignore most of the damage from a bullet or similar)
 351         damage = max(damage - 5, 1);
 352
 353         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 354         take = v_x;
 355         save = v_y;
 356
 357         if(sound_allowed(MSG_BROADCAST, attacker))
 358         {
 359                 if (save > 10)
 360                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 361                 else if (take > 30)
 362                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 363                 else if (take > 10)
 364                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 365         }
 366
 367         if (take > 50)
 368                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 369         if (take > 100)
 370                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 371
 372         if (!(self.flags & FL_GODMODE))
 373         {
 374                 self.armorvalue = self.armorvalue - save;
 375                 self.health = self.health - take;
 376                 // pause regeneration for 5 seconds
 377                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 378         }
 379         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 380         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 381         self.dmg_inflictor = inflictor;
 382
 383         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 384         {
 385                 // don't use any animations as a gib
 386                 self.frame = 0;
 387                 self.dead_frame = 0;
 388                 // view just above the floor
 389                 self.view_ofs = '0 0 4';
 390
 391                 Violence_GibSplash(self, 1, 1, attacker);
 392                 self.modelindex = 0; // restore later
 393                 self.solid = SOLID_NOT; // restore later
 394         }
 395 }
 396
 397 void ClientKill_Now_TeamChange();
 398 void freezetag_CheckWinner();
 399
 400 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 401 {
 402         float take, save, waves, sdelay, dh, da, j;
 403         vector v;
 404         float valid_damage_for_weaponstats;
 405         float excess;
 406
 407         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 408                 return;
 409
 410         dh = max(self.health, 0);
 411         da = max(self.armorvalue, 0);
 412
 413         if(!DEATH_ISSPECIAL(deathtype))
 414         {
 415                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 416                 if(self != attacker)
 417                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 418         }
 419
 420         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 421         {
 422                 // tuba causes blood to come out of the ears
 423                 vector ear1, ear2;
 424                 vector d;
 425                 float f;
 426                 ear1 = self.origin;
 427                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 428                 ear2 = ear1;
 429                 makevectors(self.angles);
 430                 ear1 += v_right * -10;
 431                 ear2 += v_right * +10;
 432                 d = inflictor.origin - self.origin;
 433                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 434                 force = v_right * vlen(force);
 435                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 436                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 437                 if(f > 0)
 438                 {
 439                         hitloc = ear1;
 440                         force = force * -1;
 441                 }
 442                 else
 443                 {
 444                         hitloc = ear2;
 445                         // force is already good
 446                 }
 447         }
 448         else
 449                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 450
 451         if (!g_minstagib)
 452         {
 453                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 454                 take = v_x;
 455                 save = v_y;
 456         }
 457         else
 458         {
 459                 save = 0;
 460                 take = damage;
 461         }
 462
 463         frag_inflictor = inflictor;
 464         frag_attacker = attacker;
 465         frag_target = self;
 466         damage_take = take;
 467         damage_save = save;
 468         damage_force = force;
 469         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 470         take = bound(0, damage_take, self.health);
 471         save = bound(0, damage_save, self.armorvalue);
 472         excess = max(0, damage - take - save);
 473
 474         if(sound_allowed(MSG_BROADCAST, attacker))
 475         {
 476                 if (save > 10)
 477                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 478                 else if (take > 30)
 479                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 480                 else if (take > 10)
 481                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 482         }
 483
 484         if (take > 50)
 485                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 486         if (take > 100)
 487                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 488
 489         if (time >= self.spawnshieldtime)
 490         {
 491                 if (!(self.flags & FL_GODMODE))
 492                 {
 493                         self.armorvalue = self.armorvalue - save;
 494                         self.health = self.health - take;
 495                         // pause regeneration for 5 seconds
 496                         if(take)
 497                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 498
 499                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 500                         {
 501                                 self.pain_finished = time + 0.5;        //Supajoe
 502
 503                                 if(sv_gentle < 1) {
 504                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 505                                         {
 506                                                 if (!self.animstate_override)
 507                                                 {
 508                                                         if (random() > 0.5)
 509                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 510                                                         else
 511                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 512                                                 }
 513                                         }
 514
 515                                         if(sound_allowed(MSG_BROADCAST, attacker))
 516                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 517                                         if(self.health > 1)
 518                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 519                                         {
 520                                                 if(deathtype == DEATH_FALL)
 521                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 522                                                 else if(self.health > 75) // TODO make a "gentle" version?
 523                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 524                                                 else if(self.health > 50)
 525                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 526                                                 else if(self.health > 25)
 527                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 528                                                 else
 529                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 530                                         }
 531                                 }
 532
 533                                 // throw off bot aim temporarily
 534                                 float shake;
 535                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 536                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 537                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 538                         }
 539                 }
 540                 else
 541                         self.max_armorvalue += (save + take);
 542         }
 543         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 544         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 545         self.dmg_inflictor = inflictor;
 546
 547         if(attacker == self)
 548         {
 549                 // don't reset pushltime for self damage as it may be an attempt to
 550                 // escape a lava pit or similar
 551                 //self.pushltime = 0;
 552         }
 553         else if(attacker.classname == "player")
 554         {
 555                 self.pusher = attacker;
 556                 self.pushltime = time + autocvar_g_maxpushtime;
 557         }
 558         else if(time < self.pushltime)
 559         {
 560                 attacker = self.pusher;
 561                 self.pushltime = max(self.pushltime, time + 0.6);
 562         }
 563         else
 564                 self.pushltime = 0;
 565
 566         float abot, vbot, awep;
 567         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 568         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 569
 570         valid_damage_for_weaponstats = 0;
 571         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 572         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 573         if(attacker && self != attacker)
 574         if(IsDifferentTeam(self, attacker))
 575         {
 576                 if(DEATH_ISSPECIAL(deathtype))
 577                         awep = attacker.weapon;
 578                 else
 579                         awep = DEATH_WEAPONOF(deathtype);
 580                 valid_damage_for_weaponstats = 1;
 581         }
 582
 583         if(valid_damage_for_weaponstats)
 584         {
 585                 dh = dh - max(self.health, 0);
 586                 da = da - max(self.armorvalue, 0);
 587                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 588         }
 589
 590         if (self.health < 1)
 591         {
 592                 float defer_ClientKill_Now_TeamChange;
 593                 defer_ClientKill_Now_TeamChange = FALSE;
 594
 595                 if(self.alivetime)
 596                 {
 597                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 598                         self.alivetime = 0;
 599                 }
 600
 601                 if(valid_damage_for_weaponstats)
 602                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 603
 604                 if(sv_gentle < 1) // TODO make a "gentle" version?
 605                 if(sound_allowed(MSG_BROADCAST, attacker))
 606                 {
 607                         if(deathtype == DEATH_DROWN)
 608                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 609                         else
 610                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 611                 }
 612
 613                 // get rid of kill indicator
 614                 if(self.killindicator)
 615                 {
 616                         remove(self.killindicator);
 617                         self.killindicator = world;
 618                         if(self.killindicator_teamchange)
 619                                 defer_ClientKill_Now_TeamChange = TRUE;
 620
 621                         if(self.classname == "body")
 622                         if(deathtype == DEATH_KILL)
 623                         {
 624                                 // for the lemmings fans, a small harmless explosion
 625                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 626                         }
 627                 }
 628
 629                 if(!g_freezetag)
 630                 {
 631                         // become fully visible
 632                         self.alpha = 1;
 633                         // throw a weapon
 634                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 635                 }
 636
 637                 // print an obituary message
 638                 Obituary (attacker, inflictor, self, deathtype);
 639                 race_PreDie();
 640                 DropAllRunes(self);
 641
 642         // increment frag counter for used weapon type
 643         float w;
 644         w = DEATH_WEAPONOF(deathtype);
 645         if(WEP_VALID(w))
 646         if(self.classname == "player")
 647         if(self != attacker)
 648         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 649
 650                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 651                 {
 652                         PutClientInServer();
 653                         count_alive_players(); // re-count players
 654                         freezetag_CheckWinner();
 655                         return;
 656                 }
 657
 658                 frag_attacker = attacker;
 659                 frag_inflictor = inflictor;
 660                 frag_target = self;
 661                 MUTATOR_CALLHOOK(PlayerDies);
 662                 weapon_action(self.weapon, WR_PLAYERDEATH);
 663
 664                 RemoveGrapplingHook(self);
 665
 666                 if(self.flagcarried)
 667                 {
 668                         if(attacker.classname != "player")
 669                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 670                         else if(attacker.team == self.team)
 671                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 672                         else
 673                                 DropFlag(self.flagcarried, world, attacker);
 674                 }
 675                 if(self.ballcarried && g_nexball)
 676                         DropBall(self.ballcarried, self.origin, self.velocity);
 677                 Portal_ClearAllLater(self);
 678
 679                 if(clienttype(self) == CLIENTTYPE_REAL)
 680                 {
 681                         stuffcmd(self, "-zoom\n");
 682                         self.fixangle = TRUE;
 683                         //msg_entity = self;
 684                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 685                         //WriteAngle (MSG_ONE, self.v_angle_x);
 686                         //WriteAngle (MSG_ONE, self.v_angle_y);
 687                         //WriteAngle (MSG_ONE, 80);
 688                 }
 689
 690                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 691                         ClientKill_Now_TeamChange();
 692
 693                 if(g_arena)
 694                         Spawnqueue_Unmark(self);
 695
 696                 if(g_freezetag)
 697                         return;
 698
 699                 // when we get here, player actually dies
 700                 // clear waypoints (do this AFTER FreezeTag)
 701                 WaypointSprite_PlayerDead();
 702
 703                 // make the corpse upright (not tilted)
 704                 self.angles_x = 0;
 705                 self.angles_z = 0;
 706                 // don't spin
 707                 self.avelocity = '0 0 0';
 708                 // view from the floor
 709                 self.view_ofs = '0 0 -8';
 710                 // toss the corpse
 711                 self.movetype = MOVETYPE_TOSS;
 712                 // shootable corpse
 713                 self.solid = SOLID_CORPSE;
 714                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 715                 // don't stick to the floor
 716                 self.flags &~= FL_ONGROUND;
 717                 // dying animation
 718                 self.deadflag = DEAD_DYING;
 719                 // when to allow respawn
 720                 sdelay = 0;
 721                 waves = 0;
 722                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 723                 if(!sdelay)
 724                 {
 725                         if(g_cts)
 726                                 sdelay = 0; // no respawn delay in CTS
 727                         else
 728                                 sdelay = autocvar_g_respawn_delay;
 729                 }
 730                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 731                 if(!waves)
 732                         waves = autocvar_g_respawn_waves;
 733                 if(waves)
 734                         self.death_time = ceil((time + sdelay) / waves) * waves;
 735                 else
 736                         self.death_time = time + sdelay;
 737                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 738                         self.respawn_countdown = 10; // first number to count down from is 10
 739                 else
 740                         self.respawn_countdown = -1; // do not count down
 741                 if (random() < 0.5)
 742                 {
 743                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 744                         self.dead_frame = self.anim_dead1_x;
 745                 }
 746                 else
 747                 {
 748                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 749                         self.dead_frame = self.anim_dead2_x;
 750                 }
 751                 // set damage function to corpse damage
 752                 self.event_damage = PlayerCorpseDamage;
 753                 // call the corpse damage function just in case it wants to gib
 754                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 755                 // set up to fade out later
 756                 SUB_SetFade (self, time + 6 + random (), 1);
 757
 758                 if(sv_gentle > 0 || autocvar_ekg) {
 759                         // remove corpse
 760                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 761                 }
 762
 763                 // reset fields the weapons may use just in case
 764                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 765                 {
 766                         weapon_action(j, WR_RESETPLAYER);
 767                         ATTACK_FINISHED_FOR(self, j) = 0;
 768                 }
 769         }
 770 }
 771
 772 .float muted; // to be used by prvm_edictset server playernumber muted 1
 773 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 774 // message "": do not say, just test flood control
 775 // return value:
 776 //   1 = accept
 777 //   0 = reject
 778 //  -1 = fake accept
 779 {
 780         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 781         float flood, privatemsgprefixlen;
 782         var .float flood_field;
 783         entity head;
 784         float ret;
 785
 786         if(Ban_MaybeEnforceBan(source))
 787                 return 0;
 788
 789         if(!teamsay && !privatesay)
 790                 if(substring(msgin, 0, 1) == " ")
 791                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 792
 793         msgin = formatmessage(msgin);
 794
 795         if(source.classname != "player")
 796                 colorstr = "^0"; // black for spectators
 797         else if(teamplay)
 798                 colorstr = Team_ColorCode(source.team);
 799         else
 800                 teamsay = FALSE;
 801
 802         if(intermission_running)
 803                 teamsay = FALSE;
 804
 805         if(msgin != "")
 806                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 807
 808         /*
 809          * using bprint solves this... me stupid
 810         // how can we prevent the message from appearing in a listen server?
 811         // for now, just give "say" back and only handle say_team
 812         if(!teamsay)
 813         {
 814                 clientcommand(self, strcat("say ", msgin));
 815                 return;
 816         }
 817         */
 818
 819         if(autocvar_g_chat_teamcolors)
 820                 namestr = playername(source);
 821         else
 822                 namestr = source.netname;
 823
 824         if(msgin != "")
 825         {
 826                 if(privatesay)
 827                 {
 828                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 829                         privatemsgprefixlen = strlen(msgstr);
 830                         msgstr = strcat(msgstr, msgin);
 831                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 832                         if(autocvar_g_chat_teamcolors)
 833                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 834                         else
 835                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 836                 }
 837                 else if(teamsay)
 838                 {
 839                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 840                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 841                 }
 842                 else
 843                 {
 844                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 845                         cmsgstr = "";
 846                 }
 847                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 848         }
 849         else
 850         {
 851                 msgstr = cmsgstr = "";
 852         }
 853
 854         fullmsgstr = msgstr;
 855         fullcmsgstr = cmsgstr;
 856
 857         // FLOOD CONTROL
 858         flood = 0;
 859         if(floodcontrol)
 860         {
 861                 float flood_spl;
 862                 float flood_burst;
 863                 float flood_lmax;
 864                 float lines;
 865                 if(privatesay)
 866                 {
 867                         flood_spl = autocvar_g_chat_flood_spl_tell;
 868                         flood_burst = autocvar_g_chat_flood_burst_tell;
 869                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 870                         flood_field = floodcontrol_chattell;
 871                 }
 872                 else if(teamsay)
 873                 {
 874                         flood_spl = autocvar_g_chat_flood_spl_team;
 875                         flood_burst = autocvar_g_chat_flood_burst_team;
 876                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 877                         flood_field = floodcontrol_chatteam;
 878                 }
 879                 else
 880                 {
 881                         flood_spl = autocvar_g_chat_flood_spl;
 882                         flood_burst = autocvar_g_chat_flood_burst;
 883                         flood_lmax = autocvar_g_chat_flood_lmax;
 884                         flood_field = floodcontrol_chat;
 885                 }
 886                 flood_burst = max(0, flood_burst - 1);
 887                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 888
 889                 // do flood control for the default line size
 890                 if(msgstr != "")
 891                 {
 892                         getWrappedLine_remaining = msgstr;
 893                         msgstr = "";
 894                         lines = 0;
 895                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 896                         {
 897                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 898                                 ++lines;
 899                         }
 900                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 901
 902                         if(getWrappedLine_remaining != "")
 903                         {
 904                                 msgstr = strcat(msgstr, "\n");
 905                                 flood = 2;
 906                         }
 907
 908                         if(time >= source.flood_field)
 909                         {
 910                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 911                         }
 912                         else
 913                         {
 914                                 flood = 1;
 915                                 msgstr = fullmsgstr;
 916                         }
 917                 }
 918                 else
 919                 {
 920                         if(time >= source.flood_field)
 921                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 922                         else
 923                                 flood = 1;
 924                 }
 925
 926                 if (timeoutStatus == 2) //when game is paused, no flood protection
 927                         source.flood_field = flood = 0;
 928         }
 929
 930         if(flood == 2) // cannot happen for empty msgstr
 931         {
 932                 if(autocvar_g_chat_flood_notify_flooder)
 933                 {
 934                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 935                         sourcecmsgstr = "";
 936                 }
 937                 else
 938                 {
 939                         sourcemsgstr = fullmsgstr;
 940                         sourcecmsgstr = fullcmsgstr;
 941                 }
 942                 cmsgstr = "";
 943         }
 944         else
 945         {
 946                 sourcemsgstr = msgstr;
 947                 sourcecmsgstr = cmsgstr;
 948         }
 949
 950         if(!privatesay)
 951         if(source.classname != "player")
 952         {
 953                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 954                         teamsay = -1; // spectators
 955         }
 956
 957         if(flood)
 958                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 959
 960         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 961         if(privatesay)
 962                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 963
 964         if(source.muted)
 965         {
 966                 // always fake the message
 967                 ret = -1;
 968         }
 969         else if(flood == 1)
 970         {
 971                 if(autocvar_g_chat_flood_notify_flooder)
 972                 {
 973                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 974                         ret = 0;
 975                 }
 976                 else
 977                         ret = -1;
 978         }
 979         else
 980         {
 981                 ret = 1;
 982         }
 983
 984         if(sourcemsgstr != "" && ret != 0)
 985         {
 986                 if(ret < 0) // fake
 987                 {
 988                         sprint(source, sourcemsgstr);
 989                         if(sourcecmsgstr != "" && !privatesay)
 990                                 centerprint(source, sourcecmsgstr);
 991                 }
 992                 else if(privatesay)
 993                 {
 994                         sprint(source, sourcemsgstr);
 995                         sprint(privatesay, msgstr);
 996                         if(cmsgstr != "")
 997                                 centerprint(privatesay, cmsgstr);
 998                 }
 999                 else if(teamsay > 0)
1000                 {
1001                         sprint(source, sourcemsgstr);
1002                         if(sourcecmsgstr != "")
1003                                 centerprint(source, sourcecmsgstr);
1004                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1005                                 if(head != source)
1006                                 {
1007                                         sprint(head, msgstr);
1008                                         if(cmsgstr != "")
1009                                                 centerprint(head, cmsgstr);
1010                                 }
1011                 }
1012                 else if(teamsay < 0)
1013                 {
1014                         sprint(source, sourcemsgstr);
1015                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1016                                 if(head != source)
1017                                         sprint(head, msgstr);
1018                 }
1019                 else if(sourcemsgstr != msgstr)
1020                 {
1021                         sprint(source, sourcemsgstr);
1022                         FOR_EACH_REALCLIENT(head)
1023                                 if(head != source)
1024                                         sprint(head, msgstr);
1025                 }
1026                 else
1027                         bprint(msgstr);
1028         }
1029
1030         return ret;
1031 }
1032
1033 float GetVoiceMessageVoiceType(string type)
1034 {
1035         if(type == "taunt")
1036                 return VOICETYPE_TAUNT;
1037         if(type == "teamshoot")
1038                 return VOICETYPE_LASTATTACKER;
1039         return VOICETYPE_TEAMRADIO;
1040 }
1041
1042 string allvoicesamples;
1043 .string GetVoiceMessageSampleField(string type)
1044 {
1045         GetPlayerSoundSampleField_notFound = 0;
1046         switch(type)
1047         {
1048 #define _VOICEMSG(m) case #m: return playersound_##m;
1049                 ALLVOICEMSGS
1050 #undef _VOICEMSG
1051         }
1052         GetPlayerSoundSampleField_notFound = 1;
1053         return playersound_taunt;
1054 }
1055
1056 .string GetPlayerSoundSampleField(string type)
1057 {
1058         GetPlayerSoundSampleField_notFound = 0;
1059         switch(type)
1060         {
1061 #define _VOICEMSG(m) case #m: return playersound_##m;
1062                 ALLPLAYERSOUNDS
1063 #undef _VOICEMSG
1064         }
1065         GetPlayerSoundSampleField_notFound = 1;
1066         return playersound_taunt;
1067 }
1068
1069 void PrecacheGlobalSound(string samplestring)
1070 {
1071         float n, i;
1072         tokenize_console(samplestring);
1073         n = stof(argv(1));
1074         if(n > 0)
1075         {
1076                 for(i = 1; i <= n; ++i)
1077                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1078         }
1079         else
1080         {
1081                 precache_sound(strcat(argv(0), ".wav"));
1082         }
1083 }
1084
1085 void PrecachePlayerSounds(string f)
1086 {
1087         float fh;
1088         string s;
1089         fh = fopen(f, FILE_READ);
1090         if(fh < 0)
1091                 return;
1092         while((s = fgets(fh)))
1093         {
1094                 if(tokenize_console(s) != 3)
1095                 {
1096                         dprint("Invalid sound info line: ", s, "\n");
1097                         continue;
1098                 }
1099                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1100         }
1101         fclose(fh);
1102
1103         if not(allvoicesamples)
1104         {
1105 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1106                 ALLVOICEMSGS
1107 #undef _VOICEMSG
1108                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1109         }
1110 }
1111
1112 void ClearPlayerSounds()
1113 {
1114 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1115         ALLPLAYERSOUNDS
1116         ALLVOICEMSGS
1117 #undef _VOICEMSG
1118 }
1119
1120 float LoadPlayerSounds(string f, float first)
1121 {
1122         float fh;
1123         string s;
1124         var .string field;
1125         fh = fopen(f, FILE_READ);
1126         if(fh < 0)
1127         {
1128                 dprint("Player sound file not found: ", f, "\n");
1129                 return 0;
1130         }
1131         while((s = fgets(fh)))
1132         {
1133                 if(tokenize_console(s) != 3)
1134                         continue;
1135                 field = GetPlayerSoundSampleField(argv(0));
1136                 if(GetPlayerSoundSampleField_notFound)
1137                         field = GetVoiceMessageSampleField(argv(0));
1138                 if(GetPlayerSoundSampleField_notFound)
1139                         continue;
1140                 if(self.field)
1141                         strunzone(self.field);
1142                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1143         }
1144         fclose(fh);
1145         return 1;
1146 }
1147
1148 .float modelindex_for_playersound;
1149 .float skinindex_for_playersound;
1150 void UpdatePlayerSounds()
1151 {
1152         if(self.modelindex == self.modelindex_for_playersound)
1153         if(self.skinindex == self.skinindex_for_playersound)
1154                 return;
1155         self.modelindex_for_playersound = self.modelindex;
1156         self.skinindex_for_playersound = self.skinindex;
1157         ClearPlayerSounds();
1158         LoadPlayerSounds("sound/player/default.sounds", 1);
1159         if(!autocvar_g_debug_defaultsounds)
1160                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1161                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1162 }
1163
1164 void FakeGlobalSound(string sample, float chan, float voicetype)
1165 {
1166         float n;
1167         float tauntrand;
1168
1169         if(sample == "")
1170                 return;
1171
1172         tokenize_console(sample);
1173         n = stof(argv(1));
1174         if(n > 0)
1175                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1176         else
1177                 sample = strcat(argv(0), ".wav"); // randomization
1178
1179         switch(voicetype)
1180         {
1181                 case VOICETYPE_LASTATTACKER_ONLY:
1182                         break;
1183                 case VOICETYPE_LASTATTACKER:
1184                         if(self.pusher)
1185                         {
1186                                 msg_entity = self;
1187                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1188                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1189                         }
1190                         break;
1191                 case VOICETYPE_TEAMRADIO:
1192                         msg_entity = self;
1193                         if(msg_entity.cvar_cl_voice_directional == 1)
1194                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1195                         else
1196                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1197                         break;
1198                 case VOICETYPE_AUTOTAUNT:
1199                         if(!sv_autotaunt)
1200                                 break;
1201                         if(!sv_taunt)
1202                                 break;
1203                         if(sv_gentle)
1204                                 break;
1205                         tauntrand = random();
1206                         msg_entity = self;
1207                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1208                         {
1209                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1210                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1211                                 else
1212                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1213                         }
1214                         break;
1215                 case VOICETYPE_TAUNT:
1216                         if(self.classname == "player")
1217                                 if(self.deadflag == DEAD_NO)
1218                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1219                         if(!sv_taunt)
1220                                 break;
1221                         if(sv_gentle)
1222                                 break;
1223                         msg_entity = self;
1224                         if (msg_entity.cvar_cl_voice_directional >= 1)
1225                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1226                         else
1227                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1228                         break;
1229                 case VOICETYPE_PLAYERSOUND:
1230                         msg_entity = self;
1231                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1232                         break;
1233                 default:
1234                         backtrace("Invalid voice type!");
1235                         break;
1236         }
1237 }
1238
1239 void GlobalSound(string sample, float chan, float voicetype)
1240 {
1241         float n;
1242         float tauntrand;
1243
1244         if(sample == "")
1245                 return;
1246
1247         tokenize_console(sample);
1248         n = stof(argv(1));
1249         if(n > 0)
1250                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1251         else
1252                 sample = strcat(argv(0), ".wav"); // randomization
1253
1254         switch(voicetype)
1255         {
1256                 case VOICETYPE_LASTATTACKER_ONLY:
1257                         if(self.pusher)
1258                         {
1259                                 msg_entity = self.pusher;
1260                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1261                                 {
1262                                         if(msg_entity.cvar_cl_voice_directional == 1)
1263                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1264                                         else
1265                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1266                                 }
1267                         }
1268                         break;
1269                 case VOICETYPE_LASTATTACKER:
1270                         if(self.pusher)
1271                         {
1272                                 msg_entity = self.pusher;
1273                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1274                                 {
1275                                         if(msg_entity.cvar_cl_voice_directional == 1)
1276                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1277                                         else
1278                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1279                                 }
1280                                 msg_entity = self;
1281                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1282                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1283                         }
1284                         break;
1285                 case VOICETYPE_TEAMRADIO:
1286                         FOR_EACH_REALCLIENT(msg_entity)
1287                                 if(!teamplay || msg_entity.team == self.team)
1288                                 {
1289                                         if(msg_entity.cvar_cl_voice_directional == 1)
1290                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1291                                         else
1292                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1293                                 }
1294                         break;
1295                 case VOICETYPE_AUTOTAUNT:
1296                         if(!sv_autotaunt)
1297                                 break;
1298                         if(!sv_taunt)
1299                                 break;
1300                         if(sv_gentle)
1301                                 break;
1302                         tauntrand = random();
1303                         FOR_EACH_REALCLIENT(msg_entity)
1304                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1305                                 {
1306                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1308                                         else
1309                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1310                                 }
1311                         break;
1312                 case VOICETYPE_TAUNT:
1313                         if(self.classname == "player")
1314                                 if(self.deadflag == DEAD_NO)
1315                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1316                         if(!sv_taunt)
1317                                 break;
1318                         if(sv_gentle)
1319                                 break;
1320                         FOR_EACH_REALCLIENT(msg_entity)
1321                         {
1322                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1323                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1324                                 else
1325                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1326                         }
1327                         break;
1328                 case VOICETYPE_PLAYERSOUND:
1329                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1330                         break;
1331                 default:
1332                         backtrace("Invalid voice type!");
1333                         break;
1334         }
1335 }
1336
1337 void PlayerSound(.string samplefield, float chan, float voicetype)
1338 {
1339         GlobalSound(self.samplefield, chan, voicetype);
1340 }
1341
1342 void VoiceMessage(string type, string msg)
1343 {
1344         var .string sample;
1345         float voicetype, ownteam;
1346         float flood;
1347         sample = GetVoiceMessageSampleField(type);
1348
1349         if(GetPlayerSoundSampleField_notFound)
1350         {
1351                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1352                 return;
1353         }
1354
1355         voicetype = GetVoiceMessageVoiceType(type);
1356         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1357
1358         flood = Say(self, ownteam, world, msg, 1);
1359
1360         if (flood > 0)
1361                 GlobalSound(self.sample, CH_VOICE, voicetype);
1362         else if (flood < 0)
1363                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1364 }
1365
1366 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1367 {
1368 //      show_message
1369 //      0 (00) automove centerprint, admin message
1370 //      1 (01) automove centerprint, no admin message
1371 //      2 (10) no centerprint, admin message
1372 //      3 (11) no centerprint, no admin message
1373
1374         float lockteams_backup;
1375
1376         lockteams_backup = lockteams;  // backup any team lock
1377
1378         lockteams = 0;  // disable locked teams
1379
1380         TeamchangeFrags(client);  // move the players frags
1381         SetPlayerColors(client, team_colour - 1);  // set the players colour
1382         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1383
1384         lockteams = lockteams_backup;  // restore the team lock
1385
1386         LogTeamchange(client.playerid, client.team, type);
1387
1388         if not(show_message & 1) // admin message
1389                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1390
1391         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1392 }