qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         weapon_rate = t;
  18         MUTATOR_CALLHOOK(WeaponRateFactor);
  19         t = weapon_rate;
  20
  21         return t;
  22 }
  23
  24 void W_SwitchWeapon_Force(entity e, float w)
  25 {
  26         e.cnt = e.switchweapon;
  27         e.switchweapon = w;
  28         e.selectweapon = w;
  29 }
  30
  31 .float antilag_debug;
  32
  33 // VorteX: static frame globals
  34 const float WFRAME_DONTCHANGE = -1;
  35 const float WFRAME_FIRE1 = 0;
  36 const float WFRAME_FIRE2 = 1;
  37 const float WFRAME_IDLE = 2;
  38 const float WFRAME_RELOAD = 3;
  39 .float wframe;
  40
  41 void(float fr, float t, void() func) weapon_thinkf;
  42
  43 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  44 {
  45         vector ret;
  46         ret_x = screenright * v;
  47         ret_y = screenup * v;
  48         ret_z = screenforward * v;
  49         return ret;
  50 }
  51
  52 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  53 {
  54         float i, j, k;
  55         vector mi, ma, thisv, myv, ret;
  56
  57         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  58
  59         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  60
  61         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  62         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  63         {
  64                 thisv = targ.origin;
  65                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  66                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  67                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  68                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  69                 if(i || j || k)
  70                 {
  71                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  72                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  73                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  74                 }
  75                 else
  76                 {
  77                         // first run
  78                         mi = ma = thisv;
  79                 }
  80         }
  81
  82         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  83         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  84         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  85         ret_z = thisv_z - myv_z;
  86         return ret;
  87 }
  88
  89 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  90 {
  91         vector hitplot;
  92         vector org;
  93         float lag;
  94
  95         if(player.hitplotfh >= 0)
  96         {
  97                 lag = ANTILAG_LATENCY(player);
  98                 if(lag < 0.001)
  99                         lag = 0;
 100                 if (!IS_REAL_CLIENT(player))
 101                         lag = 0; // only antilag for clients
 102
 103                 org = player.origin + player.view_ofs;
 104                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 105                 if(IS_CLIENT(trace_ent) || (trace_ent.flags & FL_MONSTER))
 106                 {
 107                         antilag_takeback(trace_ent, time - lag);
 108                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 109                         antilag_restore(trace_ent);
 110                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 111                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 112                 }
 113         }
 114 }
 115
 116 vector w_shotorg;
 117 vector w_shotdir;
 118 vector w_shotend;
 119
 120 .float prevstrengthsound;
 121 .float prevstrengthsoundattempt;
 122 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 123 {
 124         if((player.items & IT_STRENGTH)
 125                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 126                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 127                 {
 128                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTEN_NORM);
 129                         player.prevstrengthsound = time;
 130                 }
 131                 player.prevstrengthsoundattempt = time;
 132 }
 133
 134 // this function calculates w_shotorg and w_shotdir based on the weapon model
 135 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 136 // make sure you call makevectors first (FIXME?)
 137 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 138 {
 139         float nudge = 1; // added to traceline target and subtracted from result
 140         float oldsolid;
 141         vector vecs, dv;
 142         oldsolid = ent.dphitcontentsmask;
 143         if(ent.weapon == WEP_RIFLE)
 144                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 145         else
 146                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 147         if(antilag)
 148                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 149                 // passing world, because we do NOT want it to touch dphitcontentsmask
 150         else
 151                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 152         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 153
 154         vector vf, vr, vu;
 155         vf = v_forward;
 156         vr = v_right;
 157         vu = v_up;
 158         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 159         v_forward = vf;
 160         v_right = vr;
 161         v_up = vu;
 162
 163         // un-adjust trueaim if shotend is too close
 164         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 165                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 166
 167         // track max damage
 168         if(accuracy_canbegooddamage(ent))
 169                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 170
 171         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 172
 173         if(ent.weaponentity.movedir_x > 0)
 174                 vecs = ent.weaponentity.movedir;
 175         else
 176                 vecs = '0 0 0';
 177
 178         dv = v_right * -vecs_y + v_up * vecs_z;
 179         w_shotorg = ent.origin + ent.view_ofs + dv;
 180
 181         // now move the shotorg forward as much as requested if possible
 182         if(antilag)
 183         {
 184                 if(ent.antilag_debug)
 185                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 186                 else
 187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 188         }
 189         else
 190                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 191         w_shotorg = trace_endpos - v_forward * nudge;
 192         // calculate the shotdir from the chosen shotorg
 193         w_shotdir = normalize(w_shotend - w_shotorg);
 194
 195         if (antilag)
 196         if (!ent.cvar_cl_noantilag)
 197         {
 198                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 199                 {
 200                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 201                         if (!trace_ent.takedamage)
 202                         {
 203                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 204                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 205                                 {
 206                                         entity e;
 207                                         e = trace_ent;
 208                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 209                                         if(trace_ent == e)
 210                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 211                                 }
 212                         }
 213                 }
 214                 else if(autocvar_g_antilag == 3) // client side hitscan
 215                 {
 216                         // this part MUST use prydon cursor
 217                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 218                         if (ent.cursor_trace_ent != ent)         // just to make sure
 219                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 220                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 221                         {
 222                                 // verify that the shot would miss without antilag
 223                                 // (avoids an issue where guns would always shoot at their origin)
 224                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 225                                 if (!trace_ent.takedamage)
 226                                 {
 227                                         // verify that the shot would hit if altered
 228                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 229                                         if (trace_ent == ent.cursor_trace_ent)
 230                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 231                                         else
 232                                                 print("antilag fail\n");
 233                                 }
 234                         }
 235                 }
 236         }
 237
 238         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 239
 240         if (!autocvar_g_norecoil)
 241                 ent.punchangle_x = recoil * -1;
 242
 243         if (snd != "")
 244         {
 245                 sound (ent, chan, snd, VOL_BASE, ATTEN_NORM);
 246                 W_PlayStrengthSound(ent);
 247         }
 248
 249         // nudge w_shotend so a trace to w_shotend hits
 250         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 251 }
 252
 253 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 254 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 255 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 256 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 257 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 258
 259 float CL_Weaponentity_CustomizeEntityForClient()
 260 {
 261         self.viewmodelforclient = self.owner;
 262         if(IS_SPEC(other))
 263                 if(other.enemy == self.owner)
 264                         self.viewmodelforclient = other;
 265         return TRUE;
 266 }
 267
 268 /*
 269  * supported formats:
 270  *
 271  * 1. simple animated model, muzzle flash handling on h_ model:
 272  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 273  *      tags:
 274  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 275  *        shell = casings ejection point (must be on the right hand side of the gun)
 276  *        weapon = attachment for v_tuba.md3
 277  *    v_tuba.md3 - first and third person model
 278  *    g_tuba.md3 - pickup model
 279  *
 280  * 2. simple animated model, muzzle flash handling on v_ model:
 281  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 282  *      tags:
 283  *        weapon = attachment for v_tuba.md3
 284  *    v_tuba.md3 - first and third person model
 285  *      tags:
 286  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 287  *        shell = casings ejection point (must be on the right hand side of the gun)
 288  *    g_tuba.md3 - pickup model
 289  *
 290  * 3. fully animated model, muzzle flash handling on h_ model:
 291  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 292  *      tags:
 293  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 294  *        shell = casings ejection point (must be on the right hand side of the gun)
 295  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 296  *    v_tuba.md3 - third person model
 297  *    g_tuba.md3 - pickup model
 298  *
 299  * 4. fully animated model, muzzle flash handling on v_ model:
 300  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 301  *      tags:
 302  *        shot = muzzle end (shot origin)
 303  *        shell = casings ejection point (must be on the right hand side of the gun)
 304  *    v_tuba.md3 - third person model
 305  *      tags:
 306  *        shot = muzzle end (for muzzle flashes)
 307  *    g_tuba.md3 - pickup model
 308  */
 309
 310 // writes:
 311 //   self.origin, self.angles
 312 //   self.weaponentity
 313 //   self.movedir, self.view_ofs
 314 //   attachment stuff
 315 //   anim stuff
 316 // to free:
 317 //   call again with ""
 318 //   remove the ent
 319 void CL_WeaponEntity_SetModel(string name)
 320 {
 321         float v_shot_idx;
 322         if (name != "")
 323         {
 324                 // if there is a child entity, hide it until we're sure we use it
 325                 if (self.weaponentity)
 326                         self.weaponentity.model = "";
 327                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 328                 v_shot_idx = gettagindex(self, "shot"); // used later
 329                 if(!v_shot_idx)
 330                         v_shot_idx = gettagindex(self, "tag_shot");
 331
 332                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 333                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 334                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
 335                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
 336                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
 337                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
 338
 339                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 340                 // if we don't, this is a "real" animated model
 341                 if(gettagindex(self, "weapon"))
 342                 {
 343                         if (!self.weaponentity)
 344                                 self.weaponentity = spawn();
 345                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 346                         setattachment(self.weaponentity, self, "weapon");
 347                 }
 348                 else if(gettagindex(self, "tag_weapon"))
 349                 {
 350                         if (!self.weaponentity)
 351                                 self.weaponentity = spawn();
 352                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 353                         setattachment(self.weaponentity, self, "tag_weapon");
 354                 }
 355                 else
 356                 {
 357                         if(self.weaponentity)
 358                                 remove(self.weaponentity);
 359                         self.weaponentity = world;
 360                 }
 361
 362                 setorigin(self,'0 0 0');
 363                 self.angles = '0 0 0';
 364                 self.frame = 0;
 365                 self.viewmodelforclient = world;
 366
 367                 float idx;
 368
 369                 if(v_shot_idx) // v_ model attached to invisible h_ model
 370                 {
 371                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 372                 }
 373                 else
 374                 {
 375                         idx = gettagindex(self, "shot");
 376                         if(!idx)
 377                                 idx = gettagindex(self, "tag_shot");
 378                         if(idx)
 379                                 self.movedir = gettaginfo(self, idx);
 380                         else
 381                         {
 382                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 383                                 self.movedir = '0 0 0';
 384                         }
 385                 }
 386
 387                 if(self.weaponentity) // v_ model attached to invisible h_ model
 388                 {
 389                         idx = gettagindex(self.weaponentity, "shell");
 390                         if(!idx)
 391                                 idx = gettagindex(self.weaponentity, "tag_shell");
 392                         if(idx)
 393                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 394                 }
 395                 else
 396                         idx = 0;
 397                 if(!idx)
 398                 {
 399                         idx = gettagindex(self, "shell");
 400                         if(!idx)
 401                                 idx = gettagindex(self, "tag_shell");
 402                         if(idx)
 403                                 self.spawnorigin = gettaginfo(self, idx);
 404                         else
 405                         {
 406                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 407                                 self.spawnorigin = self.movedir;
 408                         }
 409                 }
 410
 411                 if(v_shot_idx)
 412                 {
 413                         self.oldorigin = '0 0 0'; // use regular attachment
 414                 }
 415                 else
 416                 {
 417                         if(self.weaponentity)
 418                         {
 419                                 idx = gettagindex(self, "weapon");
 420                                 if(!idx)
 421                                         idx = gettagindex(self, "tag_weapon");
 422                         }
 423                         else
 424                         {
 425                                 idx = gettagindex(self, "handle");
 426                                 if(!idx)
 427                                         idx = gettagindex(self, "tag_handle");
 428                         }
 429                         if(idx)
 430                         {
 431                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 432                         }
 433                         else
 434                         {
 435                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 436                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 437                         }
 438                 }
 439
 440                 self.viewmodelforclient = self.owner;
 441         }
 442         else
 443         {
 444                 self.model = "";
 445                 if(self.weaponentity)
 446                         remove(self.weaponentity);
 447                 self.weaponentity = world;
 448                 self.movedir = '0 0 0';
 449                 self.spawnorigin = '0 0 0';
 450                 self.oldorigin = '0 0 0';
 451                 self.anim_fire1  = '0 1 0.01';
 452                 self.anim_fire2  = '0 1 0.01';
 453                 self.anim_idle   = '0 1 0.01';
 454                 self.anim_reload = '0 1 0.01';
 455         }
 456
 457         self.view_ofs = '0 0 0';
 458
 459         if(self.movedir_x >= 0)
 460         {
 461                 vector v0;
 462                 v0 = self.movedir;
 463                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 464                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 465         }
 466         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 467         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 468
 469         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 470
 471         // check if an instant weapon switch occurred
 472         setorigin(self, self.view_ofs);
 473         // reset animstate now
 474         self.wframe = WFRAME_IDLE;
 475         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 476 }
 477
 478 vector CL_Weapon_GetShotOrg(float wpn)
 479 {
 480         entity wi, oldself;
 481         vector ret;
 482         wi = get_weaponinfo(wpn);
 483         oldself = self;
 484         self = spawn();
 485         CL_WeaponEntity_SetModel(wi.mdl);
 486         ret = self.movedir;
 487         CL_WeaponEntity_SetModel("");
 488         remove(self);
 489         self = oldself;
 490         return ret;
 491 }
 492
 493 void CL_Weaponentity_Think()
 494 {
 495         float tb;
 496         self.nextthink = time;
 497         if (intermission_running)
 498                 self.frame = self.anim_idle_x;
 499         if (self.owner.weaponentity != self)
 500         {
 501                 if (self.weaponentity)
 502                         remove(self.weaponentity);
 503                 remove(self);
 504                 return;
 505         }
 506         if (self.owner.deadflag != DEAD_NO)
 507         {
 508                 self.model = "";
 509                 if (self.weaponentity)
 510                         self.weaponentity.model = "";
 511                 return;
 512         }
 513         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 514         {
 515                 self.weaponname = self.owner.weaponname;
 516                 self.dmg = self.owner.modelindex;
 517                 self.deadflag = self.owner.deadflag;
 518
 519                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 520         }
 521
 522         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 523         self.effects = self.owner.effects & EFMASK_CHEAP;
 524         self.effects &= ~EF_LOWPRECISION;
 525         self.effects &= ~EF_FULLBRIGHT; // can mask team color, so get rid of it
 526         self.effects &= ~EF_TELEPORT_BIT;
 527         self.effects &= ~EF_RESTARTANIM_BIT;
 528         self.effects |= tb;
 529
 530         if(self.owner.alpha == default_player_alpha)
 531                 self.alpha = default_weapon_alpha;
 532         else if(self.owner.alpha != 0)
 533                 self.alpha = self.owner.alpha;
 534         else
 535                 self.alpha = 1;
 536
 537         self.glowmod = self.owner.weaponentity_glowmod;
 538         self.colormap = self.owner.colormap;
 539         if (self.weaponentity)
 540         {
 541                 self.weaponentity.effects = self.effects;
 542                 self.weaponentity.alpha = self.alpha;
 543                 self.weaponentity.colormap = self.colormap;
 544                 self.weaponentity.glowmod = self.glowmod;
 545         }
 546
 547         self.angles = '0 0 0';
 548
 549         float f = (self.owner.weapon_nextthink - time);
 550         if (self.state == WS_RAISE && !intermission_running)
 551         {
 552                 entity newwep = get_weaponinfo(self.owner.switchweapon);
 553                 f = f * g_weaponratefactor / max(f, cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname)));
 554                 //printf("CL_Weaponentity_Think(): cvar: %s, value: %f, nextthink: %f\n", sprintf("g_balance_%s_switchdelay_raise", newwep.netname), cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname)), (self.owner.weapon_nextthink - time));
 555                 self.angles_x = -90 * f * f;
 556         }
 557         else if (self.state == WS_DROP && !intermission_running)
 558         {
 559                 entity oldwep = get_weaponinfo(self.owner.weapon);
 560                 f = 1 - f * g_weaponratefactor / max(f, cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname)));
 561                 //printf("CL_Weaponentity_Think(): cvar: %s, value: %f, nextthink: %f\n", sprintf("g_balance_%s_switchdelay_drop", oldwep.netname), cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname)), (self.owner.weapon_nextthink - time));
 562                 self.angles_x = -90 * f * f;
 563         }
 564         else if (self.state == WS_CLEAR)
 565         {
 566                 f = 1;
 567                 self.angles_x = -90 * f * f;
 568         }
 569 }
 570
 571 void CL_ExteriorWeaponentity_Think()
 572 {
 573         float tag_found;
 574         self.nextthink = time;
 575         if (self.owner.exteriorweaponentity != self)
 576         {
 577                 remove(self);
 578                 return;
 579         }
 580         if (self.owner.deadflag != DEAD_NO)
 581         {
 582                 self.model = "";
 583                 return;
 584         }
 585         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 586         {
 587                 self.weaponname = self.owner.weaponname;
 588                 self.dmg = self.owner.modelindex;
 589                 self.deadflag = self.owner.deadflag;
 590                 if (self.owner.weaponname != "")
 591                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 592                 else
 593                         self.model = "";
 594
 595                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 596                 {
 597                         self.tag_index = tag_found;
 598                         self.tag_entity = self.owner;
 599                 }
 600                 else
 601                         setattachment(self, self.owner, "bip01 r hand");
 602         }
 603         self.effects = self.owner.effects;
 604         self.effects |= EF_LOWPRECISION;
 605         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 606         if(self.owner.alpha == default_player_alpha)
 607                 self.alpha = default_weapon_alpha;
 608         else if(self.owner.alpha != 0)
 609                 self.alpha = self.owner.alpha;
 610         else
 611                 self.alpha = 1;
 612
 613         self.glowmod = self.owner.weaponentity_glowmod;
 614         self.colormap = self.owner.colormap;
 615
 616         CSQCMODEL_AUTOUPDATE();
 617 }
 618
 619 // spawning weaponentity for client
 620 void CL_SpawnWeaponentity()
 621 {
 622         self.weaponentity = spawn();
 623         self.weaponentity.classname = "weaponentity";
 624         self.weaponentity.solid = SOLID_NOT;
 625         self.weaponentity.owner = self;
 626         setmodel(self.weaponentity, ""); // precision set when changed
 627         setorigin(self.weaponentity, '0 0 0');
 628         self.weaponentity.angles = '0 0 0';
 629         self.weaponentity.viewmodelforclient = self;
 630         self.weaponentity.flags = 0;
 631         self.weaponentity.think = CL_Weaponentity_Think;
 632         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 633         self.weaponentity.nextthink = time;
 634
 635         self.exteriorweaponentity = spawn();
 636         self.exteriorweaponentity.classname = "exteriorweaponentity";
 637         self.exteriorweaponentity.solid = SOLID_NOT;
 638         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 639         self.exteriorweaponentity.owner = self;
 640         setorigin(self.exteriorweaponentity, '0 0 0');
 641         self.exteriorweaponentity.angles = '0 0 0';
 642         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 643         self.exteriorweaponentity.nextthink = time;
 644
 645         {
 646                 entity oldself = self;
 647                 self = self.exteriorweaponentity;
 648                 CSQCMODEL_AUTOINIT();
 649                 self = oldself;
 650         }
 651 }
 652
 653 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 654 {
 655         msg_entity = e;
 656         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 657         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 658         WriteByte(MSG_ONE, wpn);
 659         WriteString(MSG_ONE, wpnname);
 660         WriteByte(MSG_ONE, type);
 661 }
 662
 663 .float hasweapon_complain_spam;
 664
 665 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 666 {
 667         float f;
 668         entity oldself;
 669
 670         if(time < self.hasweapon_complain_spam)
 671                 complain = 0;
 672         if(complain)
 673                 self.hasweapon_complain_spam = time + 0.2;
 674
 675         if(wpn == WEP_HOOK && !g_grappling_hook && autocvar_g_nades && !((cl.weapons | weaponsInMap) & WepSet_FromWeapon(wpn)))
 676                 complain = 0;
 677
 678         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 679         {
 680                 if (complain)
 681                         sprint(self, "Invalid weapon\n");
 682                 return FALSE;
 683         }
 684         if (cl.weapons & WepSet_FromWeapon(wpn))
 685         {
 686                 if (andammo)
 687                 {
 688                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 689                         {
 690                                 f = 1;
 691                         }
 692                         else
 693                         {
 694                                 oldself = self;
 695                                 self = cl;
 696                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 697                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 698
 699                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 700                                 entity mine;
 701                                 if(wpn == WEP_MINE_LAYER)
 702                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 703                                         f = 1;
 704
 705                                 self = oldself;
 706                         }
 707                         if (!f)
 708                         {
 709                                 if (complain)
 710                                 if(IS_REAL_CLIENT(cl))
 711                                 {
 712                                         play2(cl, "weapons/unavailable.wav");
 713                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 714                                 }
 715                                 return FALSE;
 716                         }
 717                 }
 718                 return TRUE;
 719         }
 720         if (complain)
 721         {
 722                 // DRESK - 3/16/07
 723                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 724                 if (weaponsInMap & WepSet_FromWeapon(wpn))
 725                 {
 726                         Send_WeaponComplain(cl, wpn, W_Name(wpn), 1);
 727
 728                         if(autocvar_g_showweaponspawns)
 729                         {
 730                                 entity e;
 731                                 string s;
 732
 733                                 e = get_weaponinfo(wpn);
 734                                 s = e.model2;
 735
 736                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 737                                 {
 738                                         if(e.classname == "droppedweapon")
 739                                                 continue;
 740                                         if (!(e.flags & FL_ITEM))
 741                                                 continue;
 742                                         WaypointSprite_Spawn(
 743                                                 s,
 744                                                 1, 0,
 745                                                 world, e.origin,
 746                                                 self, 0,
 747                                                 world, enemy,
 748                                                 0,
 749                                                 RADARICON_NONE, '0 0 0'
 750                                         );
 751                                 }
 752                         }
 753                 }
 754                 else
 755                 {
 756                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 757                 }
 758
 759                 play2(cl, "weapons/unavailable.wav");
 760         }
 761         return FALSE;
 762 }
 763
 764 // Weapon subs
 765 void w_clear()
 766 {
 767         if (self.weapon != -1)
 768         {
 769                 self.weapon = 0;
 770                 self.switchingweapon = 0;
 771         }
 772         if (self.weaponentity)
 773         {
 774                 self.weaponentity.state = WS_CLEAR;
 775                 self.weaponentity.effects = 0;
 776         }
 777 }
 778
 779 void w_ready()
 780 {
 781         if (self.weaponentity)
 782                 self.weaponentity.state = WS_READY;
 783         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 784 }
 785
 786 // Setup weapon for client (after this raise frame will be launched)
 787 void weapon_setup(float windex)
 788 {
 789         entity e;
 790         e = get_weaponinfo(windex);
 791         self.items &= ~IT_AMMO;
 792         self.items = self.items | (e.items & IT_AMMO);
 793
 794         // the two weapon entities will notice this has changed and update their models
 795         self.weapon = windex;
 796         self.switchingweapon = windex; // to make sure
 797         self.weaponname = e.mdl;
 798         self.bulletcounter = 0;
 799 }
 800
 801 // perform weapon to attack (weaponstate and attack_finished check is here)
 802 void W_SwitchToOtherWeapon(entity pl)
 803 {
 804         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 805         float w, ww;
 806         w = pl.weapon;
 807         if(pl.weapons & WepSet_FromWeapon(w))
 808         {
 809                 pl.weapons &= ~WepSet_FromWeapon(w);
 810                 ww = w_getbestweapon(pl);
 811                 pl.weapons |= WepSet_FromWeapon(w);
 812         }
 813         else
 814                 ww = w_getbestweapon(pl);
 815         if(ww)
 816                 W_SwitchWeapon_Force(pl, ww);
 817 }
 818
 819 .float prevdryfire;
 820 .float prevwarntime;
 821 float weapon_prepareattack_checkammo(float secondary)
 822 {
 823         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 824         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 825         {
 826                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 827                 entity mine;
 828                 if(self.weapon == WEP_MINE_LAYER)
 829                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 830                         return FALSE;
 831
 832                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 833                 {
 834                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTEN_NORM);
 835                         self.prevdryfire = time;
 836                 }
 837
 838                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 839                 {
 840                         if(time - self.prevwarntime > 1)
 841                         {
 842                                 Send_Notification(
 843                                         NOTIF_ONE,
 844                                         self,
 845                                         MSG_MULTI,
 846                                         ITEM_WEAPON_PRIMORSEC,
 847                                         self.weapon,
 848                                         secondary,
 849                                         (1 - secondary)
 850                                 );
 851                         }
 852                         self.prevwarntime = time;
 853                 }
 854                 else // this weapon is totally unable to fire, switch to another one
 855                 {
 856                         W_SwitchToOtherWeapon(self);
 857                 }
 858
 859                 return FALSE;
 860         }
 861         return TRUE;
 862 }
 863 .float race_penalty;
 864 float weapon_prepareattack_check(float secondary, float attacktime)
 865 {
 866         if(!weapon_prepareattack_checkammo(secondary))
 867                 return FALSE;
 868
 869         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 870         //if all players readied up and the countdown is running
 871         if(time < game_starttime || time < self.race_penalty) {
 872                 return FALSE;
 873         }
 874
 875         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 876                 return FALSE;
 877
 878         // do not even think about shooting if switching
 879         if(self.switchweapon != self.weapon)
 880                 return FALSE;
 881
 882         if(attacktime >= 0)
 883         {
 884                 // don't fire if previous attack is not finished
 885                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 886                         return FALSE;
 887                 // don't fire while changing weapon
 888                 if (self.weaponentity.state != WS_READY)
 889                         return FALSE;
 890         }
 891
 892         return TRUE;
 893 }
 894 float weapon_prepareattack_do(float secondary, float attacktime)
 895 {
 896         self.weaponentity.state = WS_INUSE;
 897
 898         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 899
 900         // if the weapon hasn't been firing continuously, reset the timer
 901         if(attacktime >= 0)
 902         {
 903                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 904                 {
 905                         ATTACK_FINISHED(self) = time;
 906                         //dprint("resetting attack finished to ", ftos(time), "\n");
 907                 }
 908                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 909         }
 910         self.bulletcounter += 1;
 911         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 912         return TRUE;
 913 }
 914 float weapon_prepareattack(float secondary, float attacktime)
 915 {
 916         if(weapon_prepareattack_check(secondary, attacktime))
 917         {
 918                 weapon_prepareattack_do(secondary, attacktime);
 919                 return TRUE;
 920         }
 921         else
 922                 return FALSE;
 923 }
 924
 925 void weapon_thinkf(float fr, float t, void() func)
 926 {
 927         vector a;
 928         vector of, or, ou;
 929         float restartanim;
 930
 931         if(fr == WFRAME_DONTCHANGE)
 932         {
 933                 fr = self.weaponentity.wframe;
 934                 restartanim = FALSE;
 935         }
 936         else if (fr == WFRAME_IDLE)
 937                 restartanim = FALSE;
 938         else
 939                 restartanim = TRUE;
 940
 941         of = v_forward;
 942         or = v_right;
 943         ou = v_up;
 944
 945         if (self.weaponentity)
 946         {
 947                 self.weaponentity.wframe = fr;
 948                 a = '0 0 0';
 949                 if (fr == WFRAME_IDLE)
 950                         a = self.weaponentity.anim_idle;
 951                 else if (fr == WFRAME_FIRE1)
 952                         a = self.weaponentity.anim_fire1;
 953                 else if (fr == WFRAME_FIRE2)
 954                         a = self.weaponentity.anim_fire2;
 955                 else // if (fr == WFRAME_RELOAD)
 956                         a = self.weaponentity.anim_reload;
 957                 a_z *= g_weaponratefactor;
 958                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 959         }
 960
 961         v_forward = of;
 962         v_right = or;
 963         v_up = ou;
 964
 965         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 966         {
 967                 backtrace("Tried to override initial weapon think function - should this really happen?");
 968         }
 969
 970         t *= W_WeaponRateFactor();
 971
 972         // VorteX: haste can be added here
 973         if (self.weapon_think == w_ready)
 974         {
 975                 self.weapon_nextthink = time;
 976                 //dprint("started firing at ", ftos(time), "\n");
 977         }
 978         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
 979         {
 980                 self.weapon_nextthink = time;
 981                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 982         }
 983         self.weapon_nextthink = self.weapon_nextthink + t;
 984         self.weapon_think = func;
 985         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 986
 987         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 988         {
 989                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
 990                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
 991                 else
 992                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
 993         }
 994         else
 995         {
 996                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
 997                         self.anim_upper_action = 0;
 998         }
 999 }
