qcsrc/server/cl_weapons.qc

   1 void W_TriggerReload()
   2 {
   3     weapon_action(self.weapon, WR_RELOAD);
   4 }
   5
   6 // switch between weapons
   7 void W_SwitchWeapon(float imp)
   8 {
   9         if (self.switchweapon != imp)
  10         {
  11                 if (client_hasweapon(self, imp, TRUE, TRUE))
  12                         W_SwitchWeapon_Force(self, imp);
  13                 else
  14                         self.selectweapon = imp; // update selectweapon ANYWAY
  15         }
  16         else
  17         {
  18                 W_TriggerReload();
  19         }
  20 }
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain, float skipmissing)
  24 {
  25         // We cannot tokenize in this function, as GiveItems calls this
  26         // function. Thus we must use car/cdr.
  27         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  28         string rest;
  29         switchtonext = switchtolast = 0;
  30         first_valid = prev_valid = 0;
  31         float weaponcur;
  32
  33         if(skipmissing || pl.selectweapon == 0)
  34                 weaponcur = pl.switchweapon;
  35         else
  36                 weaponcur = pl.selectweapon;
  37
  38         if(dir == 0)
  39                 switchtonext = 1;
  40
  41         c = 0;
  42
  43         rest = weaponorder;
  44         while(rest != "")
  45         {
  46                 weaponwant = stof(car(rest)); rest = cdr(rest);
  47                 if(imp >= 0)
  48                         if((get_weaponinfo(weaponwant)).impulse != imp)
  49                                 continue;
  50
  51                 ++c;
  52
  53                 if(!skipmissing || client_hasweapon(pl, weaponwant, TRUE, FALSE))
  54                 {
  55                         if(switchtonext)
  56                                 return weaponwant;
  57                         if(!first_valid)
  58                                 first_valid = weaponwant;
  59                         if(weaponwant == weaponcur)
  60                         {
  61                                 if(dir >= 0)
  62                                         switchtonext = 1;
  63                                 else if(prev_valid)
  64                                         return prev_valid;
  65                                 else
  66                                         switchtolast = 1;
  67                         }
  68                         prev_valid = weaponwant;
  69                 }
  70         }
  71         if(first_valid)
  72         {
  73                 if(switchtolast)
  74                         return prev_valid;
  75                 else
  76                         return first_valid;
  77         }
  78         // complain (but only for one weapon on the button that has been pressed)
  79         if(complain)
  80         {
  81                 self.weaponcomplainindex += 1;
  82                 c = mod(self.weaponcomplainindex, c) + 1;
  83                 rest = weaponorder;
  84                 while(rest != "")
  85                 {
  86                         weaponwant = stof(car(rest)); rest = cdr(rest);
  87                         if(imp >= 0)
  88                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  89                                         continue;
  90
  91                         --c;
  92                         if(c == 0)
  93                         {
  94                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  95                                 break;
  96                         }
  97                 }
  98         }
  99         return 0;
 100 }
 101
 102 void W_CycleWeapon(string weaponorder, float dir)
 103 {
 104         float w;
 105         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1, TRUE);
 106         if(w > 0)
 107                 W_SwitchWeapon(w);
 108 }
 109
 110 void W_NextWeaponOnImpulse(float imp)
 111 {
 112         float w;
 113         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1, (self.cvar_cl_weaponimpulsemode == 0));
 114         if(w > 0)
 115                 W_SwitchWeapon(w);
 116 }
 117
 118 // next weapon
 119 void W_NextWeapon(float list)
 120 {
 121         if(list == 0)
 122                 W_CycleWeapon(weaponorder_byid, -1);
 123         else if(list == 1)
 124                 W_CycleWeapon(self.weaponorder_byimpulse, -1);
 125         else if(list == 2)
 126                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 127 }
 128
 129 // prev weapon
 130 void W_PreviousWeapon(float list)
 131 {
 132         if(list == 0)
 133                 W_CycleWeapon(weaponorder_byid, +1);
 134         else if(list == 1)
 135                 W_CycleWeapon(self.weaponorder_byimpulse, +1);
 136         else if(list == 2)
 137                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 138 }
 139
 140 // previously used if exists and has ammo, (second) best otherwise
 141 void W_LastWeapon()
 142 {
 143         if(client_hasweapon(self, self.cnt, TRUE, FALSE))
 144                 W_SwitchWeapon(self.cnt);
 145         else
 146                 W_SwitchToOtherWeapon(self);
 147 }
 148
 149 float w_getbestweapon(entity e)
 150 {
 151         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, FALSE, TRUE);
 152 }
 153
 154 // generic weapons table
 155 // TODO should they be macros instead?
 156 float weapon_action(float wpn, float wrequest)
 157 {
 158         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 159 }
 160
 161 string W_Name(float weaponid)
 162 {
 163         return (get_weaponinfo(weaponid)).message;
 164 }
 165
 166 float W_AmmoItemCode(float wpn)
 167 {
 168         return (get_weaponinfo(wpn)).items & IT_AMMO;
 169 }
 170
 171 .float savenextthink;
 172 void thrown_wep_think()
 173 {
 174         self.owner = world;
 175         float timeleft = self.savenextthink - time;
 176         if(timeleft > 1)
 177                 SUB_SetFade(self, self.savenextthink - 1, 1);
 178         else if(timeleft > 0)
 179                 SUB_SetFade(self, time, timeleft);
 180         else
 181                 SUB_VanishOrRemove(self);
 182 }
 183
 184 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 185 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 186 {
 187         entity oldself, wep;
 188         float wa, thisammo, i, j;
 189         string s;
 190         var .float ammofield;
 191
 192         wep = spawn();
 193
 194         setorigin(wep, org);
 195         wep.classname = "droppedweapon";
 196         wep.velocity = velo;
 197         wep.owner = wep.enemy = own;
 198         wep.flags |= FL_TOSSED;
 199         wep.colormap = own.colormap;
 200
 201         if(WEPSET_CONTAINS_AW(WEPBIT_SUPERWEAPONS, wpn))
 202         {
 203                 if(own.items & IT_UNLIMITED_SUPERWEAPONS)
 204                 {
 205                         wep.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 206                 }
 207                 else
 208                 {
 209                         float superweapons = 1;
 210                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 211                                 if(WEPSET_CONTAINS_AW(WEPBIT_SUPERWEAPONS, i))
 212                                         if(WEPSET_CONTAINS_EW(own, i))
 213                                                 ++superweapons;
 214                         if(superweapons <= 1)
 215                         {
 216                                 wep.superweapons_finished = own.superweapons_finished;
 217                                 own.superweapons_finished = 0;
 218                         }
 219                         else
 220                         {
 221                                 float timeleft = own.superweapons_finished - time;
 222                                 float weptimeleft = timeleft / superweapons;
 223                                 wep.superweapons_finished = time + weptimeleft;
 224                                 own.superweapons_finished -= weptimeleft;
 225                         }
 226                 }
 227         }
 228
 229         wa = W_AmmoItemCode(wpn);
 230         if(wa == 0)
 231         {
 232                 oldself = self;
 233                 self = wep;
 234                 weapon_defaultspawnfunc(wpn);
 235                 self = oldself;
 236                 if(startitem_failed)
 237                         return string_null;
 238                 wep.glowmod = own.weaponentity_glowmod;
 239                 wep.think = thrown_wep_think;
 240                 wep.savenextthink = wep.nextthink;
 241                 wep.nextthink = min(wep.nextthink, time + 0.5);
 242                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 243                 return "";
 244         }
 245         else
 246         {
 247                 s = "";
 248                 oldself = self;
 249                 self = wep;
 250                 weapon_defaultspawnfunc(wpn);
 251                 self = oldself;
 252                 if(startitem_failed)
 253                         return string_null;
 254                 if(doreduce && g_weapon_stay == 2)
 255                 {
 256                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 257                         {
 258                                 if(wa & j)
 259                                 {
 260                                         ammofield = Item_CounterField(j);
 261
 262                                         // if our weapon is loaded, give its load back to the player
 263                                         if(self.(weapon_load[self.weapon]) > 0)
 264                                         {
 265                                                 own.ammofield += self.(weapon_load[self.weapon]);
 266                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 267                                         }
 268
 269                                         wep.ammofield = 0;
 270                                 }
 271                         }
 272                 }
 273                 else if(doreduce)
 274                 {
 275                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 276                         {
 277                                 if(wa & j)
 278                                 {
 279                                         ammofield = Item_CounterField(j);
 280
 281                                         // if our weapon is loaded, give its load back to the player
 282                                         if(self.(weapon_load[self.weapon]) > 0)
 283                                         {
 284                                                 own.ammofield += self.(weapon_load[self.weapon]);
 285                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 286                                         }
 287
 288                                         thisammo = min(own.ammofield, wep.ammofield);
 289                                         wep.ammofield = thisammo;
 290                                         own.ammofield -= thisammo;
 291                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 292                                 }
 293                         }
 294                         s = substring(s, 5, -1);
 295                 }
 296                 wep.glowmod = own.weaponentity_glowmod;
 297                 wep.think = thrown_wep_think;
 298                 wep.savenextthink = wep.nextthink;
 299                 wep.nextthink = min(wep.nextthink, time + 0.5);
 300                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 301
 302                 return s;
 303         }
 304 }
 305
 306 float W_IsWeaponThrowable(float w)
 307 {
 308         float wa;
 309
 310         if (!autocvar_g_pickup_items)
 311                 return 0;
 312         if (g_weaponarena)
 313                 return 0;
 314         if (g_ca)
 315                 return 0;
 316         if (g_cts)
 317                 return 0;
 318         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 319                 return 0;
 320     if(w == 0)
 321         return 0;
 322
 323         wa = W_AmmoItemCode(w);
 324         if(WEPSET_CONTAINS_AW(start_weapons, w))
 325         {
 326                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 327                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 328                         return 0;
 329                 if(wa == 0)
 330                         return 0;
 331         }
 332
 333         return 1;
 334 }
 335
 336 // toss current weapon
 337 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 338 {
 339         float w;
 340         string a;
 341
 342         w = self.weapon;
 343         if (w == 0)
 344                 return; // just in case
 345         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 346                 return;
 347         if(!autocvar_g_weapon_throwable)
 348                 return;
 349         if(self.weaponentity.state != WS_READY)
 350                 return;
 351         if(!W_IsWeaponThrowable(w))
 352                 return;
 353
 354         if(!WEPSET_CONTAINS_EW(self, w))
 355                 return;
 356         WEPSET_ANDNOT_EW(self, w);
 357
 358         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 359         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 360         if not(a)
 361                 return;
 362         if(a == "")
 363                 sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 364         else
 365                 sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 366 }
 367
 368 // Bringed back weapon frame
 369 void W_WeaponFrame()
 370 {
 371         vector fo, ri, up;
 372
 373         if (frametime)
 374                 self.weapon_frametime = frametime;
 375
 376         if(((arena_roundbased || g_ca || g_freezetag) && time < warmup) || ((time < game_starttime) && !autocvar_sv_ready_restart_after_countdown))
 377                 return;
 378
 379         if(self.freezetag_frozen == 1)
 380                 return;
 381
 382         if (!self.weaponentity || self.health < 1)
 383                 return; // Dead player can't use weapons and injure impulse commands
 384
 385         if(!self.switchweapon)
 386         {
 387                 self.weapon = 0;
 388                 self.switchingweapon = 0;
 389                 self.weaponentity.state = WS_CLEAR;
 390                 self.weaponname = "";
 391                 self.items &~= IT_AMMO;
 392                 return;
 393         }
 394
 395         makevectors(self.v_angle);
 396         fo = v_forward; // save them in case the weapon think functions change it
 397         ri = v_right;
 398         up = v_up;
 399
 400         // Change weapon
 401         if (self.weapon != self.switchweapon)
 402         {
 403                 if (self.weaponentity.state == WS_CLEAR)
 404                 {
 405                         // end switching!
 406                         self.switchingweapon = self.switchweapon;
 407
 408                         //setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 409                         self.weaponentity.state = WS_RAISE;
 410                         weapon_action(self.switchweapon, WR_SETUP);
 411
 412                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 413                         entity e;
 414                         e = get_weaponinfo(self.switchweapon);
 415                         if(e.spawnflags & WEP_FLAG_RELOADABLE && cvar(strcat("g_balance_", e.netname, "_reload_ammo"))) // prevent accessing undefined cvars
 416                         {
 417                                 self.clip_load = self.(weapon_load[self.switchweapon]);
 418                                 self.clip_size = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 419                         }
 420                         else
 421                                 self.clip_load = self.clip_size = 0;
 422
 423                         // VorteX: add player model weapon select frame here
 424                         // setcustomframe(PlayerWeaponRaise);
 425                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_weaponswitchdelay, w_ready);
 426                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 427                 }
 428                 else if (self.weaponentity.state == WS_DROP)
 429                 {
 430                         // in dropping phase we can switch at any time
 431                         self.switchingweapon = self.switchweapon;
 432                 }
 433                 else if (self.weaponentity.state == WS_READY)
 434                 {
 435                         // start switching!
 436                         self.switchingweapon = self.switchweapon;
 437
 438 #ifndef INDEPENDENT_ATTACK_FINISHED
 439                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
 440                         {
 441 #endif
 442                         sound (self, CH_WEAPON_SINGLE, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 443                         self.weaponentity.state = WS_DROP;
 444                         // set up weapon switch think in the future, and start drop anim
 445                         weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_weaponswitchdelay, w_clear);
 446                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 447 #ifndef INDEPENDENT_ATTACK_FINISHED
 448                         }
 449 #endif
 450                 }
 451         }
 452
 453         // LordHavoc: network timing test code
 454         //if (self.button0)
 455         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
 456
 457         float w;
 458         w = self.weapon;
 459
 460         // call the think code which may fire the weapon
 461         // and do so multiple times to resolve framerate dependency issues if the
 462         // server framerate is very low and the weapon fire rate very high
 463         float c;
 464         c = 0;
 465         while (c < W_TICSPERFRAME)
 466         {
 467                 c = c + 1;
 468                 if(w && !WEPSET_CONTAINS_EW(self, w))
 469                 {
 470                         if(self.weapon == self.switchweapon)
 471                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 472                         w = 0;
 473                 }
 474
 475                 v_forward = fo;
 476                 v_right = ri;
 477                 v_up = up;
 478
 479                 if(w)
 480                         weapon_action(self.weapon, WR_THINK);
 481                 else
 482                         weapon_action(self.weapon, WR_GONETHINK);
 483
 484                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
 485                 {
 486                         if(self.weapon_think)
 487                         {
 488                                 v_forward = fo;
 489                                 v_right = ri;
 490                                 v_up = up;
 491                                 self.weapon_think();
 492                         }
 493                         else
 494                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 495                 }
 496         }
 497
 498         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 499         //if (ATTACK_FINISHED(self) < time)
 500         //      ATTACK_FINISHED(self) = time;
 501
 502         //if (self.weapon_nextthink < time)
 503         //      self.weapon_nextthink = time;
 504
 505         // update currentammo incase it has changed
 506 #if 0
 507         if (self.items & IT_CELLS)
 508                 self.currentammo = self.ammo_cells;
 509         else if (self.items & IT_ROCKETS)
 510                 self.currentammo = self.ammo_rockets;
 511         else if (self.items & IT_NAILS)
 512                 self.currentammo = self.ammo_nails;
 513         else if (self.items & IT_SHELLS)
 514                 self.currentammo = self.ammo_shells;
 515         else
 516                 self.currentammo = 1;
 517 #endif
 518 }
 519
 520 string W_Apply_Weaponreplace(string in)
 521 {
 522         float n = tokenize_console(in);
 523         string out = "";
 524         float i;
 525         for(i = 0; i < n; ++i)
 526         {
 527                 string s = argv(i);
 528                 string r = cvar_string(strcat("g_weaponreplace_", s));
 529                 if(r == "")
 530                         out = strcat(out, " ", s);
 531                 else if(r != "0")
 532                         out = strcat(out, " ", r);
 533         }
 534         return substring(out, 1, -1);
 535 }