qcsrc/server/cl_weapons.qc

   1 void W_TriggerReload()
   2 {
   3     weapon_action(self.weapon, WR_RELOAD);
   4 }
   5
   6 // switch between weapons
   7 void W_SwitchWeapon(float imp)
   8 {
   9         if (self.switchweapon != imp)
  10         {
  11                 if (client_hasweapon(self, imp, TRUE, TRUE))
  12                         W_SwitchWeapon_Force(self, imp);
  13                 else
  14                         self.selectweapon = imp; // update selectweapon ANYWAY
  15         }
  16         else
  17         {
  18                 W_TriggerReload();
  19         }
  20 };
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain, float skipmissing)
  24 {
  25         // We cannot tokenize in this function, as GiveItems calls this
  26         // function. Thus we must use car/cdr.
  27         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  28         string rest;
  29         switchtonext = switchtolast = 0;
  30         first_valid = prev_valid = 0;
  31         float weaponcur;
  32
  33         if(skipmissing || pl.selectweapon == 0)
  34                 weaponcur = pl.switchweapon;
  35         else
  36                 weaponcur = pl.selectweapon;
  37
  38         if(dir == 0)
  39                 switchtonext = 1;
  40
  41         c = 0;
  42
  43         rest = weaponorder;
  44         while(rest != "")
  45         {
  46                 weaponwant = stof(car(rest)); rest = cdr(rest);
  47                 if(imp >= 0)
  48                         if((get_weaponinfo(weaponwant)).impulse != imp)
  49                                 continue;
  50
  51                 ++c;
  52
  53                 if(!skipmissing || client_hasweapon(pl, weaponwant, TRUE, FALSE))
  54                 {
  55                         if(switchtonext)
  56                                 return weaponwant;
  57                         if(!first_valid)
  58                                 first_valid = weaponwant;
  59                         if(weaponwant == weaponcur)
  60                         {
  61                                 if(dir >= 0)
  62                                         switchtonext = 1;
  63                                 else if(prev_valid)
  64                                         return prev_valid;
  65                                 else
  66                                         switchtolast = 1;
  67                         }
  68                         prev_valid = weaponwant;
  69                 }
  70         }
  71         if(first_valid)
  72         {
  73                 if(switchtolast)
  74                         return prev_valid;
  75                 else
  76                         return first_valid;
  77         }
  78         // complain (but only for one weapon on the button that has been pressed)
  79         if(complain)
  80         {
  81                 self.weaponcomplainindex += 1;
  82                 c = mod(self.weaponcomplainindex, c) + 1;
  83                 rest = weaponorder;
  84                 while(rest != "")
  85                 {
  86                         weaponwant = stof(car(rest)); rest = cdr(rest);
  87                         if(imp >= 0)
  88                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  89                                         continue;
  90
  91                         --c;
  92                         if(c == 0)
  93                         {
  94                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  95                                 break;
  96                         }
  97                 }
  98         }
  99         return 0;
 100 }
 101
 102 void W_CycleWeapon(string weaponorder, float dir)
 103 {
 104         float w;
 105         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1, TRUE);
 106         if(w > 0)
 107                 W_SwitchWeapon(w);
 108 }
 109
 110 void W_NextWeaponOnImpulse(float imp)
 111 {
 112         float w;
 113         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1, (self.cvar_cl_weaponimpulsemode == 0));
 114         if(w > 0)
 115                 W_SwitchWeapon(w);
 116 }
 117
 118 // next weapon
 119 void W_NextWeapon(float list)
 120 {
 121         if(list == 0)
 122                 W_CycleWeapon(weaponorder_byid, -1);
 123         else if(list == 1)
 124                 W_CycleWeapon(self.weaponorder_byimpulse, -1);
 125         else if(list == 2)
 126                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 127 }
 128
 129 // prev weapon
 130 void W_PreviousWeapon(float list)
 131 {
 132         if(list == 0)
 133                 W_CycleWeapon(weaponorder_byid, +1);
 134         else if(list == 1)
 135                 W_CycleWeapon(self.weaponorder_byimpulse, +1);
 136         else if(list == 2)
 137                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 138 }
 139
 140 float w_getbestweapon(entity e)
 141 {
 142         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, FALSE, TRUE);
 143 };
 144
 145 // generic weapons table
 146 // TODO should they be macros instead?
 147 float weapon_action(float wpn, float wrequest)
 148 {
 149         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 150 };
 151
 152 string W_Name(float weaponid)
 153 {
 154         return (get_weaponinfo(weaponid)).message;
 155 }
 156
 157 float W_WeaponBit(float wpn)
 158 {
 159         return (get_weaponinfo(wpn)).weapons;
 160 }
 161
 162 float W_AmmoItemCode(float wpn)
 163 {
 164         return (get_weaponinfo(wpn)).items;
 165 }
 166
 167 void thrown_wep_think()
 168 {
 169         self.solid = SOLID_TRIGGER;
 170         self.owner = world;
 171         SUB_SetFade(self, time + 20, 1);
 172 }
 173
 174 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 175 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 176 {
 177         entity oldself, wep;
 178         float wa, thisammo, i, j;
 179         string s;
 180         var .float ammofield;
 181
 182         wep = spawn();
 183
 184         setorigin(wep, org);
 185         wep.classname = "droppedweapon";
 186         wep.velocity = velo;
 187         wep.owner = wep.enemy = own;
 188         wep.flags |= FL_TOSSED;
 189         wep.colormap = own.colormap;
 190
 191         wa = W_AmmoItemCode(wpn);
 192         if(wa == IT_SUPERWEAPON || wa == 0)
 193         {
 194                 oldself = self;
 195                 self = wep;
 196                 weapon_defaultspawnfunc(wpn);
 197                 self = oldself;
 198                 if(startitem_failed)
 199                         return string_null;
 200                 wep.think = thrown_wep_think;
 201                 wep.nextthink = time + 0.5;
 202                 return "";
 203         }
 204         else
 205         {
 206                 s = "";
 207                 oldself = self;
 208                 self = wep;
 209                 weapon_defaultspawnfunc(wpn);
 210                 self = oldself;
 211                 if(startitem_failed)
 212                         return string_null;
 213                 if(doreduce)
 214                 {
 215                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 216                         {
 217                                 if(wa & j)
 218                                 {
 219                                         ammofield = Item_CounterField(j);
 220                                         thisammo = min(own.ammofield, wep.ammofield);
 221                                         wep.ammofield = thisammo;
 222                                         own.ammofield -= thisammo;
 223                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 224
 225                                         // if our weapon is loaded, give its load back to the player
 226                                         if(self.weapon_load[self.weapon] > 0)
 227                                         {
 228                                                 own.ammofield += self.weapon_load[self.weapon];
 229                                                 self.weapon_load[self.weapon] = -1; // schedule the weapon for reloading
 230                                         }
 231                                 }
 232                         }
 233                         s = substring(s, 5, -1);
 234                 }
 235                 wep.think = thrown_wep_think;
 236                 wep.nextthink = time + 0.5;
 237                 return s;
 238         }
 239 }
 240
 241 float W_IsWeaponThrowable(float w)
 242 {
 243         float wb, wa;
 244
 245         if (!autocvar_g_pickup_items)
 246                 return 0;
 247         if (g_weaponarena)
 248                 return 0;
 249         if (g_lms)
 250                 return 0;
 251         if (g_ca)
 252                 return 0;
 253         if (g_cts)
 254                 return 0;
 255         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 256                 return 0;
 257
 258         wb = W_WeaponBit(w);
 259         if(!wb)
 260                 return 0;
 261         wa = W_AmmoItemCode(w);
 262         if(start_weapons & wb)
 263         {
 264                 if(wa == IT_SUPERWEAPON && start_items & IT_UNLIMITED_SUPERWEAPONS)
 265                         return 0;
 266                 if(wa != IT_SUPERWEAPON && start_items & IT_UNLIMITED_WEAPON_AMMO)
 267                         return 0;
 268                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 269                 if(wa == 0)
 270                         return 0;
 271         }
 272
 273         return 1;
 274 }
 275
 276 // toss current weapon
 277 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 278 {
 279         local float w, wb;
 280         string a;
 281
 282         w = self.weapon;
 283         if (w == 0)
 284                 return; // just in case
 285         if(self.weapon_forbidchange)
 286                 return;
 287         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 288                 return;
 289         if(!autocvar_g_weapon_throwable)
 290                 return;
 291         if(autocvar_g_weapon_stay == 1)
 292                 return;
 293         if(self.weaponentity.state != WS_READY)
 294                 return;
 295         if(!W_IsWeaponThrowable(w))
 296                 return;
 297
 298         wb = W_WeaponBit(w);
 299         if(self.weapons & wb != wb)
 300                 return;
 301
 302         self.weapons &~= wb;
 303         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 304         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 305         if not(a)
 306                 return;
 307         if(a == "")
 308                 sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 309         else
 310                 sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 311 };
 312
 313 // Bringed back weapon frame
 314 void W_WeaponFrame()
 315 {
 316         vector fo, ri, up;
 317
 318         if (frametime)
 319                 self.weapon_frametime = frametime;
 320
 321         if(((arena_roundbased || g_ca || g_freezetag) && time < warmup) || ((time < game_starttime) && !autocvar_sv_ready_restart_after_countdown))
 322                 return;
 323
 324         if(self.freezetag_frozen == 1)
 325                 return;
 326
 327         if (!self.weaponentity || self.health < 1)
 328                 return; // Dead player can't use weapons and injure impulse commands
 329
 330         if(!self.switchweapon)
 331         {
 332                 self.weapon = 0;
 333                 self.weaponentity.state = WS_CLEAR;
 334                 self.weaponname = "";
 335                 self.items &~= IT_AMMO;
 336                 return;
 337         }
 338
 339         makevectors(self.v_angle);
 340         fo = v_forward; // save them in case the weapon think functions change it
 341         ri = v_right;
 342         up = v_up;
 343
 344         // Change weapon
 345         if (self.weapon != self.switchweapon)
 346         {
 347                 if (self.weaponentity.state == WS_CLEAR)
 348                 {
 349                         setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 350                         self.weaponentity.state = WS_RAISE;
 351                         weapon_action(self.switchweapon, WR_SETUP);
 352
 353                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 354                         entity e;
 355                         e = get_weaponinfo(self.switchweapon);
 356                         if(e.spawnflags & WEP_FLAG_RELOADABLE && cvar(strcat("g_balance_", e.netname, "_reload_ammo"))) // prevent accessing undefined cvars
 357                         {
 358                                 self.clip_load = self.weapon_load[self.switchweapon];
 359                                 self.clip_size = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 360                         }
 361                         else
 362                                 self.clip_load = self.clip_size = 0;
 363
 364                         // VorteX: add player model weapon select frame here
 365                         // setcustomframe(PlayerWeaponRaise);
 366                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_weaponswitchdelay, w_ready);
 367                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 368                 }
 369                 else if (self.weaponentity.state == WS_READY)
 370                 {
 371 #ifndef INDEPENDENT_ATTACK_FINISHED
 372                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
 373                         {
 374 #endif
 375                         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 376                         sound (self, CHAN_WEAPON2, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 377                         self.weaponentity.state = WS_DROP;
 378                         // set up weapon switch think in the future, and start drop anim
 379                         weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_weaponswitchdelay, w_clear);
 380                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 381 #ifndef INDEPENDENT_ATTACK_FINISHED
 382                         }
 383 #endif
 384                 }
 385         }
 386
 387         // LordHavoc: network timing test code
 388         //if (self.button0)
 389         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
 390
 391         float wb;
 392         wb = W_WeaponBit(self.weapon);
 393
 394         // call the think code which may fire the weapon
 395         // and do so multiple times to resolve framerate dependency issues if the
 396         // server framerate is very low and the weapon fire rate very high
 397         local float c;
 398         c = 0;
 399         while (c < W_TICSPERFRAME)
 400         {
 401                 c = c + 1;
 402                 if(wb && ((self.weapons & wb) == 0))
 403                 {
 404                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 405                         wb = 0;
 406                 }
 407                 if(wb)
 408                 {
 409                         v_forward = fo;
 410                         v_right = ri;
 411                         v_up = up;
 412                         self.weaponentity_glowmod = '0 0 0'; // reset glowmod, weapon think function only *might* set it
 413                         weapon_action(self.weapon, WR_THINK);
 414                 }
 415                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
 416                 {
 417                         if(self.weapon_think)
 418                         {
 419                                 v_forward = fo;
 420                                 v_right = ri;
 421                                 v_up = up;
 422                                 self.weapon_think();
 423                         }
 424                         else
 425                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 426                 }
 427         }
 428
 429         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 430         //if (ATTACK_FINISHED(self) < time)
 431         //      ATTACK_FINISHED(self) = time;
 432
 433         //if (self.weapon_nextthink < time)
 434         //      self.weapon_nextthink = time;
 435
 436         // update currentammo incase it has changed
 437 #if 0
 438         if (self.items & IT_CELLS)
 439                 self.currentammo = self.ammo_cells;
 440         else if (self.items & IT_ROCKETS)
 441                 self.currentammo = self.ammo_rockets;
 442         else if (self.items & IT_NAILS)
 443                 self.currentammo = self.ammo_nails;
 444         else if (self.items & IT_SHELLS)
 445                 self.currentammo = self.ammo_shells;
 446         else
 447                 self.currentammo = 1;
 448 #endif
 449 };