qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.ballistics_density = oldself.ballistics_density;
 146         self.takedamage = oldself.takedamage;
 147         self.think = oldself.think;
 148         self.customizeentityforclient = oldself.customizeentityforclient;
 149         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 150         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 151         if (keepvelocity == 1)
 152                 self.velocity = oldself.velocity;
 153         self.oldvelocity = self.velocity;
 154         self.fade_time = oldself.fade_time;
 155         self.fade_rate = oldself.fade_rate;
 156         //self.weapon = oldself.weapon;
 157         setorigin(self, oldself.origin);
 158         setsize(self, oldself.mins, oldself.maxs);
 159         self.prevorigin = oldself.origin;
 160         self.reset = SUB_Remove;
 161
 162         Drag_MoveDrag(oldself, self);
 163
 164         self = oldself;
 165 }
 166
 167 float player_getspecies()
 168 {
 169         float s;
 170         get_model_parameters(self.playermodel, self.skinindex);
 171         s = get_model_parameters_species;
 172         get_model_parameters(string_null, 0);
 173         if(s < 0)
 174                 return SPECIES_HUMAN;
 175         return s;
 176 }
 177
 178 void player_setupanimsformodel()
 179 {
 180         local string animfilename;
 181         local float animfile;
 182         // defaults for legacy .zym models without animinfo files
 183         self.anim_die1 = '0 1 0.5'; // 2 seconds
 184         self.anim_die2 = '1 1 0.5'; // 2 seconds
 185         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 186         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 187         self.anim_duckwalk = '4 1 1';
 188         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 189         self.anim_duckidle = '6 1 1';
 190         self.anim_idle = '7 1 1';
 191         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 192         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 193         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 194         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 195         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 196         self.anim_run = '13 1 1';
 197         self.anim_runbackwards = '14 1 1';
 198         self.anim_strafeleft = '15 1 1';
 199         self.anim_straferight = '16 1 1';
 200         self.anim_dead1 = '17 1 1';
 201         self.anim_dead2 = '18 1 1';
 202         self.anim_forwardright = '19 1 1';
 203         self.anim_forwardleft = '20 1 1';
 204         self.anim_backright = '21 1 1';
 205         self.anim_backleft  = '22 1 1';
 206         animparseerror = FALSE;
 207         animfilename = strcat(self.model, ".animinfo");
 208         animfile = fopen(animfilename, FILE_READ);
 209         if (animfile >= 0)
 210         {
 211                 self.anim_die1         = animparseline(animfile);
 212                 self.anim_die2         = animparseline(animfile);
 213                 self.anim_draw         = animparseline(animfile);
 214                 self.anim_duck         = animparseline(animfile);
 215                 self.anim_duckwalk     = animparseline(animfile);
 216                 self.anim_duckjump     = animparseline(animfile);
 217                 self.anim_duckidle     = animparseline(animfile);
 218                 self.anim_idle         = animparseline(animfile);
 219                 self.anim_jump         = animparseline(animfile);
 220                 self.anim_pain1        = animparseline(animfile);
 221                 self.anim_pain2        = animparseline(animfile);
 222                 self.anim_shoot        = animparseline(animfile);
 223                 self.anim_taunt        = animparseline(animfile);
 224                 self.anim_run          = animparseline(animfile);
 225                 self.anim_runbackwards = animparseline(animfile);
 226                 self.anim_strafeleft   = animparseline(animfile);
 227                 self.anim_straferight  = animparseline(animfile);
 228                 self.anim_forwardright = animparseline(animfile);
 229                 self.anim_forwardleft  = animparseline(animfile);
 230                 self.anim_backright    = animparseline(animfile);
 231                 self.anim_backleft     = animparseline(animfile);
 232                 fclose(animfile);
 233
 234                 // derived anims
 235                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 236                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 237
 238                 if (animparseerror)
 239                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 240         }
 241         else
 242                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 243         // reset animstate now
 244         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 245 };
 246
 247 void player_anim (void)
 248 {
 249         updateanim(self);
 250         if (self.weaponentity)
 251                 updateanim(self.weaponentity);
 252
 253         if (self.deadflag != DEAD_NO)
 254         {
 255                 if (time > self.animstate_endtime)
 256                 {
 257                         if (self.maxs_z > 5)
 258                         {
 259                                 self.maxs_z = 5;
 260                                 setsize(self, self.mins, self.maxs);
 261                         }
 262                         self.frame = self.dead_frame;
 263                 }
 264                 return;
 265         }
 266
 267         if (!self.animstate_override)
 268         {
 269                 if (!(self.flags & FL_ONGROUND))
 270                 {
 271                         if (self.crouch)
 272                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 273                         else
 274                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 275                         self.restart_jump = FALSE;
 276                 }
 277                 else if (self.crouch)
 278                 {
 279                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 280                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 281                         else
 282                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 283                 }
 284                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 285                 {
 286                         if (self.movement_x > 0 && self.movement_y == 0)
 287                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 288                         else if (self.movement_x < 0 && self.movement_y == 0)
 289                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 290                         else if (self.movement_x == 0 && self.movement_y > 0)
 291                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 292                         else if (self.movement_x == 0 && self.movement_y < 0)
 293                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 294                         else if (self.movement_x > 0 && self.movement_y > 0)
 295                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 296                         else if (self.movement_x > 0 && self.movement_y < 0)
 297                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 298                         else if (self.movement_x < 0 && self.movement_y > 0)
 299                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x < 0 && self.movement_y < 0)
 301                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 302                         else
 303                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 304                 }
 305                 else
 306                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 307         }
 308
 309         if (self.weaponentity)
 310         if (!self.weaponentity.animstate_override)
 311                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 312 }
 313
 314 void SpawnThrownWeapon (vector org, float w)
 315 {
 316         if(g_minstagib)
 317         if(self.ammo_cells <= 0)
 318                 return;
 319
 320         if(g_pinata)
 321         {
 322                 float j;
 323                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 324                 {
 325                         if(self.weapons & W_WeaponBit(j))
 326                                 if(W_IsWeaponThrowable(j))
 327                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 328                 }
 329         }
 330         else
 331                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 332 }
 333
 334 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 335 {
 336         local float take, save;
 337         vector v;
 338         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 339
 340         // damage resistance (ignore most of the damage from a bullet or similar)
 341         damage = max(damage - 5, 1);
 342
 343         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 344         take = v_x;
 345         save = v_y;
 346
 347         if(sound_allowed(MSG_BROADCAST, attacker))
 348         {
 349                 if (save > 10)
 350                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 351                 else if (take > 30)
 352                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 353                 else if (take > 10)
 354                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 355         }
 356
 357         if (take > 50)
 358                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 359         if (take > 100)
 360                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 361
 362         if (!(self.flags & FL_GODMODE))
 363         {
 364                 self.armorvalue = self.armorvalue - save;
 365                 self.health = self.health - take;
 366                 // pause regeneration for 5 seconds
 367                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 368         }
 369         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 370         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 371         self.dmg_inflictor = inflictor;
 372
 373         if (self.health <= -100 && self.modelindex != 0)
 374         {
 375                 // don't use any animations as a gib
 376                 self.frame = 0;
 377                 self.dead_frame = 0;
 378                 // view just above the floor
 379                 self.view_ofs = '0 0 4';
 380
 381                 Violence_GibSplash(self, 1, 1, attacker);
 382                 self.modelindex = 0; // restore later
 383                 self.solid = SOLID_NOT; // restore later
 384         }
 385 }
 386
 387 void ClientKill_Now_TeamChange();
 388
 389 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 390 {
 391         local float take, save, waves, sdelay, dh, da, j;
 392         vector v;
 393         float valid_damage_for_weaponstats;
 394
 395         dh = max(self.health, 0);
 396         da = max(self.armorvalue, 0);
 397
 398         if(!DEATH_ISSPECIAL(deathtype))
 399         {
 400                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 401                 if(self != attacker)
 402                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 403         }
 404
 405         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 406         {
 407                 // tuba causes blood to come out of the ears
 408                 vector ear1, ear2;
 409                 vector d;
 410                 float f;
 411                 ear1 = self.origin;
 412                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 413                 ear2 = ear1;
 414                 makevectors(self.angles);
 415                 ear1 += v_right * -10;
 416                 ear2 += v_right * +10;
 417                 d = inflictor.origin - self.origin;
 418                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 419                 force = v_right * vlen(force);
 420                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 421                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 422                 if(f > 0)
 423                 {
 424                         hitloc = ear1;
 425                         force = force * -1;
 426                 }
 427                 else
 428                 {
 429                         hitloc = ear2;
 430                         // force is already good
 431                 }
 432         }
 433         else
 434                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 435
 436         if((g_arena && numspawned < 2) || (g_ca && player_cnt < 2) && !inWarmupStage)
 437                 return;
 438
 439         if (!g_minstagib)
 440         {
 441                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 442                 take = v_x;
 443                 save = v_y;
 444         }
 445         else
 446         {
 447                 save = 0;
 448                 take = damage;
 449         }
 450
 451         if(sound_allowed(MSG_BROADCAST, attacker))
 452         {
 453                 if (save > 10)
 454                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 455                 else if (take > 30)
 456                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 457                 else if (take > 10)
 458                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 459         }
 460
 461         if (take > 50)
 462                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 463         if (take > 100)
 464                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 465
 466         if (time >= self.spawnshieldtime)
 467         {
 468                 if (!(self.flags & FL_GODMODE))
 469                 {
 470                         self.armorvalue = self.armorvalue - save;
 471                         self.health = self.health - take;
 472                         // pause regeneration for 5 seconds
 473                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 474
 475                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 476                         {
 477                                 self.pain_finished = time + 0.5;        //Supajoe
 478
 479                                 if(sv_gentle < 1) {
 480                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 481                                         {
 482                                                 if (random() > 0.5)
 483                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 484                                                 else
 485                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 486                                         }
 487
 488                                         if(sound_allowed(MSG_BROADCAST, attacker))
 489                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 490                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 491                                         {
 492                                                 if(self.health > 75) // TODO make a "gentle" version?
 493                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 494                                                 else if(self.health > 50)
 495                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 496                                                 else if(self.health > 25)
 497                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 498                                                 else if(self.health > 1)
 499                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 500                                         }
 501                                 }
 502
 503                                 // throw off bot aim temporarily
 504                                 local float shake;
 505                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 506                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 507                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 508                         }
 509                 }
 510                 else
 511                         self.max_armorvalue += (save + take);
 512         }
 513         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 514         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 515         self.dmg_inflictor = inflictor;
 516
 517         if(attacker == self)
 518         {
 519                 // don't reset pushltime for self damage as it may be an attempt to
 520                 // escape a lava pit or similar
 521                 //self.pushltime = 0;
 522         }
 523         else if(attacker.classname == "player" || attacker.classname == "gib")
 524         {
 525                 self.pusher = attacker;
 526                 self.pushltime = time + cvar("g_maxpushtime");
 527         }
 528         else if(time < self.pushltime)
 529         {
 530                 attacker = self.pusher;
 531                 self.pushltime = max(self.pushltime, time + 0.6);
 532         }
 533         else
 534                 self.pushltime = 0;
 535
 536         valid_damage_for_weaponstats = 0;
 537         if(clienttype(self) == CLIENTTYPE_REAL)
 538         if(clienttype(attacker) == CLIENTTYPE_REAL)
 539         if(self != attacker)
 540         if(!DEATH_ISSPECIAL(deathtype))
 541         if(IsDifferentTeam(self, attacker))
 542                 valid_damage_for_weaponstats = 1;
 543
 544         if(valid_damage_for_weaponstats)
 545         {
 546                 dh = dh - max(self.health, 0);
 547                 da = da - max(self.armorvalue, 0);
 548                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 549         }
 550
 551         if (self.health < 1)
 552         {
 553                 float defer_ClientKill_Now_TeamChange;
 554                 defer_ClientKill_Now_TeamChange = FALSE;
 555
 556                 if(valid_damage_for_weaponstats)
 557                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 558
 559                 if(sv_gentle < 1) // TODO make a "gentle" version?
 560                 if(sound_allowed(MSG_BROADCAST, attacker))
 561                 {
 562                         if(deathtype == DEATH_DROWN)
 563                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 564                         else
 565                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 566                 }
 567
 568                 // get rid of kill indicator
 569                 if(self.killindicator)
 570                 {
 571                         remove(self.killindicator);
 572                         self.killindicator = world;
 573                         if(self.killindicator_teamchange)
 574                                 defer_ClientKill_Now_TeamChange = TRUE;
 575
 576                         if(self.classname == "body")
 577                         if(deathtype == DEATH_KILL)
 578                         {
 579                                 // for the lemmings fans, a small harmless explosion
 580                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 581                         }
 582                 }
 583
 584                 // become fully visible
 585                 self.alpha = 1;
 586                 // clear selected player display
 587                 ClearSelectedPlayer();
 588                 // throw a weapon
 589                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 590                 // print an obituary message
 591                 Obituary (attacker, inflictor, self, deathtype);
 592                 race_PreDie();
 593                 DropAllRunes(self);
 594
 595                 frag_attacker = attacker;
 596                 frag_inflictor = inflictor;
 597                 frag_target = self;
 598                 MUTATOR_CALLHOOK(PlayerDies);
 599
 600                 if(self.flagcarried)
 601                 {
 602                         if(attacker.classname != "player" && attacker.classname != "gib")
 603                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 604                         else if(attacker.team == self.team)
 605                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 606                         else
 607                                 DropFlag(self.flagcarried, world, attacker);
 608                 }
 609                 if(self.ballcarried)
 610                         DropBall(self.ballcarried, self.origin, self.velocity);
 611                 Portal_ClearAllLater(self);
 612                 // clear waypoints
 613                 WaypointSprite_PlayerDead();
 614                 // make the corpse upright (not tilted)
 615                 self.angles_x = 0;
 616                 self.angles_z = 0;
 617                 // don't spin
 618                 self.avelocity = '0 0 0';
 619                 // view from the floor
 620                 self.view_ofs = '0 0 -8';
 621                 // toss the corpse
 622                 self.movetype = MOVETYPE_TOSS;
 623                 // shootable corpse
 624                 self.solid = SOLID_CORPSE;
 625                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 626                 // don't stick to the floor
 627                 self.flags &~= FL_ONGROUND;
 628                 // dying animation
 629                 self.deadflag = DEAD_DYING;
 630                 // when to allow respawn
 631                 sdelay = 0;
 632                 waves = 0;
 633                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 634                 if(!sdelay)
 635                         sdelay = cvar("g_respawn_delay");
 636                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 637                 if(!waves)
 638                         waves = cvar("g_respawn_waves");
 639                 if(waves)
 640                         self.death_time = ceil((time + sdelay) / waves) * waves;
 641                 else
 642                         self.death_time = time + sdelay;
 643                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 644                         self.respawn_countdown = 10; // first number to count down from is 10
 645                 else
 646                         self.respawn_countdown = -1; // do not count down
 647                 if (random() < 0.5)
 648                 {
 649                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 650                         self.dead_frame = self.anim_dead1_x;
 651                 }
 652                 else
 653                 {
 654                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 655                         self.dead_frame = self.anim_dead2_x;
 656                 }
 657                 // set damage function to corpse damage
 658                 self.event_damage = PlayerCorpseDamage;
 659                 // call the corpse damage function just in case it wants to gib
 660                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 661                 // set up to fade out later
 662                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 663
 664                 // remove laserdot
 665                 if(self.weaponentity)
 666                         if(self.weaponentity.lasertarget)
 667                                 remove(self.weaponentity.lasertarget);
 668
 669                 if(clienttype(self) == CLIENTTYPE_REAL)
 670                 {
 671                         self.fixangle = TRUE;
 672                         //msg_entity = self;
 673                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 674                         //WriteAngle (MSG_ONE, self.v_angle_x);
 675                         //WriteAngle (MSG_ONE, self.v_angle_y);
 676                         //WriteAngle (MSG_ONE, 80);
 677                 }
 678
 679                 if(g_arena)
 680                         Spawnqueue_Unmark(self);
 681
 682                 if(defer_ClientKill_Now_TeamChange)
 683                         ClientKill_Now_TeamChange();
 684
 685                 if(sv_gentle > 0 || cvar("ekg")) {
 686                         // remove corpse
 687                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 688                 }
 689
 690                 // reset fields the weapons may use just in case
 691         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 692                 {
 693             weapon_action(j, WR_RESETPLAYER);
 694                         ATTACK_FINISHED_FOR(self, j) = 0;
 695                 }
 696         }
 697 }
 698
 699 float UpdateSelectedPlayer_countvalue(float v)
 700 {
 701         return max(0, (v - 1.0) / 0.5);
 702 }
 703
 704 // returns: -2 if no hit, otherwise cos of the angle
 705 // uses the global v_angle
 706 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 707 {
 708         vector so, d;
 709         float c;
 710
 711         if(p == self)
 712                 return -2;
 713
 714         if(p.deadflag)
 715                 return -2;
 716
 717         so = self.origin + self.view_ofs;
 718         d = p.origin - so;
 719
 720         // misaimed?
 721         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 722                 return -2;
 723
 724         // now find the cos of the angle...
 725         c = normalize(d) * v_forward;
 726
 727         if(c <= mincosangle)
 728                 return -2;
 729
 730         // not visible in any way? forget it
 731         if(!checkpvs(so, p))
 732                 return -2;
 733
 734         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 735         if(trace_fraction < 1)
 736                 return -2;
 737
 738         return c;
 739 }
 740
 741 void ClearSelectedPlayer()
 742 {
 743         if(self.selected_player)
 744         {
 745                 centerprint_expire(self, CENTERPRIO_POINT);
 746                 self.selected_player = world;
 747                 self.selected_player_display_needs_update = FALSE;
 748         }
 749 }
 750
 751 void UpdateSelectedPlayer()
 752 {
 753         entity selected;
 754         float selected_score;
 755         selected = world;
 756         selected_score = 0.95; // 18 degrees
 757
 758         if(!cvar("sv_allow_shownames"))
 759                 return;
 760
 761         if(clienttype(self) != CLIENTTYPE_REAL)
 762                 return;
 763
 764         if(self.cvar_cl_shownames == 0)
 765                 return;
 766
 767         if(self.cvar_cl_shownames == 1 && !teams_matter)
 768                 return;
 769
 770         makevectors(self.v_angle); // sets v_forward
 771
 772         // 1. cursor trace is always right
 773         WarpZone_crosshair_trace(self);
 774         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 775         {
 776                 selected = trace_ent;
 777         }
 778         else
 779         {
 780                 // 2. if we don't have a cursor trace, find the player which is least
 781                 //    mis-aimed at
 782                 entity p;
 783                 FOR_EACH_PLAYER(p)
 784                 {
 785                         float c;
 786                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 787                         if(c >= -1)
 788                         {
 789                                 selected = p;
 790                                 selected_score = c;
 791                         }
 792                 }
 793         }
 794
 795         if(selected)
 796         {
 797                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 798         }
 799         else
 800         {
 801                 if(time < self.selected_player_display_timeout)
 802                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 803                                 selected = self.selected_player;
 804         }
 805
 806         if(selected)
 807         {
 808                 if(selected == self.selected_player)
 809                 {
 810                         float save;
 811                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 812                         self.selected_player_count = self.selected_player_count + frametime;
 813                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 814                         {
 815                                 string namestr, healthstr;
 816                                 namestr = playername(selected);
 817                                 if(teams_matter)
 818                                 {
 819                                         healthstr = ftos(floor(selected.health));
 820                                         if(self.team == selected.team)
 821                                         {
 822                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 823                                                 self.selected_player_display_needs_update = TRUE;
 824                                         }
 825                                 }
 826                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 827                         }
 828                 }
 829                 else
 830                 {
 831                         ClearSelectedPlayer();
 832                         self.selected_player = selected;
 833                         self.selected_player_time = time;
 834                         self.selected_player_count = 0;
 835                         self.selected_player_display_needs_update = FALSE;
 836                 }
 837         }
 838         else
 839         {
 840                 ClearSelectedPlayer();
 841         }
 842
 843         if(self.selected_player)
 844                 self.last_selected_player = self.selected_player;
 845 }
 846
 847 .float muted; // to be used by prvm_edictset server playernumber muted 1
 848 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 849 // message "": do not say, just test flood control
 850 // return value:
 851 //   1 = accept
 852 //   0 = reject
 853 //  -1 = fake accept
 854 {
 855         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 856         float flood, privatemsgprefixlen;
 857         entity head;
 858         float ret;
 859
 860         if(Ban_MaybeEnforceBan(source))
 861                 return 0;
 862
 863         if(!teamsay && !privatesay)
 864                 if(substring(msgin, 0, 1) == " ")
 865                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 866
 867         msgin = formatmessage(msgin);
 868
 869         if(source.classname != "player")
 870                 colorstr = "^0"; // black for spectators
 871         else if(teams_matter)
 872                 colorstr = Team_ColorCode(source.team);
 873         else
 874                 teamsay = FALSE;
 875
 876         if(intermission_running)
 877                 teamsay = FALSE;
 878
 879         if(msgin != "")
 880                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 881
 882         /*
 883          * using bprint solves this... me stupid
 884         // how can we prevent the message from appearing in a listen server?
 885         // for now, just give "say" back and only handle say_team
 886         if(!teamsay)
 887         {
 888                 clientcommand(self, strcat("say ", msgin));
 889                 return;
 890         }
 891         */
 892
 893         if(cvar("g_chat_teamcolors"))
 894                 namestr = playername(source);
 895         else
 896                 namestr = source.netname;
 897
 898         if(msgin != "")
 899         {
 900                 if(privatesay)
 901                 {
 902                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 903                         privatemsgprefixlen = strlen(msgstr);
 904                         msgstr = strcat(msgstr, msgin);
 905                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 906                         if(cvar("g_chat_teamcolors"))
 907                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 908                         else
 909                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 910                 }
 911                 else if(teamsay)
 912                 {
 913                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 914                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 915                 }
 916                 else
 917                 {
 918                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 919                         cmsgstr = "";
 920                 }
 921                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 922         }
 923         else
 924         {
 925                 msgstr = cmsgstr = "";
 926         }
 927
 928         fullmsgstr = msgstr;
 929         fullcmsgstr = cmsgstr;
 930
 931         // FLOOD CONTROL
 932         flood = 0;
 933         if(floodcontrol)
 934         {
 935                 float flood_spl;
 936                 float flood_burst;
 937                 float flood_lmax;
 938                 var .float flood_field;
 939                 float lines;
 940                 if(privatesay)
 941                 {
 942                         flood_spl = cvar("g_chat_flood_spl_tell");
 943                         flood_burst = cvar("g_chat_flood_burst_tell");
 944                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 945                         flood_field = floodcontrol_chattell;
 946                 }
 947                 else if(teamsay)
 948                 {
 949                         flood_spl = cvar("g_chat_flood_spl_team");
 950                         flood_burst = cvar("g_chat_flood_burst_team");
 951                         flood_lmax = cvar("g_chat_flood_lmax_team");
 952                         flood_field = floodcontrol_chatteam;
 953                 }
 954                 else
 955                 {
 956                         flood_spl = cvar("g_chat_flood_spl");
 957                         flood_burst = cvar("g_chat_flood_burst");
 958                         flood_lmax = cvar("g_chat_flood_lmax");
 959                         flood_field = floodcontrol_chat;
 960                 }
 961                 flood_burst = max(0, flood_burst - 1);
 962                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 963
 964                 // do flood control for the default line size
 965                 if(msgstr != "")
 966                 {
 967                         getWrappedLine_remaining = msgstr;
 968                         msgstr = "";
 969                         lines = 0;
 970                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 971                         {
 972                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 973                                 ++lines;
 974                         }
 975                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 976
 977                         if(getWrappedLine_remaining != "")
 978                         {
 979                                 msgstr = strcat(msgstr, "\n");
 980                                 flood = 2;
 981                         }
 982
 983                         if(time >= source.flood_field)
 984                         {
 985                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 986                         }
 987                         else
 988                         {
 989                                 flood = 1;
 990                                 msgstr = fullmsgstr;
 991                         }
 992                 }
 993                 else
 994                 {
 995                         if(time >= source.flood_field)
 996                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 997                         else
 998                                 flood = 1;
 999                 }
1000         }
1001
1002         if (timeoutStatus == 2) //when game is paused, no flood protection
1003                 source.flood_field = flood = 0;
1004
1005         if(flood == 2) // cannot happen for empty msgstr
1006         {
1007                 if(cvar("g_chat_flood_notify_flooder"))
1008                 {
1009                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1010                         sourcecmsgstr = "";
1011                 }
1012                 else
1013                 {
1014                         sourcemsgstr = fullmsgstr;
1015                         sourcecmsgstr = fullcmsgstr;
1016                 }
1017                 cmsgstr = "";
1018         }
1019         else
1020         {
1021                 sourcemsgstr = msgstr;
1022                 sourcecmsgstr = cmsgstr;
1023         }
1024
1025         if(!privatesay)
1026         if(source.classname != "player")
1027         {
1028                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1029                         teamsay = -1; // spectators
1030         }
1031
1032         if(flood)
1033                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1034
1035         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1036         if(privatesay)
1037                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1038
1039         if(source.muted)
1040         {
1041                 // always fake the message
1042                 ret = -1;
1043         }
1044         else if(flood == 1)
1045         {
1046                 if(cvar("g_chat_flood_notify_flooder"))
1047                 {
1048                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1049                         ret = 0;
1050                 }
1051                 else
1052                         ret = -1;
1053         }
1054         else
1055         {
1056                 ret = 1;
1057         }
1058
1059         if(sourcemsgstr != "" && ret != 0)
1060         {
1061                 if(ret < 0) // fake
1062                 {
1063                         sprint(source, sourcemsgstr);
1064                         if(sourcecmsgstr != "" && !privatesay)
1065                                 centerprint(source, sourcecmsgstr);
1066                 }
1067                 else if(privatesay)
1068                 {
1069                         sprint(source, sourcemsgstr);
1070                         sprint(privatesay, msgstr);
1071                         if(cmsgstr != "")
1072                                 centerprint(privatesay, cmsgstr);
1073                 }
1074                 else if(teamsay > 0)
1075                 {
1076                         sprint(source, sourcemsgstr);
1077                         if(sourcecmsgstr != "")
1078                                 centerprint(source, sourcecmsgstr);
1079                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1080                                 if(head != source)
1081                                 {
1082                                         sprint(head, msgstr);
1083                                         if(cmsgstr != "")
1084                                                 centerprint(head, cmsgstr);
1085                                 }
1086                 }
1087                 else if(teamsay < 0)
1088                 {
1089                         sprint(source, sourcemsgstr);
1090                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1091                                 if(head != source)
1092                                         sprint(head, msgstr);
1093                 }
1094                 else if(sourcemsgstr != msgstr)
1095                 {
1096                         sprint(source, sourcemsgstr);
1097                         FOR_EACH_REALCLIENT(head)
1098                                 if(head != source)
1099                                         sprint(head, msgstr);
1100                 }
1101                 else
1102                         bprint(msgstr);
1103         }
1104
1105         return ret;
1106 }
1107
1108 float GetVoiceMessageVoiceType(string type)
1109 {
1110         if(type == "taunt")
1111                 return VOICETYPE_TAUNT;
1112         if(type == "teamshoot")
1113                 return VOICETYPE_LASTATTACKER;
1114         return VOICETYPE_TEAMRADIO;
1115 }
1116
1117 string allvoicesamples;
1118 float GetPlayerSoundSampleField_notFound;
1119 float GetPlayerSoundSampleField_fixed;
1120 .string GetVoiceMessageSampleField(string type)
1121 {
1122         GetPlayerSoundSampleField_notFound = 0;
1123         GetPlayerSoundSampleField_fixed = 0;
1124         switch(type)
1125         {
1126 #define _VOICEMSG(m) case #m: return playersound_##m;
1127                 ALLVOICEMSGS
1128 #undef _VOICEMSG
1129         }
1130         GetPlayerSoundSampleField_notFound = 1;
1131         return playersound_taunt;
1132 }
1133
1134 .string GetPlayerSoundSampleField(string type)
1135 {
1136         GetPlayerSoundSampleField_notFound = 0;
1137         GetPlayerSoundSampleField_fixed = 0;
1138         switch(type)
1139         {
1140 #define _VOICEMSG(m) case #m: return playersound_##m;
1141                 ALLPLAYERSOUNDS
1142 #undef _VOICEMSG
1143         }
1144         GetPlayerSoundSampleField_notFound = 1;
1145         return playersound_taunt;
1146 }
1147
1148 void PrecacheGlobalSound(string samplestring)
1149 {
1150         float n, i;
1151         tokenize_console(samplestring);
1152         n = stof(argv(1));
1153         if(n > 0)
1154         {
1155                 for(i = 1; i <= n; ++i)
1156                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1157         }
1158         else
1159         {
1160                 precache_sound(strcat(argv(0), ".wav"));
1161         }
1162 }
1163
1164 void PrecachePlayerSounds(string f)
1165 {
1166         float fh;
1167         string s;
1168         fh = fopen(f, FILE_READ);
1169         if(fh < 0)
1170                 return;
1171         while((s = fgets(fh)))
1172         {
1173                 if(tokenize_console(s) != 3)
1174                 {
1175                         dprint("Invalid sound info line: ", s, "\n");
1176                         continue;
1177                 }
1178                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1179         }
1180         fclose(fh);
1181
1182         if not(allvoicesamples)
1183         {
1184 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1185                 ALLVOICEMSGS
1186 #undef _VOICEMSG
1187                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1188         }
1189 }
1190
1191 void ClearPlayerSounds()
1192 {
1193 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1194         ALLPLAYERSOUNDS
1195         ALLVOICEMSGS
1196 #undef _VOICEMSG
1197 }
1198
1199 void LoadPlayerSounds(string f, float first)
1200 {
1201         float fh;
1202         string s;
1203         var .string field;
1204         fh = fopen(f, FILE_READ);
1205         if(fh < 0)
1206         {
1207                 dprint("Player sound file not found: ", f, "\n");
1208                 return;
1209         }
1210         while((s = fgets(fh)))
1211         {
1212                 if(tokenize_console(s) != 3)
1213                         continue;
1214                 field = GetPlayerSoundSampleField(argv(0));
1215                 if(GetPlayerSoundSampleField_notFound)
1216                         field = GetVoiceMessageSampleField(argv(0));
1217                 if(GetPlayerSoundSampleField_notFound)
1218                         continue;
1219                 if(GetPlayerSoundSampleField_fixed)
1220                         if not(first)
1221                                 continue;
1222                 if(self.field)
1223                         strunzone(self.field);
1224                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1225         }
1226         fclose(fh);
1227 }
1228
1229 .float modelindex_for_playersound;
1230 .float skinindex_for_playersound;
1231 void UpdatePlayerSounds()
1232 {
1233         if(self.modelindex == self.modelindex_for_playersound)
1234         if(self.skinindex == self.skinindex_for_playersound)
1235                 return;
1236         self.modelindex_for_playersound = self.modelindex;
1237         self.skinindex_for_playersound = self.skinindex;
1238         ClearPlayerSounds();
1239         LoadPlayerSounds("sound/player/default.sounds", 1);
1240         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1241 }
1242
1243 void FakeGlobalSound(string sample, float chan, float voicetype)
1244 {
1245         float n;
1246         float tauntrand;
1247
1248         if(sample == "")
1249                 return;
1250
1251         tokenize_console(sample);
1252         n = stof(argv(1));
1253         if(n > 0)
1254                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1255         else
1256                 sample = strcat(argv(0), ".wav"); // randomization
1257
1258         switch(voicetype)
1259         {
1260                 case VOICETYPE_LASTATTACKER_ONLY:
1261                         break;
1262                 case VOICETYPE_LASTATTACKER:
1263                         if(self.pusher)
1264                         {
1265                                 msg_entity = self;
1266                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1267                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1268                         }
1269                         break;
1270                 case VOICETYPE_TEAMRADIO:
1271                         msg_entity = self;
1272                         if(msg_entity.cvar_cl_voice_directional == 1)
1273                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1274                         else
1275                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1276                         break;
1277                 case VOICETYPE_AUTOTAUNT:
1278                         if(!sv_autotaunt)
1279                                 break;
1280                         if(!sv_taunt)
1281                                 break;
1282                         if(sv_gentle)
1283                                 break;
1284                         tauntrand = random();
1285                         msg_entity = self;
1286                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1287                         {
1288                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1289                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1290                                 else
1291                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1292                         }
1293                         break;
1294                 case VOICETYPE_TAUNT:
1295                         if(self.classname == "player")
1296                                 if(self.deadflag == DEAD_NO)
1297                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1298                         if(!sv_taunt)
1299                                 break;
1300                         if(sv_gentle)
1301                                 break;
1302                         msg_entity = self;
1303                         if (msg_entity.cvar_cl_voice_directional >= 1)
1304                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1305                         else
1306                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1307                         break;
1308                 case VOICETYPE_PLAYERSOUND:
1309                         msg_entity = self;
1310                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1311                         break;
1312                 default:
1313                         backtrace("Invalid voice type!");
1314                         break;
1315         }
1316 }
1317
1318 void GlobalSound(string sample, float chan, float voicetype)
1319 {
1320         float n;
1321         float tauntrand;
1322
1323         if(sample == "")
1324                 return;
1325
1326         tokenize_console(sample);
1327         n = stof(argv(1));
1328         if(n > 0)
1329                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1330         else
1331                 sample = strcat(argv(0), ".wav"); // randomization
1332
1333         switch(voicetype)
1334         {
1335                 case VOICETYPE_LASTATTACKER_ONLY:
1336                         if(self.pusher)
1337                         {
1338                                 msg_entity = self.pusher;
1339                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1340                                 {
1341                                         if(msg_entity.cvar_cl_voice_directional == 1)
1342                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1343                                         else
1344                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1345                                 }
1346                         }
1347                         break;
1348                 case VOICETYPE_LASTATTACKER:
1349                         if(self.pusher)
1350                         {
1351                                 msg_entity = self.pusher;
1352                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1353                                 {
1354                                         if(msg_entity.cvar_cl_voice_directional == 1)
1355                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1356                                         else
1357                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1358                                 }
1359                                 msg_entity = self;
1360                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1361                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1362                         }
1363                         break;
1364                 case VOICETYPE_TEAMRADIO:
1365                         FOR_EACH_REALCLIENT(msg_entity)
1366                                 if(!teams_matter || msg_entity.team == self.team)
1367                                 {
1368                                         if(msg_entity.cvar_cl_voice_directional == 1)
1369                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1370                                         else
1371                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1372                                 }
1373                         break;
1374                 case VOICETYPE_AUTOTAUNT:
1375                         if(!sv_autotaunt)
1376                                 break;
1377                         if(!sv_taunt)
1378                                 break;
1379                         if(sv_gentle)
1380                                 break;
1381                         tauntrand = random();
1382                         FOR_EACH_REALCLIENT(msg_entity)
1383                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1384                                 {
1385                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1386                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1387                                         else
1388                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1389                                 }
1390                         break;
1391                 case VOICETYPE_TAUNT:
1392                         if(self.classname == "player")
1393                                 if(self.deadflag == DEAD_NO)
1394                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1395                         if(!sv_taunt)
1396                                 break;
1397                         if(sv_gentle)
1398                                 break;
1399                         FOR_EACH_REALCLIENT(msg_entity)
1400                         {
1401                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1402                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1403                                 else
1404                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1405                         }
1406                         break;
1407                 case VOICETYPE_PLAYERSOUND:
1408                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1409                         break;
1410                 default:
1411                         backtrace("Invalid voice type!");
1412                         break;
1413         }
1414 }
1415
1416 void PlayerSound(.string samplefield, float chan, float voicetype)
1417 {
1418         GlobalSound(self.samplefield, chan, voicetype);
1419 }
1420
1421 void VoiceMessage(string type, string msg)
1422 {
1423         var .string sample;
1424         float voicetype, ownteam;
1425         float flood;
1426         sample = GetVoiceMessageSampleField(type);
1427
1428         if(GetPlayerSoundSampleField_notFound)
1429         {
1430                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1431                 return;
1432         }
1433
1434         voicetype = GetVoiceMessageVoiceType(type);
1435         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1436
1437         flood = Say(self, ownteam, world, msg, 1);
1438
1439         if (flood > 0)
1440                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1441         else if (flood < 0)
1442                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1443 }
1444
1445 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1446 {
1447 //      show_message
1448 //      0 (00) automove centerprint, admin message
1449 //      1 (01) automove centerprint, no admin message
1450 //      2 (10) no centerprint, admin message
1451 //      3 (11) no centerprint, no admin message
1452
1453         float lockteams_backup;
1454
1455         lockteams_backup = lockteams;  // backup any team lock
1456
1457         lockteams = 0;  // disable locked teams
1458
1459         TeamchangeFrags(client);  // move the players frags
1460         SetPlayerColors(client, team_colour - 1);  // set the players colour
1461         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1462
1463         lockteams = lockteams_backup;  // restore the team lock
1464
1465         LogTeamchange(client.playerid, client.team, type);
1466
1467         if not(show_message & 1) // admin message
1468                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1469
1470         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1471 }