qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_pinata)
 266         {
 267                 float j;
 268                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 269                 {
 270                         if(WEPSET_CONTAINS_EW(self, j))
 271                                 if(W_IsWeaponThrowable(j))
 272                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 273                 }
 274         }
 275         else
 276         {
 277                 if(WEPSET_CONTAINS_EW(self, self.weapon))
 278                         if(W_IsWeaponThrowable(self.weapon))
 279                                 W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 280         }
 281 }
 282
 283 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 284 {
 285         float take, save;
 286         vector v;
 287         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 288
 289         // damage resistance (ignore most of the damage from a bullet or similar)
 290         damage = max(damage - 5, 1);
 291
 292         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 293         take = v_x;
 294         save = v_y;
 295
 296         if(sound_allowed(MSG_BROADCAST, attacker))
 297         {
 298                 if (save > 10)
 299                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 300                 else if (take > 30)
 301                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 302                 else if (take > 10)
 303                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 304         }
 305
 306         if (take > 50)
 307                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 308         if (take > 100)
 309                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 310
 311         if (!(self.flags & FL_GODMODE))
 312         {
 313                 self.armorvalue = self.armorvalue - save;
 314                 self.health = self.health - take;
 315                 // pause regeneration for 5 seconds
 316                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 317         }
 318         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 319         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 320         self.dmg_inflictor = inflictor;
 321
 322         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 323         {
 324                 // don't use any animations as a gib
 325                 self.frame = 0;
 326                 // view just above the floor
 327                 self.view_ofs = '0 0 4';
 328
 329                 Violence_GibSplash(self, 1, 1, attacker);
 330                 self.alpha = -1;
 331                 self.solid = SOLID_NOT; // restore later
 332                 self.takedamage = DAMAGE_NO; // restore later
 333                 self.damagedbycontents = FALSE;
 334         }
 335 }
 336
 337 void ClientKill_Now_TeamChange();
 338
 339 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 340 {
 341         float take, save, waves, sdelay, dh, da, j;
 342         vector v;
 343         float valid_damage_for_weaponstats;
 344         float excess;
 345
 346         dh = max(self.health, 0);
 347         da = max(self.armorvalue, 0);
 348
 349         if(!DEATH_ISSPECIAL(deathtype))
 350         {
 351                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 352                 if(self != attacker)
 353                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 354         }
 355
 356         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 357         {
 358                 // tuba causes blood to come out of the ears
 359                 vector ear1, ear2;
 360                 vector d;
 361                 float f;
 362                 ear1 = self.origin;
 363                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 364                 ear2 = ear1;
 365                 makevectors(self.angles);
 366                 ear1 += v_right * -10;
 367                 ear2 += v_right * +10;
 368                 d = inflictor.origin - self.origin;
 369                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 370                 force = v_right * vlen(force);
 371                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 372                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 373                 if(f > 0)
 374                 {
 375                         hitloc = ear1;
 376                         force = force * -1;
 377                 }
 378                 else
 379                 {
 380                         hitloc = ear2;
 381                         // force is already good
 382                 }
 383         }
 384         else
 385                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 386
 387
 388         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 389         take = v_x;
 390         save = v_y;
 391
 392         if(attacker == self)
 393         {
 394                 // don't reset pushltime for self damage as it may be an attempt to
 395                 // escape a lava pit or similar
 396                 //self.pushltime = 0;
 397                 self.istypefrag = 0;
 398         }
 399         else if(IS_PLAYER(attacker))
 400         {
 401                 self.pusher = attacker;
 402                 self.pushltime = time + autocvar_g_maxpushtime;
 403                 self.istypefrag = self.BUTTON_CHAT;
 404         }
 405         else if(time < self.pushltime)
 406         {
 407                 attacker = self.pusher;
 408                 self.pushltime = max(self.pushltime, time + 0.6);
 409         }
 410         else
 411         {
 412                 self.pushltime = 0;
 413                 self.istypefrag = 0;
 414         }
 415
 416         frag_inflictor = inflictor;
 417         frag_attacker = attacker;
 418         frag_target = self;
 419         damage_take = take;
 420         damage_save = save;
 421         damage_force = force;
 422         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 423         take = bound(0, damage_take, self.health);
 424         save = bound(0, damage_save, self.armorvalue);
 425         excess = max(0, damage - take - save);
 426
 427         if(sound_allowed(MSG_BROADCAST, attacker))
 428         {
 429                 if (save > 10)
 430                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 431                 else if (take > 30)
 432                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 433                 else if (take > 10)
 434                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 435         }
 436
 437         if (take > 50)
 438                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 439         if (take > 100)
 440                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 441
 442         if (time >= self.spawnshieldtime)
 443         {
 444                 if (!(self.flags & FL_GODMODE))
 445                 {
 446                         self.armorvalue = self.armorvalue - save;
 447                         self.health = self.health - take;
 448                         // pause regeneration for 5 seconds
 449                         if(take)
 450                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 451
 452                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 453                         {
 454                                 self.pain_finished = time + 0.5;        //Supajoe
 455
 456                                 if(autocvar_sv_gentle < 1) {
 457                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 458                                         {
 459                                                 if (!self.animstate_override)
 460                                                 {
 461                                                         if (random() > 0.5)
 462                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 463                                                         else
 464                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 465                                                 }
 466                                         }
 467
 468                                         if(sound_allowed(MSG_BROADCAST, attacker))
 469                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 470                                         if(self.health > 1)
 471                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 472                                         {
 473                                                 if(deathtype == DEATH_FALL)
 474                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 475                                                 else if(self.health > 75) // TODO make a "gentle" version?
 476                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 477                                                 else if(self.health > 50)
 478                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 479                                                 else if(self.health > 25)
 480                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 481                                                 else
 482                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 483                                         }
 484                                 }
 485
 486                                 // throw off bot aim temporarily
 487                                 float shake;
 488                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 489                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 490                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 491                         }
 492                 }
 493                 else
 494                         self.max_armorvalue += (save + take);
 495         }
 496         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 497         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 498         self.dmg_inflictor = inflictor;
 499
 500         if(g_ca && self != attacker && IS_PLAYER(attacker))
 501                 PlayerTeamScore_Add(attacker, SP_SCORE, ST_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 502
 503         float abot, vbot, awep;
 504         abot = (IS_BOT_CLIENT(attacker));
 505         vbot = (IS_BOT_CLIENT(self));
 506
 507         valid_damage_for_weaponstats = 0;
 508         awep = 0;
 509
 510         if(vbot || IS_REAL_CLIENT(self))
 511         if(abot || IS_REAL_CLIENT(attacker))
 512         if(attacker && self != attacker)
 513         if(IsDifferentTeam(self, attacker))
 514         {
 515                 if(DEATH_ISSPECIAL(deathtype))
 516                         awep = attacker.weapon;
 517                 else
 518                         awep = DEATH_WEAPONOF(deathtype);
 519                 valid_damage_for_weaponstats = 1;
 520         }
 521
 522         if(valid_damage_for_weaponstats)
 523         {
 524                 dh = dh - max(self.health, 0);
 525                 da = da - max(self.armorvalue, 0);
 526                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 527         }
 528
 529         if (self.health < 1)
 530         {
 531                 float defer_ClientKill_Now_TeamChange;
 532                 defer_ClientKill_Now_TeamChange = FALSE;
 533
 534                 if(self.alivetime)
 535                 {
 536                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 537                         self.alivetime = 0;
 538                 }
 539
 540                 if(valid_damage_for_weaponstats)
 541                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 542
 543                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 544                 if(sound_allowed(MSG_BROADCAST, attacker))
 545                 {
 546                         if(deathtype == DEATH_DROWN)
 547                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 548                         else
 549                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 550                 }
 551
 552                 // get rid of kill indicator
 553                 if(self.killindicator)
 554                 {
 555                         remove(self.killindicator);
 556                         self.killindicator = world;
 557                         if(self.killindicator_teamchange)
 558                                 defer_ClientKill_Now_TeamChange = TRUE;
 559
 560                         if(self.classname == "body")
 561                         if(deathtype == DEATH_KILL)
 562                         {
 563                                 // for the lemmings fans, a small harmless explosion
 564                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 565                         }
 566                 }
 567
 568                 // print an obituary message
 569                 Obituary (attacker, inflictor, self, deathtype);
 570                 race_PreDie();
 571
 572         // increment frag counter for used weapon type
 573         float w;
 574         w = DEATH_WEAPONOF(deathtype);
 575         if(WEP_VALID(w))
 576         if(accuracy_isgooddamage(attacker, self))
 577         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 578
 579                 frag_attacker = attacker;
 580                 frag_inflictor = inflictor;
 581                 frag_target = self;
 582                 frag_deathtype = deathtype;
 583                 MUTATOR_CALLHOOK(PlayerDies);
 584
 585                 weapon_action(self.weapon, WR_PLAYERDEATH);
 586
 587                 RemoveGrapplingHook(self);
 588
 589                 Portal_ClearAllLater(self);
 590
 591                 if(IS_REAL_CLIENT(self))
 592                 {
 593                         self.fixangle = TRUE;
 594                         //msg_entity = self;
 595                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 596                         //WriteAngle (MSG_ONE, self.v_angle_x);
 597                         //WriteAngle (MSG_ONE, self.v_angle_y);
 598                         //WriteAngle (MSG_ONE, 80);
 599                 }
 600
 601                 if(defer_ClientKill_Now_TeamChange)
 602                         ClientKill_Now_TeamChange(); // can turn player into spectator
 603
 604                 // player could have been miraculously resuscitated ;)
 605                 // e.g. players in freezetag get frozen, they don't really die
 606                 if(self.health >= 1 || !IS_PLAYER(self))
 607                         return;
 608
 609                 // when we get here, player actually dies
 610
 611                 // clear waypoints
 612                 WaypointSprite_PlayerDead();
 613                 // throw a weapon
 614                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 615
 616                 // become fully visible
 617                 self.alpha = default_player_alpha;
 618                 // make the corpse upright (not tilted)
 619                 self.angles_x = 0;
 620                 self.angles_z = 0;
 621                 // don't spin
 622                 self.avelocity = '0 0 0';
 623                 // view from the floor
 624                 self.view_ofs = '0 0 -8';
 625                 // toss the corpse
 626                 self.movetype = MOVETYPE_TOSS;
 627                 // shootable corpse
 628                 self.solid = SOLID_CORPSE;
 629                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 630                 // don't stick to the floor
 631                 self.flags &~= FL_ONGROUND;
 632                 // dying animation
 633                 self.deadflag = DEAD_DYING;
 634                 // when to allow respawn
 635                 sdelay = 0;
 636                 waves = 0;
 637                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 638                 if(!sdelay)
 639                 {
 640                         if(g_cts)
 641                                 sdelay = 0; // no respawn delay in CTS
 642                         else
 643                                 sdelay = autocvar_g_respawn_delay;
 644                 }
 645                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 646                 if(!waves)
 647                         waves = autocvar_g_respawn_waves;
 648                 if(waves)
 649                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 650                 else
 651                         self.respawn_time = time + sdelay;
 652                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 653                         self.respawn_countdown = 10; // first number to count down from is 10
 654                 else
 655                         self.respawn_countdown = -1; // do not count down
 656
 657                 if(g_cts || autocvar_g_forced_respawn)
 658                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 659
 660                 self.death_time = time;
 661                 if (random() < 0.5)
 662                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 663                 else
 664                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 665                 if (self.maxs_z > 5)
 666                 {
 667                         self.maxs_z = 5;
 668                         setsize(self, self.mins, self.maxs);
 669                 }
 670                 // set damage function to corpse damage
 671                 self.event_damage = PlayerCorpseDamage;
 672                 // call the corpse damage function just in case it wants to gib
 673                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 674                 // set up to fade out later
 675                 SUB_SetFade (self, time + 6 + random (), 1);
 676
 677                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 678                         // remove corpse
 679                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 680                 }
 681
 682                 // reset fields the weapons may use just in case
 683                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 684                 {
 685                         weapon_action(j, WR_RESETPLAYER);
 686                         ATTACK_FINISHED_FOR(self, j) = 0;
 687                 }
 688         }
 689 }
 690
 691 .float muted; // to be used by prvm_edictset server playernumber muted 1
 692 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 693 // message "": do not say, just test flood control
 694 // return value:
 695 //   1 = accept
 696 //   0 = reject
 697 //  -1 = fake accept
 698 {
 699         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 700         float flood;
 701         var .float flood_field;
 702         entity head;
 703         float ret;
 704         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 705
 706         if(!teamsay && !privatesay)
 707                 if(substring(msgin, 0, 1) == " ")
 708                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 709
 710         msgin = formatmessage(msgin);
 711
 712         if not(IS_PLAYER(source))
 713                 colorstr = "^0"; // black for spectators
 714         else if(teamplay)
 715                 colorstr = Team_ColorCode(source.team);
 716         else
 717         {
 718                 colorstr = "";
 719                 teamsay = FALSE;
 720         }
 721
 722         if(intermission_running)
 723                 teamsay = FALSE;
 724
 725         if(msgin != "")
 726                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 727
 728         /*
 729          * using bprint solves this... me stupid
 730         // how can we prevent the message from appearing in a listen server?
 731         // for now, just give "say" back and only handle say_team
 732         if(!teamsay)
 733         {
 734                 clientcommand(self, strcat("say ", msgin));
 735                 return;
 736         }
 737         */
 738
 739         if(autocvar_g_chat_teamcolors)
 740                 namestr = playername(source);
 741         else
 742                 namestr = source.netname;
 743
 744         if(msgin != "")
 745         {
 746                 if(privatesay)
 747                 {
 748                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 749                         privatemsgprefixlen = strlen(msgstr);
 750                         msgstr = strcat(msgstr, msgin);
 751                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 752                         if(autocvar_g_chat_teamcolors)
 753                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 754                         else
 755                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 756                 }
 757                 else if(teamsay)
 758                 {
 759                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 760                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 761                 }
 762                 else
 763                 {
 764                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 765                         cmsgstr = "";
 766                 }
 767                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 768         }
 769         else
 770         {
 771                 msgstr = cmsgstr = "";
 772         }
 773
 774         fullmsgstr = msgstr;
 775         fullcmsgstr = cmsgstr;
 776
 777         // FLOOD CONTROL
 778         flood = 0;
 779         flood_field = floodcontrol_chat;
 780         if(floodcontrol)
 781         {
 782                 float flood_spl;
 783                 float flood_burst;
 784                 float flood_lmax;
 785                 float lines;
 786                 if(privatesay)
 787                 {
 788                         flood_spl = autocvar_g_chat_flood_spl_tell;
 789                         flood_burst = autocvar_g_chat_flood_burst_tell;
 790                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 791                         flood_field = floodcontrol_chattell;
 792                 }
 793                 else if(teamsay)
 794                 {
 795                         flood_spl = autocvar_g_chat_flood_spl_team;
 796                         flood_burst = autocvar_g_chat_flood_burst_team;
 797                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 798                         flood_field = floodcontrol_chatteam;
 799                 }
 800                 else
 801                 {
 802                         flood_spl = autocvar_g_chat_flood_spl;
 803                         flood_burst = autocvar_g_chat_flood_burst;
 804                         flood_lmax = autocvar_g_chat_flood_lmax;
 805                         flood_field = floodcontrol_chat;
 806                 }
 807                 flood_burst = max(0, flood_burst - 1);
 808                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 809
 810                 // do flood control for the default line size
 811                 if(msgstr != "")
 812                 {
 813                         getWrappedLine_remaining = msgstr;
 814                         msgstr = "";
 815                         lines = 0;
 816                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 817                         {
 818                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 819                                 ++lines;
 820                         }
 821                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 822
 823                         if(getWrappedLine_remaining != "")
 824                         {
 825                                 msgstr = strcat(msgstr, "\n");
 826                                 flood = 2;
 827                         }
 828
 829                         if(time >= source.flood_field)
 830                         {
 831                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 832                         }
 833                         else
 834                         {
 835                                 flood = 1;
 836                                 msgstr = fullmsgstr;
 837                         }
 838                 }
 839                 else
 840                 {
 841                         if(time >= source.flood_field)
 842                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 843                         else
 844                                 flood = 1;
 845                 }
 846
 847                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 848                         source.flood_field = flood = 0;
 849         }
 850
 851         if(flood == 2) // cannot happen for empty msgstr
 852         {
 853                 if(autocvar_g_chat_flood_notify_flooder)
 854                 {
 855                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 856                         sourcecmsgstr = "";
 857                 }
 858                 else
 859                 {
 860                         sourcemsgstr = fullmsgstr;
 861                         sourcecmsgstr = fullcmsgstr;
 862                 }
 863                 cmsgstr = "";
 864         }
 865         else
 866         {
 867                 sourcemsgstr = msgstr;
 868                 sourcecmsgstr = cmsgstr;
 869         }
 870
 871         if(!privatesay)
 872         if not(IS_PLAYER(source))
 873         {
 874                 if not(intermission_running)
 875                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 876                                 teamsay = -1; // spectators
 877         }
 878
 879         if(flood)
 880                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 881
 882         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 883         if(privatesay)
 884                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 885
 886         if(source.muted)
 887         {
 888                 // always fake the message
 889                 ret = -1;
 890         }
 891         else if(flood == 1)
 892         {
 893                 if(autocvar_g_chat_flood_notify_flooder)
 894                 {
 895                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 896                         ret = 0;
 897                 }
 898                 else
 899                         ret = -1;
 900         }
 901         else
 902         {
 903                 ret = 1;
 904         }
 905
 906         if(sourcemsgstr != "" && ret != 0)
 907         {
 908                 if(ret < 0) // faked message, because the player is muted
 909                 {
 910                         sprint(source, sourcemsgstr);
 911                         if(sourcecmsgstr != "" && !privatesay)
 912                                 centerprint(source, sourcecmsgstr);
 913                 }
 914                 else if(privatesay) // private message, between 2 people only
 915                 {
 916                         sprint(source, sourcemsgstr);
 917                         sprint(privatesay, msgstr);
 918                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 919                         if(cmsgstr != "")
 920                                 centerprint(privatesay, cmsgstr);
 921                 }
 922                 else if(teamsay > 0) // team message, only sent to team mates
 923                 {
 924                         sprint(source, sourcemsgstr);
 925                         dedicated_print(msgstr); // send to server console too
 926                         if(sourcecmsgstr != "")
 927                                 centerprint(source, sourcecmsgstr);
 928                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 929                                 if(head != source)
 930                                 {
 931                                         sprint(head, msgstr);
 932                                         if(cmsgstr != "")
 933                                                 centerprint(head, cmsgstr);
 934                                 }
 935                 }
 936                 else if(teamsay < 0) // spectator message, only sent to spectators
 937                 {
 938                         sprint(source, sourcemsgstr);
 939                         dedicated_print(msgstr); // send to server console too
 940                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 941                                 if(head != source)
 942                                         sprint(head, msgstr);
 943                 }
 944                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 945                 {
 946                         sprint(source, sourcemsgstr);
 947                         dedicated_print(msgstr); // send to server console too
 948                         FOR_EACH_REALCLIENT(head)
 949                                 if(head != source)
 950                                         sprint(head, msgstr);
 951                 }
 952                 else
 953                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 954         }
 955
 956         return ret;
 957 }
 958
 959 float GetVoiceMessageVoiceType(string type)
 960 {
 961         if(type == "taunt")
 962                 return VOICETYPE_TAUNT;
 963         if(type == "teamshoot")
 964                 return VOICETYPE_LASTATTACKER;
 965         return VOICETYPE_TEAMRADIO;
 966 }
 967
 968 string allvoicesamples;
 969 .string GetVoiceMessageSampleField(string type)
 970 {
 971         GetPlayerSoundSampleField_notFound = 0;
 972         switch(type)
 973         {
 974 #define _VOICEMSG(m) case #m: return playersound_##m;
 975                 ALLVOICEMSGS
 976 #undef _VOICEMSG
 977         }
 978         GetPlayerSoundSampleField_notFound = 1;
 979         return playersound_taunt;
 980 }
 981
 982 .string GetPlayerSoundSampleField(string type)
 983 {
 984         GetPlayerSoundSampleField_notFound = 0;
 985         switch(type)
 986         {
 987 #define _VOICEMSG(m) case #m: return playersound_##m;
 988                 ALLPLAYERSOUNDS
 989 #undef _VOICEMSG
 990         }
 991         GetPlayerSoundSampleField_notFound = 1;
 992         return playersound_taunt;
 993 }
 994
 995 void PrecacheGlobalSound(string samplestring)
 996 {
 997         float n, i;
 998         tokenize_console(samplestring);
 999         n = stof(argv(1));
1000         if(n > 0)
1001         {
1002                 for(i = 1; i <= n; ++i)
1003                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1004         }
1005         else
1006         {
1007                 precache_sound(strcat(argv(0), ".wav"));
1008         }
1009 }
1010
1011 void PrecachePlayerSounds(string f)
1012 {
1013         float fh;
1014         string s;
1015         fh = fopen(f, FILE_READ);
1016         if(fh < 0)
1017                 return;
1018         while((s = fgets(fh)))
1019         {
1020                 if(tokenize_console(s) != 3)
1021                 {
1022                         dprint("Invalid sound info line: ", s, "\n");
1023                         continue;
1024                 }
1025                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1026         }
1027         fclose(fh);
1028
1029         if not(allvoicesamples)
1030         {
1031 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1032                 ALLVOICEMSGS
1033 #undef _VOICEMSG
1034                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1035         }
1036 }
1037
1038 void ClearPlayerSounds()
1039 {
1040 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1041         ALLPLAYERSOUNDS
1042         ALLVOICEMSGS
1043 #undef _VOICEMSG
1044 }
1045
1046 float LoadPlayerSounds(string f, float first)
1047 {
1048         float fh;
1049         string s;
1050         var .string field;
1051         fh = fopen(f, FILE_READ);
1052         if(fh < 0)
1053         {
1054                 dprint("Player sound file not found: ", f, "\n");
1055                 return 0;
1056         }
1057         while((s = fgets(fh)))
1058         {
1059                 if(tokenize_console(s) != 3)
1060                         continue;
1061                 field = GetPlayerSoundSampleField(argv(0));
1062                 if(GetPlayerSoundSampleField_notFound)
1063                         field = GetVoiceMessageSampleField(argv(0));
1064                 if(GetPlayerSoundSampleField_notFound)
1065                         continue;
1066                 if(self.field)
1067                         strunzone(self.field);
1068                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1069         }
1070         fclose(fh);
1071         return 1;
1072 }
1073
1074 .float modelindex_for_playersound;
1075 .float skin_for_playersound;
1076 void UpdatePlayerSounds()
1077 {
1078         if(self.modelindex == self.modelindex_for_playersound)
1079         if(self.skin == self.skin_for_playersound)
1080                 return;
1081         self.modelindex_for_playersound = self.modelindex;
1082         self.skin_for_playersound = self.skin;
1083         ClearPlayerSounds();
1084         LoadPlayerSounds("sound/player/default.sounds", 1);
1085         if(!autocvar_g_debug_defaultsounds)
1086                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1087                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1088 }
1089
1090 void FakeGlobalSound(string sample, float chan, float voicetype)
1091 {
1092         float n;
1093         float tauntrand;
1094
1095         if(sample == "")
1096                 return;
1097
1098         tokenize_console(sample);
1099         n = stof(argv(1));
1100         if(n > 0)
1101                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1102         else
1103                 sample = strcat(argv(0), ".wav"); // randomization
1104
1105         switch(voicetype)
1106         {
1107                 case VOICETYPE_LASTATTACKER_ONLY:
1108                         break;
1109                 case VOICETYPE_LASTATTACKER:
1110                         if(self.pusher)
1111                         {
1112                                 msg_entity = self;
1113                                 if(IS_REAL_CLIENT(msg_entity))
1114                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1115                         }
1116                         break;
1117                 case VOICETYPE_TEAMRADIO:
1118                         msg_entity = self;
1119                         if(msg_entity.cvar_cl_voice_directional == 1)
1120                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1121                         else
1122                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1123                         break;
1124                 case VOICETYPE_AUTOTAUNT:
1125                         if(!sv_autotaunt)
1126                                 break;
1127                         if(!sv_taunt)
1128                                 break;
1129                         if(autocvar_sv_gentle)
1130                                 break;
1131                         tauntrand = random();
1132                         msg_entity = self;
1133                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1134                         {
1135                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1136                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1137                                 else
1138                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1139                         }
1140                         break;
1141                 case VOICETYPE_TAUNT:
1142                         if(IS_PLAYER(self))
1143                                 if(self.deadflag == DEAD_NO)
1144                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1145                         if(!sv_taunt)
1146                                 break;
1147                         if(autocvar_sv_gentle)
1148                                 break;
1149                         msg_entity = self;
1150                         if (msg_entity.cvar_cl_voice_directional >= 1)
1151                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1152                         else
1153                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1154                         break;
1155                 case VOICETYPE_PLAYERSOUND:
1156                         msg_entity = self;
1157                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1158                         break;
1159                 default:
1160                         backtrace("Invalid voice type!");
1161                         break;
1162         }
1163 }
1164
1165 void GlobalSound(string sample, float chan, float voicetype)
1166 {
1167         float n;
1168         float tauntrand;
1169
1170         if(sample == "")
1171                 return;
1172
1173         tokenize_console(sample);
1174         n = stof(argv(1));
1175         if(n > 0)
1176                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1177         else
1178                 sample = strcat(argv(0), ".wav"); // randomization
1179
1180         switch(voicetype)
1181         {
1182                 case VOICETYPE_LASTATTACKER_ONLY:
1183                         if(self.pusher)
1184                         {
1185                                 msg_entity = self.pusher;
1186                                 if(IS_REAL_CLIENT(msg_entity))
1187                                 {
1188                                         if(msg_entity.cvar_cl_voice_directional == 1)
1189                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1190                                         else
1191                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1192                                 }
1193                         }
1194                         break;
1195                 case VOICETYPE_LASTATTACKER:
1196                         if(self.pusher)
1197                         {
1198                                 msg_entity = self.pusher;
1199                                 if(IS_REAL_CLIENT(msg_entity))
1200                                 {
1201                                         if(msg_entity.cvar_cl_voice_directional == 1)
1202                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1203                                         else
1204                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1205                                 }
1206                                 msg_entity = self;
1207                                 if(IS_REAL_CLIENT(msg_entity))
1208                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1209                         }
1210                         break;
1211                 case VOICETYPE_TEAMRADIO:
1212                         FOR_EACH_REALCLIENT(msg_entity)
1213                                 if(!teamplay || msg_entity.team == self.team)
1214                                 {
1215                                         if(msg_entity.cvar_cl_voice_directional == 1)
1216                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1217                                         else
1218                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1219                                 }
1220                         break;
1221                 case VOICETYPE_AUTOTAUNT:
1222                         if(!sv_autotaunt)
1223                                 break;
1224                         if(!sv_taunt)
1225                                 break;
1226                         if(autocvar_sv_gentle)
1227                                 break;
1228                         tauntrand = random();
1229                         FOR_EACH_REALCLIENT(msg_entity)
1230                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1231                                 {
1232                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1233                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1234                                         else
1235                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1236                                 }
1237                         break;
1238                 case VOICETYPE_TAUNT:
1239                         if(IS_PLAYER(self))
1240                                 if(self.deadflag == DEAD_NO)
1241                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1242                         if(!sv_taunt)
1243                                 break;
1244                         if(autocvar_sv_gentle)
1245                                 break;
1246                         FOR_EACH_REALCLIENT(msg_entity)
1247                         {
1248                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1249                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1250                                 else
1251                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1252                         }
1253                         break;
1254                 case VOICETYPE_PLAYERSOUND:
1255                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1256                         break;
1257                 default:
1258                         backtrace("Invalid voice type!");
1259                         break;
1260         }
1261 }
1262
1263 void PlayerSound(.string samplefield, float chan, float voicetype)
1264 {
1265         GlobalSound(self.samplefield, chan, voicetype);
1266 }
1267
1268 void VoiceMessage(string type, string msg)
1269 {
1270         var .string sample;
1271         float voicetype, ownteam;
1272         float flood;
1273         sample = GetVoiceMessageSampleField(type);
1274
1275         if(GetPlayerSoundSampleField_notFound)
1276         {
1277                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1278                 return;
1279         }
1280
1281         voicetype = GetVoiceMessageVoiceType(type);
1282         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1283
1284         flood = Say(self, ownteam, world, msg, 1);
1285
1286         if (flood > 0)
1287                 GlobalSound(self.sample, CH_VOICE, voicetype);
1288         else if (flood < 0)
1289                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1290 }
1291
1292 void MoveToTeam(entity client, float team_colour, float type)
1293 {
1294         float lockteams_backup;
1295
1296         lockteams_backup = lockteams;  // backup any team lock
1297
1298         lockteams = 0;  // disable locked teams
1299
1300         TeamchangeFrags(client);  // move the players frags
1301         SetPlayerColors(client, team_colour - 1);  // set the players colour
1302         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1303
1304         lockteams = lockteams_backup;  // restore the team lock
1305
1306         LogTeamchange(client.playerid, client.team, type);
1307 }