qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         // don't switch to another weapon if we're not allowed to
  38         if(e.weapon_forbidchange)
  39                 return;
  40
  41         e.cnt = e.switchweapon;
  42         e.switchweapon = w;
  43         e.selectweapon = w;
  44 }
  45
  46 .float antilag_debug;
  47
  48 // VorteX: static frame globals
  49 float WFRAME_DONTCHANGE = -1;
  50 float WFRAME_FIRE1 = 0;
  51 float WFRAME_FIRE2 = 1;
  52 float WFRAME_IDLE = 2;
  53 float WFRAME_RELOAD = 3;
  54 .float wframe;
  55
  56 void(float fr, float t, void() func) weapon_thinkf;
  57
  58 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  59 {
  60         vector ret;
  61         ret_x = screenright * v;
  62         ret_y = screenup * v;
  63         ret_z = screenforward * v;
  64         return ret;
  65 }
  66
  67 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  68 {
  69         float i, j, k;
  70         vector mi, ma, thisv, myv, ret;
  71
  72         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  73
  74         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  75
  76         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  77         {
  78                 thisv = targ.origin;
  79                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  80                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  81                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  82                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  83                 if(i || j || k)
  84                 {
  85                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  86                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  87                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  88                 }
  89                 else
  90                 {
  91                         // first run
  92                         mi = ma = thisv;
  93                 }
  94         }
  95
  96         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  97         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  98         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  99         ret_z = thisv_z - myv_z;
 100         return ret;
 101 }
 102
 103 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 104 {
 105         vector hitplot;
 106         vector org;
 107         float lag;
 108
 109         if(player.hitplotfh >= 0)
 110         {
 111                 lag = ANTILAG_LATENCY(player);
 112                 if(lag < 0.001)
 113                         lag = 0;
 114                 if(clienttype(player) != CLIENTTYPE_REAL)
 115                         lag = 0; // only antilag for clients
 116
 117                 org = player.origin + player.view_ofs;
 118                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 119                 if(trace_ent.flags & FL_CLIENT)
 120                 {
 121                         antilag_takeback(trace_ent, time - lag);
 122                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 123                         antilag_restore(trace_ent);
 124                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 125                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 126                 }
 127         }
 128 }
 129
 130 vector w_shotorg;
 131 vector w_shotdir;
 132 vector w_shotend;
 133
 134 // this function calculates w_shotorg and w_shotdir based on the weapon model
 135 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 136 // make sure you call makevectors first (FIXME?)
 137 .float prevstrengthsound;
 138 .float prevstrengthsoundattempt;
 139 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 140 {
 141         float nudge = 1; // added to traceline target and subtracted from result
 142         local float oldsolid;
 143         vector vecs, dv;
 144         oldsolid = ent.dphitcontentsmask;
 145         if(ent.weapon == WEP_RIFLE)
 146                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 147         else
 148                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 149         if(antilag)
 150                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 151                 // passing world, because we do NOT want it to touch dphitcontentsmask
 152         else
 153                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 154         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 155
 156         vector vf, vr, vu;
 157         vf = v_forward;
 158         vr = v_right;
 159         vu = v_up;
 160         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 161         v_forward = vf;
 162         v_right = vr;
 163         v_up = vu;
 164
 165         // un-adjust trueaim if shotend is too close
 166         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 167                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 168
 169         // track max damage
 170         if(accuracy_canbegooddamage(ent))
 171                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 172
 173         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 174
 175         if(ent.weaponentity.movedir_x > 0)
 176                 vecs = ent.weaponentity.movedir;
 177         else
 178                 vecs = '0 0 0';
 179         if(debug_shotorg != '0 0 0')
 180                 vecs = debug_shotorg;
 181
 182         dv = v_right * -vecs_y + v_up * vecs_z;
 183         w_shotorg = ent.origin + ent.view_ofs + dv;
 184
 185         // now move the shotorg forward as much as requested if possible
 186         if(antilag)
 187         {
 188                 if(ent.antilag_debug)
 189                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 190                 else
 191                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 192         }
 193         else
 194                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 195         w_shotorg = trace_endpos - v_forward * nudge;
 196         // calculate the shotdir from the chosen shotorg
 197         w_shotdir = normalize(w_shotend - w_shotorg);
 198
 199         if (antilag)
 200         if (!ent.cvar_cl_noantilag)
 201         {
 202                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 203                 {
 204                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 205                         if (!trace_ent.takedamage)
 206                         {
 207                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 208                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 209                                 {
 210                                         entity e;
 211                                         e = trace_ent;
 212                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 213                                         if(trace_ent == e)
 214                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 215                                 }
 216                         }
 217                 }
 218                 else if(autocvar_g_antilag == 3) // client side hitscan
 219                 {
 220                         // this part MUST use prydon cursor
 221                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 222                         if (ent.cursor_trace_ent != ent)         // just to make sure
 223                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 224                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 225                         {
 226                                 // verify that the shot would miss without antilag
 227                                 // (avoids an issue where guns would always shoot at their origin)
 228                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 229                                 if (!trace_ent.takedamage)
 230                                 {
 231                                         // verify that the shot would hit if altered
 232                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 233                                         if (trace_ent == ent.cursor_trace_ent)
 234                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 235                                         else
 236                                                 print("antilag fail\n");
 237                                 }
 238                         }
 239                 }
 240         }
 241
 242         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 243
 244         if (!g_norecoil)
 245                 ent.punchangle_x = recoil * -1;
 246
 247         if (snd != "")
 248                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 249
 250         if(ent.items & IT_STRENGTH)
 251         if(!g_minstagib)
 252         if(
 253                 (time > ent.prevstrengthsound + autocvar_sv_strengthsound_antispam_time)
 254                 ||
 255                 (time > ent.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)
 256         ) // prevent insane sound spam
 257         {
 258                 sound(ent, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 259                 ent.prevstrengthsound = time;
 260         }
 261         ent.prevstrengthsoundattempt = time;
 262
 263         // nudge w_shotend so a trace to w_shotend hits
 264         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 265 };
 266
 267 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 268 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 270 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 271 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 272
 273 float CL_Weaponentity_CustomizeEntityForClient()
 274 {
 275         self.viewmodelforclient = self.owner;
 276         if(other.classname == "spectator")
 277                 if(other.enemy == self.owner)
 278                         self.viewmodelforclient = other;
 279         return TRUE;
 280 }
 281
 282 float qcweaponanimation;
 283 vector weapon_offset = '0 -10 0';
 284 vector weapon_adjust = '10 0 -15';
 285 .vector weapon_morph0origin;
 286 .vector weapon_morph0angles;
 287 .float  weapon_morph0time;
 288 .vector weapon_morph1origin;
 289 .vector weapon_morph1angles;
 290 .float  weapon_morph1time;
 291 .vector weapon_morph2origin;
 292 .vector weapon_morph2angles;
 293 .float  weapon_morph2time;
 294 .vector weapon_morph3origin;
 295 .vector weapon_morph3angles;
 296 .float  weapon_morph3time;
 297 .vector weapon_morph4origin;
 298 .vector weapon_morph4angles;
 299 .float  weapon_morph4time;
 300 .string weaponname;
 301 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 302
 303 /*
 304  * supported formats:
 305  *
 306  * 1. simple animated model, muzzle flash handling on h_ model:
 307  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 308  *      tags:
 309  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 310  *        shell = casings ejection point (must be on the right hand side of the gun)
 311  *        weapon = attachment for v_tuba.md3
 312  *    v_tuba.md3 - first and third person model
 313  *    g_tuba.md3 - pickup model
 314  *
 315  * 2. simple animated model, muzzle flash handling on v_ model:
 316  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 317  *      tags:
 318  *        weapon = attachment for v_tuba.md3
 319  *    v_tuba.md3 - first and third person model
 320  *      tags:
 321  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 322  *        shell = casings ejection point (must be on the right hand side of the gun)
 323  *    g_tuba.md3 - pickup model
 324  *
 325  * 3. fully animated model, muzzle flash handling on h_ model:
 326  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 327  *      tags:
 328  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 329  *        shell = casings ejection point (must be on the right hand side of the gun)
 330  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 331  *    v_tuba.md3 - third person model
 332  *    g_tuba.md3 - pickup model
 333  *
 334  * 4. fully animated model, muzzle flash handling on v_ model:
 335  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 336  *      tags:
 337  *        shot = muzzle end (shot origin)
 338  *        shell = casings ejection point (must be on the right hand side of the gun)
 339  *    v_tuba.md3 - third person model
 340  *      tags:
 341  *        shot = muzzle end (for muzzle flashes)
 342  *    g_tuba.md3 - pickup model
 343  */
 344
 345 // writes:
 346 //   self.origin, self.angles
 347 //   self.weaponentity
 348 //   self.movedir, self.view_ofs
 349 //   attachment stuff
 350 //   anim stuff
 351 // to free:
 352 //   call again with ""
 353 //   remove the ent
 354 void CL_WeaponEntity_SetModel(string name)
 355 {
 356         string animfilename;
 357         float animfile;
 358         float v_shot_idx;
 359         if (name != "")
 360         {
 361                 // if there is a child entity, hide it until we're sure we use it
 362                 if (self.weaponentity)
 363                         self.weaponentity.model = "";
 364                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 365                 v_shot_idx = gettagindex(self, "shot"); // used later
 366                 if(!v_shot_idx)
 367                         v_shot_idx = gettagindex(self, "tag_shot");
 368
 369                 if(qcweaponanimation)
 370                 {
 371                         self.angles = '0 0 0';
 372                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 373                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 374                         self.movedir_x += 32;
 375                         self.spawnorigin = self.movedir;
 376                         // oldorigin - not calculated here
 377                 }
 378                 else
 379                 {
 380                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 381                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 382                         animfile = fopen(animfilename, FILE_READ);
 383                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 384                         self.anim_fire1  = '0 1 0.01';
 385                         self.anim_fire2  = '1 1 0.01';
 386                         self.anim_idle   = '2 1 0.01';
 387                         self.anim_reload = '3 1 0.01';
 388                         if (animfile >= 0)
 389                         {
 390                                 animparseerror = FALSE;
 391                                 self.anim_fire1  = animparseline(animfile);
 392                                 self.anim_fire2  = animparseline(animfile);
 393                                 self.anim_idle   = animparseline(animfile);
 394                                 self.anim_reload = animparseline(animfile);
 395                                 fclose(animfile);
 396                                 if (animparseerror)
 397                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 398                         }
 399
 400                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 401                         // if we don't, this is a "real" animated model
 402                         if(gettagindex(self, "weapon"))
 403                         {
 404                                 if (!self.weaponentity)
 405                                         self.weaponentity = spawn();
 406                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 407                                 setattachment(self.weaponentity, self, "weapon");
 408                         }
 409                         else if(gettagindex(self, "tag_weapon"))
 410                         {
 411                                 if (!self.weaponentity)
 412                                         self.weaponentity = spawn();
 413                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 414                                 setattachment(self.weaponentity, self, "tag_weapon");
 415                         }
 416                         else
 417                         {
 418                                 if(self.weaponentity)
 419                                         remove(self.weaponentity);
 420                                 self.weaponentity = world;
 421                         }
 422
 423                         setorigin(self,'0 0 0');
 424                         self.angles = '0 0 0';
 425                         self.frame = 0;
 426                         self.viewmodelforclient = world;
 427
 428                         float idx;
 429
 430                         if(v_shot_idx) // v_ model attached to invisible h_ model
 431                         {
 432                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 433                         }
 434                         else
 435                         {
 436                                 idx = gettagindex(self, "shot");
 437                                 if(!idx)
 438                                         idx = gettagindex(self, "tag_shot");
 439                                 if(idx)
 440                                         self.movedir = gettaginfo(self, idx);
 441                                 else
 442                                 {
 443                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 444                                         self.movedir = '0 0 0';
 445                                 }
 446                         }
 447
 448                         if(self.weaponentity) // v_ model attached to invisible h_ model
 449                         {
 450                                 idx = gettagindex(self.weaponentity, "shell");
 451                                 if(!idx)
 452                                         idx = gettagindex(self.weaponentity, "tag_shell");
 453                                 if(idx)
 454                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 455                         }
 456                         else
 457                                 idx = 0;
 458                         if(!idx)
 459                         {
 460                                 idx = gettagindex(self, "shell");
 461                                 if(!idx)
 462                                         idx = gettagindex(self, "tag_shell");
 463                                 if(idx)
 464                                         self.spawnorigin = gettaginfo(self, idx);
 465                                 else
 466                                 {
 467                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 468                                         self.spawnorigin = self.movedir;
 469                                 }
 470                         }
 471
 472                         if(v_shot_idx)
 473                         {
 474                                 self.oldorigin = '0 0 0'; // use regular attachment
 475                         }
 476                         else
 477                         {
 478                                 if(self.weaponentity)
 479                                 {
 480                                         idx = gettagindex(self, "weapon");
 481                                         if(!idx)
 482                                                 idx = gettagindex(self, "tag_weapon");
 483                                 }
 484                                 else
 485                                 {
 486                                         idx = gettagindex(self, "handle");
 487                                         if(!idx)
 488                                                 idx = gettagindex(self, "tag_handle");
 489                                 }
 490                                 if(idx)
 491                                 {
 492                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 493                                 }
 494                                 else
 495                                 {
 496                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 497                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 498                                 }
 499                         }
 500
 501                         self.viewmodelforclient = self.owner;
 502                 }
 503         }
 504         else
 505         {
 506                 self.model = "";
 507                 if(self.weaponentity)
 508                         remove(self.weaponentity);
 509                 self.weaponentity = world;
 510                 self.movedir = '0 0 0';
 511                 self.spawnorigin = '0 0 0';
 512                 self.oldorigin = '0 0 0';
 513                 self.anim_fire1  = '0 1 0.01';
 514                 self.anim_fire2  = '0 1 0.01';
 515                 self.anim_idle   = '0 1 0.01';
 516                 self.anim_reload = '0 1 0.01';
 517         }
 518
 519         self.view_ofs = '0 0 0';
 520
 521         if(self.movedir_x >= 0)
 522         {
 523                 vector v0;
 524                 v0 = self.movedir;
 525                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 526                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 527         }
 528         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 529         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 530
 531         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 532
 533         // check if an instant weapon switch occurred
 534         if (qcweaponanimation)
 535         {
 536                 if (self.state == WS_READY)
 537                 {
 538                         self.angles = '0 0 0';
 539                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 540                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 541                 }
 542         }
 543         else
 544                 setorigin(self, self.view_ofs);
 545         // reset animstate now
 546         self.wframe = WFRAME_IDLE;
 547         self.weapon_morph0time = 0;
 548         self.weapon_morph1time = 0;
 549         self.weapon_morph2time = 0;
 550         self.weapon_morph3time = 0;
 551         self.weapon_morph4time = 0;
 552         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 553 }
 554
 555 vector CL_Weapon_GetShotOrg(float wpn)
 556 {
 557         entity wi, oldself;
 558         vector ret;
 559         wi = get_weaponinfo(wpn);
 560         oldself = self;
 561         self = spawn();
 562         CL_WeaponEntity_SetModel(wi.mdl);
 563         ret = self.movedir;
 564         CL_WeaponEntity_SetModel("");
 565         remove(self);
 566         self = oldself;
 567         return ret;
 568 }
 569
 570 void CL_Weaponentity_Think()
 571 {
 572         float tb;
 573         self.nextthink = time;
 574         if (intermission_running)
 575                 self.frame = self.anim_idle_x;
 576         if (self.owner.weaponentity != self)
 577         {
 578                 if (self.weaponentity)
 579                         remove(self.weaponentity);
 580                 remove(self);
 581                 return;
 582         }
 583         if (self.owner.deadflag != DEAD_NO)
 584         {
 585                 self.model = "";
 586                 if (self.weaponentity)
 587                         self.weaponentity.model = "";
 588                 return;
 589         }
 590         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 591         {
 592                 self.cnt = self.owner.weapon;
 593                 self.dmg = self.owner.modelindex;
 594                 self.deadflag = self.owner.deadflag;
 595
 596                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 597         }
 598
 599         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 600         self.effects = self.owner.effects & EFMASK_CHEAP;
 601         self.effects &~= EF_LOWPRECISION;
 602         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 603         self.effects &~= EF_TELEPORT_BIT;
 604         self.effects &~= EF_RESTARTANIM_BIT;
 605         self.effects |= tb;
 606
 607         if(self.owner.alpha == default_player_alpha)
 608                 self.alpha = default_weapon_alpha;
 609         else if(self.owner.alpha != 0)
 610                 self.alpha = self.owner.alpha;
 611         else
 612                 self.alpha = 1;
 613
 614         self.glowmod = self.owner.weaponentity_glowmod;
 615         self.colormap = self.owner.colormap;
 616         if (self.weaponentity)
 617         {
 618                 self.weaponentity.effects = self.effects;
 619                 self.weaponentity.alpha = self.alpha;
 620                 self.weaponentity.colormap = self.colormap;
 621                 self.weaponentity.glowmod = self.glowmod;
 622         }
 623
 624         self.angles = '0 0 0';
 625         local float f;
 626         f = 0;
 627         if (self.state == WS_RAISE && !intermission_running)
 628         {
 629                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 630                 self.angles_x = -90 * f * f;
 631                 if (qcweaponanimation)
 632                 {
 633                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 634                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 635                 }
 636         }
 637         else if (self.state == WS_DROP && !intermission_running)
 638         {
 639                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 640                 self.angles_x = -90 * f * f;
 641                 if (qcweaponanimation)
 642                 {
 643                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 644                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 645                 }
 646         }
 647         else if (self.state == WS_CLEAR)
 648         {
 649                 f = 1;
 650                 self.angles_x = -90 * f * f;
 651                 if (qcweaponanimation)
 652                 {
 653                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 654                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 655                 }
 656         }
 657         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 658         {
 659                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 660                 f = 1 - pow(1 - f, 3);
 661                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 662                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 663         }
 664         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 665         {
 666                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 667                 f = 1 - pow(1 - f, 3);
 668                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 669                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 670         }
 671         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 672         {
 673                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 674                 f = 1 - pow(1 - f, 3);
 675                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 676                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 677         }
 678         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 679         {
 680                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 681                 f = 1 - pow(1 - f, 3);
 682                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 683                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 684         }
 685         else if (qcweaponanimation)
 686         {
 687                 // begin a new idle morph
 688                 self.owner.weapon_morph0time   = time;
 689                 self.owner.weapon_morph0angles = self.angles;
 690                 self.owner.weapon_morph0origin = self.origin;
 691
 692                 float r;
 693                 float t;
 694
 695                 r = random();
 696                 if (r < 0.1)
 697                 {
 698                         // turn gun to the left to look at it
 699                         t = 2;
 700                         self.owner.weapon_morph1time   = time + t * 0.2;
 701                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 702                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 703                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 704
 705                         self.owner.weapon_morph2time   = time + t * 0.6;
 706                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 707                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 708                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 709
 710                         self.owner.weapon_morph3time   = time + t;
 711                         self.owner.weapon_morph3angles = '0 0 0';
 712                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 713                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 714                 }
 715                 else if (r < 0.2)
 716                 {
 717                         // raise the gun a bit
 718                         t = 2;
 719                         self.owner.weapon_morph1time   = time + t * 0.2;
 720                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 721                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 722                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 723
 724                         self.owner.weapon_morph2time   = time + t * 0.5;
 725                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 726                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 727                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 728
 729                         self.owner.weapon_morph3time   = time + t;
 730                         self.owner.weapon_morph3angles = '0 0 0';
 731                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 732                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 733                 }
 734                 else if (r < 0.3)
 735                 {
 736                         // tweak it a bit
 737                         t = 5;
 738                         self.owner.weapon_morph1time   = time + t * 0.3;
 739                         self.owner.weapon_morph1angles = randomvec() * 6;
 740                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 741                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 742
 743                         self.owner.weapon_morph2time   = time + t * 0.7;
 744                         self.owner.weapon_morph2angles = randomvec() * 6;
 745                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 746                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 747
 748                         self.owner.weapon_morph3time   = time + t;
 749                         self.owner.weapon_morph3angles = '0 0 0';
 750                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 751                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 752                 }
 753                 else
 754                 {
 755                         // hold it mostly steady
 756                         t = random() * 6 + 4;
 757                         self.owner.weapon_morph1time   = time + t * 0.2;
 758                         self.owner.weapon_morph1angles = randomvec() * 1;
 759                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 760                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 761
 762                         self.owner.weapon_morph2time   = time + t * 0.5;
 763                         self.owner.weapon_morph2angles = randomvec() * 1;
 764                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 765                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 766
 767                         self.owner.weapon_morph3time   = time + t * 0.7;
 768                         self.owner.weapon_morph3angles = randomvec() * 1;
 769                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 770                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 771                 }
 772
 773                 self.owner.weapon_morph4time   = time + t;
 774                 self.owner.weapon_morph4angles = '0 0 0';
 775                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 776                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 777
 778         }
 779 };
 780
 781 void CL_ExteriorWeaponentity_Think()
 782 {
 783         float tag_found;
 784         vector ang;
 785         self.nextthink = time;
 786         if (self.owner.exteriorweaponentity != self)
 787         {
 788                 remove(self);
 789                 return;
 790         }
 791         if (self.owner.deadflag != DEAD_NO)
 792         {
 793                 self.model = "";
 794                 return;
 795         }
 796         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 797         {
 798                 self.cnt = self.owner.weapon;
 799                 self.dmg = self.owner.modelindex;
 800                 self.deadflag = self.owner.deadflag;
 801                 if (self.owner.weaponname != "")
 802                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 803                 else
 804                         self.model = "";
 805
 806                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 807                 {
 808                         self.tag_index = tag_found;
 809                         self.tag_entity = self.owner;
 810                 }
 811                 else
 812                         setattachment(self, self.owner, "bip01 r hand");
 813
 814                 // if that didn't find a tag, hide the exterior weapon model
 815                 if (!self.tag_index)
 816                         self.model = "";
 817         }
 818         self.effects = self.owner.effects;
 819         if(sv_pitch_min == sv_pitch_max)
 820                 self.effects |= EF_LOWPRECISION;
 821         else
 822                 self.effects &~= EF_LOWPRECISION;
 823         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 824         if(self.owner.alpha == default_player_alpha)
 825                 self.alpha = default_weapon_alpha;
 826         else if(self.owner.alpha != 0)
 827                 self.alpha = self.owner.alpha;
 828         else
 829                 self.alpha = 1;
 830
 831         if (!intermission_running)
 832         {
 833                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 834                 ang_y = 0;
 835                 ang_z = 0;
 836
 837                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 838                 {
 839                         ang_y = self.owner.v_angle_y;
 840                         makevectors(ang);
 841                         var vector v = v_forward;
 842                         var float t = self.tag_entity.frame1time;
 843                         var float f = self.tag_entity.frame;
 844                         self.tag_entity.frame1time = time;
 845                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 846                         gettaginfo(self.tag_entity, self.tag_index);
 847                         self.tag_entity.frame1time = t;
 848                         self.tag_entity.frame = f;
 849                         // untransform v according to this coordinate space
 850                         vector w;
 851                         w_x = v_forward * v;
 852                         w_y = -v_right * v;
 853                         w_z = v_up * v;
 854                         self.angles = vectoangles(w);
 855                 }
 856                 else
 857                 {
 858                         ang_x = -/* don't ask */ang_x;
 859                         self.angles = ang;
 860                 }
 861         }
 862
 863         self.glowmod = self.owner.weaponentity_glowmod;
 864         self.colormap = self.owner.colormap;
 865 };
 866
 867 // spawning weaponentity for client
 868 void CL_SpawnWeaponentity()
 869 {
 870         self.weaponentity = spawn();
 871         self.weaponentity.classname = "weaponentity";
 872         self.weaponentity.solid = SOLID_NOT;
 873         self.weaponentity.owner = self;
 874         setmodel(self.weaponentity, ""); // precision set when changed
 875         setorigin(self.weaponentity, '0 0 0');
 876         self.weaponentity.angles = '0 0 0';
 877         self.weaponentity.viewmodelforclient = self;
 878         self.weaponentity.flags = 0;
 879         self.weaponentity.think = CL_Weaponentity_Think;
 880         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 881         self.weaponentity.nextthink = time;
 882
 883         self.exteriorweaponentity = spawn();
 884         self.exteriorweaponentity.classname = "exteriorweaponentity";
 885         self.exteriorweaponentity.solid = SOLID_NOT;
 886         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 887         self.exteriorweaponentity.owner = self;
 888         setorigin(self.exteriorweaponentity, '0 0 0');
 889         self.exteriorweaponentity.angles = '0 0 0';
 890         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 891         self.exteriorweaponentity.nextthink = time;
 892 };
 893
 894 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 895 {
 896         msg_entity = e;
 897         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 898         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 899         WriteByte(MSG_ONE, wpn);
 900         WriteString(MSG_ONE, wpnname);
 901         WriteByte(MSG_ONE, type);
 902 }
 903
 904 .float hasweapon_complain_spam;
 905
 906 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 907 {
 908         local float weaponbit, f;
 909         local entity oldself;
 910
 911         if(time < self.hasweapon_complain_spam)
 912                 complain = 0;
 913         if(complain)
 914                 self.hasweapon_complain_spam = time + 0.2;
 915
 916         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 917         {
 918                 if (complain)
 919                         sprint(self, "Invalid weapon\n");
 920                 return FALSE;
 921         }
 922         weaponbit = W_WeaponBit(wpn);
 923         if (cl.weapons & weaponbit)
 924         {
 925                 if (andammo)
 926                 {
 927                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 928                         {
 929                                 f = 1;
 930                         }
 931                         else
 932                         {
 933                                 oldself = self;
 934                                 self = cl;
 935                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 936                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 937
 938                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 939                                 local entity mine;
 940                                 if(wpn == WEP_MINE_LAYER)
 941                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 942                                         f = 1;
 943
 944                                 self = oldself;
 945                         }
 946                         if (!f)
 947                         {
 948                                 if (complain)
 949                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 950                                 {
 951                                         play2(cl, "weapons/unavailable.wav");
 952                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 953                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 954                                 }
 955                                 return FALSE;
 956                         }
 957                 }
 958                 return TRUE;
 959         }
 960         if (complain)
 961         {
 962                 // DRESK - 3/16/07
 963                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 964                 if(weaponsInMap & weaponbit)
 965                 {
 966                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 967                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 968
 969                         if(autocvar_g_showweaponspawns)
 970                         {
 971                                 entity e;
 972                                 string s;
 973
 974                                 e = get_weaponinfo(wpn);
 975                                 s = e.model2;
 976
 977                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 978                                 {
 979                                         if(e.classname == "droppedweapon")
 980                                                 continue;
 981                                         if not(e.flags & FL_ITEM)
 982                                                 continue;
 983                                         WaypointSprite_Spawn(
 984                                                 s,
 985                                                 1, 0,
 986                                                 world, e.origin,
 987                                                 self, 0,
 988                                                 world, enemy,
 989                                                 0,
 990                                                 RADARICON_NONE, '0 0 0'
 991                                         );
 992                                 }
 993                         }
 994                 }
 995                 else
 996                 {
 997                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 998                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 999                 }
1000
1001                 play2(cl, "weapons/unavailable.wav");
1002         }
1003         return FALSE;
1004 };
1005
1006 // Weapon subs
1007 void w_clear()
1008 {
1009         if (self.weapon != -1)
1010                 self.weapon = 0;
1011         if (self.weaponentity)
1012         {
1013                 self.weaponentity.state = WS_CLEAR;
1014                 self.weaponentity.effects = 0;
1015         }
1016 };
1017
1018 void w_ready()
1019 {
1020         if (self.weaponentity)
1021                 self.weaponentity.state = WS_READY;
1022         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1023 };
1024
1025 // Setup weapon for client (after this raise frame will be launched)
1026 void weapon_setup(float windex)
1027 {
1028         entity e;
1029         qcweaponanimation = autocvar_sv_qcweaponanimation;
1030         e = get_weaponinfo(windex);
1031         self.items &~= IT_AMMO;
1032         self.items = self.items | e.items;
1033
1034         // the two weapon entities will notice this has changed and update their models
1035         self.weapon = windex;
1036         self.weaponname = e.mdl;
1037         self.bulletcounter = 0;
1038 };
1039
1040 // perform weapon to attack (weaponstate and attack_finished check is here)
1041 void W_SwitchToOtherWeapon(entity pl)
1042 {
1043         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1044         float w, ww;
1045         w = W_WeaponBit(pl.weapon);
1046         pl.weapons &~= w;
1047         ww = w_getbestweapon(pl);
1048         pl.weapons |= w;
1049         if(ww)
1050                 W_SwitchWeapon_Force(pl, ww);
1051 }
1052 .float prevdryfire;
1053 float weapon_prepareattack_checkammo(float secondary)
1054 {
1055         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1056         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1057         {
1058                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1059                 local entity mine;
1060                 if(self.weapon == WEP_MINE_LAYER)
1061                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1062                         return FALSE;
1063
1064                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1065                 {
1066                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1067                         self.prevdryfire = time;
1068                 }
1069
1070                 W_SwitchToOtherWeapon(self);
1071                 return FALSE;
1072         }
1073         return TRUE;
1074 }
1075 .float race_penalty;
1076 float weapon_prepareattack_check(float secondary, float attacktime)
1077 {
1078         if(!weapon_prepareattack_checkammo(secondary))
1079                 return FALSE;
1080
1081         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1082         //if all players readied up and the countdown is running
1083         if(time < game_starttime || time < self.race_penalty) {
1084                 return FALSE;
1085         }
1086
1087         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1088                 return FALSE;
1089
1090         // do not even think about shooting if switching
1091         if(self.switchweapon != self.weapon)
1092                 return FALSE;
1093
1094         if(attacktime >= 0)
1095         {
1096                 // don't fire if previous attack is not finished
1097                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1098                         return FALSE;
1099                 // don't fire while changing weapon
1100                 if (self.weaponentity.state != WS_READY)
1101                         return FALSE;
1102         }
1103
1104         return TRUE;
1105 }
1106 float weapon_prepareattack_do(float secondary, float attacktime)
1107 {
1108         self.weaponentity.state = WS_INUSE;
1109
1110         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1111
1112         // if the weapon hasn't been firing continuously, reset the timer
1113         if(attacktime >= 0)
1114         {
1115                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1116                 {
1117                         ATTACK_FINISHED(self) = time;
1118                         //dprint("resetting attack finished to ", ftos(time), "\n");
1119                 }
1120                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1121         }
1122         self.bulletcounter += 1;
1123         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1124         return TRUE;
1125 }
1126 float weapon_prepareattack(float secondary, float attacktime)
1127 {
1128         if(weapon_prepareattack_check(secondary, attacktime))
1129         {
1130                 weapon_prepareattack_do(secondary, attacktime);
1131                 return TRUE;
1132         }
1133         else
1134                 return FALSE;
1135 }
1136
1137 void weapon_thinkf(float fr, float t, void() func)
1138 {
1139         vector a;
1140         vector of, or, ou;
1141         float restartanim;
1142
1143         if(fr == WFRAME_DONTCHANGE)
1144         {
1145                 fr = self.weaponentity.wframe;
1146                 restartanim = FALSE;
1147         }
1148         else if (fr == WFRAME_IDLE)
1149                 restartanim = FALSE;
1150         else
1151                 restartanim = TRUE;
1152
1153         of = v_forward;
1154         or = v_right;
1155         ou = v_up;
1156
1157         if (self.weaponentity)
1158         {
1159                 self.weaponentity.wframe = fr;
1160                 if (qcweaponanimation)
1161                 {
1162                         if (fr != WFRAME_IDLE)
1163                         {
1164                                 self.weapon_morph0time = time;
1165                                 self.weapon_morph0angles = self.weaponentity.angles;
1166                                 self.weapon_morph0origin = self.weaponentity.origin;
1167
1168                                 self.weapon_morph1angles = '0 0 0';
1169                                 self.weapon_morph1time = time + t;
1170                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1171                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1172
1173                                 self.weapon_morph2angles = '0 0 0';
1174                                 self.weapon_morph2time = time + t;
1175                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1176                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1177
1178                                 self.weapon_morph3angles = '0 0 0';
1179                                 self.weapon_morph3time = time + t;
1180                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1181                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1182
1183                                 self.weapon_morph4angles = '0 0 0';
1184                                 self.weapon_morph4time = time + t;
1185                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1186                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1187
1188                                 if (fr == WFRAME_FIRE1)
1189                                 {
1190                                         self.weapon_morph1angles = '5 0 0';
1191                                         self.weapon_morph1time = time + t * 0.1;
1192                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1193                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1194                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1195                                 }
1196                                 else if (fr == WFRAME_FIRE2)
1197                                 {
1198                                         self.weapon_morph1angles = '10 0 0';
1199                                         self.weapon_morph1time = time + t * 0.1;
1200                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1201                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1202                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1203                                 }
1204                                 else if (fr == WFRAME_RELOAD)
1205                                 {
1206                                         self.weapon_morph1time = time + t * 0.05;
1207                                         self.weapon_morph1angles = '-10 40 0';
1208                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1209                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1210
1211                                         self.weapon_morph2time = time + t * 0.15;
1212                                         self.weapon_morph2angles = '-10 40 5';
1213                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1214                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1215
1216                                         self.weapon_morph3time = time + t * 0.25;
1217                                         self.weapon_morph3angles = '-10 40 0';
1218                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1219                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1220                                 }
1221                         }
1222                 }
1223                 else
1224                 {
1225                         if (fr == WFRAME_IDLE)
1226                                 a = self.weaponentity.anim_idle;
1227                         else if (fr == WFRAME_FIRE1)
1228                                 a = self.weaponentity.anim_fire1;
1229                         else if (fr == WFRAME_FIRE2)
1230                                 a = self.weaponentity.anim_fire2;
1231                         else if (fr == WFRAME_RELOAD)
1232                                 a = self.weaponentity.anim_reload;
1233                         a_z *= g_weaponratefactor;
1234                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1235                 }
1236         }
1237
1238         v_forward = of;
1239         v_right = or;
1240         v_up = ou;
1241
1242         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1243         {
1244                 backtrace("Tried to override initial weapon think function - should this really happen?");
1245         }
1246
1247         t *= W_WeaponRateFactor();
1248
1249         // VorteX: haste can be added here
1250         if (self.weapon_think == w_ready)
1251         {
1252                 self.weapon_nextthink = time;
1253                 //dprint("started firing at ", ftos(time), "\n");
1254         }
1255         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1256         {
1257                 self.weapon_nextthink = time;
1258                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1259         }
1260         self.weapon_nextthink = self.weapon_nextthink + t;
1261         self.weapon_think = func;
1262         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1263
1264         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1265         //anim = self.anim_shoot;
1266         if (restartanim)
1267         if (t)
1268         if (!self.crouch) // shoot anim stands up, this looks bad
1269         {
1270                 vector anim;
1271                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1272                 {
1273                         anim = self.anim_melee;
1274                         anim_z = anim_y / (t + sys_frametime);
1275                         setanim(self, anim, FALSE, TRUE, TRUE);
1276                 }
1277                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1278                 {
1279                         anim = self.anim_shoot;
1280                         anim_z = anim_y / (t + sys_frametime);
1281                         setanim(self, anim, FALSE, TRUE, TRUE);
1282                 }
1283         }
1284 };
1285
1286 void weapon_boblayer1(float spd, vector org)
1287 {
1288         // VorteX: haste can be added here
1289 };
1290
1291 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1292 {
1293         vector mdirection;
1294         float mspeed;
1295         float outspeed;
1296         float nstyle;
1297         vector outvelocity;
1298
1299         mvelocity = mvelocity * g_weaponspeedfactor;
1300
1301         mdirection = normalize(mvelocity);
1302         mspeed = vlen(mvelocity);
1303
1304         nstyle = autocvar_g_projectiles_newton_style;
1305         if(nstyle == 0 || forceAbsolute)
1306         {
1307                 // absolute velocity
1308                 outvelocity = mvelocity;
1309         }
1310         else if(nstyle == 1)
1311         {
1312                 // true Newtonian projectiles
1313                 outvelocity = pvelocity + mvelocity;
1314         }
1315         else if(nstyle == 2)
1316         {
1317                 // true Newtonian projectiles with automatic aim adjustment
1318                 //
1319                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1320                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1321                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1322                 // PLUS SIGN!
1323                 // not defined?
1324                 // then...
1325                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1326                 // velocity without mdirection component > mspeed
1327                 // fire at smallest possible mspeed that works?
1328                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1329
1330                 vector solution;
1331                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1332                 if(solution_z)
1333                         outspeed = solution_y; // the larger one
1334                 else
1335                 {
1336                         //outspeed = 0; // slowest possible shot
1337                         outspeed = solution_x; // the real part (that is, the average!)
1338                         //dprint("impossible shot, adjusting\n");
1339                 }
1340
1341                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1342                 outvelocity = mdirection * outspeed;
1343         }
1344         else if(nstyle == 3)
1345         {
1346                 // pseudo-Newtonian:
1347                 outspeed = mspeed + mdirection * pvelocity;
1348                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1349                 outvelocity = mdirection * outspeed;
1350         }
1351         else if(nstyle == 4)
1352         {
1353                 // tZorkian:
1354                 outspeed = mspeed + vlen(pvelocity);
1355                 outvelocity = mdirection * outspeed;
1356         }
1357         else
1358                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1359
1360         return outvelocity;
1361 }
1362
1363 void W_AttachToShotorg(entity flash, vector offset)
1364 {
1365         entity xflash;
1366         flash.owner = self;
1367         flash.angles_z = random() * 360;
1368         if(qcweaponanimation)
1369         {
1370                 setorigin(flash, w_shotorg + w_shotdir * 50);
1371                 flash.angles = vectoangles(w_shotdir);
1372                 flash.angles_z = random() * 360;
1373         }
1374         else
1375         {
1376                 if(gettagindex(self.weaponentity, "shot"))
1377                         setattachment(flash, self.weaponentity, "shot");
1378                 else
1379                         setattachment(flash, self.weaponentity, "tag_shot");
1380                 setorigin(flash, offset);
1381
1382                 xflash = spawn();
1383                 copyentity(flash, xflash);
1384
1385                 flash.viewmodelforclient = self;
1386
1387                 if(self.weaponentity.oldorigin_x > 0)
1388                 {
1389                         setattachment(xflash, self.exteriorweaponentity, "");
1390                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1391                 }
1392                 else
1393                 {
1394                         if(gettagindex(self.exteriorweaponentity, "shot"))
1395                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1396                         else
1397                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1398                         setorigin(xflash, offset);
1399                 }
1400         }
1401 }
1402
1403 vector cliptoplane(vector v, vector p)
1404 {
1405         return v - (v * p) * p;
1406 }
1407
1408 vector solve_cubic_pq(float p, float q)
1409 {
1410         float D, u, v, a;
1411         D = q*q/4.0 + p*p*p/27.0;
1412         if(D < 0)
1413         {
1414                 // irreducibilis
1415                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1416                 u = sqrt(-4.0/3.0 * p);
1417                 // a in range 0..pi/3
1418                 // cos(a)
1419                 // cos(a + 2pi/3)
1420                 // cos(a + 4pi/3)
1421                 return
1422                         u *
1423                         (
1424                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1425                                 +
1426                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1427                                 +
1428                                 '0 0 1' * cos(a)
1429                         );
1430         }
1431         else if(D == 0)
1432         {
1433                 // simple
1434                 if(p == 0)
1435                         return '0 0 0';
1436                 u = 3*q/p;
1437                 v = -u/2;
1438                 if(u >= v)
1439                         return '1 1 0' * v + '0 0 1' * u;
1440                 else
1441                         return '0 1 1' * v + '1 0 0' * u;
1442         }
1443         else
1444         {
1445                 // cardano
1446                 u = cbrt(-q/2.0 + sqrt(D));
1447                 v = cbrt(-q/2.0 - sqrt(D));
1448                 return '1 1 1' * (u + v);
1449         }
1450 }
1451 vector solve_cubic_abcd(float a, float b, float c, float d)
1452 {
1453         // y = 3*a*x + b
1454         // x = (y - b) / 3a
1455         float p, q;
1456         vector v;
1457         p = (9*a*c - 3*b*b);
1458         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1459         v = solve_cubic_pq(p, q);
1460         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1461         if(a < 0)
1462                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1463         return v;
1464 }
1465
1466 vector findperpendicular(vector v)
1467 {
1468         vector p;
1469         p_x = v_z;
1470         p_y = -v_x;
1471         p_z = v_y;
1472         return normalize(cliptoplane(p, v));
1473 }
1474
1475 vector W_CalculateProjectileSpread(vector forward, float spread)
1476 {
1477         float sigma;
1478         vector v1, v2;
1479         float dx, dy, r;
1480         float sstyle;
1481         spread *= g_weaponspreadfactor;
1482         if(spread <= 0)
1483                 return forward;
1484         sstyle = autocvar_g_projectiles_spread_style;
1485
1486         if(sstyle == 0)
1487         {
1488                 // this is the baseline for the spread value!
1489                 // standard deviation: sqrt(2/5)
1490                 // density function: sqrt(1-r^2)
1491                 return forward + randomvec() * spread;
1492         }
1493         else if(sstyle == 1)
1494         {
1495                 // same thing, basically
1496                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1497         }
1498         else if(sstyle == 2)
1499         {
1500                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1501                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1502                 v1 = findperpendicular(forward);
1503                 v2 = cross(forward, v1);
1504                 // random point on unit circle
1505                 dx = random() * 2 * M_PI;
1506                 dy = sin(dx);
1507                 dx = cos(dx);
1508                 // radius in our dist function
1509                 r = random();
1510                 r = sqrt(r);
1511                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1512         }
1513         else if(sstyle == 3) // gauss 3d
1514         {
1515                 sigma = spread * 0.44721359549996; // match baseline stddev
1516                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1517                 v1 = forward;
1518                 v1_x += gsl_ran_gaussian(sigma);
1519                 v1_y += gsl_ran_gaussian(sigma);
1520                 v1_z += gsl_ran_gaussian(sigma);
1521                 return v1;
1522         }
1523         else if(sstyle == 4) // gauss 2d
1524         {
1525                 sigma = spread * 0.44721359549996; // match baseline stddev
1526                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1527                 v1_x = gsl_ran_gaussian(sigma);
1528                 v1_y = gsl_ran_gaussian(sigma);
1529                 v1_z = gsl_ran_gaussian(sigma);
1530                 return normalize(forward + cliptoplane(v1, forward));
1531         }
1532         else if(sstyle == 5) // 1-r
1533         {
1534                 sigma = spread * 1.154700538379252; // match baseline stddev
1535                 v1 = findperpendicular(forward);
1536                 v2 = cross(forward, v1);
1537                 // random point on unit circle
1538                 dx = random() * 2 * M_PI;
1539                 dy = sin(dx);
1540                 dx = cos(dx);
1541                 // radius in our dist function
1542                 r = random();
1543                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1544                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1545         }
1546         else if(sstyle == 6) // 1-r^2
1547         {
1548                 sigma = spread * 1.095445115010332; // match baseline stddev
1549                 v1 = findperpendicular(forward);
1550                 v2 = cross(forward, v1);
1551                 // random point on unit circle
1552                 dx = random() * 2 * M_PI;
1553                 dy = sin(dx);
1554                 dx = cos(dx);
1555                 // radius in our dist function
1556                 r = random();
1557                 r = sqrt(1 - r);
1558                 r = sqrt(1 - r);
1559                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1560         }
1561         else if(sstyle == 7) // (1-r) (2-r)
1562         {
1563                 sigma = spread * 1.224744871391589; // match baseline stddev
1564                 v1 = findperpendicular(forward);
1565                 v2 = cross(forward, v1);
1566                 // random point on unit circle
1567                 dx = random() * 2 * M_PI;
1568                 dy = sin(dx);
1569                 dx = cos(dx);
1570                 // radius in our dist function
1571                 r = random();
1572                 r = 1 - sqrt(r);
1573                 r = 1 - sqrt(r);
1574                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1575         }
1576         else
1577                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1578         return '0 0 0';
1579         /*
1580          * how to derive falloff functions:
1581          * rho(r) := (2-r) * (1-r);
1582          * a : 0;
1583          * b : 1;
1584          * rhor(r) := r * rho(r);
1585          * cr(t) := integrate(rhor(r), r, a, t);
1586          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1587          * variance : scr(b) / cr(b);
1588          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1589          * sqrt(0.4 / variance), numer;
1590          */
1591 }
1592
1593 #if 0
1594 float mspercallsum;
1595 float mspercallsstyle;
1596 float mspercallcount;
1597 #endif
1598 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1599 {
1600         if(missile.owner == world)
1601                 error("Unowned missile");
1602
1603         dir = dir + upDir * (pUpSpeed / pSpeed);
1604         dir_z += pZSpeed / pSpeed;
1605         pSpeed *= vlen(dir);
1606         dir = normalize(dir);
1607
1608 #if 0
1609         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1610         {
1611                 mspercallsum = mspercallcount = 0;
1612                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1613         }
1614         mspercallsum -= gettime(GETTIME_HIRES);
1615 #endif
1616         dir = W_CalculateProjectileSpread(dir, spread);
1617 #if 0
1618         mspercallsum += gettime(GETTIME_HIRES);
1619         mspercallcount += 1;
1620         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1621 #endif
1622
1623         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1624 }
1625
1626 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1627 {
1628         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1629 }
1630
1631 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1632 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1633
1634 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1635 {
1636         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1637                 return;
1638
1639         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1640         if(ammo_reload)
1641         {
1642                 self.clip_load -= ammo_use;
1643                 self.weapon_load[self.weapon] = self.clip_load;
1644         }
1645         else
1646                 self.(self.current_ammo) -= ammo_use;
1647 }
1648
1649 // weapon reloading code
1650
1651 .float reload_ammo_amount, reload_ammo_min, reload_time;
1652 .float reload_complain;
1653 .string reload_sound;
1654
1655 void W_ReloadedAndReady()
1656 {
1657         // finish the reloading process, and do the ammo transfer
1658
1659         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1660
1661         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1662         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1663                 self.clip_load = self.reload_ammo_amount;
1664         else
1665         {
1666                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1667                 {
1668                         self.clip_load += 1;
1669                         self.(self.current_ammo) -= 1;
1670                 }
1671         }
1672         self.weapon_load[self.weapon] = self.clip_load;
1673
1674         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1675         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1676         // so your weapon is disabled for a few seconds without reason
1677
1678         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1679
1680         w_ready();
1681 }
1682
1683 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1684 {
1685         // set global values to work with
1686
1687         self.reload_ammo_min = sent_ammo_min;
1688         self.reload_ammo_amount = sent_ammo_amount;
1689         self.reload_time = sent_time;
1690         self.reload_sound = sent_sound;
1691
1692         // check if we meet the necessary conditions to reload
1693
1694         entity e;
1695         e = get_weaponinfo(self.weapon);
1696
1697         // don't reload weapons that don't have the RELOADABLE flag
1698         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1699         {
1700                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1701                 return;
1702         }
1703
1704         // return if reloading is disabled for this weapon
1705         if(!self.reload_ammo_amount)
1706                 return;
1707
1708         // our weapon is fully loaded, no need to reload
1709         if (self.clip_load >= self.reload_ammo_amount)
1710                 return;
1711
1712         // no ammo, so nothing to load
1713         if(!self.(self.current_ammo) && self.reload_ammo_min)
1714         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1715         {
1716                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1717                 {
1718                         play2(self, "weapons/unavailable.wav");
1719                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1720                         self.reload_complain = time + 1;
1721                 }
1722                 // switch away if the amount of ammo is not enough to keep using this weapon
1723                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1724                 {
1725                         self.clip_load = -1; // reload later
1726                         W_SwitchToOtherWeapon(self);
1727                 }
1728                 return;
1729         }
1730
1731         if (self.weaponentity)
1732         {
1733                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1734                         return;
1735
1736                 // allow switching away while reloading, but this will cause a new reload!
1737                 self.weaponentity.state = WS_READY;
1738         }
1739
1740         // now begin the reloading process
1741
1742         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1743
1744         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1745         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1746         // so your weapon is disabled for a few seconds without reason
1747
1748         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1749
1750         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1751
1752         if(self.clip_load < 0)
1753                 self.clip_load = 0;
1754         self.old_clip_load = self.clip_load;
1755         self.clip_load = self.weapon_load[self.weapon] = -1;
1756 }