qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.playermodel, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389 void freezetag_CheckWinner();
 390
 391 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 392 {
 393         local float take, save, waves, sdelay, dh, da, j;
 394         vector v;
 395         float valid_damage_for_weaponstats;
 396
 397         dh = max(self.health, 0);
 398         da = max(self.armorvalue, 0);
 399
 400         if(!DEATH_ISSPECIAL(deathtype))
 401         {
 402                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 403                 if(self != attacker)
 404                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 405         }
 406
 407         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 408         {
 409                 // tuba causes blood to come out of the ears
 410                 vector ear1, ear2;
 411                 vector d;
 412                 float f;
 413                 ear1 = self.origin;
 414                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 415                 ear2 = ear1;
 416                 makevectors(self.angles);
 417                 ear1 += v_right * -10;
 418                 ear2 += v_right * +10;
 419                 d = inflictor.origin - self.origin;
 420                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 421                 force = v_right * vlen(force);
 422                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 423                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 424                 if(f > 0)
 425                 {
 426                         hitloc = ear1;
 427                         force = force * -1;
 428                 }
 429                 else
 430                 {
 431                         hitloc = ear2;
 432                         // force is already good
 433                 }
 434         }
 435         else
 436                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 437
 438         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 439                 return;
 440
 441         if (!g_minstagib)
 442         {
 443                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 444                 take = v_x;
 445                 save = v_y;
 446         }
 447         else
 448         {
 449                 save = 0;
 450                 take = damage;
 451         }
 452
 453         frag_inflictor = inflictor;
 454         frag_attacker = attacker;
 455         frag_target = self;
 456         damage_take = take;
 457         damage_save = save;
 458         damage_force = force;
 459         MUTATOR_CALLHOOK(PlayerDamage);
 460         take = bound(0, damage_take, self.health);
 461         save = bound(0, damage_save, self.armorvalue);
 462
 463         if(sound_allowed(MSG_BROADCAST, attacker))
 464         {
 465                 if (save > 10)
 466                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 467                 else if (take > 30)
 468                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 469                 else if (take > 10)
 470                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 471         }
 472
 473         if (take > 50)
 474                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 475         if (take > 100)
 476                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 477
 478         if (time >= self.spawnshieldtime)
 479         {
 480                 if (!(self.flags & FL_GODMODE))
 481                 {
 482                         self.armorvalue = self.armorvalue - save;
 483                         self.health = self.health - take;
 484                         // pause regeneration for 5 seconds
 485                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 486
 487                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 488                         {
 489                                 self.pain_finished = time + 0.5;        //Supajoe
 490
 491                                 if(sv_gentle < 1) {
 492                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 493                                         {
 494                                                 if (random() > 0.5)
 495                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 496                                                 else
 497                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 498                                         }
 499
 500                                         if(sound_allowed(MSG_BROADCAST, attacker))
 501                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 502                                         if(self.health > 1)
 503                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 504                                         {
 505                                                 if(deathtype == DEATH_FALL)
 506                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 507                                                 else if(self.health > 75) // TODO make a "gentle" version?
 508                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 509                                                 else if(self.health > 50)
 510                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 511                                                 else if(self.health > 25)
 512                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 513                                                 else
 514                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 515                                         }
 516                                 }
 517
 518                                 // throw off bot aim temporarily
 519                                 local float shake;
 520                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 521                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 522                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 523                         }
 524                 }
 525                 else
 526                         self.max_armorvalue += (save + take);
 527         }
 528         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 529         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 530         self.dmg_inflictor = inflictor;
 531
 532         if(attacker == self)
 533         {
 534                 // don't reset pushltime for self damage as it may be an attempt to
 535                 // escape a lava pit or similar
 536                 //self.pushltime = 0;
 537         }
 538         else if(attacker.classname == "player" || attacker.classname == "gib")
 539         {
 540                 self.pusher = attacker;
 541                 self.pushltime = time + cvar("g_maxpushtime");
 542         }
 543         else if(time < self.pushltime)
 544         {
 545                 attacker = self.pusher;
 546                 self.pushltime = max(self.pushltime, time + 0.6);
 547         }
 548         else
 549                 self.pushltime = 0;
 550
 551         valid_damage_for_weaponstats = 0;
 552         if(clienttype(self) == CLIENTTYPE_REAL)
 553         if(clienttype(attacker) == CLIENTTYPE_REAL)
 554         if(self != attacker)
 555         if(!DEATH_ISSPECIAL(deathtype))
 556         if(IsDifferentTeam(self, attacker))
 557                 valid_damage_for_weaponstats = 1;
 558
 559         if(valid_damage_for_weaponstats)
 560         {
 561                 dh = dh - max(self.health, 0);
 562                 da = da - max(self.armorvalue, 0);
 563                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 564         }
 565
 566         if (self.health < 1)
 567         {
 568                 float defer_ClientKill_Now_TeamChange;
 569                 defer_ClientKill_Now_TeamChange = FALSE;
 570
 571                 if(valid_damage_for_weaponstats)
 572                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 573
 574                 if(sv_gentle < 1) // TODO make a "gentle" version?
 575                 if(sound_allowed(MSG_BROADCAST, attacker))
 576                 {
 577                         if(deathtype == DEATH_DROWN)
 578                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 579                         else
 580                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 581                 }
 582
 583                 // get rid of kill indicator
 584                 if(self.killindicator)
 585                 {
 586                         remove(self.killindicator);
 587                         self.killindicator = world;
 588                         if(self.killindicator_teamchange)
 589                                 defer_ClientKill_Now_TeamChange = TRUE;
 590
 591                         if(self.classname == "body")
 592                         if(deathtype == DEATH_KILL)
 593                         {
 594                                 // for the lemmings fans, a small harmless explosion
 595                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 596                         }
 597                 }
 598
 599                 if(!g_freezetag)
 600                 {
 601                         // become fully visible
 602                         self.alpha = 1;
 603                         // clear selected player display
 604                         ClearSelectedPlayer();
 605                         // throw a weapon
 606                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 607                 }
 608
 609                 // print an obituary message
 610                 Obituary (attacker, inflictor, self, deathtype);
 611                 race_PreDie();
 612                 DropAllRunes(self);
 613
 614                 if(deathtype == DEATH_HURTTRIGGER)
 615                 {
 616                         PutClientInServer();
 617                         count_alive_players(); // re-count players
 618                         freezetag_CheckWinner();
 619                         return;
 620                 }
 621
 622                 frag_attacker = attacker;
 623                 frag_inflictor = inflictor;
 624                 frag_target = self;
 625                 MUTATOR_CALLHOOK(PlayerDies);
 626
 627                 if(g_freezetag)
 628                         return;
 629
 630                 if(self.flagcarried)
 631                 {
 632                         if(attacker.classname != "player" && attacker.classname != "gib")
 633                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 634                         else if(attacker.team == self.team)
 635                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 636                         else
 637                                 DropFlag(self.flagcarried, world, attacker);
 638                 }
 639                 if(self.ballcarried)
 640                         DropBall(self.ballcarried, self.origin, self.velocity);
 641                 Portal_ClearAllLater(self);
 642                 // clear waypoints
 643                 WaypointSprite_PlayerDead();
 644                 // make the corpse upright (not tilted)
 645                 self.angles_x = 0;
 646                 self.angles_z = 0;
 647                 // don't spin
 648                 self.avelocity = '0 0 0';
 649                 // view from the floor
 650                 self.view_ofs = '0 0 -8';
 651                 // toss the corpse
 652                 self.movetype = MOVETYPE_TOSS;
 653                 // shootable corpse
 654                 self.solid = SOLID_CORPSE;
 655                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 656                 // don't stick to the floor
 657                 self.flags &~= FL_ONGROUND;
 658                 // dying animation
 659                 self.deadflag = DEAD_DYING;
 660                 // when to allow respawn
 661                 sdelay = 0;
 662                 waves = 0;
 663                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 664                 if(!sdelay)
 665                         sdelay = cvar("g_respawn_delay");
 666                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 667                 if(!waves)
 668                         waves = cvar("g_respawn_waves");
 669                 if(waves)
 670                         self.death_time = ceil((time + sdelay) / waves) * waves;
 671                 else
 672                         self.death_time = time + sdelay;
 673                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 674                         self.respawn_countdown = 10; // first number to count down from is 10
 675                 else
 676                         self.respawn_countdown = -1; // do not count down
 677                 if (random() < 0.5)
 678                 {
 679                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 680                         self.dead_frame = self.anim_dead1_x;
 681                 }
 682                 else
 683                 {
 684                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 685                         self.dead_frame = self.anim_dead2_x;
 686                 }
 687                 // set damage function to corpse damage
 688                 self.event_damage = PlayerCorpseDamage;
 689                 // call the corpse damage function just in case it wants to gib
 690                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 691                 // set up to fade out later
 692                 SUB_SetFade (self, time + 6 + random (), 1);
 693
 694                 if(clienttype(self) == CLIENTTYPE_REAL)
 695                 {
 696                         self.fixangle = TRUE;
 697                         //msg_entity = self;
 698                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 699                         //WriteAngle (MSG_ONE, self.v_angle_x);
 700                         //WriteAngle (MSG_ONE, self.v_angle_y);
 701                         //WriteAngle (MSG_ONE, 80);
 702                 }
 703
 704                 if(g_arena)
 705                         Spawnqueue_Unmark(self);
 706
 707                 if(defer_ClientKill_Now_TeamChange)
 708                         ClientKill_Now_TeamChange();
 709
 710                 if(sv_gentle > 0 || cvar("ekg")) {
 711                         // remove corpse
 712                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 713                 }
 714
 715                 // reset fields the weapons may use just in case
 716         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 717                 {
 718             weapon_action(j, WR_RESETPLAYER);
 719                         ATTACK_FINISHED_FOR(self, j) = 0;
 720                 }
 721         }
 722 }
 723
 724 float UpdateSelectedPlayer_countvalue(float v)
 725 {
 726         return max(0, (v - 1.0) / 0.5);
 727 }
 728
 729 // returns: -2 if no hit, otherwise cos of the angle
 730 // uses the global v_angle
 731 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 732 {
 733         vector so, d;
 734         float c;
 735
 736         if(p == self)
 737                 return -2;
 738
 739         if(p.deadflag)
 740                 return -2;
 741
 742         so = self.origin + self.view_ofs;
 743         d = p.origin - so;
 744
 745         // misaimed?
 746         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 747                 return -2;
 748
 749         // now find the cos of the angle...
 750         c = normalize(d) * v_forward;
 751
 752         if(c <= mincosangle)
 753                 return -2;
 754
 755         // not visible in any way? forget it
 756         if(!checkpvs(so, p))
 757                 return -2;
 758
 759         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 760         if(trace_fraction < 1)
 761                 return -2;
 762
 763         return c;
 764 }
 765
 766 void ClearSelectedPlayer()
 767 {
 768         if(self.selected_player)
 769         {
 770                 centerprint_expire(self, CENTERPRIO_POINT);
 771                 self.selected_player = world;
 772                 self.selected_player_display_needs_update = FALSE;
 773         }
 774 }
 775
 776 void UpdateSelectedPlayer()
 777 {
 778         entity selected;
 779         float selected_score;
 780         selected = world;
 781         selected_score = 0.95; // 18 degrees
 782
 783         if(!cvar("sv_allow_shownames"))
 784                 return;
 785
 786         if(clienttype(self) != CLIENTTYPE_REAL)
 787                 return;
 788
 789         if(self.cvar_cl_shownames == 0)
 790                 return;
 791
 792         if(self.cvar_cl_shownames == 1 && !teams_matter)
 793                 return;
 794
 795         makevectors(self.v_angle); // sets v_forward
 796
 797         // 1. cursor trace is always right
 798         WarpZone_crosshair_trace(self);
 799         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 800         {
 801                 selected = trace_ent;
 802         }
 803         else
 804         {
 805                 // 2. if we don't have a cursor trace, find the player which is least
 806                 //    mis-aimed at
 807                 entity p;
 808                 FOR_EACH_PLAYER(p)
 809                 {
 810                         float c;
 811                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 812                         if(c >= -1)
 813                         {
 814                                 selected = p;
 815                                 selected_score = c;
 816                         }
 817                 }
 818         }
 819
 820         if(selected)
 821         {
 822                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 823         }
 824         else
 825         {
 826                 if(time < self.selected_player_display_timeout)
 827                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 828                                 selected = self.selected_player;
 829         }
 830
 831         if(selected)
 832         {
 833                 if(selected == self.selected_player)
 834                 {
 835                         float save;
 836                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 837                         self.selected_player_count = self.selected_player_count + frametime;
 838                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 839                         {
 840                                 string namestr, healthstr;
 841                                 namestr = playername(selected);
 842                                 if(teams_matter)
 843                                 {
 844                                         healthstr = ftos(floor(selected.health));
 845                                         if(self.team == selected.team)
 846                                         {
 847                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 848                                                 self.selected_player_display_needs_update = TRUE;
 849                                         }
 850                                 }
 851                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 852                         }
 853                 }
 854                 else
 855                 {
 856                         ClearSelectedPlayer();
 857                         self.selected_player = selected;
 858                         self.selected_player_time = time;
 859                         self.selected_player_count = 0;
 860                         self.selected_player_display_needs_update = FALSE;
 861                 }
 862         }
 863         else
 864         {
 865                 ClearSelectedPlayer();
 866         }
 867
 868         if(self.selected_player)
 869                 self.last_selected_player = self.selected_player;
 870 }
 871
 872 .float muted; // to be used by prvm_edictset server playernumber muted 1
 873 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 874 // message "": do not say, just test flood control
 875 // return value:
 876 //   1 = accept
 877 //   0 = reject
 878 //  -1 = fake accept
 879 {
 880         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 881         float flood, privatemsgprefixlen;
 882         var .float flood_field;
 883         entity head;
 884         float ret;
 885
 886         if(Ban_MaybeEnforceBan(source))
 887                 return 0;
 888
 889         if(!teamsay && !privatesay)
 890                 if(substring(msgin, 0, 1) == " ")
 891                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 892
 893         msgin = formatmessage(msgin);
 894
 895         if(source.classname != "player")
 896                 colorstr = "^0"; // black for spectators
 897         else if(teams_matter)
 898                 colorstr = Team_ColorCode(source.team);
 899         else
 900                 teamsay = FALSE;
 901
 902         if(intermission_running)
 903                 teamsay = FALSE;
 904
 905         if(msgin != "")
 906                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 907
 908         /*
 909          * using bprint solves this... me stupid
 910         // how can we prevent the message from appearing in a listen server?
 911         // for now, just give "say" back and only handle say_team
 912         if(!teamsay)
 913         {
 914                 clientcommand(self, strcat("say ", msgin));
 915                 return;
 916         }
 917         */
 918
 919         if(cvar("g_chat_teamcolors"))
 920                 namestr = playername(source);
 921         else
 922                 namestr = source.netname;
 923
 924         if(msgin != "")
 925         {
 926                 if(privatesay)
 927                 {
 928                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 929                         privatemsgprefixlen = strlen(msgstr);
 930                         msgstr = strcat(msgstr, msgin);
 931                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 932                         if(cvar("g_chat_teamcolors"))
 933                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 934                         else
 935                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 936                 }
 937                 else if(teamsay)
 938                 {
 939                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 940                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 941                 }
 942                 else
 943                 {
 944                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 945                         cmsgstr = "";
 946                 }
 947                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 948         }
 949         else
 950         {
 951                 msgstr = cmsgstr = "";
 952         }
 953
 954         fullmsgstr = msgstr;
 955         fullcmsgstr = cmsgstr;
 956
 957         // FLOOD CONTROL
 958         flood = 0;
 959         if(floodcontrol)
 960         {
 961                 float flood_spl;
 962                 float flood_burst;
 963                 float flood_lmax;
 964                 float lines;
 965                 if(privatesay)
 966                 {
 967                         flood_spl = cvar("g_chat_flood_spl_tell");
 968                         flood_burst = cvar("g_chat_flood_burst_tell");
 969                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 970                         flood_field = floodcontrol_chattell;
 971                 }
 972                 else if(teamsay)
 973                 {
 974                         flood_spl = cvar("g_chat_flood_spl_team");
 975                         flood_burst = cvar("g_chat_flood_burst_team");
 976                         flood_lmax = cvar("g_chat_flood_lmax_team");
 977                         flood_field = floodcontrol_chatteam;
 978                 }
 979                 else
 980                 {
 981                         flood_spl = cvar("g_chat_flood_spl");
 982                         flood_burst = cvar("g_chat_flood_burst");
 983                         flood_lmax = cvar("g_chat_flood_lmax");
 984                         flood_field = floodcontrol_chat;
 985                 }
 986                 flood_burst = max(0, flood_burst - 1);
 987                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 988
 989                 // do flood control for the default line size
 990                 if(msgstr != "")
 991                 {
 992                         getWrappedLine_remaining = msgstr;
 993                         msgstr = "";
 994                         lines = 0;
 995                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 996                         {
 997                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 998                                 ++lines;
 999                         }
1000                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1001
1002                         if(getWrappedLine_remaining != "")
1003                         {
1004                                 msgstr = strcat(msgstr, "\n");
1005                                 flood = 2;
1006                         }
1007
1008                         if(time >= source.flood_field)
1009                         {
1010                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1011                         }
1012                         else
1013                         {
1014                                 flood = 1;
1015                                 msgstr = fullmsgstr;
1016                         }
1017                 }
1018                 else
1019                 {
1020                         if(time >= source.flood_field)
1021                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1022                         else
1023                                 flood = 1;
1024                 }
1025
1026                 if (timeoutStatus == 2) //when game is paused, no flood protection
1027                         source.flood_field = flood = 0;
1028         }
1029
1030         if(flood == 2) // cannot happen for empty msgstr
1031         {
1032                 if(cvar("g_chat_flood_notify_flooder"))
1033                 {
1034                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1035                         sourcecmsgstr = "";
1036                 }
1037                 else
1038                 {
1039                         sourcemsgstr = fullmsgstr;
1040                         sourcecmsgstr = fullcmsgstr;
1041                 }
1042                 cmsgstr = "";
1043         }
1044         else
1045         {
1046                 sourcemsgstr = msgstr;
1047                 sourcecmsgstr = cmsgstr;
1048         }
1049
1050         if(!privatesay)
1051         if(source.classname != "player")
1052         {
1053                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1054                         teamsay = -1; // spectators
1055         }
1056
1057         if(flood)
1058                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1059
1060         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1061         if(privatesay)
1062                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1063
1064         if(source.muted)
1065         {
1066                 // always fake the message
1067                 ret = -1;
1068         }
1069         else if(flood == 1)
1070         {
1071                 if(cvar("g_chat_flood_notify_flooder"))
1072                 {
1073                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1074                         ret = 0;
1075                 }
1076                 else
1077                         ret = -1;
1078         }
1079         else
1080         {
1081                 ret = 1;
1082         }
1083
1084         if(sourcemsgstr != "" && ret != 0)
1085         {
1086                 if(ret < 0) // fake
1087                 {
1088                         sprint(source, sourcemsgstr);
1089                         if(sourcecmsgstr != "" && !privatesay)
1090                                 centerprint(source, sourcecmsgstr);
1091                 }
1092                 else if(privatesay)
1093                 {
1094                         sprint(source, sourcemsgstr);
1095                         sprint(privatesay, msgstr);
1096                         if(cmsgstr != "")
1097                                 centerprint(privatesay, cmsgstr);
1098                 }
1099                 else if(teamsay > 0)
1100                 {
1101                         sprint(source, sourcemsgstr);
1102                         if(sourcecmsgstr != "")
1103                                 centerprint(source, sourcecmsgstr);
1104                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1105                                 if(head != source)
1106                                 {
1107                                         sprint(head, msgstr);
1108                                         if(cmsgstr != "")
1109                                                 centerprint(head, cmsgstr);
1110                                 }
1111                 }
1112                 else if(teamsay < 0)
1113                 {
1114                         sprint(source, sourcemsgstr);
1115                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1116                                 if(head != source)
1117                                         sprint(head, msgstr);
1118                 }
1119                 else if(sourcemsgstr != msgstr)
1120                 {
1121                         sprint(source, sourcemsgstr);
1122                         FOR_EACH_REALCLIENT(head)
1123                                 if(head != source)
1124                                         sprint(head, msgstr);
1125                 }
1126                 else
1127                         bprint(msgstr);
1128         }
1129
1130         return ret;
1131 }
1132
1133 float GetVoiceMessageVoiceType(string type)
1134 {
1135         if(type == "taunt")
1136                 return VOICETYPE_TAUNT;
1137         if(type == "teamshoot")
1138                 return VOICETYPE_LASTATTACKER;
1139         return VOICETYPE_TEAMRADIO;
1140 }
1141
1142 string allvoicesamples;
1143 float GetPlayerSoundSampleField_notFound;
1144 float GetPlayerSoundSampleField_fixed;
1145 .string GetVoiceMessageSampleField(string type)
1146 {
1147         GetPlayerSoundSampleField_notFound = 0;
1148         GetPlayerSoundSampleField_fixed = 0;
1149         switch(type)
1150         {
1151 #define _VOICEMSG(m) case #m: return playersound_##m;
1152                 ALLVOICEMSGS
1153 #undef _VOICEMSG
1154         }
1155         GetPlayerSoundSampleField_notFound = 1;
1156         return playersound_taunt;
1157 }
1158
1159 .string GetPlayerSoundSampleField(string type)
1160 {
1161         GetPlayerSoundSampleField_notFound = 0;
1162         GetPlayerSoundSampleField_fixed = 0;
1163         switch(type)
1164         {
1165 #define _VOICEMSG(m) case #m: return playersound_##m;
1166                 ALLPLAYERSOUNDS
1167 #undef _VOICEMSG
1168         }
1169         GetPlayerSoundSampleField_notFound = 1;
1170         return playersound_taunt;
1171 }
1172
1173 void PrecacheGlobalSound(string samplestring)
1174 {
1175         float n, i;
1176         tokenize_console(samplestring);
1177         n = stof(argv(1));
1178         if(n > 0)
1179         {
1180                 for(i = 1; i <= n; ++i)
1181                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1182         }
1183         else
1184         {
1185                 precache_sound(strcat(argv(0), ".wav"));
1186         }
1187 }
1188
1189 void PrecachePlayerSounds(string f)
1190 {
1191         float fh;
1192         string s;
1193         fh = fopen(f, FILE_READ);
1194         if(fh < 0)
1195                 return;
1196         while((s = fgets(fh)))
1197         {
1198                 if(tokenize_console(s) != 3)
1199                 {
1200                         dprint("Invalid sound info line: ", s, "\n");
1201                         continue;
1202                 }
1203                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1204         }
1205         fclose(fh);
1206
1207         if not(allvoicesamples)
1208         {
1209 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1210                 ALLVOICEMSGS
1211 #undef _VOICEMSG
1212                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1213         }
1214 }
1215
1216 void ClearPlayerSounds()
1217 {
1218 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1219         ALLPLAYERSOUNDS
1220         ALLVOICEMSGS
1221 #undef _VOICEMSG
1222 }
1223
1224 void LoadPlayerSounds(string f, float first)
1225 {
1226         float fh;
1227         string s;
1228         var .string field;
1229         fh = fopen(f, FILE_READ);
1230         if(fh < 0)
1231         {
1232                 dprint("Player sound file not found: ", f, "\n");
1233                 return;
1234         }
1235         while((s = fgets(fh)))
1236         {
1237                 if(tokenize_console(s) != 3)
1238                         continue;
1239                 field = GetPlayerSoundSampleField(argv(0));
1240                 if(GetPlayerSoundSampleField_notFound)
1241                         field = GetVoiceMessageSampleField(argv(0));
1242                 if(GetPlayerSoundSampleField_notFound)
1243                         continue;
1244                 if(GetPlayerSoundSampleField_fixed)
1245                         if not(first)
1246                                 continue;
1247                 if(self.field)
1248                         strunzone(self.field);
1249                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1250         }
1251         fclose(fh);
1252 }
1253
1254 .float modelindex_for_playersound;
1255 .float skinindex_for_playersound;
1256 void UpdatePlayerSounds()
1257 {
1258         if(self.modelindex == self.modelindex_for_playersound)
1259         if(self.skinindex == self.skinindex_for_playersound)
1260                 return;
1261         self.modelindex_for_playersound = self.modelindex;
1262         self.skinindex_for_playersound = self.skinindex;
1263         ClearPlayerSounds();
1264         LoadPlayerSounds("sound/player/default.sounds", 1);
1265         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1266 }
1267
1268 void FakeGlobalSound(string sample, float chan, float voicetype)
1269 {
1270         float n;
1271         float tauntrand;
1272
1273         if(sample == "")
1274                 return;
1275
1276         tokenize_console(sample);
1277         n = stof(argv(1));
1278         if(n > 0)
1279                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1280         else
1281                 sample = strcat(argv(0), ".wav"); // randomization
1282
1283         switch(voicetype)
1284         {
1285                 case VOICETYPE_LASTATTACKER_ONLY:
1286                         break;
1287                 case VOICETYPE_LASTATTACKER:
1288                         if(self.pusher)
1289                         {
1290                                 msg_entity = self;
1291                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1292                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1293                         }
1294                         break;
1295                 case VOICETYPE_TEAMRADIO:
1296                         msg_entity = self;
1297                         if(msg_entity.cvar_cl_voice_directional == 1)
1298                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1299                         else
1300                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1301                         break;
1302                 case VOICETYPE_AUTOTAUNT:
1303                         if(!sv_autotaunt)
1304                                 break;
1305                         if(!sv_taunt)
1306                                 break;
1307                         if(sv_gentle)
1308                                 break;
1309                         tauntrand = random();
1310                         msg_entity = self;
1311                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1312                         {
1313                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1314                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1315                                 else
1316                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1317                         }
1318                         break;
1319                 case VOICETYPE_TAUNT:
1320                         if(self.classname == "player")
1321                                 if(self.deadflag == DEAD_NO)
1322                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1323                         if(!sv_taunt)
1324                                 break;
1325                         if(sv_gentle)
1326                                 break;
1327                         msg_entity = self;
1328                         if (msg_entity.cvar_cl_voice_directional >= 1)
1329                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1330                         else
1331                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1332                         break;
1333                 case VOICETYPE_PLAYERSOUND:
1334                         msg_entity = self;
1335                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1336                         break;
1337                 default:
1338                         backtrace("Invalid voice type!");
1339                         break;
1340         }
1341 }
1342
1343 void GlobalSound(string sample, float chan, float voicetype)
1344 {
1345         float n;
1346         float tauntrand;
1347
1348         if(sample == "")
1349                 return;
1350
1351         tokenize_console(sample);
1352         n = stof(argv(1));
1353         if(n > 0)
1354                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1355         else
1356                 sample = strcat(argv(0), ".wav"); // randomization
1357
1358         switch(voicetype)
1359         {
1360                 case VOICETYPE_LASTATTACKER_ONLY:
1361                         if(self.pusher)
1362                         {
1363                                 msg_entity = self.pusher;
1364                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1365                                 {
1366                                         if(msg_entity.cvar_cl_voice_directional == 1)
1367                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1368                                         else
1369                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1370                                 }
1371                         }
1372                         break;
1373                 case VOICETYPE_LASTATTACKER:
1374                         if(self.pusher)
1375                         {
1376                                 msg_entity = self.pusher;
1377                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1378                                 {
1379                                         if(msg_entity.cvar_cl_voice_directional == 1)
1380                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1381                                         else
1382                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1383                                 }
1384                                 msg_entity = self;
1385                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1386                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1387                         }
1388                         break;
1389                 case VOICETYPE_TEAMRADIO:
1390                         FOR_EACH_REALCLIENT(msg_entity)
1391                                 if(!teams_matter || msg_entity.team == self.team)
1392                                 {
1393                                         if(msg_entity.cvar_cl_voice_directional == 1)
1394                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1395                                         else
1396                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1397                                 }
1398                         break;
1399                 case VOICETYPE_AUTOTAUNT:
1400                         if(!sv_autotaunt)
1401                                 break;
1402                         if(!sv_taunt)
1403                                 break;
1404                         if(sv_gentle)
1405                                 break;
1406                         tauntrand = random();
1407                         FOR_EACH_REALCLIENT(msg_entity)
1408                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1409                                 {
1410                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1411                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1412                                         else
1413                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1414                                 }
1415                         break;
1416                 case VOICETYPE_TAUNT:
1417                         if(self.classname == "player")
1418                                 if(self.deadflag == DEAD_NO)
1419                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1420                         if(!sv_taunt)
1421                                 break;
1422                         if(sv_gentle)
1423                                 break;
1424                         FOR_EACH_REALCLIENT(msg_entity)
1425                         {
1426                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1427                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1428                                 else
1429                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1430                         }
1431                         break;
1432                 case VOICETYPE_PLAYERSOUND:
1433                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1434                         break;
1435                 default:
1436                         backtrace("Invalid voice type!");
1437                         break;
1438         }
1439 }
1440
1441 void PlayerSound(.string samplefield, float chan, float voicetype)
1442 {
1443         GlobalSound(self.samplefield, chan, voicetype);
1444 }
1445
1446 void VoiceMessage(string type, string msg)
1447 {
1448         var .string sample;
1449         float voicetype, ownteam;
1450         float flood;
1451         sample = GetVoiceMessageSampleField(type);
1452
1453         if(GetPlayerSoundSampleField_notFound)
1454         {
1455                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1456                 return;
1457         }
1458
1459         voicetype = GetVoiceMessageVoiceType(type);
1460         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1461
1462         flood = Say(self, ownteam, world, msg, 1);
1463
1464         if (flood > 0)
1465                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1466         else if (flood < 0)
1467                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1468 }
1469
1470 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1471 {
1472 //      show_message
1473 //      0 (00) automove centerprint, admin message
1474 //      1 (01) automove centerprint, no admin message
1475 //      2 (10) no centerprint, admin message
1476 //      3 (11) no centerprint, no admin message
1477
1478         float lockteams_backup;
1479
1480         lockteams_backup = lockteams;  // backup any team lock
1481
1482         lockteams = 0;  // disable locked teams
1483
1484         TeamchangeFrags(client);  // move the players frags
1485         SetPlayerColors(client, team_colour - 1);  // set the players colour
1486         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1487
1488         lockteams = lockteams_backup;  // restore the team lock
1489
1490         LogTeamchange(client.playerid, client.team, type);
1491
1492         if not(show_message & 1) // admin message
1493                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1494
1495         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1496 }