qcsrc/server/cl_weapons.qc

   1 void W_TriggerReload()
   2 {
   3     weapon_action(self.weapon, WR_RELOAD);
   4 }
   5
   6 // switch between weapons
   7 void W_SwitchWeapon(float imp)
   8 {
   9         if (self.switchweapon != imp)
  10         {
  11                 if (client_hasweapon(self, imp, TRUE, TRUE))
  12                         W_SwitchWeapon_Force(self, imp);
  13                 else
  14                         self.selectweapon = imp; // update selectweapon ANYWAY
  15         }
  16         else
  17         {
  18                 W_TriggerReload();
  19         }
  20 }
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain, float skipmissing)
  24 {
  25         // We cannot tokenize in this function, as GiveItems calls this
  26         // function. Thus we must use car/cdr.
  27         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  28         string rest;
  29         switchtonext = switchtolast = 0;
  30         first_valid = prev_valid = 0;
  31         float weaponcur;
  32
  33         if(skipmissing || pl.selectweapon == 0)
  34                 weaponcur = pl.switchweapon;
  35         else
  36                 weaponcur = pl.selectweapon;
  37
  38         if(dir == 0)
  39                 switchtonext = 1;
  40
  41         c = 0;
  42
  43         rest = weaponorder;
  44         while(rest != "")
  45         {
  46                 weaponwant = stof(car(rest)); rest = cdr(rest);
  47                 if(imp >= 0)
  48                         if((get_weaponinfo(weaponwant)).impulse != imp)
  49                                 continue;
  50
  51                 ++c;
  52
  53                 if(!skipmissing || client_hasweapon(pl, weaponwant, TRUE, FALSE))
  54                 {
  55                         if(switchtonext)
  56                                 return weaponwant;
  57                         if(!first_valid)
  58                                 first_valid = weaponwant;
  59                         if(weaponwant == weaponcur)
  60                         {
  61                                 if(dir >= 0)
  62                                         switchtonext = 1;
  63                                 else if(prev_valid)
  64                                         return prev_valid;
  65                                 else
  66                                         switchtolast = 1;
  67                         }
  68                         prev_valid = weaponwant;
  69                 }
  70         }
  71         if(first_valid)
  72         {
  73                 if(switchtolast)
  74                         return prev_valid;
  75                 else
  76                         return first_valid;
  77         }
  78         // complain (but only for one weapon on the button that has been pressed)
  79         if(complain)
  80         {
  81                 self.weaponcomplainindex += 1;
  82                 c = mod(self.weaponcomplainindex, c) + 1;
  83                 rest = weaponorder;
  84                 while(rest != "")
  85                 {
  86                         weaponwant = stof(car(rest)); rest = cdr(rest);
  87                         if(imp >= 0)
  88                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  89                                         continue;
  90
  91                         --c;
  92                         if(c == 0)
  93                         {
  94                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  95                                 break;
  96                         }
  97                 }
  98         }
  99         return 0;
 100 }
 101
 102 void W_CycleWeapon(string weaponorder, float dir)
 103 {
 104         float w;
 105         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1, TRUE);
 106         if(w > 0)
 107                 W_SwitchWeapon(w);
 108 }
 109
 110 void W_NextWeaponOnImpulse(float imp)
 111 {
 112         float w;
 113         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1, (self.cvar_cl_weaponimpulsemode == 0));
 114         if(w > 0)
 115                 W_SwitchWeapon(w);
 116 }
 117
 118 // next weapon
 119 void W_NextWeapon(float list)
 120 {
 121         if(list == 0)
 122                 W_CycleWeapon(weaponorder_byid, -1);
 123         else if(list == 1)
 124                 W_CycleWeapon(self.weaponorder_byimpulse, -1);
 125         else if(list == 2)
 126                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 127 }
 128
 129 // prev weapon
 130 void W_PreviousWeapon(float list)
 131 {
 132         if(list == 0)
 133                 W_CycleWeapon(weaponorder_byid, +1);
 134         else if(list == 1)
 135                 W_CycleWeapon(self.weaponorder_byimpulse, +1);
 136         else if(list == 2)
 137                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 138 }
 139
 140 // previously used if exists and has ammo, (second) best otherwise
 141 void W_LastWeapon()
 142 {
 143         if(client_hasweapon(self, self.cnt, TRUE, FALSE))
 144                 W_SwitchWeapon(self.cnt);
 145         else
 146                 W_SwitchToOtherWeapon(self);
 147 }
 148
 149 float w_getbestweapon(entity e)
 150 {
 151         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, FALSE, TRUE);
 152 }
 153
 154 // generic weapons table
 155 // TODO should they be macros instead?
 156 float weapon_action(float wpn, float wrequest)
 157 {
 158         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 159 }
 160
 161 string W_Name(float weaponid)
 162 {
 163         return (get_weaponinfo(weaponid)).message;
 164 }
 165
 166 float W_WeaponBit(float wpn)
 167 {
 168         return (get_weaponinfo(wpn)).weapons;
 169 }
 170
 171 float W_AmmoItemCode(float wpn)
 172 {
 173         return (get_weaponinfo(wpn)).items & IT_AMMO;
 174 }
 175
 176 .float savenextthink;
 177 void thrown_wep_think()
 178 {
 179         self.owner = world;
 180         float timeleft = self.savenextthink - time;
 181         if(timeleft > 1)
 182                 SUB_SetFade(self, self.savenextthink - 1, 1);
 183         else if(timeleft > 0)
 184                 SUB_SetFade(self, time, timeleft);
 185         else
 186                 SUB_VanishOrRemove(self);
 187 }
 188
 189 void thrown_wep_ode_think()
 190 {
 191         self.nextthink = time;
 192         if(!self.owner.modelindex)
 193                 remove(self); // the real weapon is gone, remove this
 194 }
 195
 196 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 197 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 198 {
 199         entity oldself, wep;
 200         float wa, thisammo, i, j;
 201         string s;
 202         var .float ammofield;
 203
 204         wep = spawn();
 205
 206         setorigin(wep, org);
 207         wep.classname = "droppedweapon";
 208         wep.velocity = velo;
 209         wep.owner = wep.enemy = own;
 210         wep.flags |= FL_TOSSED;
 211         wep.colormap = own.colormap;
 212
 213         if(W_WeaponBit(wpn) & WEPBIT_SUPERWEAPONS)
 214         {
 215                 if(own.items & IT_UNLIMITED_SUPERWEAPONS)
 216                 {
 217                         wep.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 218                 }
 219                 else
 220                 {
 221                         float superweapons = 1;
 222                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 223                                 if(own.weapons & WEPBIT_SUPERWEAPONS & W_WeaponBit(i))
 224                                         ++superweapons;
 225                         if(superweapons <= 1)
 226                         {
 227                                 wep.superweapons_finished = own.superweapons_finished;
 228                                 own.superweapons_finished = 0;
 229                         }
 230                         else
 231                         {
 232                                 float timeleft = own.superweapons_finished - time;
 233                                 float weptimeleft = timeleft / superweapons;
 234                                 wep.superweapons_finished = time + weptimeleft;
 235                                 own.superweapons_finished -= weptimeleft;
 236                         }
 237                 }
 238         }
 239
 240         wa = W_AmmoItemCode(wpn);
 241         if(wa == 0)
 242         {
 243                 oldself = self;
 244                 self = wep;
 245                 weapon_defaultspawnfunc(wpn);
 246                 self = oldself;
 247                 if(startitem_failed)
 248                         return string_null;
 249                 wep.glowmod = own.weaponentity_glowmod;
 250                 wep.think = thrown_wep_think;
 251                 wep.savenextthink = wep.nextthink;
 252                 wep.nextthink = min(wep.nextthink, time + 0.5);
 253                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 254                 return "";
 255         }
 256         else
 257         {
 258                 s = "";
 259                 oldself = self;
 260                 self = wep;
 261                 weapon_defaultspawnfunc(wpn);
 262                 self = oldself;
 263                 if(startitem_failed)
 264                         return string_null;
 265                 if(doreduce && g_weapon_stay == 2)
 266                 {
 267                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 268                         {
 269                                 if(wa & j)
 270                                 {
 271                                         ammofield = Item_CounterField(j);
 272
 273                                         // if our weapon is loaded, give its load back to the player
 274                                         if(self.(weapon_load[self.weapon]) > 0)
 275                                         {
 276                                                 own.ammofield += self.(weapon_load[self.weapon]);
 277                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 278                                         }
 279
 280                                         wep.ammofield = 0;
 281                                 }
 282                         }
 283                 }
 284                 else if(doreduce)
 285                 {
 286                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 287                         {
 288                                 if(wa & j)
 289                                 {
 290                                         ammofield = Item_CounterField(j);
 291
 292                                         // if our weapon is loaded, give its load back to the player
 293                                         if(self.(weapon_load[self.weapon]) > 0)
 294                                         {
 295                                                 own.ammofield += self.(weapon_load[self.weapon]);
 296                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 297                                         }
 298
 299                                         thisammo = min(own.ammofield, wep.ammofield);
 300                                         wep.ammofield = thisammo;
 301                                         own.ammofield -= thisammo;
 302                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 303                                 }
 304                         }
 305                         s = substring(s, 5, -1);
 306                 }
 307                 wep.glowmod = own.weaponentity_glowmod;
 308                 wep.think = thrown_wep_think;
 309                 wep.savenextthink = wep.nextthink;
 310                 wep.nextthink = min(wep.nextthink, time + 0.5);
 311                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 312
 313                 // make the dropped weapon physical
 314                 /*if(autocvar_physics_ode && autocvar_physics_ode_droppedweapon)
 315                 {
 316                         entity wep2;
 317                         wep2 = spawn();
 318                         setsize(wep2, wep.mins, wep.maxs);
 319                         setorigin(wep2, wep.origin);
 320                         wep2.angles = wep.angles;
 321                         wep2.velocity = velo;
 322
 323                         wep2.classname = "droppedweapon2";
 324                         wep2.owner = wep;
 325                         wep2.solid = SOLID_CORPSE;
 326                         wep2.movetype = MOVETYPE_PHYSICS;
 327                         wep2.takedamage = DAMAGE_AIM;
 328                         wep2.damageforcescale = autocvar_physics_ode_droppedweapon_damageforcescale;
 329
 330                         wep2.think = thrown_wep_ode_think;
 331                         wep2.nextthink = time;
 332
 333                         wep.effects |= EF_NOMODELFLAGS; // disable the spinning
 334                         wep.movetype = MOVETYPE_FOLLOW;
 335                         wep.aiment = wep2;
 336                 }*/
 337
 338                 return s;
 339         }
 340 }
 341
 342 float W_IsWeaponThrowable(float w)
 343 {
 344         float wb, wa;
 345
 346         if (!autocvar_g_pickup_items)
 347                 return 0;
 348         if (g_weaponarena)
 349                 return 0;
 350         if (g_lms)
 351                 return 0;
 352         if (g_ca)
 353                 return 0;
 354         if (g_cts)
 355                 return 0;
 356         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 357                 return 0;
 358
 359         wb = W_WeaponBit(w);
 360         if(!wb)
 361                 return 0;
 362         wa = W_AmmoItemCode(w);
 363         if(start_weapons & wb)
 364         {
 365                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 366                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 367                         return 0;
 368                 if(wa == 0)
 369                         return 0;
 370         }
 371
 372         return 1;
 373 }
 374
 375 // toss current weapon
 376 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 377 {
 378         float w, wb;
 379         string a;
 380
 381         w = self.weapon;
 382         if (w == 0)
 383                 return; // just in case
 384         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 385                 return;
 386         if(!autocvar_g_weapon_throwable)
 387                 return;
 388         if(self.weaponentity.state != WS_READY)
 389                 return;
 390         if(!W_IsWeaponThrowable(w))
 391                 return;
 392
 393         wb = W_WeaponBit(w);
 394         if(self.weapons & wb != wb)
 395                 return;
 396
 397         self.weapons &~= wb;
 398         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 399         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 400         if not(a)
 401                 return;
 402         if(a == "")
 403                 sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 404         else
 405                 sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 406 }
 407
 408 // Bringed back weapon frame
 409 void W_WeaponFrame()
 410 {
 411         vector fo, ri, up;
 412
 413         if (frametime)
 414                 self.weapon_frametime = frametime;
 415
 416         if(((arena_roundbased || g_ca || g_freezetag) && time < warmup) || ((time < game_starttime) && !autocvar_sv_ready_restart_after_countdown))
 417                 return;
 418
 419         if(self.freezetag_frozen == 1)
 420                 return;
 421
 422         if (!self.weaponentity || self.health < 1)
 423                 return; // Dead player can't use weapons and injure impulse commands
 424
 425         if(!self.switchweapon)
 426         {
 427                 self.weapon = 0;
 428                 self.switchingweapon = 0;
 429                 self.weaponentity.state = WS_CLEAR;
 430                 self.weaponname = "";
 431                 self.items &~= IT_AMMO;
 432                 return;
 433         }
 434
 435         makevectors(self.v_angle);
 436         fo = v_forward; // save them in case the weapon think functions change it
 437         ri = v_right;
 438         up = v_up;
 439
 440         // Change weapon
 441         if (self.weapon != self.switchweapon)
 442         {
 443                 if (self.weaponentity.state == WS_CLEAR)
 444                 {
 445                         // end switching!
 446                         self.switchingweapon = self.switchweapon;
 447
 448                         //setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 449                         self.weaponentity.state = WS_RAISE;
 450                         weapon_action(self.switchweapon, WR_SETUP);
 451
 452                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 453                         entity e;
 454                         e = get_weaponinfo(self.switchweapon);
 455                         if(e.spawnflags & WEP_FLAG_RELOADABLE && cvar(strcat("g_balance_", e.netname, "_reload_ammo"))) // prevent accessing undefined cvars
 456                         {
 457                                 self.clip_load = self.(weapon_load[self.switchweapon]);
 458                                 self.clip_size = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 459                         }
 460                         else
 461                                 self.clip_load = self.clip_size = 0;
 462
 463                         // VorteX: add player model weapon select frame here
 464                         // setcustomframe(PlayerWeaponRaise);
 465                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_weaponswitchdelay, w_ready);
 466                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 467                 }
 468                 else if (self.weaponentity.state == WS_DROP)
 469                 {
 470                         // in dropping phase we can switch at any time
 471                         self.switchingweapon = self.switchweapon;
 472                 }
 473                 else if (self.weaponentity.state == WS_READY)
 474                 {
 475                         // start switching!
 476                         self.switchingweapon = self.switchweapon;
 477
 478 #ifndef INDEPENDENT_ATTACK_FINISHED
 479                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
 480                         {
 481 #endif
 482                         sound (self, CH_WEAPON_SINGLE, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 483                         self.weaponentity.state = WS_DROP;
 484                         // set up weapon switch think in the future, and start drop anim
 485                         weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_weaponswitchdelay, w_clear);
 486                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 487 #ifndef INDEPENDENT_ATTACK_FINISHED
 488                         }
 489 #endif
 490                 }
 491         }
 492
 493         // LordHavoc: network timing test code
 494         //if (self.button0)
 495         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
 496
 497         float wb;
 498         wb = W_WeaponBit(self.weapon);
 499
 500         // call the think code which may fire the weapon
 501         // and do so multiple times to resolve framerate dependency issues if the
 502         // server framerate is very low and the weapon fire rate very high
 503         float c;
 504         c = 0;
 505         while (c < W_TICSPERFRAME)
 506         {
 507                 c = c + 1;
 508                 if(wb && ((self.weapons & wb) == 0))
 509                 {
 510                         if(self.weapon == self.switchweapon)
 511                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 512                         wb = 0;
 513                 }
 514
 515                 v_forward = fo;
 516                 v_right = ri;
 517                 v_up = up;
 518
 519                 if(wb)
 520                         weapon_action(self.weapon, WR_THINK);
 521                 else
 522                         weapon_action(self.weapon, WR_GONETHINK);
 523
 524                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
 525                 {
 526                         if(self.weapon_think)
 527                         {
 528                                 v_forward = fo;
 529                                 v_right = ri;
 530                                 v_up = up;
 531                                 self.weapon_think();
 532                         }
 533                         else
 534                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 535                 }
 536         }
 537
 538         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 539         //if (ATTACK_FINISHED(self) < time)
 540         //      ATTACK_FINISHED(self) = time;
 541
 542         //if (self.weapon_nextthink < time)
 543         //      self.weapon_nextthink = time;
 544
 545         // update currentammo incase it has changed
 546 #if 0
 547         if (self.items & IT_CELLS)
 548                 self.currentammo = self.ammo_cells;
 549         else if (self.items & IT_ROCKETS)
 550                 self.currentammo = self.ammo_rockets;
 551         else if (self.items & IT_NAILS)
 552                 self.currentammo = self.ammo_nails;
 553         else if (self.items & IT_SHELLS)
 554                 self.currentammo = self.ammo_shells;
 555         else
 556                 self.currentammo = 1;
 557 #endif
 558 }