Merge remote-tracking branch 'origin/divVerent/allow-override-item-model'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
23                         else
24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * autocvar_g_balance_curse_slow_atkrate;
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
73         {
74                 thisv = targ.origin;
75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
79                 if(i || j || k)
80                 {
81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
84                 }
85                 else
86                 {
87                         // first run
88                         mi = ma = thisv;
89                 }
90         }
91
92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
95         ret_z = thisv_z - myv_z;
96         return ret;
97 }
98
99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
100 {
101         vector hitplot;
102         vector org;
103         float lag;
104
105         if(player.hitplotfh >= 0)
106         {
107                 lag = ANTILAG_LATENCY(player);
108                 if(lag < 0.001)
109                         lag = 0;
110                 if(clienttype(player) != CLIENTTYPE_REAL)
111                         lag = 0; // only antilag for clients
112
113                 org = player.origin + player.view_ofs;
114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
115                 if(trace_ent.flags & FL_CLIENT)
116                 {
117                         antilag_takeback(trace_ent, time - lag);
118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
119                         antilag_restore(trace_ent);
120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
122                 }
123         }
124 }
125
126 vector w_shotorg;
127 vector w_shotdir;
128 vector w_shotend;
129
130 .float prevstrengthsound;
131 .float prevstrengthsoundattempt;
132 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
133 {
134                 if((!g_minstagib)
135                         && (player.items & IT_STRENGTH)
136                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
137                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
138                 {
139                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
140                         player.prevstrengthsound = time;
141                 }
142                 player.prevstrengthsoundattempt = time;
143 }
144
145 // this function calculates w_shotorg and w_shotdir based on the weapon model
146 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
147 // make sure you call makevectors first (FIXME?)
148 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
149 {
150         float nudge = 1; // added to traceline target and subtracted from result
151         float oldsolid;
152         vector vecs, dv;
153         oldsolid = ent.dphitcontentsmask;
154         if(ent.weapon == WEP_RIFLE)
155                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
156         else
157                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
158         if(antilag)
159                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
160                 // passing world, because we do NOT want it to touch dphitcontentsmask
161         else
162                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
163         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
164
165         vector vf, vr, vu;
166         vf = v_forward;
167         vr = v_right;
168         vu = v_up;
169         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
170         v_forward = vf;
171         v_right = vr;
172         v_up = vu;
173
174         // un-adjust trueaim if shotend is too close
175         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
176                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
177
178         // track max damage
179         if(accuracy_canbegooddamage(ent))
180                 accuracy_add(ent, ent.weapon, maxdamage, 0);
181
182         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
183
184         if(ent.weaponentity.movedir_x > 0)
185                 vecs = ent.weaponentity.movedir;
186         else
187                 vecs = '0 0 0';
188
189         dv = v_right * -vecs_y + v_up * vecs_z;
190         w_shotorg = ent.origin + ent.view_ofs + dv;
191
192         // now move the shotorg forward as much as requested if possible
193         if(antilag)
194         {
195                 if(ent.antilag_debug)
196                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
197                 else
198                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
199         }
200         else
201                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
202         w_shotorg = trace_endpos - v_forward * nudge;
203         // calculate the shotdir from the chosen shotorg
204         w_shotdir = normalize(w_shotend - w_shotorg);
205
206         if (antilag)
207         if (!ent.cvar_cl_noantilag)
208         {
209                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
210                 {
211                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
212                         if (!trace_ent.takedamage)
213                         {
214                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
215                                 if (trace_ent.takedamage && trace_ent.classname == "player")
216                                 {
217                                         entity e;
218                                         e = trace_ent;
219                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
220                                         if(trace_ent == e)
221                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
222                                 }
223                         }
224                 }
225                 else if(autocvar_g_antilag == 3) // client side hitscan
226                 {
227                         // this part MUST use prydon cursor
228                         if (ent.cursor_trace_ent)                 // client was aiming at someone
229                         if (ent.cursor_trace_ent != ent)         // just to make sure
230                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
231                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
232                         {
233                                 // verify that the shot would miss without antilag
234                                 // (avoids an issue where guns would always shoot at their origin)
235                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
236                                 if (!trace_ent.takedamage)
237                                 {
238                                         // verify that the shot would hit if altered
239                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
240                                         if (trace_ent == ent.cursor_trace_ent)
241                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
242                                         else
243                                                 print("antilag fail\n");
244                                 }
245                         }
246                 }
247         }
248
249         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
250
251         if (!g_norecoil)
252                 ent.punchangle_x = recoil * -1;
253
254         if (snd != "")
255         {
256                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
257                 W_PlayStrengthSound(ent);
258         }
259
260         // nudge w_shotend so a trace to w_shotend hits
261         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
262 }
263
264 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
265 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
266 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
267 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
268 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
269
270 float CL_Weaponentity_CustomizeEntityForClient()
271 {
272         self.viewmodelforclient = self.owner;
273         if(other.classname == "spectator")
274                 if(other.enemy == self.owner)
275                         self.viewmodelforclient = other;
276         return TRUE;
277 }
278
279 /*
280  * supported formats:
281  *
282  * 1. simple animated model, muzzle flash handling on h_ model:
283  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
284  *      tags:
285  *        shot = muzzle end (shot origin, also used for muzzle flashes)
286  *        shell = casings ejection point (must be on the right hand side of the gun)
287  *        weapon = attachment for v_tuba.md3
288  *    v_tuba.md3 - first and third person model
289  *    g_tuba.md3 - pickup model
290  *
291  * 2. simple animated model, muzzle flash handling on v_ model:
292  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
293  *      tags:
294  *        weapon = attachment for v_tuba.md3
295  *    v_tuba.md3 - first and third person model
296  *      tags:
297  *        shot = muzzle end (shot origin, also used for muzzle flashes)
298  *        shell = casings ejection point (must be on the right hand side of the gun)
299  *    g_tuba.md3 - pickup model
300  *
301  * 3. fully animated model, muzzle flash handling on h_ model:
302  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
303  *      tags:
304  *        shot = muzzle end (shot origin, also used for muzzle flashes)
305  *        shell = casings ejection point (must be on the right hand side of the gun)
306  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
307  *    v_tuba.md3 - third person model
308  *    g_tuba.md3 - pickup model
309  *
310  * 4. fully animated model, muzzle flash handling on v_ model:
311  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
312  *      tags:
313  *        shot = muzzle end (shot origin)
314  *        shell = casings ejection point (must be on the right hand side of the gun)
315  *    v_tuba.md3 - third person model
316  *      tags:
317  *        shot = muzzle end (for muzzle flashes)
318  *    g_tuba.md3 - pickup model
319  */
320
321 // writes:
322 //   self.origin, self.angles
323 //   self.weaponentity
324 //   self.movedir, self.view_ofs
325 //   attachment stuff
326 //   anim stuff
327 // to free:
328 //   call again with ""
329 //   remove the ent
330 void CL_WeaponEntity_SetModel(string name)
331 {
332         float v_shot_idx;
333         if (name != "")
334         {
335                 // if there is a child entity, hide it until we're sure we use it
336                 if (self.weaponentity)
337                         self.weaponentity.model = "";
338                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
339                 v_shot_idx = gettagindex(self, "shot"); // used later
340                 if(!v_shot_idx)
341                         v_shot_idx = gettagindex(self, "tag_shot");
342
343                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
344                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
345                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
346                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
347                 self.anim_idle   = animfixfps(self, '2 1 0.01');
348                 self.anim_reload = animfixfps(self, '3 1 0.01');
349
350                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
351                 // if we don't, this is a "real" animated model
352                 if(gettagindex(self, "weapon"))
353                 {
354                         if (!self.weaponentity)
355                                 self.weaponentity = spawn();
356                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
357                         setattachment(self.weaponentity, self, "weapon");
358                 }
359                 else if(gettagindex(self, "tag_weapon"))
360                 {
361                         if (!self.weaponentity)
362                                 self.weaponentity = spawn();
363                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
364                         setattachment(self.weaponentity, self, "tag_weapon");
365                 }
366                 else
367                 {
368                         if(self.weaponentity)
369                                 remove(self.weaponentity);
370                         self.weaponentity = world;
371                 }
372
373                 setorigin(self,'0 0 0');
374                 self.angles = '0 0 0';
375                 self.frame = 0;
376                 self.viewmodelforclient = world;
377
378                 float idx;
379
380                 if(v_shot_idx) // v_ model attached to invisible h_ model
381                 {
382                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
383                 }
384                 else
385                 {
386                         idx = gettagindex(self, "shot");
387                         if(!idx)
388                                 idx = gettagindex(self, "tag_shot");
389                         if(idx)
390                                 self.movedir = gettaginfo(self, idx);
391                         else
392                         {
393                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
394                                 self.movedir = '0 0 0';
395                         }
396                 }
397
398                 if(self.weaponentity) // v_ model attached to invisible h_ model
399                 {
400                         idx = gettagindex(self.weaponentity, "shell");
401                         if(!idx)
402                                 idx = gettagindex(self.weaponentity, "tag_shell");
403                         if(idx)
404                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
405                 }
406                 else
407                         idx = 0;
408                 if(!idx)
409                 {
410                         idx = gettagindex(self, "shell");
411                         if(!idx)
412                                 idx = gettagindex(self, "tag_shell");
413                         if(idx)
414                                 self.spawnorigin = gettaginfo(self, idx);
415                         else
416                         {
417                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
418                                 self.spawnorigin = self.movedir;
419                         }
420                 }
421
422                 if(v_shot_idx)
423                 {
424                         self.oldorigin = '0 0 0'; // use regular attachment
425                 }
426                 else
427                 {
428                         if(self.weaponentity)
429                         {
430                                 idx = gettagindex(self, "weapon");
431                                 if(!idx)
432                                         idx = gettagindex(self, "tag_weapon");
433                         }
434                         else
435                         {
436                                 idx = gettagindex(self, "handle");
437                                 if(!idx)
438                                         idx = gettagindex(self, "tag_handle");
439                         }
440                         if(idx)
441                         {
442                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
443                         }
444                         else
445                         {
446                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
447                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
448                         }
449                 }
450
451                 self.viewmodelforclient = self.owner;
452         }
453         else
454         {
455                 self.model = "";
456                 if(self.weaponentity)
457                         remove(self.weaponentity);
458                 self.weaponentity = world;
459                 self.movedir = '0 0 0';
460                 self.spawnorigin = '0 0 0';
461                 self.oldorigin = '0 0 0';
462                 self.anim_fire1  = '0 1 0.01';
463                 self.anim_fire2  = '0 1 0.01';
464                 self.anim_idle   = '0 1 0.01';
465                 self.anim_reload = '0 1 0.01';
466         }
467
468         self.view_ofs = '0 0 0';
469
470         if(self.movedir_x >= 0)
471         {
472                 vector v0;
473                 v0 = self.movedir;
474                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
475                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
476         }
477         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
478         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
479
480         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
481
482         // check if an instant weapon switch occurred
483         setorigin(self, self.view_ofs);
484         // reset animstate now
485         self.wframe = WFRAME_IDLE;
486         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
487 }
488
489 vector CL_Weapon_GetShotOrg(float wpn)
490 {
491         entity wi, oldself;
492         vector ret;
493         wi = get_weaponinfo(wpn);
494         oldself = self;
495         self = spawn();
496         CL_WeaponEntity_SetModel(wi.mdl);
497         ret = self.movedir;
498         CL_WeaponEntity_SetModel("");
499         remove(self);
500         self = oldself;
501         return ret;
502 }
503
504 void CL_Weaponentity_Think()
505 {
506         float tb;
507         self.nextthink = time;
508         if (intermission_running)
509                 self.frame = self.anim_idle_x;
510         if (self.owner.weaponentity != self)
511         {
512                 if (self.weaponentity)
513                         remove(self.weaponentity);
514                 remove(self);
515                 return;
516         }
517         if (self.owner.deadflag != DEAD_NO)
518         {
519                 self.model = "";
520                 if (self.weaponentity)
521                         self.weaponentity.model = "";
522                 return;
523         }
524         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
525         {
526                 self.weaponname = self.owner.weaponname;
527                 self.dmg = self.owner.modelindex;
528                 self.deadflag = self.owner.deadflag;
529
530                 CL_WeaponEntity_SetModel(self.owner.weaponname);
531         }
532
533         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
534         self.effects = self.owner.effects & EFMASK_CHEAP;
535         self.effects &~= EF_LOWPRECISION;
536         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
537         self.effects &~= EF_TELEPORT_BIT;
538         self.effects &~= EF_RESTARTANIM_BIT;
539         self.effects |= tb;
540
541         if(self.owner.alpha == default_player_alpha)
542                 self.alpha = default_weapon_alpha;
543         else if(self.owner.alpha != 0)
544                 self.alpha = self.owner.alpha;
545         else
546                 self.alpha = 1;
547
548         self.glowmod = self.owner.weaponentity_glowmod;
549         self.colormap = self.owner.colormap;
550         if (self.weaponentity)
551         {
552                 self.weaponentity.effects = self.effects;
553                 self.weaponentity.alpha = self.alpha;
554                 self.weaponentity.colormap = self.colormap;
555                 self.weaponentity.glowmod = self.glowmod;
556         }
557
558         self.angles = '0 0 0';
559         float f;
560         f = 0;
561         if (self.state == WS_RAISE && !intermission_running)
562         {
563                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
564                 self.angles_x = -90 * f * f;
565         }
566         else if (self.state == WS_DROP && !intermission_running)
567         {
568                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
569                 self.angles_x = -90 * f * f;
570         }
571         else if (self.state == WS_CLEAR)
572         {
573                 f = 1;
574                 self.angles_x = -90 * f * f;
575         }
576 }
577
578 void CL_ExteriorWeaponentity_Think()
579 {
580         float tag_found;
581         vector ang;
582         self.nextthink = time;
583         if (self.owner.exteriorweaponentity != self)
584         {
585                 remove(self);
586                 return;
587         }
588         if (self.owner.deadflag != DEAD_NO)
589         {
590                 self.model = "";
591                 return;
592         }
593         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
594         {
595                 self.weaponname = self.owner.weaponname;
596                 self.dmg = self.owner.modelindex;
597                 self.deadflag = self.owner.deadflag;
598                 if (self.owner.weaponname != "")
599                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
600                 else
601                         self.model = "";
602
603                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
604                 {
605                         self.tag_index = tag_found;
606                         self.tag_entity = self.owner;
607                 }
608                 else
609                         setattachment(self, self.owner, "bip01 r hand");
610         }
611         self.effects = self.owner.effects;
612         if(sv_pitch_min == sv_pitch_max)
613                 self.effects |= EF_LOWPRECISION;
614         else
615                 self.effects &~= EF_LOWPRECISION;
616         self.effects = self.effects & EFMASK_CHEAP; // eat performance
617         if(self.owner.alpha == default_player_alpha)
618                 self.alpha = default_weapon_alpha;
619         else if(self.owner.alpha != 0)
620                 self.alpha = self.owner.alpha;
621         else
622                 self.alpha = 1;
623
624         if (!intermission_running)
625         {
626                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
627                 ang_y = 0;
628                 ang_z = 0;
629
630                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
631                 {
632                         ang_y = self.owner.v_angle_y;
633                         makevectors(ang);
634                         var vector v = v_forward;
635                         var float t = self.tag_entity.frame1time;
636                         var float f = self.tag_entity.frame;
637                         self.tag_entity.frame1time = time;
638                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
639                         gettaginfo(self.tag_entity, self.tag_index);
640                         self.tag_entity.frame1time = t;
641                         self.tag_entity.frame = f;
642                         // untransform v according to this coordinate space
643                         vector w;
644                         w_x = v_forward * v;
645                         w_y = -v_right * v;
646                         w_z = v_up * v;
647                         self.angles = vectoangles(w);
648                 }
649                 else
650                 {
651                         ang_x = -/* don't ask */ang_x;
652                         self.angles = ang;
653                 }
654
655                 if(autocvar_g_loituma)
656                 {
657                         vector modangles;
658                         float t;
659
660                         t = time * autocvar_g_loituma;
661
662                         modangles_x = t * 360;
663                         modangles_y = 90;
664                         modangles_z = 0;
665
666                         self.angles =
667                                 AnglesTransform_ToAngles(
668                                         AnglesTransform_Multiply(
669                                                 AnglesTransform_FromAngles(self.angles),
670                                                 AnglesTransform_FromAngles(modangles)
671                                         )
672                                 );
673                 }
674         }
675
676         self.glowmod = self.owner.weaponentity_glowmod;
677         self.colormap = self.owner.colormap;
678
679         CSQCMODEL_AUTOUPDATE();
680 }
681
682 // spawning weaponentity for client
683 void CL_SpawnWeaponentity()
684 {
685         self.weaponentity = spawn();
686         self.weaponentity.classname = "weaponentity";
687         self.weaponentity.solid = SOLID_NOT;
688         self.weaponentity.owner = self;
689         setmodel(self.weaponentity, ""); // precision set when changed
690         setorigin(self.weaponentity, '0 0 0');
691         self.weaponentity.angles = '0 0 0';
692         self.weaponentity.viewmodelforclient = self;
693         self.weaponentity.flags = 0;
694         self.weaponentity.think = CL_Weaponentity_Think;
695         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
696         self.weaponentity.nextthink = time;
697
698         self.exteriorweaponentity = spawn();
699         self.exteriorweaponentity.classname = "exteriorweaponentity";
700         self.exteriorweaponentity.solid = SOLID_NOT;
701         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
702         self.exteriorweaponentity.owner = self;
703         setorigin(self.exteriorweaponentity, '0 0 0');
704         self.exteriorweaponentity.angles = '0 0 0';
705         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
706         self.exteriorweaponentity.nextthink = time;
707
708         {
709                 entity oldself = self;
710                 self = self.exteriorweaponentity;
711                 CSQCMODEL_AUTOINIT();
712                 self = oldself;
713         }
714 }
715
716 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
717 {
718         msg_entity = e;
719         WriteByte(MSG_ONE, SVC_TEMPENTITY);
720         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
721         WriteByte(MSG_ONE, wpn);
722         WriteString(MSG_ONE, wpnname);
723         WriteByte(MSG_ONE, type);
724 }
725
726 .float hasweapon_complain_spam;
727
728 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
729 {
730         float weaponbit, f;
731         entity oldself;
732
733         if(time < self.hasweapon_complain_spam)
734                 complain = 0;
735         if(complain)
736                 self.hasweapon_complain_spam = time + 0.2;
737
738         if (wpn < WEP_FIRST || wpn > WEP_LAST)
739         {
740                 if (complain)
741                         sprint(self, "Invalid weapon\n");
742                 return FALSE;
743         }
744         weaponbit = W_WeaponBit(wpn);
745         if (cl.weapons & weaponbit)
746         {
747                 if (andammo)
748                 {
749                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
750                         {
751                                 f = 1;
752                         }
753                         else
754                         {
755                                 oldself = self;
756                                 self = cl;
757                                 f = weapon_action(wpn, WR_CHECKAMMO1);
758                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
759
760                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
761                                 entity mine;
762                                 if(wpn == WEP_MINE_LAYER)
763                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
764                                         f = 1;
765
766                                 self = oldself;
767                         }
768                         if (!f)
769                         {
770                                 if (complain)
771                                 if(clienttype(cl) == CLIENTTYPE_REAL)
772                                 {
773                                         play2(cl, "weapons/unavailable.wav");
774                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
775                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
776                                 }
777                                 return FALSE;
778                         }
779                 }
780                 return TRUE;
781         }
782         if (complain)
783         {
784                 // DRESK - 3/16/07
785                 // Report Proper Weapon Status / Modified Weapon Ownership Message
786                 if(weaponsInMap & weaponbit)
787                 {
788                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
789                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
790
791                         if(autocvar_g_showweaponspawns)
792                         {
793                                 entity e;
794                                 string s;
795
796                                 e = get_weaponinfo(wpn);
797                                 s = e.model2;
798
799                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
800                                 {
801                                         if(e.classname == "droppedweapon")
802                                                 continue;
803                                         if not(e.flags & FL_ITEM)
804                                                 continue;
805                                         WaypointSprite_Spawn(
806                                                 s,
807                                                 1, 0,
808                                                 world, e.origin,
809                                                 self, 0,
810                                                 world, enemy,
811                                                 0,
812                                                 RADARICON_NONE, '0 0 0'
813                                         );
814                                 }
815                         }
816                 }
817                 else
818                 {
819                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
820                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
821                 }
822
823                 play2(cl, "weapons/unavailable.wav");
824         }
825         return FALSE;
826 }
827
828 // Weapon subs
829 void w_clear()
830 {
831         if (self.weapon != -1)
832         {
833                 self.weapon = 0;
834                 self.switchingweapon = 0;
835         }
836         if (self.weaponentity)
837         {
838                 self.weaponentity.state = WS_CLEAR;
839                 self.weaponentity.effects = 0;
840         }
841 }
842
843 void w_ready()
844 {
845         if (self.weaponentity)
846                 self.weaponentity.state = WS_READY;
847         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
848 }
849
850 // Setup weapon for client (after this raise frame will be launched)
851 void weapon_setup(float windex)
852 {
853         entity e;
854         e = get_weaponinfo(windex);
855         self.items &~= IT_AMMO;
856         self.items = self.items | e.items;
857
858         // the two weapon entities will notice this has changed and update their models
859         self.weapon = windex;
860         self.switchingweapon = windex; // to make sure
861         self.weaponname = e.mdl;
862         self.bulletcounter = 0;
863 }
864
865 // perform weapon to attack (weaponstate and attack_finished check is here)
866 void W_SwitchToOtherWeapon(entity pl)
867 {
868         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
869         float w, ww;
870         w = W_WeaponBit(pl.weapon);
871         pl.weapons &~= w;
872         ww = w_getbestweapon(pl);
873         pl.weapons |= w;
874         if(ww)
875                 W_SwitchWeapon_Force(pl, ww);
876 }
877
878 string PrimaryOrSecondary(float secondary)
879 {
880         if(secondary)
881                 return "secondary";
882         else
883                 return "primary";
884 }
885
886 .float prevdryfire;
887 .float prevwarntime;
888 float weapon_prepareattack_checkammo(float secondary)
889 {
890         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
891         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
892         {
893                 // always keep the Mine Layer if we placed mines, so that we can detonate them
894                 entity mine;
895                 if(self.weapon == WEP_MINE_LAYER)
896                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
897                         return FALSE;
898
899                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
900                 {
901                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
902                         self.prevdryfire = time;
903                 }
904
905                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
906                 {
907                         if(time - self.prevwarntime > 1)
908                         {
909                                 sprint(self, strcat("^2", W_Name(self.weapon), " ", PrimaryOrSecondary(secondary), "^7 is unable to fire, but its ^2", PrimaryOrSecondary(1 - secondary), "^7 can.\n"));
910                         }
911                         self.prevwarntime = time;
912                 }
913                 else // this weapon is totally unable to fire, switch to another one
914                 {
915                         W_SwitchToOtherWeapon(self);
916                 }
917                 
918                 return FALSE;
919         }
920         return TRUE;
921 }
922 .float race_penalty;
923 float weapon_prepareattack_check(float secondary, float attacktime)
924 {
925         if(!weapon_prepareattack_checkammo(secondary))
926                 return FALSE;
927
928         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
929         //if all players readied up and the countdown is running
930         if(time < game_starttime || time < self.race_penalty) {
931                 return FALSE;
932         }
933
934         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
935                 return FALSE;
936
937         // do not even think about shooting if switching
938         if(self.switchweapon != self.weapon)
939                 return FALSE;
940
941         if(attacktime >= 0)
942         {
943                 // don't fire if previous attack is not finished
944                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
945                         return FALSE;
946                 // don't fire while changing weapon
947                 if (self.weaponentity.state != WS_READY)
948                         return FALSE;
949         }
950
951         return TRUE;
952 }
953 float weapon_prepareattack_do(float secondary, float attacktime)
954 {
955         self.weaponentity.state = WS_INUSE;
956
957         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
958
959         // if the weapon hasn't been firing continuously, reset the timer
960         if(attacktime >= 0)
961         {
962                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
963                 {
964                         ATTACK_FINISHED(self) = time;
965                         //dprint("resetting attack finished to ", ftos(time), "\n");
966                 }
967                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
968         }
969         self.bulletcounter += 1;
970         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
971         return TRUE;
972 }
973 float weapon_prepareattack(float secondary, float attacktime)
974 {
975         if(weapon_prepareattack_check(secondary, attacktime))
976         {
977                 weapon_prepareattack_do(secondary, attacktime);
978                 return TRUE;
979         }
980         else
981                 return FALSE;
982 }
983
984 void weapon_thinkf(float fr, float t, void() func)
985 {
986         vector a;
987         vector of, or, ou;
988         float restartanim;
989
990         if(fr == WFRAME_DONTCHANGE)
991         {
992                 fr = self.weaponentity.wframe;
993                 restartanim = FALSE;
994         }
995         else if (fr == WFRAME_IDLE)
996                 restartanim = FALSE;
997         else
998                 restartanim = TRUE;
999
1000         of = v_forward;
1001         or = v_right;
1002         ou = v_up;
1003
1004         if (self.weaponentity)
1005         {
1006                 self.weaponentity.wframe = fr;
1007                 if (fr == WFRAME_IDLE)
1008                         a = self.weaponentity.anim_idle;
1009                 else if (fr == WFRAME_FIRE1)
1010                         a = self.weaponentity.anim_fire1;
1011                 else if (fr == WFRAME_FIRE2)
1012                         a = self.weaponentity.anim_fire2;
1013                 else if (fr == WFRAME_RELOAD)
1014                         a = self.weaponentity.anim_reload;
1015                 a_z *= g_weaponratefactor;
1016                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1017         }
1018
1019         v_forward = of;
1020         v_right = or;
1021         v_up = ou;
1022
1023         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1024         {
1025                 backtrace("Tried to override initial weapon think function - should this really happen?");
1026         }
1027
1028         t *= W_WeaponRateFactor();
1029
1030         // VorteX: haste can be added here
1031         if (self.weapon_think == w_ready)
1032         {
1033                 self.weapon_nextthink = time;
1034                 //dprint("started firing at ", ftos(time), "\n");
1035         }
1036         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1037         {
1038                 self.weapon_nextthink = time;
1039                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1040         }
1041         self.weapon_nextthink = self.weapon_nextthink + t;
1042         self.weapon_think = func;
1043         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1044
1045         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1046         //anim = self.anim_shoot;
1047         if (restartanim)
1048         if (t)
1049         if (!self.crouch) // shoot anim stands up, this looks bad
1050         {
1051                 vector anim;
1052                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1053                 {
1054                         anim = self.anim_melee;
1055                         anim_z = anim_y / (t + sys_frametime);
1056                         setanim(self, anim, FALSE, TRUE, TRUE);
1057                 }
1058                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1059                 {
1060                         anim = self.anim_shoot;
1061                         anim_z = anim_y / (t + sys_frametime);
1062                         setanim(self, anim, FALSE, TRUE, TRUE);
1063                 }
1064         }
1065 }
1066
1067 void weapon_boblayer1(float spd, vector org)
1068 {
1069         // VorteX: haste can be added here
1070 }
1071
1072 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1073 {
1074         vector mdirection;
1075         float mspeed;
1076         float outspeed;
1077         float nstyle;
1078         vector outvelocity;
1079
1080         mvelocity = mvelocity * g_weaponspeedfactor;
1081
1082         mdirection = normalize(mvelocity);
1083         mspeed = vlen(mvelocity);
1084
1085         nstyle = autocvar_g_projectiles_newton_style;
1086         if(nstyle == 0 || forceAbsolute)
1087         {
1088                 // absolute velocity
1089                 outvelocity = mvelocity;
1090         }
1091         else if(nstyle == 1)
1092         {
1093                 // true Newtonian projectiles
1094                 outvelocity = pvelocity + mvelocity;
1095         }
1096         else if(nstyle == 2)
1097         {
1098                 // true Newtonian projectiles with automatic aim adjustment
1099                 //
1100                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1101                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1102                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1103                 // PLUS SIGN!
1104                 // not defined?
1105                 // then...
1106                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1107                 // velocity without mdirection component > mspeed
1108                 // fire at smallest possible mspeed that works?
1109                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1110
1111                 vector solution;
1112                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1113                 if(solution_z)
1114                         outspeed = solution_y; // the larger one
1115                 else
1116                 {
1117                         //outspeed = 0; // slowest possible shot
1118                         outspeed = solution_x; // the real part (that is, the average!)
1119                         //dprint("impossible shot, adjusting\n");
1120                 }
1121
1122                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1123                 outvelocity = mdirection * outspeed;
1124         }
1125         else if(nstyle == 3)
1126         {
1127                 // pseudo-Newtonian:
1128                 outspeed = mspeed + mdirection * pvelocity;
1129                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1130                 outvelocity = mdirection * outspeed;
1131         }
1132         else if(nstyle == 4)
1133         {
1134                 // tZorkian:
1135                 outspeed = mspeed + vlen(pvelocity);
1136                 outvelocity = mdirection * outspeed;
1137         }
1138         else
1139                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1140
1141         return outvelocity;
1142 }
1143
1144 void W_AttachToShotorg(entity flash, vector offset)
1145 {
1146         entity xflash;
1147         flash.owner = self;
1148         flash.angles_z = random() * 360;
1149
1150         if(gettagindex(self.weaponentity, "shot"))
1151                 setattachment(flash, self.weaponentity, "shot");
1152         else
1153                 setattachment(flash, self.weaponentity, "tag_shot");
1154         setorigin(flash, offset);
1155
1156         xflash = spawn();
1157         copyentity(flash, xflash);
1158
1159         flash.viewmodelforclient = self;
1160
1161         if(self.weaponentity.oldorigin_x > 0)
1162         {
1163                 setattachment(xflash, self.exteriorweaponentity, "");
1164                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1165         }
1166         else
1167         {
1168                 if(gettagindex(self.exteriorweaponentity, "shot"))
1169                         setattachment(xflash, self.exteriorweaponentity, "shot");
1170                 else
1171                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1172                 setorigin(xflash, offset);
1173         }
1174 }
1175
1176 vector cliptoplane(vector v, vector p)
1177 {
1178         return v - (v * p) * p;
1179 }
1180
1181 vector solve_cubic_pq(float p, float q)
1182 {
1183         float D, u, v, a;
1184         D = q*q/4.0 + p*p*p/27.0;
1185         if(D < 0)
1186         {
1187                 // irreducibilis
1188                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1189                 u = sqrt(-4.0/3.0 * p);
1190                 // a in range 0..pi/3
1191                 // cos(a)
1192                 // cos(a + 2pi/3)
1193                 // cos(a + 4pi/3)
1194                 return
1195                         u *
1196                         (
1197                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1198                                 +
1199                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1200                                 +
1201                                 '0 0 1' * cos(a)
1202                         );
1203         }
1204         else if(D == 0)
1205         {
1206                 // simple
1207                 if(p == 0)
1208                         return '0 0 0';
1209                 u = 3*q/p;
1210                 v = -u/2;
1211                 if(u >= v)
1212                         return '1 1 0' * v + '0 0 1' * u;
1213                 else
1214                         return '0 1 1' * v + '1 0 0' * u;
1215         }
1216         else
1217         {
1218                 // cardano
1219                 u = cbrt(-q/2.0 + sqrt(D));
1220                 v = cbrt(-q/2.0 - sqrt(D));
1221                 return '1 1 1' * (u + v);
1222         }
1223 }
1224 vector solve_cubic_abcd(float a, float b, float c, float d)
1225 {
1226         // y = 3*a*x + b
1227         // x = (y - b) / 3a
1228         float p, q;
1229         vector v;
1230         p = (9*a*c - 3*b*b);
1231         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1232         v = solve_cubic_pq(p, q);
1233         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1234         if(a < 0)
1235                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1236         return v;
1237 }
1238
1239 vector findperpendicular(vector v)
1240 {
1241         vector p;
1242         p_x = v_z;
1243         p_y = -v_x;
1244         p_z = v_y;
1245         return normalize(cliptoplane(p, v));
1246 }
1247
1248 vector W_CalculateProjectileSpread(vector forward, float spread)
1249 {
1250         float sigma;
1251         vector v1, v2;
1252         float dx, dy, r;
1253         float sstyle;
1254         spread *= g_weaponspreadfactor;
1255         if(spread <= 0)
1256                 return forward;
1257         sstyle = autocvar_g_projectiles_spread_style;
1258         
1259         if(sstyle == 0)
1260         {
1261                 // this is the baseline for the spread value!
1262                 // standard deviation: sqrt(2/5)
1263                 // density function: sqrt(1-r^2)
1264                 return forward + randomvec() * spread;
1265         }
1266         else if(sstyle == 1)
1267         {
1268                 // same thing, basically
1269                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1270         }
1271         else if(sstyle == 2)
1272         {
1273                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1274                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1275                 v1 = findperpendicular(forward);
1276                 v2 = cross(forward, v1);
1277                 // random point on unit circle
1278                 dx = random() * 2 * M_PI;
1279                 dy = sin(dx);
1280                 dx = cos(dx);
1281                 // radius in our dist function
1282                 r = random();
1283                 r = sqrt(r);
1284                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1285         }
1286         else if(sstyle == 3) // gauss 3d
1287         {
1288                 sigma = spread * 0.44721359549996; // match baseline stddev
1289                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1290                 v1 = forward;
1291                 v1_x += gsl_ran_gaussian(sigma);
1292                 v1_y += gsl_ran_gaussian(sigma);
1293                 v1_z += gsl_ran_gaussian(sigma);
1294                 return v1;
1295         }
1296         else if(sstyle == 4) // gauss 2d
1297         {
1298                 sigma = spread * 0.44721359549996; // match baseline stddev
1299                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1300                 v1_x = gsl_ran_gaussian(sigma);
1301                 v1_y = gsl_ran_gaussian(sigma);
1302                 v1_z = gsl_ran_gaussian(sigma);
1303                 return normalize(forward + cliptoplane(v1, forward));
1304         }
1305         else if(sstyle == 5) // 1-r
1306         {
1307                 sigma = spread * 1.154700538379252; // match baseline stddev
1308                 v1 = findperpendicular(forward);
1309                 v2 = cross(forward, v1);
1310                 // random point on unit circle
1311                 dx = random() * 2 * M_PI;
1312                 dy = sin(dx);
1313                 dx = cos(dx);
1314                 // radius in our dist function
1315                 r = random();
1316                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1317                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1318         }
1319         else if(sstyle == 6) // 1-r^2
1320         {
1321                 sigma = spread * 1.095445115010332; // match baseline stddev
1322                 v1 = findperpendicular(forward);
1323                 v2 = cross(forward, v1);
1324                 // random point on unit circle
1325                 dx = random() * 2 * M_PI;
1326                 dy = sin(dx);
1327                 dx = cos(dx);
1328                 // radius in our dist function
1329                 r = random();
1330                 r = sqrt(1 - r);
1331                 r = sqrt(1 - r);
1332                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1333         }
1334         else if(sstyle == 7) // (1-r) (2-r)
1335         {
1336                 sigma = spread * 1.224744871391589; // match baseline stddev
1337                 v1 = findperpendicular(forward);
1338                 v2 = cross(forward, v1);
1339                 // random point on unit circle
1340                 dx = random() * 2 * M_PI;
1341                 dy = sin(dx);
1342                 dx = cos(dx);
1343                 // radius in our dist function
1344                 r = random();
1345                 r = 1 - sqrt(r);
1346                 r = 1 - sqrt(r);
1347                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1348         }
1349         else
1350                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1351         return '0 0 0';
1352         /*
1353          * how to derive falloff functions:
1354          * rho(r) := (2-r) * (1-r);
1355          * a : 0;
1356          * b : 1;
1357          * rhor(r) := r * rho(r);
1358          * cr(t) := integrate(rhor(r), r, a, t);
1359          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1360          * variance : scr(b) / cr(b);
1361          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1362          * sqrt(0.4 / variance), numer;
1363          */
1364 }
1365
1366 #if 0
1367 float mspercallsum;
1368 float mspercallsstyle;
1369 float mspercallcount;
1370 #endif
1371 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1372 {
1373         if(missile.owner == world)
1374                 error("Unowned missile");
1375
1376         dir = dir + upDir * (pUpSpeed / pSpeed);
1377         dir_z += pZSpeed / pSpeed;
1378         pSpeed *= vlen(dir);
1379         dir = normalize(dir);
1380
1381 #if 0
1382         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1383         {
1384                 mspercallsum = mspercallcount = 0;
1385                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1386         }
1387         mspercallsum -= gettime(GETTIME_HIRES);
1388 #endif
1389         dir = W_CalculateProjectileSpread(dir, spread);
1390 #if 0
1391         mspercallsum += gettime(GETTIME_HIRES);
1392         mspercallcount += 1;
1393         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1394 #endif
1395
1396         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1397 }
1398
1399 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1400 {
1401         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1402 }
1403
1404 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1405 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1406
1407 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1408 {
1409         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1410                 return;
1411
1412         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1413         if(ammo_reload)
1414         {
1415                 self.clip_load -= ammo_use;
1416                 self.(weapon_load[self.weapon]) = self.clip_load;
1417         }
1418         else
1419                 self.(self.current_ammo) -= ammo_use;
1420 }
1421
1422 // weapon reloading code
1423
1424 .float reload_ammo_amount, reload_ammo_min, reload_time;
1425 .float reload_complain;
1426 .string reload_sound;
1427
1428 void W_ReloadedAndReady()
1429 {
1430         // finish the reloading process, and do the ammo transfer
1431
1432         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1433
1434         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1435         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1436                 self.clip_load = self.reload_ammo_amount;
1437         else
1438         {
1439                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1440                 {
1441                         self.clip_load += 1;
1442                         self.(self.current_ammo) -= 1;
1443                 }
1444         }
1445         self.(weapon_load[self.weapon]) = self.clip_load;
1446
1447         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1448         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1449         // so your weapon is disabled for a few seconds without reason
1450
1451         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1452
1453         w_ready();
1454 }
1455
1456 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1457 {
1458         // set global values to work with
1459
1460         self.reload_ammo_min = sent_ammo_min;
1461         self.reload_ammo_amount = sent_ammo_amount;
1462         self.reload_time = sent_time;
1463         self.reload_sound = sent_sound;
1464
1465         // check if we meet the necessary conditions to reload
1466
1467         entity e;
1468         e = get_weaponinfo(self.weapon);
1469
1470         // don't reload weapons that don't have the RELOADABLE flag
1471         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1472         {
1473                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1474                 return;
1475         }
1476
1477         // return if reloading is disabled for this weapon
1478         if(!self.reload_ammo_amount)
1479                 return;
1480
1481         // our weapon is fully loaded, no need to reload
1482         if (self.clip_load >= self.reload_ammo_amount)
1483                 return;
1484
1485         // no ammo, so nothing to load
1486         if(!self.(self.current_ammo) && self.reload_ammo_min)
1487         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1488         {
1489                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1490                 {
1491                         play2(self, "weapons/unavailable.wav");
1492                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1493                         self.reload_complain = time + 1;
1494                 }
1495                 // switch away if the amount of ammo is not enough to keep using this weapon
1496                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1497                 {
1498                         self.clip_load = -1; // reload later
1499                         W_SwitchToOtherWeapon(self);
1500                 }
1501                 return;
1502         }
1503
1504         if (self.weaponentity)
1505         {
1506                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1507                         return;
1508
1509                 // allow switching away while reloading, but this will cause a new reload!
1510                 self.weaponentity.state = WS_READY;
1511         }
1512
1513         // now begin the reloading process
1514
1515         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1516
1517         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1518         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1519         // so your weapon is disabled for a few seconds without reason
1520
1521         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1522
1523         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1524
1525         if(self.clip_load < 0)
1526                 self.clip_load = 0;
1527         self.old_clip_load = self.clip_load;
1528         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1529 }