qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_pinata)
 266         {
 267                 float j;
 268                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 269                 {
 270                         if(WEPSET_CONTAINS_EW(self, j))
 271                                 if(W_IsWeaponThrowable(j))
 272                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 273                 }
 274         }
 275         else
 276         {
 277                 if(WEPSET_CONTAINS_EW(self, self.weapon))
 278                         if(W_IsWeaponThrowable(self.weapon))
 279                                 W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 280         }
 281 }
 282
 283 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 284 {
 285         float take, save;
 286         vector v;
 287         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 288
 289         // damage resistance (ignore most of the damage from a bullet or similar)
 290         damage = max(damage - 5, 1);
 291
 292         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 293         take = v_x;
 294         save = v_y;
 295
 296         if(sound_allowed(MSG_BROADCAST, attacker))
 297         {
 298                 if (save > 10)
 299                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 300                 else if (take > 30)
 301                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 302                 else if (take > 10)
 303                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 304         }
 305
 306         if (take > 50)
 307                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 308         if (take > 100)
 309                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 310
 311         if (!(self.flags & FL_GODMODE))
 312         {
 313                 self.armorvalue = self.armorvalue - save;
 314                 self.health = self.health - take;
 315                 // pause regeneration for 5 seconds
 316                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 317         }
 318         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 319         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 320         self.dmg_inflictor = inflictor;
 321
 322         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 323         {
 324                 // don't use any animations as a gib
 325                 self.frame = 0;
 326                 // view just above the floor
 327                 self.view_ofs = '0 0 4';
 328
 329                 Violence_GibSplash(self, 1, 1, attacker);
 330                 self.alpha = -1;
 331                 self.solid = SOLID_NOT; // restore later
 332                 self.takedamage = DAMAGE_NO; // restore later
 333                 self.damagedbycontents = FALSE;
 334         }
 335 }
 336
 337 void ClientKill_Now_TeamChange();
 338
 339 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 340 {
 341         float take, save, waves, sdelay, dh, da, j;
 342         vector v;
 343         float valid_damage_for_weaponstats;
 344         float excess;
 345
 346         dh = max(self.health, 0);
 347         da = max(self.armorvalue, 0);
 348
 349         if(!DEATH_ISSPECIAL(deathtype))
 350         {
 351                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 352                 if(self != attacker)
 353                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 354         }
 355
 356         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 357         {
 358                 // tuba causes blood to come out of the ears
 359                 vector ear1, ear2;
 360                 vector d;
 361                 float f;
 362                 ear1 = self.origin;
 363                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 364                 ear2 = ear1;
 365                 makevectors(self.angles);
 366                 ear1 += v_right * -10;
 367                 ear2 += v_right * +10;
 368                 d = inflictor.origin - self.origin;
 369                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 370                 force = v_right * vlen(force);
 371                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 372                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 373                 if(f > 0)
 374                 {
 375                         hitloc = ear1;
 376                         force = force * -1;
 377                 }
 378                 else
 379                 {
 380                         hitloc = ear2;
 381                         // force is already good
 382                 }
 383         }
 384         else
 385                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 386
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(attacker == self)
 393         {
 394                 // don't reset pushltime for self damage as it may be an attempt to
 395                 // escape a lava pit or similar
 396                 //self.pushltime = 0;
 397                 self.istypefrag = 0;
 398         }
 399         else if(IS_PLAYER(attacker))
 400         {
 401                 self.pusher = attacker;
 402                 self.pushltime = time + autocvar_g_maxpushtime;
 403                 self.istypefrag = self.BUTTON_CHAT;
 404         }
 405         else if(time < self.pushltime)
 406         {
 407                 attacker = self.pusher;
 408                 self.pushltime = max(self.pushltime, time + 0.6);
 409         }
 410         else
 411         {
 412                 self.pushltime = 0;
 413                 self.istypefrag = 0;
 414         }
 415
 416         frag_inflictor = inflictor;
 417         frag_attacker = attacker;
 418         frag_target = self;
 419         frag_damage = damage;
 420         damage_take = take;
 421         damage_save = save;
 422         damage_force = force;
 423         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 424         take = bound(0, damage_take, self.health);
 425         save = bound(0, damage_save, self.armorvalue);
 426         excess = max(0, damage - take - save);
 427
 428         if(sound_allowed(MSG_BROADCAST, attacker))
 429         {
 430                 if (save > 10)
 431                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 432                 else if (take > 30)
 433                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 434                 else if (take > 10)
 435                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 436         }
 437
 438         if (take > 50)
 439                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 440         if (take > 100)
 441                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 442
 443         if (time >= self.spawnshieldtime)
 444         {
 445                 if (!(self.flags & FL_GODMODE))
 446                 {
 447                         self.armorvalue = self.armorvalue - save;
 448                         self.health = self.health - take;
 449                         // pause regeneration for 5 seconds
 450                         if(take)
 451                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 452
 453                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 454                         {
 455                                 self.pain_finished = time + 0.5;        //Supajoe
 456
 457                                 if(autocvar_sv_gentle < 1) {
 458                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 459                                         {
 460                                                 if (!self.animstate_override)
 461                                                 {
 462                                                         if (random() > 0.5)
 463                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 464                                                         else
 465                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 466                                                 }
 467                                         }
 468
 469                                         if(sound_allowed(MSG_BROADCAST, attacker))
 470                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 471                                         if(self.health > 1)
 472                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 473                                         {
 474                                                 if(deathtype == DEATH_FALL)
 475                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 476                                                 else if(self.health > 75) // TODO make a "gentle" version?
 477                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 478                                                 else if(self.health > 50)
 479                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 480                                                 else if(self.health > 25)
 481                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 482                                                 else
 483                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 484                                         }
 485                                 }
 486
 487                                 // throw off bot aim temporarily
 488                                 float shake;
 489                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 490                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 491                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 492                         }
 493                 }
 494                 else
 495                         self.max_armorvalue += (save + take);
 496         }
 497         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 498         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 499         self.dmg_inflictor = inflictor;
 500
 501         if(g_ca && self != attacker && IS_PLAYER(attacker))
 502                 PlayerTeamScore_Add(attacker, SP_SCORE, ST_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 503
 504         float abot, vbot, awep;
 505         abot = (IS_BOT_CLIENT(attacker));
 506         vbot = (IS_BOT_CLIENT(self));
 507
 508         valid_damage_for_weaponstats = 0;
 509         awep = 0;
 510
 511         if(vbot || IS_REAL_CLIENT(self))
 512         if(abot || IS_REAL_CLIENT(attacker))
 513         if(attacker && self != attacker)
 514         if(IsDifferentTeam(self, attacker))
 515         {
 516                 if(DEATH_ISSPECIAL(deathtype))
 517                         awep = attacker.weapon;
 518                 else
 519                         awep = DEATH_WEAPONOF(deathtype);
 520                 valid_damage_for_weaponstats = 1;
 521         }
 522
 523         if(valid_damage_for_weaponstats)
 524         {
 525                 dh = dh - max(self.health, 0);
 526                 da = da - max(self.armorvalue, 0);
 527                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 528         }
 529
 530         if (self.health < 1)
 531         {
 532                 float defer_ClientKill_Now_TeamChange;
 533                 defer_ClientKill_Now_TeamChange = FALSE;
 534
 535                 if(self.alivetime)
 536                 {
 537                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 538                         self.alivetime = 0;
 539                 }
 540
 541                 if(valid_damage_for_weaponstats)
 542                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 543
 544                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 545                 if(sound_allowed(MSG_BROADCAST, attacker))
 546                 {
 547                         if(deathtype == DEATH_DROWN)
 548                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 549                         else
 550                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 551                 }
 552
 553                 // get rid of kill indicator
 554                 if(self.killindicator)
 555                 {
 556                         remove(self.killindicator);
 557                         self.killindicator = world;
 558                         if(self.killindicator_teamchange)
 559                                 defer_ClientKill_Now_TeamChange = TRUE;
 560
 561                         if(self.classname == "body")
 562                         if(deathtype == DEATH_KILL)
 563                         {
 564                                 // for the lemmings fans, a small harmless explosion
 565                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 566                         }
 567                 }
 568
 569                 // print an obituary message
 570                 Obituary (attacker, inflictor, self, deathtype);
 571                 race_PreDie();
 572
 573         // increment frag counter for used weapon type
 574         float w;
 575         w = DEATH_WEAPONOF(deathtype);
 576         if(WEP_VALID(w))
 577         if(accuracy_isgooddamage(attacker, self))
 578         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 579
 580                 frag_attacker = attacker;
 581                 frag_inflictor = inflictor;
 582                 frag_target = self;
 583                 frag_deathtype = deathtype;
 584                 MUTATOR_CALLHOOK(PlayerDies);
 585
 586                 weapon_action(self.weapon, WR_PLAYERDEATH);
 587
 588                 RemoveGrapplingHook(self);
 589
 590                 Portal_ClearAllLater(self);
 591
 592                 if(IS_REAL_CLIENT(self))
 593                 {
 594                         self.fixangle = TRUE;
 595                         //msg_entity = self;
 596                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 597                         //WriteAngle (MSG_ONE, self.v_angle_x);
 598                         //WriteAngle (MSG_ONE, self.v_angle_y);
 599                         //WriteAngle (MSG_ONE, 80);
 600                 }
 601
 602                 if(defer_ClientKill_Now_TeamChange)
 603                         ClientKill_Now_TeamChange(); // can turn player into spectator
 604
 605                 // player could have been miraculously resuscitated ;)
 606                 // e.g. players in freezetag get frozen, they don't really die
 607                 if(self.health >= 1 || !IS_PLAYER(self))
 608                         return;
 609
 610                 // when we get here, player actually dies
 611
 612                 // clear waypoints
 613                 WaypointSprite_PlayerDead();
 614                 // throw a weapon
 615                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 616
 617                 // become fully visible
 618                 self.alpha = default_player_alpha;
 619                 // make the corpse upright (not tilted)
 620                 self.angles_x = 0;
 621                 self.angles_z = 0;
 622                 // don't spin
 623                 self.avelocity = '0 0 0';
 624                 // view from the floor
 625                 self.view_ofs = '0 0 -8';
 626                 // toss the corpse
 627                 self.movetype = MOVETYPE_TOSS;
 628                 // shootable corpse
 629                 self.solid = SOLID_CORPSE;
 630                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 631                 // don't stick to the floor
 632                 self.flags &~= FL_ONGROUND;
 633                 // dying animation
 634                 self.deadflag = DEAD_DYING;
 635                 // when to allow respawn
 636                 sdelay = 0;
 637                 waves = 0;
 638                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 639                 if(!sdelay)
 640                 {
 641                         if(g_cts)
 642                                 sdelay = 0; // no respawn delay in CTS
 643                         else
 644                                 sdelay = autocvar_g_respawn_delay;
 645                 }
 646                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 647                 if(!waves)
 648                         waves = autocvar_g_respawn_waves;
 649                 if(waves)
 650                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 651                 else
 652                         self.respawn_time = time + sdelay;
 653                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 654                         self.respawn_countdown = 10; // first number to count down from is 10
 655                 else
 656                         self.respawn_countdown = -1; // do not count down
 657
 658                 if(g_cts || autocvar_g_forced_respawn)
 659                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 660
 661                 self.death_time = time;
 662                 if (random() < 0.5)
 663                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 664                 else
 665                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 666                 if (self.maxs_z > 5)
 667                 {
 668                         self.maxs_z = 5;
 669                         setsize(self, self.mins, self.maxs);
 670                 }
 671                 // set damage function to corpse damage
 672                 self.event_damage = PlayerCorpseDamage;
 673                 // call the corpse damage function just in case it wants to gib
 674                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 675                 // set up to fade out later
 676                 SUB_SetFade (self, time + 6 + random (), 1);
 677
 678                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 679                         // remove corpse
 680                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 681                 }
 682
 683                 // reset fields the weapons may use just in case
 684                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 685                 {
 686                         weapon_action(j, WR_RESETPLAYER);
 687                         ATTACK_FINISHED_FOR(self, j) = 0;
 688                 }
 689         }
 690 }
 691
 692 .float muted; // to be used by prvm_edictset server playernumber muted 1
 693 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 694 // message "": do not say, just test flood control
 695 // return value:
 696 //   1 = accept
 697 //   0 = reject
 698 //  -1 = fake accept
 699 {
 700         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 701         float flood;
 702         var .float flood_field;
 703         entity head;
 704         float ret;
 705         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 706
 707         if(!teamsay && !privatesay)
 708                 if(substring(msgin, 0, 1) == " ")
 709                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 710
 711         msgin = formatmessage(msgin);
 712
 713         if not(IS_PLAYER(source))
 714                 colorstr = "^0"; // black for spectators
 715         else if(teamplay)
 716                 colorstr = Team_ColorCode(source.team);
 717         else
 718         {
 719                 colorstr = "";
 720                 teamsay = FALSE;
 721         }
 722
 723         if(intermission_running)
 724                 teamsay = FALSE;
 725
 726         if(msgin != "")
 727                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 728
 729         /*
 730          * using bprint solves this... me stupid
 731         // how can we prevent the message from appearing in a listen server?
 732         // for now, just give "say" back and only handle say_team
 733         if(!teamsay)
 734         {
 735                 clientcommand(self, strcat("say ", msgin));
 736                 return;
 737         }
 738         */
 739
 740         if(autocvar_g_chat_teamcolors)
 741                 namestr = playername(source);
 742         else
 743                 namestr = source.netname;
 744
 745         if(msgin != "")
 746         {
 747                 if(privatesay)
 748                 {
 749                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 750                         privatemsgprefixlen = strlen(msgstr);
 751                         msgstr = strcat(msgstr, msgin);
 752                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 753                         if(autocvar_g_chat_teamcolors)
 754                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 755                         else
 756                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 757                 }
 758                 else if(teamsay)
 759                 {
 760                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 761                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 762                 }
 763                 else
 764                 {
 765                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 766                         cmsgstr = "";
 767                 }
 768                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 769         }
 770         else
 771         {
 772                 msgstr = cmsgstr = "";
 773         }
 774
 775         fullmsgstr = msgstr;
 776         fullcmsgstr = cmsgstr;
 777
 778         // FLOOD CONTROL
 779         flood = 0;
 780         flood_field = floodcontrol_chat;
 781         if(floodcontrol)
 782         {
 783                 float flood_spl;
 784                 float flood_burst;
 785                 float flood_lmax;
 786                 float lines;
 787                 if(privatesay)
 788                 {
 789                         flood_spl = autocvar_g_chat_flood_spl_tell;
 790                         flood_burst = autocvar_g_chat_flood_burst_tell;
 791                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 792                         flood_field = floodcontrol_chattell;
 793                 }
 794                 else if(teamsay)
 795                 {
 796                         flood_spl = autocvar_g_chat_flood_spl_team;
 797                         flood_burst = autocvar_g_chat_flood_burst_team;
 798                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 799                         flood_field = floodcontrol_chatteam;
 800                 }
 801                 else
 802                 {
 803                         flood_spl = autocvar_g_chat_flood_spl;
 804                         flood_burst = autocvar_g_chat_flood_burst;
 805                         flood_lmax = autocvar_g_chat_flood_lmax;
 806                         flood_field = floodcontrol_chat;
 807                 }
 808                 flood_burst = max(0, flood_burst - 1);
 809                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 810
 811                 // do flood control for the default line size
 812                 if(msgstr != "")
 813                 {
 814                         getWrappedLine_remaining = msgstr;
 815                         msgstr = "";
 816                         lines = 0;
 817                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 818                         {
 819                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 820                                 ++lines;
 821                         }
 822                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 823
 824                         if(getWrappedLine_remaining != "")
 825                         {
 826                                 msgstr = strcat(msgstr, "\n");
 827                                 flood = 2;
 828                         }
 829
 830                         if(time >= source.flood_field)
 831                         {
 832                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 833                         }
 834                         else
 835                         {
 836                                 flood = 1;
 837                                 msgstr = fullmsgstr;
 838                         }
 839                 }
 840                 else
 841                 {
 842                         if(time >= source.flood_field)
 843                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 844                         else
 845                                 flood = 1;
 846                 }
 847
 848                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 849                         source.flood_field = flood = 0;
 850         }
 851
 852         if(flood == 2) // cannot happen for empty msgstr
 853         {
 854                 if(autocvar_g_chat_flood_notify_flooder)
 855                 {
 856                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 857                         sourcecmsgstr = "";
 858                 }
 859                 else
 860                 {
 861                         sourcemsgstr = fullmsgstr;
 862                         sourcecmsgstr = fullcmsgstr;
 863                 }
 864                 cmsgstr = "";
 865         }
 866         else
 867         {
 868                 sourcemsgstr = msgstr;
 869                 sourcecmsgstr = cmsgstr;
 870         }
 871
 872         if(!privatesay)
 873         if not(IS_PLAYER(source))
 874         {
 875                 if not(intermission_running)
 876                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 877                                 teamsay = -1; // spectators
 878         }
 879
 880         if(flood)
 881                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 882
 883         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 884         if(privatesay)
 885                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 886
 887         if(source.muted)
 888         {
 889                 // always fake the message
 890                 ret = -1;
 891         }
 892         else if(flood == 1)
 893         {
 894                 if(autocvar_g_chat_flood_notify_flooder)
 895                 {
 896                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 897                         ret = 0;
 898                 }
 899                 else
 900                         ret = -1;
 901         }
 902         else
 903         {
 904                 ret = 1;
 905         }
 906
 907         if(sourcemsgstr != "" && ret != 0)
 908         {
 909                 if(ret < 0) // faked message, because the player is muted
 910                 {
 911                         sprint(source, sourcemsgstr);
 912                         if(sourcecmsgstr != "" && !privatesay)
 913                                 centerprint(source, sourcecmsgstr);
 914                 }
 915                 else if(privatesay) // private message, between 2 people only
 916                 {
 917                         sprint(source, sourcemsgstr);
 918                         sprint(privatesay, msgstr);
 919                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 920                         if(cmsgstr != "")
 921                                 centerprint(privatesay, cmsgstr);
 922                 }
 923                 else if(teamsay > 0) // team message, only sent to team mates
 924                 {
 925                         sprint(source, sourcemsgstr);
 926                         dedicated_print(msgstr); // send to server console too
 927                         if(sourcecmsgstr != "")
 928                                 centerprint(source, sourcecmsgstr);
 929                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 930                                 if(head != source)
 931                                 {
 932                                         sprint(head, msgstr);
 933                                         if(cmsgstr != "")
 934                                                 centerprint(head, cmsgstr);
 935                                 }
 936                 }
 937                 else if(teamsay < 0) // spectator message, only sent to spectators
 938                 {
 939                         sprint(source, sourcemsgstr);
 940                         dedicated_print(msgstr); // send to server console too
 941                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 942                                 if(head != source)
 943                                         sprint(head, msgstr);
 944                 }
 945                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 946                 {
 947                         sprint(source, sourcemsgstr);
 948                         dedicated_print(msgstr); // send to server console too
 949                         FOR_EACH_REALCLIENT(head)
 950                                 if(head != source)
 951                                         sprint(head, msgstr);
 952                 }
 953                 else
 954                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 955         }
 956
 957         return ret;
 958 }
 959
 960 float GetVoiceMessageVoiceType(string type)
 961 {
 962         if(type == "taunt")
 963                 return VOICETYPE_TAUNT;
 964         if(type == "teamshoot")
 965                 return VOICETYPE_LASTATTACKER;
 966         return VOICETYPE_TEAMRADIO;
 967 }
 968
 969 string allvoicesamples;
 970 .string GetVoiceMessageSampleField(string type)
 971 {
 972         GetPlayerSoundSampleField_notFound = 0;
 973         switch(type)
 974         {
 975 #define _VOICEMSG(m) case #m: return playersound_##m;
 976                 ALLVOICEMSGS
 977 #undef _VOICEMSG
 978         }
 979         GetPlayerSoundSampleField_notFound = 1;
 980         return playersound_taunt;
 981 }
 982
 983 .string GetPlayerSoundSampleField(string type)
 984 {
 985         GetPlayerSoundSampleField_notFound = 0;
 986         switch(type)
 987         {
 988 #define _VOICEMSG(m) case #m: return playersound_##m;
 989                 ALLPLAYERSOUNDS
 990 #undef _VOICEMSG
 991         }
 992         GetPlayerSoundSampleField_notFound = 1;
 993         return playersound_taunt;
 994 }
 995
 996 void PrecacheGlobalSound(string samplestring)
 997 {
 998         float n, i;
 999         tokenize_console(samplestring);
1000         n = stof(argv(1));
1001         if(n > 0)
1002         {
1003                 for(i = 1; i <= n; ++i)
1004                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1005         }
1006         else
1007         {
1008                 precache_sound(strcat(argv(0), ".wav"));
1009         }
1010 }
1011
1012 void PrecachePlayerSounds(string f)
1013 {
1014         float fh;
1015         string s;
1016         fh = fopen(f, FILE_READ);
1017         if(fh < 0)
1018                 return;
1019         while((s = fgets(fh)))
1020         {
1021                 if(tokenize_console(s) != 3)
1022                 {
1023                         dprint("Invalid sound info line: ", s, "\n");
1024                         continue;
1025                 }
1026                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1027         }
1028         fclose(fh);
1029
1030         if not(allvoicesamples)
1031         {
1032 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1033                 ALLVOICEMSGS
1034 #undef _VOICEMSG
1035                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1036         }
1037 }
1038
1039 void ClearPlayerSounds()
1040 {
1041 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1042         ALLPLAYERSOUNDS
1043         ALLVOICEMSGS
1044 #undef _VOICEMSG
1045 }
1046
1047 float LoadPlayerSounds(string f, float first)
1048 {
1049         float fh;
1050         string s;
1051         var .string field;
1052         fh = fopen(f, FILE_READ);
1053         if(fh < 0)
1054         {
1055                 dprint("Player sound file not found: ", f, "\n");
1056                 return 0;
1057         }
1058         while((s = fgets(fh)))
1059         {
1060                 if(tokenize_console(s) != 3)
1061                         continue;
1062                 field = GetPlayerSoundSampleField(argv(0));
1063                 if(GetPlayerSoundSampleField_notFound)
1064                         field = GetVoiceMessageSampleField(argv(0));
1065                 if(GetPlayerSoundSampleField_notFound)
1066                         continue;
1067                 if(self.field)
1068                         strunzone(self.field);
1069                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1070         }
1071         fclose(fh);
1072         return 1;
1073 }
1074
1075 .float modelindex_for_playersound;
1076 .float skin_for_playersound;
1077 void UpdatePlayerSounds()
1078 {
1079         if(self.modelindex == self.modelindex_for_playersound)
1080         if(self.skin == self.skin_for_playersound)
1081                 return;
1082         self.modelindex_for_playersound = self.modelindex;
1083         self.skin_for_playersound = self.skin;
1084         ClearPlayerSounds();
1085         LoadPlayerSounds("sound/player/default.sounds", 1);
1086         if(!autocvar_g_debug_defaultsounds)
1087                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1088                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1089 }
1090
1091 void FakeGlobalSound(string sample, float chan, float voicetype)
1092 {
1093         float n;
1094         float tauntrand;
1095
1096         if(sample == "")
1097                 return;
1098
1099         tokenize_console(sample);
1100         n = stof(argv(1));
1101         if(n > 0)
1102                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1103         else
1104                 sample = strcat(argv(0), ".wav"); // randomization
1105
1106         switch(voicetype)
1107         {
1108                 case VOICETYPE_LASTATTACKER_ONLY:
1109                         break;
1110                 case VOICETYPE_LASTATTACKER:
1111                         if(self.pusher)
1112                         {
1113                                 msg_entity = self;
1114                                 if(IS_REAL_CLIENT(msg_entity))
1115                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1116                         }
1117                         break;
1118                 case VOICETYPE_TEAMRADIO:
1119                         msg_entity = self;
1120                         if(msg_entity.cvar_cl_voice_directional == 1)
1121                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1122                         else
1123                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1124                         break;
1125                 case VOICETYPE_AUTOTAUNT:
1126                         if(!sv_autotaunt)
1127                                 break;
1128                         if(!sv_taunt)
1129                                 break;
1130                         if(autocvar_sv_gentle)
1131                                 break;
1132                         tauntrand = random();
1133                         msg_entity = self;
1134                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1135                         {
1136                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1137                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1138                                 else
1139                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1140                         }
1141                         break;
1142                 case VOICETYPE_TAUNT:
1143                         if(IS_PLAYER(self))
1144                                 if(self.deadflag == DEAD_NO)
1145                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1146                         if(!sv_taunt)
1147                                 break;
1148                         if(autocvar_sv_gentle)
1149                                 break;
1150                         msg_entity = self;
1151                         if (msg_entity.cvar_cl_voice_directional >= 1)
1152                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1153                         else
1154                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1155                         break;
1156                 case VOICETYPE_PLAYERSOUND:
1157                         msg_entity = self;
1158                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1159                         break;
1160                 default:
1161                         backtrace("Invalid voice type!");
1162                         break;
1163         }
1164 }
1165
1166 void GlobalSound(string sample, float chan, float voicetype)
1167 {
1168         float n;
1169         float tauntrand;
1170
1171         if(sample == "")
1172                 return;
1173
1174         tokenize_console(sample);
1175         n = stof(argv(1));
1176         if(n > 0)
1177                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1178         else
1179                 sample = strcat(argv(0), ".wav"); // randomization
1180
1181         switch(voicetype)
1182         {
1183                 case VOICETYPE_LASTATTACKER_ONLY:
1184                         if(self.pusher)
1185                         {
1186                                 msg_entity = self.pusher;
1187                                 if(IS_REAL_CLIENT(msg_entity))
1188                                 {
1189                                         if(msg_entity.cvar_cl_voice_directional == 1)
1190                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1191                                         else
1192                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1193                                 }
1194                         }
1195                         break;
1196                 case VOICETYPE_LASTATTACKER:
1197                         if(self.pusher)
1198                         {
1199                                 msg_entity = self.pusher;
1200                                 if(IS_REAL_CLIENT(msg_entity))
1201                                 {
1202                                         if(msg_entity.cvar_cl_voice_directional == 1)
1203                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1204                                         else
1205                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1206                                 }
1207                                 msg_entity = self;
1208                                 if(IS_REAL_CLIENT(msg_entity))
1209                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1210                         }
1211                         break;
1212                 case VOICETYPE_TEAMRADIO:
1213                         FOR_EACH_REALCLIENT(msg_entity)
1214                                 if(!teamplay || msg_entity.team == self.team)
1215                                 {
1216                                         if(msg_entity.cvar_cl_voice_directional == 1)
1217                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1218                                         else
1219                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1220                                 }
1221                         break;
1222                 case VOICETYPE_AUTOTAUNT:
1223                         if(!sv_autotaunt)
1224                                 break;
1225                         if(!sv_taunt)
1226                                 break;
1227                         if(autocvar_sv_gentle)
1228                                 break;
1229                         tauntrand = random();
1230                         FOR_EACH_REALCLIENT(msg_entity)
1231                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1232                                 {
1233                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1234                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1235                                         else
1236                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1237                                 }
1238                         break;
1239                 case VOICETYPE_TAUNT:
1240                         if(IS_PLAYER(self))
1241                                 if(self.deadflag == DEAD_NO)
1242                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1243                         if(!sv_taunt)
1244                                 break;
1245                         if(autocvar_sv_gentle)
1246                                 break;
1247                         FOR_EACH_REALCLIENT(msg_entity)
1248                         {
1249                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1250                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1251                                 else
1252                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1253                         }
1254                         break;
1255                 case VOICETYPE_PLAYERSOUND:
1256                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1257                         break;
1258                 default:
1259                         backtrace("Invalid voice type!");
1260                         break;
1261         }
1262 }
1263
1264 void PlayerSound(.string samplefield, float chan, float voicetype)
1265 {
1266         GlobalSound(self.samplefield, chan, voicetype);
1267 }
1268
1269 void VoiceMessage(string type, string msg)
1270 {
1271         var .string sample;
1272         float voicetype, ownteam;
1273         float flood;
1274         sample = GetVoiceMessageSampleField(type);
1275
1276         if(GetPlayerSoundSampleField_notFound)
1277         {
1278                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1279                 return;
1280         }
1281
1282         voicetype = GetVoiceMessageVoiceType(type);
1283         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1284
1285         flood = Say(self, ownteam, world, msg, 1);
1286
1287         if (flood > 0)
1288                 GlobalSound(self.sample, CH_VOICE, voicetype);
1289         else if (flood < 0)
1290                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1291 }
1292
1293 void MoveToTeam(entity client, float team_colour, float type)
1294 {
1295         float lockteams_backup;
1296
1297         lockteams_backup = lockteams;  // backup any team lock
1298
1299         lockteams = 0;  // disable locked teams
1300
1301         TeamchangeFrags(client);  // move the players frags
1302         SetPlayerColors(client, team_colour - 1);  // set the players colour
1303         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1304
1305         lockteams = lockteams_backup;  // restore the team lock
1306
1307         LogTeamchange(client.playerid, client.team, type);
1308 }