qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  73         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  74         {
  75                 thisv = targ.origin;
  76                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  77                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  78                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  79                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  80                 if(i || j || k)
  81                 {
  82                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  83                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  84                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  85                 }
  86                 else
  87                 {
  88                         // first run
  89                         mi = ma = thisv;
  90                 }
  91         }
  92
  93         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  94         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  95         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  96         ret_z = thisv_z - myv_z;
  97         return ret;
  98 }
  99
 100 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 101 {
 102         vector hitplot;
 103         vector org;
 104         float lag;
 105
 106         if(player.hitplotfh >= 0)
 107         {
 108                 lag = ANTILAG_LATENCY(player);
 109                 if(lag < 0.001)
 110                         lag = 0;
 111                 if(clienttype(player) != CLIENTTYPE_REAL)
 112                         lag = 0; // only antilag for clients
 113
 114                 org = player.origin + player.view_ofs;
 115                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 116                 if(trace_ent.flags & FL_CLIENT)
 117                 {
 118                         antilag_takeback(trace_ent, time - lag);
 119                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 120                         antilag_restore(trace_ent);
 121                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 122                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 123                 }
 124         }
 125 }
 126
 127 vector w_shotorg;
 128 vector w_shotdir;
 129 vector w_shotend;
 130
 131 .float prevstrengthsound;
 132 .float prevstrengthsoundattempt;
 133 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 134 {
 135                 if((!g_minstagib)
 136                         && (player.items & IT_STRENGTH)
 137                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 138                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 139                 {
 140                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 141                         player.prevstrengthsound = time;
 142                 }
 143                 player.prevstrengthsoundattempt = time;
 144 }
 145
 146 // this function calculates w_shotorg and w_shotdir based on the weapon model
 147 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 148 // make sure you call makevectors first (FIXME?)
 149 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 150 {
 151         float nudge = 1; // added to traceline target and subtracted from result
 152         float oldsolid;
 153         vector vecs, dv;
 154         oldsolid = ent.dphitcontentsmask;
 155         if(ent.weapon == WEP_RIFLE)
 156                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 157         else
 158                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 159         if(antilag)
 160                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 161                 // passing world, because we do NOT want it to touch dphitcontentsmask
 162         else
 163                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 164         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 165
 166         vector vf, vr, vu;
 167         vf = v_forward;
 168         vr = v_right;
 169         vu = v_up;
 170         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 171         v_forward = vf;
 172         v_right = vr;
 173         v_up = vu;
 174
 175         // un-adjust trueaim if shotend is too close
 176         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 177                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 178
 179         // track max damage
 180         if(accuracy_canbegooddamage(ent))
 181                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 182
 183         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 184
 185         if(ent.weaponentity.movedir_x > 0)
 186                 vecs = ent.weaponentity.movedir;
 187         else
 188                 vecs = '0 0 0';
 189
 190         dv = v_right * -vecs_y + v_up * vecs_z;
 191         w_shotorg = ent.origin + ent.view_ofs + dv;
 192
 193         // now move the shotorg forward as much as requested if possible
 194         if(antilag)
 195         {
 196                 if(ent.antilag_debug)
 197                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 198                 else
 199                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200         }
 201         else
 202                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 203         w_shotorg = trace_endpos - v_forward * nudge;
 204         // calculate the shotdir from the chosen shotorg
 205         w_shotdir = normalize(w_shotend - w_shotorg);
 206
 207         if (antilag)
 208         if (!ent.cvar_cl_noantilag)
 209         {
 210                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 211                 {
 212                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 213                         if (!trace_ent.takedamage)
 214                         {
 215                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 216                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 217                                 {
 218                                         entity e;
 219                                         e = trace_ent;
 220                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 221                                         if(trace_ent == e)
 222                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 223                                 }
 224                         }
 225                 }
 226                 else if(autocvar_g_antilag == 3) // client side hitscan
 227                 {
 228                         // this part MUST use prydon cursor
 229                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 230                         if (ent.cursor_trace_ent != ent)         // just to make sure
 231                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 232                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 233                         {
 234                                 // verify that the shot would miss without antilag
 235                                 // (avoids an issue where guns would always shoot at their origin)
 236                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 237                                 if (!trace_ent.takedamage)
 238                                 {
 239                                         // verify that the shot would hit if altered
 240                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 241                                         if (trace_ent == ent.cursor_trace_ent)
 242                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 243                                         else
 244                                                 print("antilag fail\n");
 245                                 }
 246                         }
 247                 }
 248         }
 249
 250         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 251
 252         if (!g_norecoil)
 253                 ent.punchangle_x = recoil * -1;
 254
 255         if (snd != "")
 256         {
 257                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 258                 W_PlayStrengthSound(ent);
 259         }
 260
 261         // nudge w_shotend so a trace to w_shotend hits
 262         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 263 }
 264
 265 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 266 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 269 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 270
 271 float CL_Weaponentity_CustomizeEntityForClient()
 272 {
 273         self.viewmodelforclient = self.owner;
 274         if(other.classname == "spectator")
 275                 if(other.enemy == self.owner)
 276                         self.viewmodelforclient = other;
 277         return TRUE;
 278 }
 279
 280 /*
 281  * supported formats:
 282  *
 283  * 1. simple animated model, muzzle flash handling on h_ model:
 284  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 285  *      tags:
 286  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 287  *        shell = casings ejection point (must be on the right hand side of the gun)
 288  *        weapon = attachment for v_tuba.md3
 289  *    v_tuba.md3 - first and third person model
 290  *    g_tuba.md3 - pickup model
 291  *
 292  * 2. simple animated model, muzzle flash handling on v_ model:
 293  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 294  *      tags:
 295  *        weapon = attachment for v_tuba.md3
 296  *    v_tuba.md3 - first and third person model
 297  *      tags:
 298  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 299  *        shell = casings ejection point (must be on the right hand side of the gun)
 300  *    g_tuba.md3 - pickup model
 301  *
 302  * 3. fully animated model, muzzle flash handling on h_ model:
 303  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 304  *      tags:
 305  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 306  *        shell = casings ejection point (must be on the right hand side of the gun)
 307  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 308  *    v_tuba.md3 - third person model
 309  *    g_tuba.md3 - pickup model
 310  *
 311  * 4. fully animated model, muzzle flash handling on v_ model:
 312  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 313  *      tags:
 314  *        shot = muzzle end (shot origin)
 315  *        shell = casings ejection point (must be on the right hand side of the gun)
 316  *    v_tuba.md3 - third person model
 317  *      tags:
 318  *        shot = muzzle end (for muzzle flashes)
 319  *    g_tuba.md3 - pickup model
 320  */
 321
 322 // writes:
 323 //   self.origin, self.angles
 324 //   self.weaponentity
 325 //   self.movedir, self.view_ofs
 326 //   attachment stuff
 327 //   anim stuff
 328 // to free:
 329 //   call again with ""
 330 //   remove the ent
 331 void CL_WeaponEntity_SetModel(string name)
 332 {
 333         float v_shot_idx;
 334         if (name != "")
 335         {
 336                 // if there is a child entity, hide it until we're sure we use it
 337                 if (self.weaponentity)
 338                         self.weaponentity.model = "";
 339                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 340                 v_shot_idx = gettagindex(self, "shot"); // used later
 341                 if(!v_shot_idx)
 342                         v_shot_idx = gettagindex(self, "tag_shot");
 343
 344                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 345                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 346                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
 347                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
 348                 self.anim_idle   = animfixfps(self, '2 1 0.01');
 349                 self.anim_reload = animfixfps(self, '3 1 0.01');
 350
 351                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 352                 // if we don't, this is a "real" animated model
 353                 if(gettagindex(self, "weapon"))
 354                 {
 355                         if (!self.weaponentity)
 356                                 self.weaponentity = spawn();
 357                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 358                         setattachment(self.weaponentity, self, "weapon");
 359                 }
 360                 else if(gettagindex(self, "tag_weapon"))
 361                 {
 362                         if (!self.weaponentity)
 363                                 self.weaponentity = spawn();
 364                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 365                         setattachment(self.weaponentity, self, "tag_weapon");
 366                 }
 367                 else
 368                 {
 369                         if(self.weaponentity)
 370                                 remove(self.weaponentity);
 371                         self.weaponentity = world;
 372                 }
 373
 374                 setorigin(self,'0 0 0');
 375                 self.angles = '0 0 0';
 376                 self.frame = 0;
 377                 self.viewmodelforclient = world;
 378
 379                 float idx;
 380
 381                 if(v_shot_idx) // v_ model attached to invisible h_ model
 382                 {
 383                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 384                 }
 385                 else
 386                 {
 387                         idx = gettagindex(self, "shot");
 388                         if(!idx)
 389                                 idx = gettagindex(self, "tag_shot");
 390                         if(idx)
 391                                 self.movedir = gettaginfo(self, idx);
 392                         else
 393                         {
 394                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 395                                 self.movedir = '0 0 0';
 396                         }
 397                 }
 398
 399                 if(self.weaponentity) // v_ model attached to invisible h_ model
 400                 {
 401                         idx = gettagindex(self.weaponentity, "shell");
 402                         if(!idx)
 403                                 idx = gettagindex(self.weaponentity, "tag_shell");
 404                         if(idx)
 405                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 406                 }
 407                 else
 408                         idx = 0;
 409                 if(!idx)
 410                 {
 411                         idx = gettagindex(self, "shell");
 412                         if(!idx)
 413                                 idx = gettagindex(self, "tag_shell");
 414                         if(idx)
 415                                 self.spawnorigin = gettaginfo(self, idx);
 416                         else
 417                         {
 418                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 419                                 self.spawnorigin = self.movedir;
 420                         }
 421                 }
 422
 423                 if(v_shot_idx)
 424                 {
 425                         self.oldorigin = '0 0 0'; // use regular attachment
 426                 }
 427                 else
 428                 {
 429                         if(self.weaponentity)
 430                         {
 431                                 idx = gettagindex(self, "weapon");
 432                                 if(!idx)
 433                                         idx = gettagindex(self, "tag_weapon");
 434                         }
 435                         else
 436                         {
 437                                 idx = gettagindex(self, "handle");
 438                                 if(!idx)
 439                                         idx = gettagindex(self, "tag_handle");
 440                         }
 441                         if(idx)
 442                         {
 443                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 444                         }
 445                         else
 446                         {
 447                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 448                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 449                         }
 450                 }
 451
 452                 self.viewmodelforclient = self.owner;
 453         }
 454         else
 455         {
 456                 self.model = "";
 457                 if(self.weaponentity)
 458                         remove(self.weaponentity);
 459                 self.weaponentity = world;
 460                 self.movedir = '0 0 0';
 461                 self.spawnorigin = '0 0 0';
 462                 self.oldorigin = '0 0 0';
 463                 self.anim_fire1  = '0 1 0.01';
 464                 self.anim_fire2  = '0 1 0.01';
 465                 self.anim_idle   = '0 1 0.01';
 466                 self.anim_reload = '0 1 0.01';
 467         }
 468
 469         self.view_ofs = '0 0 0';
 470
 471         if(self.movedir_x >= 0)
 472         {
 473                 vector v0;
 474                 v0 = self.movedir;
 475                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 476                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 477         }
 478         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 479         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 480
 481         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 482
 483         // check if an instant weapon switch occurred
 484         setorigin(self, self.view_ofs);
 485         // reset animstate now
 486         self.wframe = WFRAME_IDLE;
 487         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 488 }
 489
 490 vector CL_Weapon_GetShotOrg(float wpn)
 491 {
 492         entity wi, oldself;
 493         vector ret;
 494         wi = get_weaponinfo(wpn);
 495         oldself = self;
 496         self = spawn();
 497         CL_WeaponEntity_SetModel(wi.mdl);
 498         ret = self.movedir;
 499         CL_WeaponEntity_SetModel("");
 500         remove(self);
 501         self = oldself;
 502         return ret;
 503 }
 504
 505 void CL_Weaponentity_Think()
 506 {
 507         float tb;
 508         self.nextthink = time;
 509         if (intermission_running)
 510                 self.frame = self.anim_idle_x;
 511         if (self.owner.weaponentity != self)
 512         {
 513                 if (self.weaponentity)
 514                         remove(self.weaponentity);
 515                 remove(self);
 516                 return;
 517         }
 518         if (self.owner.deadflag != DEAD_NO)
 519         {
 520                 self.model = "";
 521                 if (self.weaponentity)
 522                         self.weaponentity.model = "";
 523                 return;
 524         }
 525         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 526         {
 527                 self.weaponname = self.owner.weaponname;
 528                 self.dmg = self.owner.modelindex;
 529                 self.deadflag = self.owner.deadflag;
 530
 531                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 532         }
 533
 534         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 535         self.effects = self.owner.effects & EFMASK_CHEAP;
 536         self.effects &~= EF_LOWPRECISION;
 537         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 538         self.effects &~= EF_TELEPORT_BIT;
 539         self.effects &~= EF_RESTARTANIM_BIT;
 540         self.effects |= tb;
 541
 542         if(self.owner.alpha == default_player_alpha)
 543                 self.alpha = default_weapon_alpha;
 544         else if(self.owner.alpha != 0)
 545                 self.alpha = self.owner.alpha;
 546         else
 547                 self.alpha = 1;
 548
 549         self.glowmod = self.owner.weaponentity_glowmod;
 550         self.colormap = self.owner.colormap;
 551         if (self.weaponentity)
 552         {
 553                 self.weaponentity.effects = self.effects;
 554                 self.weaponentity.alpha = self.alpha;
 555                 self.weaponentity.colormap = self.colormap;
 556                 self.weaponentity.glowmod = self.glowmod;
 557         }
 558
 559         self.angles = '0 0 0';
 560         float f;
 561         if (self.state == WS_RAISE && !intermission_running)
 562         {
 563                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 564                 self.angles_x = -90 * f * f;
 565         }
 566         else if (self.state == WS_DROP && !intermission_running)
 567         {
 568                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 569                 self.angles_x = -90 * f * f;
 570         }
 571         else if (self.state == WS_CLEAR)
 572         {
 573                 f = 1;
 574                 self.angles_x = -90 * f * f;
 575         }
 576 }
 577
 578 void CL_ExteriorWeaponentity_Think()
 579 {
 580         float tag_found;
 581         vector ang;
 582         self.nextthink = time;
 583         if (self.owner.exteriorweaponentity != self)
 584         {
 585                 remove(self);
 586                 return;
 587         }
 588         if (self.owner.deadflag != DEAD_NO)
 589         {
 590                 self.model = "";
 591                 return;
 592         }
 593         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 594         {
 595                 self.weaponname = self.owner.weaponname;
 596                 self.dmg = self.owner.modelindex;
 597                 self.deadflag = self.owner.deadflag;
 598                 if (self.owner.weaponname != "")
 599                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 600                 else
 601                         self.model = "";
 602
 603                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 604                 {
 605                         self.tag_index = tag_found;
 606                         self.tag_entity = self.owner;
 607                 }
 608                 else
 609                         setattachment(self, self.owner, "bip01 r hand");
 610         }
 611         self.effects = self.owner.effects;
 612         if(sv_pitch_min == sv_pitch_max)
 613                 self.effects |= EF_LOWPRECISION;
 614         else
 615                 self.effects &~= EF_LOWPRECISION;
 616         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 617         if(self.owner.alpha == default_player_alpha)
 618                 self.alpha = default_weapon_alpha;
 619         else if(self.owner.alpha != 0)
 620                 self.alpha = self.owner.alpha;
 621         else
 622                 self.alpha = 1;
 623
 624         if (!intermission_running)
 625         {
 626                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 627                 ang_y = 0;
 628                 ang_z = 0;
 629
 630                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 631                 {
 632                         ang_y = self.owner.v_angle_y;
 633                         makevectors(ang);
 634                         var vector v = v_forward;
 635                         var float t = self.tag_entity.frame1time;
 636                         var float f = self.tag_entity.frame;
 637                         self.tag_entity.frame1time = time;
 638                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 639                         gettaginfo(self.tag_entity, self.tag_index);
 640                         self.tag_entity.frame1time = t;
 641                         self.tag_entity.frame = f;
 642                         // untransform v according to this coordinate space
 643                         vector w;
 644                         w_x = v_forward * v;
 645                         w_y = -v_right * v;
 646                         w_z = v_up * v;
 647                         self.angles = vectoangles(w);
 648                 }
 649                 else
 650                 {
 651                         ang_x = -/* don't ask */ang_x;
 652                         self.angles = ang;
 653                 }
 654
 655                 if(autocvar_g_loituma)
 656                 {
 657                         vector modangles;
 658                         float t;
 659
 660                         t = time * autocvar_g_loituma;
 661
 662                         modangles_x = t * 360;
 663                         modangles_y = 90;
 664                         modangles_z = 0;
 665
 666                         self.angles =
 667                                 AnglesTransform_ToAngles(
 668                                         AnglesTransform_Multiply(
 669                                                 AnglesTransform_FromAngles(self.angles),
 670                                                 AnglesTransform_FromAngles(modangles)
 671                                         )
 672                                 );
 673                 }
 674         }
 675
 676         self.glowmod = self.owner.weaponentity_glowmod;
 677         self.colormap = self.owner.colormap;
 678
 679         CSQCMODEL_AUTOUPDATE();
 680 }
 681
 682 // spawning weaponentity for client
 683 void CL_SpawnWeaponentity()
 684 {
 685         self.weaponentity = spawn();
 686         self.weaponentity.classname = "weaponentity";
 687         self.weaponentity.solid = SOLID_NOT;
 688         self.weaponentity.owner = self;
 689         setmodel(self.weaponentity, ""); // precision set when changed
 690         setorigin(self.weaponentity, '0 0 0');
 691         self.weaponentity.angles = '0 0 0';
 692         self.weaponentity.viewmodelforclient = self;
 693         self.weaponentity.flags = 0;
 694         self.weaponentity.think = CL_Weaponentity_Think;
 695         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 696         self.weaponentity.nextthink = time;
 697
 698         self.exteriorweaponentity = spawn();
 699         self.exteriorweaponentity.classname = "exteriorweaponentity";
 700         self.exteriorweaponentity.solid = SOLID_NOT;
 701         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 702         self.exteriorweaponentity.owner = self;
 703         setorigin(self.exteriorweaponentity, '0 0 0');
 704         self.exteriorweaponentity.angles = '0 0 0';
 705         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 706         self.exteriorweaponentity.nextthink = time;
 707
 708         {
 709                 entity oldself = self;
 710                 self = self.exteriorweaponentity;
 711                 CSQCMODEL_AUTOINIT();
 712                 self = oldself;
 713         }
 714 }
 715
 716 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 717 {
 718         msg_entity = e;
 719         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 720         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 721         WriteByte(MSG_ONE, wpn);
 722         WriteString(MSG_ONE, wpnname);
 723         WriteByte(MSG_ONE, type);
 724 }
 725
 726 .float hasweapon_complain_spam;
 727
 728 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 729 {
 730         float f;
 731         entity oldself;
 732
 733         if(time < self.hasweapon_complain_spam)
 734                 complain = 0;
 735         if(complain)
 736                 self.hasweapon_complain_spam = time + 0.2;
 737
 738         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 739         {
 740                 if (complain)
 741                         sprint(self, "Invalid weapon\n");
 742                 return FALSE;
 743         }
 744         if (WEPSET_CONTAINS_EW(cl, wpn))
 745         {
 746                 if (andammo)
 747                 {
 748                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 749                         {
 750                                 f = 1;
 751                         }
 752                         else
 753                         {
 754                                 oldself = self;
 755                                 self = cl;
 756                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 757                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 758
 759                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 760                                 entity mine;
 761                                 if(wpn == WEP_MINE_LAYER)
 762                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 763                                         f = 1;
 764
 765                                 self = oldself;
 766                         }
 767                         if (!f)
 768                         {
 769                                 if (complain)
 770                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 771                                 {
 772                                         play2(cl, "weapons/unavailable.wav");
 773                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 774                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 775                                 }
 776                                 return FALSE;
 777                         }
 778                 }
 779                 return TRUE;
 780         }
 781         if (complain)
 782         {
 783                 // DRESK - 3/16/07
 784                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 785                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 786                 {
 787                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 788                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 789
 790                         if(autocvar_g_showweaponspawns)
 791                         {
 792                                 entity e;
 793                                 string s;
 794
 795                                 e = get_weaponinfo(wpn);
 796                                 s = e.model2;
 797
 798                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 799                                 {
 800                                         if(e.classname == "droppedweapon")
 801                                                 continue;
 802                                         if not(e.flags & FL_ITEM)
 803                                                 continue;
 804                                         WaypointSprite_Spawn(
 805                                                 s,
 806                                                 1, 0,
 807                                                 world, e.origin,
 808                                                 self, 0,
 809                                                 world, enemy,
 810                                                 0,
 811                                                 RADARICON_NONE, '0 0 0'
 812                                         );
 813                                 }
 814                         }
 815                 }
 816                 else
 817                 {
 818                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 819                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 820                 }
 821
 822                 play2(cl, "weapons/unavailable.wav");
 823         }
 824         return FALSE;
 825 }
 826
 827 // Weapon subs
 828 void w_clear()
 829 {
 830         if (self.weapon != -1)
 831         {
 832                 self.weapon = 0;
 833                 self.switchingweapon = 0;
 834         }
 835         if (self.weaponentity)
 836         {
 837                 self.weaponentity.state = WS_CLEAR;
 838                 self.weaponentity.effects = 0;
 839         }
 840 }
 841
 842 void w_ready()
 843 {
 844         if (self.weaponentity)
 845                 self.weaponentity.state = WS_READY;
 846         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 847 }
 848
 849 // Setup weapon for client (after this raise frame will be launched)
 850 void weapon_setup(float windex)
 851 {
 852         entity e;
 853         e = get_weaponinfo(windex);
 854         self.items &~= IT_AMMO;
 855         self.items = self.items | (e.items & IT_AMMO);
 856
 857         // the two weapon entities will notice this has changed and update their models
 858         self.weapon = windex;
 859         self.switchingweapon = windex; // to make sure
 860         self.weaponname = e.mdl;
 861         self.bulletcounter = 0;
 862 }
 863
 864 // perform weapon to attack (weaponstate and attack_finished check is here)
 865 void W_SwitchToOtherWeapon(entity pl)
 866 {
 867         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 868         float w, ww;
 869         w = pl.weapon;
 870         if(WEPSET_CONTAINS_EW(pl, w))
 871         {
 872                 WEPSET_ANDNOT_EW(pl, w);
 873                 ww = w_getbestweapon(pl);
 874                 WEPSET_OR_EW(pl, w);
 875         }
 876         else
 877                 ww = w_getbestweapon(pl);
 878         if(ww)
 879                 W_SwitchWeapon_Force(pl, ww);
 880 }
 881
 882 string PrimaryOrSecondary(float secondary)
 883 {
 884         if(secondary)
 885                 return "secondary";
 886         else
 887                 return "primary";
 888 }
 889
 890 .float prevdryfire;
 891 .float prevwarntime;
 892 float weapon_prepareattack_checkammo(float secondary)
 893 {
 894         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 895         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 896         {
 897                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 898                 entity mine;
 899                 if(self.weapon == WEP_MINE_LAYER)
 900                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 901                         return FALSE;
 902
 903                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 904                 {
 905                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 906                         self.prevdryfire = time;
 907                 }
 908
 909                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 910                 {
 911                         if(time - self.prevwarntime > 1)
 912                         {
 913                                 sprint(self, strcat("^2", W_Name(self.weapon), " ", PrimaryOrSecondary(secondary), "^7 is unable to fire, but its ^2", PrimaryOrSecondary(1 - secondary), "^7 can.\n"));
 914                         }
 915                         self.prevwarntime = time;
 916                 }
 917                 else // this weapon is totally unable to fire, switch to another one
 918                 {
 919                         W_SwitchToOtherWeapon(self);
 920                 }
 921
 922                 return FALSE;
 923         }
 924         return TRUE;
 925 }
 926 .float race_penalty;
 927 float weapon_prepareattack_check(float secondary, float attacktime)
 928 {
 929         if(!weapon_prepareattack_checkammo(secondary))
 930                 return FALSE;
 931
 932         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 933         //if all players readied up and the countdown is running
 934         if(time < game_starttime || time < self.race_penalty) {
 935                 return FALSE;
 936         }
 937
 938         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 939                 return FALSE;
 940
 941         // do not even think about shooting if switching
 942         if(self.switchweapon != self.weapon)
 943                 return FALSE;
 944
 945         if(attacktime >= 0)
 946         {
 947                 // don't fire if previous attack is not finished
 948                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 949                         return FALSE;
 950                 // don't fire while changing weapon
 951                 if (self.weaponentity.state != WS_READY)
 952                         return FALSE;
 953         }
 954
 955         return TRUE;
 956 }
 957 float weapon_prepareattack_do(float secondary, float attacktime)
 958 {
 959         self.weaponentity.state = WS_INUSE;
 960
 961         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 962
 963         // if the weapon hasn't been firing continuously, reset the timer
 964         if(attacktime >= 0)
 965         {
 966                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 967                 {
 968                         ATTACK_FINISHED(self) = time;
 969                         //dprint("resetting attack finished to ", ftos(time), "\n");
 970                 }
 971                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 972         }
 973         self.bulletcounter += 1;
 974         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 975         return TRUE;
 976 }
 977 float weapon_prepareattack(float secondary, float attacktime)
 978 {
 979         if(weapon_prepareattack_check(secondary, attacktime))
 980         {
 981                 weapon_prepareattack_do(secondary, attacktime);
 982                 return TRUE;
 983         }
 984         else
 985                 return FALSE;
 986 }
 987
 988 void weapon_thinkf(float fr, float t, void() func)
 989 {
 990         vector a;
 991         vector of, or, ou;
 992         float restartanim;
 993
 994         if(fr == WFRAME_DONTCHANGE)
 995         {
 996                 fr = self.weaponentity.wframe;
 997                 restartanim = FALSE;
 998         }
 999         else if (fr == WFRAME_IDLE)
1000                 restartanim = FALSE;
1001         else
1002                 restartanim = TRUE;
1003
1004         of = v_forward;
1005         or = v_right;
1006         ou = v_up;
1007
1008         if (self.weaponentity)
1009         {
1010                 self.weaponentity.wframe = fr;
1011                 if (fr == WFRAME_IDLE)
1012                         a = self.weaponentity.anim_idle;
1013                 else if (fr == WFRAME_FIRE1)
1014                         a = self.weaponentity.anim_fire1;
1015                 else if (fr == WFRAME_FIRE2)
1016                         a = self.weaponentity.anim_fire2;
1017                 else if (fr == WFRAME_RELOAD)
1018                         a = self.weaponentity.anim_reload;
1019                 a_z *= g_weaponratefactor;
1020                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1021         }
1022
1023         v_forward = of;
1024         v_right = or;
1025         v_up = ou;
1026
1027         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1028         {
1029                 backtrace("Tried to override initial weapon think function - should this really happen?");
1030         }
1031
1032         t *= W_WeaponRateFactor();
1033
1034         // VorteX: haste can be added here
1035         if (self.weapon_think == w_ready)
1036         {
1037                 self.weapon_nextthink = time;
1038                 //dprint("started firing at ", ftos(time), "\n");
1039         }
1040         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1041         {
1042                 self.weapon_nextthink = time;
1043                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1044         }
1045         self.weapon_nextthink = self.weapon_nextthink + t;
1046         self.weapon_think = func;
1047         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1048
1049         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1050         //anim = self.anim_shoot;
1051         if (restartanim)
1052         if (t)
1053         if (!self.crouch) // shoot anim stands up, this looks bad
1054         {
1055                 vector anim;
1056                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1057                 {
1058                         anim = self.anim_melee;
1059                         anim_z = anim_y / (t + sys_frametime);
1060                         setanim(self, anim, FALSE, TRUE, TRUE);
1061                 }
1062                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1063                 {
1064                         anim = self.anim_shoot;
1065                         anim_z = anim_y / (t + sys_frametime);
1066                         setanim(self, anim, FALSE, TRUE, TRUE);
1067                 }
1068         }
1069 }
1070
1071 void weapon_boblayer1(float spd, vector org)
1072 {
1073         // VorteX: haste can be added here
1074 }
1075
1076 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1077 {
1078         vector mdirection;
1079         float mspeed;
1080         vector outvelocity;
1081
1082         mvelocity = mvelocity * g_weaponspeedfactor;
1083
1084         mdirection = normalize(mvelocity);
1085         mspeed = vlen(mvelocity);
1086
1087         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1088
1089         return outvelocity;
1090 }
1091
1092 void W_AttachToShotorg(entity flash, vector offset)
1093 {
1094         entity xflash;
1095         flash.owner = self;
1096         flash.angles_z = random() * 360;
1097
1098         if(gettagindex(self.weaponentity, "shot"))
1099                 setattachment(flash, self.weaponentity, "shot");
1100         else
1101                 setattachment(flash, self.weaponentity, "tag_shot");
1102         setorigin(flash, offset);
1103
1104         xflash = spawn();
1105         copyentity(flash, xflash);
1106
1107         flash.viewmodelforclient = self;
1108
1109         if(self.weaponentity.oldorigin_x > 0)
1110         {
1111                 setattachment(xflash, self.exteriorweaponentity, "");
1112                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1113         }
1114         else
1115         {
1116                 if(gettagindex(self.exteriorweaponentity, "shot"))
1117                         setattachment(xflash, self.exteriorweaponentity, "shot");
1118                 else
1119                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1120                 setorigin(xflash, offset);
1121         }
1122 }
1123
1124 vector cliptoplane(vector v, vector p)
1125 {
1126         return v - (v * p) * p;
1127 }
1128
1129 vector solve_cubic_pq(float p, float q)
1130 {
1131         float D, u, v, a;
1132         D = q*q/4.0 + p*p*p/27.0;
1133         if(D < 0)
1134         {
1135                 // irreducibilis
1136                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1137                 u = sqrt(-4.0/3.0 * p);
1138                 // a in range 0..pi/3
1139                 // cos(a)
1140                 // cos(a + 2pi/3)
1141                 // cos(a + 4pi/3)
1142                 return
1143                         u *
1144                         (
1145                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1146                                 +
1147                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1148                                 +
1149                                 '0 0 1' * cos(a)
1150                         );
1151         }
1152         else if(D == 0)
1153         {
1154                 // simple
1155                 if(p == 0)
1156                         return '0 0 0';
1157                 u = 3*q/p;
1158                 v = -u/2;
1159                 if(u >= v)
1160                         return '1 1 0' * v + '0 0 1' * u;
1161                 else
1162                         return '0 1 1' * v + '1 0 0' * u;
1163         }
1164         else
1165         {
1166                 // cardano
1167                 u = cbrt(-q/2.0 + sqrt(D));
1168                 v = cbrt(-q/2.0 - sqrt(D));
1169                 return '1 1 1' * (u + v);
1170         }
1171 }
1172 vector solve_cubic_abcd(float a, float b, float c, float d)
1173 {
1174         // y = 3*a*x + b
1175         // x = (y - b) / 3a
1176         float p, q;
1177         vector v;
1178         p = (9*a*c - 3*b*b);
1179         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1180         v = solve_cubic_pq(p, q);
1181         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1182         if(a < 0)
1183                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1184         return v;
1185 }
1186
1187 vector findperpendicular(vector v)
1188 {
1189         vector p;
1190         p_x = v_z;
1191         p_y = -v_x;
1192         p_z = v_y;
1193         return normalize(cliptoplane(p, v));
1194 }
1195
1196 vector W_CalculateProjectileSpread(vector forward, float spread)
1197 {
1198         float sigma;
1199         vector v1, v2;
1200         float dx, dy, r;
1201         float sstyle;
1202         spread *= g_weaponspreadfactor;
1203         if(spread <= 0)
1204                 return forward;
1205         sstyle = autocvar_g_projectiles_spread_style;
1206
1207         if(sstyle == 0)
1208         {
1209                 // this is the baseline for the spread value!
1210                 // standard deviation: sqrt(2/5)
1211                 // density function: sqrt(1-r^2)
1212                 return forward + randomvec() * spread;
1213         }
1214         else if(sstyle == 1)
1215         {
1216                 // same thing, basically
1217                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1218         }
1219         else if(sstyle == 2)
1220         {
1221                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1222                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1223                 v1 = findperpendicular(forward);
1224                 v2 = cross(forward, v1);
1225                 // random point on unit circle
1226                 dx = random() * 2 * M_PI;
1227                 dy = sin(dx);
1228                 dx = cos(dx);
1229                 // radius in our dist function
1230                 r = random();
1231                 r = sqrt(r);
1232                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1233         }
1234         else if(sstyle == 3) // gauss 3d
1235         {
1236                 sigma = spread * 0.44721359549996; // match baseline stddev
1237                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1238                 v1 = forward;
1239                 v1_x += gsl_ran_gaussian(sigma);
1240                 v1_y += gsl_ran_gaussian(sigma);
1241                 v1_z += gsl_ran_gaussian(sigma);
1242                 return v1;
1243         }
1244         else if(sstyle == 4) // gauss 2d
1245         {
1246                 sigma = spread * 0.44721359549996; // match baseline stddev
1247                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1248                 v1_x = gsl_ran_gaussian(sigma);
1249                 v1_y = gsl_ran_gaussian(sigma);
1250                 v1_z = gsl_ran_gaussian(sigma);
1251                 return normalize(forward + cliptoplane(v1, forward));
1252         }
1253         else if(sstyle == 5) // 1-r
1254         {
1255                 sigma = spread * 1.154700538379252; // match baseline stddev
1256                 v1 = findperpendicular(forward);
1257                 v2 = cross(forward, v1);
1258                 // random point on unit circle
1259                 dx = random() * 2 * M_PI;
1260                 dy = sin(dx);
1261                 dx = cos(dx);
1262                 // radius in our dist function
1263                 r = random();
1264                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1265                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1266         }
1267         else if(sstyle == 6) // 1-r^2
1268         {
1269                 sigma = spread * 1.095445115010332; // match baseline stddev
1270                 v1 = findperpendicular(forward);
1271                 v2 = cross(forward, v1);
1272                 // random point on unit circle
1273                 dx = random() * 2 * M_PI;
1274                 dy = sin(dx);
1275                 dx = cos(dx);
1276                 // radius in our dist function
1277                 r = random();
1278                 r = sqrt(1 - r);
1279                 r = sqrt(1 - r);
1280                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1281         }
1282         else if(sstyle == 7) // (1-r) (2-r)
1283         {
1284                 sigma = spread * 1.224744871391589; // match baseline stddev
1285                 v1 = findperpendicular(forward);
1286                 v2 = cross(forward, v1);
1287                 // random point on unit circle
1288                 dx = random() * 2 * M_PI;
1289                 dy = sin(dx);
1290                 dx = cos(dx);
1291                 // radius in our dist function
1292                 r = random();
1293                 r = 1 - sqrt(r);
1294                 r = 1 - sqrt(r);
1295                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1296         }
1297         else
1298                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1299         return '0 0 0';
1300         /*
1301          * how to derive falloff functions:
1302          * rho(r) := (2-r) * (1-r);
1303          * a : 0;
1304          * b : 1;
1305          * rhor(r) := r * rho(r);
1306          * cr(t) := integrate(rhor(r), r, a, t);
1307          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1308          * variance : scr(b) / cr(b);
1309          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1310          * sqrt(0.4 / variance), numer;
1311          */
1312 }
1313
1314 #if 0
1315 float mspercallsum;
1316 float mspercallsstyle;
1317 float mspercallcount;
1318 #endif
1319 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1320 {
1321         if(missile.owner == world)
1322                 error("Unowned missile");
1323
1324         dir = dir + upDir * (pUpSpeed / pSpeed);
1325         dir_z += pZSpeed / pSpeed;
1326         pSpeed *= vlen(dir);
1327         dir = normalize(dir);
1328
1329 #if 0
1330         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1331         {
1332                 mspercallsum = mspercallcount = 0;
1333                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1334         }
1335         mspercallsum -= gettime(GETTIME_HIRES);
1336 #endif
1337         dir = W_CalculateProjectileSpread(dir, spread);
1338 #if 0
1339         mspercallsum += gettime(GETTIME_HIRES);
1340         mspercallcount += 1;
1341         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1342 #endif
1343
1344         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1345 }
1346
1347 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1348 {
1349         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1350 }
1351
1352 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1353 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1354
1355 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1356 {
1357         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1358                 return;
1359
1360         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1361         if(ammo_reload)
1362         {
1363                 self.clip_load -= ammo_use;
1364                 self.(weapon_load[self.weapon]) = self.clip_load;
1365         }
1366         else
1367                 self.(self.current_ammo) -= ammo_use;
1368 }
1369
1370 // weapon reloading code
1371
1372 .float reload_ammo_amount, reload_ammo_min, reload_time;
1373 .float reload_complain;
1374 .string reload_sound;
1375
1376 void W_ReloadedAndReady()
1377 {
1378         // finish the reloading process, and do the ammo transfer
1379
1380         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1381
1382         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1383         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1384                 self.clip_load = self.reload_ammo_amount;
1385         else
1386         {
1387                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1388                 {
1389                         self.clip_load += 1;
1390                         self.(self.current_ammo) -= 1;
1391                 }
1392         }
1393         self.(weapon_load[self.weapon]) = self.clip_load;
1394
1395         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1396         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1397         // so your weapon is disabled for a few seconds without reason
1398
1399         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1400
1401         w_ready();
1402 }
1403
1404 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1405 {
1406         // set global values to work with
1407
1408         self.reload_ammo_min = sent_ammo_min;
1409         self.reload_ammo_amount = sent_ammo_amount;
1410         self.reload_time = sent_time;
1411         self.reload_sound = sent_sound;
1412
1413         // check if we meet the necessary conditions to reload
1414
1415         entity e;
1416         e = get_weaponinfo(self.weapon);
1417
1418         // don't reload weapons that don't have the RELOADABLE flag
1419         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1420         {
1421                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1422                 return;
1423         }
1424
1425         // return if reloading is disabled for this weapon
1426         if(!self.reload_ammo_amount)
1427                 return;
1428
1429         // our weapon is fully loaded, no need to reload
1430         if (self.clip_load >= self.reload_ammo_amount)
1431                 return;
1432
1433         // no ammo, so nothing to load
1434         if(!self.(self.current_ammo) && self.reload_ammo_min)
1435         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1436         {
1437                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1438                 {
1439                         play2(self, "weapons/unavailable.wav");
1440                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1441                         self.reload_complain = time + 1;
1442                 }
1443                 // switch away if the amount of ammo is not enough to keep using this weapon
1444                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1445                 {
1446                         self.clip_load = -1; // reload later
1447                         W_SwitchToOtherWeapon(self);
1448                 }
1449                 return;
1450         }
1451
1452         if (self.weaponentity)
1453         {
1454                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1455                         return;
1456
1457                 // allow switching away while reloading, but this will cause a new reload!
1458                 self.weaponentity.state = WS_READY;
1459         }
1460
1461         // now begin the reloading process
1462
1463         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1464
1465         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1466         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1467         // so your weapon is disabled for a few seconds without reason
1468
1469         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1470
1471         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1472
1473         if(self.clip_load < 0)
1474                 self.clip_load = 0;
1475         self.old_clip_load = self.clip_load;
1476         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1477 }