qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 .float prevstrengthsound;
 134 .float prevstrengthsoundattempt;
 135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 136 {
 137         float nudge = 1; // added to traceline target and subtracted from result
 138         local float oldsolid;
 139         vector vecs, dv;
 140         oldsolid = ent.dphitcontentsmask;
 141         if(ent.weapon == WEP_CAMPINGRIFLE)
 142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         else
 144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 145         if(antilag)
 146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 147                 // passing world, because we do NOT want it to touch dphitcontentsmask
 148         else
 149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 151
 152         vector vf, vr, vu;
 153         vf = v_forward;
 154         vr = v_right;
 155         vu = v_up;
 156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 157         v_forward = vf;
 158         v_right = vr;
 159         v_up = vu;
 160
 161         // track max damage
 162         if(accuracy_canbegooddamage(ent))
 163                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 164
 165         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 166
 167         if(ent.weaponentity.movedir_x > 0)
 168                 vecs = ent.weaponentity.movedir;
 169         else
 170                 vecs = '0 0 0';
 171         if(debug_shotorg != '0 0 0')
 172                 vecs = debug_shotorg;
 173
 174         dv = v_right * -vecs_y + v_up * vecs_z;
 175         w_shotorg = ent.origin + ent.view_ofs + dv;
 176
 177         // now move the shotorg forward as much as requested if possible
 178         if(antilag)
 179         {
 180                 if(ent.antilag_debug)
 181                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 182                 else
 183                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 184         }
 185         else
 186                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 187         w_shotorg = trace_endpos - v_forward * nudge;
 188         // calculate the shotdir from the chosen shotorg
 189         w_shotdir = normalize(w_shotend - w_shotorg);
 190
 191         if (antilag)
 192         if (!ent.cvar_cl_noantilag)
 193         {
 194                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 195                 {
 196                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 197                         if (!trace_ent.takedamage)
 198                         {
 199                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 201                                 {
 202                                         entity e;
 203                                         e = trace_ent;
 204                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 205                                         if(trace_ent == e)
 206                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 207                                 }
 208                         }
 209                 }
 210                 else if(autocvar_g_antilag == 3) // client side hitscan
 211                 {
 212                         // this part MUST use prydon cursor
 213                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 214                         if (ent.cursor_trace_ent != ent)         // just to make sure
 215                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 216                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 217                         {
 218                                 // verify that the shot would miss without antilag
 219                                 // (avoids an issue where guns would always shoot at their origin)
 220                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 221                                 if (!trace_ent.takedamage)
 222                                 {
 223                                         // verify that the shot would hit if altered
 224                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 225                                         if (trace_ent == ent.cursor_trace_ent)
 226                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 227                                         else
 228                                                 print("antilag fail\n");
 229                                 }
 230                         }
 231                 }
 232         }
 233
 234         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 235
 236         if (!g_norecoil)
 237                 ent.punchangle_x = recoil * -1;
 238
 239         if (snd != "")
 240                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 241
 242         if(ent.items & IT_STRENGTH)
 243         if(!g_minstagib)
 244         if(
 245                 (time > ent.prevstrengthsound + autocvar_sv_strengthsound_antispam_time)
 246                 ||
 247                 (time > ent.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)
 248         ) // prevent insane sound spam
 249         {
 250                 sound(ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 251                 ent.prevstrengthsound = time;
 252         }
 253         ent.prevstrengthsoundattempt = time;
 254
 255         // nudge w_shotend so a trace to w_shotend hits
 256         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 257 };
 258
 259 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 260 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 261 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 262 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 263 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 264
 265 float CL_Weaponentity_CustomizeEntityForClient()
 266 {
 267         self.viewmodelforclient = self.owner;
 268         if(other.classname == "spectator")
 269                 if(other.enemy == self.owner)
 270                         self.viewmodelforclient = other;
 271         return TRUE;
 272 }
 273
 274 float qcweaponanimation;
 275 vector weapon_offset = '0 -10 0';
 276 vector weapon_adjust = '10 0 -15';
 277 .vector weapon_morph0origin;
 278 .vector weapon_morph0angles;
 279 .float  weapon_morph0time;
 280 .vector weapon_morph1origin;
 281 .vector weapon_morph1angles;
 282 .float  weapon_morph1time;
 283 .vector weapon_morph2origin;
 284 .vector weapon_morph2angles;
 285 .float  weapon_morph2time;
 286 .vector weapon_morph3origin;
 287 .vector weapon_morph3angles;
 288 .float  weapon_morph3time;
 289 .vector weapon_morph4origin;
 290 .vector weapon_morph4angles;
 291 .float  weapon_morph4time;
 292 .string weaponname;
 293 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 294
 295 /*
 296  * supported formats:
 297  *
 298  * 1. simple animated model, muzzle flash handling on h_ model:
 299  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 300  *      tags:
 301  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 302  *        shell = casings ejection point (must be on the right hand side of the gun)
 303  *        weapon = attachment for v_tuba.md3
 304  *    v_tuba.md3 - first and third person model
 305  *    g_tuba.md3 - pickup model
 306  *
 307  * 2. simple animated model, muzzle flash handling on v_ model:
 308  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 309  *      tags:
 310  *        weapon = attachment for v_tuba.md3
 311  *    v_tuba.md3 - first and third person model
 312  *      tags:
 313  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 314  *        shell = casings ejection point (must be on the right hand side of the gun)
 315  *    g_tuba.md3 - pickup model
 316  *
 317  * 3. fully animated model, muzzle flash handling on h_ model:
 318  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 319  *      tags:
 320  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 321  *        shell = casings ejection point (must be on the right hand side of the gun)
 322  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 323  *    v_tuba.md3 - third person model
 324  *    g_tuba.md3 - pickup model
 325  *
 326  * 4. fully animated model, muzzle flash handling on v_ model:
 327  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 328  *      tags:
 329  *        shot = muzzle end (shot origin)
 330  *        shell = casings ejection point (must be on the right hand side of the gun)
 331  *    v_tuba.md3 - third person model
 332  *      tags:
 333  *        shot = muzzle end (for muzzle flashes)
 334  *    g_tuba.md3 - pickup model
 335  */
 336
 337 // writes:
 338 //   self.origin, self.angles
 339 //   self.weaponentity
 340 //   self.movedir, self.view_ofs
 341 //   attachment stuff
 342 //   anim stuff
 343 // to free:
 344 //   call again with ""
 345 //   remove the ent
 346 void CL_WeaponEntity_SetModel(string name)
 347 {
 348         string animfilename;
 349         float animfile;
 350         float v_shot_idx;
 351         if (name != "")
 352         {
 353                 // if there is a child entity, hide it until we're sure we use it
 354                 if (self.weaponentity)
 355                         self.weaponentity.model = "";
 356                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 357                 v_shot_idx = gettagindex(self, "shot"); // used later
 358                 if(!v_shot_idx)
 359                         v_shot_idx = gettagindex(self, "tag_shot");
 360
 361                 if(qcweaponanimation)
 362                 {
 363                         self.angles = '0 0 0';
 364                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 365                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 366                         self.movedir_x += 32;
 367                         self.spawnorigin = self.movedir;
 368                         // oldorigin - not calculated here
 369                 }
 370                 else
 371                 {
 372                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 373                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 374                         animfile = fopen(animfilename, FILE_READ);
 375                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 376                         self.anim_fire1  = '0 1 0.01';
 377                         self.anim_fire2  = '1 1 0.01';
 378                         self.anim_idle   = '2 1 0.01';
 379                         self.anim_reload = '3 1 0.01';
 380                         if (animfile >= 0)
 381                         {
 382                                 animparseerror = FALSE;
 383                                 self.anim_fire1  = animparseline(animfile);
 384                                 self.anim_fire2  = animparseline(animfile);
 385                                 self.anim_idle   = animparseline(animfile);
 386                                 self.anim_reload = animparseline(animfile);
 387                                 fclose(animfile);
 388                                 if (animparseerror)
 389                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 390                         }
 391
 392                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 393                         // if we don't, this is a "real" animated model
 394                         if(gettagindex(self, "weapon"))
 395                         {
 396                                 if (!self.weaponentity)
 397                                         self.weaponentity = spawn();
 398                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 399                                 setattachment(self.weaponentity, self, "weapon");
 400                         }
 401                         else if(gettagindex(self, "tag_weapon"))
 402                         {
 403                                 if (!self.weaponentity)
 404                                         self.weaponentity = spawn();
 405                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 406                                 setattachment(self.weaponentity, self, "tag_weapon");
 407                         }
 408                         else
 409                         {
 410                                 if(self.weaponentity)
 411                                         remove(self.weaponentity);
 412                                 self.weaponentity = world;
 413                         }
 414
 415                         setorigin(self,'0 0 0');
 416                         self.angles = '0 0 0';
 417                         self.frame = 0;
 418                         self.viewmodelforclient = world;
 419
 420                         float idx;
 421
 422                         if(v_shot_idx) // v_ model attached to invisible h_ model
 423                         {
 424                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 425                         }
 426                         else
 427                         {
 428                                 idx = gettagindex(self, "shot");
 429                                 if(!idx)
 430                                         idx = gettagindex(self, "tag_shot");
 431                                 if(idx)
 432                                         self.movedir = gettaginfo(self, idx);
 433                                 else
 434                                 {
 435                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 436                                         self.movedir = '0 0 0';
 437                                 }
 438                         }
 439
 440                         if(self.weaponentity) // v_ model attached to invisible h_ model
 441                         {
 442                                 idx = gettagindex(self.weaponentity, "shell");
 443                                 if(!idx)
 444                                         idx = gettagindex(self.weaponentity, "tag_shell");
 445                                 if(idx)
 446                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 447                         }
 448                         else
 449                                 idx = 0;
 450                         if(!idx)
 451                         {
 452                                 idx = gettagindex(self, "shell");
 453                                 if(!idx)
 454                                         idx = gettagindex(self, "tag_shell");
 455                                 if(idx)
 456                                         self.spawnorigin = gettaginfo(self, idx);
 457                                 else
 458                                 {
 459                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 460                                         self.spawnorigin = self.movedir;
 461                                 }
 462                         }
 463
 464                         if(v_shot_idx)
 465                         {
 466                                 self.oldorigin = '0 0 0'; // use regular attachment
 467                         }
 468                         else
 469                         {
 470                                 if(self.weaponentity)
 471                                 {
 472                                         idx = gettagindex(self, "weapon");
 473                                         if(!idx)
 474                                                 idx = gettagindex(self, "tag_weapon");
 475                                 }
 476                                 else
 477                                 {
 478                                         idx = gettagindex(self, "handle");
 479                                         if(!idx)
 480                                                 idx = gettagindex(self, "tag_handle");
 481                                 }
 482                                 if(idx)
 483                                 {
 484                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 485                                 }
 486                                 else
 487                                 {
 488                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 489                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 490                                 }
 491                         }
 492
 493                         self.viewmodelforclient = self.owner;
 494                 }
 495         }
 496         else
 497         {
 498                 self.model = "";
 499                 if(self.weaponentity)
 500                         remove(self.weaponentity);
 501                 self.weaponentity = world;
 502                 self.movedir = '0 0 0';
 503                 self.spawnorigin = '0 0 0';
 504                 self.oldorigin = '0 0 0';
 505                 self.anim_fire1  = '0 1 0.01';
 506                 self.anim_fire2  = '0 1 0.01';
 507                 self.anim_idle   = '0 1 0.01';
 508                 self.anim_reload = '0 1 0.01';
 509         }
 510
 511         self.view_ofs = '0 0 0';
 512
 513         if(self.movedir_x >= 0)
 514         {
 515                 vector v0;
 516                 v0 = self.movedir;
 517                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 518                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 519         }
 520         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 521         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 522
 523         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 524
 525         // check if an instant weapon switch occurred
 526         if (qcweaponanimation)
 527         {
 528                 if (self.state == WS_READY)
 529                 {
 530                         self.angles = '0 0 0';
 531                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 532                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 533                 }
 534         }
 535         else
 536                 setorigin(self, self.view_ofs);
 537         // reset animstate now
 538         self.wframe = WFRAME_IDLE;
 539         self.weapon_morph0time = 0;
 540         self.weapon_morph1time = 0;
 541         self.weapon_morph2time = 0;
 542         self.weapon_morph3time = 0;
 543         self.weapon_morph4time = 0;
 544         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 545 }
 546
 547 vector CL_Weapon_GetShotOrg(float wpn)
 548 {
 549         entity wi, oldself;
 550         vector ret;
 551         wi = get_weaponinfo(wpn);
 552         oldself = self;
 553         self = spawn();
 554         CL_WeaponEntity_SetModel(wi.mdl);
 555         ret = self.movedir;
 556         CL_WeaponEntity_SetModel("");
 557         remove(self);
 558         self = oldself;
 559         return ret;
 560 }
 561
 562 void CL_Weaponentity_Think()
 563 {
 564         float tb;
 565         self.nextthink = time;
 566         if (intermission_running)
 567                 self.frame = self.anim_idle_x;
 568         if (self.owner.weaponentity != self)
 569         {
 570                 if (self.weaponentity)
 571                         remove(self.weaponentity);
 572                 remove(self);
 573                 return;
 574         }
 575         if (self.owner.deadflag != DEAD_NO)
 576         {
 577                 self.model = "";
 578                 if (self.weaponentity)
 579                         self.weaponentity.model = "";
 580                 return;
 581         }
 582         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 583         {
 584                 self.cnt = self.owner.weapon;
 585                 self.dmg = self.owner.modelindex;
 586                 self.deadflag = self.owner.deadflag;
 587
 588                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 589         }
 590
 591         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 592         self.effects = self.owner.effects & EFMASK_CHEAP;
 593         self.effects &~= EF_LOWPRECISION;
 594         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 595         self.effects &~= EF_TELEPORT_BIT;
 596         self.effects &~= EF_RESTARTANIM_BIT;
 597         self.effects |= tb;
 598
 599         if(self.owner.alpha == default_player_alpha)
 600                 self.alpha = default_weapon_alpha;
 601         else if(self.owner.alpha != 0)
 602                 self.alpha = self.owner.alpha;
 603         else
 604                 self.alpha = 1;
 605
 606         self.colormap = self.owner.colormap;
 607         if (self.weaponentity)
 608         {
 609                 self.weaponentity.effects = self.effects;
 610                 self.weaponentity.alpha = self.alpha;
 611                 self.weaponentity.colormap = self.colormap;
 612         }
 613
 614         self.angles = '0 0 0';
 615         local float f;
 616         f = 0;
 617         if (self.state == WS_RAISE && !intermission_running)
 618         {
 619                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 620                 self.angles_x = -90 * f * f;
 621                 if (qcweaponanimation)
 622                 {
 623                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 624                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 625                 }
 626         }
 627         else if (self.state == WS_DROP && !intermission_running)
 628         {
 629                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 630                 self.angles_x = -90 * f * f;
 631                 if (qcweaponanimation)
 632                 {
 633                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 634                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 635                 }
 636         }
 637         else if (self.state == WS_CLEAR)
 638         {
 639                 f = 1;
 640                 self.angles_x = -90 * f * f;
 641                 if (qcweaponanimation)
 642                 {
 643                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 644                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 645                 }
 646         }
 647         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 648         {
 649                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 650                 f = 1 - pow(1 - f, 3);
 651                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 652                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 653         }
 654         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 655         {
 656                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 657                 f = 1 - pow(1 - f, 3);
 658                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 659                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 660         }
 661         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 662         {
 663                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 664                 f = 1 - pow(1 - f, 3);
 665                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 666                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 667         }
 668         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 669         {
 670                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 671                 f = 1 - pow(1 - f, 3);
 672                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 673                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 674         }
 675         else if (qcweaponanimation)
 676         {
 677                 // begin a new idle morph
 678                 self.owner.weapon_morph0time   = time;
 679                 self.owner.weapon_morph0angles = self.angles;
 680                 self.owner.weapon_morph0origin = self.origin;
 681
 682                 float r;
 683                 float t;
 684
 685                 r = random();
 686                 if (r < 0.1)
 687                 {
 688                         // turn gun to the left to look at it
 689                         t = 2;
 690                         self.owner.weapon_morph1time   = time + t * 0.2;
 691                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 692                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 693                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 694
 695                         self.owner.weapon_morph2time   = time + t * 0.6;
 696                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 697                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 698                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 699
 700                         self.owner.weapon_morph3time   = time + t;
 701                         self.owner.weapon_morph3angles = '0 0 0';
 702                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 703                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 704                 }
 705                 else if (r < 0.2)
 706                 {
 707                         // raise the gun a bit
 708                         t = 2;
 709                         self.owner.weapon_morph1time   = time + t * 0.2;
 710                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 711                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 712                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 713
 714                         self.owner.weapon_morph2time   = time + t * 0.5;
 715                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 716                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 717                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 718
 719                         self.owner.weapon_morph3time   = time + t;
 720                         self.owner.weapon_morph3angles = '0 0 0';
 721                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 722                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 723                 }
 724                 else if (r < 0.3)
 725                 {
 726                         // tweak it a bit
 727                         t = 5;
 728                         self.owner.weapon_morph1time   = time + t * 0.3;
 729                         self.owner.weapon_morph1angles = randomvec() * 6;
 730                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 731                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 732
 733                         self.owner.weapon_morph2time   = time + t * 0.7;
 734                         self.owner.weapon_morph2angles = randomvec() * 6;
 735                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 736                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 737
 738                         self.owner.weapon_morph3time   = time + t;
 739                         self.owner.weapon_morph3angles = '0 0 0';
 740                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 741                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 742                 }
 743                 else
 744                 {
 745                         // hold it mostly steady
 746                         t = random() * 6 + 4;
 747                         self.owner.weapon_morph1time   = time + t * 0.2;
 748                         self.owner.weapon_morph1angles = randomvec() * 1;
 749                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 750                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 751
 752                         self.owner.weapon_morph2time   = time + t * 0.5;
 753                         self.owner.weapon_morph2angles = randomvec() * 1;
 754                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 755                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 756
 757                         self.owner.weapon_morph3time   = time + t * 0.7;
 758                         self.owner.weapon_morph3angles = randomvec() * 1;
 759                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 760                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 761                 }
 762
 763                 self.owner.weapon_morph4time   = time + t;
 764                 self.owner.weapon_morph4angles = '0 0 0';
 765                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 766                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 767
 768         }
 769 };
 770
 771 void CL_ExteriorWeaponentity_Think()
 772 {
 773         float tag_found;
 774         vector ang;
 775         self.nextthink = time;
 776         if (self.owner.exteriorweaponentity != self)
 777         {
 778                 remove(self);
 779                 return;
 780         }
 781         if (self.owner.deadflag != DEAD_NO)
 782         {
 783                 self.model = "";
 784                 return;
 785         }
 786         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 787         {
 788                 self.cnt = self.owner.weapon;
 789                 self.dmg = self.owner.modelindex;
 790                 self.deadflag = self.owner.deadflag;
 791                 if (self.owner.weaponname != "")
 792                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 793                 else
 794                         self.model = "";
 795
 796                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 797                 {
 798                         self.tag_index = tag_found;
 799                         self.tag_entity = self.owner;
 800                 }
 801                 else
 802                         setattachment(self, self.owner, "bip01 r hand");
 803
 804                 // if that didn't find a tag, hide the exterior weapon model
 805                 if (!self.tag_index)
 806                         self.model = "";
 807         }
 808         self.effects = self.owner.effects;
 809         if(sv_pitch_min == sv_pitch_max)
 810                 self.effects |= EF_LOWPRECISION;
 811         else
 812                 self.effects &~= EF_LOWPRECISION;
 813         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 814         if(self.owner.alpha == default_player_alpha)
 815                 self.alpha = default_weapon_alpha;
 816         else if(self.owner.alpha != 0)
 817                 self.alpha = self.owner.alpha;
 818         else
 819                 self.alpha = 1;
 820
 821         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 822         ang_y = 0;
 823         ang_z = 0;
 824
 825         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 826         {
 827                 ang_y = self.owner.v_angle_y;
 828                 makevectors(ang);
 829                 var vector v = v_forward;
 830                 var float t = self.tag_entity.frame1time;
 831                 var float f = self.tag_entity.frame;
 832                 self.tag_entity.frame1time = time;
 833                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
 834                 gettaginfo(self.tag_entity, self.tag_index);
 835                 self.tag_entity.frame1time = t;
 836                 self.tag_entity.frame = f;
 837                 // untransform v according to this coordinate space
 838                 vector w;
 839                 w_x = v_forward * v;
 840                 w_y = -v_right * v;
 841                 w_z = v_up * v;
 842                 self.angles = vectoangles(w);
 843         }
 844         else
 845         {
 846                 ang_x = -/* don't ask */ang_x;
 847                 self.angles = ang;
 848         }
 849
 850         self.colormap = self.owner.colormap;
 851 };
 852
 853 // spawning weaponentity for client
 854 void CL_SpawnWeaponentity()
 855 {
 856         self.weaponentity = spawn();
 857         self.weaponentity.classname = "weaponentity";
 858         self.weaponentity.solid = SOLID_NOT;
 859         self.weaponentity.owner = self;
 860         setmodel(self.weaponentity, ""); // precision set when changed
 861         setorigin(self.weaponentity, '0 0 0');
 862         self.weaponentity.angles = '0 0 0';
 863         self.weaponentity.viewmodelforclient = self;
 864         self.weaponentity.flags = 0;
 865         self.weaponentity.think = CL_Weaponentity_Think;
 866         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 867         self.weaponentity.nextthink = time;
 868
 869         self.exteriorweaponentity = spawn();
 870         self.exteriorweaponentity.classname = "exteriorweaponentity";
 871         self.exteriorweaponentity.solid = SOLID_NOT;
 872         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 873         self.exteriorweaponentity.owner = self;
 874         setorigin(self.exteriorweaponentity, '0 0 0');
 875         self.exteriorweaponentity.angles = '0 0 0';
 876         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 877         self.exteriorweaponentity.nextthink = time;
 878 };
 879
 880 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 881 {
 882         msg_entity = e;
 883         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 884         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 885         WriteByte(MSG_ONE, wpn);
 886         WriteString(MSG_ONE, wpnname);
 887         WriteByte(MSG_ONE, type);
 888 }
 889
 890 .float hasweapon_complain_spam;
 891
 892 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 893 {
 894         local float weaponbit, f;
 895         local entity oldself;
 896
 897         if(time < self.hasweapon_complain_spam)
 898                 complain = 0;
 899         if(complain)
 900                 self.hasweapon_complain_spam = time + 0.2;
 901
 902         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 903         {
 904                 if (complain)
 905                         sprint(self, "Invalid weapon\n");
 906                 return FALSE;
 907         }
 908         weaponbit = W_WeaponBit(wpn);
 909         if (cl.weapons & weaponbit)
 910         {
 911                 if (andammo)
 912                 {
 913                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 914                         {
 915                                 f = 1;
 916                         }
 917                         else
 918                         {
 919                                 oldself = self;
 920                                 self = cl;
 921                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 922                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 923
 924                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 925                                 local entity mine;
 926                                 if(wpn == WEP_MINE_LAYER)
 927                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 928                                         f = 1;
 929
 930                                 self = oldself;
 931                         }
 932                         if (!f)
 933                         {
 934                                 if (complain)
 935                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 936                                 {
 937                                         play2(cl, "weapons/unavailable.wav");
 938                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 939                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 940                                 }
 941                                 return FALSE;
 942                         }
 943                 }
 944                 return TRUE;
 945         }
 946         if (complain)
 947         {
 948                 // DRESK - 3/16/07
 949                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 950                 if(weaponsInMap & weaponbit)
 951                 {
 952                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 953                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 954
 955                         if(autocvar_g_showweaponspawns)
 956                         {
 957                                 entity e;
 958                                 string s;
 959
 960                                 e = get_weaponinfo(wpn);
 961                                 s = e.model2;
 962
 963                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 964                                 {
 965                                         if(e.classname == "droppedweapon")
 966                                                 continue;
 967                                         if not(e.flags & FL_ITEM)
 968                                                 continue;
 969                                         WaypointSprite_Spawn(
 970                                                 s,
 971                                                 1, 0,
 972                                                 world, e.origin,
 973                                                 self, 0,
 974                                                 world, enemy,
 975                                                 0
 976                                         );
 977                                 }
 978                         }
 979                 }
 980                 else
 981                 {
 982                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 983                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 984                 }
 985
 986                 play2(cl, "weapons/unavailable.wav");
 987         }
 988         return FALSE;
 989 };
 990
 991 // Weapon subs
 992 void w_clear()
 993 {
 994         if (self.weapon != -1)
 995                 self.weapon = 0;
 996         if (self.weaponentity)
 997         {
 998                 self.weaponentity.state = WS_CLEAR;
 999                 self.weaponentity.effects = 0;
1000         }
1001 };
1002
1003 void w_ready()
1004 {
1005         if (self.weaponentity)
1006                 self.weaponentity.state = WS_READY;
1007         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1008 };
1009
1010 // Setup weapon for client (after this raise frame will be launched)
1011 void weapon_setup(float windex)
1012 {
1013         entity e;
1014         qcweaponanimation = autocvar_sv_qcweaponanimation;
1015         e = get_weaponinfo(windex);
1016         self.items &~= IT_AMMO;
1017         self.items = self.items | e.items;
1018
1019         // the two weapon entities will notice this has changed and update their models
1020         self.weapon = windex;
1021         self.weaponname = e.mdl;
1022         self.bulletcounter = 0;
1023 };
1024
1025 // perform weapon to attack (weaponstate and attack_finished check is here)
1026 void W_SwitchToOtherWeapon(entity pl)
1027 {
1028         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1029         float w, ww;
1030         w = W_WeaponBit(pl.weapon);
1031         pl.weapons &~= w;
1032         ww = w_getbestweapon(pl);
1033         pl.weapons |= w;
1034         if(ww)
1035                 W_SwitchWeapon_Force(pl, ww);
1036 }
1037 .float prevdryfire;
1038 float weapon_prepareattack_checkammo(float secondary)
1039 {
1040         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1041         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1042         {
1043                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1044                 local entity mine;
1045                 if(self.weapon == WEP_MINE_LAYER)
1046                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1047                         return FALSE;
1048
1049                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1050                 {
1051                         sound (self, CHAN_AUTO, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1052                         self.prevdryfire = time;
1053                 }
1054
1055                 W_SwitchToOtherWeapon(self);
1056                 return FALSE;
1057         }
1058         return TRUE;
1059 }
1060 .float race_penalty;
1061 float weapon_prepareattack_check(float secondary, float attacktime)
1062 {
1063         if(!weapon_prepareattack_checkammo(secondary))
1064                 return FALSE;
1065
1066         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1067         //if all players readied up and the countdown is running
1068         if(time < game_starttime || time < self.race_penalty) {
1069                 return FALSE;
1070         }
1071
1072         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1073                 return FALSE;
1074
1075         // do not even think about shooting if switching
1076         if(self.switchweapon != self.weapon)
1077                 return FALSE;
1078
1079         if(attacktime >= 0)
1080         {
1081                 // don't fire if previous attack is not finished
1082                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1083                         return FALSE;
1084                 // don't fire while changing weapon
1085                 if (self.weaponentity.state != WS_READY)
1086                         return FALSE;
1087         }
1088
1089         return TRUE;
1090 }
1091 float weapon_prepareattack_do(float secondary, float attacktime)
1092 {
1093         self.weaponentity.state = WS_INUSE;
1094
1095         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1096
1097         // if the weapon hasn't been firing continuously, reset the timer
1098         if(attacktime >= 0)
1099         {
1100                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1101                 {
1102                         ATTACK_FINISHED(self) = time;
1103                         //dprint("resetting attack finished to ", ftos(time), "\n");
1104                 }
1105                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1106         }
1107         self.bulletcounter += 1;
1108         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1109         return TRUE;
1110 }
1111 float weapon_prepareattack(float secondary, float attacktime)
1112 {
1113         if(weapon_prepareattack_check(secondary, attacktime))
1114         {
1115                 weapon_prepareattack_do(secondary, attacktime);
1116                 return TRUE;
1117         }
1118         else
1119                 return FALSE;
1120 }
1121
1122 void weapon_thinkf(float fr, float t, void() func)
1123 {
1124         vector a;
1125         vector of, or, ou;
1126         float restartanim;
1127
1128         if(fr == WFRAME_DONTCHANGE)
1129         {
1130                 fr = self.weaponentity.wframe;
1131                 restartanim = FALSE;
1132         }
1133         else if (fr == WFRAME_IDLE)
1134                 restartanim = FALSE;
1135         else
1136                 restartanim = TRUE;
1137
1138         of = v_forward;
1139         or = v_right;
1140         ou = v_up;
1141
1142         if (self.weaponentity)
1143         {
1144                 self.weaponentity.wframe = fr;
1145                 if (qcweaponanimation)
1146                 {
1147                         if (fr != WFRAME_IDLE)
1148                         {
1149                                 self.weapon_morph0time = time;
1150                                 self.weapon_morph0angles = self.weaponentity.angles;
1151                                 self.weapon_morph0origin = self.weaponentity.origin;
1152
1153                                 self.weapon_morph1angles = '0 0 0';
1154                                 self.weapon_morph1time = time + t;
1155                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1156                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1157
1158                                 self.weapon_morph2angles = '0 0 0';
1159                                 self.weapon_morph2time = time + t;
1160                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1161                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1162
1163                                 self.weapon_morph3angles = '0 0 0';
1164                                 self.weapon_morph3time = time + t;
1165                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1166                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1167
1168                                 self.weapon_morph4angles = '0 0 0';
1169                                 self.weapon_morph4time = time + t;
1170                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1171                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1172
1173                                 if (fr == WFRAME_FIRE1)
1174                                 {
1175                                         self.weapon_morph1angles = '5 0 0';
1176                                         self.weapon_morph1time = time + t * 0.1;
1177                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1178                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1179                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1180                                 }
1181                                 else if (fr == WFRAME_FIRE2)
1182                                 {
1183                                         self.weapon_morph1angles = '10 0 0';
1184                                         self.weapon_morph1time = time + t * 0.1;
1185                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1186                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1187                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1188                                 }
1189                                 else if (fr == WFRAME_RELOAD)
1190                                 {
1191                                         self.weapon_morph1time = time + t * 0.05;
1192                                         self.weapon_morph1angles = '-10 40 0';
1193                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1194                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1195
1196                                         self.weapon_morph2time = time + t * 0.15;
1197                                         self.weapon_morph2angles = '-10 40 5';
1198                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1199                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1200
1201                                         self.weapon_morph3time = time + t * 0.25;
1202                                         self.weapon_morph3angles = '-10 40 0';
1203                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1204                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1205                                 }
1206                         }
1207                 }
1208                 else
1209                 {
1210                         if (fr == WFRAME_IDLE)
1211                                 a = self.weaponentity.anim_idle;
1212                         else if (fr == WFRAME_FIRE1)
1213                                 a = self.weaponentity.anim_fire1;
1214                         else if (fr == WFRAME_FIRE2)
1215                                 a = self.weaponentity.anim_fire2;
1216                         else if (fr == WFRAME_RELOAD)
1217                                 a = self.weaponentity.anim_reload;
1218                         a_z *= g_weaponratefactor;
1219                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1220                 }
1221         }
1222
1223         v_forward = of;
1224         v_right = or;
1225         v_up = ou;
1226
1227         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1228         {
1229                 backtrace("Tried to override initial weapon think function - should this really happen?");
1230         }
1231
1232         t *= W_WeaponRateFactor();
1233
1234         // VorteX: haste can be added here
1235         if (self.weapon_think == w_ready)
1236         {
1237                 self.weapon_nextthink = time;
1238                 //dprint("started firing at ", ftos(time), "\n");
1239         }
1240         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1241         {
1242                 self.weapon_nextthink = time;
1243                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1244         }
1245         self.weapon_nextthink = self.weapon_nextthink + t;
1246         self.weapon_think = func;
1247         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1248
1249         if (restartanim)
1250         if (t)
1251         if (!self.crouch) // shoot anim stands up, this looks bad
1252         {
1253                 local vector anim;
1254                 anim = self.anim_shoot;
1255                 anim_z = anim_y / (t + sys_frametime);
1256                 setanim(self, anim, FALSE, TRUE, TRUE);
1257         }
1258 };
1259
1260 void weapon_boblayer1(float spd, vector org)
1261 {
1262         // VorteX: haste can be added here
1263 };
1264
1265 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1266 {
1267         vector mdirection;
1268         float mspeed;
1269         float outspeed;
1270         float nstyle;
1271         vector outvelocity;
1272
1273         mvelocity = mvelocity * g_weaponspeedfactor;
1274
1275         mdirection = normalize(mvelocity);
1276         mspeed = vlen(mvelocity);
1277
1278         nstyle = autocvar_g_projectiles_newton_style;
1279         if(nstyle == 0 || forceAbsolute)
1280         {
1281                 // absolute velocity
1282                 outvelocity = mvelocity;
1283         }
1284         else if(nstyle == 1)
1285         {
1286                 // true Newtonian projectiles
1287                 outvelocity = pvelocity + mvelocity;
1288         }
1289         else if(nstyle == 2)
1290         {
1291                 // true Newtonian projectiles with automatic aim adjustment
1292                 //
1293                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1294                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1295                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1296                 // PLUS SIGN!
1297                 // not defined?
1298                 // then...
1299                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1300                 // velocity without mdirection component > mspeed
1301                 // fire at smallest possible mspeed that works?
1302                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1303
1304                 vector solution;
1305                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1306                 if(solution_z)
1307                         outspeed = solution_y; // the larger one
1308                 else
1309                 {
1310                         //outspeed = 0; // slowest possible shot
1311                         outspeed = solution_x; // the real part (that is, the average!)
1312                         //dprint("impossible shot, adjusting\n");
1313                 }
1314
1315                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1316                 outvelocity = mdirection * outspeed;
1317         }
1318         else if(nstyle == 3)
1319         {
1320                 // pseudo-Newtonian:
1321                 outspeed = mspeed + mdirection * pvelocity;
1322                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1323                 outvelocity = mdirection * outspeed;
1324         }
1325         else if(nstyle == 4)
1326         {
1327                 // tZorkian:
1328                 outspeed = mspeed + vlen(pvelocity);
1329                 outvelocity = mdirection * outspeed;
1330         }
1331         else
1332                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1333
1334         return outvelocity;
1335 }
1336
1337 void W_AttachToShotorg(entity flash, vector offset)
1338 {
1339         entity xflash;
1340         flash.owner = self;
1341         flash.angles_z = random() * 360;
1342         if(qcweaponanimation)
1343         {
1344                 setorigin(flash, w_shotorg + w_shotdir * 50);
1345                 flash.angles = vectoangles(w_shotdir);
1346                 flash.angles_z = random() * 360;
1347         }
1348         else
1349         {
1350                 if(gettagindex(self.weaponentity, "shot"))
1351                         setattachment(flash, self.weaponentity, "shot");
1352                 else
1353                         setattachment(flash, self.weaponentity, "tag_shot");
1354                 setorigin(flash, offset);
1355
1356                 xflash = spawn();
1357                 copyentity(flash, xflash);
1358
1359                 flash.viewmodelforclient = self;
1360
1361                 if(self.weaponentity.oldorigin_x > 0)
1362                 {
1363                         setattachment(xflash, self.exteriorweaponentity, "");
1364                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1365                 }
1366                 else
1367                 {
1368                         if(gettagindex(self.exteriorweaponentity, "shot"))
1369                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1370                         else
1371                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1372                         setorigin(xflash, offset);
1373                 }
1374         }
1375 }
1376
1377 vector cliptoplane(vector v, vector p)
1378 {
1379         return v - (v * p) * p;
1380 }
1381
1382 vector solve_cubic_pq(float p, float q)
1383 {
1384         float D, u, v, a;
1385         D = q*q/4.0 + p*p*p/27.0;
1386         if(D < 0)
1387         {
1388                 // irreducibilis
1389                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1390                 u = sqrt(-4.0/3.0 * p);
1391                 // a in range 0..pi/3
1392                 // cos(a)
1393                 // cos(a + 2pi/3)
1394                 // cos(a + 4pi/3)
1395                 return
1396                         u *
1397                         (
1398                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1399                                 +
1400                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1401                                 +
1402                                 '0 0 1' * cos(a)
1403                         );
1404         }
1405         else if(D == 0)
1406         {
1407                 // simple
1408                 if(p == 0)
1409                         return '0 0 0';
1410                 u = 3*q/p;
1411                 v = -u/2;
1412                 if(u >= v)
1413                         return '1 1 0' * v + '0 0 1' * u;
1414                 else
1415                         return '0 1 1' * v + '1 0 0' * u;
1416         }
1417         else
1418         {
1419                 // cardano
1420                 u = cbrt(-q/2.0 + sqrt(D));
1421                 v = cbrt(-q/2.0 - sqrt(D));
1422                 return '1 1 1' * (u + v);
1423         }
1424 }
1425 vector solve_cubic_abcd(float a, float b, float c, float d)
1426 {
1427         // y = 3*a*x + b
1428         // x = (y - b) / 3a
1429         float p, q;
1430         vector v;
1431         p = (9*a*c - 3*b*b);
1432         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1433         v = solve_cubic_pq(p, q);
1434         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1435         if(a < 0)
1436                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1437         return v;
1438 }
1439
1440 vector findperpendicular(vector v)
1441 {
1442         vector p;
1443         p_x = v_z;
1444         p_y = -v_x;
1445         p_z = v_y;
1446         return normalize(cliptoplane(p, v));
1447 }
1448
1449 vector W_CalculateProjectileSpread(vector forward, float spread)
1450 {
1451         float sigma;
1452         vector v1, v2;
1453         float dx, dy, r;
1454         float sstyle;
1455         spread *= g_weaponspreadfactor;
1456         if(spread <= 0)
1457                 return forward;
1458         sstyle = autocvar_g_projectiles_spread_style;
1459
1460         if(sstyle == 0)
1461         {
1462                 // this is the baseline for the spread value!
1463                 // standard deviation: sqrt(2/5)
1464                 // density function: sqrt(1-r^2)
1465                 return forward + randomvec() * spread;
1466         }
1467         else if(sstyle == 1)
1468         {
1469                 // same thing, basically
1470                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1471         }
1472         else if(sstyle == 2)
1473         {
1474                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1475                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1476                 v1 = findperpendicular(forward);
1477                 v2 = cross(forward, v1);
1478                 // random point on unit circle
1479                 dx = random() * 2 * M_PI;
1480                 dy = sin(dx);
1481                 dx = cos(dx);
1482                 // radius in our dist function
1483                 r = random();
1484                 r = sqrt(r);
1485                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1486         }
1487         else if(sstyle == 3) // gauss 3d
1488         {
1489                 sigma = spread * 0.44721359549996; // match baseline stddev
1490                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1491                 v1 = forward;
1492                 v1_x += gsl_ran_gaussian(sigma);
1493                 v1_y += gsl_ran_gaussian(sigma);
1494                 v1_z += gsl_ran_gaussian(sigma);
1495                 return v1;
1496         }
1497         else if(sstyle == 4) // gauss 2d
1498         {
1499                 sigma = spread * 0.44721359549996; // match baseline stddev
1500                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1501                 v1_x = gsl_ran_gaussian(sigma);
1502                 v1_y = gsl_ran_gaussian(sigma);
1503                 v1_z = gsl_ran_gaussian(sigma);
1504                 return normalize(forward + cliptoplane(v1, forward));
1505         }
1506         else if(sstyle == 5) // 1-r
1507         {
1508                 sigma = spread * 1.154700538379252; // match baseline stddev
1509                 v1 = findperpendicular(forward);
1510                 v2 = cross(forward, v1);
1511                 // random point on unit circle
1512                 dx = random() * 2 * M_PI;
1513                 dy = sin(dx);
1514                 dx = cos(dx);
1515                 // radius in our dist function
1516                 r = random();
1517                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1518                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1519         }
1520         else if(sstyle == 6) // 1-r^2
1521         {
1522                 sigma = spread * 1.095445115010332; // match baseline stddev
1523                 v1 = findperpendicular(forward);
1524                 v2 = cross(forward, v1);
1525                 // random point on unit circle
1526                 dx = random() * 2 * M_PI;
1527                 dy = sin(dx);
1528                 dx = cos(dx);
1529                 // radius in our dist function
1530                 r = random();
1531                 r = sqrt(1 - r);
1532                 r = sqrt(1 - r);
1533                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1534         }
1535         else if(sstyle == 7) // (1-r) (2-r)
1536         {
1537                 sigma = spread * 1.224744871391589; // match baseline stddev
1538                 v1 = findperpendicular(forward);
1539                 v2 = cross(forward, v1);
1540                 // random point on unit circle
1541                 dx = random() * 2 * M_PI;
1542                 dy = sin(dx);
1543                 dx = cos(dx);
1544                 // radius in our dist function
1545                 r = random();
1546                 r = 1 - sqrt(r);
1547                 r = 1 - sqrt(r);
1548                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1549         }
1550         else
1551                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1552         return '0 0 0';
1553         /*
1554          * how to derive falloff functions:
1555          * rho(r) := (2-r) * (1-r);
1556          * a : 0;
1557          * b : 1;
1558          * rhor(r) := r * rho(r);
1559          * cr(t) := integrate(rhor(r), r, a, t);
1560          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1561          * variance : scr(b) / cr(b);
1562          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1563          * sqrt(0.4 / variance), numer;
1564          */
1565 }
1566
1567 #if 0
1568 float mspercallsum;
1569 float mspercallsstyle;
1570 float mspercallcount;
1571 #endif
1572 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1573 {
1574         if(missile.owner == world)
1575                 error("Unowned missile");
1576
1577         dir = dir + upDir * (pUpSpeed / pSpeed);
1578         dir_z += pZSpeed / pSpeed;
1579         pSpeed *= vlen(dir);
1580         dir = normalize(dir);
1581
1582 #if 0
1583         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1584         {
1585                 mspercallsum = mspercallcount = 0;
1586                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1587         }
1588         mspercallsum -= gettime(GETTIME_HIRES);
1589 #endif
1590         dir = W_CalculateProjectileSpread(dir, spread);
1591 #if 0
1592         mspercallsum += gettime(GETTIME_HIRES);
1593         mspercallcount += 1;
1594         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1595 #endif
1596
1597         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1598 }
1599
1600 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1601 {
1602         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1603 }
1604
1605 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1606 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)