Merge remote-tracking branch 'origin/fruitiex/disable-shootanim'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
23                         else
24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * autocvar_g_balance_curse_slow_atkrate;
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         // don't switch to another weapon if we're not allowed to
38         if(e.weapon_forbidchange)
39                 return;
40
41         e.cnt = e.switchweapon;
42         e.switchweapon = w;
43         e.selectweapon = w;
44 }
45
46 .float antilag_debug;
47
48 // VorteX: static frame globals
49 float WFRAME_DONTCHANGE = -1;
50 float WFRAME_FIRE1 = 0;
51 float WFRAME_FIRE2 = 1;
52 float WFRAME_IDLE = 2;
53 float WFRAME_RELOAD = 3;
54 .float wframe;
55
56 void(float fr, float t, void() func) weapon_thinkf;
57
58 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
59 {
60         vector ret;
61         ret_x = screenright * v;
62         ret_y = screenup * v;
63         ret_z = screenforward * v;
64         return ret;
65 }
66
67 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
68 {
69         float i, j, k;
70         vector mi, ma, thisv, myv, ret;
71
72         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
73
74         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
75
76         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
77         {
78                 thisv = targ.origin;
79                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
80                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
81                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
82                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
83                 if(i || j || k)
84                 {
85                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
86                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
87                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
88                 }
89                 else
90                 {
91                         // first run
92                         mi = ma = thisv;
93                 }
94         }
95
96         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
97         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
98         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
99         ret_z = thisv_z - myv_z;
100         return ret;
101 }
102
103 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
104 {
105         vector hitplot;
106         vector org;
107         float lag;
108
109         if(player.hitplotfh >= 0)
110         {
111                 lag = ANTILAG_LATENCY(player);
112                 if(lag < 0.001)
113                         lag = 0;
114                 if(clienttype(player) != CLIENTTYPE_REAL)
115                         lag = 0; // only antilag for clients
116
117                 org = player.origin + player.view_ofs;
118                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
119                 if(trace_ent.flags & FL_CLIENT)
120                 {
121                         antilag_takeback(trace_ent, time - lag);
122                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
123                         antilag_restore(trace_ent);
124                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
125                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
126                 }
127         }
128 }
129
130 vector w_shotorg;
131 vector w_shotdir;
132 vector w_shotend;
133
134 // this function calculates w_shotorg and w_shotdir based on the weapon model
135 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
136 // make sure you call makevectors first (FIXME?)
137 .float prevstrengthsound;
138 .float prevstrengthsoundattempt;
139 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
140 {
141         float nudge = 1; // added to traceline target and subtracted from result
142         local float oldsolid;
143         vector vecs, dv;
144         oldsolid = ent.dphitcontentsmask;
145         if(ent.weapon == WEP_SNIPERRIFLE)
146                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
147         else
148                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
149         if(antilag)
150                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
151                 // passing world, because we do NOT want it to touch dphitcontentsmask
152         else
153                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
154         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
155
156         vector vf, vr, vu;
157         vf = v_forward;
158         vr = v_right;
159         vu = v_up;
160         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
161         v_forward = vf;
162         v_right = vr;
163         v_up = vu;
164
165         // un-adjust trueaim if shotend is too close
166         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
167                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
168
169         // track max damage
170         if(accuracy_canbegooddamage(ent))
171                 accuracy_add(ent, ent.weapon, maxdamage, 0);
172
173         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
174
175         if(ent.weaponentity.movedir_x > 0)
176                 vecs = ent.weaponentity.movedir;
177         else
178                 vecs = '0 0 0';
179         if(debug_shotorg != '0 0 0')
180                 vecs = debug_shotorg;
181
182         dv = v_right * -vecs_y + v_up * vecs_z;
183         w_shotorg = ent.origin + ent.view_ofs + dv;
184
185         // now move the shotorg forward as much as requested if possible
186         if(antilag)
187         {
188                 if(ent.antilag_debug)
189                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
190                 else
191                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
192         }
193         else
194                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
195         w_shotorg = trace_endpos - v_forward * nudge;
196         // calculate the shotdir from the chosen shotorg
197         w_shotdir = normalize(w_shotend - w_shotorg);
198
199         if (antilag)
200         if (!ent.cvar_cl_noantilag)
201         {
202                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
203                 {
204                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
205                         if (!trace_ent.takedamage)
206                         {
207                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
208                                 if (trace_ent.takedamage && trace_ent.classname == "player")
209                                 {
210                                         entity e;
211                                         e = trace_ent;
212                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
213                                         if(trace_ent == e)
214                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
215                                 }
216                         }
217                 }
218                 else if(autocvar_g_antilag == 3) // client side hitscan
219                 {
220                         // this part MUST use prydon cursor
221                         if (ent.cursor_trace_ent)                 // client was aiming at someone
222                         if (ent.cursor_trace_ent != ent)         // just to make sure
223                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
224                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
225                         {
226                                 // verify that the shot would miss without antilag
227                                 // (avoids an issue where guns would always shoot at their origin)
228                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
229                                 if (!trace_ent.takedamage)
230                                 {
231                                         // verify that the shot would hit if altered
232                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
233                                         if (trace_ent == ent.cursor_trace_ent)
234                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
235                                         else
236                                                 print("antilag fail\n");
237                                 }
238                         }
239                 }
240         }
241
242         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
243
244         if (!g_norecoil)
245                 ent.punchangle_x = recoil * -1;
246
247         if (snd != "")
248                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
249
250         if(ent.items & IT_STRENGTH)
251         if(!g_minstagib)
252         if(
253                 (time > ent.prevstrengthsound + autocvar_sv_strengthsound_antispam_time)
254                 ||
255                 (time > ent.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)
256         ) // prevent insane sound spam
257         {
258                 sound(ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
259                 ent.prevstrengthsound = time;
260         }
261         ent.prevstrengthsoundattempt = time;
262
263         // nudge w_shotend so a trace to w_shotend hits
264         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
265 };
266
267 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
268 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
269 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
270 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
271 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
272
273 float CL_Weaponentity_CustomizeEntityForClient()
274 {
275         self.viewmodelforclient = self.owner;
276         if(other.classname == "spectator")
277                 if(other.enemy == self.owner)
278                         self.viewmodelforclient = other;
279         return TRUE;
280 }
281
282 float qcweaponanimation;
283 vector weapon_offset = '0 -10 0';
284 vector weapon_adjust = '10 0 -15';
285 .vector weapon_morph0origin;
286 .vector weapon_morph0angles;
287 .float  weapon_morph0time;
288 .vector weapon_morph1origin;
289 .vector weapon_morph1angles;
290 .float  weapon_morph1time;
291 .vector weapon_morph2origin;
292 .vector weapon_morph2angles;
293 .float  weapon_morph2time;
294 .vector weapon_morph3origin;
295 .vector weapon_morph3angles;
296 .float  weapon_morph3time;
297 .vector weapon_morph4origin;
298 .vector weapon_morph4angles;
299 .float  weapon_morph4time;
300 .string weaponname;
301 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
302
303 /*
304  * supported formats:
305  *
306  * 1. simple animated model, muzzle flash handling on h_ model:
307  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
308  *      tags:
309  *        shot = muzzle end (shot origin, also used for muzzle flashes)
310  *        shell = casings ejection point (must be on the right hand side of the gun)
311  *        weapon = attachment for v_tuba.md3
312  *    v_tuba.md3 - first and third person model
313  *    g_tuba.md3 - pickup model
314  *
315  * 2. simple animated model, muzzle flash handling on v_ model:
316  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
317  *      tags:
318  *        weapon = attachment for v_tuba.md3
319  *    v_tuba.md3 - first and third person model
320  *      tags:
321  *        shot = muzzle end (shot origin, also used for muzzle flashes)
322  *        shell = casings ejection point (must be on the right hand side of the gun)
323  *    g_tuba.md3 - pickup model
324  *
325  * 3. fully animated model, muzzle flash handling on h_ model:
326  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
327  *      tags:
328  *        shot = muzzle end (shot origin, also used for muzzle flashes)
329  *        shell = casings ejection point (must be on the right hand side of the gun)
330  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
331  *    v_tuba.md3 - third person model
332  *    g_tuba.md3 - pickup model
333  *
334  * 4. fully animated model, muzzle flash handling on v_ model:
335  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
336  *      tags:
337  *        shot = muzzle end (shot origin)
338  *        shell = casings ejection point (must be on the right hand side of the gun)
339  *    v_tuba.md3 - third person model
340  *      tags:
341  *        shot = muzzle end (for muzzle flashes)
342  *    g_tuba.md3 - pickup model
343  */
344
345 // writes:
346 //   self.origin, self.angles
347 //   self.weaponentity
348 //   self.movedir, self.view_ofs
349 //   attachment stuff
350 //   anim stuff
351 // to free:
352 //   call again with ""
353 //   remove the ent
354 void CL_WeaponEntity_SetModel(string name)
355 {
356         string animfilename;
357         float animfile;
358         float v_shot_idx;
359         if (name != "")
360         {
361                 // if there is a child entity, hide it until we're sure we use it
362                 if (self.weaponentity)
363                         self.weaponentity.model = "";
364                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
365                 v_shot_idx = gettagindex(self, "shot"); // used later
366                 if(!v_shot_idx)
367                         v_shot_idx = gettagindex(self, "tag_shot");
368
369                 if(qcweaponanimation)
370                 {
371                         self.angles = '0 0 0';
372                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
373                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
374                         self.movedir_x += 32;
375                         self.spawnorigin = self.movedir;
376                         // oldorigin - not calculated here
377                 }
378                 else
379                 {
380                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
381                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
382                         animfile = fopen(animfilename, FILE_READ);
383                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
384                         self.anim_fire1  = '0 1 0.01';
385                         self.anim_fire2  = '1 1 0.01';
386                         self.anim_idle   = '2 1 0.01';
387                         self.anim_reload = '3 1 0.01';
388                         if (animfile >= 0)
389                         {
390                                 animparseerror = FALSE;
391                                 self.anim_fire1  = animparseline(animfile);
392                                 self.anim_fire2  = animparseline(animfile);
393                                 self.anim_idle   = animparseline(animfile);
394                                 self.anim_reload = animparseline(animfile);
395                                 fclose(animfile);
396                                 if (animparseerror)
397                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
398                         }
399
400                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
401                         // if we don't, this is a "real" animated model
402                         if(gettagindex(self, "weapon"))
403                         {
404                                 if (!self.weaponentity)
405                                         self.weaponentity = spawn();
406                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
407                                 setattachment(self.weaponentity, self, "weapon");
408                         }
409                         else if(gettagindex(self, "tag_weapon"))
410                         {
411                                 if (!self.weaponentity)
412                                         self.weaponentity = spawn();
413                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
414                                 setattachment(self.weaponentity, self, "tag_weapon");
415                         }
416                         else
417                         {
418                                 if(self.weaponentity)
419                                         remove(self.weaponentity);
420                                 self.weaponentity = world;
421                         }
422
423                         setorigin(self,'0 0 0');
424                         self.angles = '0 0 0';
425                         self.frame = 0;
426                         self.viewmodelforclient = world;
427
428                         float idx;
429
430                         if(v_shot_idx) // v_ model attached to invisible h_ model
431                         {
432                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
433                         }
434                         else
435                         {
436                                 idx = gettagindex(self, "shot");
437                                 if(!idx)
438                                         idx = gettagindex(self, "tag_shot");
439                                 if(idx)
440                                         self.movedir = gettaginfo(self, idx);
441                                 else
442                                 {
443                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
444                                         self.movedir = '0 0 0';
445                                 }
446                         }
447
448                         if(self.weaponentity) // v_ model attached to invisible h_ model
449                         {
450                                 idx = gettagindex(self.weaponentity, "shell");
451                                 if(!idx)
452                                         idx = gettagindex(self.weaponentity, "tag_shell");
453                                 if(idx)
454                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
455                         }
456                         else
457                                 idx = 0;
458                         if(!idx)
459                         {
460                                 idx = gettagindex(self, "shell");
461                                 if(!idx)
462                                         idx = gettagindex(self, "tag_shell");
463                                 if(idx)
464                                         self.spawnorigin = gettaginfo(self, idx);
465                                 else
466                                 {
467                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
468                                         self.spawnorigin = self.movedir;
469                                 }
470                         }
471
472                         if(v_shot_idx)
473                         {
474                                 self.oldorigin = '0 0 0'; // use regular attachment
475                         }
476                         else
477                         {
478                                 if(self.weaponentity)
479                                 {
480                                         idx = gettagindex(self, "weapon");
481                                         if(!idx)
482                                                 idx = gettagindex(self, "tag_weapon");
483                                 }
484                                 else
485                                 {
486                                         idx = gettagindex(self, "handle");
487                                         if(!idx)
488                                                 idx = gettagindex(self, "tag_handle");
489                                 }
490                                 if(idx)
491                                 {
492                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
493                                 }
494                                 else
495                                 {
496                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
497                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
498                                 }
499                         }
500
501                         self.viewmodelforclient = self.owner;
502                 }
503         }
504         else
505         {
506                 self.model = "";
507                 if(self.weaponentity)
508                         remove(self.weaponentity);
509                 self.weaponentity = world;
510                 self.movedir = '0 0 0';
511                 self.spawnorigin = '0 0 0';
512                 self.oldorigin = '0 0 0';
513                 self.anim_fire1  = '0 1 0.01';
514                 self.anim_fire2  = '0 1 0.01';
515                 self.anim_idle   = '0 1 0.01';
516                 self.anim_reload = '0 1 0.01';
517         }
518
519         self.view_ofs = '0 0 0';
520
521         if(self.movedir_x >= 0)
522         {
523                 vector v0;
524                 v0 = self.movedir;
525                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
526                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
527         }
528         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
529         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
530
531         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
532
533         // check if an instant weapon switch occurred
534         if (qcweaponanimation)
535         {
536                 if (self.state == WS_READY)
537                 {
538                         self.angles = '0 0 0';
539                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
540                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
541                 }
542         }
543         else
544                 setorigin(self, self.view_ofs);
545         // reset animstate now
546         self.wframe = WFRAME_IDLE;
547         self.weapon_morph0time = 0;
548         self.weapon_morph1time = 0;
549         self.weapon_morph2time = 0;
550         self.weapon_morph3time = 0;
551         self.weapon_morph4time = 0;
552         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
553 }
554
555 vector CL_Weapon_GetShotOrg(float wpn)
556 {
557         entity wi, oldself;
558         vector ret;
559         wi = get_weaponinfo(wpn);
560         oldself = self;
561         self = spawn();
562         CL_WeaponEntity_SetModel(wi.mdl);
563         ret = self.movedir;
564         CL_WeaponEntity_SetModel("");
565         remove(self);
566         self = oldself;
567         return ret;
568 }
569
570 void CL_Weaponentity_Think()
571 {
572         float tb;
573         self.nextthink = time;
574         if (intermission_running)
575                 self.frame = self.anim_idle_x;
576         if (self.owner.weaponentity != self)
577         {
578                 if (self.weaponentity)
579                         remove(self.weaponentity);
580                 remove(self);
581                 return;
582         }
583         if (self.owner.deadflag != DEAD_NO)
584         {
585                 self.model = "";
586                 if (self.weaponentity)
587                         self.weaponentity.model = "";
588                 return;
589         }
590         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
591         {
592                 self.cnt = self.owner.weapon;
593                 self.dmg = self.owner.modelindex;
594                 self.deadflag = self.owner.deadflag;
595
596                 CL_WeaponEntity_SetModel(self.owner.weaponname);
597         }
598
599         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
600         self.effects = self.owner.effects & EFMASK_CHEAP;
601         self.effects &~= EF_LOWPRECISION;
602         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
603         self.effects &~= EF_TELEPORT_BIT;
604         self.effects &~= EF_RESTARTANIM_BIT;
605         self.effects |= tb;
606
607         if(self.owner.alpha == default_player_alpha)
608                 self.alpha = default_weapon_alpha;
609         else if(self.owner.alpha != 0)
610                 self.alpha = self.owner.alpha;
611         else
612                 self.alpha = 1;
613
614         self.glowmod = self.owner.weaponentity_glowmod;
615         self.colormap = self.owner.colormap;
616         if (self.weaponentity)
617         {
618                 self.weaponentity.effects = self.effects;
619                 self.weaponentity.alpha = self.alpha;
620                 self.weaponentity.colormap = self.colormap;
621                 self.weaponentity.glowmod = self.glowmod;
622         }
623
624         self.angles = '0 0 0';
625         local float f;
626         f = 0;
627         if (self.state == WS_RAISE && !intermission_running)
628         {
629                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
630                 self.angles_x = -90 * f * f;
631                 if (qcweaponanimation)
632                 {
633                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
634                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
635                 }
636         }
637         else if (self.state == WS_DROP && !intermission_running)
638         {
639                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
640                 self.angles_x = -90 * f * f;
641                 if (qcweaponanimation)
642                 {
643                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
644                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
645                 }
646         }
647         else if (self.state == WS_CLEAR)
648         {
649                 f = 1;
650                 self.angles_x = -90 * f * f;
651                 if (qcweaponanimation)
652                 {
653                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
654                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
655                 }
656         }
657         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
658         {
659                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
660                 f = 1 - pow(1 - f, 3);
661                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
662                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
663         }
664         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
665         {
666                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
667                 f = 1 - pow(1 - f, 3);
668                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
669                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
670         }
671         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
672         {
673                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
674                 f = 1 - pow(1 - f, 3);
675                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
676                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
677         }
678         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
679         {
680                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
681                 f = 1 - pow(1 - f, 3);
682                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
683                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
684         }
685         else if (qcweaponanimation)
686         {
687                 // begin a new idle morph
688                 self.owner.weapon_morph0time   = time;
689                 self.owner.weapon_morph0angles = self.angles;
690                 self.owner.weapon_morph0origin = self.origin;
691
692                 float r;
693                 float t;
694
695                 r = random();
696                 if (r < 0.1)
697                 {
698                         // turn gun to the left to look at it
699                         t = 2;
700                         self.owner.weapon_morph1time   = time + t * 0.2;
701                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
702                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
703                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
704
705                         self.owner.weapon_morph2time   = time + t * 0.6;
706                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
707                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
708                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
709
710                         self.owner.weapon_morph3time   = time + t;
711                         self.owner.weapon_morph3angles = '0 0 0';
712                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
713                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
714                 }
715                 else if (r < 0.2)
716                 {
717                         // raise the gun a bit
718                         t = 2;
719                         self.owner.weapon_morph1time   = time + t * 0.2;
720                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
721                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
722                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
723
724                         self.owner.weapon_morph2time   = time + t * 0.5;
725                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
726                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
727                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
728
729                         self.owner.weapon_morph3time   = time + t;
730                         self.owner.weapon_morph3angles = '0 0 0';
731                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
732                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
733                 }
734                 else if (r < 0.3)
735                 {
736                         // tweak it a bit
737                         t = 5;
738                         self.owner.weapon_morph1time   = time + t * 0.3;
739                         self.owner.weapon_morph1angles = randomvec() * 6;
740                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
741                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
742
743                         self.owner.weapon_morph2time   = time + t * 0.7;
744                         self.owner.weapon_morph2angles = randomvec() * 6;
745                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
746                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
747
748                         self.owner.weapon_morph3time   = time + t;
749                         self.owner.weapon_morph3angles = '0 0 0';
750                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
751                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
752                 }
753                 else
754                 {
755                         // hold it mostly steady
756                         t = random() * 6 + 4;
757                         self.owner.weapon_morph1time   = time + t * 0.2;
758                         self.owner.weapon_morph1angles = randomvec() * 1;
759                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
760                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
761
762                         self.owner.weapon_morph2time   = time + t * 0.5;
763                         self.owner.weapon_morph2angles = randomvec() * 1;
764                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
765                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
766
767                         self.owner.weapon_morph3time   = time + t * 0.7;
768                         self.owner.weapon_morph3angles = randomvec() * 1;
769                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
770                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
771                 }
772
773                 self.owner.weapon_morph4time   = time + t;
774                 self.owner.weapon_morph4angles = '0 0 0';
775                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
776                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
777
778         }
779 };
780
781 void CL_ExteriorWeaponentity_Think()
782 {
783         float tag_found;
784         vector ang;
785         self.nextthink = time;
786         if (self.owner.exteriorweaponentity != self)
787         {
788                 remove(self);
789                 return;
790         }
791         if (self.owner.deadflag != DEAD_NO)
792         {
793                 self.model = "";
794                 return;
795         }
796         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
797         {
798                 self.cnt = self.owner.weapon;
799                 self.dmg = self.owner.modelindex;
800                 self.deadflag = self.owner.deadflag;
801                 if (self.owner.weaponname != "")
802                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
803                 else
804                         self.model = "";
805
806                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
807                 {
808                         self.tag_index = tag_found;
809                         self.tag_entity = self.owner;
810                 }
811                 else
812                         setattachment(self, self.owner, "bip01 r hand");
813
814                 // if that didn't find a tag, hide the exterior weapon model
815                 if (!self.tag_index)
816                         self.model = "";
817         }
818         self.effects = self.owner.effects;
819         if(sv_pitch_min == sv_pitch_max)
820                 self.effects |= EF_LOWPRECISION;
821         else
822                 self.effects &~= EF_LOWPRECISION;
823         self.effects = self.effects & EFMASK_CHEAP; // eat performance
824         if(self.owner.alpha == default_player_alpha)
825                 self.alpha = default_weapon_alpha;
826         else if(self.owner.alpha != 0)
827                 self.alpha = self.owner.alpha;
828         else
829                 self.alpha = 1;
830
831         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
832         ang_y = 0;
833         ang_z = 0;
834
835         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
836         {
837                 ang_y = self.owner.v_angle_y;
838                 makevectors(ang);
839                 var vector v = v_forward;
840                 var float t = self.tag_entity.frame1time;
841                 var float f = self.tag_entity.frame;
842                 self.tag_entity.frame1time = time;
843                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
844                 gettaginfo(self.tag_entity, self.tag_index);
845                 self.tag_entity.frame1time = t;
846                 self.tag_entity.frame = f;
847                 // untransform v according to this coordinate space
848                 vector w;
849                 w_x = v_forward * v;
850                 w_y = -v_right * v;
851                 w_z = v_up * v;
852                 self.angles = vectoangles(w);
853         }
854         else
855         {
856                 ang_x = -/* don't ask */ang_x;
857                 self.angles = ang;
858         }
859
860         self.glowmod = self.owner.weaponentity_glowmod;
861         self.colormap = self.owner.colormap;
862 };
863
864 // spawning weaponentity for client
865 void CL_SpawnWeaponentity()
866 {
867         self.weaponentity = spawn();
868         self.weaponentity.classname = "weaponentity";
869         self.weaponentity.solid = SOLID_NOT;
870         self.weaponentity.owner = self;
871         setmodel(self.weaponentity, ""); // precision set when changed
872         setorigin(self.weaponentity, '0 0 0');
873         self.weaponentity.angles = '0 0 0';
874         self.weaponentity.viewmodelforclient = self;
875         self.weaponentity.flags = 0;
876         self.weaponentity.think = CL_Weaponentity_Think;
877         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
878         self.weaponentity.nextthink = time;
879
880         self.exteriorweaponentity = spawn();
881         self.exteriorweaponentity.classname = "exteriorweaponentity";
882         self.exteriorweaponentity.solid = SOLID_NOT;
883         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
884         self.exteriorweaponentity.owner = self;
885         setorigin(self.exteriorweaponentity, '0 0 0');
886         self.exteriorweaponentity.angles = '0 0 0';
887         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
888         self.exteriorweaponentity.nextthink = time;
889 };
890
891 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
892 {
893         msg_entity = e;
894         WriteByte(MSG_ONE, SVC_TEMPENTITY);
895         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
896         WriteByte(MSG_ONE, wpn);
897         WriteString(MSG_ONE, wpnname);
898         WriteByte(MSG_ONE, type);
899 }
900
901 .float hasweapon_complain_spam;
902
903 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
904 {
905         local float weaponbit, f;
906         local entity oldself;
907
908         if(time < self.hasweapon_complain_spam)
909                 complain = 0;
910         if(complain)
911                 self.hasweapon_complain_spam = time + 0.2;
912
913         if (wpn < WEP_FIRST || wpn > WEP_LAST)
914         {
915                 if (complain)
916                         sprint(self, "Invalid weapon\n");
917                 return FALSE;
918         }
919         weaponbit = W_WeaponBit(wpn);
920         if (cl.weapons & weaponbit)
921         {
922                 if (andammo)
923                 {
924                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
925                         {
926                                 f = 1;
927                         }
928                         else
929                         {
930                                 oldself = self;
931                                 self = cl;
932                                 f = weapon_action(wpn, WR_CHECKAMMO1);
933                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
934
935                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
936                                 local entity mine;
937                                 if(wpn == WEP_MINE_LAYER)
938                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
939                                         f = 1;
940
941                                 self = oldself;
942                         }
943                         if (!f)
944                         {
945                                 if (complain)
946                                 if(clienttype(cl) == CLIENTTYPE_REAL)
947                                 {
948                                         play2(cl, "weapons/unavailable.wav");
949                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
950                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
951                                 }
952                                 return FALSE;
953                         }
954                 }
955                 return TRUE;
956         }
957         if (complain)
958         {
959                 // DRESK - 3/16/07
960                 // Report Proper Weapon Status / Modified Weapon Ownership Message
961                 if(weaponsInMap & weaponbit)
962                 {
963                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
964                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
965
966                         if(autocvar_g_showweaponspawns)
967                         {
968                                 entity e;
969                                 string s;
970
971                                 e = get_weaponinfo(wpn);
972                                 s = e.model2;
973
974                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
975                                 {
976                                         if(e.classname == "droppedweapon")
977                                                 continue;
978                                         if not(e.flags & FL_ITEM)
979                                                 continue;
980                                         WaypointSprite_Spawn(
981                                                 s,
982                                                 1, 0,
983                                                 world, e.origin,
984                                                 self, 0,
985                                                 world, enemy,
986                                                 0
987                                         );
988                                 }
989                         }
990                 }
991                 else
992                 {
993                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
994                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
995                 }
996
997                 play2(cl, "weapons/unavailable.wav");
998         }
999         return FALSE;
1000 };
1001
1002 // Weapon subs
1003 void w_clear()
1004 {
1005         if (self.weapon != -1)
1006                 self.weapon = 0;
1007         if (self.weaponentity)
1008         {
1009                 self.weaponentity.state = WS_CLEAR;
1010                 self.weaponentity.effects = 0;
1011         }
1012 };
1013
1014 void w_ready()
1015 {
1016         if (self.weaponentity)
1017                 self.weaponentity.state = WS_READY;
1018         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1019 };
1020
1021 // Setup weapon for client (after this raise frame will be launched)
1022 void weapon_setup(float windex)
1023 {
1024         entity e;
1025         qcweaponanimation = autocvar_sv_qcweaponanimation;
1026         e = get_weaponinfo(windex);
1027         self.items &~= IT_AMMO;
1028         self.items = self.items | e.items;
1029
1030         // the two weapon entities will notice this has changed and update their models
1031         self.weapon = windex;
1032         self.weaponname = e.mdl;
1033         self.bulletcounter = 0;
1034 };
1035
1036 // perform weapon to attack (weaponstate and attack_finished check is here)
1037 void W_SwitchToOtherWeapon(entity pl)
1038 {
1039         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1040         float w, ww;
1041         w = W_WeaponBit(pl.weapon);
1042         pl.weapons &~= w;
1043         ww = w_getbestweapon(pl);
1044         pl.weapons |= w;
1045         if(ww)
1046                 W_SwitchWeapon_Force(pl, ww);
1047 }
1048 .float prevdryfire;
1049 float weapon_prepareattack_checkammo(float secondary)
1050 {
1051         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1052         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1053         {
1054                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1055                 local entity mine;
1056                 if(self.weapon == WEP_MINE_LAYER)
1057                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1058                         return FALSE;
1059
1060                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1061                 {
1062                         sound (self, CHAN_AUTO, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1063                         self.prevdryfire = time;
1064                 }
1065
1066                 W_SwitchToOtherWeapon(self);
1067                 return FALSE;
1068         }
1069         return TRUE;
1070 }
1071 .float race_penalty;
1072 float weapon_prepareattack_check(float secondary, float attacktime)
1073 {
1074         if(!weapon_prepareattack_checkammo(secondary))
1075                 return FALSE;
1076
1077         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1078         //if all players readied up and the countdown is running
1079         if(time < game_starttime || time < self.race_penalty) {
1080                 return FALSE;
1081         }
1082
1083         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1084                 return FALSE;
1085
1086         // do not even think about shooting if switching
1087         if(self.switchweapon != self.weapon)
1088                 return FALSE;
1089
1090         if(attacktime >= 0)
1091         {
1092                 // don't fire if previous attack is not finished
1093                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1094                         return FALSE;
1095                 // don't fire while changing weapon
1096                 if (self.weaponentity.state != WS_READY)
1097                         return FALSE;
1098         }
1099
1100         return TRUE;
1101 }
1102 float weapon_prepareattack_do(float secondary, float attacktime)
1103 {
1104         self.weaponentity.state = WS_INUSE;
1105
1106         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1107
1108         // if the weapon hasn't been firing continuously, reset the timer
1109         if(attacktime >= 0)
1110         {
1111                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1112                 {
1113                         ATTACK_FINISHED(self) = time;
1114                         //dprint("resetting attack finished to ", ftos(time), "\n");
1115                 }
1116                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1117         }
1118         self.bulletcounter += 1;
1119         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1120         return TRUE;
1121 }
1122 float weapon_prepareattack(float secondary, float attacktime)
1123 {
1124         if(weapon_prepareattack_check(secondary, attacktime))
1125         {
1126                 weapon_prepareattack_do(secondary, attacktime);
1127                 return TRUE;
1128         }
1129         else
1130                 return FALSE;
1131 }
1132
1133 void weapon_thinkf(float fr, float t, void() func)
1134 {
1135         vector a;
1136         vector of, or, ou;
1137         float restartanim;
1138
1139         if(fr == WFRAME_DONTCHANGE)
1140         {
1141                 fr = self.weaponentity.wframe;
1142                 restartanim = FALSE;
1143         }
1144         else if (fr == WFRAME_IDLE)
1145                 restartanim = FALSE;
1146         else
1147                 restartanim = TRUE;
1148
1149         of = v_forward;
1150         or = v_right;
1151         ou = v_up;
1152
1153         if (self.weaponentity)
1154         {
1155                 self.weaponentity.wframe = fr;
1156                 if (qcweaponanimation)
1157                 {
1158                         if (fr != WFRAME_IDLE)
1159                         {
1160                                 self.weapon_morph0time = time;
1161                                 self.weapon_morph0angles = self.weaponentity.angles;
1162                                 self.weapon_morph0origin = self.weaponentity.origin;
1163
1164                                 self.weapon_morph1angles = '0 0 0';
1165                                 self.weapon_morph1time = time + t;
1166                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1167                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1168
1169                                 self.weapon_morph2angles = '0 0 0';
1170                                 self.weapon_morph2time = time + t;
1171                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1172                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1173
1174                                 self.weapon_morph3angles = '0 0 0';
1175                                 self.weapon_morph3time = time + t;
1176                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1177                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1178
1179                                 self.weapon_morph4angles = '0 0 0';
1180                                 self.weapon_morph4time = time + t;
1181                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1182                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1183
1184                                 if (fr == WFRAME_FIRE1)
1185                                 {
1186                                         self.weapon_morph1angles = '5 0 0';
1187                                         self.weapon_morph1time = time + t * 0.1;
1188                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1189                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1190                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1191                                 }
1192                                 else if (fr == WFRAME_FIRE2)
1193                                 {
1194                                         self.weapon_morph1angles = '10 0 0';
1195                                         self.weapon_morph1time = time + t * 0.1;
1196                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1197                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1198                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1199                                 }
1200                                 else if (fr == WFRAME_RELOAD)
1201                                 {
1202                                         self.weapon_morph1time = time + t * 0.05;
1203                                         self.weapon_morph1angles = '-10 40 0';
1204                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1205                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1206
1207                                         self.weapon_morph2time = time + t * 0.15;
1208                                         self.weapon_morph2angles = '-10 40 5';
1209                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1210                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1211
1212                                         self.weapon_morph3time = time + t * 0.25;
1213                                         self.weapon_morph3angles = '-10 40 0';
1214                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1215                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1216                                 }
1217                         }
1218                 }
1219                 else
1220                 {
1221                         if (fr == WFRAME_IDLE)
1222                                 a = self.weaponentity.anim_idle;
1223                         else if (fr == WFRAME_FIRE1)
1224                                 a = self.weaponentity.anim_fire1;
1225                         else if (fr == WFRAME_FIRE2)
1226                                 a = self.weaponentity.anim_fire2;
1227                         else if (fr == WFRAME_RELOAD)
1228                                 a = self.weaponentity.anim_reload;
1229                         a_z *= g_weaponratefactor;
1230                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1231                 }
1232         }
1233
1234         v_forward = of;
1235         v_right = or;
1236         v_up = ou;
1237
1238         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1239         {
1240                 backtrace("Tried to override initial weapon think function - should this really happen?");
1241         }
1242
1243         t *= W_WeaponRateFactor();
1244
1245         // VorteX: haste can be added here
1246         if (self.weapon_think == w_ready)
1247         {
1248                 self.weapon_nextthink = time;
1249                 //dprint("started firing at ", ftos(time), "\n");
1250         }
1251         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1252         {
1253                 self.weapon_nextthink = time;
1254                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1255         }
1256         self.weapon_nextthink = self.weapon_nextthink + t;
1257         self.weapon_think = func;
1258         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1259
1260     // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1261     /*
1262         if (restartanim)
1263         if (t)
1264         if (!self.crouch) // shoot anim stands up, this looks bad
1265         {
1266                 local vector anim;
1267                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1268                         anim = self.anim_melee;
1269                 else
1270                         anim = self.anim_shoot;
1271                 anim_z = anim_y / (t + sys_frametime);
1272                 setanim(self, anim, FALSE, TRUE, TRUE);
1273         }
1274     */
1275 };
1276
1277 void weapon_boblayer1(float spd, vector org)
1278 {
1279         // VorteX: haste can be added here
1280 };
1281
1282 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1283 {
1284         vector mdirection;
1285         float mspeed;
1286         float outspeed;
1287         float nstyle;
1288         vector outvelocity;
1289
1290         mvelocity = mvelocity * g_weaponspeedfactor;
1291
1292         mdirection = normalize(mvelocity);
1293         mspeed = vlen(mvelocity);
1294
1295         nstyle = autocvar_g_projectiles_newton_style;
1296         if(nstyle == 0 || forceAbsolute)
1297         {
1298                 // absolute velocity
1299                 outvelocity = mvelocity;
1300         }
1301         else if(nstyle == 1)
1302         {
1303                 // true Newtonian projectiles
1304                 outvelocity = pvelocity + mvelocity;
1305         }
1306         else if(nstyle == 2)
1307         {
1308                 // true Newtonian projectiles with automatic aim adjustment
1309                 //
1310                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1311                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1312                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1313                 // PLUS SIGN!
1314                 // not defined?
1315                 // then...
1316                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1317                 // velocity without mdirection component > mspeed
1318                 // fire at smallest possible mspeed that works?
1319                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1320
1321                 vector solution;
1322                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1323                 if(solution_z)
1324                         outspeed = solution_y; // the larger one
1325                 else
1326                 {
1327                         //outspeed = 0; // slowest possible shot
1328                         outspeed = solution_x; // the real part (that is, the average!)
1329                         //dprint("impossible shot, adjusting\n");
1330                 }
1331
1332                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1333                 outvelocity = mdirection * outspeed;
1334         }
1335         else if(nstyle == 3)
1336         {
1337                 // pseudo-Newtonian:
1338                 outspeed = mspeed + mdirection * pvelocity;
1339                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1340                 outvelocity = mdirection * outspeed;
1341         }
1342         else if(nstyle == 4)
1343         {
1344                 // tZorkian:
1345                 outspeed = mspeed + vlen(pvelocity);
1346                 outvelocity = mdirection * outspeed;
1347         }
1348         else
1349                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1350
1351         return outvelocity;
1352 }
1353
1354 void W_AttachToShotorg(entity flash, vector offset)
1355 {
1356         entity xflash;
1357         flash.owner = self;
1358         flash.angles_z = random() * 360;
1359         if(qcweaponanimation)
1360         {
1361                 setorigin(flash, w_shotorg + w_shotdir * 50);
1362                 flash.angles = vectoangles(w_shotdir);
1363                 flash.angles_z = random() * 360;
1364         }
1365         else
1366         {
1367                 if(gettagindex(self.weaponentity, "shot"))
1368                         setattachment(flash, self.weaponentity, "shot");
1369                 else
1370                         setattachment(flash, self.weaponentity, "tag_shot");
1371                 setorigin(flash, offset);
1372
1373                 xflash = spawn();
1374                 copyentity(flash, xflash);
1375
1376                 flash.viewmodelforclient = self;
1377
1378                 if(self.weaponentity.oldorigin_x > 0)
1379                 {
1380                         setattachment(xflash, self.exteriorweaponentity, "");
1381                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1382                 }
1383                 else
1384                 {
1385                         if(gettagindex(self.exteriorweaponentity, "shot"))
1386                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1387                         else
1388                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1389                         setorigin(xflash, offset);
1390                 }
1391         }
1392 }
1393
1394 vector cliptoplane(vector v, vector p)
1395 {
1396         return v - (v * p) * p;
1397 }
1398
1399 vector solve_cubic_pq(float p, float q)
1400 {
1401         float D, u, v, a;
1402         D = q*q/4.0 + p*p*p/27.0;
1403         if(D < 0)
1404         {
1405                 // irreducibilis
1406                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1407                 u = sqrt(-4.0/3.0 * p);
1408                 // a in range 0..pi/3
1409                 // cos(a)
1410                 // cos(a + 2pi/3)
1411                 // cos(a + 4pi/3)
1412                 return
1413                         u *
1414                         (
1415                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1416                                 +
1417                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1418                                 +
1419                                 '0 0 1' * cos(a)
1420                         );
1421         }
1422         else if(D == 0)
1423         {
1424                 // simple
1425                 if(p == 0)
1426                         return '0 0 0';
1427                 u = 3*q/p;
1428                 v = -u/2;
1429                 if(u >= v)
1430                         return '1 1 0' * v + '0 0 1' * u;
1431                 else
1432                         return '0 1 1' * v + '1 0 0' * u;
1433         }
1434         else
1435         {
1436                 // cardano
1437                 u = cbrt(-q/2.0 + sqrt(D));
1438                 v = cbrt(-q/2.0 - sqrt(D));
1439                 return '1 1 1' * (u + v);
1440         }
1441 }
1442 vector solve_cubic_abcd(float a, float b, float c, float d)
1443 {
1444         // y = 3*a*x + b
1445         // x = (y - b) / 3a
1446         float p, q;
1447         vector v;
1448         p = (9*a*c - 3*b*b);
1449         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1450         v = solve_cubic_pq(p, q);
1451         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1452         if(a < 0)
1453                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1454         return v;
1455 }
1456
1457 vector findperpendicular(vector v)
1458 {
1459         vector p;
1460         p_x = v_z;
1461         p_y = -v_x;
1462         p_z = v_y;
1463         return normalize(cliptoplane(p, v));
1464 }
1465
1466 vector W_CalculateProjectileSpread(vector forward, float spread)
1467 {
1468         float sigma;
1469         vector v1, v2;
1470         float dx, dy, r;
1471         float sstyle;
1472         spread *= g_weaponspreadfactor;
1473         if(spread <= 0)
1474                 return forward;
1475         sstyle = autocvar_g_projectiles_spread_style;
1476         
1477         if(sstyle == 0)
1478         {
1479                 // this is the baseline for the spread value!
1480                 // standard deviation: sqrt(2/5)
1481                 // density function: sqrt(1-r^2)
1482                 return forward + randomvec() * spread;
1483         }
1484         else if(sstyle == 1)
1485         {
1486                 // same thing, basically
1487                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1488         }
1489         else if(sstyle == 2)
1490         {
1491                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1492                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1493                 v1 = findperpendicular(forward);
1494                 v2 = cross(forward, v1);
1495                 // random point on unit circle
1496                 dx = random() * 2 * M_PI;
1497                 dy = sin(dx);
1498                 dx = cos(dx);
1499                 // radius in our dist function
1500                 r = random();
1501                 r = sqrt(r);
1502                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1503         }
1504         else if(sstyle == 3) // gauss 3d
1505         {
1506                 sigma = spread * 0.44721359549996; // match baseline stddev
1507                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1508                 v1 = forward;
1509                 v1_x += gsl_ran_gaussian(sigma);
1510                 v1_y += gsl_ran_gaussian(sigma);
1511                 v1_z += gsl_ran_gaussian(sigma);
1512                 return v1;
1513         }
1514         else if(sstyle == 4) // gauss 2d
1515         {
1516                 sigma = spread * 0.44721359549996; // match baseline stddev
1517                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1518                 v1_x = gsl_ran_gaussian(sigma);
1519                 v1_y = gsl_ran_gaussian(sigma);
1520                 v1_z = gsl_ran_gaussian(sigma);
1521                 return normalize(forward + cliptoplane(v1, forward));
1522         }
1523         else if(sstyle == 5) // 1-r
1524         {
1525                 sigma = spread * 1.154700538379252; // match baseline stddev
1526                 v1 = findperpendicular(forward);
1527                 v2 = cross(forward, v1);
1528                 // random point on unit circle
1529                 dx = random() * 2 * M_PI;
1530                 dy = sin(dx);
1531                 dx = cos(dx);
1532                 // radius in our dist function
1533                 r = random();
1534                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1535                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1536         }
1537         else if(sstyle == 6) // 1-r^2
1538         {
1539                 sigma = spread * 1.095445115010332; // match baseline stddev
1540                 v1 = findperpendicular(forward);
1541                 v2 = cross(forward, v1);
1542                 // random point on unit circle
1543                 dx = random() * 2 * M_PI;
1544                 dy = sin(dx);
1545                 dx = cos(dx);
1546                 // radius in our dist function
1547                 r = random();
1548                 r = sqrt(1 - r);
1549                 r = sqrt(1 - r);
1550                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1551         }
1552         else if(sstyle == 7) // (1-r) (2-r)
1553         {
1554                 sigma = spread * 1.224744871391589; // match baseline stddev
1555                 v1 = findperpendicular(forward);
1556                 v2 = cross(forward, v1);
1557                 // random point on unit circle
1558                 dx = random() * 2 * M_PI;
1559                 dy = sin(dx);
1560                 dx = cos(dx);
1561                 // radius in our dist function
1562                 r = random();
1563                 r = 1 - sqrt(r);
1564                 r = 1 - sqrt(r);
1565                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1566         }
1567         else
1568                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1569         return '0 0 0';
1570         /*
1571          * how to derive falloff functions:
1572          * rho(r) := (2-r) * (1-r);
1573          * a : 0;
1574          * b : 1;
1575          * rhor(r) := r * rho(r);
1576          * cr(t) := integrate(rhor(r), r, a, t);
1577          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1578          * variance : scr(b) / cr(b);
1579          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1580          * sqrt(0.4 / variance), numer;
1581          */
1582 }
1583
1584 #if 0
1585 float mspercallsum;
1586 float mspercallsstyle;
1587 float mspercallcount;
1588 #endif
1589 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1590 {
1591         if(missile.owner == world)
1592                 error("Unowned missile");
1593
1594         dir = dir + upDir * (pUpSpeed / pSpeed);
1595         dir_z += pZSpeed / pSpeed;
1596         pSpeed *= vlen(dir);
1597         dir = normalize(dir);
1598
1599 #if 0
1600         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1601         {
1602                 mspercallsum = mspercallcount = 0;
1603                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1604         }
1605         mspercallsum -= gettime(GETTIME_HIRES);
1606 #endif
1607         dir = W_CalculateProjectileSpread(dir, spread);
1608 #if 0
1609         mspercallsum += gettime(GETTIME_HIRES);
1610         mspercallcount += 1;
1611         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1612 #endif
1613
1614         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1615 }
1616
1617 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1618 {
1619         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1620 }
1621
1622 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1623 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1624
1625 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1626 {
1627         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1628                 return;
1629
1630         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1631         if(ammo_reload)
1632         {
1633                 self.clip_load -= ammo_use;
1634                 self.weapon_load[self.weapon] = self.clip_load;
1635         }
1636         else
1637                 self.(self.current_ammo) -= ammo_use;
1638 }
1639
1640 // weapon reloading code
1641
1642 .float reload_ammo_amount, reload_ammo_min, reload_time;
1643 .float reload_complain;
1644 .string reload_sound;
1645
1646 void W_ReloadedAndReady()
1647 {
1648         // finish the reloading process, and do the ammo transfer
1649
1650         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1651
1652         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1653         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1654                 self.clip_load = self.reload_ammo_amount;
1655         else
1656         {
1657                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1658                 {
1659                         self.clip_load += 1;
1660                         self.(self.current_ammo) -= 1;
1661                 }
1662         }
1663         self.weapon_load[self.weapon] = self.clip_load;
1664
1665         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1666         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1667         // so your weapon is disabled for a few seconds without reason
1668
1669         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1670
1671         w_ready();
1672 }
1673
1674 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1675 {
1676         // set global values to work with
1677
1678         self.reload_ammo_min = sent_ammo_min;
1679         self.reload_ammo_amount = sent_ammo_amount;
1680         self.reload_time = sent_time;
1681         self.reload_sound = sent_sound;
1682
1683         // check if we meet the necessary conditions to reload
1684
1685         entity e;
1686         e = get_weaponinfo(self.weapon);
1687
1688         // don't reload weapons that don't have the RELOADABLE flag
1689         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1690         {
1691                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1692                 return;
1693         }
1694
1695         // return if reloading is disabled for this weapon
1696         if(!self.reload_ammo_amount)
1697                 return;
1698
1699         // our weapon is fully loaded, no need to reload
1700         if (self.clip_load >= self.reload_ammo_amount)
1701                 return;
1702
1703         // no ammo, so nothing to load
1704         if(!self.(self.current_ammo) && self.reload_ammo_min)
1705         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1706         {
1707                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1708                 {
1709                         play2(self, "weapons/unavailable.wav");
1710                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1711                         self.reload_complain = time + 1;
1712                 }
1713                 // switch away if the amount of ammo is not enough to keep using this weapon
1714                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1715                 {
1716                         self.clip_load = -1; // reload later
1717                         W_SwitchToOtherWeapon(self);
1718                 }
1719                 return;
1720         }
1721
1722         if (self.weaponentity)
1723         {
1724                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1725                         return;
1726
1727                 // allow switching away while reloading, but this will cause a new reload!
1728                 self.weaponentity.state = WS_READY;
1729         }
1730
1731         // now begin the reloading process
1732
1733         sound (self, CHAN_WEAPON2, self.reload_sound, VOL_BASE, ATTN_NORM);
1734
1735         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1736         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1737         // so your weapon is disabled for a few seconds without reason
1738
1739         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1740
1741         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1742
1743         if(self.clip_load < 0)
1744                 self.clip_load = 0;
1745         self.old_clip_load = self.clip_load;
1746         self.clip_load = self.weapon_load[self.weapon] = -1;
1747 }