1000
1001 void weapon_boblayer1(float spd, vector org)
1002 {
1003         // VorteX: haste can be added here
1004 }
1005
1006 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1007 {
1008         vector mdirection;
1009         float mspeed;
1010         vector outvelocity;
1011
1012         mvelocity = mvelocity * g_weaponspeedfactor;
1013
1014         mdirection = normalize(mvelocity);
1015         mspeed = vlen(mvelocity);
1016
1017         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1018
1019         return outvelocity;
1020 }
1021
1022 void W_AttachToShotorg(entity flash, vector offset)
1023 {
1024         entity xflash;
1025         flash.owner = self;
1026         flash.angles_z = random() * 360;
1027
1028         if(gettagindex(self.weaponentity, "shot"))
1029                 setattachment(flash, self.weaponentity, "shot");
1030         else
1031                 setattachment(flash, self.weaponentity, "tag_shot");
1032         setorigin(flash, offset);
1033
1034         xflash = spawn();
1035         copyentity(flash, xflash);
1036
1037         flash.viewmodelforclient = self;
1038
1039         if(self.weaponentity.oldorigin_x > 0)
1040         {
1041                 setattachment(xflash, self.exteriorweaponentity, "");
1042                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1043         }
1044         else
1045         {
1046                 if(gettagindex(self.exteriorweaponentity, "shot"))
1047                         setattachment(xflash, self.exteriorweaponentity, "shot");
1048                 else
1049                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1050                 setorigin(xflash, offset);
1051         }
1052 }
1053
1054 vector cliptoplane(vector v, vector p)
1055 {
1056         return v - (v * p) * p;
1057 }
1058
1059 vector solve_cubic_pq(float p, float q)
1060 {
1061         float D, u, v, a;
1062         D = q*q/4.0 + p*p*p/27.0;
1063         if(D < 0)
1064         {
1065                 // irreducibilis
1066                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1067                 u = sqrt(-4.0/3.0 * p);
1068                 // a in range 0..pi/3
1069                 // cos(a)
1070                 // cos(a + 2pi/3)
1071                 // cos(a + 4pi/3)
1072                 return
1073                         u *
1074                         (
1075                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1076                                 +
1077                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1078                                 +
1079                                 '0 0 1' * cos(a)
1080                         );
1081         }
1082         else if(D == 0)
1083         {
1084                 // simple
1085                 if(p == 0)
1086                         return '0 0 0';
1087                 u = 3*q/p;
1088                 v = -u/2;
1089                 if(u >= v)
1090                         return '1 1 0' * v + '0 0 1' * u;
1091                 else
1092                         return '0 1 1' * v + '1 0 0' * u;
1093         }
1094         else
1095         {
1096                 // cardano
1097                 u = cbrt(-q/2.0 + sqrt(D));
1098                 v = cbrt(-q/2.0 - sqrt(D));
1099                 return '1 1 1' * (u + v);
1100         }
1101 }
1102 vector solve_cubic_abcd(float a, float b, float c, float d)
1103 {
1104         // y = 3*a*x + b
1105         // x = (y - b) / 3a
1106         float p, q;
1107         vector v;
1108         p = (9*a*c - 3*b*b);
1109         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1110         v = solve_cubic_pq(p, q);
1111         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1112         if(a < 0)
1113                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1114         return v;
1115 }
1116
1117 vector findperpendicular(vector v)
1118 {
1119         vector p;
1120         p_x = v_z;
1121         p_y = -v_x;
1122         p_z = v_y;
1123         return normalize(cliptoplane(p, v));
1124 }
1125
1126 vector W_CalculateProjectileSpread(vector forward, float spread)
1127 {
1128         float sigma;
1129         vector v1 = '0 0 0', v2;
1130         float dx, dy, r;
1131         float sstyle;
1132         spread *= g_weaponspreadfactor;
1133         if(spread <= 0)
1134                 return forward;
1135         sstyle = autocvar_g_projectiles_spread_style;
1136
1137         if(sstyle == 0)
1138         {
1139                 // this is the baseline for the spread value!
1140                 // standard deviation: sqrt(2/5)
1141                 // density function: sqrt(1-r^2)
1142                 return forward + randomvec() * spread;
1143         }
1144         else if(sstyle == 1)
1145         {
1146                 // same thing, basically
1147                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1148         }
1149         else if(sstyle == 2)
1150         {
1151                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1152                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1153                 v1 = findperpendicular(forward);
1154                 v2 = cross(forward, v1);
1155                 // random point on unit circle
1156                 dx = random() * 2 * M_PI;
1157                 dy = sin(dx);
1158                 dx = cos(dx);
1159                 // radius in our dist function
1160                 r = random();
1161                 r = sqrt(r);
1162                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1163         }
1164         else if(sstyle == 3) // gauss 3d
1165         {
1166                 sigma = spread * 0.44721359549996; // match baseline stddev
1167                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1168                 v1 = forward;
1169                 v1_x += gsl_ran_gaussian(sigma);
1170                 v1_y += gsl_ran_gaussian(sigma);
1171                 v1_z += gsl_ran_gaussian(sigma);
1172                 return v1;
1173         }
1174         else if(sstyle == 4) // gauss 2d
1175         {
1176                 sigma = spread * 0.44721359549996; // match baseline stddev
1177                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1178                 v1_x = gsl_ran_gaussian(sigma);
1179                 v1_y = gsl_ran_gaussian(sigma);
1180                 v1_z = gsl_ran_gaussian(sigma);
1181                 return normalize(forward + cliptoplane(v1, forward));
1182         }
1183         else if(sstyle == 5) // 1-r
1184         {
1185                 sigma = spread * 1.154700538379252; // match baseline stddev
1186                 v1 = findperpendicular(forward);
1187                 v2 = cross(forward, v1);
1188                 // random point on unit circle
1189                 dx = random() * 2 * M_PI;
1190                 dy = sin(dx);
1191                 dx = cos(dx);
1192                 // radius in our dist function
1193                 r = random();
1194                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1195                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1196         }
1197         else if(sstyle == 6) // 1-r^2
1198         {
1199                 sigma = spread * 1.095445115010332; // match baseline stddev
1200                 v1 = findperpendicular(forward);
1201                 v2 = cross(forward, v1);
1202                 // random point on unit circle
1203                 dx = random() * 2 * M_PI;
1204                 dy = sin(dx);
1205                 dx = cos(dx);
1206                 // radius in our dist function
1207                 r = random();
1208                 r = sqrt(1 - r);
1209                 r = sqrt(1 - r);
1210                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1211         }
1212         else if(sstyle == 7) // (1-r) (2-r)
1213         {
1214                 sigma = spread * 1.224744871391589; // match baseline stddev
1215                 v1 = findperpendicular(forward);
1216                 v2 = cross(forward, v1);
1217                 // random point on unit circle
1218                 dx = random() * 2 * M_PI;
1219                 dy = sin(dx);
1220                 dx = cos(dx);
1221                 // radius in our dist function
1222                 r = random();
1223                 r = 1 - sqrt(r);
1224                 r = 1 - sqrt(r);
1225                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1226         }
1227         else
1228                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1229         return '0 0 0';
1230         /*
1231          * how to derive falloff functions:
1232          * rho(r) := (2-r) * (1-r);
1233          * a : 0;
1234          * b : 1;
1235          * rhor(r) := r * rho(r);
1236          * cr(t) := integrate(rhor(r), r, a, t);
1237          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1238          * variance : scr(b) / cr(b);
1239          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1240          * sqrt(0.4 / variance), numer;
1241          */
1242 }
1243
1244 #if 0
1245 float mspercallsum;
1246 float mspercallsstyle;
1247 float mspercallcount;
1248 #endif
1249 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1250 {
1251         if(missile.owner == world)
1252                 error("Unowned missile");
1253
1254         dir = dir + upDir * (pUpSpeed / pSpeed);
1255         dir_z += pZSpeed / pSpeed;
1256         pSpeed *= vlen(dir);
1257         dir = normalize(dir);
1258
1259 #if 0
1260         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1261         {
1262                 mspercallsum = mspercallcount = 0;
1263                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1264         }
1265         mspercallsum -= gettime(GETTIME_HIRES);
1266 #endif
1267         dir = W_CalculateProjectileSpread(dir, spread);
1268 #if 0
1269         mspercallsum += gettime(GETTIME_HIRES);
1270         mspercallcount += 1;
1271         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1272 #endif
1273
1274         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1275 }
1276
1277 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1278 {
1279         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1280 }
1281
1282 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1283 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1284
1285 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1286 {
1287         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1288                 return;
1289
1290         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1291         if(ammo_reload)
1292         {
1293                 self.clip_load -= ammo_use;
1294                 self.(weapon_load[self.weapon]) = self.clip_load;
1295         }
1296         else
1297                 self.(self.current_ammo) -= ammo_use;
1298 }
1299
1300 // weapon reloading code
1301
1302 .float reload_ammo_amount, reload_ammo_min, reload_time;
1303 .float reload_complain;
1304 .string reload_sound;
1305
1306 void W_ReloadedAndReady()
1307 {
1308         // finish the reloading process, and do the ammo transfer
1309
1310         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1311
1312         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1313         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1314                 self.clip_load = self.reload_ammo_amount;
1315         else
1316         {
1317                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1318                 {
1319                         self.clip_load += 1;
1320                         self.(self.current_ammo) -= 1;
1321                 }
1322         }
1323         self.(weapon_load[self.weapon]) = self.clip_load;
1324
1325         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1326         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1327         // so your weapon is disabled for a few seconds without reason
1328
1329         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1330
1331         w_ready();
1332 }
1333
1334 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1335 {
1336         // set global values to work with
1337
1338         self.reload_ammo_min = sent_ammo_min;
1339         self.reload_ammo_amount = sent_ammo_amount;
1340         self.reload_time = sent_time;
1341         self.reload_sound = sent_sound;
1342
1343         // check if we meet the necessary conditions to reload
1344
1345         entity e;
1346         e = get_weaponinfo(self.weapon);
1347
1348         // don't reload weapons that don't have the RELOADABLE flag
1349         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
1350         {
1351                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1352                 return;
1353         }
1354
1355         // return if reloading is disabled for this weapon
1356         if(!self.reload_ammo_amount)
1357                 return;
1358
1359         // our weapon is fully loaded, no need to reload
1360         if (self.clip_load >= self.reload_ammo_amount)
1361                 return;
1362
1363         // no ammo, so nothing to load
1364         if(!self.(self.current_ammo) && self.reload_ammo_min)
1365         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1366         {
1367                 if(IS_REAL_CLIENT(self) && self.reload_complain < time)
1368                 {
1369                         play2(self, "weapons/unavailable.wav");
1370                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1371                         self.reload_complain = time + 1;
1372                 }
1373                 // switch away if the amount of ammo is not enough to keep using this weapon
1374                 if (!(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2)))
1375                 {
1376                         self.clip_load = -1; // reload later
1377                         W_SwitchToOtherWeapon(self);
1378                 }
1379                 return;
1380         }
1381
1382         if (self.weaponentity)
1383         {
1384                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1385                         return;
1386
1387                 // allow switching away while reloading, but this will cause a new reload!
1388                 self.weaponentity.state = WS_READY;
1389         }
1390
1391         // now begin the reloading process
1392
1393         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTEN_NORM);
1394
1395         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1396         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1397         // so your weapon is disabled for a few seconds without reason
1398
1399         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1400
1401         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1402
1403         if(self.clip_load < 0)
1404                 self.clip_load = 0;
1405         self.old_clip_load = self.clip_load;
1406         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1407 }