qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 218
 219         self = oldself;
 220 }
 221
 222 float player_getspecies()
 223 {
 224         float s;
 225         get_model_parameters(self.model, self.skin);
 226         s = get_model_parameters_species;
 227         get_model_parameters(string_null, 0);
 228         if(s < 0)
 229                 return SPECIES_HUMAN;
 230         return s;
 231 }
 232
 233 void player_setupanimsformodel()
 234 {
 235         // load animation info
 236         animdecide_init(self);
 237         animdecide_setstate(self, 0, FALSE);
 238 }
 239
 240 void player_anim (void)
 241 {
 242         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 243         if(self.deadflag) {
 244                 if (!deadbits) {
 245                         // Decide on which death animation to use.
 246                         if(random() < 0.5)
 247                                 deadbits = ANIMSTATE_DEAD1;
 248                         else
 249                                 deadbits = ANIMSTATE_DEAD2;
 250                 }
 251         } else {
 252                 // Clear a previous death animation.
 253                 deadbits = 0;
 254         }
 255         float animbits = deadbits;
 256         if(self.frozen)
 257                 animbits |= ANIMSTATE_FROZEN;
 258         if(self.crouch)
 259                 animbits |= ANIMSTATE_DUCK;
 260         animdecide_setstate(self, animbits, FALSE);
 261         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 262
 263         if (self.weaponentity)
 264         {
 265                 updateanim(self.weaponentity);
 266                 if (!self.weaponentity.animstate_override)
 267                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 268         }
 269 }
 270
 271 void SpawnThrownWeapon (vector org, float w)
 272 {
 273         if(self.weapons & WepSet_FromWeapon(self.weapon))
 274                 if(W_IsWeaponThrowable(self.weapon))
 275                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 276 }
 277
 278 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 279 {
 280         float take, save;
 281         vector v;
 282         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 283
 284         // damage resistance (ignore most of the damage from a bullet or similar)
 285         damage = max(damage - 5, 1);
 286
 287         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 288         take = v_x;
 289         save = v_y;
 290
 291         if(sound_allowed(MSG_BROADCAST, attacker))
 292         {
 293                 if (save > 10)
 294                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 295                 else if (take > 30)
 296                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 297                 else if (take > 10)
 298                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 299         }
 300
 301         if (take > 50)
 302                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 303         if (take > 100)
 304                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 305
 306         if (!(self.flags & FL_GODMODE))
 307         {
 308                 self.armorvalue = self.armorvalue - save;
 309                 self.health = self.health - take;
 310                 // pause regeneration for 5 seconds
 311                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 312         }
 313         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 314         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 315         self.dmg_inflictor = inflictor;
 316
 317         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 318         {
 319                 // don't use any animations as a gib
 320                 self.frame = 0;
 321                 // view just above the floor
 322                 self.view_ofs = '0 0 4';
 323
 324                 Violence_GibSplash(self, 1, 1, attacker);
 325                 self.alpha = -1;
 326                 self.solid = SOLID_NOT; // restore later
 327                 self.takedamage = DAMAGE_NO; // restore later
 328                 self.damagedbycontents = FALSE;
 329         }
 330 }
 331
 332 // g_<gametype>_str:
 333 // If 0, default is used.
 334 // If <0, 0 is used.
 335 // Otherwise, g_str (default value) is used.
 336 // For consistency, negative values there are mapped to zero too.
 337 #define GAMETYPE_DEFAULTED_SETTING(str) \
 338         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 339          (gametype_setting_tmp < 0) ? 0 : \
 340          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 341          gametype_setting_tmp)
 342
 343
 344 void calculate_player_respawn_time()
 345 {
 346         float gametype_setting_tmp;
 347         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 348         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 349         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 350         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 351         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 352         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 353
 354         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 355         entity pl;
 356         if (teamplay)
 357         {
 358                 FOR_EACH_PLAYER(pl)
 359                         if (pl != self)
 360                                 if (pl.team == self.team)
 361                                         ++pcount;
 362                 if (sdelay_small_count == 0)
 363                         sdelay_small_count = 1;
 364                 if (sdelay_large_count == 0)
 365                         sdelay_large_count = 1;
 366         }
 367         else
 368         {
 369                 FOR_EACH_PLAYER(pl)
 370                         if (pl != self)
 371                                 ++pcount;
 372                 if (sdelay_small_count == 0)
 373                 {
 374                         if (g_cts)
 375                         {
 376                                 // Players play independently. No point in requiring enemies.
 377                                 sdelay_small_count = 1;
 378                         }
 379                         else
 380                         {
 381                                 // Players play AGAINST each other. Enemies required.
 382                                 sdelay_small_count = 2;
 383                         }
 384                 }
 385                 if (sdelay_large_count == 0)
 386                 {
 387                         if (g_cts)
 388                         {
 389                                 // Players play independently. No point in requiring enemies.
 390                                 sdelay_large_count = 1;
 391                         }
 392                         else
 393                         {
 394                                 // Players play AGAINST each other. Enemies required.
 395                                 sdelay_large_count = 2;
 396                         }
 397                 }
 398         }
 399
 400         float sdelay;
 401
 402         if (pcount <= sdelay_small_count)
 403                 sdelay = sdelay_small;
 404         else if (pcount >= sdelay_large_count)
 405                 sdelay = sdelay_large;
 406         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 407                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 408
 409         if(waves)
 410                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 411         else
 412                 self.respawn_time = time + sdelay;
 413
 414         if(sdelay < sdelay_max)
 415                 self.respawn_time_max = time + sdelay_max;
 416         else
 417                 self.respawn_time_max = self.respawn_time;
 418
 419         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 420                 self.respawn_countdown = 10; // first number to count down from is 10
 421         else
 422                 self.respawn_countdown = -1; // do not count down
 423
 424         if(autocvar_g_forced_respawn)
 425                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 426 }
 427
 428 void ClientKill_Now_TeamChange();
 429
 430 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 431 {
 432         float take, save, dh, da, j;
 433         vector v;
 434         float valid_damage_for_weaponstats;
 435         float excess;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 if (d)
 461                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 462                 else
 463                         f = 0;  // Assum ecenter.
 464                 force = v_right * vlen(force);
 465                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 466                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 467                 if(f > 0)
 468                 {
 469                         hitloc = ear1;
 470                         force = force * -1;
 471                 }
 472                 else
 473                 {
 474                         hitloc = ear2;
 475                         // force is already good
 476                 }
 477         }
 478         else
 479                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 480
 481
 482         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 483         take = v_x;
 484         save = v_y;
 485
 486         if(attacker == self)
 487         {
 488                 // don't reset pushltime for self damage as it may be an attempt to
 489                 // escape a lava pit or similar
 490                 //self.pushltime = 0;
 491                 self.istypefrag = 0;
 492         }
 493         else if(IS_PLAYER(attacker))
 494         {
 495                 self.pusher = attacker;
 496                 self.pushltime = time + autocvar_g_maxpushtime;
 497                 self.istypefrag = self.BUTTON_CHAT;
 498         }
 499         else if(time < self.pushltime)
 500         {
 501                 attacker = self.pusher;
 502                 self.pushltime = max(self.pushltime, time + 0.6);
 503         }
 504         else
 505         {
 506                 self.pushltime = 0;
 507                 self.istypefrag = 0;
 508         }
 509
 510         frag_inflictor = inflictor;
 511         frag_attacker = attacker;
 512         frag_target = self;
 513         frag_damage = damage;
 514         damage_take = take;
 515         damage_save = save;
 516         damage_force = force;
 517         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 518         take = bound(0, damage_take, self.health);
 519         save = bound(0, damage_save, self.armorvalue);
 520         excess = max(0, damage - take - save);
 521
 522         if(sound_allowed(MSG_BROADCAST, attacker))
 523         {
 524                 if (save > 10)
 525                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 526                 else if (take > 30)
 527                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 528                 else if (take > 10)
 529                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 530         }
 531
 532         if (take > 50)
 533                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 534         if (take > 100)
 535                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 536
 537         if (time >= self.spawnshieldtime)
 538         {
 539                 if (!(self.flags & FL_GODMODE))
 540                 {
 541                         self.armorvalue = self.armorvalue - save;
 542                         self.health = self.health - take;
 543                         // pause regeneration for 5 seconds
 544                         if(take)
 545                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 546
 547                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 548                         {
 549                                 self.pain_finished = time + 0.5;        //Supajoe
 550
 551                                 if(autocvar_sv_gentle < 1) {
 552                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 553                                         {
 554                                                 if (!self.animstate_override)
 555                                                 {
 556                                                         if (random() > 0.5)
 557                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 558                                                         else
 559                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 560                                                 }
 561                                         }
 562
 563                                         if(sound_allowed(MSG_BROADCAST, attacker))
 564                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 565                                         if(self.health > 1)
 566                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 567                                         {
 568                                                 if(deathtype == DEATH_FALL)
 569                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 570                                                 else if(self.health > 75) // TODO make a "gentle" version?
 571                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 572                                                 else if(self.health > 50)
 573                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 574                                                 else if(self.health > 25)
 575                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 576                                                 else
 577                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 578                                         }
 579                                 }
 580                         }
 581
 582                         // throw off bot aim temporarily
 583                         float shake;
 584                         if(IS_BOT_CLIENT(self) && self.health >= 1)
 585                         {
 586                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 587                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 588                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 589                                 self.v_angle_x = bound(-90, self.v_angle_x, 90);
 590                         }
 591                 }
 592                 else
 593                         self.max_armorvalue += (save + take);
 594         }
 595         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 596         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 597         self.dmg_inflictor = inflictor;
 598
 599         float abot, vbot, awep;
 600         abot = (IS_BOT_CLIENT(attacker));
 601         vbot = (IS_BOT_CLIENT(self));
 602
 603         valid_damage_for_weaponstats = 0;
 604         awep = 0;
 605
 606         if(vbot || IS_REAL_CLIENT(self))
 607         if(abot || IS_REAL_CLIENT(attacker))
 608         if(attacker && self != attacker)
 609         if(DIFF_TEAM(self, attacker))
 610         {
 611                 if(DEATH_ISSPECIAL(deathtype))
 612                         awep = attacker.weapon;
 613                 else
 614                         awep = DEATH_WEAPONOF(deathtype);
 615                 valid_damage_for_weaponstats = 1;
 616         }
 617
 618         if(valid_damage_for_weaponstats)
 619         {
 620                 dh = dh - max(self.health, 0);
 621                 da = da - max(self.armorvalue, 0);
 622                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 623         }
 624
 625         if (self.health < 1)
 626         {
 627                 float defer_ClientKill_Now_TeamChange;
 628                 defer_ClientKill_Now_TeamChange = FALSE;
 629
 630                 if(self.alivetime)
 631                 {
 632                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 633                         self.alivetime = 0;
 634                 }
 635
 636                 if(valid_damage_for_weaponstats)
 637                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 638
 639                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 640                 if(sound_allowed(MSG_BROADCAST, attacker))
 641                 {
 642                         if(deathtype == DEATH_DROWN)
 643                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 644                         else
 645                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 646                 }
 647
 648                 // get rid of kill indicator
 649                 if(self.killindicator)
 650                 {
 651                         remove(self.killindicator);
 652                         self.killindicator = world;
 653                         if(self.killindicator_teamchange)
 654                                 defer_ClientKill_Now_TeamChange = TRUE;
 655
 656                         if(self.classname == "body")
 657                         if(deathtype == DEATH_KILL)
 658                         {
 659                                 // for the lemmings fans, a small harmless explosion
 660                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 661                         }
 662                 }
 663
 664                 // print an obituary message
 665                 Obituary (attacker, inflictor, self, deathtype);
 666
 667         // increment frag counter for used weapon type
 668         float w;
 669         w = DEATH_WEAPONOF(deathtype);
 670         if(WEP_VALID(w))
 671         if(accuracy_isgooddamage(attacker, self))
 672         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 673
 674                 frag_attacker = attacker;
 675                 frag_inflictor = inflictor;
 676                 frag_target = self;
 677                 frag_deathtype = deathtype;
 678                 MUTATOR_CALLHOOK(PlayerDies);
 679
 680                 weapon_action(self.weapon, WR_PLAYERDEATH);
 681
 682                 RemoveGrapplingHook(self);
 683
 684                 Portal_ClearAllLater(self);
 685
 686                 self.fixangle = TRUE;
 687
 688                 if(defer_ClientKill_Now_TeamChange)
 689                         ClientKill_Now_TeamChange(); // can turn player into spectator
 690
 691                 // player could have been miraculously resuscitated ;)
 692                 // e.g. players in freezetag get frozen, they don't really die
 693                 if(self.health >= 1 || !IS_PLAYER(self))
 694                         return;
 695
 696                 // when we get here, player actually dies
 697
 698                 Unfreeze(self); // remove any icy remains
 699                 self.health = 0; // Unfreeze resets health, so we need to set it back
 700
 701                 // clear waypoints
 702                 WaypointSprite_PlayerDead();
 703                 // throw a weapon
 704                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 705
 706                 // become fully visible
 707                 self.alpha = default_player_alpha;
 708                 // make the corpse upright (not tilted)
 709                 self.angles_x = 0;
 710                 self.angles_z = 0;
 711                 // don't spin
 712                 self.avelocity = '0 0 0';
 713                 // view from the floor
 714                 self.view_ofs = '0 0 -8';
 715                 // toss the corpse
 716                 self.movetype = MOVETYPE_TOSS;
 717                 // shootable corpse
 718                 self.solid = SOLID_CORPSE;
 719                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 720                 // don't stick to the floor
 721                 self.flags &= ~FL_ONGROUND;
 722                 // dying animation
 723                 self.deadflag = DEAD_DYING;
 724                 // when to allow respawn
 725                 calculate_player_respawn_time();
 726
 727                 self.death_time = time;
 728                 if (random() < 0.5)
 729                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 730                 else
 731                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 732                 if (self.maxs_z > 5)
 733                 {
 734                         self.maxs_z = 5;
 735                         setsize(self, self.mins, self.maxs);
 736                 }
 737                 // set damage function to corpse damage
 738                 self.event_damage = PlayerCorpseDamage;
 739                 // call the corpse damage function just in case it wants to gib
 740                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 741                 // set up to fade out later
 742                 SUB_SetFade (self, time + 6 + random (), 1);
 743
 744                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 745                         // remove corpse
 746                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 747                 }
 748
 749                 // reset fields the weapons may use just in case
 750                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 751                 {
 752                         weapon_action(j, WR_RESETPLAYER);
 753                         ATTACK_FINISHED_FOR(self, j) = 0;
 754                 }
 755         }
 756 }
 757
 758 .float muted; // to be used by prvm_edictset server playernumber muted 1
 759 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 760 // message "": do not say, just test flood control
 761 // return value:
 762 //   1 = accept
 763 //   0 = reject
 764 //  -1 = fake accept
 765 {
 766         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 767         float flood;
 768         var .float flood_field;
 769         entity head;
 770         float ret;
 771         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 772
 773         if(!teamsay && !privatesay)
 774                 if(substring(msgin, 0, 1) == " ")
 775                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 776
 777         msgin = formatmessage(msgin);
 778
 779         if (!IS_PLAYER(source))
 780                 colorstr = "^0"; // black for spectators
 781         else if(teamplay)
 782                 colorstr = Team_ColorCode(source.team);
 783         else
 784         {
 785                 colorstr = "";
 786                 teamsay = FALSE;
 787         }
 788
 789         if(intermission_running)
 790                 teamsay = FALSE;
 791
 792         if(msgin != "")
 793                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 794
 795         /*
 796          * using bprint solves this... me stupid
 797         // how can we prevent the message from appearing in a listen server?
 798         // for now, just give "say" back and only handle say_team
 799         if(!teamsay)
 800         {
 801                 clientcommand(self, strcat("say ", msgin));
 802                 return;
 803         }
 804         */
 805
 806         if(autocvar_g_chat_teamcolors)
 807                 namestr = playername(source);
 808         else
 809                 namestr = source.netname;
 810
 811         if(strdecolorize(namestr) == namestr)
 812                 colorprefix = "^3";
 813         else
 814                 colorprefix = "^7";
 815
 816         if(msgin != "")
 817         {
 818                 if(privatesay)
 819                 {
 820                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 821                         privatemsgprefixlen = strlen(msgstr);
 822                         msgstr = strcat(msgstr, msgin);
 823                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 824                         if(autocvar_g_chat_teamcolors)
 825                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 826                         else
 827                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 828                 }
 829                 else if(teamsay)
 830                 {
 831                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 832                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 833                 }
 834                 else
 835                 {
 836                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 837                         cmsgstr = "";
 838                 }
 839                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 840         }
 841         else
 842         {
 843                 msgstr = cmsgstr = "";
 844         }
 845
 846         fullmsgstr = msgstr;
 847         fullcmsgstr = cmsgstr;
 848
 849         // FLOOD CONTROL
 850         flood = 0;
 851         flood_field = floodcontrol_chat;
 852         if(floodcontrol)
 853         {
 854                 float flood_spl;
 855                 float flood_burst;
 856                 float flood_lmax;
 857                 float lines;
 858                 if(privatesay)
 859                 {
 860                         flood_spl = autocvar_g_chat_flood_spl_tell;
 861                         flood_burst = autocvar_g_chat_flood_burst_tell;
 862                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 863                         flood_field = floodcontrol_chattell;
 864                 }
 865                 else if(teamsay)
 866                 {
 867                         flood_spl = autocvar_g_chat_flood_spl_team;
 868                         flood_burst = autocvar_g_chat_flood_burst_team;
 869                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 870                         flood_field = floodcontrol_chatteam;
 871                 }
 872                 else
 873                 {
 874                         flood_spl = autocvar_g_chat_flood_spl;
 875                         flood_burst = autocvar_g_chat_flood_burst;
 876                         flood_lmax = autocvar_g_chat_flood_lmax;
 877                         flood_field = floodcontrol_chat;
 878                 }
 879                 flood_burst = max(0, flood_burst - 1);
 880                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 881
 882                 // do flood control for the default line size
 883                 if(msgstr != "")
 884                 {
 885                         getWrappedLine_remaining = msgstr;
 886                         msgstr = "";
 887                         lines = 0;
 888                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 889                         {
 890                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 891                                 ++lines;
 892                         }
 893                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 894
 895                         if(getWrappedLine_remaining != "")
 896                         {
 897                                 msgstr = strcat(msgstr, "\n");
 898                                 flood = 2;
 899                         }
 900
 901                         if(time >= source.flood_field)
 902                         {
 903                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 904                         }
 905                         else
 906                         {
 907                                 flood = 1;
 908                                 msgstr = fullmsgstr;
 909                         }
 910                 }
 911                 else
 912                 {
 913                         if(time >= source.flood_field)
 914                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 915                         else
 916                                 flood = 1;
 917                 }
 918
 919                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 920                         source.flood_field = flood = 0;
 921         }
 922
 923         if(flood == 2) // cannot happen for empty msgstr
 924         {
 925                 if(autocvar_g_chat_flood_notify_flooder)
 926                 {
 927                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 928                         sourcecmsgstr = "";
 929                 }
 930                 else
 931                 {
 932                         sourcemsgstr = fullmsgstr;
 933                         sourcecmsgstr = fullcmsgstr;
 934                 }
 935                 cmsgstr = "";
 936         }
 937         else
 938         {
 939                 sourcemsgstr = msgstr;
 940                 sourcecmsgstr = cmsgstr;
 941         }
 942
 943         if(!privatesay)
 944         if (!IS_PLAYER(source))
 945         {
 946                 if (!intermission_running)
 947                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 948                                 teamsay = -1; // spectators
 949         }
 950
 951         if(flood)
 952                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 953
 954         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 955         if(privatesay)
 956                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 957
 958         if(source.muted)
 959         {
 960                 // always fake the message
 961                 ret = -1;
 962         }
 963         else if(flood == 1)
 964         {
 965                 if(autocvar_g_chat_flood_notify_flooder)
 966                 {
 967                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 968                         ret = 0;
 969                 }
 970                 else
 971                         ret = -1;
 972         }
 973         else
 974         {
 975                 ret = 1;
 976         }
 977
 978         if(sourcemsgstr != "" && ret != 0)
 979         {
 980                 if(ret < 0) // faked message, because the player is muted
 981                 {
 982                         sprint(source, sourcemsgstr);
 983                         if(sourcecmsgstr != "" && !privatesay)
 984                                 centerprint(source, sourcecmsgstr);
 985                 }
 986                 else if(privatesay) // private message, between 2 people only
 987                 {
 988                         sprint(source, sourcemsgstr);
 989                         sprint(privatesay, msgstr);
 990                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 991                         if(cmsgstr != "")
 992                                 centerprint(privatesay, cmsgstr);
 993                 }
 994                 else if(teamsay > 0) // team message, only sent to team mates
 995                 {
 996                         sprint(source, sourcemsgstr);
 997                         dedicated_print(msgstr); // send to server console too
 998                         if(sourcecmsgstr != "")
 999                                 centerprint(source, sourcecmsgstr);
1000                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1001                                 if(head != source)
1002                                 {
1003                                         sprint(head, msgstr);
1004                                         if(cmsgstr != "")
1005                                                 centerprint(head, cmsgstr);
1006                                 }
1007                 }
1008                 else if(teamsay < 0) // spectator message, only sent to spectators
1009                 {
1010                         sprint(source, sourcemsgstr);
1011                         dedicated_print(msgstr); // send to server console too
1012                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
1013                                 if(head != source)
1014                                         sprint(head, msgstr);
1015                 }
1016                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1017                 {
1018                         sprint(source, sourcemsgstr);
1019                         dedicated_print(msgstr); // send to server console too
1020                         FOR_EACH_REALCLIENT(head)
1021                                 if(head != source)
1022                                         sprint(head, msgstr);
1023                 }
1024                 else
1025                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1026         }
1027
1028         return ret;
1029 }
1030
1031 float GetVoiceMessageVoiceType(string type)
1032 {
1033         if(type == "taunt")
1034                 return VOICETYPE_TAUNT;
1035         if(type == "teamshoot")
1036                 return VOICETYPE_LASTATTACKER;
1037         return VOICETYPE_TEAMRADIO;
1038 }
1039
1040 string allvoicesamples;
1041 .string GetVoiceMessageSampleField(string type)
1042 {
1043         GetPlayerSoundSampleField_notFound = 0;
1044         switch(type)
1045         {
1046 #define _VOICEMSG(m) case #m: return playersound_##m;
1047                 ALLVOICEMSGS
1048 #undef _VOICEMSG
1049         }
1050         GetPlayerSoundSampleField_notFound = 1;
1051         return playersound_taunt;
1052 }
1053
1054 .string GetPlayerSoundSampleField(string type)
1055 {
1056         GetPlayerSoundSampleField_notFound = 0;
1057         switch(type)
1058         {
1059 #define _VOICEMSG(m) case #m: return playersound_##m;
1060                 ALLPLAYERSOUNDS
1061 #undef _VOICEMSG
1062         }
1063         GetPlayerSoundSampleField_notFound = 1;
1064         return playersound_taunt;
1065 }
1066
1067 void PrecacheGlobalSound(string samplestring)
1068 {
1069         float n, i;
1070         tokenize_console(samplestring);
1071         n = stof(argv(1));
1072         if(n > 0)
1073         {
1074                 for(i = 1; i <= n; ++i)
1075                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1076         }
1077         else
1078         {
1079                 precache_sound(strcat(argv(0), ".wav"));
1080         }
1081 }
1082
1083 void PrecachePlayerSounds(string f)
1084 {
1085         float fh;
1086         string s;
1087         fh = fopen(f, FILE_READ);
1088         if(fh < 0)
1089                 return;
1090         while((s = fgets(fh)))
1091         {
1092                 if(tokenize_console(s) != 3)
1093                 {
1094                         dprint("Invalid sound info line: ", s, "\n");
1095                         continue;
1096                 }
1097                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1098         }
1099         fclose(fh);
1100
1101         if (!allvoicesamples)
1102         {
1103 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1104                 ALLVOICEMSGS
1105 #undef _VOICEMSG
1106                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1107         }
1108 }
1109
1110 void ClearPlayerSounds()
1111 {
1112 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1113         ALLPLAYERSOUNDS
1114         ALLVOICEMSGS
1115 #undef _VOICEMSG
1116 }
1117
1118 float LoadPlayerSounds(string f, float first)
1119 {
1120         float fh;
1121         string s;
1122         var .string field;
1123         fh = fopen(f, FILE_READ);
1124         if(fh < 0)
1125         {
1126                 dprint("Player sound file not found: ", f, "\n");
1127                 return 0;
1128         }
1129         while((s = fgets(fh)))
1130         {
1131                 if(tokenize_console(s) != 3)
1132                         continue;
1133                 field = GetPlayerSoundSampleField(argv(0));
1134                 if(GetPlayerSoundSampleField_notFound)
1135                         field = GetVoiceMessageSampleField(argv(0));
1136                 if(GetPlayerSoundSampleField_notFound)
1137                         continue;
1138                 if(self.field)
1139                         strunzone(self.field);
1140                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1141         }
1142         fclose(fh);
1143         return 1;
1144 }
1145
1146 .float modelindex_for_playersound;
1147 .float skin_for_playersound;
1148 void UpdatePlayerSounds()
1149 {
1150         if(self.modelindex == self.modelindex_for_playersound)
1151         if(self.skin == self.skin_for_playersound)
1152                 return;
1153         self.modelindex_for_playersound = self.modelindex;
1154         self.skin_for_playersound = self.skin;
1155         ClearPlayerSounds();
1156         LoadPlayerSounds("sound/player/default.sounds", 1);
1157         if(!autocvar_g_debug_defaultsounds)
1158                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1159                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1160 }
1161
1162 void FakeGlobalSound(string sample, float chan, float voicetype)
1163 {
1164         float n;
1165         float tauntrand;
1166
1167         if(sample == "")
1168                 return;
1169
1170         tokenize_console(sample);
1171         n = stof(argv(1));
1172         if(n > 0)
1173                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1174         else
1175                 sample = strcat(argv(0), ".wav"); // randomization
1176
1177         switch(voicetype)
1178         {
1179                 case VOICETYPE_LASTATTACKER_ONLY:
1180                         break;
1181                 case VOICETYPE_LASTATTACKER:
1182                         if(self.pusher)
1183                         {
1184                                 msg_entity = self;
1185                                 if(IS_REAL_CLIENT(msg_entity))
1186                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1187                         }
1188                         break;
1189                 case VOICETYPE_TEAMRADIO:
1190                         msg_entity = self;
1191                         if(msg_entity.cvar_cl_voice_directional == 1)
1192                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1193                         else
1194                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1195                         break;
1196                 case VOICETYPE_AUTOTAUNT:
1197                         if(!sv_autotaunt)
1198                                 break;
1199                         if(!sv_taunt)
1200                                 break;
1201                         if(autocvar_sv_gentle)
1202                                 break;
1203                         tauntrand = random();
1204                         msg_entity = self;
1205                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1206                         {
1207                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1208                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1209                                 else
1210                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1211                         }
1212                         break;
1213                 case VOICETYPE_TAUNT:
1214                         if(IS_PLAYER(self))
1215                                 if(self.deadflag == DEAD_NO)
1216                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1217                         if(!sv_taunt)
1218                                 break;
1219                         if(autocvar_sv_gentle)
1220                                 break;
1221                         msg_entity = self;
1222                         if (msg_entity.cvar_cl_voice_directional >= 1)
1223                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1224                         else
1225                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1226                         break;
1227                 case VOICETYPE_PLAYERSOUND:
1228                         msg_entity = self;
1229                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1230                         break;
1231                 default:
1232                         backtrace("Invalid voice type!");
1233                         break;
1234         }
1235 }
1236
1237 void GlobalSound(string sample, float chan, float voicetype)
1238 {
1239         float n;
1240         float tauntrand;
1241
1242         if(sample == "")
1243                 return;
1244
1245         tokenize_console(sample);
1246         n = stof(argv(1));
1247         if(n > 0)
1248                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1249         else
1250                 sample = strcat(argv(0), ".wav"); // randomization
1251
1252         switch(voicetype)
1253         {
1254                 case VOICETYPE_LASTATTACKER_ONLY:
1255                         if(self.pusher)
1256                         {
1257                                 msg_entity = self.pusher;
1258                                 if(IS_REAL_CLIENT(msg_entity))
1259                                 {
1260                                         if(msg_entity.cvar_cl_voice_directional == 1)
1261                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1262                                         else
1263                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1264                                 }
1265                         }
1266                         break;
1267                 case VOICETYPE_LASTATTACKER:
1268                         if(self.pusher)
1269                         {
1270                                 msg_entity = self.pusher;
1271                                 if(IS_REAL_CLIENT(msg_entity))
1272                                 {
1273                                         if(msg_entity.cvar_cl_voice_directional == 1)
1274                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1275                                         else
1276                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1277                                 }
1278                                 msg_entity = self;
1279                                 if(IS_REAL_CLIENT(msg_entity))
1280                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1281                         }
1282                         break;
1283                 case VOICETYPE_TEAMRADIO:
1284                         FOR_EACH_REALCLIENT(msg_entity)
1285                                 if(!teamplay || msg_entity.team == self.team)
1286                                 {
1287                                         if(msg_entity.cvar_cl_voice_directional == 1)
1288                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1289                                         else
1290                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1291                                 }
1292                         break;
1293                 case VOICETYPE_AUTOTAUNT:
1294                         if(!sv_autotaunt)
1295                                 break;
1296                         if(!sv_taunt)
1297                                 break;
1298                         if(autocvar_sv_gentle)
1299                                 break;
1300                         tauntrand = random();
1301                         FOR_EACH_REALCLIENT(msg_entity)
1302                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1303                                 {
1304                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1305                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1306                                         else
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1308                                 }
1309                         break;
1310                 case VOICETYPE_TAUNT:
1311                         if(IS_PLAYER(self))
1312                                 if(self.deadflag == DEAD_NO)
1313                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1314                         if(!sv_taunt)
1315                                 break;
1316                         if(autocvar_sv_gentle)
1317                                 break;
1318                         FOR_EACH_REALCLIENT(msg_entity)
1319                         {
1320                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1321                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1322                                 else
1323                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1324                         }
1325                         break;
1326                 case VOICETYPE_PLAYERSOUND:
1327                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1328                         break;
1329                 default:
1330                         backtrace("Invalid voice type!");
1331                         break;
1332         }
1333 }
1334
1335 void PlayerSound(.string samplefield, float chan, float voicetype)
1336 {
1337         GlobalSound(self.samplefield, chan, voicetype);
1338 }
1339
1340 void VoiceMessage(string type, string msg)
1341 {
1342         var .string sample;
1343         float voicetype, ownteam;
1344         float flood;
1345         sample = GetVoiceMessageSampleField(type);
1346
1347         if(GetPlayerSoundSampleField_notFound)
1348         {
1349                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1350                 return;
1351         }
1352
1353         voicetype = GetVoiceMessageVoiceType(type);
1354         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1355
1356         flood = Say(self, ownteam, world, msg, 1);
1357
1358         if (flood > 0)
1359                 GlobalSound(self.sample, CH_VOICE, voicetype);
1360         else if (flood < 0)
1361                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1362 }
1363
1364 void MoveToTeam(entity client, float team_colour, float type)
1365 {
1366         float lockteams_backup;
1367
1368         lockteams_backup = lockteams;  // backup any team lock
1369
1370         lockteams = 0;  // disable locked teams
1371
1372         TeamchangeFrags(client);  // move the players frags
1373         SetPlayerColors(client, team_colour - 1);  // set the players colour
1374         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1375
1376         lockteams = lockteams_backup;  // restore the team lock
1377
1378         LogTeamchange(client.playerid, client.team, type);
1379 }