Fix extra life powerup giving infinite lives in lms & minstagib
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         return t;
18 }
19
20 void W_SwitchWeapon_Force(entity e, float w)
21 {
22         e.cnt = e.switchweapon;
23         e.switchweapon = w;
24         e.selectweapon = w;
25 }
26
27 .float antilag_debug;
28
29 // VorteX: static frame globals
30 float WFRAME_DONTCHANGE = -1;
31 float WFRAME_FIRE1 = 0;
32 float WFRAME_FIRE2 = 1;
33 float WFRAME_IDLE = 2;
34 float WFRAME_RELOAD = 3;
35 .float wframe;
36
37 void(float fr, float t, void() func) weapon_thinkf;
38
39 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
40 {
41         vector ret;
42         ret_x = screenright * v;
43         ret_y = screenup * v;
44         ret_z = screenforward * v;
45         return ret;
46 }
47
48 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
49 {
50         float i, j, k;
51         vector mi, ma, thisv, myv, ret;
52
53         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
54
55         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
56
57         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
58         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
59         {
60                 thisv = targ.origin;
61                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
62                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
63                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
64                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
65                 if(i || j || k)
66                 {
67                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
68                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
69                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
70                 }
71                 else
72                 {
73                         // first run
74                         mi = ma = thisv;
75                 }
76         }
77
78         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
79         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
80         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
81         ret_z = thisv_z - myv_z;
82         return ret;
83 }
84
85 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
86 {
87         vector hitplot;
88         vector org;
89         float lag;
90
91         if(player.hitplotfh >= 0)
92         {
93                 lag = ANTILAG_LATENCY(player);
94                 if(lag < 0.001)
95                         lag = 0;
96                 if(clienttype(player) != CLIENTTYPE_REAL)
97                         lag = 0; // only antilag for clients
98
99                 org = player.origin + player.view_ofs;
100                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
101                 if(trace_ent.flags & FL_CLIENT)
102                 {
103                         antilag_takeback(trace_ent, time - lag);
104                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
105                         antilag_restore(trace_ent);
106                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
107                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
108                 }
109         }
110 }
111
112 vector w_shotorg;
113 vector w_shotdir;
114 vector w_shotend;
115
116 .float prevstrengthsound;
117 .float prevstrengthsoundattempt;
118 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
119 {
120         if((player.items & IT_STRENGTH)
121                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
122                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
123                 {
124                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
125                         player.prevstrengthsound = time;
126                 }
127                 player.prevstrengthsoundattempt = time;
128 }
129
130 // this function calculates w_shotorg and w_shotdir based on the weapon model
131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
132 // make sure you call makevectors first (FIXME?)
133 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
134 {
135         float nudge = 1; // added to traceline target and subtracted from result
136         float oldsolid;
137         vector vecs, dv;
138         oldsolid = ent.dphitcontentsmask;
139         if(ent.weapon == WEP_RIFLE)
140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
141         else
142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
143         if(antilag)
144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
145                 // passing world, because we do NOT want it to touch dphitcontentsmask
146         else
147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
149
150         vector vf, vr, vu;
151         vf = v_forward;
152         vr = v_right;
153         vu = v_up;
154         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
155         v_forward = vf;
156         v_right = vr;
157         v_up = vu;
158
159         // un-adjust trueaim if shotend is too close
160         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
161                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
162
163         // track max damage
164         if(accuracy_canbegooddamage(ent))
165                 accuracy_add(ent, ent.weapon, maxdamage, 0);
166
167         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
168
169         if(ent.weaponentity.movedir_x > 0)
170                 vecs = ent.weaponentity.movedir;
171         else
172                 vecs = '0 0 0';
173
174         dv = v_right * -vecs_y + v_up * vecs_z;
175         w_shotorg = ent.origin + ent.view_ofs + dv;
176
177         // now move the shotorg forward as much as requested if possible
178         if(antilag)
179         {
180                 if(ent.antilag_debug)
181                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
182                 else
183                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
184         }
185         else
186                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
187         w_shotorg = trace_endpos - v_forward * nudge;
188         // calculate the shotdir from the chosen shotorg
189         w_shotdir = normalize(w_shotend - w_shotorg);
190
191         if (antilag)
192         if (!ent.cvar_cl_noantilag)
193         {
194                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
195                 {
196                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
197                         if (!trace_ent.takedamage)
198                         {
199                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
200                                 if (trace_ent.takedamage && trace_ent.classname == "player")
201                                 {
202                                         entity e;
203                                         e = trace_ent;
204                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
205                                         if(trace_ent == e)
206                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
207                                 }
208                         }
209                 }
210                 else if(autocvar_g_antilag == 3) // client side hitscan
211                 {
212                         // this part MUST use prydon cursor
213                         if (ent.cursor_trace_ent)                 // client was aiming at someone
214                         if (ent.cursor_trace_ent != ent)         // just to make sure
215                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
216                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
217                         {
218                                 // verify that the shot would miss without antilag
219                                 // (avoids an issue where guns would always shoot at their origin)
220                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
221                                 if (!trace_ent.takedamage)
222                                 {
223                                         // verify that the shot would hit if altered
224                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
225                                         if (trace_ent == ent.cursor_trace_ent)
226                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
227                                         else
228                                                 print("antilag fail\n");
229                                 }
230                         }
231                 }
232         }
233
234         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
235
236         if (!g_norecoil)
237                 ent.punchangle_x = recoil * -1;
238
239         if (snd != "")
240         {
241                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
242                 W_PlayStrengthSound(ent);
243         }
244
245         // nudge w_shotend so a trace to w_shotend hits
246         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
247 }
248
249 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
250 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
251 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
252 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
253 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
254
255 float CL_Weaponentity_CustomizeEntityForClient()
256 {
257         self.viewmodelforclient = self.owner;
258         if(other.classname == "spectator")
259                 if(other.enemy == self.owner)
260                         self.viewmodelforclient = other;
261         return TRUE;
262 }
263
264 /*
265  * supported formats:
266  *
267  * 1. simple animated model, muzzle flash handling on h_ model:
268  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
269  *      tags:
270  *        shot = muzzle end (shot origin, also used for muzzle flashes)
271  *        shell = casings ejection point (must be on the right hand side of the gun)
272  *        weapon = attachment for v_tuba.md3
273  *    v_tuba.md3 - first and third person model
274  *    g_tuba.md3 - pickup model
275  *
276  * 2. simple animated model, muzzle flash handling on v_ model:
277  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
278  *      tags:
279  *        weapon = attachment for v_tuba.md3
280  *    v_tuba.md3 - first and third person model
281  *      tags:
282  *        shot = muzzle end (shot origin, also used for muzzle flashes)
283  *        shell = casings ejection point (must be on the right hand side of the gun)
284  *    g_tuba.md3 - pickup model
285  *
286  * 3. fully animated model, muzzle flash handling on h_ model:
287  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
288  *      tags:
289  *        shot = muzzle end (shot origin, also used for muzzle flashes)
290  *        shell = casings ejection point (must be on the right hand side of the gun)
291  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
292  *    v_tuba.md3 - third person model
293  *    g_tuba.md3 - pickup model
294  *
295  * 4. fully animated model, muzzle flash handling on v_ model:
296  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
297  *      tags:
298  *        shot = muzzle end (shot origin)
299  *        shell = casings ejection point (must be on the right hand side of the gun)
300  *    v_tuba.md3 - third person model
301  *      tags:
302  *        shot = muzzle end (for muzzle flashes)
303  *    g_tuba.md3 - pickup model
304  */
305
306 // writes:
307 //   self.origin, self.angles
308 //   self.weaponentity
309 //   self.movedir, self.view_ofs
310 //   attachment stuff
311 //   anim stuff
312 // to free:
313 //   call again with ""
314 //   remove the ent
315 void CL_WeaponEntity_SetModel(string name)
316 {
317         float v_shot_idx;
318         if (name != "")
319         {
320                 // if there is a child entity, hide it until we're sure we use it
321                 if (self.weaponentity)
322                         self.weaponentity.model = "";
323                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
324                 v_shot_idx = gettagindex(self, "shot"); // used later
325                 if(!v_shot_idx)
326                         v_shot_idx = gettagindex(self, "tag_shot");
327
328                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
329                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
330                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
331                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
332                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
333                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
334
335                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
336                 // if we don't, this is a "real" animated model
337                 if(gettagindex(self, "weapon"))
338                 {
339                         if (!self.weaponentity)
340                                 self.weaponentity = spawn();
341                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
342                         setattachment(self.weaponentity, self, "weapon");
343                 }
344                 else if(gettagindex(self, "tag_weapon"))
345                 {
346                         if (!self.weaponentity)
347                                 self.weaponentity = spawn();
348                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
349                         setattachment(self.weaponentity, self, "tag_weapon");
350                 }
351                 else
352                 {
353                         if(self.weaponentity)
354                                 remove(self.weaponentity);
355                         self.weaponentity = world;
356                 }
357
358                 setorigin(self,'0 0 0');
359                 self.angles = '0 0 0';
360                 self.frame = 0;
361                 self.viewmodelforclient = world;
362
363                 float idx;
364
365                 if(v_shot_idx) // v_ model attached to invisible h_ model
366                 {
367                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
368                 }
369                 else
370                 {
371                         idx = gettagindex(self, "shot");
372                         if(!idx)
373                                 idx = gettagindex(self, "tag_shot");
374                         if(idx)
375                                 self.movedir = gettaginfo(self, idx);
376                         else
377                         {
378                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
379                                 self.movedir = '0 0 0';
380                         }
381                 }
382
383                 if(self.weaponentity) // v_ model attached to invisible h_ model
384                 {
385                         idx = gettagindex(self.weaponentity, "shell");
386                         if(!idx)
387                                 idx = gettagindex(self.weaponentity, "tag_shell");
388                         if(idx)
389                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
390                 }
391                 else
392                         idx = 0;
393                 if(!idx)
394                 {
395                         idx = gettagindex(self, "shell");
396                         if(!idx)
397                                 idx = gettagindex(self, "tag_shell");
398                         if(idx)
399                                 self.spawnorigin = gettaginfo(self, idx);
400                         else
401                         {
402                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
403                                 self.spawnorigin = self.movedir;
404                         }
405                 }
406
407                 if(v_shot_idx)
408                 {
409                         self.oldorigin = '0 0 0'; // use regular attachment
410                 }
411                 else
412                 {
413                         if(self.weaponentity)
414                         {
415                                 idx = gettagindex(self, "weapon");
416                                 if(!idx)
417                                         idx = gettagindex(self, "tag_weapon");
418                         }
419                         else
420                         {
421                                 idx = gettagindex(self, "handle");
422                                 if(!idx)
423                                         idx = gettagindex(self, "tag_handle");
424                         }
425                         if(idx)
426                         {
427                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
428                         }
429                         else
430                         {
431                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
432                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
433                         }
434                 }
435
436                 self.viewmodelforclient = self.owner;
437         }
438         else
439         {
440                 self.model = "";
441                 if(self.weaponentity)
442                         remove(self.weaponentity);
443                 self.weaponentity = world;
444                 self.movedir = '0 0 0';
445                 self.spawnorigin = '0 0 0';
446                 self.oldorigin = '0 0 0';
447                 self.anim_fire1  = '0 1 0.01';
448                 self.anim_fire2  = '0 1 0.01';
449                 self.anim_idle   = '0 1 0.01';
450                 self.anim_reload = '0 1 0.01';
451         }
452
453         self.view_ofs = '0 0 0';
454
455         if(self.movedir_x >= 0)
456         {
457                 vector v0;
458                 v0 = self.movedir;
459                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
460                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
461         }
462         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
463         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
464
465         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
466
467         // check if an instant weapon switch occurred
468         setorigin(self, self.view_ofs);
469         // reset animstate now
470         self.wframe = WFRAME_IDLE;
471         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
472 }
473
474 vector CL_Weapon_GetShotOrg(float wpn)
475 {
476         entity wi, oldself;
477         vector ret;
478         wi = get_weaponinfo(wpn);
479         oldself = self;
480         self = spawn();
481         CL_WeaponEntity_SetModel(wi.mdl);
482         ret = self.movedir;
483         CL_WeaponEntity_SetModel("");
484         remove(self);
485         self = oldself;
486         return ret;
487 }
488
489 void CL_Weaponentity_Think()
490 {
491         float tb;
492         self.nextthink = time;
493         if (intermission_running)
494                 self.frame = self.anim_idle_x;
495         if (self.owner.weaponentity != self)
496         {
497                 if (self.weaponentity)
498                         remove(self.weaponentity);
499                 remove(self);
500                 return;
501         }
502         if (self.owner.deadflag != DEAD_NO)
503         {
504                 self.model = "";
505                 if (self.weaponentity)
506                         self.weaponentity.model = "";
507                 return;
508         }
509         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
510         {
511                 self.weaponname = self.owner.weaponname;
512                 self.dmg = self.owner.modelindex;
513                 self.deadflag = self.owner.deadflag;
514
515                 CL_WeaponEntity_SetModel(self.owner.weaponname);
516         }
517
518         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
519         self.effects = self.owner.effects & EFMASK_CHEAP;
520         self.effects &~= EF_LOWPRECISION;
521         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
522         self.effects &~= EF_TELEPORT_BIT;
523         self.effects &~= EF_RESTARTANIM_BIT;
524         self.effects |= tb;
525
526         if(self.owner.alpha == default_player_alpha)
527                 self.alpha = default_weapon_alpha;
528         else if(self.owner.alpha != 0)
529                 self.alpha = self.owner.alpha;
530         else
531                 self.alpha = 1;
532
533         self.glowmod = self.owner.weaponentity_glowmod;
534         self.colormap = self.owner.colormap;
535         if (self.weaponentity)
536         {
537                 self.weaponentity.effects = self.effects;
538                 self.weaponentity.alpha = self.alpha;
539                 self.weaponentity.colormap = self.colormap;
540                 self.weaponentity.glowmod = self.glowmod;
541         }
542
543         self.angles = '0 0 0';
544         float f;
545         if (self.state == WS_RAISE && !intermission_running)
546         {
547                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
548                 self.angles_x = -90 * f * f;
549         }
550         else if (self.state == WS_DROP && !intermission_running)
551         {
552                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
553                 self.angles_x = -90 * f * f;
554         }
555         else if (self.state == WS_CLEAR)
556         {
557                 f = 1;
558                 self.angles_x = -90 * f * f;
559         }
560 }
561
562 void CL_ExteriorWeaponentity_Think()
563 {
564         float tag_found;
565         self.nextthink = time;
566         if (self.owner.exteriorweaponentity != self)
567         {
568                 remove(self);
569                 return;
570         }
571         if (self.owner.deadflag != DEAD_NO)
572         {
573                 self.model = "";
574                 return;
575         }
576         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
577         {
578                 self.weaponname = self.owner.weaponname;
579                 self.dmg = self.owner.modelindex;
580                 self.deadflag = self.owner.deadflag;
581                 if (self.owner.weaponname != "")
582                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
583                 else
584                         self.model = "";
585
586                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
587                 {
588                         self.tag_index = tag_found;
589                         self.tag_entity = self.owner;
590                 }
591                 else
592                         setattachment(self, self.owner, "bip01 r hand");
593         }
594         self.effects = self.owner.effects;
595         self.effects |= EF_LOWPRECISION;
596         self.effects = self.effects & EFMASK_CHEAP; // eat performance
597         if(self.owner.alpha == default_player_alpha)
598                 self.alpha = default_weapon_alpha;
599         else if(self.owner.alpha != 0)
600                 self.alpha = self.owner.alpha;
601         else
602                 self.alpha = 1;
603
604         self.glowmod = self.owner.weaponentity_glowmod;
605         self.colormap = self.owner.colormap;
606
607         CSQCMODEL_AUTOUPDATE();
608 }
609
610 // spawning weaponentity for client
611 void CL_SpawnWeaponentity()
612 {
613         self.weaponentity = spawn();
614         self.weaponentity.classname = "weaponentity";
615         self.weaponentity.solid = SOLID_NOT;
616         self.weaponentity.owner = self;
617         setmodel(self.weaponentity, ""); // precision set when changed
618         setorigin(self.weaponentity, '0 0 0');
619         self.weaponentity.angles = '0 0 0';
620         self.weaponentity.viewmodelforclient = self;
621         self.weaponentity.flags = 0;
622         self.weaponentity.think = CL_Weaponentity_Think;
623         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
624         self.weaponentity.nextthink = time;
625
626         self.exteriorweaponentity = spawn();
627         self.exteriorweaponentity.classname = "exteriorweaponentity";
628         self.exteriorweaponentity.solid = SOLID_NOT;
629         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
630         self.exteriorweaponentity.owner = self;
631         setorigin(self.exteriorweaponentity, '0 0 0');
632         self.exteriorweaponentity.angles = '0 0 0';
633         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
634         self.exteriorweaponentity.nextthink = time;
635
636         {
637                 entity oldself = self;
638                 self = self.exteriorweaponentity;
639                 CSQCMODEL_AUTOINIT();
640                 self = oldself;
641         }
642 }
643
644 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
645 {
646         msg_entity = e;
647         WriteByte(MSG_ONE, SVC_TEMPENTITY);
648         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
649         WriteByte(MSG_ONE, wpn);
650         WriteString(MSG_ONE, wpnname);
651         WriteByte(MSG_ONE, type);
652 }
653
654 .float hasweapon_complain_spam;
655
656 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
657 {
658         float f;
659         entity oldself;
660
661         if(time < self.hasweapon_complain_spam)
662                 complain = 0;
663         if(complain)
664                 self.hasweapon_complain_spam = time + 0.2;
665
666         if (wpn < WEP_FIRST || wpn > WEP_LAST)
667         {
668                 if (complain)
669                         sprint(self, "Invalid weapon\n");
670                 return FALSE;
671         }
672         if (WEPSET_CONTAINS_EW(cl, wpn))
673         {
674                 if (andammo)
675                 {
676                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
677                         {
678                                 f = 1;
679                         }
680                         else
681                         {
682                                 oldself = self;
683                                 self = cl;
684                                 f = weapon_action(wpn, WR_CHECKAMMO1);
685                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
686
687                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
688                                 entity mine;
689                                 if(wpn == WEP_MINE_LAYER)
690                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
691                                         f = 1;
692
693                                 self = oldself;
694                         }
695                         if (!f)
696                         {
697                                 if (complain)
698                                 if(clienttype(cl) == CLIENTTYPE_REAL)
699                                 {
700                                         play2(cl, "weapons/unavailable.wav");
701                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
702                                 }
703                                 return FALSE;
704                         }
705                 }
706                 return TRUE;
707         }
708         if (complain)
709         {
710                 // DRESK - 3/16/07
711                 // Report Proper Weapon Status / Modified Weapon Ownership Message
712                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
713                 {
714                         Send_WeaponComplain(cl, wpn, W_Name(wpn), 1);
715
716                         if(autocvar_g_showweaponspawns)
717                         {
718                                 entity e;
719                                 string s;
720
721                                 e = get_weaponinfo(wpn);
722                                 s = e.model2;
723
724                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
725                                 {
726                                         if(e.classname == "droppedweapon")
727                                                 continue;
728                                         if not(e.flags & FL_ITEM)
729                                                 continue;
730                                         WaypointSprite_Spawn(
731                                                 s,
732                                                 1, 0,
733                                                 world, e.origin,
734                                                 self, 0,
735                                                 world, enemy,
736                                                 0,
737                                                 RADARICON_NONE, '0 0 0'
738                                         );
739                                 }
740                         }
741                 }
742                 else
743                 {
744                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
745                 }
746
747                 play2(cl, "weapons/unavailable.wav");
748         }
749         return FALSE;
750 }
751
752 // Weapon subs
753 void w_clear()
754 {
755         if (self.weapon != -1)
756         {
757                 self.weapon = 0;
758                 self.switchingweapon = 0;
759         }
760         if (self.weaponentity)
761         {
762                 self.weaponentity.state = WS_CLEAR;
763                 self.weaponentity.effects = 0;
764         }
765 }
766
767 void w_ready()
768 {
769         if (self.weaponentity)
770                 self.weaponentity.state = WS_READY;
771         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
772 }
773
774 // Setup weapon for client (after this raise frame will be launched)
775 void weapon_setup(float windex)
776 {
777         entity e;
778         e = get_weaponinfo(windex);
779         self.items &~= IT_AMMO;
780         self.items = self.items | (e.items & IT_AMMO);
781
782         // the two weapon entities will notice this has changed and update their models
783         self.weapon = windex;
784         self.switchingweapon = windex; // to make sure
785         self.weaponname = e.mdl;
786         self.bulletcounter = 0;
787 }
788
789 // perform weapon to attack (weaponstate and attack_finished check is here)
790 void W_SwitchToOtherWeapon(entity pl)
791 {
792         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
793         float w, ww;
794         w = pl.weapon;
795         if(WEPSET_CONTAINS_EW(pl, w))
796         {
797                 WEPSET_ANDNOT_EW(pl, w);
798                 ww = w_getbestweapon(pl);
799                 WEPSET_OR_EW(pl, w);
800         }
801         else
802                 ww = w_getbestweapon(pl);
803         if(ww)
804                 W_SwitchWeapon_Force(pl, ww);
805 }
806
807 .float prevdryfire;
808 .float prevwarntime;
809 float weapon_prepareattack_checkammo(float secondary)
810 {
811         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
812         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
813         {
814                 // always keep the Mine Layer if we placed mines, so that we can detonate them
815                 entity mine;
816                 if(self.weapon == WEP_MINE_LAYER)
817                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
818                         return FALSE;
819
820                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
821                 {
822                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
823                         self.prevdryfire = time;
824                 }
825
826                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
827                 {
828                         if(time - self.prevwarntime > 1)
829                         {
830                                 Send_Notification(
831                                         NOTIF_ONE,
832                                         self,
833                                         MSG_MULTI,
834                                         ITEM_WEAPON_PRIMORSEC,
835                                         self.weapon,
836                                         secondary,
837                                         (1 - secondary)
838                                 );
839                         }
840                         self.prevwarntime = time;
841                 }
842                 else // this weapon is totally unable to fire, switch to another one
843                 {
844                         W_SwitchToOtherWeapon(self);
845                 }
846                 
847                 return FALSE;
848         }
849         return TRUE;
850 }
851 .float race_penalty;
852 float weapon_prepareattack_check(float secondary, float attacktime)
853 {
854         if(!weapon_prepareattack_checkammo(secondary))
855                 return FALSE;
856
857         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
858         //if all players readied up and the countdown is running
859         if(time < game_starttime || time < self.race_penalty) {
860                 return FALSE;
861         }
862
863         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
864                 return FALSE;
865
866         // do not even think about shooting if switching
867         if(self.switchweapon != self.weapon)
868                 return FALSE;
869
870         if(attacktime >= 0)
871         {
872                 // don't fire if previous attack is not finished
873                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
874                         return FALSE;
875                 // don't fire while changing weapon
876                 if (self.weaponentity.state != WS_READY)
877                         return FALSE;
878         }
879
880         return TRUE;
881 }
882 float weapon_prepareattack_do(float secondary, float attacktime)
883 {
884         self.weaponentity.state = WS_INUSE;
885
886         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
887
888         // if the weapon hasn't been firing continuously, reset the timer
889         if(attacktime >= 0)
890         {
891                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
892                 {
893                         ATTACK_FINISHED(self) = time;
894                         //dprint("resetting attack finished to ", ftos(time), "\n");
895                 }
896                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
897         }
898         self.bulletcounter += 1;
899         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
900         return TRUE;
901 }
902 float weapon_prepareattack(float secondary, float attacktime)
903 {
904         if(weapon_prepareattack_check(secondary, attacktime))
905         {
906                 weapon_prepareattack_do(secondary, attacktime);
907                 return TRUE;
908         }
909         else
910                 return FALSE;
911 }
912
913 void weapon_thinkf(float fr, float t, void() func)
914 {
915         vector a;
916         vector of, or, ou;
917         float restartanim;
918
919         if(fr == WFRAME_DONTCHANGE)
920         {
921                 fr = self.weaponentity.wframe;
922                 restartanim = FALSE;
923         }
924         else if (fr == WFRAME_IDLE)
925                 restartanim = FALSE;
926         else
927                 restartanim = TRUE;
928
929         of = v_forward;
930         or = v_right;
931         ou = v_up;
932
933         if (self.weaponentity)
934         {
935                 self.weaponentity.wframe = fr;
936                 a = '0 0 0';
937                 if (fr == WFRAME_IDLE)
938                         a = self.weaponentity.anim_idle;
939                 else if (fr == WFRAME_FIRE1)
940                         a = self.weaponentity.anim_fire1;
941                 else if (fr == WFRAME_FIRE2)
942                         a = self.weaponentity.anim_fire2;
943                 else // if (fr == WFRAME_RELOAD)
944                         a = self.weaponentity.anim_reload;
945                 a_z *= g_weaponratefactor;
946                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
947         }
948
949         v_forward = of;
950         v_right = or;
951         v_up = ou;
952
953         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
954         {
955                 backtrace("Tried to override initial weapon think function - should this really happen?");
956         }
957
958         t *= W_WeaponRateFactor();
959
960         // VorteX: haste can be added here
961         if (self.weapon_think == w_ready)
962         {
963                 self.weapon_nextthink = time;
964                 //dprint("started firing at ", ftos(time), "\n");
965         }
966         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
967         {
968                 self.weapon_nextthink = time;
969                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
970         }
971         self.weapon_nextthink = self.weapon_nextthink + t;
972         self.weapon_think = func;
973         //dprint("next ", ftos(self.weapon_nextthink), "\n");
974
975         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
976         {
977                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
978                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
979                 else
980                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
981         }
982         else
983         {
984                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
985                         self.anim_upper_action = 0;
986         }
987 }
988
989 void weapon_boblayer1(float spd, vector org)
990 {
991         // VorteX: haste can be added here
992 }
993
994 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
995 {
996         vector mdirection;
997         float mspeed;
998         vector outvelocity;
999
1000         mvelocity = mvelocity * g_weaponspeedfactor;
1001
1002         mdirection = normalize(mvelocity);
1003         mspeed = vlen(mvelocity);
1004
1005         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1006
1007         return outvelocity;
1008 }
1009
1010 void W_AttachToShotorg(entity flash, vector offset)
1011 {
1012         entity xflash;
1013         flash.owner = self;
1014         flash.angles_z = random() * 360;
1015
1016         if(gettagindex(self.weaponentity, "shot"))
1017                 setattachment(flash, self.weaponentity, "shot");
1018         else
1019                 setattachment(flash, self.weaponentity, "tag_shot");
1020         setorigin(flash, offset);
1021
1022         xflash = spawn();
1023         copyentity(flash, xflash);
1024
1025         flash.viewmodelforclient = self;
1026
1027         if(self.weaponentity.oldorigin_x > 0)
1028         {
1029                 setattachment(xflash, self.exteriorweaponentity, "");
1030                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1031         }
1032         else
1033         {
1034                 if(gettagindex(self.exteriorweaponentity, "shot"))
1035                         setattachment(xflash, self.exteriorweaponentity, "shot");
1036                 else
1037                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1038                 setorigin(xflash, offset);
1039         }
1040 }
1041
1042 vector cliptoplane(vector v, vector p)
1043 {
1044         return v - (v * p) * p;
1045 }
1046
1047 vector solve_cubic_pq(float p, float q)
1048 {
1049         float D, u, v, a;
1050         D = q*q/4.0 + p*p*p/27.0;
1051         if(D < 0)
1052         {
1053                 // irreducibilis
1054                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1055                 u = sqrt(-4.0/3.0 * p);
1056                 // a in range 0..pi/3
1057                 // cos(a)
1058                 // cos(a + 2pi/3)
1059                 // cos(a + 4pi/3)
1060                 return
1061                         u *
1062                         (
1063                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1064                                 +
1065                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1066                                 +
1067                                 '0 0 1' * cos(a)
1068                         );
1069         }
1070         else if(D == 0)
1071         {
1072                 // simple
1073                 if(p == 0)
1074                         return '0 0 0';
1075                 u = 3*q/p;
1076                 v = -u/2;
1077                 if(u >= v)
1078                         return '1 1 0' * v + '0 0 1' * u;
1079                 else
1080                         return '0 1 1' * v + '1 0 0' * u;
1081         }
1082         else
1083         {
1084                 // cardano
1085                 u = cbrt(-q/2.0 + sqrt(D));
1086                 v = cbrt(-q/2.0 - sqrt(D));
1087                 return '1 1 1' * (u + v);
1088         }
1089 }
1090 vector solve_cubic_abcd(float a, float b, float c, float d)
1091 {
1092         // y = 3*a*x + b
1093         // x = (y - b) / 3a
1094         float p, q;
1095         vector v;
1096         p = (9*a*c - 3*b*b);
1097         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1098         v = solve_cubic_pq(p, q);
1099         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1100         if(a < 0)
1101                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1102         return v;
1103 }
1104
1105 vector findperpendicular(vector v)
1106 {
1107         vector p;
1108         p_x = v_z;
1109         p_y = -v_x;
1110         p_z = v_y;
1111         return normalize(cliptoplane(p, v));
1112 }
1113
1114 vector W_CalculateProjectileSpread(vector forward, float spread)
1115 {
1116         float sigma;
1117         vector v1 = '0 0 0', v2;
1118         float dx, dy, r;
1119         float sstyle;
1120         spread *= g_weaponspreadfactor;
1121         if(spread <= 0)
1122                 return forward;
1123         sstyle = autocvar_g_projectiles_spread_style;
1124         
1125         if(sstyle == 0)
1126         {
1127                 // this is the baseline for the spread value!
1128                 // standard deviation: sqrt(2/5)
1129                 // density function: sqrt(1-r^2)
1130                 return forward + randomvec() * spread;
1131         }
1132         else if(sstyle == 1)
1133         {
1134                 // same thing, basically
1135                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1136         }
1137         else if(sstyle == 2)
1138         {
1139                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1140                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1141                 v1 = findperpendicular(forward);
1142                 v2 = cross(forward, v1);
1143                 // random point on unit circle
1144                 dx = random() * 2 * M_PI;
1145                 dy = sin(dx);
1146                 dx = cos(dx);
1147                 // radius in our dist function
1148                 r = random();
1149                 r = sqrt(r);
1150                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1151         }
1152         else if(sstyle == 3) // gauss 3d
1153         {
1154                 sigma = spread * 0.44721359549996; // match baseline stddev
1155                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1156                 v1 = forward;
1157                 v1_x += gsl_ran_gaussian(sigma);
1158                 v1_y += gsl_ran_gaussian(sigma);
1159                 v1_z += gsl_ran_gaussian(sigma);
1160                 return v1;
1161         }
1162         else if(sstyle == 4) // gauss 2d
1163         {
1164                 sigma = spread * 0.44721359549996; // match baseline stddev
1165                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1166                 v1_x = gsl_ran_gaussian(sigma);
1167                 v1_y = gsl_ran_gaussian(sigma);
1168                 v1_z = gsl_ran_gaussian(sigma);
1169                 return normalize(forward + cliptoplane(v1, forward));
1170         }
1171         else if(sstyle == 5) // 1-r
1172         {
1173                 sigma = spread * 1.154700538379252; // match baseline stddev
1174                 v1 = findperpendicular(forward);
1175                 v2 = cross(forward, v1);
1176                 // random point on unit circle
1177                 dx = random() * 2 * M_PI;
1178                 dy = sin(dx);
1179                 dx = cos(dx);
1180                 // radius in our dist function
1181                 r = random();
1182                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1183                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1184         }
1185         else if(sstyle == 6) // 1-r^2
1186         {
1187                 sigma = spread * 1.095445115010332; // match baseline stddev
1188                 v1 = findperpendicular(forward);
1189                 v2 = cross(forward, v1);
1190                 // random point on unit circle
1191                 dx = random() * 2 * M_PI;
1192                 dy = sin(dx);
1193                 dx = cos(dx);
1194                 // radius in our dist function
1195                 r = random();
1196                 r = sqrt(1 - r);
1197                 r = sqrt(1 - r);
1198                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1199         }
1200         else if(sstyle == 7) // (1-r) (2-r)
1201         {
1202                 sigma = spread * 1.224744871391589; // match baseline stddev
1203                 v1 = findperpendicular(forward);
1204                 v2 = cross(forward, v1);
1205                 // random point on unit circle
1206                 dx = random() * 2 * M_PI;
1207                 dy = sin(dx);
1208                 dx = cos(dx);
1209                 // radius in our dist function
1210                 r = random();
1211                 r = 1 - sqrt(r);
1212                 r = 1 - sqrt(r);
1213                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1214         }
1215         else
1216                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1217         return '0 0 0';
1218         /*
1219          * how to derive falloff functions:
1220          * rho(r) := (2-r) * (1-r);
1221          * a : 0;
1222          * b : 1;
1223          * rhor(r) := r * rho(r);
1224          * cr(t) := integrate(rhor(r), r, a, t);
1225          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1226          * variance : scr(b) / cr(b);
1227          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1228          * sqrt(0.4 / variance), numer;
1229          */
1230 }
1231
1232 #if 0
1233 float mspercallsum;
1234 float mspercallsstyle;
1235 float mspercallcount;
1236 #endif
1237 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1238 {
1239         if(missile.owner == world)
1240                 error("Unowned missile");
1241
1242         dir = dir + upDir * (pUpSpeed / pSpeed);
1243         dir_z += pZSpeed / pSpeed;
1244         pSpeed *= vlen(dir);
1245         dir = normalize(dir);
1246
1247 #if 0
1248         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1249         {
1250                 mspercallsum = mspercallcount = 0;
1251                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1252         }
1253         mspercallsum -= gettime(GETTIME_HIRES);
1254 #endif
1255         dir = W_CalculateProjectileSpread(dir, spread);
1256 #if 0
1257         mspercallsum += gettime(GETTIME_HIRES);
1258         mspercallcount += 1;
1259         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1260 #endif
1261
1262         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1263 }
1264
1265 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1266 {
1267         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1268 }
1269
1270 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1271 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1272
1273 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1274 {
1275         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1276                 return;
1277
1278         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1279         if(ammo_reload)
1280         {
1281                 self.clip_load -= ammo_use;
1282                 self.(weapon_load[self.weapon]) = self.clip_load;
1283         }
1284         else
1285                 self.(self.current_ammo) -= ammo_use;
1286 }
1287
1288 // weapon reloading code
1289
1290 .float reload_ammo_amount, reload_ammo_min, reload_time;
1291 .float reload_complain;
1292 .string reload_sound;
1293
1294 void W_ReloadedAndReady()
1295 {
1296         // finish the reloading process, and do the ammo transfer
1297
1298         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1299
1300         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1301         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1302                 self.clip_load = self.reload_ammo_amount;
1303         else
1304         {
1305                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1306                 {
1307                         self.clip_load += 1;
1308                         self.(self.current_ammo) -= 1;
1309                 }
1310         }
1311         self.(weapon_load[self.weapon]) = self.clip_load;
1312
1313         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1314         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1315         // so your weapon is disabled for a few seconds without reason
1316
1317         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1318
1319         w_ready();
1320 }
1321
1322 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1323 {
1324         // set global values to work with
1325
1326         self.reload_ammo_min = sent_ammo_min;
1327         self.reload_ammo_amount = sent_ammo_amount;
1328         self.reload_time = sent_time;
1329         self.reload_sound = sent_sound;
1330
1331         // check if we meet the necessary conditions to reload
1332
1333         entity e;
1334         e = get_weaponinfo(self.weapon);
1335
1336         // don't reload weapons that don't have the RELOADABLE flag
1337         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1338         {
1339                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1340                 return;
1341         }
1342
1343         // return if reloading is disabled for this weapon
1344         if(!self.reload_ammo_amount)
1345                 return;
1346
1347         // our weapon is fully loaded, no need to reload
1348         if (self.clip_load >= self.reload_ammo_amount)
1349                 return;
1350
1351         // no ammo, so nothing to load
1352         if(!self.(self.current_ammo) && self.reload_ammo_min)
1353         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1354         {
1355                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1356                 {
1357                         play2(self, "weapons/unavailable.wav");
1358                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1359                         self.reload_complain = time + 1;
1360                 }
1361                 // switch away if the amount of ammo is not enough to keep using this weapon
1362                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1363                 {
1364                         self.clip_load = -1; // reload later
1365                         W_SwitchToOtherWeapon(self);
1366                 }
1367                 return;
1368         }
1369
1370         if (self.weaponentity)
1371         {
1372                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1373                         return;
1374
1375                 // allow switching away while reloading, but this will cause a new reload!
1376                 self.weaponentity.state = WS_READY;
1377         }
1378
1379         // now begin the reloading process
1380
1381         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1382
1383         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1384         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1385         // so your weapon is disabled for a few seconds without reason
1386
1387         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1388
1389         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1390
1391         if(self.clip_load < 0)
1392                 self.clip_load = 0;
1393         self.old_clip_load = self.clip_load;
1394         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1395 }