qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.frame = oldself.frame;
 170         self.pain_finished = oldself.pain_finished;
 171         self.health = oldself.health;
 172         self.armorvalue = oldself.armorvalue;
 173         self.armortype = oldself.armortype;
 174         self.model = oldself.model;
 175         self.modelindex = oldself.modelindex;
 176         self.skin = oldself.skin;
 177         self.species = oldself.species;
 178         self.movetype = oldself.movetype;
 179         self.solid = oldself.solid;
 180         self.ballistics_density = oldself.ballistics_density;
 181         self.takedamage = oldself.takedamage;
 182         self.customizeentityforclient = oldself.customizeentityforclient;
 183         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 184         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 185         if (keepvelocity == 1)
 186                 self.velocity = oldself.velocity;
 187         self.oldvelocity = self.velocity;
 188         self.fade_time = oldself.fade_time;
 189         self.fade_rate = oldself.fade_rate;
 190         //self.weapon = oldself.weapon;
 191         setorigin(self, oldself.origin);
 192         setsize(self, oldself.mins, oldself.maxs);
 193         self.prevorigin = oldself.origin;
 194         self.reset = SUB_Remove;
 195
 196         Drag_MoveDrag(oldself, self);
 197
 198         if(self.colormap <= maxclients && self.colormap > 0)
 199                 self.colormap = 1024 + self.clientcolors;
 200
 201         CSQCMODEL_AUTOINIT();
 202         self.CopyBody_nextthink = oldself.nextthink;
 203         self.CopyBody_think = oldself.think;
 204         self.nextthink = time;
 205         self.think = CopyBody_Think;
 206
 207         self = oldself;
 208 }
 209
 210 float player_getspecies()
 211 {
 212         float s;
 213         get_model_parameters(self.model, self.skin);
 214         s = get_model_parameters_species;
 215         get_model_parameters(string_null, 0);
 216         if(s < 0)
 217                 return SPECIES_HUMAN;
 218         return s;
 219 }
 220
 221 void player_setupanimsformodel()
 222 {
 223         // defaults for legacy .zym models without animinfo files
 224         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 225         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 226         self.anim_draw = animfixfps(self, '2 1 3');
 227         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 228         self.anim_duckwalk = animfixfps(self, '4 1 1');
 229         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 230         self.anim_duckidle = animfixfps(self, '6 1 1');
 231         self.anim_idle = animfixfps(self, '7 1 1');
 232         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 233         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 234         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 235         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 236         self.anim_taunt = animfixfps(self, '12 1 0.33');
 237         self.anim_run = animfixfps(self, '13 1 1');
 238         self.anim_runbackwards = animfixfps(self, '14 1 1');
 239         self.anim_strafeleft = animfixfps(self, '15 1 1');
 240         self.anim_straferight = animfixfps(self, '16 1 1');
 241         //self.anim_dead1 = animfixfps(self, '17 1 1');
 242         //self.anim_dead2 = animfixfps(self, '18 1 1');
 243         self.anim_forwardright = animfixfps(self, '19 1 1');
 244         self.anim_forwardleft = animfixfps(self, '20 1 1');
 245         self.anim_backright = animfixfps(self, '21 1 1');
 246         self.anim_backleft  = animfixfps(self, '22 1 1');
 247         self.anim_melee = animfixfps(self, '23 1 1');
 248         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 249         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 250         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 251         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 252         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 253         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 254         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 255         // TODO introspect models for finding right "fps" value (1/duration)
 256         // reset animstate now
 257         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 258 }
 259
 260 void player_anim (void)
 261 {
 262         updateanim(self);
 263         if (self.weaponentity)
 264                 updateanim(self.weaponentity);
 265
 266         if (self.deadflag != DEAD_NO)
 267                 return;
 268
 269         if (!self.animstate_override)
 270         {
 271                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 272                 {
 273                         if (self.crouch)
 274                         {
 275                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 276                                 {
 277                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 278                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 279                                         {
 280                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 281                                                 self.restart_jump = FALSE;
 282                                         }
 283                                 }
 284                         }
 285                         else
 286                         {
 287                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 288                 {
 289                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 290                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 291                     {
 292                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 293                         self.restart_jump = FALSE;
 294                     }
 295                 }
 296                         }
 297                 }
 298                 else if (self.crouch)
 299                 {
 300                         if (self.movement_x > 0 && self.movement_y == 0)
 301                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x < 0 && self.movement_y == 0)
 303                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x == 0 && self.movement_y > 0)
 305                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x == 0 && self.movement_y < 0)
 307                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 308                         else if (self.movement_x > 0 && self.movement_y > 0)
 309                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 310                         else if (self.movement_x > 0 && self.movement_y < 0)
 311                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 312                         else if (self.movement_x < 0 && self.movement_y > 0)
 313                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 314                         else if (self.movement_x < 0 && self.movement_y < 0)
 315                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 316                         else
 317                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 318                 }
 319                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 320                 {
 321                         if (self.movement_x > 0 && self.movement_y == 0)
 322                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 323                         else if (self.movement_x < 0 && self.movement_y == 0)
 324                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 325                         else if (self.movement_x == 0 && self.movement_y > 0)
 326                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 327                         else if (self.movement_x == 0 && self.movement_y < 0)
 328                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 329                         else if (self.movement_x > 0 && self.movement_y > 0)
 330                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 331                         else if (self.movement_x > 0 && self.movement_y < 0)
 332                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 333                         else if (self.movement_x < 0 && self.movement_y > 0)
 334                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 335                         else if (self.movement_x < 0 && self.movement_y < 0)
 336                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 337                         else
 338                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 339                 }
 340                 else
 341                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 342         }
 343
 344         if (self.weaponentity)
 345         if (!self.weaponentity.animstate_override)
 346                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 347 }
 348
 349 void SpawnThrownWeapon (vector org, float w)
 350 {
 351         if(g_minstagib)
 352         if(self.ammo_cells <= 0)
 353                 return;
 354
 355         if(g_pinata)
 356         {
 357                 float j;
 358                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 359                 {
 360                         if(self.weapons & W_WeaponBit(j))
 361                                 if(W_IsWeaponThrowable(j))
 362                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 363                 }
 364         }
 365         else
 366         {
 367                 if(W_IsWeaponThrowable(self.weapon))
 368                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 369         }
 370 }
 371
 372 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 373 {
 374         float take, save;
 375         vector v;
 376         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 377
 378         // damage resistance (ignore most of the damage from a bullet or similar)
 379         damage = max(damage - 5, 1);
 380
 381         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 382         take = v_x;
 383         save = v_y;
 384
 385         if(sound_allowed(MSG_BROADCAST, attacker))
 386         {
 387                 if (save > 10)
 388                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 389                 else if (take > 30)
 390                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 391                 else if (take > 10)
 392                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 393         }
 394
 395         if (take > 50)
 396                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 397         if (take > 100)
 398                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 399
 400         if (!(self.flags & FL_GODMODE))
 401         {
 402                 self.armorvalue = self.armorvalue - save;
 403                 self.health = self.health - take;
 404                 // pause regeneration for 5 seconds
 405                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 406         }
 407         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 408         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 409         self.dmg_inflictor = inflictor;
 410
 411         if (self.health <= -autocvar_sv_gibhealth && !(self.effects & CSQCMODEL_EF_INVISIBLE))
 412         {
 413                 // don't use any animations as a gib
 414                 self.frame = 0;
 415                 // view just above the floor
 416                 self.view_ofs = '0 0 4';
 417
 418                 Violence_GibSplash(self, 1, 1, attacker);
 419                 self.effects |= CSQCMODEL_EF_INVISIBLE;
 420                 self.solid = SOLID_NOT; // restore later
 421         }
 422 }
 423
 424 void ClientKill_Now_TeamChange();
 425 void freezetag_CheckWinner();
 426
 427 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 428 {
 429         float take, save, waves, sdelay, dh, da, j;
 430         vector v;
 431         float valid_damage_for_weaponstats;
 432         float excess;
 433
 434         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 435                 return;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 461                 force = v_right * vlen(force);
 462                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 463                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 464                 if(f > 0)
 465                 {
 466                         hitloc = ear1;
 467                         force = force * -1;
 468                 }
 469                 else
 470                 {
 471                         hitloc = ear2;
 472                         // force is already good
 473                 }
 474         }
 475         else
 476                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 477
 478         if (!g_minstagib)
 479         {
 480                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 481                 take = v_x;
 482                 save = v_y;
 483         }
 484         else
 485         {
 486                 save = 0;
 487                 take = damage;
 488         }
 489
 490         frag_inflictor = inflictor;
 491         frag_attacker = attacker;
 492         frag_target = self;
 493         damage_take = take;
 494         damage_save = save;
 495         damage_force = force;
 496         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 497         take = bound(0, damage_take, self.health);
 498         save = bound(0, damage_save, self.armorvalue);
 499         excess = max(0, damage - take - save);
 500
 501         if(sound_allowed(MSG_BROADCAST, attacker))
 502         {
 503                 if (save > 10)
 504                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 505                 else if (take > 30)
 506                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 507                 else if (take > 10)
 508                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 509         }
 510
 511         if (take > 50)
 512                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 513         if (take > 100)
 514                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 515
 516         if (time >= self.spawnshieldtime)
 517         {
 518                 if (!(self.flags & FL_GODMODE))
 519                 {
 520                         self.armorvalue = self.armorvalue - save;
 521                         self.health = self.health - take;
 522                         // pause regeneration for 5 seconds
 523                         if(take)
 524                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 525
 526                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 527                         {
 528                                 self.pain_finished = time + 0.5;        //Supajoe
 529
 530                                 if(sv_gentle < 1) {
 531                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 532                                         {
 533                                                 if (!self.animstate_override)
 534                                                 {
 535                                                         if (random() > 0.5)
 536                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 537                                                         else
 538                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 539                                                 }
 540                                         }
 541
 542                                         if(sound_allowed(MSG_BROADCAST, attacker))
 543                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 544                                         if(self.health > 1)
 545                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 546                                         {
 547                                                 if(deathtype == DEATH_FALL)
 548                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 549                                                 else if(self.health > 75) // TODO make a "gentle" version?
 550                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 551                                                 else if(self.health > 50)
 552                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 553                                                 else if(self.health > 25)
 554                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else
 556                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                         }
 558                                 }
 559
 560                                 // throw off bot aim temporarily
 561                                 float shake;
 562                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 563                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 564                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 565                         }
 566                 }
 567                 else
 568                         self.max_armorvalue += (save + take);
 569         }
 570         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 571         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 572         self.dmg_inflictor = inflictor;
 573
 574         if(attacker == self)
 575         {
 576                 // don't reset pushltime for self damage as it may be an attempt to
 577                 // escape a lava pit or similar
 578                 //self.pushltime = 0;
 579         }
 580         else if(attacker.classname == "player")
 581         {
 582                 self.pusher = attacker;
 583                 self.pushltime = time + autocvar_g_maxpushtime;
 584         }
 585         else if(time < self.pushltime)
 586         {
 587                 attacker = self.pusher;
 588                 self.pushltime = max(self.pushltime, time + 0.6);
 589         }
 590         else
 591                 self.pushltime = 0;
 592
 593         float abot, vbot, awep;
 594         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 595         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 596
 597         valid_damage_for_weaponstats = 0;
 598         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 599         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 600         if(attacker && self != attacker)
 601         if(IsDifferentTeam(self, attacker))
 602         {
 603                 if(DEATH_ISSPECIAL(deathtype))
 604                         awep = attacker.weapon;
 605                 else
 606                         awep = DEATH_WEAPONOF(deathtype);
 607                 valid_damage_for_weaponstats = 1;
 608         }
 609
 610         if(valid_damage_for_weaponstats)
 611         {
 612                 dh = dh - max(self.health, 0);
 613                 da = da - max(self.armorvalue, 0);
 614                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 615         }
 616
 617         if (self.health < 1)
 618         {
 619                 float defer_ClientKill_Now_TeamChange;
 620                 defer_ClientKill_Now_TeamChange = FALSE;
 621
 622                 if(self.alivetime)
 623                 {
 624                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                         self.alivetime = 0;
 626                 }
 627
 628                 if(valid_damage_for_weaponstats)
 629                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 630
 631                 if(sv_gentle < 1) // TODO make a "gentle" version?
 632                 if(sound_allowed(MSG_BROADCAST, attacker))
 633                 {
 634                         if(deathtype == DEATH_DROWN)
 635                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 636                         else
 637                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 638                 }
 639
 640                 // get rid of kill indicator
 641                 if(self.killindicator)
 642                 {
 643                         remove(self.killindicator);
 644                         self.killindicator = world;
 645                         if(self.killindicator_teamchange)
 646                                 defer_ClientKill_Now_TeamChange = TRUE;
 647
 648                         if(self.classname == "body")
 649                         if(deathtype == DEATH_KILL)
 650                         {
 651                                 // for the lemmings fans, a small harmless explosion
 652                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 653                         }
 654                 }
 655
 656                 if(!g_freezetag)
 657                 {
 658                         // become fully visible
 659                         self.alpha = 1;
 660                         // throw a weapon
 661                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 662                 }
 663
 664                 // print an obituary message
 665                 Obituary (attacker, inflictor, self, deathtype);
 666                 race_PreDie();
 667                 DropAllRunes(self);
 668
 669         // increment frag counter for used weapon type
 670         float w;
 671         w = DEATH_WEAPONOF(deathtype);
 672         if(WEP_VALID(w))
 673         if(accuracy_isgooddamage(attacker, self))
 674         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 675
 676                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 677                 {
 678                         PutClientInServer();
 679                         count_alive_players(); // re-count players
 680                         freezetag_CheckWinner();
 681                         return;
 682                 }
 683
 684                 frag_attacker = attacker;
 685                 frag_inflictor = inflictor;
 686                 frag_target = self;
 687                 MUTATOR_CALLHOOK(PlayerDies);
 688                 weapon_action(self.weapon, WR_PLAYERDEATH);
 689
 690                 RemoveGrapplingHook(self);
 691
 692                 if(self.flagcarried)
 693                 {
 694                         if(attacker.classname != "player")
 695                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 696                         else if(attacker.team == self.team)
 697                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 698                         else
 699                                 DropFlag(self.flagcarried, world, attacker);
 700                 }
 701                 if(self.ballcarried && g_nexball)
 702                         DropBall(self.ballcarried, self.origin, self.velocity);
 703                 Portal_ClearAllLater(self);
 704
 705                 if(clienttype(self) == CLIENTTYPE_REAL)
 706                 {
 707                         stuffcmd(self, "-zoom\n");
 708                         self.fixangle = TRUE;
 709                         //msg_entity = self;
 710                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 711                         //WriteAngle (MSG_ONE, self.v_angle_x);
 712                         //WriteAngle (MSG_ONE, self.v_angle_y);
 713                         //WriteAngle (MSG_ONE, 80);
 714                 }
 715
 716                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 717                         ClientKill_Now_TeamChange();
 718
 719                 if(g_arena)
 720                         Spawnqueue_Unmark(self);
 721
 722                 if(g_freezetag)
 723                         return;
 724
 725                 // when we get here, player actually dies
 726                 // clear waypoints (do this AFTER FreezeTag)
 727                 WaypointSprite_PlayerDead();
 728
 729                 // make the corpse upright (not tilted)
 730                 self.angles_x = 0;
 731                 self.angles_z = 0;
 732                 // don't spin
 733                 self.avelocity = '0 0 0';
 734                 // view from the floor
 735                 self.view_ofs = '0 0 -8';
 736                 // toss the corpse
 737                 self.movetype = MOVETYPE_TOSS;
 738                 // shootable corpse
 739                 self.solid = SOLID_CORPSE;
 740                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 741                 // don't stick to the floor
 742                 self.flags &~= FL_ONGROUND;
 743                 // dying animation
 744                 self.deadflag = DEAD_DYING;
 745                 // when to allow respawn
 746                 sdelay = 0;
 747                 waves = 0;
 748                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 749                 if(!sdelay)
 750                 {
 751                         if(g_cts)
 752                                 sdelay = 0; // no respawn delay in CTS
 753                         else
 754                                 sdelay = autocvar_g_respawn_delay;
 755                 }
 756                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 757                 if(!waves)
 758                         waves = autocvar_g_respawn_waves;
 759                 if(waves)
 760                         self.death_time = ceil((time + sdelay) / waves) * waves;
 761                 else
 762                         self.death_time = time + sdelay;
 763                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 764                         self.respawn_countdown = 10; // first number to count down from is 10
 765                 else
 766                         self.respawn_countdown = -1; // do not count down
 767                 if (random() < 0.5)
 768                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 769                 else
 770                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 771                 if (self.maxs_z > 5)
 772                 {
 773                         self.maxs_z = 5;
 774                         setsize(self, self.mins, self.maxs);
 775                 }
 776                 // set damage function to corpse damage
 777                 self.event_damage = PlayerCorpseDamage;
 778                 // call the corpse damage function just in case it wants to gib
 779                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 780                 // set up to fade out later
 781                 SUB_SetFade (self, time + 6 + random (), 1);
 782
 783                 if(sv_gentle > 0 || autocvar_ekg) {
 784                         // remove corpse
 785                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 786                 }
 787
 788                 // reset fields the weapons may use just in case
 789                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 790                 {
 791                         weapon_action(j, WR_RESETPLAYER);
 792                         ATTACK_FINISHED_FOR(self, j) = 0;
 793                 }
 794         }
 795 }
 796
 797 .float muted; // to be used by prvm_edictset server playernumber muted 1
 798 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 799 // message "": do not say, just test flood control
 800 // return value:
 801 //   1 = accept
 802 //   0 = reject
 803 //  -1 = fake accept
 804 {
 805         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 806         float flood, privatemsgprefixlen;
 807         var .float flood_field;
 808         entity head;
 809         float ret;
 810
 811         if(Ban_MaybeEnforceBan(source))
 812                 return 0;
 813
 814         if(!teamsay && !privatesay)
 815                 if(substring(msgin, 0, 1) == " ")
 816                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 817
 818         msgin = formatmessage(msgin);
 819
 820         if(source.classname != "player")
 821                 colorstr = "^0"; // black for spectators
 822         else if(teamplay)
 823                 colorstr = Team_ColorCode(source.team);
 824         else
 825                 teamsay = FALSE;
 826
 827         if(intermission_running)
 828                 teamsay = FALSE;
 829
 830         if(msgin != "")
 831                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 832
 833         /*
 834          * using bprint solves this... me stupid
 835         // how can we prevent the message from appearing in a listen server?
 836         // for now, just give "say" back and only handle say_team
 837         if(!teamsay)
 838         {
 839                 clientcommand(self, strcat("say ", msgin));
 840                 return;
 841         }
 842         */
 843
 844         if(autocvar_g_chat_teamcolors)
 845                 namestr = playername(source);
 846         else
 847                 namestr = source.netname;
 848
 849         if(msgin != "")
 850         {
 851                 if(privatesay)
 852                 {
 853                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 854                         privatemsgprefixlen = strlen(msgstr);
 855                         msgstr = strcat(msgstr, msgin);
 856                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 857                         if(autocvar_g_chat_teamcolors)
 858                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 859                         else
 860                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 861                 }
 862                 else if(teamsay)
 863                 {
 864                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 865                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 866                 }
 867                 else
 868                 {
 869                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 870                         cmsgstr = "";
 871                 }
 872                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 873         }
 874         else
 875         {
 876                 msgstr = cmsgstr = "";
 877         }
 878
 879         fullmsgstr = msgstr;
 880         fullcmsgstr = cmsgstr;
 881
 882         // FLOOD CONTROL
 883         flood = 0;
 884         if(floodcontrol)
 885         {
 886                 float flood_spl;
 887                 float flood_burst;
 888                 float flood_lmax;
 889                 float lines;
 890                 if(privatesay)
 891                 {
 892                         flood_spl = autocvar_g_chat_flood_spl_tell;
 893                         flood_burst = autocvar_g_chat_flood_burst_tell;
 894                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 895                         flood_field = floodcontrol_chattell;
 896                 }
 897                 else if(teamsay)
 898                 {
 899                         flood_spl = autocvar_g_chat_flood_spl_team;
 900                         flood_burst = autocvar_g_chat_flood_burst_team;
 901                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 902                         flood_field = floodcontrol_chatteam;
 903                 }
 904                 else
 905                 {
 906                         flood_spl = autocvar_g_chat_flood_spl;
 907                         flood_burst = autocvar_g_chat_flood_burst;
 908                         flood_lmax = autocvar_g_chat_flood_lmax;
 909                         flood_field = floodcontrol_chat;
 910                 }
 911                 flood_burst = max(0, flood_burst - 1);
 912                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 913
 914                 // do flood control for the default line size
 915                 if(msgstr != "")
 916                 {
 917                         getWrappedLine_remaining = msgstr;
 918                         msgstr = "";
 919                         lines = 0;
 920                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 921                         {
 922                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 923                                 ++lines;
 924                         }
 925                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 926
 927                         if(getWrappedLine_remaining != "")
 928                         {
 929                                 msgstr = strcat(msgstr, "\n");
 930                                 flood = 2;
 931                         }
 932
 933                         if(time >= source.flood_field)
 934                         {
 935                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 936                         }
 937                         else
 938                         {
 939                                 flood = 1;
 940                                 msgstr = fullmsgstr;
 941                         }
 942                 }
 943                 else
 944                 {
 945                         if(time >= source.flood_field)
 946                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 947                         else
 948                                 flood = 1;
 949                 }
 950
 951                 if (timeoutStatus == 2) //when game is paused, no flood protection
 952                         source.flood_field = flood = 0;
 953         }
 954
 955         if(flood == 2) // cannot happen for empty msgstr
 956         {
 957                 if(autocvar_g_chat_flood_notify_flooder)
 958                 {
 959                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 960                         sourcecmsgstr = "";
 961                 }
 962                 else
 963                 {
 964                         sourcemsgstr = fullmsgstr;
 965                         sourcecmsgstr = fullcmsgstr;
 966                 }
 967                 cmsgstr = "";
 968         }
 969         else
 970         {
 971                 sourcemsgstr = msgstr;
 972                 sourcecmsgstr = cmsgstr;
 973         }
 974
 975         if(!privatesay)
 976         if(source.classname != "player")
 977         {
 978                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 979                         teamsay = -1; // spectators
 980         }
 981
 982         if(flood)
 983                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 984
 985         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 986         if(privatesay)
 987                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 988
 989         if(source.muted)
 990         {
 991                 // always fake the message
 992                 ret = -1;
 993         }
 994         else if(flood == 1)
 995         {
 996                 if(autocvar_g_chat_flood_notify_flooder)
 997                 {
 998                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 999                         ret = 0;
1000                 }
1001                 else
1002                         ret = -1;
1003         }
1004         else
1005         {
1006                 ret = 1;
1007         }
1008
1009         if(sourcemsgstr != "" && ret != 0)
1010         {
1011                 if(ret < 0) // fake
1012                 {
1013                         sprint(source, sourcemsgstr);
1014                         if(sourcecmsgstr != "" && !privatesay)
1015                                 centerprint(source, sourcecmsgstr);
1016                 }
1017                 else if(privatesay)
1018                 {
1019                         sprint(source, sourcemsgstr);
1020                         sprint(privatesay, msgstr);
1021                         if(cmsgstr != "")
1022                                 centerprint(privatesay, cmsgstr);
1023                 }
1024                 else if(teamsay > 0)
1025                 {
1026                         sprint(source, sourcemsgstr);
1027                         if(sourcecmsgstr != "")
1028                                 centerprint(source, sourcecmsgstr);
1029                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1030                                 if(head != source)
1031                                 {
1032                                         sprint(head, msgstr);
1033                                         if(cmsgstr != "")
1034                                                 centerprint(head, cmsgstr);
1035                                 }
1036                 }
1037                 else if(teamsay < 0)
1038                 {
1039                         sprint(source, sourcemsgstr);
1040                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1041                                 if(head != source)
1042                                         sprint(head, msgstr);
1043                 }
1044                 else if(sourcemsgstr != msgstr)
1045                 {
1046                         sprint(source, sourcemsgstr);
1047                         FOR_EACH_REALCLIENT(head)
1048                                 if(head != source)
1049                                         sprint(head, msgstr);
1050                 }
1051                 else
1052                         bprint(msgstr);
1053         }
1054
1055         return ret;
1056 }
1057
1058 float GetVoiceMessageVoiceType(string type)
1059 {
1060         if(type == "taunt")
1061                 return VOICETYPE_TAUNT;
1062         if(type == "teamshoot")
1063                 return VOICETYPE_LASTATTACKER;
1064         return VOICETYPE_TEAMRADIO;
1065 }
1066
1067 string allvoicesamples;
1068 .string GetVoiceMessageSampleField(string type)
1069 {
1070         GetPlayerSoundSampleField_notFound = 0;
1071         switch(type)
1072         {
1073 #define _VOICEMSG(m) case #m: return playersound_##m;
1074                 ALLVOICEMSGS
1075 #undef _VOICEMSG
1076         }
1077         GetPlayerSoundSampleField_notFound = 1;
1078         return playersound_taunt;
1079 }
1080
1081 .string GetPlayerSoundSampleField(string type)
1082 {
1083         GetPlayerSoundSampleField_notFound = 0;
1084         switch(type)
1085         {
1086 #define _VOICEMSG(m) case #m: return playersound_##m;
1087                 ALLPLAYERSOUNDS
1088 #undef _VOICEMSG
1089         }
1090         GetPlayerSoundSampleField_notFound = 1;
1091         return playersound_taunt;
1092 }
1093
1094 void PrecacheGlobalSound(string samplestring)
1095 {
1096         float n, i;
1097         tokenize_console(samplestring);
1098         n = stof(argv(1));
1099         if(n > 0)
1100         {
1101                 for(i = 1; i <= n; ++i)
1102                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1103         }
1104         else
1105         {
1106                 precache_sound(strcat(argv(0), ".wav"));
1107         }
1108 }
1109
1110 void PrecachePlayerSounds(string f)
1111 {
1112         float fh;
1113         string s;
1114         fh = fopen(f, FILE_READ);
1115         if(fh < 0)
1116                 return;
1117         while((s = fgets(fh)))
1118         {
1119                 if(tokenize_console(s) != 3)
1120                 {
1121                         dprint("Invalid sound info line: ", s, "\n");
1122                         continue;
1123                 }
1124                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1125         }
1126         fclose(fh);
1127
1128         if not(allvoicesamples)
1129         {
1130 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1131                 ALLVOICEMSGS
1132 #undef _VOICEMSG
1133                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1134         }
1135 }
1136
1137 void ClearPlayerSounds()
1138 {
1139 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1140         ALLPLAYERSOUNDS
1141         ALLVOICEMSGS
1142 #undef _VOICEMSG
1143 }
1144
1145 float LoadPlayerSounds(string f, float first)
1146 {
1147         float fh;
1148         string s;
1149         var .string field;
1150         fh = fopen(f, FILE_READ);
1151         if(fh < 0)
1152         {
1153                 dprint("Player sound file not found: ", f, "\n");
1154                 return 0;
1155         }
1156         while((s = fgets(fh)))
1157         {
1158                 if(tokenize_console(s) != 3)
1159                         continue;
1160                 field = GetPlayerSoundSampleField(argv(0));
1161                 if(GetPlayerSoundSampleField_notFound)
1162                         field = GetVoiceMessageSampleField(argv(0));
1163                 if(GetPlayerSoundSampleField_notFound)
1164                         continue;
1165                 if(self.field)
1166                         strunzone(self.field);
1167                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1168         }
1169         fclose(fh);
1170         return 1;
1171 }
1172
1173 .float modelindex_for_playersound;
1174 .float skin_for_playersound;
1175 void UpdatePlayerSounds()
1176 {
1177         if(self.modelindex == self.modelindex_for_playersound)
1178         if(self.skin == self.skin_for_playersound)
1179                 return;
1180         self.modelindex_for_playersound = self.modelindex;
1181         self.skin_for_playersound = self.skin;
1182         ClearPlayerSounds();
1183         LoadPlayerSounds("sound/player/default.sounds", 1);
1184         if(!autocvar_g_debug_defaultsounds)
1185                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1186                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1187 }
1188
1189 void FakeGlobalSound(string sample, float chan, float voicetype)
1190 {
1191         float n;
1192         float tauntrand;
1193
1194         if(sample == "")
1195                 return;
1196
1197         tokenize_console(sample);
1198         n = stof(argv(1));
1199         if(n > 0)
1200                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1201         else
1202                 sample = strcat(argv(0), ".wav"); // randomization
1203
1204         switch(voicetype)
1205         {
1206                 case VOICETYPE_LASTATTACKER_ONLY:
1207                         break;
1208                 case VOICETYPE_LASTATTACKER:
1209                         if(self.pusher)
1210                         {
1211                                 msg_entity = self;
1212                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1213                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1214                         }
1215                         break;
1216                 case VOICETYPE_TEAMRADIO:
1217                         msg_entity = self;
1218                         if(msg_entity.cvar_cl_voice_directional == 1)
1219                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1220                         else
1221                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1222                         break;
1223                 case VOICETYPE_AUTOTAUNT:
1224                         if(!sv_autotaunt)
1225                                 break;
1226                         if(!sv_taunt)
1227                                 break;
1228                         if(sv_gentle)
1229                                 break;
1230                         tauntrand = random();
1231                         msg_entity = self;
1232                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1233                         {
1234                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1235                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1236                                 else
1237                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1238                         }
1239                         break;
1240                 case VOICETYPE_TAUNT:
1241                         if(self.classname == "player")
1242                                 if(self.deadflag == DEAD_NO)
1243                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1244                         if(!sv_taunt)
1245                                 break;
1246                         if(sv_gentle)
1247                                 break;
1248                         msg_entity = self;
1249                         if (msg_entity.cvar_cl_voice_directional >= 1)
1250                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1251                         else
1252                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1253                         break;
1254                 case VOICETYPE_PLAYERSOUND:
1255                         msg_entity = self;
1256                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1257                         break;
1258                 default:
1259                         backtrace("Invalid voice type!");
1260                         break;
1261         }
1262 }
1263
1264 void GlobalSound(string sample, float chan, float voicetype)
1265 {
1266         float n;
1267         float tauntrand;
1268
1269         if(sample == "")
1270                 return;
1271
1272         tokenize_console(sample);
1273         n = stof(argv(1));
1274         if(n > 0)
1275                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1276         else
1277                 sample = strcat(argv(0), ".wav"); // randomization
1278
1279         switch(voicetype)
1280         {
1281                 case VOICETYPE_LASTATTACKER_ONLY:
1282                         if(self.pusher)
1283                         {
1284                                 msg_entity = self.pusher;
1285                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1286                                 {
1287                                         if(msg_entity.cvar_cl_voice_directional == 1)
1288                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1289                                         else
1290                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1291                                 }
1292                         }
1293                         break;
1294                 case VOICETYPE_LASTATTACKER:
1295                         if(self.pusher)
1296                         {
1297                                 msg_entity = self.pusher;
1298                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1299                                 {
1300                                         if(msg_entity.cvar_cl_voice_directional == 1)
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1302                                         else
1303                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1304                                 }
1305                                 msg_entity = self;
1306                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1307                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1308                         }
1309                         break;
1310                 case VOICETYPE_TEAMRADIO:
1311                         FOR_EACH_REALCLIENT(msg_entity)
1312                                 if(!teamplay || msg_entity.team == self.team)
1313                                 {
1314                                         if(msg_entity.cvar_cl_voice_directional == 1)
1315                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1316                                         else
1317                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1318                                 }
1319                         break;
1320                 case VOICETYPE_AUTOTAUNT:
1321                         if(!sv_autotaunt)
1322                                 break;
1323                         if(!sv_taunt)
1324                                 break;
1325                         if(sv_gentle)
1326                                 break;
1327                         tauntrand = random();
1328                         FOR_EACH_REALCLIENT(msg_entity)
1329                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1330                                 {
1331                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1332                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1333                                         else
1334                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1335                                 }
1336                         break;
1337                 case VOICETYPE_TAUNT:
1338                         if(self.classname == "player")
1339                                 if(self.deadflag == DEAD_NO)
1340                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1341                         if(!sv_taunt)
1342                                 break;
1343                         if(sv_gentle)
1344                                 break;
1345                         FOR_EACH_REALCLIENT(msg_entity)
1346                         {
1347                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1348                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1349                                 else
1350                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1351                         }
1352                         break;
1353                 case VOICETYPE_PLAYERSOUND:
1354                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1355                         break;
1356                 default:
1357                         backtrace("Invalid voice type!");
1358                         break;
1359         }
1360 }
1361
1362 void PlayerSound(.string samplefield, float chan, float voicetype)
1363 {
1364         GlobalSound(self.samplefield, chan, voicetype);
1365 }
1366
1367 void VoiceMessage(string type, string msg)
1368 {
1369         var .string sample;
1370         float voicetype, ownteam;
1371         float flood;
1372         sample = GetVoiceMessageSampleField(type);
1373
1374         if(GetPlayerSoundSampleField_notFound)
1375         {
1376                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1377                 return;
1378         }
1379
1380         voicetype = GetVoiceMessageVoiceType(type);
1381         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1382
1383         flood = Say(self, ownteam, world, msg, 1);
1384
1385         if (flood > 0)
1386                 GlobalSound(self.sample, CH_VOICE, voicetype);
1387         else if (flood < 0)
1388                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1389 }
1390
1391 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1392 {
1393 //      show_message
1394 //      0 (00) automove centerprint, admin message
1395 //      1 (01) automove centerprint, no admin message
1396 //      2 (10) no centerprint, admin message
1397 //      3 (11) no centerprint, no admin message
1398
1399         float lockteams_backup;
1400
1401         lockteams_backup = lockteams;  // backup any team lock
1402
1403         lockteams = 0;  // disable locked teams
1404
1405         TeamchangeFrags(client);  // move the players frags
1406         SetPlayerColors(client, team_colour - 1);  // set the players colour
1407         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1408
1409         lockteams = lockteams_backup;  // restore the team lock
1410
1411         LogTeamchange(client.playerid, client.team, type);
1412
1413         if not(show_message & 1) // admin message
1414                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1415
1416         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1417 }