qcsrc/server/cl_weapons.qc

   1 void W_TriggerReload()
   2 {
   3     weapon_action(self.weapon, WR_RELOAD);
   4 }
   5
   6 // switch between weapons
   7 void W_SwitchWeapon(float imp)
   8 {
   9         if (self.switchweapon != imp)
  10         {
  11                 if (client_hasweapon(self, imp, TRUE, TRUE))
  12                         W_SwitchWeapon_Force(self, imp);
  13                 else
  14                         self.selectweapon = imp; // update selectweapon ANYWAY
  15         }
  16         else
  17         {
  18                 W_TriggerReload();
  19         }
  20 };
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain, float skipmissing)
  24 {
  25         // We cannot tokenize in this function, as GiveItems calls this
  26         // function. Thus we must use car/cdr.
  27         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  28         string rest;
  29         switchtonext = switchtolast = 0;
  30         first_valid = prev_valid = 0;
  31         float weaponcur;
  32
  33         if(skipmissing || pl.selectweapon == 0)
  34                 weaponcur = pl.switchweapon;
  35         else
  36                 weaponcur = pl.selectweapon;
  37
  38         if(dir == 0)
  39                 switchtonext = 1;
  40
  41         c = 0;
  42
  43         rest = weaponorder;
  44         while(rest != "")
  45         {
  46                 weaponwant = stof(car(rest)); rest = cdr(rest);
  47                 if(imp >= 0)
  48                         if((get_weaponinfo(weaponwant)).impulse != imp)
  49                                 continue;
  50
  51                 ++c;
  52
  53                 if(!skipmissing || client_hasweapon(pl, weaponwant, TRUE, FALSE))
  54                 {
  55                         if(switchtonext)
  56                                 return weaponwant;
  57                         if(!first_valid)
  58                                 first_valid = weaponwant;
  59                         if(weaponwant == weaponcur)
  60                         {
  61                                 if(dir >= 0)
  62                                         switchtonext = 1;
  63                                 else if(prev_valid)
  64                                         return prev_valid;
  65                                 else
  66                                         switchtolast = 1;
  67                         }
  68                         prev_valid = weaponwant;
  69                 }
  70         }
  71         if(first_valid)
  72         {
  73                 if(switchtolast)
  74                         return prev_valid;
  75                 else
  76                         return first_valid;
  77         }
  78         // complain (but only for one weapon on the button that has been pressed)
  79         if(complain)
  80         {
  81                 self.weaponcomplainindex += 1;
  82                 c = mod(self.weaponcomplainindex, c) + 1;
  83                 rest = weaponorder;
  84                 while(rest != "")
  85                 {
  86                         weaponwant = stof(car(rest)); rest = cdr(rest);
  87                         if(imp >= 0)
  88                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  89                                         continue;
  90
  91                         --c;
  92                         if(c == 0)
  93                         {
  94                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  95                                 break;
  96                         }
  97                 }
  98         }
  99         return 0;
 100 }
 101
 102 void W_CycleWeapon(string weaponorder, float dir)
 103 {
 104         float w;
 105         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1, TRUE);
 106         if(w > 0)
 107                 W_SwitchWeapon(w);
 108 }
 109
 110 void W_NextWeaponOnImpulse(float imp)
 111 {
 112         float w;
 113         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1, (self.cvar_cl_weaponimpulsemode == 0));
 114         if(w > 0)
 115                 W_SwitchWeapon(w);
 116 }
 117
 118 // next weapon
 119 void W_NextWeapon(float list)
 120 {
 121         if(list == 0)
 122                 W_CycleWeapon(weaponorder_byid, -1);
 123         else if(list == 1)
 124                 W_CycleWeapon(self.weaponorder_byimpulse, -1);
 125         else if(list == 2)
 126                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 127 }
 128
 129 // prev weapon
 130 void W_PreviousWeapon(float list)
 131 {
 132         if(list == 0)
 133                 W_CycleWeapon(weaponorder_byid, +1);
 134         else if(list == 1)
 135                 W_CycleWeapon(self.weaponorder_byimpulse, +1);
 136         else if(list == 2)
 137                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 138 }
 139
 140 float w_getbestweapon(entity e)
 141 {
 142         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, FALSE, TRUE);
 143 };
 144
 145 // generic weapons table
 146 // TODO should they be macros instead?
 147 float weapon_action(float wpn, float wrequest)
 148 {
 149         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 150 };
 151
 152 string W_Name(float weaponid)
 153 {
 154         return (get_weaponinfo(weaponid)).message;
 155 }
 156
 157 float W_WeaponBit(float wpn)
 158 {
 159         return (get_weaponinfo(wpn)).weapons;
 160 }
 161
 162 float W_AmmoItemCode(float wpn)
 163 {
 164         return (get_weaponinfo(wpn)).items;
 165 }
 166
 167 void thrown_wep_think()
 168 {
 169         self.solid = SOLID_TRIGGER;
 170         self.owner = world;
 171         SUB_SetFade(self, time + 20, 1);
 172 }
 173
 174 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 175 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 176 {
 177         entity oldself, wep;
 178         float wa, thisammo, i, j;
 179         string s;
 180         var .float ammofield;
 181
 182         wep = spawn();
 183
 184         setorigin(wep, org);
 185         wep.classname = "droppedweapon";
 186         wep.velocity = velo;
 187         wep.owner = wep.enemy = own;
 188         wep.flags |= FL_TOSSED;
 189         wep.colormap = own.colormap;
 190
 191         wa = W_AmmoItemCode(wpn);
 192         if(wa == IT_SUPERWEAPON || wa == 0)
 193         {
 194                 oldself = self;
 195                 self = wep;
 196                 weapon_defaultspawnfunc(wpn);
 197                 self = oldself;
 198                 if(startitem_failed)
 199                         return string_null;
 200                 wep.glowmod = own.weaponentity_glowmod;
 201                 wep.think = thrown_wep_think;
 202                 wep.nextthink = time + 0.5;
 203                 return "";
 204         }
 205         else
 206         {
 207                 s = "";
 208                 oldself = self;
 209                 self = wep;
 210                 weapon_defaultspawnfunc(wpn);
 211                 self = oldself;
 212                 if(startitem_failed)
 213                         return string_null;
 214                 if(doreduce)
 215                 {
 216                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 217                         {
 218                                 if(wa & j)
 219                                 {
 220                                         ammofield = Item_CounterField(j);
 221                                         thisammo = min(own.ammofield, wep.ammofield);
 222                                         wep.ammofield = thisammo;
 223                                         own.ammofield -= thisammo;
 224                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 225
 226                                         // if our weapon is loaded, give its load back to the player
 227                                         if(self.weapon_load[self.weapon] > 0)
 228                                         {
 229                                                 own.ammofield += self.weapon_load[self.weapon];
 230                                                 self.weapon_load[self.weapon] = -1; // schedule the weapon for reloading
 231                                         }
 232                                 }
 233                         }
 234                         s = substring(s, 5, -1);
 235                 }
 236                 wep.glowmod = own.weaponentity_glowmod;
 237                 wep.think = thrown_wep_think;
 238                 wep.nextthink = time + 0.5;
 239                 return s;
 240         }
 241 }
 242
 243 float W_IsWeaponThrowable(float w)
 244 {
 245         float wb, wa;
 246
 247         if (!autocvar_g_pickup_items)
 248                 return 0;
 249         if (g_weaponarena)
 250                 return 0;
 251         if (g_lms)
 252                 return 0;
 253         if (g_ca)
 254                 return 0;
 255         if (g_cts)
 256                 return 0;
 257         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 258                 return 0;
 259
 260         wb = W_WeaponBit(w);
 261         if(!wb)
 262                 return 0;
 263         wa = W_AmmoItemCode(w);
 264         if(start_weapons & wb)
 265         {
 266                 if(wa == IT_SUPERWEAPON && start_items & IT_UNLIMITED_SUPERWEAPONS)
 267                         return 0;
 268                 if(wa != IT_SUPERWEAPON && start_items & IT_UNLIMITED_WEAPON_AMMO)
 269                         return 0;
 270                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 271                 if(wa == 0)
 272                         return 0;
 273         }
 274
 275         return 1;
 276 }
 277
 278 // toss current weapon
 279 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 280 {
 281         local float w, wb;
 282         string a;
 283
 284         w = self.weapon;
 285         if (w == 0)
 286                 return; // just in case
 287         if(self.weapon_forbidchange)
 288                 return;
 289         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 290                 return;
 291         if(!autocvar_g_weapon_throwable)
 292                 return;
 293         if(autocvar_g_weapon_stay == 1)
 294                 return;
 295         if(self.weaponentity.state != WS_READY)
 296                 return;
 297         if(!W_IsWeaponThrowable(w))
 298                 return;
 299
 300         wb = W_WeaponBit(w);
 301         if(self.weapons & wb != wb)
 302                 return;
 303
 304         self.weapons &~= wb;
 305         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 306         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 307         if not(a)
 308                 return;
 309         if(a == "")
 310                 sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 311         else
 312                 sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 313 };
 314
 315 // Bringed back weapon frame
 316 void W_WeaponFrame()
 317 {
 318         vector fo, ri, up;
 319
 320         if (frametime)
 321                 self.weapon_frametime = frametime;
 322
 323         if(((arena_roundbased || g_ca || g_freezetag) && time < warmup) || ((time < game_starttime) && !autocvar_sv_ready_restart_after_countdown))
 324                 return;
 325
 326         if(self.freezetag_frozen == 1)
 327                 return;
 328
 329         if (!self.weaponentity || self.health < 1)
 330                 return; // Dead player can't use weapons and injure impulse commands
 331
 332         if(!self.switchweapon)
 333         {
 334                 self.weapon = 0;
 335                 self.weaponentity.state = WS_CLEAR;
 336                 self.weaponname = "";
 337                 self.items &~= IT_AMMO;
 338                 return;
 339         }
 340
 341         makevectors(self.v_angle);
 342         fo = v_forward; // save them in case the weapon think functions change it
 343         ri = v_right;
 344         up = v_up;
 345
 346         // Change weapon
 347         if (self.weapon != self.switchweapon)
 348         {
 349                 if (self.weaponentity.state == WS_CLEAR)
 350                 {
 351                         setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 352                         self.weaponentity.state = WS_RAISE;
 353                         weapon_action(self.switchweapon, WR_SETUP);
 354
 355                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 356                         entity e;
 357                         e = get_weaponinfo(self.switchweapon);
 358                         if(e.spawnflags & WEP_FLAG_RELOADABLE && cvar(strcat("g_balance_", e.netname, "_reload_ammo"))) // prevent accessing undefined cvars
 359                         {
 360                                 self.clip_load = self.weapon_load[self.switchweapon];
 361                                 self.clip_size = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 362                         }
 363                         else
 364                                 self.clip_load = self.clip_size = 0;
 365
 366                         // VorteX: add player model weapon select frame here
 367                         // setcustomframe(PlayerWeaponRaise);
 368                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_weaponswitchdelay, w_ready);
 369                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 370                 }
 371                 else if (self.weaponentity.state == WS_READY)
 372                 {
 373 #ifndef INDEPENDENT_ATTACK_FINISHED
 374                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
 375                         {
 376 #endif
 377                         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 378                         sound (self, CHAN_WEAPON2, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 379                         self.weaponentity.state = WS_DROP;
 380                         // set up weapon switch think in the future, and start drop anim
 381                         weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_weaponswitchdelay, w_clear);
 382                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 383 #ifndef INDEPENDENT_ATTACK_FINISHED
 384                         }
 385 #endif
 386                 }
 387         }
 388
 389         // LordHavoc: network timing test code
 390         //if (self.button0)
 391         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
 392
 393         float wb;
 394         wb = W_WeaponBit(self.weapon);
 395
 396         // call the think code which may fire the weapon
 397         // and do so multiple times to resolve framerate dependency issues if the
 398         // server framerate is very low and the weapon fire rate very high
 399         local float c;
 400         c = 0;
 401         while (c < W_TICSPERFRAME)
 402         {
 403                 c = c + 1;
 404                 if(wb && ((self.weapons & wb) == 0))
 405                 {
 406                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 407                         wb = 0;
 408                 }
 409                 if(wb)
 410                 {
 411                         v_forward = fo;
 412                         v_right = ri;
 413                         v_up = up;
 414                         weapon_action(self.weapon, WR_THINK);
 415                 }
 416                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
 417                 {
 418                         if(self.weapon_think)
 419                         {
 420                                 v_forward = fo;
 421                                 v_right = ri;
 422                                 v_up = up;
 423                                 self.weapon_think();
 424                         }
 425                         else
 426                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 427                 }
 428         }
 429
 430         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 431         //if (ATTACK_FINISHED(self) < time)
 432         //      ATTACK_FINISHED(self) = time;
 433
 434         //if (self.weapon_nextthink < time)
 435         //      self.weapon_nextthink = time;
 436
 437         // update currentammo incase it has changed
 438 #if 0
 439         if (self.items & IT_CELLS)
 440                 self.currentammo = self.ammo_cells;
 441         else if (self.items & IT_ROCKETS)
 442                 self.currentammo = self.ammo_rockets;
 443         else if (self.items & IT_NAILS)
 444                 self.currentammo = self.ammo_nails;
 445         else if (self.items & IT_SHELLS)
 446                 self.currentammo = self.ammo_shells;
 447         else
 448                 self.currentammo = 1;
 449 #endif
 450 };