qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 .float prevstrengthsound;
 131 .float prevstrengthsoundattempt;
 132 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 133 {
 134                 if((!g_minstagib)
 135                         && (player.items & IT_STRENGTH)
 136                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 137                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 138                 {
 139                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 140                         player.prevstrengthsound = time;
 141                 }
 142                 player.prevstrengthsoundattempt = time;
 143 }
 144
 145 // this function calculates w_shotorg and w_shotdir based on the weapon model
 146 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 147 // make sure you call makevectors first (FIXME?)
 148 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 149 {
 150         float nudge = 1; // added to traceline target and subtracted from result
 151         float oldsolid;
 152         vector vecs, dv;
 153         oldsolid = ent.dphitcontentsmask;
 154         if(ent.weapon == WEP_RIFLE)
 155                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 156         else
 157                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 158         if(antilag)
 159                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 160                 // passing world, because we do NOT want it to touch dphitcontentsmask
 161         else
 162                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 163         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 164
 165         vector vf, vr, vu;
 166         vf = v_forward;
 167         vr = v_right;
 168         vu = v_up;
 169         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 170         v_forward = vf;
 171         v_right = vr;
 172         v_up = vu;
 173
 174         // un-adjust trueaim if shotend is too close
 175         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 176                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 177
 178         // track max damage
 179         if(accuracy_canbegooddamage(ent))
 180                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 181
 182         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 183
 184         if(ent.weaponentity.movedir_x > 0)
 185                 vecs = ent.weaponentity.movedir;
 186         else
 187                 vecs = '0 0 0';
 188         if(debug_shotorg != '0 0 0')
 189                 vecs = debug_shotorg;
 190
 191         dv = v_right * -vecs_y + v_up * vecs_z;
 192         w_shotorg = ent.origin + ent.view_ofs + dv;
 193
 194         // now move the shotorg forward as much as requested if possible
 195         if(antilag)
 196         {
 197                 if(ent.antilag_debug)
 198                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 199                 else
 200                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 201         }
 202         else
 203                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 204         w_shotorg = trace_endpos - v_forward * nudge;
 205         // calculate the shotdir from the chosen shotorg
 206         w_shotdir = normalize(w_shotend - w_shotorg);
 207
 208         if (antilag)
 209         if (!ent.cvar_cl_noantilag)
 210         {
 211                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 212                 {
 213                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 214                         if (!trace_ent.takedamage)
 215                         {
 216                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 217                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 218                                 {
 219                                         entity e;
 220                                         e = trace_ent;
 221                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 222                                         if(trace_ent == e)
 223                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 224                                 }
 225                         }
 226                 }
 227                 else if(autocvar_g_antilag == 3) // client side hitscan
 228                 {
 229                         // this part MUST use prydon cursor
 230                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 231                         if (ent.cursor_trace_ent != ent)         // just to make sure
 232                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 233                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 234                         {
 235                                 // verify that the shot would miss without antilag
 236                                 // (avoids an issue where guns would always shoot at their origin)
 237                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 238                                 if (!trace_ent.takedamage)
 239                                 {
 240                                         // verify that the shot would hit if altered
 241                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 242                                         if (trace_ent == ent.cursor_trace_ent)
 243                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 244                                         else
 245                                                 print("antilag fail\n");
 246                                 }
 247                         }
 248                 }
 249         }
 250
 251         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 252
 253         if (!g_norecoil)
 254                 ent.punchangle_x = recoil * -1;
 255
 256         if (snd != "")
 257         {
 258                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 259                 W_PlayStrengthSound(ent);
 260         }
 261
 262         // nudge w_shotend so a trace to w_shotend hits
 263         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 264 }
 265
 266 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 267 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 270 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 271
 272 float CL_Weaponentity_CustomizeEntityForClient()
 273 {
 274         self.viewmodelforclient = self.owner;
 275         if(other.classname == "spectator")
 276                 if(other.enemy == self.owner)
 277                         self.viewmodelforclient = other;
 278         return TRUE;
 279 }
 280
 281 /*
 282  * supported formats:
 283  *
 284  * 1. simple animated model, muzzle flash handling on h_ model:
 285  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 286  *      tags:
 287  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 288  *        shell = casings ejection point (must be on the right hand side of the gun)
 289  *        weapon = attachment for v_tuba.md3
 290  *    v_tuba.md3 - first and third person model
 291  *    g_tuba.md3 - pickup model
 292  *
 293  * 2. simple animated model, muzzle flash handling on v_ model:
 294  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 295  *      tags:
 296  *        weapon = attachment for v_tuba.md3
 297  *    v_tuba.md3 - first and third person model
 298  *      tags:
 299  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 300  *        shell = casings ejection point (must be on the right hand side of the gun)
 301  *    g_tuba.md3 - pickup model
 302  *
 303  * 3. fully animated model, muzzle flash handling on h_ model:
 304  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 305  *      tags:
 306  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 307  *        shell = casings ejection point (must be on the right hand side of the gun)
 308  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 309  *    v_tuba.md3 - third person model
 310  *    g_tuba.md3 - pickup model
 311  *
 312  * 4. fully animated model, muzzle flash handling on v_ model:
 313  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 314  *      tags:
 315  *        shot = muzzle end (shot origin)
 316  *        shell = casings ejection point (must be on the right hand side of the gun)
 317  *    v_tuba.md3 - third person model
 318  *      tags:
 319  *        shot = muzzle end (for muzzle flashes)
 320  *    g_tuba.md3 - pickup model
 321  */
 322
 323 // writes:
 324 //   self.origin, self.angles
 325 //   self.weaponentity
 326 //   self.movedir, self.view_ofs
 327 //   attachment stuff
 328 //   anim stuff
 329 // to free:
 330 //   call again with ""
 331 //   remove the ent
 332 void CL_WeaponEntity_SetModel(string name)
 333 {
 334         float v_shot_idx;
 335         if (name != "")
 336         {
 337                 // if there is a child entity, hide it until we're sure we use it
 338                 if (self.weaponentity)
 339                         self.weaponentity.model = "";
 340                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 341                 v_shot_idx = gettagindex(self, "shot"); // used later
 342                 if(!v_shot_idx)
 343                         v_shot_idx = gettagindex(self, "tag_shot");
 344
 345                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 346                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 347                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
 348                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
 349                 self.anim_idle   = animfixfps(self, '2 1 0.01');
 350                 self.anim_reload = animfixfps(self, '3 1 0.01');
 351
 352                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 353                 // if we don't, this is a "real" animated model
 354                 if(gettagindex(self, "weapon"))
 355                 {
 356                         if (!self.weaponentity)
 357                                 self.weaponentity = spawn();
 358                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 359                         setattachment(self.weaponentity, self, "weapon");
 360                 }
 361                 else if(gettagindex(self, "tag_weapon"))
 362                 {
 363                         if (!self.weaponentity)
 364                                 self.weaponentity = spawn();
 365                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 366                         setattachment(self.weaponentity, self, "tag_weapon");
 367                 }
 368                 else
 369                 {
 370                         if(self.weaponentity)
 371                                 remove(self.weaponentity);
 372                         self.weaponentity = world;
 373                 }
 374
 375                 setorigin(self,'0 0 0');
 376                 self.angles = '0 0 0';
 377                 self.frame = 0;
 378                 self.viewmodelforclient = world;
 379
 380                 float idx;
 381
 382                 if(v_shot_idx) // v_ model attached to invisible h_ model
 383                 {
 384                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 385                 }
 386                 else
 387                 {
 388                         idx = gettagindex(self, "shot");
 389                         if(!idx)
 390                                 idx = gettagindex(self, "tag_shot");
 391                         if(idx)
 392                                 self.movedir = gettaginfo(self, idx);
 393                         else
 394                         {
 395                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 396                                 self.movedir = '0 0 0';
 397                         }
 398                 }
 399
 400                 if(self.weaponentity) // v_ model attached to invisible h_ model
 401                 {
 402                         idx = gettagindex(self.weaponentity, "shell");
 403                         if(!idx)
 404                                 idx = gettagindex(self.weaponentity, "tag_shell");
 405                         if(idx)
 406                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 407                 }
 408                 else
 409                         idx = 0;
 410                 if(!idx)
 411                 {
 412                         idx = gettagindex(self, "shell");
 413                         if(!idx)
 414                                 idx = gettagindex(self, "tag_shell");
 415                         if(idx)
 416                                 self.spawnorigin = gettaginfo(self, idx);
 417                         else
 418                         {
 419                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 420                                 self.spawnorigin = self.movedir;
 421                         }
 422                 }
 423
 424                 if(v_shot_idx)
 425                 {
 426                         self.oldorigin = '0 0 0'; // use regular attachment
 427                 }
 428                 else
 429                 {
 430                         if(self.weaponentity)
 431                         {
 432                                 idx = gettagindex(self, "weapon");
 433                                 if(!idx)
 434                                         idx = gettagindex(self, "tag_weapon");
 435                         }
 436                         else
 437                         {
 438                                 idx = gettagindex(self, "handle");
 439                                 if(!idx)
 440                                         idx = gettagindex(self, "tag_handle");
 441                         }
 442                         if(idx)
 443                         {
 444                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 445                         }
 446                         else
 447                         {
 448                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 449                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 450                         }
 451                 }
 452
 453                 self.viewmodelforclient = self.owner;
 454         }
 455         else
 456         {
 457                 self.model = "";
 458                 if(self.weaponentity)
 459                         remove(self.weaponentity);
 460                 self.weaponentity = world;
 461                 self.movedir = '0 0 0';
 462                 self.spawnorigin = '0 0 0';
 463                 self.oldorigin = '0 0 0';
 464                 self.anim_fire1  = '0 1 0.01';
 465                 self.anim_fire2  = '0 1 0.01';
 466                 self.anim_idle   = '0 1 0.01';
 467                 self.anim_reload = '0 1 0.01';
 468         }
 469
 470         self.view_ofs = '0 0 0';
 471
 472         if(self.movedir_x >= 0)
 473         {
 474                 vector v0;
 475                 v0 = self.movedir;
 476                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 477                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 478         }
 479         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 480         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 481
 482         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 483
 484         // check if an instant weapon switch occurred
 485         setorigin(self, self.view_ofs);
 486         // reset animstate now
 487         self.wframe = WFRAME_IDLE;
 488         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 489 }
 490
 491 vector CL_Weapon_GetShotOrg(float wpn)
 492 {
 493         entity wi, oldself;
 494         vector ret;
 495         wi = get_weaponinfo(wpn);
 496         oldself = self;
 497         self = spawn();
 498         CL_WeaponEntity_SetModel(wi.mdl);
 499         ret = self.movedir;
 500         CL_WeaponEntity_SetModel("");
 501         remove(self);
 502         self = oldself;
 503         return ret;
 504 }
 505
 506 void CL_Weaponentity_Think()
 507 {
 508         float tb;
 509         self.nextthink = time;
 510         if (intermission_running)
 511                 self.frame = self.anim_idle_x;
 512         if (self.owner.weaponentity != self)
 513         {
 514                 if (self.weaponentity)
 515                         remove(self.weaponentity);
 516                 remove(self);
 517                 return;
 518         }
 519         if (self.owner.deadflag != DEAD_NO)
 520         {
 521                 self.model = "";
 522                 if (self.weaponentity)
 523                         self.weaponentity.model = "";
 524                 return;
 525         }
 526         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 527         {
 528                 self.weaponname = self.owner.weaponname;
 529                 self.dmg = self.owner.modelindex;
 530                 self.deadflag = self.owner.deadflag;
 531
 532                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 533         }
 534
 535         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 536         self.effects = self.owner.effects & EFMASK_CHEAP;
 537         self.effects &~= EF_LOWPRECISION;
 538         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 539         self.effects &~= EF_TELEPORT_BIT;
 540         self.effects &~= EF_RESTARTANIM_BIT;
 541         self.effects |= tb;
 542
 543         if(self.owner.alpha == default_player_alpha)
 544                 self.alpha = default_weapon_alpha;
 545         else if(self.owner.alpha != 0)
 546                 self.alpha = self.owner.alpha;
 547         else
 548                 self.alpha = 1;
 549
 550         self.glowmod = self.owner.weaponentity_glowmod;
 551         self.colormap = self.owner.colormap;
 552         if (self.weaponentity)
 553         {
 554                 self.weaponentity.effects = self.effects;
 555                 self.weaponentity.alpha = self.alpha;
 556                 self.weaponentity.colormap = self.colormap;
 557                 self.weaponentity.glowmod = self.glowmod;
 558         }
 559
 560         self.angles = '0 0 0';
 561         float f;
 562         f = 0;
 563         if (self.state == WS_RAISE && !intermission_running)
 564         {
 565                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 566                 self.angles_x = -90 * f * f;
 567         }
 568         else if (self.state == WS_DROP && !intermission_running)
 569         {
 570                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 571                 self.angles_x = -90 * f * f;
 572         }
 573         else if (self.state == WS_CLEAR)
 574         {
 575                 f = 1;
 576                 self.angles_x = -90 * f * f;
 577         }
 578 }
 579
 580 void CL_ExteriorWeaponentity_Think()
 581 {
 582         float tag_found;
 583         vector ang;
 584         self.nextthink = time;
 585         if (self.owner.exteriorweaponentity != self)
 586         {
 587                 remove(self);
 588                 return;
 589         }
 590         if (self.owner.deadflag != DEAD_NO)
 591         {
 592                 self.model = "";
 593                 return;
 594         }
 595         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 596         {
 597                 self.weaponname = self.owner.weaponname;
 598                 self.dmg = self.owner.modelindex;
 599                 self.deadflag = self.owner.deadflag;
 600                 if (self.owner.weaponname != "")
 601                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 602                 else
 603                         self.model = "";
 604
 605                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 606                 {
 607                         self.tag_index = tag_found;
 608                         self.tag_entity = self.owner;
 609                 }
 610                 else
 611                         setattachment(self, self.owner, "bip01 r hand");
 612
 613                 // if that didn't find a tag, hide the exterior weapon model
 614                 if (!self.tag_index)
 615                         self.model = "";
 616         }
 617         self.effects = self.owner.effects;
 618         if(sv_pitch_min == sv_pitch_max)
 619                 self.effects |= EF_LOWPRECISION;
 620         else
 621                 self.effects &~= EF_LOWPRECISION;
 622         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 623         if(self.owner.alpha == default_player_alpha)
 624                 self.alpha = default_weapon_alpha;
 625         else if(self.owner.alpha != 0)
 626                 self.alpha = self.owner.alpha;
 627         else
 628                 self.alpha = 1;
 629
 630         if (!intermission_running)
 631         {
 632                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 633                 ang_y = 0;
 634                 ang_z = 0;
 635
 636                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 637                 {
 638                         ang_y = self.owner.v_angle_y;
 639                         makevectors(ang);
 640                         var vector v = v_forward;
 641                         var float t = self.tag_entity.frame1time;
 642                         var float f = self.tag_entity.frame;
 643                         self.tag_entity.frame1time = time;
 644                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 645                         gettaginfo(self.tag_entity, self.tag_index);
 646                         self.tag_entity.frame1time = t;
 647                         self.tag_entity.frame = f;
 648                         // untransform v according to this coordinate space
 649                         vector w;
 650                         w_x = v_forward * v;
 651                         w_y = -v_right * v;
 652                         w_z = v_up * v;
 653                         self.angles = vectoangles(w);
 654                 }
 655                 else
 656                 {
 657                         ang_x = -/* don't ask */ang_x;
 658                         self.angles = ang;
 659                 }
 660
 661                 if(autocvar_g_loituma)
 662                 {
 663                         vector modangles;
 664                         float t;
 665
 666                         t = time * autocvar_g_loituma;
 667
 668                         modangles_x = t * 360;
 669                         modangles_y = 90;
 670                         modangles_z = 0;
 671
 672                         self.angles =
 673                                 AnglesTransform_ToAngles(
 674                                         AnglesTransform_Multiply(
 675                                                 AnglesTransform_FromAngles(self.angles),
 676                                                 AnglesTransform_FromAngles(modangles)
 677                                         )
 678                                 );
 679                 }
 680         }
 681
 682         self.glowmod = self.owner.weaponentity_glowmod;
 683         self.colormap = self.owner.colormap;
 684 }
 685
 686 // spawning weaponentity for client
 687 void CL_SpawnWeaponentity()
 688 {
 689         self.weaponentity = spawn();
 690         self.weaponentity.classname = "weaponentity";
 691         self.weaponentity.solid = SOLID_NOT;
 692         self.weaponentity.owner = self;
 693         setmodel(self.weaponentity, ""); // precision set when changed
 694         setorigin(self.weaponentity, '0 0 0');
 695         self.weaponentity.angles = '0 0 0';
 696         self.weaponentity.viewmodelforclient = self;
 697         self.weaponentity.flags = 0;
 698         self.weaponentity.think = CL_Weaponentity_Think;
 699         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 700         self.weaponentity.nextthink = time;
 701
 702         self.exteriorweaponentity = spawn();
 703         self.exteriorweaponentity.classname = "exteriorweaponentity";
 704         self.exteriorweaponentity.solid = SOLID_NOT;
 705         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 706         self.exteriorweaponentity.owner = self;
 707         setorigin(self.exteriorweaponentity, '0 0 0');
 708         self.exteriorweaponentity.angles = '0 0 0';
 709         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 710         self.exteriorweaponentity.nextthink = time;
 711 }
 712
 713 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 714 {
 715         msg_entity = e;
 716         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 717         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 718         WriteByte(MSG_ONE, wpn);
 719         WriteString(MSG_ONE, wpnname);
 720         WriteByte(MSG_ONE, type);
 721 }
 722
 723 .float hasweapon_complain_spam;
 724
 725 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 726 {
 727         float weaponbit, f;
 728         entity oldself;
 729
 730         if(time < self.hasweapon_complain_spam)
 731                 complain = 0;
 732         if(complain)
 733                 self.hasweapon_complain_spam = time + 0.2;
 734
 735         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 736         {
 737                 if (complain)
 738                         sprint(self, "Invalid weapon\n");
 739                 return FALSE;
 740         }
 741         weaponbit = W_WeaponBit(wpn);
 742         if (cl.weapons & weaponbit)
 743         {
 744                 if (andammo)
 745                 {
 746                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 747                         {
 748                                 f = 1;
 749                         }
 750                         else
 751                         {
 752                                 oldself = self;
 753                                 self = cl;
 754                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 755                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 756
 757                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 758                                 entity mine;
 759                                 if(wpn == WEP_MINE_LAYER)
 760                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 761                                         f = 1;
 762
 763                                 self = oldself;
 764                         }
 765                         if (!f)
 766                         {
 767                                 if (complain)
 768                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 769                                 {
 770                                         play2(cl, "weapons/unavailable.wav");
 771                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 772                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 773                                 }
 774                                 return FALSE;
 775                         }
 776                 }
 777                 return TRUE;
 778         }
 779         if (complain)
 780         {
 781                 // DRESK - 3/16/07
 782                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 783                 if(weaponsInMap & weaponbit)
 784                 {
 785                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 786                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 787
 788                         if(autocvar_g_showweaponspawns)
 789                         {
 790                                 entity e;
 791                                 string s;
 792
 793                                 e = get_weaponinfo(wpn);
 794                                 s = e.model2;
 795
 796                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 797                                 {
 798                                         if(e.classname == "droppedweapon")
 799                                                 continue;
 800                                         if not(e.flags & FL_ITEM)
 801                                                 continue;
 802                                         WaypointSprite_Spawn(
 803                                                 s,
 804                                                 1, 0,
 805                                                 world, e.origin,
 806                                                 self, 0,
 807                                                 world, enemy,
 808                                                 0,
 809                                                 RADARICON_NONE, '0 0 0'
 810                                         );
 811                                 }
 812                         }
 813                 }
 814                 else
 815                 {
 816                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 817                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 818                 }
 819
 820                 play2(cl, "weapons/unavailable.wav");
 821         }
 822         return FALSE;
 823 }
 824
 825 // Weapon subs
 826 void w_clear()
 827 {
 828         if (self.weapon != -1)
 829         {
 830                 self.weapon = 0;
 831                 self.switchingweapon = 0;
 832         }
 833         if (self.weaponentity)
 834         {
 835                 self.weaponentity.state = WS_CLEAR;
 836                 self.weaponentity.effects = 0;
 837         }
 838 }
 839
 840 void w_ready()
 841 {
 842         if (self.weaponentity)
 843                 self.weaponentity.state = WS_READY;
 844         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 845 }
 846
 847 // Setup weapon for client (after this raise frame will be launched)
 848 void weapon_setup(float windex)
 849 {
 850         entity e;
 851         e = get_weaponinfo(windex);
 852         self.items &~= IT_AMMO;
 853         self.items = self.items | e.items;
 854
 855         // the two weapon entities will notice this has changed and update their models
 856         self.weapon = windex;
 857         self.switchingweapon = windex; // to make sure
 858         self.weaponname = e.mdl;
 859         self.bulletcounter = 0;
 860 }
 861
 862 // perform weapon to attack (weaponstate and attack_finished check is here)
 863 void W_SwitchToOtherWeapon(entity pl)
 864 {
 865         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 866         float w, ww;
 867         w = W_WeaponBit(pl.weapon);
 868         pl.weapons &~= w;
 869         ww = w_getbestweapon(pl);
 870         pl.weapons |= w;
 871         if(ww)
 872                 W_SwitchWeapon_Force(pl, ww);
 873 }
 874 .float prevdryfire;
 875 float weapon_prepareattack_checkammo(float secondary)
 876 {
 877         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 878         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 879         {
 880                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 881                 entity mine;
 882                 if(self.weapon == WEP_MINE_LAYER)
 883                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 884                         return FALSE;
 885
 886                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 887                 {
 888                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 889                         self.prevdryfire = time;
 890                 }
 891
 892                 W_SwitchToOtherWeapon(self);
 893                 return FALSE;
 894         }
 895         return TRUE;
 896 }
 897 .float race_penalty;
 898 float weapon_prepareattack_check(float secondary, float attacktime)
 899 {
 900         if(!weapon_prepareattack_checkammo(secondary))
 901                 return FALSE;
 902
 903         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 904         //if all players readied up and the countdown is running
 905         if(time < game_starttime || time < self.race_penalty) {
 906                 return FALSE;
 907         }
 908
 909         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 910                 return FALSE;
 911
 912         // do not even think about shooting if switching
 913         if(self.switchweapon != self.weapon)
 914                 return FALSE;
 915
 916         if(attacktime >= 0)
 917         {
 918                 // don't fire if previous attack is not finished
 919                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 920                         return FALSE;
 921                 // don't fire while changing weapon
 922                 if (self.weaponentity.state != WS_READY)
 923                         return FALSE;
 924         }
 925
 926         return TRUE;
 927 }
 928 float weapon_prepareattack_do(float secondary, float attacktime)
 929 {
 930         self.weaponentity.state = WS_INUSE;
 931
 932         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 933
 934         // if the weapon hasn't been firing continuously, reset the timer
 935         if(attacktime >= 0)
 936         {
 937                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 938                 {
 939                         ATTACK_FINISHED(self) = time;
 940                         //dprint("resetting attack finished to ", ftos(time), "\n");
 941                 }
 942                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 943         }
 944         self.bulletcounter += 1;
 945         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 946         return TRUE;
 947 }
 948 float weapon_prepareattack(float secondary, float attacktime)
 949 {
 950         if(weapon_prepareattack_check(secondary, attacktime))
 951         {
 952                 weapon_prepareattack_do(secondary, attacktime);
 953                 return TRUE;
 954         }
 955         else
 956                 return FALSE;
 957 }
 958
 959 void weapon_thinkf(float fr, float t, void() func)
 960 {
 961         vector a;
 962         vector of, or, ou;
 963         float restartanim;
 964
 965         if(fr == WFRAME_DONTCHANGE)
 966         {
 967                 fr = self.weaponentity.wframe;
 968                 restartanim = FALSE;
 969         }
 970         else if (fr == WFRAME_IDLE)
 971                 restartanim = FALSE;
 972         else
 973                 restartanim = TRUE;
 974
 975         of = v_forward;
 976         or = v_right;
 977         ou = v_up;
 978
 979         if (self.weaponentity)
 980         {
 981                 self.weaponentity.wframe = fr;
 982                 if (fr == WFRAME_IDLE)
 983                         a = self.weaponentity.anim_idle;
 984                 else if (fr == WFRAME_FIRE1)
 985                         a = self.weaponentity.anim_fire1;
 986                 else if (fr == WFRAME_FIRE2)
 987                         a = self.weaponentity.anim_fire2;
 988                 else if (fr == WFRAME_RELOAD)
 989                         a = self.weaponentity.anim_reload;
 990                 a_z *= g_weaponratefactor;
 991                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 992         }
 993
 994         v_forward = of;
 995         v_right = or;
 996         v_up = ou;
 997
 998         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 999         {
1000                 backtrace("Tried to override initial weapon think function - should this really happen?");
1001         }
1002
1003         t *= W_WeaponRateFactor();
1004
1005         // VorteX: haste can be added here
1006         if (self.weapon_think == w_ready)
1007         {
1008                 self.weapon_nextthink = time;
1009                 //dprint("started firing at ", ftos(time), "\n");
1010         }
1011         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1012         {
1013                 self.weapon_nextthink = time;
1014                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1015         }
1016         self.weapon_nextthink = self.weapon_nextthink + t;
1017         self.weapon_think = func;
1018         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1019
1020         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1021         //anim = self.anim_shoot;
1022         if (restartanim)
1023         if (t)
1024         if (!self.crouch) // shoot anim stands up, this looks bad
1025         {
1026                 vector anim;
1027                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1028                 {
1029                         anim = self.anim_melee;
1030                         anim_z = anim_y / (t + sys_frametime);
1031                         setanim(self, anim, FALSE, TRUE, TRUE);
1032                 }
1033                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1034                 {
1035                         anim = self.anim_shoot;
1036                         anim_z = anim_y / (t + sys_frametime);
1037                         setanim(self, anim, FALSE, TRUE, TRUE);
1038                 }
1039         }
1040 }
1041
1042 void weapon_boblayer1(float spd, vector org)
1043 {
1044         // VorteX: haste can be added here
1045 }
1046
1047 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1048 {
1049         vector mdirection;
1050         float mspeed;
1051         float outspeed;
1052         float nstyle;
1053         vector outvelocity;
1054
1055         mvelocity = mvelocity * g_weaponspeedfactor;
1056
1057         mdirection = normalize(mvelocity);
1058         mspeed = vlen(mvelocity);
1059
1060         nstyle = autocvar_g_projectiles_newton_style;
1061         if(nstyle == 0 || forceAbsolute)
1062         {
1063                 // absolute velocity
1064                 outvelocity = mvelocity;
1065         }
1066         else if(nstyle == 1)
1067         {
1068                 // true Newtonian projectiles
1069                 outvelocity = pvelocity + mvelocity;
1070         }
1071         else if(nstyle == 2)
1072         {
1073                 // true Newtonian projectiles with automatic aim adjustment
1074                 //
1075                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1076                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1077                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1078                 // PLUS SIGN!
1079                 // not defined?
1080                 // then...
1081                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1082                 // velocity without mdirection component > mspeed
1083                 // fire at smallest possible mspeed that works?
1084                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1085
1086                 vector solution;
1087                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1088                 if(solution_z)
1089                         outspeed = solution_y; // the larger one
1090                 else
1091                 {
1092                         //outspeed = 0; // slowest possible shot
1093                         outspeed = solution_x; // the real part (that is, the average!)
1094                         //dprint("impossible shot, adjusting\n");
1095                 }
1096
1097                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1098                 outvelocity = mdirection * outspeed;
1099         }
1100         else if(nstyle == 3)
1101         {
1102                 // pseudo-Newtonian:
1103                 outspeed = mspeed + mdirection * pvelocity;
1104                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1105                 outvelocity = mdirection * outspeed;
1106         }
1107         else if(nstyle == 4)
1108         {
1109                 // tZorkian:
1110                 outspeed = mspeed + vlen(pvelocity);
1111                 outvelocity = mdirection * outspeed;
1112         }
1113         else
1114                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1115
1116         return outvelocity;
1117 }
1118
1119 void W_AttachToShotorg(entity flash, vector offset)
1120 {
1121         entity xflash;
1122         flash.owner = self;
1123         flash.angles_z = random() * 360;
1124
1125         if(gettagindex(self.weaponentity, "shot"))
1126                 setattachment(flash, self.weaponentity, "shot");
1127         else
1128                 setattachment(flash, self.weaponentity, "tag_shot");
1129         setorigin(flash, offset);
1130
1131         xflash = spawn();
1132         copyentity(flash, xflash);
1133
1134         flash.viewmodelforclient = self;
1135
1136         if(self.weaponentity.oldorigin_x > 0)
1137         {
1138                 setattachment(xflash, self.exteriorweaponentity, "");
1139                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1140         }
1141         else
1142         {
1143                 if(gettagindex(self.exteriorweaponentity, "shot"))
1144                         setattachment(xflash, self.exteriorweaponentity, "shot");
1145                 else
1146                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1147                 setorigin(xflash, offset);
1148         }
1149 }
1150
1151 vector cliptoplane(vector v, vector p)
1152 {
1153         return v - (v * p) * p;
1154 }
1155
1156 vector solve_cubic_pq(float p, float q)
1157 {
1158         float D, u, v, a;
1159         D = q*q/4.0 + p*p*p/27.0;
1160         if(D < 0)
1161         {
1162                 // irreducibilis
1163                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1164                 u = sqrt(-4.0/3.0 * p);
1165                 // a in range 0..pi/3
1166                 // cos(a)
1167                 // cos(a + 2pi/3)
1168                 // cos(a + 4pi/3)
1169                 return
1170                         u *
1171                         (
1172                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1173                                 +
1174                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1175                                 +
1176                                 '0 0 1' * cos(a)
1177                         );
1178         }
1179         else if(D == 0)
1180         {
1181                 // simple
1182                 if(p == 0)
1183                         return '0 0 0';
1184                 u = 3*q/p;
1185                 v = -u/2;
1186                 if(u >= v)
1187                         return '1 1 0' * v + '0 0 1' * u;
1188                 else
1189                         return '0 1 1' * v + '1 0 0' * u;
1190         }
1191         else
1192         {
1193                 // cardano
1194                 u = cbrt(-q/2.0 + sqrt(D));
1195                 v = cbrt(-q/2.0 - sqrt(D));
1196                 return '1 1 1' * (u + v);
1197         }
1198 }
1199 vector solve_cubic_abcd(float a, float b, float c, float d)
1200 {
1201         // y = 3*a*x + b
1202         // x = (y - b) / 3a
1203         float p, q;
1204         vector v;
1205         p = (9*a*c - 3*b*b);
1206         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1207         v = solve_cubic_pq(p, q);
1208         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1209         if(a < 0)
1210                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1211         return v;
1212 }
1213
1214 vector findperpendicular(vector v)
1215 {
1216         vector p;
1217         p_x = v_z;
1218         p_y = -v_x;
1219         p_z = v_y;
1220         return normalize(cliptoplane(p, v));
1221 }
1222
1223 vector W_CalculateProjectileSpread(vector forward, float spread)
1224 {
1225         float sigma;
1226         vector v1, v2;
1227         float dx, dy, r;
1228         float sstyle;
1229         spread *= g_weaponspreadfactor;
1230         if(spread <= 0)
1231                 return forward;
1232         sstyle = autocvar_g_projectiles_spread_style;
1233
1234         if(sstyle == 0)
1235         {
1236                 // this is the baseline for the spread value!
1237                 // standard deviation: sqrt(2/5)
1238                 // density function: sqrt(1-r^2)
1239                 return forward + randomvec() * spread;
1240         }
1241         else if(sstyle == 1)
1242         {
1243                 // same thing, basically
1244                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1245         }
1246         else if(sstyle == 2)
1247         {
1248                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1249                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1250                 v1 = findperpendicular(forward);
1251                 v2 = cross(forward, v1);
1252                 // random point on unit circle
1253                 dx = random() * 2 * M_PI;
1254                 dy = sin(dx);
1255                 dx = cos(dx);
1256                 // radius in our dist function
1257                 r = random();
1258                 r = sqrt(r);
1259                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1260         }
1261         else if(sstyle == 3) // gauss 3d
1262         {
1263                 sigma = spread * 0.44721359549996; // match baseline stddev
1264                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1265                 v1 = forward;
1266                 v1_x += gsl_ran_gaussian(sigma);
1267                 v1_y += gsl_ran_gaussian(sigma);
1268                 v1_z += gsl_ran_gaussian(sigma);
1269                 return v1;
1270         }
1271         else if(sstyle == 4) // gauss 2d
1272         {
1273                 sigma = spread * 0.44721359549996; // match baseline stddev
1274                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1275                 v1_x = gsl_ran_gaussian(sigma);
1276                 v1_y = gsl_ran_gaussian(sigma);
1277                 v1_z = gsl_ran_gaussian(sigma);
1278                 return normalize(forward + cliptoplane(v1, forward));
1279         }
1280         else if(sstyle == 5) // 1-r
1281         {
1282                 sigma = spread * 1.154700538379252; // match baseline stddev
1283                 v1 = findperpendicular(forward);
1284                 v2 = cross(forward, v1);
1285                 // random point on unit circle
1286                 dx = random() * 2 * M_PI;
1287                 dy = sin(dx);
1288                 dx = cos(dx);
1289                 // radius in our dist function
1290                 r = random();
1291                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1292                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1293         }
1294         else if(sstyle == 6) // 1-r^2
1295         {
1296                 sigma = spread * 1.095445115010332; // match baseline stddev
1297                 v1 = findperpendicular(forward);
1298                 v2 = cross(forward, v1);
1299                 // random point on unit circle
1300                 dx = random() * 2 * M_PI;
1301                 dy = sin(dx);
1302                 dx = cos(dx);
1303                 // radius in our dist function
1304                 r = random();
1305                 r = sqrt(1 - r);
1306                 r = sqrt(1 - r);
1307                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1308         }
1309         else if(sstyle == 7) // (1-r) (2-r)
1310         {
1311                 sigma = spread * 1.224744871391589; // match baseline stddev
1312                 v1 = findperpendicular(forward);
1313                 v2 = cross(forward, v1);
1314                 // random point on unit circle
1315                 dx = random() * 2 * M_PI;
1316                 dy = sin(dx);
1317                 dx = cos(dx);
1318                 // radius in our dist function
1319                 r = random();
1320                 r = 1 - sqrt(r);
1321                 r = 1 - sqrt(r);
1322                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1323         }
1324         else
1325                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1326         return '0 0 0';
1327         /*
1328          * how to derive falloff functions:
1329          * rho(r) := (2-r) * (1-r);
1330          * a : 0;
1331          * b : 1;
1332          * rhor(r) := r * rho(r);
1333          * cr(t) := integrate(rhor(r), r, a, t);
1334          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1335          * variance : scr(b) / cr(b);
1336          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1337          * sqrt(0.4 / variance), numer;
1338          */
1339 }
1340
1341 #if 0
1342 float mspercallsum;
1343 float mspercallsstyle;
1344 float mspercallcount;
1345 #endif
1346 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1347 {
1348         if(missile.owner == world)
1349                 error("Unowned missile");
1350
1351         dir = dir + upDir * (pUpSpeed / pSpeed);
1352         dir_z += pZSpeed / pSpeed;
1353         pSpeed *= vlen(dir);
1354         dir = normalize(dir);
1355
1356 #if 0
1357         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1358         {
1359                 mspercallsum = mspercallcount = 0;
1360                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1361         }
1362         mspercallsum -= gettime(GETTIME_HIRES);
1363 #endif
1364         dir = W_CalculateProjectileSpread(dir, spread);
1365 #if 0
1366         mspercallsum += gettime(GETTIME_HIRES);
1367         mspercallcount += 1;
1368         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1369 #endif
1370
1371         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1372 }
1373
1374 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1375 {
1376         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1377 }
1378
1379 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1380 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1381
1382 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1383 {
1384         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1385                 return;
1386
1387         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1388         if(ammo_reload)
1389         {
1390                 self.clip_load -= ammo_use;
1391                 self.(weapon_load[self.weapon]) = self.clip_load;
1392         }
1393         else
1394                 self.(self.current_ammo) -= ammo_use;
1395 }
1396
1397 // weapon reloading code
1398
1399 .float reload_ammo_amount, reload_ammo_min, reload_time;
1400 .float reload_complain;
1401 .string reload_sound;
1402
1403 void W_ReloadedAndReady()
1404 {
1405         // finish the reloading process, and do the ammo transfer
1406
1407         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1408
1409         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1410         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1411                 self.clip_load = self.reload_ammo_amount;
1412         else
1413         {
1414                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1415                 {
1416                         self.clip_load += 1;
1417                         self.(self.current_ammo) -= 1;
1418                 }
1419         }
1420         self.(weapon_load[self.weapon]) = self.clip_load;
1421
1422         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1423         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1424         // so your weapon is disabled for a few seconds without reason
1425
1426         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1427
1428         w_ready();
1429 }
1430
1431 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1432 {
1433         // set global values to work with
1434
1435         self.reload_ammo_min = sent_ammo_min;
1436         self.reload_ammo_amount = sent_ammo_amount;
1437         self.reload_time = sent_time;
1438         self.reload_sound = sent_sound;
1439
1440         // check if we meet the necessary conditions to reload
1441
1442         entity e;
1443         e = get_weaponinfo(self.weapon);
1444
1445         // don't reload weapons that don't have the RELOADABLE flag
1446         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1447         {
1448                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1449                 return;
1450         }
1451
1452         // return if reloading is disabled for this weapon
1453         if(!self.reload_ammo_amount)
1454                 return;
1455
1456         // our weapon is fully loaded, no need to reload
1457         if (self.clip_load >= self.reload_ammo_amount)
1458                 return;
1459
1460         // no ammo, so nothing to load
1461         if(!self.(self.current_ammo) && self.reload_ammo_min)
1462         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1463         {
1464                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1465                 {
1466                         play2(self, "weapons/unavailable.wav");
1467                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1468                         self.reload_complain = time + 1;
1469                 }
1470                 // switch away if the amount of ammo is not enough to keep using this weapon
1471                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1472                 {
1473                         self.clip_load = -1; // reload later
1474                         W_SwitchToOtherWeapon(self);
1475                 }
1476                 return;
1477         }
1478
1479         if (self.weaponentity)
1480         {
1481                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1482                         return;
1483
1484                 // allow switching away while reloading, but this will cause a new reload!
1485                 self.weaponentity.state = WS_READY;
1486         }
1487
1488         // now begin the reloading process
1489
1490         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1491
1492         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1493         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1494         // so your weapon is disabled for a few seconds without reason
1495
1496         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1497
1498         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1499
1500         if(self.clip_load < 0)
1501                 self.clip_load = 0;
1502         self.old_clip_load = self.clip_load;
1503         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1504 }