qcsrc/server/cl_player.qc

   1 #include "cl_player.qh"
   2
   3 #include "bot/bot.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "g_violence.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "weapons/throwing.qh"
  12 #include "command/common.qh"
  13 #include "../common/animdecide.qh"
  14 #include "../common/csqcmodel_settings.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/triggers/subs.qh"
  17 #include "../common/playerstats.qh"
  18 #include "../lib/csqcmodel/sv_model.qh"
  19
  20 #include "../common/minigames/sv_minigames.qh"
  21
  22 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  23 #include "../common/triggers/include.qh"
  24
  25 #include "weapons/weaponstats.qh"
  26
  27 #include "../common/animdecide.qh"
  28
  29 void Drop_Special_Items(entity player)
  30 {
  31         // called when the player has become stuck or frozen
  32         // so objective items aren't stuck with the player
  33
  34         MUTATOR_CALLHOOK(DropSpecialItems, player);
  35 }
  36
  37 void CopyBody_Think(void)
  38 {SELFPARAM();
  39         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  40         {
  41                 self.CopyBody_think();
  42                 if(wasfreed(self))
  43                         return;
  44                 self.CopyBody_nextthink = self.nextthink;
  45                 self.CopyBody_think = self.think;
  46                 self.think = CopyBody_Think;
  47         }
  48         CSQCMODEL_AUTOUPDATE(self);
  49         self.nextthink = time;
  50 }
  51 void CopyBody(float keepvelocity)
  52 {SELFPARAM();
  53         if (self.effects & EF_NODRAW)
  54                 return;
  55         setself(spawn());
  56         self.enemy = this;
  57         self.lip = this.lip;
  58         self.colormap = this.colormap;
  59         self.iscreature = this.iscreature;
  60         self.teleportable = this.teleportable;
  61         self.damagedbycontents = this.damagedbycontents;
  62         self.angles = this.angles;
  63         self.v_angle = this.v_angle;
  64         self.avelocity = this.avelocity;
  65         self.classname = "body";
  66         self.damageforcescale = this.damageforcescale;
  67         self.effects = this.effects;
  68         self.glowmod = this.glowmod;
  69         self.event_damage = this.event_damage;
  70         self.anim_state = this.anim_state;
  71         self.anim_time = this.anim_time;
  72         self.anim_lower_action = this.anim_lower_action;
  73         self.anim_lower_time = this.anim_lower_time;
  74         self.anim_upper_action = this.anim_upper_action;
  75         self.anim_upper_time = this.anim_upper_time;
  76         self.anim_implicit_state = this.anim_implicit_state;
  77         self.anim_implicit_time = this.anim_implicit_time;
  78         self.anim_lower_implicit_action = this.anim_lower_implicit_action;
  79         self.anim_lower_implicit_time = this.anim_lower_implicit_time;
  80         self.anim_upper_implicit_action = this.anim_upper_implicit_action;
  81         self.anim_upper_implicit_time = this.anim_upper_implicit_time;
  82         self.dphitcontentsmask = this.dphitcontentsmask;
  83         self.death_time = this.death_time;
  84         self.pain_finished = this.pain_finished;
  85         self.health = this.health;
  86         self.armorvalue = this.armorvalue;
  87         self.armortype = this.armortype;
  88         self.model = this.model;
  89         self.modelindex = this.modelindex;
  90         self.skin = this.skin;
  91         self.species = this.species;
  92         self.movetype = this.movetype;
  93         self.solid = this.solid;
  94         self.ballistics_density = this.ballistics_density;
  95         self.takedamage = this.takedamage;
  96         self.customizeentityforclient = this.customizeentityforclient;
  97         self.uncustomizeentityforclient = this.uncustomizeentityforclient;
  98         self.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
  99         if (keepvelocity == 1)
 100                 self.velocity = this.velocity;
 101         self.oldvelocity = self.velocity;
 102         self.alpha = this.alpha;
 103         self.fade_time = this.fade_time;
 104         self.fade_rate = this.fade_rate;
 105         //self.weapon = this.weapon;
 106         setorigin(self, this.origin);
 107         setsize(self, this.mins, this.maxs);
 108         self.prevorigin = this.origin;
 109         self.reset = SUB_Remove;
 110
 111         Drag_MoveDrag(this, self);
 112
 113         if(self.colormap <= maxclients && self.colormap > 0)
 114                 self.colormap = 1024 + this.clientcolors;
 115
 116         CSQCMODEL_AUTOINIT(self);
 117         self.CopyBody_nextthink = this.nextthink;
 118         self.CopyBody_think = this.think;
 119         self.nextthink = time;
 120         self.think = CopyBody_Think;
 121         // "bake" the current animation frame for clones (they don't get clientside animation)
 122         animdecide_load_if_needed(self);
 123         animdecide_setframes(self, false, frame, frame1time, frame2, frame2time);
 124
 125         setself(this);
 126 }
 127
 128 float player_getspecies()
 129 {SELFPARAM();
 130         float s;
 131         get_model_parameters(self.model, self.skin);
 132         s = get_model_parameters_species;
 133         get_model_parameters(string_null, 0);
 134         if(s < 0)
 135                 return SPECIES_HUMAN;
 136         return s;
 137 }
 138
 139 void player_setupanimsformodel()
 140 {SELFPARAM();
 141         // load animation info
 142         animdecide_load_if_needed(self);
 143         animdecide_setstate(self, 0, false);
 144 }
 145
 146 void player_anim (void)
 147 {SELFPARAM();
 148         int deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 149         if(self.deadflag) {
 150                 if (!deadbits) {
 151                         // Decide on which death animation to use.
 152                         if(random() < 0.5)
 153                                 deadbits = ANIMSTATE_DEAD1;
 154                         else
 155                                 deadbits = ANIMSTATE_DEAD2;
 156                 }
 157         } else {
 158                 // Clear a previous death animation.
 159                 deadbits = 0;
 160         }
 161         int animbits = deadbits;
 162         if(self.frozen)
 163                 animbits |= ANIMSTATE_FROZEN;
 164         if(self.movetype == MOVETYPE_FOLLOW)
 165                 animbits |= ANIMSTATE_FOLLOW;
 166         if(self.crouch)
 167                 animbits |= ANIMSTATE_DUCK;
 168         animdecide_setstate(self, animbits, false);
 169         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 170
 171         if (self.weaponentity)
 172         {
 173                 updateanim(self.weaponentity);
 174                 if (!self.weaponentity.animstate_override)
 175                         setanim(self.weaponentity, self.weaponentity.anim_idle, true, false, false);
 176         }
 177 }
 178
 179 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 180 {SELFPARAM();
 181         float take, save;
 182         vector v;
 183         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 184
 185         // damage resistance (ignore most of the damage from a bullet or similar)
 186         damage = max(damage - 5, 1);
 187
 188         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 189         take = v.x;
 190         save = v.y;
 191
 192         if(sound_allowed(MSG_BROADCAST, attacker))
 193         {
 194                 if (save > 10)
 195                         sound (self, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 196                 else if (take > 30)
 197                         sound (self, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 198                 else if (take > 10)
 199                         sound (self, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 200         }
 201
 202         if (take > 50)
 203                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 204         if (take > 100)
 205                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 206
 207         self.armorvalue = self.armorvalue - save;
 208         self.health = self.health - take;
 209         // pause regeneration for 5 seconds
 210         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 211
 212         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 213         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 214         self.dmg_inflictor = inflictor;
 215
 216         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 217         {
 218                 // don't use any animations as a gib
 219                 self.frame = 0;
 220                 // view just above the floor
 221                 self.view_ofs = '0 0 4';
 222
 223                 Violence_GibSplash(self, 1, 1, attacker);
 224                 self.alpha = -1;
 225                 self.solid = SOLID_NOT; // restore later
 226                 self.takedamage = DAMAGE_NO; // restore later
 227                 self.damagedbycontents = false;
 228         }
 229 }
 230
 231 void calculate_player_respawn_time()
 232 {SELFPARAM();
 233         if(g_ca)
 234                 return;
 235
 236         float gametype_setting_tmp;
 237         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 238         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 239         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 240         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 241         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 242         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 243
 244         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 245         entity pl;
 246         if (teamplay)
 247         {
 248                 FOR_EACH_PLAYER(pl)
 249                         if (pl != self)
 250                                 if (pl.team == self.team)
 251                                         ++pcount;
 252                 if (sdelay_small_count == 0)
 253                         sdelay_small_count = 1;
 254                 if (sdelay_large_count == 0)
 255                         sdelay_large_count = 1;
 256         }
 257         else
 258         {
 259                 FOR_EACH_PLAYER(pl)
 260                         if (pl != self)
 261                                 ++pcount;
 262                 if (sdelay_small_count == 0)
 263                 {
 264                         if (g_cts)
 265                         {
 266                                 // Players play independently. No point in requiring enemies.
 267                                 sdelay_small_count = 1;
 268                         }
 269                         else
 270                         {
 271                                 // Players play AGAINST each other. Enemies required.
 272                                 sdelay_small_count = 2;
 273                         }
 274                 }
 275                 if (sdelay_large_count == 0)
 276                 {
 277                         if (g_cts)
 278                         {
 279                                 // Players play independently. No point in requiring enemies.
 280                                 sdelay_large_count = 1;
 281                         }
 282                         else
 283                         {
 284                                 // Players play AGAINST each other. Enemies required.
 285                                 sdelay_large_count = 2;
 286                         }
 287                 }
 288         }
 289
 290         float sdelay;
 291
 292         if (pcount <= sdelay_small_count)
 293                 sdelay = sdelay_small;
 294         else if (pcount >= sdelay_large_count)
 295                 sdelay = sdelay_large;
 296         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 297                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 298
 299         if(waves)
 300                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 301         else
 302                 self.respawn_time = time + sdelay;
 303
 304         if(sdelay < sdelay_max)
 305                 self.respawn_time_max = time + sdelay_max;
 306         else
 307                 self.respawn_time_max = self.respawn_time;
 308
 309         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 310                 self.respawn_countdown = 10; // first number to count down from is 10
 311         else
 312                 self.respawn_countdown = -1; // do not count down
 313
 314         if(autocvar_g_forced_respawn)
 315                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 316 }
 317
 318 void PlayerDamage (entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 319 {SELFPARAM();
 320         float take, save, dh, da;
 321         int j;
 322         vector v;
 323         float valid_damage_for_weaponstats;
 324         float excess;
 325
 326         dh = max(self.health, 0);
 327         da = max(self.armorvalue, 0);
 328
 329         if(!DEATH_ISSPECIAL(deathtype))
 330         {
 331                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 332                 if(self != attacker)
 333                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 334         }
 335
 336         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 337         {
 338                 // tuba causes blood to come out of the ears
 339                 vector ear1, ear2;
 340                 vector d;
 341                 float f;
 342                 ear1 = self.origin;
 343                 ear1_z += 0.125 * self.view_ofs.z + 0.875 * self.maxs.z; // 7/8
 344                 ear2 = ear1;
 345                 makevectors(self.angles);
 346                 ear1 += v_right * -10;
 347                 ear2 += v_right * +10;
 348                 d = inflictor.origin - self.origin;
 349                 if (d)
 350                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 351                 else
 352                         f = 0;  // Assum ecenter.
 353                 force = v_right * vlen(force);
 354                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 355                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 356                 if(f > 0)
 357                 {
 358                         hitloc = ear1;
 359                         force = force * -1;
 360                 }
 361                 else
 362                 {
 363                         hitloc = ear2;
 364                         // force is already good
 365                 }
 366         }
 367         else
 368                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 369
 370
 371         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 372         take = v.x;
 373         save = v.y;
 374
 375         if(attacker == self)
 376         {
 377                 // don't reset pushltime for self damage as it may be an attempt to
 378                 // escape a lava pit or similar
 379                 //self.pushltime = 0;
 380                 self.istypefrag = 0;
 381         }
 382         else if(IS_PLAYER(attacker))
 383         {
 384                 self.pusher = attacker;
 385                 self.pushltime = time + autocvar_g_maxpushtime;
 386                 self.istypefrag = self.BUTTON_CHAT;
 387         }
 388         else if(time < self.pushltime)
 389         {
 390                 attacker = self.pusher;
 391                 self.pushltime = max(self.pushltime, time + 0.6);
 392         }
 393         else
 394         {
 395                 self.pushltime = 0;
 396                 self.istypefrag = 0;
 397         }
 398
 399         frag_damage = damage;
 400         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, self, force, take, save);
 401         take = bound(0, damage_take, self.health);
 402         save = bound(0, damage_save, self.armorvalue);
 403         excess = max(0, damage - take - save);
 404
 405         if(sound_allowed(MSG_BROADCAST, attacker))
 406         {
 407                 if (save > 10)
 408                         sound (self, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 409                 else if (take > 30)
 410                         sound (self, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 411                 else if (take > 10)
 412                         sound (self, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 413         }
 414
 415         if (take > 50)
 416                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 417         if (take > 100)
 418                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 419
 420         if (time >= self.spawnshieldtime)
 421         {
 422                 if (!(self.flags & FL_GODMODE))
 423                 {
 424                         self.armorvalue = self.armorvalue - save;
 425                         self.health = self.health - take;
 426                         // pause regeneration for 5 seconds
 427                         if(take)
 428                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 429
 430                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 431                         {
 432                                 self.pain_finished = time + 0.5;        //Supajoe
 433
 434                                 if(autocvar_sv_gentle < 1) {
 435                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 436                                         {
 437                                                 if (!self.animstate_override)
 438                                                 {
 439                                                         if (random() > 0.5)
 440                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, true);
 441                                                         else
 442                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, true);
 443                                                 }
 444                                         }
 445
 446                                         if(sound_allowed(MSG_BROADCAST, attacker))
 447                                         if((self.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != self) // WEAPONTODO: create separate limit for pain notification with laser
 448                                         if(self.health > 1)
 449                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 450                                         {
 451                                                 if(deathtype == DEATH_FALL.m_id)
 452                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 453                                                 else if(self.health > 75) // TODO make a "gentle" version?
 454                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 455                                                 else if(self.health > 50)
 456                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 457                                                 else if(self.health > 25)
 458                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 459                                                 else
 460                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 461                                         }
 462                                 }
 463                         }
 464
 465                         // throw off bot aim temporarily
 466                         float shake;
 467                         if(IS_BOT_CLIENT(self) && self.health >= 1)
 468                         {
 469                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 470                                 self.v_angle_x = self.v_angle.x + (random() * 2 - 1) * shake;
 471                                 self.v_angle_y = self.v_angle.y + (random() * 2 - 1) * shake;
 472                                 self.v_angle_x = bound(-90, self.v_angle.x, 90);
 473                         }
 474                 }
 475                 else
 476                         self.max_armorvalue += (save + take);
 477         }
 478         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 479         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 480         self.dmg_inflictor = inflictor;
 481
 482         float abot, vbot;
 483         abot = (IS_BOT_CLIENT(attacker));
 484         vbot = (IS_BOT_CLIENT(self));
 485
 486         valid_damage_for_weaponstats = 0;
 487         Weapon awep = WEP_Null;
 488
 489         if(vbot || IS_REAL_CLIENT(self))
 490         if(abot || IS_REAL_CLIENT(attacker))
 491         if(attacker && self != attacker)
 492         if(DIFF_TEAM(self, attacker))
 493         {
 494                 if(DEATH_ISSPECIAL(deathtype))
 495                         awep = get_weaponinfo(attacker.weapon);
 496                 else
 497                         awep = DEATH_WEAPONOF(deathtype);
 498                 valid_damage_for_weaponstats = 1;
 499         }
 500
 501         if(valid_damage_for_weaponstats)
 502         {
 503                 dh = dh - max(self.health, 0);
 504                 da = da - max(self.armorvalue, 0);
 505                 WeaponStats_LogDamage(awep.m_id, abot, self.weapon, vbot, dh + da);
 506                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, self, dh, da, hitloc);
 507         }
 508
 509         if (self.health < 1)
 510         {
 511                 float defer_ClientKill_Now_TeamChange;
 512                 defer_ClientKill_Now_TeamChange = false;
 513
 514                 if(self.alivetime)
 515                 {
 516                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 517                         self.alivetime = 0;
 518                 }
 519
 520                 if(valid_damage_for_weaponstats)
 521                         WeaponStats_LogKill(awep.m_id, abot, self.weapon, vbot);
 522
 523                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 524                 if(sound_allowed(MSG_BROADCAST, attacker))
 525                 {
 526                         if(deathtype == DEATH_DROWN.m_id)
 527                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 528                         else
 529                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 530                 }
 531
 532                 // get rid of kill indicator
 533                 if(self.killindicator)
 534                 {
 535                         remove(self.killindicator);
 536                         self.killindicator = world;
 537                         if(self.killindicator_teamchange)
 538                                 defer_ClientKill_Now_TeamChange = true;
 539
 540                         if(self.classname == "body")
 541                         if(deathtype == DEATH_KILL.m_id)
 542                         {
 543                                 // for the lemmings fans, a small harmless explosion
 544                                 Send_Effect(EFFECT_ROCKET_EXPLODE, self.origin, '0 0 0', 1);
 545                         }
 546                 }
 547
 548                 // print an obituary message
 549                 if(self.classname != "body")
 550                         Obituary (attacker, inflictor, self, deathtype);
 551
 552         // increment frag counter for used weapon type
 553         Weapon w = DEATH_WEAPONOF(deathtype);
 554         if(w != WEP_Null)
 555         if(accuracy_isgooddamage(attacker, self))
 556         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 557
 558                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, self, deathtype);
 559                 excess = frag_damage;
 560
 561                 Weapon wep = get_weaponinfo(self.weapon);
 562                 wep.wr_playerdeath(wep);
 563
 564                 RemoveGrapplingHook(self);
 565
 566                 Portal_ClearAllLater(self);
 567
 568                 self.fixangle = true;
 569
 570                 if(defer_ClientKill_Now_TeamChange)
 571                         ClientKill_Now_TeamChange(); // can turn player into spectator
 572
 573                 // player could have been miraculously resuscitated ;)
 574                 // e.g. players in freezetag get frozen, they don't really die
 575                 if(self.health >= 1 || !(IS_PLAYER(self) || self.classname == "body"))
 576                         return;
 577
 578                 // when we get here, player actually dies
 579
 580                 Unfreeze(self); // remove any icy remains
 581                 self.health = 0; // Unfreeze resets health, so we need to set it back
 582
 583                 // clear waypoints
 584                 WaypointSprite_PlayerDead();
 585                 // throw a weapon
 586                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 587
 588                 // become fully visible
 589                 self.alpha = default_player_alpha;
 590                 // make the corpse upright (not tilted)
 591                 self.angles_x = 0;
 592                 self.angles_z = 0;
 593                 // don't spin
 594                 self.avelocity = '0 0 0';
 595                 // view from the floor
 596                 self.view_ofs = '0 0 -8';
 597                 // toss the corpse
 598                 self.movetype = MOVETYPE_TOSS;
 599                 // shootable corpse
 600                 self.solid = SOLID_CORPSE;
 601                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 602                 // don't stick to the floor
 603                 self.flags &= ~FL_ONGROUND;
 604                 // dying animation
 605                 self.deadflag = DEAD_DYING;
 606
 607                 // when to allow respawn
 608                 calculate_player_respawn_time();
 609
 610                 self.death_time = time;
 611                 if (random() < 0.5)
 612                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, true);
 613                 else
 614                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, true);
 615                 if (self.maxs.z > 5)
 616                 {
 617                         self.maxs_z = 5;
 618                         setsize(self, self.mins, self.maxs);
 619                 }
 620                 // set damage function to corpse damage
 621                 self.event_damage = PlayerCorpseDamage;
 622                 // call the corpse damage function just in case it wants to gib
 623                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 624
 625                 // set up to fade out later
 626                 SUB_SetFade (self, time + 6 + random (), 1);
 627                 // reset body think wrapper broken by SUB_SetFade
 628                 if(self.classname == "body" && self.think != CopyBody_Think) {
 629                         self.CopyBody_think = self.think;
 630                         self.CopyBody_nextthink = self.nextthink;
 631                         self.think = CopyBody_Think;
 632                         self.nextthink = time;
 633                 }
 634
 635                 if(autocvar_sv_gentle > 0 || autocvar_ekg || self.classname == "body") {
 636                         // remove corpse
 637                         // clones don't run any animation code any more, so we must gib them when they die :(
 638                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 639                 }
 640
 641                 // reset fields the weapons may use just in case
 642                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 643                 {
 644                         Weapon w = get_weaponinfo(j);
 645                         w.wr_resetplayer(w);
 646                         ATTACK_FINISHED_FOR(self, j) = 0;
 647                 }
 648         }
 649 }
 650
 651 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 652 // message "": do not say, just test flood control
 653 // return value:
 654 //   1 = accept
 655 //   0 = reject
 656 //  -1 = fake accept
 657 {
 658         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 659         float flood;
 660         var .float flood_field;
 661         entity head;
 662         float ret;
 663         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 664
 665         if(!teamsay && !privatesay)
 666                 if(substring(msgin, 0, 1) == " ")
 667                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 668
 669         msgin = formatmessage(msgin);
 670
 671         if (!IS_PLAYER(source))
 672                 colorstr = "^0"; // black for spectators
 673         else if(teamplay)
 674                 colorstr = Team_ColorCode(source.team);
 675         else
 676         {
 677                 colorstr = "";
 678                 teamsay = false;
 679         }
 680
 681         if(intermission_running)
 682                 teamsay = false;
 683
 684         if(msgin != "")
 685                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 686
 687         /*
 688          * using bprint solves this... me stupid
 689         // how can we prevent the message from appearing in a listen server?
 690         // for now, just give "say" back and only handle say_team
 691         if(!teamsay)
 692         {
 693                 clientcommand(self, strcat("say ", msgin));
 694                 return;
 695         }
 696         */
 697
 698         if(autocvar_g_chat_teamcolors)
 699                 namestr = playername(source);
 700         else
 701                 namestr = source.netname;
 702
 703         if(strdecolorize(namestr) == namestr)
 704                 colorprefix = "^3";
 705         else
 706                 colorprefix = "^7";
 707
 708         if(msgin != "")
 709         {
 710                 if(privatesay)
 711                 {
 712                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 713                         privatemsgprefixlen = strlen(msgstr);
 714                         msgstr = strcat(msgstr, msgin);
 715                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 716                         if(autocvar_g_chat_teamcolors)
 717                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 718                         else
 719                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 720                 }
 721                 else if(teamsay)
 722                 {
 723                         if(strstrofs(msgin, "/me", 0) >= 0)
 724                         {
 725                                 //msgin = strreplace("/me", "", msgin);
 726                                 //msgin = substring(msgin, 3, strlen(msgin));
 727                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 728                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 729                         }
 730                         else
 731                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 732                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 733                 }
 734                 else
 735                 {
 736                         if(strstrofs(msgin, "/me", 0) >= 0)
 737                         {
 738                                 //msgin = strreplace("/me", "", msgin);
 739                                 //msgin = substring(msgin, 3, strlen(msgin));
 740                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 741                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 742                         }
 743                         else
 744                                 msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 745                         cmsgstr = "";
 746                 }
 747                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 748         }
 749         else
 750         {
 751                 msgstr = cmsgstr = "";
 752         }
 753
 754         fullmsgstr = msgstr;
 755         fullcmsgstr = cmsgstr;
 756
 757         // FLOOD CONTROL
 758         flood = 0;
 759         flood_field = floodcontrol_chat;
 760         if(floodcontrol)
 761         {
 762                 float flood_spl;
 763                 float flood_burst;
 764                 float flood_lmax;
 765                 float lines;
 766                 if(privatesay)
 767                 {
 768                         flood_spl = autocvar_g_chat_flood_spl_tell;
 769                         flood_burst = autocvar_g_chat_flood_burst_tell;
 770                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 771                         flood_field = floodcontrol_chattell;
 772                 }
 773                 else if(teamsay)
 774                 {
 775                         flood_spl = autocvar_g_chat_flood_spl_team;
 776                         flood_burst = autocvar_g_chat_flood_burst_team;
 777                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 778                         flood_field = floodcontrol_chatteam;
 779                 }
 780                 else
 781                 {
 782                         flood_spl = autocvar_g_chat_flood_spl;
 783                         flood_burst = autocvar_g_chat_flood_burst;
 784                         flood_lmax = autocvar_g_chat_flood_lmax;
 785                         flood_field = floodcontrol_chat;
 786                 }
 787                 flood_burst = max(0, flood_burst - 1);
 788                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 789
 790                 // do flood control for the default line size
 791                 if(msgstr != "")
 792                 {
 793                         getWrappedLine_remaining = msgstr;
 794                         msgstr = "";
 795                         lines = 0;
 796                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 797                         {
 798                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 799                                 ++lines;
 800                         }
 801                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 802
 803                         if(getWrappedLine_remaining != "")
 804                         {
 805                                 msgstr = strcat(msgstr, "\n");
 806                                 flood = 2;
 807                         }
 808
 809                         if (time >= source.(flood_field))
 810                         {
 811                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 812                         }
 813                         else
 814                         {
 815                                 flood = 1;
 816                                 msgstr = fullmsgstr;
 817                         }
 818                 }
 819                 else
 820                 {
 821                         if (time >= source.(flood_field))
 822                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 823                         else
 824                                 flood = 1;
 825                 }
 826
 827                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 828                         source.(flood_field) = flood = 0;
 829         }
 830
 831         if(flood == 2) // cannot happen for empty msgstr
 832         {
 833                 if(autocvar_g_chat_flood_notify_flooder)
 834                 {
 835                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 836                         sourcecmsgstr = "";
 837                 }
 838                 else
 839                 {
 840                         sourcemsgstr = fullmsgstr;
 841                         sourcecmsgstr = fullcmsgstr;
 842                 }
 843                 cmsgstr = "";
 844         }
 845         else
 846         {
 847                 sourcemsgstr = msgstr;
 848                 sourcecmsgstr = cmsgstr;
 849         }
 850
 851         if(!privatesay)
 852         if (!IS_PLAYER(source))
 853         {
 854                 if (!intermission_running)
 855                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 856                                 teamsay = -1; // spectators
 857         }
 858
 859         if(flood)
 860                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
 861
 862         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 863         if(privatesay)
 864                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 865
 866         if(source.muted)
 867         {
 868                 // always fake the message
 869                 ret = -1;
 870         }
 871         else if(flood == 1)
 872         {
 873                 if (autocvar_g_chat_flood_notify_flooder)
 874                 {
 875                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 876                         ret = 0;
 877                 }
 878                 else
 879                         ret = -1;
 880         }
 881         else
 882         {
 883                 ret = 1;
 884         }
 885
 886         if(sourcemsgstr != "" && ret != 0)
 887         {
 888                 if(ret < 0) // faked message, because the player is muted
 889                 {
 890                         sprint(source, sourcemsgstr);
 891                         if(sourcecmsgstr != "" && !privatesay)
 892                                 centerprint(source, sourcecmsgstr);
 893                 }
 894                 else if(privatesay) // private message, between 2 people only
 895                 {
 896                         sprint(source, sourcemsgstr);
 897                         sprint(privatesay, msgstr);
 898                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 899                         if(cmsgstr != "")
 900                                 centerprint(privatesay, cmsgstr);
 901                 }
 902                 else if ( teamsay && source.active_minigame )
 903                 {
 904                         sprint(source, sourcemsgstr);
 905                         dedicated_print(msgstr); // send to server console too
 906                         FOR_EACH_REALCLIENT(head)
 907                                 if(head != source)
 908                                 if(head.active_minigame == source.active_minigame)
 909                                         sprint(head, msgstr);
 910                 }
 911                 else if(teamsay > 0) // team message, only sent to team mates
 912                 {
 913                         sprint(source, sourcemsgstr);
 914                         dedicated_print(msgstr); // send to server console too
 915                         if(sourcecmsgstr != "")
 916                                 centerprint(source, sourcecmsgstr);
 917                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 918                                 if(head != source)
 919                                 {
 920                                         sprint(head, msgstr);
 921                                         if(cmsgstr != "")
 922                                                 centerprint(head, cmsgstr);
 923                                 }
 924                 }
 925                 else if(teamsay < 0) // spectator message, only sent to spectators
 926                 {
 927                         sprint(source, sourcemsgstr);
 928                         dedicated_print(msgstr); // send to server console too
 929                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 930                                 if(head != source)
 931                                         sprint(head, msgstr);
 932                 }
 933                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 934                 {
 935                         sprint(source, sourcemsgstr);
 936                         dedicated_print(msgstr); // send to server console too
 937                         FOR_EACH_REALCLIENT(head)
 938                                 if(head != source)
 939                                         sprint(head, msgstr);
 940                 }
 941                 else
 942                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 943         }
 944
 945         return ret;
 946 }
 947
 948 float GetVoiceMessageVoiceType(string type)
 949 {
 950         if(type == "taunt")
 951                 return VOICETYPE_TAUNT;
 952         if(type == "teamshoot")
 953                 return VOICETYPE_LASTATTACKER;
 954         return VOICETYPE_TEAMRADIO;
 955 }
 956
 957 .string GetVoiceMessageSampleField(string type)
 958 {
 959         GetPlayerSoundSampleField_notFound = 0;
 960         switch(type)
 961         {
 962 #define _VOICEMSG(m) case #m: return playersound_##m;
 963                 ALLVOICEMSGS
 964 #undef _VOICEMSG
 965         }
 966         GetPlayerSoundSampleField_notFound = 1;
 967         return playersound_taunt;
 968 }
 969
 970 .string GetPlayerSoundSampleField(string type)
 971 {
 972         GetPlayerSoundSampleField_notFound = 0;
 973         switch(type)
 974         {
 975 #define _VOICEMSG(m) case #m: return playersound_##m;
 976                 ALLPLAYERSOUNDS
 977 #undef _VOICEMSG
 978         }
 979         GetPlayerSoundSampleField_notFound = 1;
 980         return playersound_taunt;
 981 }
 982
 983 void PrecacheGlobalSound(string samplestring)
 984 {
 985         float n, i;
 986         tokenize_console(samplestring);
 987         n = stof(argv(1));
 988         if(n > 0)
 989         {
 990                 for(i = 1; i <= n; ++i)
 991                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 992         }
 993         else
 994         {
 995                 precache_sound(strcat(argv(0), ".wav"));
 996         }
 997 }
 998
 999 void PrecachePlayerSounds(string f)
1000 {
1001         int fh = fopen(f, FILE_READ);
1002         if (fh < 0)
1003                 return;
1004         for (string s; (s = fgets(fh)); )
1005         {
1006                 int n = tokenize_console(s);
1007                 if (n != 3)
1008                 {
1009                         if (n != 0) LOG_TRACEF("Invalid sound info line: %s\n", s);
1010                         continue;
1011                 }
1012                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1013         }
1014         fclose(fh);
1015
1016         if (!allvoicesamples)
1017         {
1018 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1019                 ALLVOICEMSGS
1020 #undef _VOICEMSG
1021                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1022         }
1023 }
1024
1025 void ClearPlayerSounds()
1026 {SELFPARAM();
1027 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1028         ALLPLAYERSOUNDS
1029         ALLVOICEMSGS
1030 #undef _VOICEMSG
1031 }
1032
1033 float LoadPlayerSounds(string f, float first)
1034 {SELFPARAM();
1035         float fh;
1036         string s;
1037         var .string field;
1038         fh = fopen(f, FILE_READ);
1039         if(fh < 0)
1040         {
1041                 LOG_TRACE("Player sound file not found: ", f, "\n");
1042                 return 0;
1043         }
1044         while((s = fgets(fh)))
1045         {
1046                 if(tokenize_console(s) != 3)
1047                         continue;
1048                 field = GetPlayerSoundSampleField(argv(0));
1049                 if(GetPlayerSoundSampleField_notFound)
1050                         field = GetVoiceMessageSampleField(argv(0));
1051                 if(GetPlayerSoundSampleField_notFound)
1052                         continue;
1053                 if (self.(field))
1054                         strunzone(self.(field));
1055                 self.(field) = strzone(strcat(argv(1), " ", argv(2)));
1056         }
1057         fclose(fh);
1058         return 1;
1059 }
1060
1061 void UpdatePlayerSounds()
1062 {SELFPARAM();
1063         if(self.modelindex == self.modelindex_for_playersound)
1064         if(self.skin == self.skin_for_playersound)
1065                 return;
1066         self.modelindex_for_playersound = self.modelindex;
1067         self.skin_for_playersound = self.skin;
1068         ClearPlayerSounds();
1069         LoadPlayerSounds("sound/player/default.sounds", 1);
1070         if(!autocvar_g_debug_defaultsounds)
1071                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1072                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1073 }
1074
1075 void FakeGlobalSound(string sample, float chan, float voicetype)
1076 {SELFPARAM();
1077         float n;
1078         float tauntrand;
1079
1080         if(sample == "")
1081                 return;
1082
1083         tokenize_console(sample);
1084         n = stof(argv(1));
1085         if(n > 0)
1086                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1087         else
1088                 sample = strcat(argv(0), ".wav"); // randomization
1089
1090         switch(voicetype)
1091         {
1092                 case VOICETYPE_LASTATTACKER_ONLY:
1093                         break;
1094                 case VOICETYPE_LASTATTACKER:
1095                         if(self.pusher)
1096                         {
1097                                 msg_entity = self;
1098                                 if(IS_REAL_CLIENT(msg_entity))
1099                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1100                         }
1101                         break;
1102                 case VOICETYPE_TEAMRADIO:
1103                         msg_entity = self;
1104                         if(msg_entity.cvar_cl_voice_directional == 1)
1105                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1106                         else
1107                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1108                         break;
1109                 case VOICETYPE_AUTOTAUNT:
1110                         if(!sv_autotaunt)
1111                                 break;
1112                         if(!sv_taunt)
1113                                 break;
1114                         if(autocvar_sv_gentle)
1115                                 break;
1116                         tauntrand = random();
1117                         msg_entity = self;
1118                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1119                         {
1120                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1121                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1122                                 else
1123                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1124                         }
1125                         break;
1126                 case VOICETYPE_TAUNT:
1127                         if(IS_PLAYER(self))
1128                                 if(self.deadflag == DEAD_NO)
1129                                         animdecide_setaction(self, ANIMACTION_TAUNT, true);
1130                         if(!sv_taunt)
1131                                 break;
1132                         if(autocvar_sv_gentle)
1133                                 break;
1134                         msg_entity = self;
1135                         if (msg_entity.cvar_cl_voice_directional >= 1)
1136                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1137                         else
1138                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1139                         break;
1140                 case VOICETYPE_PLAYERSOUND:
1141                         msg_entity = self;
1142                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1143                         break;
1144                 default:
1145                         backtrace("Invalid voice type!");
1146                         break;
1147         }
1148 }
1149
1150 void GlobalSound(string sample, float chan, float voicetype)
1151 {SELFPARAM();
1152         float n;
1153         float tauntrand;
1154
1155         if(sample == "")
1156                 return;
1157
1158         tokenize_console(sample);
1159         n = stof(argv(1));
1160         if(n > 0)
1161                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1162         else
1163                 sample = strcat(argv(0), ".wav"); // randomization
1164
1165         switch(voicetype)
1166         {
1167                 case VOICETYPE_LASTATTACKER_ONLY:
1168                         if(self.pusher)
1169                         {
1170                                 msg_entity = self.pusher;
1171                                 if(IS_REAL_CLIENT(msg_entity))
1172                                 {
1173                                         if(msg_entity.cvar_cl_voice_directional == 1)
1174                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1175                                         else
1176                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1177                                 }
1178                         }
1179                         break;
1180                 case VOICETYPE_LASTATTACKER:
1181                         if(self.pusher)
1182                         {
1183                                 msg_entity = self.pusher;
1184                                 if(IS_REAL_CLIENT(msg_entity))
1185                                 {
1186                                         if(msg_entity.cvar_cl_voice_directional == 1)
1187                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1188                                         else
1189                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1190                                 }
1191                                 msg_entity = self;
1192                                 if(IS_REAL_CLIENT(msg_entity))
1193                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1194                         }
1195                         break;
1196                 case VOICETYPE_TEAMRADIO:
1197                         FOR_EACH_REALCLIENT(msg_entity)
1198                                 if(!teamplay || msg_entity.team == self.team)
1199                                 {
1200                                         if(msg_entity.cvar_cl_voice_directional == 1)
1201                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1202                                         else
1203                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1204                                 }
1205                         break;
1206                 case VOICETYPE_AUTOTAUNT:
1207                         if(!sv_autotaunt)
1208                                 break;
1209                         if(!sv_taunt)
1210                                 break;
1211                         if(autocvar_sv_gentle)
1212                                 break;
1213                         tauntrand = random();
1214                         FOR_EACH_REALCLIENT(msg_entity)
1215                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1216                                 {
1217                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1218                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1219                                         else
1220                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1221                                 }
1222                         break;
1223                 case VOICETYPE_TAUNT:
1224                         if(IS_PLAYER(self))
1225                                 if(self.deadflag == DEAD_NO)
1226                                         animdecide_setaction(self, ANIMACTION_TAUNT, true);
1227                         if(!sv_taunt)
1228                                 break;
1229                         if(autocvar_sv_gentle)
1230                                 break;
1231                         FOR_EACH_REALCLIENT(msg_entity)
1232                         {
1233                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1234                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1235                                 else
1236                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1237                         }
1238                         break;
1239                 case VOICETYPE_PLAYERSOUND:
1240                         _sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1241                         break;
1242                 default:
1243                         backtrace("Invalid voice type!");
1244                         break;
1245         }
1246 }
1247
1248 void PlayerSound(.string samplefield, float chan, float voicetype)
1249 {SELFPARAM();
1250         GlobalSound(self.(samplefield), chan, voicetype);
1251 }
1252
1253 void VoiceMessage(string type, string msg)
1254 {SELFPARAM();
1255         float voicetype, ownteam;
1256         float flood;
1257         var .string sample = GetVoiceMessageSampleField(type);
1258
1259         if(GetPlayerSoundSampleField_notFound)
1260         {
1261                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1262                 return;
1263         }
1264
1265         voicetype = GetVoiceMessageVoiceType(type);
1266         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1267
1268         flood = Say(self, ownteam, world, msg, 1);
1269
1270         if (IS_SPEC(self) || IS_OBSERVER(self) || flood < 0)
1271                 FakeGlobalSound(self.(sample), CH_VOICE, voicetype);
1272         else if (flood > 0)
1273                 GlobalSound(self.(sample), CH_VOICE, voicetype);
1274 }
1275
1276 void MoveToTeam(entity client, float team_colour, float type)
1277 {
1278         float lockteams_backup;
1279
1280         lockteams_backup = lockteams;  // backup any team lock
1281
1282         lockteams = 0;  // disable locked teams
1283
1284         TeamchangeFrags(client);  // move the players frags
1285         SetPlayerColors(client, team_colour - 1);  // set the players colour
1286         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
1287
1288         lockteams = lockteams_backup;  // restore the team lock
1289
1290         LogTeamchange(client.playerid, client.team, type);
1291 }