qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.playermodel, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389
 390 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 391 {
 392         local float take, save, waves, sdelay, dh, da, j;
 393         vector v;
 394         float valid_damage_for_weaponstats;
 395
 396         dh = max(self.health, 0);
 397         da = max(self.armorvalue, 0);
 398
 399         if(!DEATH_ISSPECIAL(deathtype))
 400         {
 401                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 402                 if(self != attacker)
 403                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 404         }
 405
 406         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 407         {
 408                 // tuba causes blood to come out of the ears
 409                 vector ear1, ear2;
 410                 vector d;
 411                 float f;
 412                 ear1 = self.origin;
 413                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 414                 ear2 = ear1;
 415                 makevectors(self.angles);
 416                 ear1 += v_right * -10;
 417                 ear2 += v_right * +10;
 418                 d = inflictor.origin - self.origin;
 419                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 420                 force = v_right * vlen(force);
 421                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 422                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 423                 if(f > 0)
 424                 {
 425                         hitloc = ear1;
 426                         force = force * -1;
 427                 }
 428                 else
 429                 {
 430                         hitloc = ear2;
 431                         // force is already good
 432                 }
 433         }
 434         else
 435                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 436
 437         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 438                 return;
 439
 440         if (!g_minstagib)
 441         {
 442                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 443                 take = v_x;
 444                 save = v_y;
 445         }
 446         else
 447         {
 448                 save = 0;
 449                 take = damage;
 450         }
 451
 452         frag_inflictor = inflictor;
 453         frag_attacker = attacker;
 454         frag_target = self;
 455         damage_take = take;
 456         damage_save = save;
 457         damage_force = force;
 458         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 459         take = bound(0, damage_take, self.health);
 460         save = bound(0, damage_save, self.armorvalue);
 461
 462         if(sound_allowed(MSG_BROADCAST, attacker))
 463         {
 464                 if (save > 10)
 465                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 466                 else if (take > 30)
 467                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 468                 else if (take > 10)
 469                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 470         }
 471
 472         if (take > 50)
 473                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 474         if (take > 100)
 475                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 476
 477         if (time >= self.spawnshieldtime)
 478         {
 479                 if (!(self.flags & FL_GODMODE))
 480                 {
 481                         self.armorvalue = self.armorvalue - save;
 482                         self.health = self.health - take;
 483                         // pause regeneration for 5 seconds
 484                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 485
 486                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 487                         {
 488                                 self.pain_finished = time + 0.5;        //Supajoe
 489
 490                                 if(sv_gentle < 1) {
 491                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 492                                         {
 493                                                 if (random() > 0.5)
 494                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 495                                                 else
 496                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 497                                         }
 498
 499                                         if(sound_allowed(MSG_BROADCAST, attacker))
 500                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 501                                         if(self.health > 1)
 502                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 503                                         {
 504                                                 if(deathtype == DEATH_FALL)
 505                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 506                                                 else if(self.health > 75) // TODO make a "gentle" version?
 507                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else if(self.health > 50)
 509                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                                 else if(self.health > 25)
 511                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else
 513                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                         }
 515                                 }
 516
 517                                 // throw off bot aim temporarily
 518                                 local float shake;
 519                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 520                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 521                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 522                         }
 523                 }
 524                 else
 525                         self.max_armorvalue += (save + take);
 526         }
 527         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 528         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 529         self.dmg_inflictor = inflictor;
 530
 531         if(attacker == self)
 532         {
 533                 // don't reset pushltime for self damage as it may be an attempt to
 534                 // escape a lava pit or similar
 535                 //self.pushltime = 0;
 536         }
 537         else if(attacker.classname == "player" || attacker.classname == "gib")
 538         {
 539                 self.pusher = attacker;
 540                 self.pushltime = time + cvar("g_maxpushtime");
 541         }
 542         else if(time < self.pushltime)
 543         {
 544                 attacker = self.pusher;
 545                 self.pushltime = max(self.pushltime, time + 0.6);
 546         }
 547         else
 548                 self.pushltime = 0;
 549
 550         valid_damage_for_weaponstats = 0;
 551         if(clienttype(self) == CLIENTTYPE_REAL)
 552         if(clienttype(attacker) == CLIENTTYPE_REAL)
 553         if(self != attacker)
 554         if(!DEATH_ISSPECIAL(deathtype))
 555         if(IsDifferentTeam(self, attacker))
 556                 valid_damage_for_weaponstats = 1;
 557
 558         if(valid_damage_for_weaponstats)
 559         {
 560                 dh = dh - max(self.health, 0);
 561                 da = da - max(self.armorvalue, 0);
 562                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 563         }
 564
 565         if (self.health < 1)
 566         {
 567                 float defer_ClientKill_Now_TeamChange;
 568                 defer_ClientKill_Now_TeamChange = FALSE;
 569
 570                 if(self.alivetime)
 571                 {
 572                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 573                         self.alivetime = 0;
 574                 }
 575
 576                 if(valid_damage_for_weaponstats)
 577                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 578
 579                 if(sv_gentle < 1) // TODO make a "gentle" version?
 580                 if(sound_allowed(MSG_BROADCAST, attacker))
 581                 {
 582                         if(deathtype == DEATH_DROWN)
 583                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 584                         else
 585                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 586                 }
 587
 588                 // get rid of kill indicator
 589                 if(self.killindicator)
 590                 {
 591                         remove(self.killindicator);
 592                         self.killindicator = world;
 593                         if(self.killindicator_teamchange)
 594                                 defer_ClientKill_Now_TeamChange = TRUE;
 595
 596                         if(self.classname == "body")
 597                         if(deathtype == DEATH_KILL)
 598                         {
 599                                 // for the lemmings fans, a small harmless explosion
 600                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 601                         }
 602                 }
 603
 604                 // become fully visible
 605                 self.alpha = 1;
 606                 // clear selected player display
 607                 ClearSelectedPlayer();
 608                 // throw a weapon
 609                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 610                 // print an obituary message
 611                 Obituary (attacker, inflictor, self, deathtype);
 612                 race_PreDie();
 613                 DropAllRunes(self);
 614
 615                 frag_attacker = attacker;
 616                 frag_inflictor = inflictor;
 617                 frag_target = self;
 618                 MUTATOR_CALLHOOK(PlayerDies);
 619
 620                 if(self.flagcarried)
 621                 {
 622                         if(attacker.classname != "player" && attacker.classname != "gib")
 623                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 624                         else if(attacker.team == self.team)
 625                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 626                         else
 627                                 DropFlag(self.flagcarried, world, attacker);
 628                 }
 629                 if(self.ballcarried && g_nexball)
 630                         DropBall(self.ballcarried, self.origin, self.velocity);
 631                 Portal_ClearAllLater(self);
 632                 // clear waypoints
 633                 WaypointSprite_PlayerDead();
 634                 // make the corpse upright (not tilted)
 635                 self.angles_x = 0;
 636                 self.angles_z = 0;
 637                 // don't spin
 638                 self.avelocity = '0 0 0';
 639                 // view from the floor
 640                 self.view_ofs = '0 0 -8';
 641                 // toss the corpse
 642                 self.movetype = MOVETYPE_TOSS;
 643                 // shootable corpse
 644                 self.solid = SOLID_CORPSE;
 645                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 646                 // don't stick to the floor
 647                 self.flags &~= FL_ONGROUND;
 648                 // dying animation
 649                 self.deadflag = DEAD_DYING;
 650                 // when to allow respawn
 651                 sdelay = 0;
 652                 waves = 0;
 653                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 654                 if(!sdelay)
 655                         sdelay = cvar("g_respawn_delay");
 656                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 657                 if(!waves)
 658                         waves = cvar("g_respawn_waves");
 659                 if(waves)
 660                         self.death_time = ceil((time + sdelay) / waves) * waves;
 661                 else
 662                         self.death_time = time + sdelay;
 663                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 664                         self.respawn_countdown = 10; // first number to count down from is 10
 665                 else
 666                         self.respawn_countdown = -1; // do not count down
 667                 if (random() < 0.5)
 668                 {
 669                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 670                         self.dead_frame = self.anim_dead1_x;
 671                 }
 672                 else
 673                 {
 674                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 675                         self.dead_frame = self.anim_dead2_x;
 676                 }
 677                 // set damage function to corpse damage
 678                 self.event_damage = PlayerCorpseDamage;
 679                 // call the corpse damage function just in case it wants to gib
 680                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 681                 // set up to fade out later
 682                 SUB_SetFade (self, time + 6 + random (), 1);
 683
 684                 if(clienttype(self) == CLIENTTYPE_REAL)
 685                 {
 686                         self.fixangle = TRUE;
 687                         //msg_entity = self;
 688                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 689                         //WriteAngle (MSG_ONE, self.v_angle_x);
 690                         //WriteAngle (MSG_ONE, self.v_angle_y);
 691                         //WriteAngle (MSG_ONE, 80);
 692                 }
 693
 694                 if(g_arena)
 695                         Spawnqueue_Unmark(self);
 696
 697                 if(defer_ClientKill_Now_TeamChange)
 698                         ClientKill_Now_TeamChange();
 699
 700                 if(sv_gentle > 0 || cvar("ekg")) {
 701                         // remove corpse
 702                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 703                 }
 704
 705                 // reset fields the weapons may use just in case
 706         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 707                 {
 708             weapon_action(j, WR_RESETPLAYER);
 709                         ATTACK_FINISHED_FOR(self, j) = 0;
 710                 }
 711         }
 712 }
 713
 714 float UpdateSelectedPlayer_countvalue(float v)
 715 {
 716         return max(0, (v - 1.0) / 0.5);
 717 }
 718
 719 // returns: -2 if no hit, otherwise cos of the angle
 720 // uses the global v_angle
 721 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 722 {
 723         vector so, d;
 724         float c;
 725
 726         if(p == self)
 727                 return -2;
 728
 729         if(p.deadflag)
 730                 return -2;
 731
 732         so = self.origin + self.view_ofs;
 733         d = p.origin - so;
 734
 735         // misaimed?
 736         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 737                 return -2;
 738
 739         // now find the cos of the angle...
 740         c = normalize(d) * v_forward;
 741
 742         if(c <= mincosangle)
 743                 return -2;
 744
 745         // not visible in any way? forget it
 746         if(!checkpvs(so, p))
 747                 return -2;
 748
 749         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 750         if(trace_fraction < 1)
 751                 return -2;
 752
 753         return c;
 754 }
 755
 756 void ClearSelectedPlayer()
 757 {
 758         if(self.selected_player)
 759         {
 760                 centerprint_expire(self, CENTERPRIO_POINT);
 761                 self.selected_player = world;
 762                 self.selected_player_display_needs_update = FALSE;
 763         }
 764 }
 765
 766 void UpdateSelectedPlayer()
 767 {
 768         entity selected;
 769         float selected_score;
 770         selected = world;
 771         selected_score = 0.95; // 18 degrees
 772
 773         if(!cvar("sv_allow_shownames"))
 774                 return;
 775
 776         if(clienttype(self) != CLIENTTYPE_REAL)
 777                 return;
 778
 779         if(self.cvar_cl_shownames == 0)
 780                 return;
 781
 782         if(self.cvar_cl_shownames == 1 && !teams_matter)
 783                 return;
 784
 785         makevectors(self.v_angle); // sets v_forward
 786
 787         // 1. cursor trace is always right
 788         WarpZone_crosshair_trace(self);
 789         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 790         {
 791                 selected = trace_ent;
 792         }
 793         else
 794         {
 795                 // 2. if we don't have a cursor trace, find the player which is least
 796                 //    mis-aimed at
 797                 entity p;
 798                 FOR_EACH_PLAYER(p)
 799                 {
 800                         float c;
 801                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 802                         if(c >= -1)
 803                         {
 804                                 selected = p;
 805                                 selected_score = c;
 806                         }
 807                 }
 808         }
 809
 810         if(selected)
 811         {
 812                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 813         }
 814         else
 815         {
 816                 if(time < self.selected_player_display_timeout)
 817                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 818                                 selected = self.selected_player;
 819         }
 820
 821         if(selected)
 822         {
 823                 if(selected == self.selected_player)
 824                 {
 825                         float save;
 826                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 827                         self.selected_player_count = self.selected_player_count + frametime;
 828                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 829                         {
 830                                 string namestr, healthstr;
 831                                 namestr = playername(selected);
 832                                 if(teams_matter)
 833                                 {
 834                                         healthstr = ftos(floor(selected.health));
 835                                         if(self.team == selected.team)
 836                                         {
 837                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 838                                                 self.selected_player_display_needs_update = TRUE;
 839                                         }
 840                                 }
 841                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 842                         }
 843                 }
 844                 else
 845                 {
 846                         ClearSelectedPlayer();
 847                         self.selected_player = selected;
 848                         self.selected_player_time = time;
 849                         self.selected_player_count = 0;
 850                         self.selected_player_display_needs_update = FALSE;
 851                 }
 852         }
 853         else
 854         {
 855                 ClearSelectedPlayer();
 856         }
 857
 858         if(self.selected_player)
 859                 self.last_selected_player = self.selected_player;
 860 }
 861
 862 .float muted; // to be used by prvm_edictset server playernumber muted 1
 863 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 864 // message "": do not say, just test flood control
 865 // return value:
 866 //   1 = accept
 867 //   0 = reject
 868 //  -1 = fake accept
 869 {
 870         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 871         float flood, privatemsgprefixlen;
 872         var .float flood_field;
 873         entity head;
 874         float ret;
 875
 876         if(Ban_MaybeEnforceBan(source))
 877                 return 0;
 878
 879         if(!teamsay && !privatesay)
 880                 if(substring(msgin, 0, 1) == " ")
 881                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 882
 883         msgin = formatmessage(msgin);
 884
 885         if(source.classname != "player")
 886                 colorstr = "^0"; // black for spectators
 887         else if(teams_matter)
 888                 colorstr = Team_ColorCode(source.team);
 889         else
 890                 teamsay = FALSE;
 891
 892         if(intermission_running)
 893                 teamsay = FALSE;
 894
 895         if(msgin != "")
 896                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 897
 898         /*
 899          * using bprint solves this... me stupid
 900         // how can we prevent the message from appearing in a listen server?
 901         // for now, just give "say" back and only handle say_team
 902         if(!teamsay)
 903         {
 904                 clientcommand(self, strcat("say ", msgin));
 905                 return;
 906         }
 907         */
 908
 909         if(cvar("g_chat_teamcolors"))
 910                 namestr = playername(source);
 911         else
 912                 namestr = source.netname;
 913
 914         if(msgin != "")
 915         {
 916                 if(privatesay)
 917                 {
 918                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 919                         privatemsgprefixlen = strlen(msgstr);
 920                         msgstr = strcat(msgstr, msgin);
 921                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 922                         if(cvar("g_chat_teamcolors"))
 923                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 924                         else
 925                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 926                 }
 927                 else if(teamsay)
 928                 {
 929                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 930                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 931                 }
 932                 else
 933                 {
 934                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 935                         cmsgstr = "";
 936                 }
 937                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 938         }
 939         else
 940         {
 941                 msgstr = cmsgstr = "";
 942         }
 943
 944         fullmsgstr = msgstr;
 945         fullcmsgstr = cmsgstr;
 946
 947         // FLOOD CONTROL
 948         flood = 0;
 949         if(floodcontrol)
 950         {
 951                 float flood_spl;
 952                 float flood_burst;
 953                 float flood_lmax;
 954                 float lines;
 955                 if(privatesay)
 956                 {
 957                         flood_spl = cvar("g_chat_flood_spl_tell");
 958                         flood_burst = cvar("g_chat_flood_burst_tell");
 959                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 960                         flood_field = floodcontrol_chattell;
 961                 }
 962                 else if(teamsay)
 963                 {
 964                         flood_spl = cvar("g_chat_flood_spl_team");
 965                         flood_burst = cvar("g_chat_flood_burst_team");
 966                         flood_lmax = cvar("g_chat_flood_lmax_team");
 967                         flood_field = floodcontrol_chatteam;
 968                 }
 969                 else
 970                 {
 971                         flood_spl = cvar("g_chat_flood_spl");
 972                         flood_burst = cvar("g_chat_flood_burst");
 973                         flood_lmax = cvar("g_chat_flood_lmax");
 974                         flood_field = floodcontrol_chat;
 975                 }
 976                 flood_burst = max(0, flood_burst - 1);
 977                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 978
 979                 // do flood control for the default line size
 980                 if(msgstr != "")
 981                 {
 982                         getWrappedLine_remaining = msgstr;
 983                         msgstr = "";
 984                         lines = 0;
 985                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 986                         {
 987                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 988                                 ++lines;
 989                         }
 990                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 991
 992                         if(getWrappedLine_remaining != "")
 993                         {
 994                                 msgstr = strcat(msgstr, "\n");
 995                                 flood = 2;
 996                         }
 997
 998                         if(time >= source.flood_field)
 999                         {
1000                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1001                         }
1002                         else
1003                         {
1004                                 flood = 1;
1005                                 msgstr = fullmsgstr;
1006                         }
1007                 }
1008                 else
1009                 {
1010                         if(time >= source.flood_field)
1011                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1012                         else
1013                                 flood = 1;
1014                 }
1015
1016                 if (timeoutStatus == 2) //when game is paused, no flood protection
1017                         source.flood_field = flood = 0;
1018         }
1019
1020         if(flood == 2) // cannot happen for empty msgstr
1021         {
1022                 if(cvar("g_chat_flood_notify_flooder"))
1023                 {
1024                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1025                         sourcecmsgstr = "";
1026                 }
1027                 else
1028                 {
1029                         sourcemsgstr = fullmsgstr;
1030                         sourcecmsgstr = fullcmsgstr;
1031                 }
1032                 cmsgstr = "";
1033         }
1034         else
1035         {
1036                 sourcemsgstr = msgstr;
1037                 sourcecmsgstr = cmsgstr;
1038         }
1039
1040         if(!privatesay)
1041         if(source.classname != "player")
1042         {
1043                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1044                         teamsay = -1; // spectators
1045         }
1046
1047         if(flood)
1048                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1049
1050         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1051         if(privatesay)
1052                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1053
1054         if(source.muted)
1055         {
1056                 // always fake the message
1057                 ret = -1;
1058         }
1059         else if(flood == 1)
1060         {
1061                 if(cvar("g_chat_flood_notify_flooder"))
1062                 {
1063                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1064                         ret = 0;
1065                 }
1066                 else
1067                         ret = -1;
1068         }
1069         else
1070         {
1071                 ret = 1;
1072         }
1073
1074         if(sourcemsgstr != "" && ret != 0)
1075         {
1076                 if(ret < 0) // fake
1077                 {
1078                         sprint(source, sourcemsgstr);
1079                         if(sourcecmsgstr != "" && !privatesay)
1080                                 centerprint(source, sourcecmsgstr);
1081                 }
1082                 else if(privatesay)
1083                 {
1084                         sprint(source, sourcemsgstr);
1085                         sprint(privatesay, msgstr);
1086                         if(cmsgstr != "")
1087                                 centerprint(privatesay, cmsgstr);
1088                 }
1089                 else if(teamsay > 0)
1090                 {
1091                         sprint(source, sourcemsgstr);
1092                         if(sourcecmsgstr != "")
1093                                 centerprint(source, sourcecmsgstr);
1094                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1095                                 if(head != source)
1096                                 {
1097                                         sprint(head, msgstr);
1098                                         if(cmsgstr != "")
1099                                                 centerprint(head, cmsgstr);
1100                                 }
1101                 }
1102                 else if(teamsay < 0)
1103                 {
1104                         sprint(source, sourcemsgstr);
1105                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1106                                 if(head != source)
1107                                         sprint(head, msgstr);
1108                 }
1109                 else if(sourcemsgstr != msgstr)
1110                 {
1111                         sprint(source, sourcemsgstr);
1112                         FOR_EACH_REALCLIENT(head)
1113                                 if(head != source)
1114                                         sprint(head, msgstr);
1115                 }
1116                 else
1117                         bprint(msgstr);
1118         }
1119
1120         return ret;
1121 }
1122
1123 float GetVoiceMessageVoiceType(string type)
1124 {
1125         if(type == "taunt")
1126                 return VOICETYPE_TAUNT;
1127         if(type == "teamshoot")
1128                 return VOICETYPE_LASTATTACKER;
1129         return VOICETYPE_TEAMRADIO;
1130 }
1131
1132 string allvoicesamples;
1133 float GetPlayerSoundSampleField_notFound;
1134 float GetPlayerSoundSampleField_fixed;
1135 .string GetVoiceMessageSampleField(string type)
1136 {
1137         GetPlayerSoundSampleField_notFound = 0;
1138         GetPlayerSoundSampleField_fixed = 0;
1139         switch(type)
1140         {
1141 #define _VOICEMSG(m) case #m: return playersound_##m;
1142                 ALLVOICEMSGS
1143 #undef _VOICEMSG
1144         }
1145         GetPlayerSoundSampleField_notFound = 1;
1146         return playersound_taunt;
1147 }
1148
1149 .string GetPlayerSoundSampleField(string type)
1150 {
1151         GetPlayerSoundSampleField_notFound = 0;
1152         GetPlayerSoundSampleField_fixed = 0;
1153         switch(type)
1154         {
1155 #define _VOICEMSG(m) case #m: return playersound_##m;
1156                 ALLPLAYERSOUNDS
1157 #undef _VOICEMSG
1158         }
1159         GetPlayerSoundSampleField_notFound = 1;
1160         return playersound_taunt;
1161 }
1162
1163 void PrecacheGlobalSound(string samplestring)
1164 {
1165         float n, i;
1166         tokenize_console(samplestring);
1167         n = stof(argv(1));
1168         if(n > 0)
1169         {
1170                 for(i = 1; i <= n; ++i)
1171                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1172         }
1173         else
1174         {
1175                 precache_sound(strcat(argv(0), ".wav"));
1176         }
1177 }
1178
1179 void PrecachePlayerSounds(string f)
1180 {
1181         float fh;
1182         string s;
1183         fh = fopen(f, FILE_READ);
1184         if(fh < 0)
1185                 return;
1186         while((s = fgets(fh)))
1187         {
1188                 if(tokenize_console(s) != 3)
1189                 {
1190                         dprint("Invalid sound info line: ", s, "\n");
1191                         continue;
1192                 }
1193                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1194         }
1195         fclose(fh);
1196
1197         if not(allvoicesamples)
1198         {
1199 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1200                 ALLVOICEMSGS
1201 #undef _VOICEMSG
1202                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1203         }
1204 }
1205
1206 void ClearPlayerSounds()
1207 {
1208 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1209         ALLPLAYERSOUNDS
1210         ALLVOICEMSGS
1211 #undef _VOICEMSG
1212 }
1213
1214 void LoadPlayerSounds(string f, float first)
1215 {
1216         float fh;
1217         string s;
1218         var .string field;
1219         fh = fopen(f, FILE_READ);
1220         if(fh < 0)
1221         {
1222                 dprint("Player sound file not found: ", f, "\n");
1223                 return;
1224         }
1225         while((s = fgets(fh)))
1226         {
1227                 if(tokenize_console(s) != 3)
1228                         continue;
1229                 field = GetPlayerSoundSampleField(argv(0));
1230                 if(GetPlayerSoundSampleField_notFound)
1231                         field = GetVoiceMessageSampleField(argv(0));
1232                 if(GetPlayerSoundSampleField_notFound)
1233                         continue;
1234                 if(GetPlayerSoundSampleField_fixed)
1235                         if not(first)
1236                                 continue;
1237                 if(self.field)
1238                         strunzone(self.field);
1239                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1240         }
1241         fclose(fh);
1242 }
1243
1244 .float modelindex_for_playersound;
1245 .float skinindex_for_playersound;
1246 void UpdatePlayerSounds()
1247 {
1248         if(self.modelindex == self.modelindex_for_playersound)
1249         if(self.skinindex == self.skinindex_for_playersound)
1250                 return;
1251         self.modelindex_for_playersound = self.modelindex;
1252         self.skinindex_for_playersound = self.skinindex;
1253         ClearPlayerSounds();
1254         LoadPlayerSounds("sound/player/default.sounds", 1);
1255         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1256 }
1257
1258 void FakeGlobalSound(string sample, float chan, float voicetype)
1259 {
1260         float n;
1261         float tauntrand;
1262
1263         if(sample == "")
1264                 return;
1265
1266         tokenize_console(sample);
1267         n = stof(argv(1));
1268         if(n > 0)
1269                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1270         else
1271                 sample = strcat(argv(0), ".wav"); // randomization
1272
1273         switch(voicetype)
1274         {
1275                 case VOICETYPE_LASTATTACKER_ONLY:
1276                         break;
1277                 case VOICETYPE_LASTATTACKER:
1278                         if(self.pusher)
1279                         {
1280                                 msg_entity = self;
1281                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1282                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1283                         }
1284                         break;
1285                 case VOICETYPE_TEAMRADIO:
1286                         msg_entity = self;
1287                         if(msg_entity.cvar_cl_voice_directional == 1)
1288                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1289                         else
1290                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1291                         break;
1292                 case VOICETYPE_AUTOTAUNT:
1293                         if(!sv_autotaunt)
1294                                 break;
1295                         if(!sv_taunt)
1296                                 break;
1297                         if(sv_gentle)
1298                                 break;
1299                         tauntrand = random();
1300                         msg_entity = self;
1301                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1302                         {
1303                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1304                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1305                                 else
1306                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1307                         }
1308                         break;
1309                 case VOICETYPE_TAUNT:
1310                         if(self.classname == "player")
1311                                 if(self.deadflag == DEAD_NO)
1312                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1313                         if(!sv_taunt)
1314                                 break;
1315                         if(sv_gentle)
1316                                 break;
1317                         msg_entity = self;
1318                         if (msg_entity.cvar_cl_voice_directional >= 1)
1319                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1320                         else
1321                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1322                         break;
1323                 case VOICETYPE_PLAYERSOUND:
1324                         msg_entity = self;
1325                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1326                         break;
1327                 default:
1328                         backtrace("Invalid voice type!");
1329                         break;
1330         }
1331 }
1332
1333 void GlobalSound(string sample, float chan, float voicetype)
1334 {
1335         float n;
1336         float tauntrand;
1337
1338         if(sample == "")
1339                 return;
1340
1341         tokenize_console(sample);
1342         n = stof(argv(1));
1343         if(n > 0)
1344                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1345         else
1346                 sample = strcat(argv(0), ".wav"); // randomization
1347
1348         switch(voicetype)
1349         {
1350                 case VOICETYPE_LASTATTACKER_ONLY:
1351                         if(self.pusher)
1352                         {
1353                                 msg_entity = self.pusher;
1354                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1355                                 {
1356                                         if(msg_entity.cvar_cl_voice_directional == 1)
1357                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1358                                         else
1359                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1360                                 }
1361                         }
1362                         break;
1363                 case VOICETYPE_LASTATTACKER:
1364                         if(self.pusher)
1365                         {
1366                                 msg_entity = self.pusher;
1367                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1368                                 {
1369                                         if(msg_entity.cvar_cl_voice_directional == 1)
1370                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1371                                         else
1372                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1373                                 }
1374                                 msg_entity = self;
1375                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1376                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1377                         }
1378                         break;
1379                 case VOICETYPE_TEAMRADIO:
1380                         FOR_EACH_REALCLIENT(msg_entity)
1381                                 if(!teams_matter || msg_entity.team == self.team)
1382                                 {
1383                                         if(msg_entity.cvar_cl_voice_directional == 1)
1384                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1385                                         else
1386                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1387                                 }
1388                         break;
1389                 case VOICETYPE_AUTOTAUNT:
1390                         if(!sv_autotaunt)
1391                                 break;
1392                         if(!sv_taunt)
1393                                 break;
1394                         if(sv_gentle)
1395                                 break;
1396                         tauntrand = random();
1397                         FOR_EACH_REALCLIENT(msg_entity)
1398                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1399                                 {
1400                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1401                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1402                                         else
1403                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1404                                 }
1405                         break;
1406                 case VOICETYPE_TAUNT:
1407                         if(self.classname == "player")
1408                                 if(self.deadflag == DEAD_NO)
1409                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1410                         if(!sv_taunt)
1411                                 break;
1412                         if(sv_gentle)
1413                                 break;
1414                         FOR_EACH_REALCLIENT(msg_entity)
1415                         {
1416                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1417                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1418                                 else
1419                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1420                         }
1421                         break;
1422                 case VOICETYPE_PLAYERSOUND:
1423                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1424                         break;
1425                 default:
1426                         backtrace("Invalid voice type!");
1427                         break;
1428         }
1429 }
1430
1431 void PlayerSound(.string samplefield, float chan, float voicetype)
1432 {
1433         GlobalSound(self.samplefield, chan, voicetype);
1434 }
1435
1436 void VoiceMessage(string type, string msg)
1437 {
1438         var .string sample;
1439         float voicetype, ownteam;
1440         float flood;
1441         sample = GetVoiceMessageSampleField(type);
1442
1443         if(GetPlayerSoundSampleField_notFound)
1444         {
1445                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1446                 return;
1447         }
1448
1449         voicetype = GetVoiceMessageVoiceType(type);
1450         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1451
1452         flood = Say(self, ownteam, world, msg, 1);
1453
1454         if (flood > 0)
1455                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1456         else if (flood < 0)
1457                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1458 }
1459
1460 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1461 {
1462 //      show_message
1463 //      0 (00) automove centerprint, admin message
1464 //      1 (01) automove centerprint, no admin message
1465 //      2 (10) no centerprint, admin message
1466 //      3 (11) no centerprint, no admin message
1467
1468         float lockteams_backup;
1469
1470         lockteams_backup = lockteams;  // backup any team lock
1471
1472         lockteams = 0;  // disable locked teams
1473
1474         TeamchangeFrags(client);  // move the players frags
1475         SetPlayerColors(client, team_colour - 1);  // set the players colour
1476         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1477
1478         lockteams = lockteams_backup;  // restore the team lock
1479
1480         LogTeamchange(client.playerid, client.team, type);
1481
1482         if not(show_message & 1) // admin message
1483                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1484
1485         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1486 }