2770d43147a09eb400fc21cc3155f4b2f9bc6863
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
23                         else
24                                 t = t * cvar("g_balance_rune_speed_atkrate");
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * cvar("g_balance_curse_slow_atkrate");
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
73         {
74                 thisv = targ.origin;
75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
79                 if(i || j || k)
80                 {
81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
84                 }
85                 else
86                 {
87                         // first run
88                         mi = ma = thisv;
89                 }
90         }
91
92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
95         ret_z = thisv_z - myv_z;
96         return ret;
97 }
98
99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
100 {
101         vector hitplot;
102         vector org;
103         float lag;
104
105         if(player.hitplotfh >= 0)
106         {
107                 lag = ANTILAG_LATENCY(player);
108                 if(lag < 0.001)
109                         lag = 0;
110                 if(clienttype(player) != CLIENTTYPE_REAL)
111                         lag = 0; // only antilag for clients
112
113                 org = player.origin + player.view_ofs;
114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
115                 if(trace_ent.flags & FL_CLIENT)
116                 {
117                         antilag_takeback(trace_ent, time - lag);
118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
119                         antilag_restore(trace_ent);
120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
122                 }
123         }
124 }
125
126 vector w_shotorg;
127 vector w_shotdir;
128 vector w_shotend;
129
130 // this function calculates w_shotorg and w_shotdir based on the weapon model
131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
132 // make sure you call makevectors first (FIXME?)
133 .float prevstrengthsound;
134 .float prevstrengthsoundattempt;
135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage, float range)
136 {
137         float nudge = 1; // added to traceline target and subtracted from result
138         local float oldsolid;
139         vector vecs, dv;
140         oldsolid = ent.dphitcontentsmask;
141         if(ent.weapon == WEP_CAMPINGRIFLE)
142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
143         else
144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
145         if(antilag)
146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
147                 // passing world, because we do NOT want it to touch dphitcontentsmask
148         else
149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
151
152         vector vf, vr, vu;
153         vf = v_forward;
154         vr = v_right;
155         vu = v_up;
156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
157         v_forward = vf;
158         v_right = vr;
159         v_up = vu;
160
161         // track max damage
162         if(accuracy_canbegooddamage(ent))
163                 accuracy_add(ent, ent.weapon, maxdamage, 0);
164
165         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
166
167         if(ent.weaponentity.movedir_x > 0)
168                 vecs = ent.weaponentity.movedir;
169         else
170                 vecs = '0 0 0';
171         if(debug_shotorg != '0 0 0')
172                 vecs = debug_shotorg;
173
174         dv = v_right * -vecs_y + v_up * vecs_z;
175         w_shotorg = ent.origin + ent.view_ofs + dv;
176
177         // now move the shotorg forward as much as requested if possible
178         if(antilag)
179         {
180                 if(ent.antilag_debug)
181                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
182                 else
183                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
184         }
185         else
186                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
187         w_shotorg = trace_endpos - v_forward * nudge;
188         // calculate the shotdir from the chosen shotorg
189         w_shotdir = normalize(w_shotend - w_shotorg);
190
191         if (antilag)
192         if (!ent.cvar_cl_noantilag)
193         {
194                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
195                 {
196                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
197                         if (!trace_ent.takedamage)
198                         {
199                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
200                                 if (trace_ent.takedamage && trace_ent.classname == "player")
201                                 {
202                                         entity e;
203                                         e = trace_ent;
204                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
205                                         if(trace_ent == e)
206                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
207                                 }
208                         }
209                 }
210                 else if(cvar("g_antilag") == 3) // client side hitscan
211                 {
212                         // this part MUST use prydon cursor
213                         if (ent.cursor_trace_ent)                 // client was aiming at someone
214                         if (ent.cursor_trace_ent != ent)         // just to make sure
215                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
216                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
217                         {
218                                 // verify that the shot would miss without antilag
219                                 // (avoids an issue where guns would always shoot at their origin)
220                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
221                                 if (!trace_ent.takedamage)
222                                 {
223                                         // verify that the shot would hit if altered
224                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
225                                         if (trace_ent == ent.cursor_trace_ent)
226                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
227                                         else
228                                                 print("antilag fail\n");
229                                 }
230                         }
231                 }
232         }
233
234         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
235
236         if (!g_norecoil)
237                 ent.punchangle_x = recoil * -1;
238
239         if (snd != "")
240         {
241                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
242         }
243
244         if(ent.items & IT_STRENGTH)
245         if(!g_minstagib)
246         if(
247                 (time > ent.prevstrengthsound + cvar("sv_strengthsound_antispam_time"))
248                 ||
249                 (time > ent.prevstrengthsoundattempt + cvar("sv_strengthsound_antispam_refire_threshold"))
250         ) // prevent insane sound spam
251         {
252                 sound(ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
253                 ent.prevstrengthsound = time;
254         }
255         ent.prevstrengthsoundattempt = time;
256
257         // nudge w_shotend so a trace to w_shotend hits
258         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
259 };
260
261 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, maxdamage, MAX_SHOT_DISTANCE)
262 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
263 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
264 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
265 #define W_SetupShot_Range(ent,antilag,recoil,snd,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage, range)
266
267 float CL_Weaponentity_CustomizeEntityForClient()
268 {
269         self.viewmodelforclient = self.owner;
270         if(other.classname == "spectator")
271                 if(other.enemy == self.owner)
272                         self.viewmodelforclient = other;
273         return TRUE;
274 }
275
276 float qcweaponanimation;
277 vector weapon_offset = '0 -10 0';
278 vector weapon_adjust = '10 0 -15';
279 .vector weapon_morph0origin;
280 .vector weapon_morph0angles;
281 .float  weapon_morph0time;
282 .vector weapon_morph1origin;
283 .vector weapon_morph1angles;
284 .float  weapon_morph1time;
285 .vector weapon_morph2origin;
286 .vector weapon_morph2angles;
287 .float  weapon_morph2time;
288 .vector weapon_morph3origin;
289 .vector weapon_morph3angles;
290 .float  weapon_morph3time;
291 .vector weapon_morph4origin;
292 .vector weapon_morph4angles;
293 .float  weapon_morph4time;
294 .string weaponname;
295 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
296
297 /*
298  * supported formats:
299  *
300  * 1. simple animated model, muzzle flash handling on h_ model:
301  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
302  *      tags:
303  *        shot = muzzle end (shot origin, also used for muzzle flashes)
304  *        shell = casings ejection point (must be on the right hand side of the gun)
305  *        weapon = attachment for v_tuba.md3
306  *    v_tuba.md3 - first and third person model
307  *    g_tuba.md3 - pickup model
308  *
309  * 2. simple animated model, muzzle flash handling on v_ model:
310  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
311  *      tags:
312  *        weapon = attachment for v_tuba.md3
313  *    v_tuba.md3 - first and third person model
314  *      tags:
315  *        shot = muzzle end (shot origin, also used for muzzle flashes)
316  *        shell = casings ejection point (must be on the right hand side of the gun)
317  *    g_tuba.md3 - pickup model
318  *
319  * 3. fully animated model, muzzle flash handling on h_ model:
320  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
321  *      tags:
322  *        shot = muzzle end (shot origin, also used for muzzle flashes)
323  *        shell = casings ejection point (must be on the right hand side of the gun)
324  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
325  *    v_tuba.md3 - third person model
326  *    g_tuba.md3 - pickup model
327  *
328  * 4. fully animated model, muzzle flash handling on v_ model:
329  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
330  *      tags:
331  *        shot = muzzle end (shot origin)
332  *        shell = casings ejection point (must be on the right hand side of the gun)
333  *    v_tuba.md3 - third person model
334  *      tags:
335  *        shot = muzzle end (for muzzle flashes)
336  *    g_tuba.md3 - pickup model
337  */
338
339 // writes:
340 //   self.origin, self.angles
341 //   self.weaponentity
342 //   self.movedir, self.view_ofs
343 //   attachment stuff
344 //   anim stuff
345 // to free:
346 //   call again with ""
347 //   remove the ent
348 void CL_WeaponEntity_SetModel(string name)
349 {
350         string animfilename;
351         float animfile;
352         float v_shot_idx;
353         if (name != "")
354         {
355                 // if there is a child entity, hide it until we're sure we use it
356                 if (self.weaponentity)
357                         self.weaponentity.model = "";
358                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
359                 v_shot_idx = gettagindex(self, "shot"); // used later
360                 if(!v_shot_idx)
361                         v_shot_idx = gettagindex(self, "tag_shot");
362
363                 if(qcweaponanimation)
364                 {
365                         self.angles = '0 0 0';
366                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
367                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
368                         self.movedir_x += 32;
369                         self.spawnorigin = self.movedir;
370                         // oldorigin - not calculated here
371                 }
372                 else
373                 {
374                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
375                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
376                         animfile = fopen(animfilename, FILE_READ);
377                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
378                         self.anim_fire1  = '0 1 0.01';
379                         self.anim_fire2  = '1 1 0.01';
380                         self.anim_idle   = '2 1 0.01';
381                         self.anim_reload = '3 1 0.01';
382                         if (animfile >= 0)
383                         {
384                                 animparseerror = FALSE;
385                                 self.anim_fire1  = animparseline(animfile);
386                                 self.anim_fire2  = animparseline(animfile);
387                                 self.anim_idle   = animparseline(animfile);
388                                 self.anim_reload = animparseline(animfile);
389                                 fclose(animfile);
390                                 if (animparseerror)
391                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
392                         }
393
394                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
395                         // if we don't, this is a "real" animated model
396                         if(gettagindex(self, "weapon"))
397                         {
398                                 if (!self.weaponentity)
399                                         self.weaponentity = spawn();
400                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
401                                 setattachment(self.weaponentity, self, "weapon");
402                         }
403                         else if(gettagindex(self, "tag_weapon"))
404                         {
405                                 if (!self.weaponentity)
406                                         self.weaponentity = spawn();
407                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
408                                 setattachment(self.weaponentity, self, "tag_weapon");
409                         }
410                         else
411                         {
412                                 if(self.weaponentity)
413                                         remove(self.weaponentity);
414                                 self.weaponentity = world;
415                         }
416
417                         setorigin(self,'0 0 0');
418                         self.angles = '0 0 0';
419                         self.frame = 0;
420                         self.viewmodelforclient = world;
421
422                         float idx;
423
424                         if(v_shot_idx) // v_ model attached to invisible h_ model
425                         {
426                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
427                         }
428                         else
429                         {
430                                 idx = gettagindex(self, "shot");
431                                 if(!idx)
432                                         idx = gettagindex(self, "tag_shot");
433                                 if(idx)
434                                         self.movedir = gettaginfo(self, idx);
435                                 else
436                                 {
437                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
438                                         self.movedir = '0 0 0';
439                                 }
440                         }
441
442                         if(self.weaponentity) // v_ model attached to invisible h_ model
443                         {
444                                 idx = gettagindex(self.weaponentity, "shell");
445                                 if(!idx)
446                                         idx = gettagindex(self.weaponentity, "tag_shell");
447                                 if(idx)
448                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
449                         }
450                         else
451                                 idx = 0;
452                         if(!idx)
453                         {
454                                 idx = gettagindex(self, "shell");
455                                 if(!idx)
456                                         idx = gettagindex(self, "tag_shell");
457                                 if(idx)
458                                         self.spawnorigin = gettaginfo(self, idx);
459                                 else
460                                 {
461                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
462                                         self.spawnorigin = self.movedir;
463                                 }
464                         }
465
466                         if(v_shot_idx)
467                         {
468                                 self.oldorigin = '0 0 0'; // use regular attachment
469                         }
470                         else
471                         {
472                                 if(self.weaponentity)
473                                 {
474                                         idx = gettagindex(self, "weapon");
475                                         if(!idx)
476                                                 idx = gettagindex(self, "tag_weapon");
477                                 }
478                                 else
479                                 {
480                                         idx = gettagindex(self, "handle");
481                                         if(!idx)
482                                                 idx = gettagindex(self, "tag_handle");
483                                 }
484                                 if(idx)
485                                 {
486                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
487                                 }
488                                 else
489                                 {
490                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
491                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
492                                 }
493                         }
494
495                         self.viewmodelforclient = self.owner;
496                 }
497         }
498         else
499         {
500                 self.model = "";
501                 if(self.weaponentity)
502                         remove(self.weaponentity);
503                 self.weaponentity = world;
504                 self.movedir = '0 0 0';
505                 self.spawnorigin = '0 0 0';
506                 self.oldorigin = '0 0 0';
507                 self.anim_fire1  = '0 1 0.01';
508                 self.anim_fire2  = '0 1 0.01';
509                 self.anim_idle   = '0 1 0.01';
510                 self.anim_reload = '0 1 0.01';
511         }
512
513         self.view_ofs = '0 0 0';
514
515         if(self.movedir_x >= 0)
516         {
517                 vector v0;
518                 v0 = self.movedir;
519                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
520                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
521         }
522         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
523         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
524
525         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
526
527         // check if an instant weapon switch occurred
528         if (qcweaponanimation)
529         {
530                 if (self.state == WS_READY)
531                 {
532                         self.angles = '0 0 0';
533                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
534                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
535                 }
536         }
537         else
538                 setorigin(self, self.view_ofs);
539         // reset animstate now
540         self.wframe = WFRAME_IDLE;
541         self.weapon_morph0time = 0;
542         self.weapon_morph1time = 0;
543         self.weapon_morph2time = 0;
544         self.weapon_morph3time = 0;
545         self.weapon_morph4time = 0;
546         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
547 }
548
549 vector CL_Weapon_GetShotOrg(float wpn)
550 {
551         entity wi, oldself;
552         vector ret;
553         wi = get_weaponinfo(wpn);
554         oldself = self;
555         self = spawn();
556         CL_WeaponEntity_SetModel(wi.mdl);
557         ret = self.movedir;
558         CL_WeaponEntity_SetModel("");
559         remove(self);
560         self = oldself;
561         return ret;
562 }
563
564 void CL_Weaponentity_Think()
565 {
566         float tb;
567         self.nextthink = time;
568         if (intermission_running)
569                 self.frame = self.anim_idle_x;
570         if (self.owner.weaponentity != self)
571         {
572                 if (self.weaponentity)
573                         remove(self.weaponentity);
574                 remove(self);
575                 return;
576         }
577         if (self.owner.deadflag != DEAD_NO)
578         {
579                 self.model = "";
580                 if (self.weaponentity)
581                         self.weaponentity.model = "";
582                 return;
583         }
584         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
585         {
586                 self.cnt = self.owner.weapon;
587                 self.dmg = self.owner.modelindex;
588                 self.deadflag = self.owner.deadflag;
589
590                 CL_WeaponEntity_SetModel(self.owner.weaponname);
591         }
592
593         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
594         self.effects = self.owner.effects & EFMASK_CHEAP;
595         self.effects &~= EF_LOWPRECISION;
596         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
597         self.effects &~= EF_TELEPORT_BIT;
598         self.effects &~= EF_RESTARTANIM_BIT;
599         self.effects |= tb;
600
601         if(self.owner.alpha == default_player_alpha)
602                 self.alpha = default_weapon_alpha;
603         else if(self.owner.alpha != 0)
604                 self.alpha = self.owner.alpha;
605         else
606                 self.alpha = 1;
607
608         self.colormap = self.owner.colormap;
609         if (self.weaponentity)
610         {
611                 self.weaponentity.effects = self.effects;
612                 self.weaponentity.alpha = self.alpha;
613                 self.weaponentity.colormap = self.colormap;
614         }
615
616         self.angles = '0 0 0';
617         local float f;
618         f = 0;
619         if (self.state == WS_RAISE && !intermission_running)
620         {
621                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
622                 self.angles_x = -90 * f * f;
623                 if (qcweaponanimation)
624                 {
625                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
626                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
627                 }
628         }
629         else if (self.state == WS_DROP && !intermission_running)
630         {
631                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
632                 self.angles_x = -90 * f * f;
633                 if (qcweaponanimation)
634                 {
635                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
636                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
637                 }
638         }
639         else if (self.state == WS_CLEAR)
640         {
641                 f = 1;
642                 self.angles_x = -90 * f * f;
643                 if (qcweaponanimation)
644                 {
645                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
646                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
647                 }
648         }
649         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
650         {
651                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
652                 f = 1 - pow(1 - f, 3);
653                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
654                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
655         }
656         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
657         {
658                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
659                 f = 1 - pow(1 - f, 3);
660                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
661                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
662         }
663         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
664         {
665                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
666                 f = 1 - pow(1 - f, 3);
667                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
668                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
669         }
670         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
671         {
672                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
673                 f = 1 - pow(1 - f, 3);
674                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
675                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
676         }
677         else if (qcweaponanimation)
678         {
679                 // begin a new idle morph
680                 self.owner.weapon_morph0time   = time;
681                 self.owner.weapon_morph0angles = self.angles;
682                 self.owner.weapon_morph0origin = self.origin;
683
684                 float r;
685                 float t;
686
687                 r = random();
688                 if (r < 0.1)
689                 {
690                         // turn gun to the left to look at it
691                         t = 2;
692                         self.owner.weapon_morph1time   = time + t * 0.2;
693                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
694                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
695                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
696
697                         self.owner.weapon_morph2time   = time + t * 0.6;
698                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
699                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
700                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
701
702                         self.owner.weapon_morph3time   = time + t;
703                         self.owner.weapon_morph3angles = '0 0 0';
704                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
705                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
706                 }
707                 else if (r < 0.2)
708                 {
709                         // raise the gun a bit
710                         t = 2;
711                         self.owner.weapon_morph1time   = time + t * 0.2;
712                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
713                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
714                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
715
716                         self.owner.weapon_morph2time   = time + t * 0.5;
717                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
718                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
719                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
720
721                         self.owner.weapon_morph3time   = time + t;
722                         self.owner.weapon_morph3angles = '0 0 0';
723                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
724                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
725                 }
726                 else if (r < 0.3)
727                 {
728                         // tweak it a bit
729                         t = 5;
730                         self.owner.weapon_morph1time   = time + t * 0.3;
731                         self.owner.weapon_morph1angles = randomvec() * 6;
732                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
733                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
734
735                         self.owner.weapon_morph2time   = time + t * 0.7;
736                         self.owner.weapon_morph2angles = randomvec() * 6;
737                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
738                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
739
740                         self.owner.weapon_morph3time   = time + t;
741                         self.owner.weapon_morph3angles = '0 0 0';
742                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
743                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
744                 }
745                 else
746                 {
747                         // hold it mostly steady
748                         t = random() * 6 + 4;
749                         self.owner.weapon_morph1time   = time + t * 0.2;
750                         self.owner.weapon_morph1angles = randomvec() * 1;
751                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
752                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
753
754                         self.owner.weapon_morph2time   = time + t * 0.5;
755                         self.owner.weapon_morph2angles = randomvec() * 1;
756                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
757                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
758
759                         self.owner.weapon_morph3time   = time + t * 0.7;
760                         self.owner.weapon_morph3angles = randomvec() * 1;
761                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
762                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
763                 }
764
765                 self.owner.weapon_morph4time   = time + t;
766                 self.owner.weapon_morph4angles = '0 0 0';
767                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
768                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
769
770         }
771 };
772
773 void CL_ExteriorWeaponentity_Think()
774 {
775         float tag_found;
776         vector ang;
777         self.nextthink = time;
778         if (self.owner.exteriorweaponentity != self)
779         {
780                 remove(self);
781                 return;
782         }
783         if (self.owner.deadflag != DEAD_NO)
784         {
785                 self.model = "";
786                 return;
787         }
788         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
789         {
790                 self.cnt = self.owner.weapon;
791                 self.dmg = self.owner.modelindex;
792                 self.deadflag = self.owner.deadflag;
793                 if (self.owner.weaponname != "")
794                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
795                 else
796                         self.model = "";
797
798                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
799                 {
800                         self.tag_index = tag_found;
801                         self.tag_entity = self.owner;
802                 }
803                 else
804                         setattachment(self, self.owner, "bip01 r hand");
805
806                 // if that didn't find a tag, hide the exterior weapon model
807                 if (!self.tag_index)
808                         self.model = "";
809         }
810         self.effects = self.owner.effects;
811         if(sv_pitch_min == sv_pitch_max)
812                 self.effects |= EF_LOWPRECISION;
813         else
814                 self.effects &~= EF_LOWPRECISION;
815         self.effects = self.effects & EFMASK_CHEAP; // eat performance
816         if(self.owner.alpha == default_player_alpha)
817                 self.alpha = default_weapon_alpha;
818         else if(self.owner.alpha != 0)
819                 self.alpha = self.owner.alpha;
820         else
821                 self.alpha = 1;
822
823         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
824         ang_y = 0;
825         ang_z = 0;
826
827         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
828         {
829                 ang_y = self.owner.v_angle_y;
830                 makevectors(ang);
831                 var vector v = v_forward;
832                 var float t = self.tag_entity.frame1time;
833                 var float f = self.tag_entity.frame;
834                 self.tag_entity.frame1time = time;
835                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
836                 gettaginfo(self.tag_entity, self.tag_index);
837                 self.tag_entity.frame1time = t;
838                 self.tag_entity.frame = f;
839                 // untransform v according to this coordinate space
840                 vector w;
841                 w_x = v_forward * v;
842                 w_y = -v_right * v;
843                 w_z = v_up * v;
844                 self.angles = vectoangles(w);
845         }
846         else
847         {
848                 ang_x = -/* don't ask */ang_x;
849                 self.angles = ang;
850         }
851
852         self.colormap = self.owner.colormap;
853 };
854
855 // spawning weaponentity for client
856 void CL_SpawnWeaponentity()
857 {
858         self.weaponentity = spawn();
859         self.weaponentity.classname = "weaponentity";
860         self.weaponentity.solid = SOLID_NOT;
861         self.weaponentity.owner = self;
862         setmodel(self.weaponentity, ""); // precision set when changed
863         setorigin(self.weaponentity, '0 0 0');
864         self.weaponentity.angles = '0 0 0';
865         self.weaponentity.viewmodelforclient = self;
866         self.weaponentity.flags = 0;
867         self.weaponentity.think = CL_Weaponentity_Think;
868         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
869         self.weaponentity.nextthink = time;
870
871         self.exteriorweaponentity = spawn();
872         self.exteriorweaponentity.classname = "exteriorweaponentity";
873         self.exteriorweaponentity.solid = SOLID_NOT;
874         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
875         self.exteriorweaponentity.owner = self;
876         setorigin(self.exteriorweaponentity, '0 0 0');
877         self.exteriorweaponentity.angles = '0 0 0';
878         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
879         self.exteriorweaponentity.nextthink = time;
880 };
881
882 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
883 {
884         msg_entity = e;
885         WriteByte(MSG_ONE, SVC_TEMPENTITY);
886         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
887         WriteByte(MSG_ONE, wpn);
888         WriteString(MSG_ONE, wpnname);
889         WriteByte(MSG_ONE, type);
890 }
891
892 .float hasweapon_complain_spam;
893
894 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
895 {
896         local float weaponbit, f;
897         local entity oldself;
898
899         if(time < self.hasweapon_complain_spam)
900                 complain = 0;
901         if(complain)
902                 self.hasweapon_complain_spam = time + 0.2;
903
904         if (wpn < WEP_FIRST || wpn > WEP_LAST)
905         {
906                 if (complain)
907                         sprint(self, "Invalid weapon\n");
908                 return FALSE;
909         }
910         weaponbit = W_WeaponBit(wpn);
911         if (cl.weapons & weaponbit)
912         {
913                 if (andammo)
914                 {
915                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
916                         {
917                                 f = 1;
918                         }
919                         else
920                         {
921                                 oldself = self;
922                                 self = cl;
923                                 f = weapon_action(wpn, WR_CHECKAMMO1);
924                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
925
926                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
927                                 local entity mine;
928                                 if(wpn == WEP_MINE_LAYER)
929                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
930                                         f = 1;
931
932                                 self = oldself;
933                         }
934                         if (!f)
935                         {
936                                 if (complain)
937                                 if(clienttype(cl) == CLIENTTYPE_REAL)
938                                 {
939                                         play2(cl, "weapons/unavailable.wav");
940                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
941                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
942                                 }
943                                 return FALSE;
944                         }
945                 }
946                 return TRUE;
947         }
948         if (complain)
949         {
950                 // DRESK - 3/16/07
951                 // Report Proper Weapon Status / Modified Weapon Ownership Message
952                 if(weaponsInMap & weaponbit)
953                 {
954                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
955                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
956
957                         if(cvar("g_showweaponspawns"))
958                         {
959                                 entity e;
960                                 string s;
961
962                                 e = get_weaponinfo(wpn);
963                                 s = e.model2;
964
965                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
966                                 {
967                                         if(e.classname == "droppedweapon")
968                                                 continue;
969                                         if not(e.flags & FL_ITEM)
970                                                 continue;
971                                         WaypointSprite_Spawn(
972                                                 s,
973                                                 1, 0,
974                                                 world, e.origin,
975                                                 self, 0,
976                                                 world, enemy,
977                                                 0
978                                         );
979                                 }
980                         }
981                 }
982                 else
983                 {
984                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
985                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
986                 }
987
988                 play2(cl, "weapons/unavailable.wav");
989         }
990         return FALSE;
991 };
992
993 // Weapon subs
994 void w_clear()
995 {
996         if (self.weapon != -1)
997                 self.weapon = 0;
998         if (self.weaponentity)
999         {
1000                 self.weaponentity.state = WS_CLEAR;
1001                 self.weaponentity.effects = 0;
1002         }
1003 };
1004
1005 void w_ready()
1006 {
1007         if (self.weaponentity)
1008                 self.weaponentity.state = WS_READY;
1009         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1010 };
1011
1012 // Setup weapon for client (after this raise frame will be launched)
1013 void weapon_setup(float windex)
1014 {
1015         entity e;
1016         qcweaponanimation = cvar("sv_qcweaponanimation");
1017         e = get_weaponinfo(windex);
1018         self.items &~= IT_AMMO;
1019         self.items = self.items | e.items;
1020
1021         // the two weapon entities will notice this has changed and update their models
1022         self.weapon = windex;
1023         self.weaponname = e.mdl;
1024         self.bulletcounter = 0;
1025 };
1026
1027 // perform weapon to attack (weaponstate and attack_finished check is here)
1028 void W_SwitchToOtherWeapon(entity pl)
1029 {
1030         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1031         float w, ww;
1032         w = W_WeaponBit(pl.weapon);
1033         pl.weapons &~= w;
1034         ww = w_getbestweapon(pl);
1035         pl.weapons |= w;
1036         if(ww)
1037                 W_SwitchWeapon_Force(pl, ww);
1038 }
1039 .float prevdryfire;
1040 float weapon_prepareattack_checkammo(float secondary)
1041 {
1042         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1043         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1044         {
1045                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1046                 local entity mine;
1047                 if(self.weapon == WEP_MINE_LAYER)
1048                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1049                         return FALSE;
1050
1051                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1052                 {
1053                         sound (self, CHAN_AUTO, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1054                         self.prevdryfire = time;
1055                 }
1056
1057                 W_SwitchToOtherWeapon(self);
1058                 return FALSE;
1059         }
1060         return TRUE;
1061 }
1062 .float race_penalty;
1063 float weapon_prepareattack_check(float secondary, float attacktime)
1064 {
1065         if(!weapon_prepareattack_checkammo(secondary))
1066                 return FALSE;
1067
1068         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1069         //if all players readied up and the countdown is running
1070         if(time < game_starttime || time < self.race_penalty) {
1071                 return FALSE;
1072         }
1073
1074         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1075                 return FALSE;
1076
1077         // do not even think about shooting if switching
1078         if(self.switchweapon != self.weapon)
1079                 return FALSE;
1080
1081         if(attacktime >= 0)
1082         {
1083                 // don't fire if previous attack is not finished
1084                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1085                         return FALSE;
1086                 // don't fire while changing weapon
1087                 if (self.weaponentity.state != WS_READY)
1088                         return FALSE;
1089         }
1090
1091         return TRUE;
1092 }
1093 float weapon_prepareattack_do(float secondary, float attacktime)
1094 {
1095         self.weaponentity.state = WS_INUSE;
1096
1097         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1098
1099         // if the weapon hasn't been firing continuously, reset the timer
1100         if(attacktime >= 0)
1101         {
1102                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1103                 {
1104                         ATTACK_FINISHED(self) = time;
1105                         //dprint("resetting attack finished to ", ftos(time), "\n");
1106                 }
1107                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1108         }
1109         self.bulletcounter += 1;
1110         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1111         return TRUE;
1112 }
1113 float weapon_prepareattack(float secondary, float attacktime)
1114 {
1115         if(weapon_prepareattack_check(secondary, attacktime))
1116         {
1117                 weapon_prepareattack_do(secondary, attacktime);
1118                 return TRUE;
1119         }
1120         else
1121                 return FALSE;
1122 }
1123
1124 void weapon_thinkf(float fr, float t, void() func)
1125 {
1126         vector a;
1127         vector of, or, ou;
1128         float restartanim;
1129
1130         if(fr == WFRAME_DONTCHANGE)
1131         {
1132                 fr = self.weaponentity.wframe;
1133                 restartanim = FALSE;
1134         }
1135         else if (fr == WFRAME_IDLE)
1136                 restartanim = FALSE;
1137         else
1138                 restartanim = TRUE;
1139
1140         of = v_forward;
1141         or = v_right;
1142         ou = v_up;
1143
1144         if (self.weaponentity)
1145         {
1146                 self.weaponentity.wframe = fr;
1147                 if (qcweaponanimation)
1148                 {
1149                         if (fr != WFRAME_IDLE)
1150                         {
1151                                 self.weapon_morph0time = time;
1152                                 self.weapon_morph0angles = self.weaponentity.angles;
1153                                 self.weapon_morph0origin = self.weaponentity.origin;
1154
1155                                 self.weapon_morph1angles = '0 0 0';
1156                                 self.weapon_morph1time = time + t;
1157                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1158                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1159
1160                                 self.weapon_morph2angles = '0 0 0';
1161                                 self.weapon_morph2time = time + t;
1162                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1163                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1164
1165                                 self.weapon_morph3angles = '0 0 0';
1166                                 self.weapon_morph3time = time + t;
1167                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1168                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1169
1170                                 self.weapon_morph4angles = '0 0 0';
1171                                 self.weapon_morph4time = time + t;
1172                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1173                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1174
1175                                 if (fr == WFRAME_FIRE1)
1176                                 {
1177                                         self.weapon_morph1angles = '5 0 0';
1178                                         self.weapon_morph1time = time + t * 0.1;
1179                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1180                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1181                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1182                                 }
1183                                 else if (fr == WFRAME_FIRE2)
1184                                 {
1185                                         self.weapon_morph1angles = '10 0 0';
1186                                         self.weapon_morph1time = time + t * 0.1;
1187                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1188                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1189                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1190                                 }
1191                                 else if (fr == WFRAME_RELOAD)
1192                                 {
1193                                         self.weapon_morph1time = time + t * 0.05;
1194                                         self.weapon_morph1angles = '-10 40 0';
1195                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1196                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1197
1198                                         self.weapon_morph2time = time + t * 0.15;
1199                                         self.weapon_morph2angles = '-10 40 5';
1200                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1201                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1202
1203                                         self.weapon_morph3time = time + t * 0.25;
1204                                         self.weapon_morph3angles = '-10 40 0';
1205                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1206                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1207                                 }
1208                         }
1209                 }
1210                 else
1211                 {
1212                         if (fr == WFRAME_IDLE)
1213                                 a = self.weaponentity.anim_idle;
1214                         else if (fr == WFRAME_FIRE1)
1215                                 a = self.weaponentity.anim_fire1;
1216                         else if (fr == WFRAME_FIRE2)
1217                                 a = self.weaponentity.anim_fire2;
1218                         else if (fr == WFRAME_RELOAD)
1219                                 a = self.weaponentity.anim_reload;
1220                         a_z *= g_weaponratefactor;
1221                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1222                 }
1223         }
1224
1225         v_forward = of;
1226         v_right = or;
1227         v_up = ou;
1228
1229         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1230         {
1231                 backtrace("Tried to override initial weapon think function - should this really happen?");
1232         }
1233
1234         t *= W_WeaponRateFactor();
1235
1236         // VorteX: haste can be added here
1237         if (self.weapon_think == w_ready)
1238         {
1239                 self.weapon_nextthink = time;
1240                 //dprint("started firing at ", ftos(time), "\n");
1241         }
1242         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1243         {
1244                 self.weapon_nextthink = time;
1245                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1246         }
1247         self.weapon_nextthink = self.weapon_nextthink + t;
1248         self.weapon_think = func;
1249         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1250
1251         if (restartanim)
1252         if (t)
1253         if (!self.crouch) // shoot anim stands up, this looks bad
1254         {
1255                 local vector anim;
1256                 anim = self.anim_shoot;
1257                 anim_z = anim_y / (t + sys_frametime);
1258                 setanim(self, anim, FALSE, TRUE, TRUE);
1259         }
1260 };
1261
1262 void weapon_boblayer1(float spd, vector org)
1263 {
1264         // VorteX: haste can be added here
1265 };
1266
1267 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1268 {
1269         vector mdirection;
1270         float mspeed;
1271         float outspeed;
1272         float nstyle;
1273         vector outvelocity;
1274
1275         mvelocity = mvelocity * g_weaponspeedfactor;
1276
1277         mdirection = normalize(mvelocity);
1278         mspeed = vlen(mvelocity);
1279
1280         nstyle = cvar("g_projectiles_newton_style");
1281         if(nstyle == 0 || forceAbsolute)
1282         {
1283                 // absolute velocity
1284                 outvelocity = mvelocity;
1285         }
1286         else if(nstyle == 1)
1287         {
1288                 // true Newtonian projectiles
1289                 outvelocity = pvelocity + mvelocity;
1290         }
1291         else if(nstyle == 2)
1292         {
1293                 // true Newtonian projectiles with automatic aim adjustment
1294                 //
1295                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1296                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1297                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1298                 // PLUS SIGN!
1299                 // not defined?
1300                 // then...
1301                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1302                 // velocity without mdirection component > mspeed
1303                 // fire at smallest possible mspeed that works?
1304                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1305
1306                 vector solution;
1307                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1308                 if(solution_z)
1309                         outspeed = solution_y; // the larger one
1310                 else
1311                 {
1312                         //outspeed = 0; // slowest possible shot
1313                         outspeed = solution_x; // the real part (that is, the average!)
1314                         //dprint("impossible shot, adjusting\n");
1315                 }
1316
1317                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1318                 outvelocity = mdirection * outspeed;
1319         }
1320         else if(nstyle == 3)
1321         {
1322                 // pseudo-Newtonian:
1323                 outspeed = mspeed + mdirection * pvelocity;
1324                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1325                 outvelocity = mdirection * outspeed;
1326         }
1327         else if(nstyle == 4)
1328         {
1329                 // tZorkian:
1330                 outspeed = mspeed + vlen(pvelocity);
1331                 outvelocity = mdirection * outspeed;
1332         }
1333         else
1334                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1335
1336         return outvelocity;
1337 }
1338
1339 void W_AttachToShotorg(entity flash, vector offset)
1340 {
1341         entity xflash;
1342         flash.owner = self;
1343         flash.angles_z = random() * 360;
1344         if(qcweaponanimation)
1345         {
1346                 setorigin(flash, w_shotorg + w_shotdir * 50);
1347                 flash.angles = vectoangles(w_shotdir);
1348                 flash.angles_z = random() * 360;
1349         }
1350         else
1351         {
1352                 if(gettagindex(self.weaponentity, "shot"))
1353                         setattachment(flash, self.weaponentity, "shot");
1354                 else
1355                         setattachment(flash, self.weaponentity, "tag_shot");
1356                 setorigin(flash, offset);
1357
1358                 xflash = spawn();
1359                 copyentity(flash, xflash);
1360
1361                 flash.viewmodelforclient = self;
1362
1363                 if(self.weaponentity.oldorigin_x > 0)
1364                 {
1365                         setattachment(xflash, self.exteriorweaponentity, "");
1366                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1367                 }
1368                 else
1369                 {
1370                         if(gettagindex(self.exteriorweaponentity, "shot"))
1371                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1372                         else
1373                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1374                         setorigin(xflash, offset);
1375                 }
1376         }
1377 }
1378
1379 vector cliptoplane(vector v, vector p)
1380 {
1381         return v - (v * p) * p;
1382 }
1383
1384 vector solve_cubic_pq(float p, float q)
1385 {
1386         float D, u, v, a;
1387         D = q*q/4.0 + p*p*p/27.0;
1388         if(D < 0)
1389         {
1390                 // irreducibilis
1391                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1392                 u = sqrt(-4.0/3.0 * p);
1393                 // a in range 0..pi/3
1394                 // cos(a)
1395                 // cos(a + 2pi/3)
1396                 // cos(a + 4pi/3)
1397                 return
1398                         u *
1399                         (
1400                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1401                                 +
1402                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1403                                 +
1404                                 '0 0 1' * cos(a)
1405                         );
1406         }
1407         else if(D == 0)
1408         {
1409                 // simple
1410                 if(p == 0)
1411                         return '0 0 0';
1412                 u = 3*q/p;
1413                 v = -u/2;
1414                 if(u >= v)
1415                         return '1 1 0' * v + '0 0 1' * u;
1416                 else
1417                         return '0 1 1' * v + '1 0 0' * u;
1418         }
1419         else
1420         {
1421                 // cardano
1422                 u = cbrt(-q/2.0 + sqrt(D));
1423                 v = cbrt(-q/2.0 - sqrt(D));
1424                 return '1 1 1' * (u + v);
1425         }
1426 }
1427 vector solve_cubic_abcd(float a, float b, float c, float d)
1428 {
1429         // y = 3*a*x + b
1430         // x = (y - b) / 3a
1431         float p, q;
1432         vector v;
1433         p = (9*a*c - 3*b*b);
1434         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1435         v = solve_cubic_pq(p, q);
1436         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1437         if(a < 0)
1438                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1439         return v;
1440 }
1441
1442 vector findperpendicular(vector v)
1443 {
1444         vector p;
1445         p_x = v_z;
1446         p_y = -v_x;
1447         p_z = v_y;
1448         return normalize(cliptoplane(p, v));
1449 }
1450
1451 vector W_CalculateProjectileSpread(vector forward, float spread)
1452 {
1453         float sigma;
1454         vector v1, v2;
1455         float dx, dy, r;
1456         float sstyle;
1457         spread *= g_weaponspreadfactor;
1458         if(spread <= 0)
1459                 return forward;
1460         sstyle = cvar("g_projectiles_spread_style");
1461         
1462         if(sstyle == 0)
1463         {
1464                 // this is the baseline for the spread value!
1465                 // standard deviation: sqrt(2/5)
1466                 // density function: sqrt(1-r^2)
1467                 return forward + randomvec() * spread;
1468         }
1469         else if(sstyle == 1)
1470         {
1471                 // same thing, basically
1472                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1473         }
1474         else if(sstyle == 2)
1475         {
1476                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1477                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1478                 v1 = findperpendicular(forward);
1479                 v2 = cross(forward, v1);
1480                 // random point on unit circle
1481                 dx = random() * 2 * M_PI;
1482                 dy = sin(dx);
1483                 dx = cos(dx);
1484                 // radius in our dist function
1485                 r = random();
1486                 r = sqrt(r);
1487                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1488         }
1489         else if(sstyle == 3) // gauss 3d
1490         {
1491                 sigma = spread * 0.44721359549996; // match baseline stddev
1492                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1493                 v1 = forward;
1494                 v1_x += gsl_ran_gaussian(sigma);
1495                 v1_y += gsl_ran_gaussian(sigma);
1496                 v1_z += gsl_ran_gaussian(sigma);
1497                 return v1;
1498         }
1499         else if(sstyle == 4) // gauss 2d
1500         {
1501                 sigma = spread * 0.44721359549996; // match baseline stddev
1502                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1503                 v1_x = gsl_ran_gaussian(sigma);
1504                 v1_y = gsl_ran_gaussian(sigma);
1505                 v1_z = gsl_ran_gaussian(sigma);
1506                 return normalize(forward + cliptoplane(v1, forward));
1507         }
1508         else if(sstyle == 5) // 1-r
1509         {
1510                 sigma = spread * 1.154700538379252; // match baseline stddev
1511                 v1 = findperpendicular(forward);
1512                 v2 = cross(forward, v1);
1513                 // random point on unit circle
1514                 dx = random() * 2 * M_PI;
1515                 dy = sin(dx);
1516                 dx = cos(dx);
1517                 // radius in our dist function
1518                 r = random();
1519                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1520                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1521         }
1522         else if(sstyle == 6) // 1-r^2
1523         {
1524                 sigma = spread * 1.095445115010332; // match baseline stddev
1525                 v1 = findperpendicular(forward);
1526                 v2 = cross(forward, v1);
1527                 // random point on unit circle
1528                 dx = random() * 2 * M_PI;
1529                 dy = sin(dx);
1530                 dx = cos(dx);
1531                 // radius in our dist function
1532                 r = random();
1533                 r = sqrt(1 - r);
1534                 r = sqrt(1 - r);
1535                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1536         }
1537         else if(sstyle == 7) // (1-r) (2-r)
1538         {
1539                 sigma = spread * 1.224744871391589; // match baseline stddev
1540                 v1 = findperpendicular(forward);
1541                 v2 = cross(forward, v1);
1542                 // random point on unit circle
1543                 dx = random() * 2 * M_PI;
1544                 dy = sin(dx);
1545                 dx = cos(dx);
1546                 // radius in our dist function
1547                 r = random();
1548                 r = 1 - sqrt(r);
1549                 r = 1 - sqrt(r);
1550                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1551         }
1552         else
1553                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1554         return '0 0 0';
1555         /*
1556          * how to derive falloff functions:
1557          * rho(r) := (2-r) * (1-r);
1558          * a : 0;
1559          * b : 1;
1560          * rhor(r) := r * rho(r);
1561          * cr(t) := integrate(rhor(r), r, a, t);
1562          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1563          * variance : scr(b) / cr(b);
1564          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1565          * sqrt(0.4 / variance), numer;
1566          */
1567 }
1568
1569 #if 0
1570 float mspercallsum;
1571 float mspercallsstyle;
1572 float mspercallcount;
1573 #endif
1574 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1575 {
1576         if(missile.owner == world)
1577                 error("Unowned missile");
1578
1579         dir = dir + upDir * (pUpSpeed / pSpeed);
1580         dir_z += pZSpeed / pSpeed;
1581         pSpeed *= vlen(dir);
1582         dir = normalize(dir);
1583
1584 #if 0
1585         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1586         {
1587                 mspercallsum = mspercallcount = 0;
1588                 mspercallsstyle = cvar("g_projectiles_spread_style");
1589         }
1590         mspercallsum -= gettime(GETTIME_HIRES);
1591 #endif
1592         dir = W_CalculateProjectileSpread(dir, spread);
1593 #if 0
1594         mspercallsum += gettime(GETTIME_HIRES);
1595         mspercallcount += 1;
1596         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1597 #endif
1598
1599         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1600 }
1601
1602 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1603 {
1604         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1605 }
1606
1607 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1608 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)