qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(self.weapons & WepSet_FromWeapon(self.weapon))
 266                 if(W_IsWeaponThrowable(self.weapon))
 267                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 268 }
 269
 270 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 271 {
 272         float take, save;
 273         vector v;
 274         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 275
 276         // damage resistance (ignore most of the damage from a bullet or similar)
 277         damage = max(damage - 5, 1);
 278
 279         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 280         take = v_x;
 281         save = v_y;
 282
 283         if(sound_allowed(MSG_BROADCAST, attacker))
 284         {
 285                 if (save > 10)
 286                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 287                 else if (take > 30)
 288                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 289                 else if (take > 10)
 290                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 291         }
 292
 293         if (take > 50)
 294                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 295         if (take > 100)
 296                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 297
 298         if (!(self.flags & FL_GODMODE))
 299         {
 300                 self.armorvalue = self.armorvalue - save;
 301                 self.health = self.health - take;
 302                 // pause regeneration for 5 seconds
 303                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 304         }
 305         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 306         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 307         self.dmg_inflictor = inflictor;
 308
 309         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 310         {
 311                 // don't use any animations as a gib
 312                 self.frame = 0;
 313                 // view just above the floor
 314                 self.view_ofs = '0 0 4';
 315
 316                 Violence_GibSplash(self, 1, 1, attacker);
 317                 self.alpha = -1;
 318                 self.solid = SOLID_NOT; // restore later
 319                 self.takedamage = DAMAGE_NO; // restore later
 320                 self.damagedbycontents = FALSE;
 321         }
 322 }
 323
 324 void ClientKill_Now_TeamChange();
 325
 326 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 327 {
 328         float take, save, waves, sdelay, dh, da, j;
 329         vector v;
 330         float valid_damage_for_weaponstats;
 331         float excess;
 332
 333         dh = max(self.health, 0);
 334         da = max(self.armorvalue, 0);
 335
 336         if(!DEATH_ISSPECIAL(deathtype))
 337         {
 338                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 339                 if(self != attacker)
 340                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 341         }
 342
 343         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 344         {
 345                 // tuba causes blood to come out of the ears
 346                 vector ear1, ear2;
 347                 vector d;
 348                 float f;
 349                 ear1 = self.origin;
 350                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 351                 ear2 = ear1;
 352                 makevectors(self.angles);
 353                 ear1 += v_right * -10;
 354                 ear2 += v_right * +10;
 355                 d = inflictor.origin - self.origin;
 356                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 357                 force = v_right * vlen(force);
 358                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 359                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 360                 if(f > 0)
 361                 {
 362                         hitloc = ear1;
 363                         force = force * -1;
 364                 }
 365                 else
 366                 {
 367                         hitloc = ear2;
 368                         // force is already good
 369                 }
 370         }
 371         else
 372                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 373
 374
 375         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 376         take = v_x;
 377         save = v_y;
 378
 379         if(attacker == self)
 380         {
 381                 // don't reset pushltime for self damage as it may be an attempt to
 382                 // escape a lava pit or similar
 383                 //self.pushltime = 0;
 384                 self.istypefrag = 0;
 385         }
 386         else if(IS_PLAYER(attacker))
 387         {
 388                 self.pusher = attacker;
 389                 self.pushltime = time + autocvar_g_maxpushtime;
 390                 self.istypefrag = self.BUTTON_CHAT;
 391         }
 392         else if(time < self.pushltime)
 393         {
 394                 attacker = self.pusher;
 395                 self.pushltime = max(self.pushltime, time + 0.6);
 396         }
 397         else
 398         {
 399                 self.pushltime = 0;
 400                 self.istypefrag = 0;
 401         }
 402
 403         frag_inflictor = inflictor;
 404         frag_attacker = attacker;
 405         frag_target = self;
 406         frag_damage = damage;
 407         damage_take = take;
 408         damage_save = save;
 409         damage_force = force;
 410         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 411         take = bound(0, damage_take, self.health);
 412         save = bound(0, damage_save, self.armorvalue);
 413         excess = max(0, damage - take - save);
 414
 415         if(sound_allowed(MSG_BROADCAST, attacker))
 416         {
 417                 if (save > 10)
 418                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 419                 else if (take > 30)
 420                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 421                 else if (take > 10)
 422                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 423         }
 424
 425         if (take > 50)
 426                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 427         if (take > 100)
 428                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 429
 430         if (time >= self.spawnshieldtime)
 431         {
 432                 if (!(self.flags & FL_GODMODE))
 433                 {
 434                         self.armorvalue = self.armorvalue - save;
 435                         self.health = self.health - take;
 436                         // pause regeneration for 5 seconds
 437                         if(take)
 438                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 439
 440                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 441                         {
 442                                 self.pain_finished = time + 0.5;        //Supajoe
 443
 444                                 if(autocvar_sv_gentle < 1) {
 445                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 446                                         {
 447                                                 if (!self.animstate_override)
 448                                                 {
 449                                                         if (random() > 0.5)
 450                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 451                                                         else
 452                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 453                                                 }
 454                                         }
 455
 456                                         if(sound_allowed(MSG_BROADCAST, attacker))
 457                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 458                                         if(self.health > 1)
 459                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 460                                         {
 461                                                 if(deathtype == DEATH_FALL)
 462                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 463                                                 else if(self.health > 75) // TODO make a "gentle" version?
 464                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 465                                                 else if(self.health > 50)
 466                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 467                                                 else if(self.health > 25)
 468                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 469                                                 else
 470                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 471                                         }
 472                                 }
 473
 474                                 // throw off bot aim temporarily
 475                                 float shake;
 476                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 477                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 478                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 479                         }
 480                 }
 481                 else
 482                         self.max_armorvalue += (save + take);
 483         }
 484         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 485         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 486         self.dmg_inflictor = inflictor;
 487
 488         float abot, vbot, awep;
 489         abot = (IS_BOT_CLIENT(attacker));
 490         vbot = (IS_BOT_CLIENT(self));
 491
 492         valid_damage_for_weaponstats = 0;
 493         awep = 0;
 494
 495         if(vbot || IS_REAL_CLIENT(self))
 496         if(abot || IS_REAL_CLIENT(attacker))
 497         if(attacker && self != attacker)
 498         if(IsDifferentTeam(self, attacker))
 499         {
 500                 if(DEATH_ISSPECIAL(deathtype))
 501                         awep = attacker.weapon;
 502                 else
 503                         awep = DEATH_WEAPONOF(deathtype);
 504                 valid_damage_for_weaponstats = 1;
 505         }
 506
 507         if(valid_damage_for_weaponstats)
 508         {
 509                 dh = dh - max(self.health, 0);
 510                 da = da - max(self.armorvalue, 0);
 511                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 512         }
 513
 514         if (self.health < 1)
 515         {
 516                 float defer_ClientKill_Now_TeamChange;
 517                 defer_ClientKill_Now_TeamChange = FALSE;
 518
 519                 if(self.alivetime)
 520                 {
 521                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 522                         self.alivetime = 0;
 523                 }
 524
 525                 if(valid_damage_for_weaponstats)
 526                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 527
 528                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 529                 if(sound_allowed(MSG_BROADCAST, attacker))
 530                 {
 531                         if(deathtype == DEATH_DROWN)
 532                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 533                         else
 534                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 535                 }
 536
 537                 // get rid of kill indicator
 538                 if(self.killindicator)
 539                 {
 540                         remove(self.killindicator);
 541                         self.killindicator = world;
 542                         if(self.killindicator_teamchange)
 543                                 defer_ClientKill_Now_TeamChange = TRUE;
 544
 545                         if(self.classname == "body")
 546                         if(deathtype == DEATH_KILL)
 547                         {
 548                                 // for the lemmings fans, a small harmless explosion
 549                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 550                         }
 551                 }
 552
 553                 // print an obituary message
 554                 Obituary (attacker, inflictor, self, deathtype);
 555                 race_PreDie();
 556
 557         // increment frag counter for used weapon type
 558         float w;
 559         w = DEATH_WEAPONOF(deathtype);
 560         if(WEP_VALID(w))
 561         if(accuracy_isgooddamage(attacker, self))
 562         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 563
 564                 frag_attacker = attacker;
 565                 frag_inflictor = inflictor;
 566                 frag_target = self;
 567                 frag_deathtype = deathtype;
 568                 MUTATOR_CALLHOOK(PlayerDies);
 569
 570                 weapon_action(self.weapon, WR_PLAYERDEATH);
 571
 572                 RemoveGrapplingHook(self);
 573
 574                 Portal_ClearAllLater(self);
 575
 576                 if(IS_REAL_CLIENT(self))
 577                 {
 578                         self.fixangle = TRUE;
 579                         //msg_entity = self;
 580                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 581                         //WriteAngle (MSG_ONE, self.v_angle_x);
 582                         //WriteAngle (MSG_ONE, self.v_angle_y);
 583                         //WriteAngle (MSG_ONE, 80);
 584                 }
 585
 586                 if(defer_ClientKill_Now_TeamChange)
 587                         ClientKill_Now_TeamChange(); // can turn player into spectator
 588
 589                 // player could have been miraculously resuscitated ;)
 590                 // e.g. players in freezetag get frozen, they don't really die
 591                 if(self.health >= 1 || !IS_PLAYER(self))
 592                         return;
 593
 594                 // when we get here, player actually dies
 595
 596                 // clear waypoints
 597                 WaypointSprite_PlayerDead();
 598                 // throw a weapon
 599                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 600
 601                 // become fully visible
 602                 self.alpha = default_player_alpha;
 603                 // make the corpse upright (not tilted)
 604                 self.angles_x = 0;
 605                 self.angles_z = 0;
 606                 // don't spin
 607                 self.avelocity = '0 0 0';
 608                 // view from the floor
 609                 self.view_ofs = '0 0 -8';
 610                 // toss the corpse
 611                 self.movetype = MOVETYPE_TOSS;
 612                 // shootable corpse
 613                 self.solid = SOLID_CORPSE;
 614                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 615                 // don't stick to the floor
 616                 self.flags &= ~FL_ONGROUND;
 617                 // dying animation
 618                 self.deadflag = DEAD_DYING;
 619                 // when to allow respawn
 620                 sdelay = 0;
 621                 waves = 0;
 622                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 623                 if(!sdelay)
 624                 {
 625                         if(g_cts)
 626                                 sdelay = 0; // no respawn delay in CTS
 627                         else
 628                                 sdelay = autocvar_g_respawn_delay;
 629                 }
 630                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 631                 if(!waves)
 632                         waves = autocvar_g_respawn_waves;
 633                 if(waves)
 634                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 635                 else
 636                         self.respawn_time = time + sdelay;
 637                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 638                         self.respawn_countdown = 10; // first number to count down from is 10
 639                 else
 640                         self.respawn_countdown = -1; // do not count down
 641
 642                 if(g_cts || autocvar_g_forced_respawn)
 643                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 644
 645                 self.death_time = time;
 646                 if (random() < 0.5)
 647                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 648                 else
 649                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 650                 if (self.maxs_z > 5)
 651                 {
 652                         self.maxs_z = 5;
 653                         setsize(self, self.mins, self.maxs);
 654                 }
 655                 // set damage function to corpse damage
 656                 self.event_damage = PlayerCorpseDamage;
 657                 // call the corpse damage function just in case it wants to gib
 658                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 659                 // set up to fade out later
 660                 SUB_SetFade (self, time + 6 + random (), 1);
 661
 662                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 663                         // remove corpse
 664                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 665                 }
 666
 667                 // reset fields the weapons may use just in case
 668                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 669                 {
 670                         weapon_action(j, WR_RESETPLAYER);
 671                         ATTACK_FINISHED_FOR(self, j) = 0;
 672                 }
 673         }
 674 }
 675
 676 .float muted; // to be used by prvm_edictset server playernumber muted 1
 677 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 678 // message "": do not say, just test flood control
 679 // return value:
 680 //   1 = accept
 681 //   0 = reject
 682 //  -1 = fake accept
 683 {
 684         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 685         float flood;
 686         var .float flood_field;
 687         entity head;
 688         float ret;
 689         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 690
 691         if(!teamsay && !privatesay)
 692                 if(substring(msgin, 0, 1) == " ")
 693                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 694
 695         msgin = formatmessage(msgin);
 696
 697         if not(IS_PLAYER(source))
 698                 colorstr = "^0"; // black for spectators
 699         else if(teamplay)
 700                 colorstr = Team_ColorCode(source.team);
 701         else
 702         {
 703                 colorstr = "";
 704                 teamsay = FALSE;
 705         }
 706
 707         if(intermission_running)
 708                 teamsay = FALSE;
 709
 710         if(msgin != "")
 711                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 712
 713         /*
 714          * using bprint solves this... me stupid
 715         // how can we prevent the message from appearing in a listen server?
 716         // for now, just give "say" back and only handle say_team
 717         if(!teamsay)
 718         {
 719                 clientcommand(self, strcat("say ", msgin));
 720                 return;
 721         }
 722         */
 723
 724         if(autocvar_g_chat_teamcolors)
 725                 namestr = playername(source);
 726         else
 727                 namestr = source.netname;
 728
 729         if(msgin != "")
 730         {
 731                 if(privatesay)
 732                 {
 733                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 734                         privatemsgprefixlen = strlen(msgstr);
 735                         msgstr = strcat(msgstr, msgin);
 736                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 737                         if(autocvar_g_chat_teamcolors)
 738                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 739                         else
 740                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 741                 }
 742                 else if(teamsay)
 743                 {
 744                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 745                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 746                 }
 747                 else
 748                 {
 749                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 750                         cmsgstr = "";
 751                 }
 752                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 753         }
 754         else
 755         {
 756                 msgstr = cmsgstr = "";
 757         }
 758
 759         fullmsgstr = msgstr;
 760         fullcmsgstr = cmsgstr;
 761
 762         // FLOOD CONTROL
 763         flood = 0;
 764         flood_field = floodcontrol_chat;
 765         if(floodcontrol)
 766         {
 767                 float flood_spl;
 768                 float flood_burst;
 769                 float flood_lmax;
 770                 float lines;
 771                 if(privatesay)
 772                 {
 773                         flood_spl = autocvar_g_chat_flood_spl_tell;
 774                         flood_burst = autocvar_g_chat_flood_burst_tell;
 775                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 776                         flood_field = floodcontrol_chattell;
 777                 }
 778                 else if(teamsay)
 779                 {
 780                         flood_spl = autocvar_g_chat_flood_spl_team;
 781                         flood_burst = autocvar_g_chat_flood_burst_team;
 782                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 783                         flood_field = floodcontrol_chatteam;
 784                 }
 785                 else
 786                 {
 787                         flood_spl = autocvar_g_chat_flood_spl;
 788                         flood_burst = autocvar_g_chat_flood_burst;
 789                         flood_lmax = autocvar_g_chat_flood_lmax;
 790                         flood_field = floodcontrol_chat;
 791                 }
 792                 flood_burst = max(0, flood_burst - 1);
 793                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 794
 795                 // do flood control for the default line size
 796                 if(msgstr != "")
 797                 {
 798                         getWrappedLine_remaining = msgstr;
 799                         msgstr = "";
 800                         lines = 0;
 801                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 802                         {
 803                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 804                                 ++lines;
 805                         }
 806                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 807
 808                         if(getWrappedLine_remaining != "")
 809                         {
 810                                 msgstr = strcat(msgstr, "\n");
 811                                 flood = 2;
 812                         }
 813
 814                         if(time >= source.flood_field)
 815                         {
 816                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 817                         }
 818                         else
 819                         {
 820                                 flood = 1;
 821                                 msgstr = fullmsgstr;
 822                         }
 823                 }
 824                 else
 825                 {
 826                         if(time >= source.flood_field)
 827                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 828                         else
 829                                 flood = 1;
 830                 }
 831
 832                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 833                         source.flood_field = flood = 0;
 834         }
 835
 836         if(flood == 2) // cannot happen for empty msgstr
 837         {
 838                 if(autocvar_g_chat_flood_notify_flooder)
 839                 {
 840                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 841                         sourcecmsgstr = "";
 842                 }
 843                 else
 844                 {
 845                         sourcemsgstr = fullmsgstr;
 846                         sourcecmsgstr = fullcmsgstr;
 847                 }
 848                 cmsgstr = "";
 849         }
 850         else
 851         {
 852                 sourcemsgstr = msgstr;
 853                 sourcecmsgstr = cmsgstr;
 854         }
 855
 856         if(!privatesay)
 857         if not(IS_PLAYER(source))
 858         {
 859                 if not(intermission_running)
 860                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 861                                 teamsay = -1; // spectators
 862         }
 863
 864         if(flood)
 865                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 866
 867         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 868         if(privatesay)
 869                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 870
 871         if(source.muted)
 872         {
 873                 // always fake the message
 874                 ret = -1;
 875         }
 876         else if(flood == 1)
 877         {
 878                 if(autocvar_g_chat_flood_notify_flooder)
 879                 {
 880                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 881                         ret = 0;
 882                 }
 883                 else
 884                         ret = -1;
 885         }
 886         else
 887         {
 888                 ret = 1;
 889         }
 890
 891         if(sourcemsgstr != "" && ret != 0)
 892         {
 893                 if(ret < 0) // faked message, because the player is muted
 894                 {
 895                         sprint(source, sourcemsgstr);
 896                         if(sourcecmsgstr != "" && !privatesay)
 897                                 centerprint(source, sourcecmsgstr);
 898                 }
 899                 else if(privatesay) // private message, between 2 people only
 900                 {
 901                         sprint(source, sourcemsgstr);
 902                         sprint(privatesay, msgstr);
 903                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 904                         if(cmsgstr != "")
 905                                 centerprint(privatesay, cmsgstr);
 906                 }
 907                 else if(teamsay > 0) // team message, only sent to team mates
 908                 {
 909                         sprint(source, sourcemsgstr);
 910                         dedicated_print(msgstr); // send to server console too
 911                         if(sourcecmsgstr != "")
 912                                 centerprint(source, sourcecmsgstr);
 913                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 914                                 if(head != source)
 915                                 {
 916                                         sprint(head, msgstr);
 917                                         if(cmsgstr != "")
 918                                                 centerprint(head, cmsgstr);
 919                                 }
 920                 }
 921                 else if(teamsay < 0) // spectator message, only sent to spectators
 922                 {
 923                         sprint(source, sourcemsgstr);
 924                         dedicated_print(msgstr); // send to server console too
 925                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 926                                 if(head != source)
 927                                         sprint(head, msgstr);
 928                 }
 929                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 930                 {
 931                         sprint(source, sourcemsgstr);
 932                         dedicated_print(msgstr); // send to server console too
 933                         FOR_EACH_REALCLIENT(head)
 934                                 if(head != source)
 935                                         sprint(head, msgstr);
 936                 }
 937                 else
 938                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 939         }
 940
 941         return ret;
 942 }
 943
 944 float GetVoiceMessageVoiceType(string type)
 945 {
 946         if(type == "taunt")
 947                 return VOICETYPE_TAUNT;
 948         if(type == "teamshoot")
 949                 return VOICETYPE_LASTATTACKER;
 950         return VOICETYPE_TEAMRADIO;
 951 }
 952
 953 string allvoicesamples;
 954 .string GetVoiceMessageSampleField(string type)
 955 {
 956         GetPlayerSoundSampleField_notFound = 0;
 957         switch(type)
 958         {
 959 #define _VOICEMSG(m) case #m: return playersound_##m;
 960                 ALLVOICEMSGS
 961 #undef _VOICEMSG
 962         }
 963         GetPlayerSoundSampleField_notFound = 1;
 964         return playersound_taunt;
 965 }
 966
 967 .string GetPlayerSoundSampleField(string type)
 968 {
 969         GetPlayerSoundSampleField_notFound = 0;
 970         switch(type)
 971         {
 972 #define _VOICEMSG(m) case #m: return playersound_##m;
 973                 ALLPLAYERSOUNDS
 974 #undef _VOICEMSG
 975         }
 976         GetPlayerSoundSampleField_notFound = 1;
 977         return playersound_taunt;
 978 }
 979
 980 void PrecacheGlobalSound(string samplestring)
 981 {
 982         float n, i;
 983         tokenize_console(samplestring);
 984         n = stof(argv(1));
 985         if(n > 0)
 986         {
 987                 for(i = 1; i <= n; ++i)
 988                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 989         }
 990         else
 991         {
 992                 precache_sound(strcat(argv(0), ".wav"));
 993         }
 994 }
 995
 996 void PrecachePlayerSounds(string f)
 997 {
 998         float fh;
 999         string s;
1000         fh = fopen(f, FILE_READ);
1001         if(fh < 0)
1002                 return;
1003         while((s = fgets(fh)))
1004         {
1005                 if(tokenize_console(s) != 3)
1006                 {
1007                         dprint("Invalid sound info line: ", s, "\n");
1008                         continue;
1009                 }
1010                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1011         }
1012         fclose(fh);
1013
1014         if not(allvoicesamples)
1015         {
1016 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1017                 ALLVOICEMSGS
1018 #undef _VOICEMSG
1019                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1020         }
1021 }
1022
1023 void ClearPlayerSounds()
1024 {
1025 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1026         ALLPLAYERSOUNDS
1027         ALLVOICEMSGS
1028 #undef _VOICEMSG
1029 }
1030
1031 float LoadPlayerSounds(string f, float first)
1032 {
1033         float fh;
1034         string s;
1035         var .string field;
1036         fh = fopen(f, FILE_READ);
1037         if(fh < 0)
1038         {
1039                 dprint("Player sound file not found: ", f, "\n");
1040                 return 0;
1041         }
1042         while((s = fgets(fh)))
1043         {
1044                 if(tokenize_console(s) != 3)
1045                         continue;
1046                 field = GetPlayerSoundSampleField(argv(0));
1047                 if(GetPlayerSoundSampleField_notFound)
1048                         field = GetVoiceMessageSampleField(argv(0));
1049                 if(GetPlayerSoundSampleField_notFound)
1050                         continue;
1051                 if(self.field)
1052                         strunzone(self.field);
1053                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1054         }
1055         fclose(fh);
1056         return 1;
1057 }
1058
1059 .float modelindex_for_playersound;
1060 .float skin_for_playersound;
1061 void UpdatePlayerSounds()
1062 {
1063         if(self.modelindex == self.modelindex_for_playersound)
1064         if(self.skin == self.skin_for_playersound)
1065                 return;
1066         self.modelindex_for_playersound = self.modelindex;
1067         self.skin_for_playersound = self.skin;
1068         ClearPlayerSounds();
1069         LoadPlayerSounds("sound/player/default.sounds", 1);
1070         if(!autocvar_g_debug_defaultsounds)
1071                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1072                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1073 }
1074
1075 void FakeGlobalSound(string sample, float chan, float voicetype)
1076 {
1077         float n;
1078         float tauntrand;
1079
1080         if(sample == "")
1081                 return;
1082
1083         tokenize_console(sample);
1084         n = stof(argv(1));
1085         if(n > 0)
1086                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1087         else
1088                 sample = strcat(argv(0), ".wav"); // randomization
1089
1090         switch(voicetype)
1091         {
1092                 case VOICETYPE_LASTATTACKER_ONLY:
1093                         break;
1094                 case VOICETYPE_LASTATTACKER:
1095                         if(self.pusher)
1096                         {
1097                                 msg_entity = self;
1098                                 if(IS_REAL_CLIENT(msg_entity))
1099                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1100                         }
1101                         break;
1102                 case VOICETYPE_TEAMRADIO:
1103                         msg_entity = self;
1104                         if(msg_entity.cvar_cl_voice_directional == 1)
1105                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1106                         else
1107                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1108                         break;
1109                 case VOICETYPE_AUTOTAUNT:
1110                         if(!sv_autotaunt)
1111                                 break;
1112                         if(!sv_taunt)
1113                                 break;
1114                         if(autocvar_sv_gentle)
1115                                 break;
1116                         tauntrand = random();
1117                         msg_entity = self;
1118                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1119                         {
1120                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1121                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1122                                 else
1123                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1124                         }
1125                         break;
1126                 case VOICETYPE_TAUNT:
1127                         if(IS_PLAYER(self))
1128                                 if(self.deadflag == DEAD_NO)
1129                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1130                         if(!sv_taunt)
1131                                 break;
1132                         if(autocvar_sv_gentle)
1133                                 break;
1134                         msg_entity = self;
1135                         if (msg_entity.cvar_cl_voice_directional >= 1)
1136                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1137                         else
1138                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1139                         break;
1140                 case VOICETYPE_PLAYERSOUND:
1141                         msg_entity = self;
1142                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1143                         break;
1144                 default:
1145                         backtrace("Invalid voice type!");
1146                         break;
1147         }
1148 }
1149
1150 void GlobalSound(string sample, float chan, float voicetype)
1151 {
1152         float n;
1153         float tauntrand;
1154
1155         if(sample == "")
1156                 return;
1157
1158         tokenize_console(sample);
1159         n = stof(argv(1));
1160         if(n > 0)
1161                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1162         else
1163                 sample = strcat(argv(0), ".wav"); // randomization
1164
1165         switch(voicetype)
1166         {
1167                 case VOICETYPE_LASTATTACKER_ONLY:
1168                         if(self.pusher)
1169                         {
1170                                 msg_entity = self.pusher;
1171                                 if(IS_REAL_CLIENT(msg_entity))
1172                                 {
1173                                         if(msg_entity.cvar_cl_voice_directional == 1)
1174                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1175                                         else
1176                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1177                                 }
1178                         }
1179                         break;
1180                 case VOICETYPE_LASTATTACKER:
1181                         if(self.pusher)
1182                         {
1183                                 msg_entity = self.pusher;
1184                                 if(IS_REAL_CLIENT(msg_entity))
1185                                 {
1186                                         if(msg_entity.cvar_cl_voice_directional == 1)
1187                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1188                                         else
1189                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1190                                 }
1191                                 msg_entity = self;
1192                                 if(IS_REAL_CLIENT(msg_entity))
1193                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1194                         }
1195                         break;
1196                 case VOICETYPE_TEAMRADIO:
1197                         FOR_EACH_REALCLIENT(msg_entity)
1198                                 if(!teamplay || msg_entity.team == self.team)
1199                                 {
1200                                         if(msg_entity.cvar_cl_voice_directional == 1)
1201                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1202                                         else
1203                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1204                                 }
1205                         break;
1206                 case VOICETYPE_AUTOTAUNT:
1207                         if(!sv_autotaunt)
1208                                 break;
1209                         if(!sv_taunt)
1210                                 break;
1211                         if(autocvar_sv_gentle)
1212                                 break;
1213                         tauntrand = random();
1214                         FOR_EACH_REALCLIENT(msg_entity)
1215                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1216                                 {
1217                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1218                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1219                                         else
1220                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1221                                 }
1222                         break;
1223                 case VOICETYPE_TAUNT:
1224                         if(IS_PLAYER(self))
1225                                 if(self.deadflag == DEAD_NO)
1226                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1227                         if(!sv_taunt)
1228                                 break;
1229                         if(autocvar_sv_gentle)
1230                                 break;
1231                         FOR_EACH_REALCLIENT(msg_entity)
1232                         {
1233                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1234                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1235                                 else
1236                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1237                         }
1238                         break;
1239                 case VOICETYPE_PLAYERSOUND:
1240                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1241                         break;
1242                 default:
1243                         backtrace("Invalid voice type!");
1244                         break;
1245         }
1246 }
1247
1248 void PlayerSound(.string samplefield, float chan, float voicetype)
1249 {
1250         GlobalSound(self.samplefield, chan, voicetype);
1251 }
1252
1253 void VoiceMessage(string type, string msg)
1254 {
1255         var .string sample;
1256         float voicetype, ownteam;
1257         float flood;
1258         sample = GetVoiceMessageSampleField(type);
1259
1260         if(GetPlayerSoundSampleField_notFound)
1261         {
1262                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1263                 return;
1264         }
1265
1266         voicetype = GetVoiceMessageVoiceType(type);
1267         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1268
1269         flood = Say(self, ownteam, world, msg, 1);
1270
1271         if (flood > 0)
1272                 GlobalSound(self.sample, CH_VOICE, voicetype);
1273         else if (flood < 0)
1274                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1275 }
1276
1277 void MoveToTeam(entity client, float team_colour, float type)
1278 {
1279         float lockteams_backup;
1280
1281         lockteams_backup = lockteams;  // backup any team lock
1282
1283         lockteams = 0;  // disable locked teams
1284
1285         TeamchangeFrags(client);  // move the players frags
1286         SetPlayerColors(client, team_colour - 1);  // set the players colour
1287         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1288
1289         lockteams = lockteams_backup;  // restore the team lock
1290
1291         LogTeamchange(client.playerid, client.team, type);
1292 }