qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 .float prevstrengthsound;
 134 .float prevstrengthsoundattempt;
 135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage, float range)
 136 {
 137         float nudge = 1; // added to traceline target and subtracted from result
 138         local float oldsolid;
 139         vector vecs, dv;
 140         oldsolid = ent.dphitcontentsmask;
 141         if(ent.weapon == WEP_CAMPINGRIFLE)
 142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         else
 144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 145         if(antilag)
 146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 147                 // passing world, because we do NOT want it to touch dphitcontentsmask
 148         else
 149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 151
 152         vector vf, vr, vu;
 153         vf = v_forward;
 154         vr = v_right;
 155         vu = v_up;
 156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 157         v_forward = vf;
 158         v_right = vr;
 159         v_up = vu;
 160
 161         // track max damage
 162         if not(inWarmupStage) {
 163                 entity w;
 164                 w = get_weaponinfo(ent.weapon);
 165                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage
 166                         ent.stats_fired[ent.weapon - 1] += maxdamage;
 167                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
 168                 }
 169         }
 170
 171         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 172
 173         if(ent.weaponentity.movedir_x > 0)
 174                 vecs = ent.weaponentity.movedir;
 175         else
 176                 vecs = '0 0 0';
 177         if(debug_shotorg != '0 0 0')
 178                 vecs = debug_shotorg;
 179
 180         dv = v_right * -vecs_y + v_up * vecs_z;
 181         w_shotorg = ent.origin + ent.view_ofs + dv;
 182
 183         // now move the shotorg forward as much as requested if possible
 184         if(antilag)
 185         {
 186                 if(ent.antilag_debug)
 187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 188                 else
 189                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 190         }
 191         else
 192                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 193         w_shotorg = trace_endpos - v_forward * nudge;
 194         // calculate the shotdir from the chosen shotorg
 195         w_shotdir = normalize(w_shotend - w_shotorg);
 196
 197         if (antilag)
 198         if (!ent.cvar_cl_noantilag)
 199         {
 200                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 201                 {
 202                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 203                         if (!trace_ent.takedamage)
 204                         {
 205                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 206                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 207                                 {
 208                                         entity e;
 209                                         e = trace_ent;
 210                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 211                                         if(trace_ent == e)
 212                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 213                                 }
 214                         }
 215                 }
 216                 else if(cvar("g_antilag") == 3) // client side hitscan
 217                 {
 218                         // this part MUST use prydon cursor
 219                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 220                         if (ent.cursor_trace_ent != ent)         // just to make sure
 221                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 222                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 223                         {
 224                                 // verify that the shot would miss without antilag
 225                                 // (avoids an issue where guns would always shoot at their origin)
 226                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 227                                 if (!trace_ent.takedamage)
 228                                 {
 229                                         // verify that the shot would hit if altered
 230                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 231                                         if (trace_ent == ent.cursor_trace_ent)
 232                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 233                                         else
 234                                                 print("antilag fail\n");
 235                                 }
 236                         }
 237                 }
 238         }
 239
 240         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 241
 242         if (!g_norecoil)
 243                 ent.punchangle_x = recoil * -1;
 244
 245         if (snd != "")
 246         {
 247                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 248         }
 249
 250         if(ent.items & IT_STRENGTH)
 251         if(!g_minstagib)
 252         if(
 253                 (time > ent.prevstrengthsound + cvar("sv_strengthsound_antispam_time"))
 254                 ||
 255                 (time > ent.prevstrengthsoundattempt + cvar("sv_strengthsound_antispam_refire_threshold"))
 256         ) // prevent insane sound spam
 257         {
 258                 sound(ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 259                 ent.prevstrengthsound = time;
 260         }
 261         ent.prevstrengthsoundattempt = time;
 262
 263         // nudge w_shotend so a trace to w_shotend hits
 264         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 265 };
 266
 267 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, maxdamage, MAX_SHOT_DISTANCE)
 268 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 269 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 270 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 271 #define W_SetupShot_Range(ent,antilag,recoil,snd,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage, range)
 272
 273 float CL_Weaponentity_CustomizeEntityForClient()
 274 {
 275         self.viewmodelforclient = self.owner;
 276         if(other.classname == "spectator")
 277                 if(other.enemy == self.owner)
 278                         self.viewmodelforclient = other;
 279         return TRUE;
 280 }
 281
 282 float qcweaponanimation;
 283 vector weapon_offset = '0 -10 0';
 284 vector weapon_adjust = '10 0 -15';
 285 .vector weapon_morph0origin;
 286 .vector weapon_morph0angles;
 287 .float  weapon_morph0time;
 288 .vector weapon_morph1origin;
 289 .vector weapon_morph1angles;
 290 .float  weapon_morph1time;
 291 .vector weapon_morph2origin;
 292 .vector weapon_morph2angles;
 293 .float  weapon_morph2time;
 294 .vector weapon_morph3origin;
 295 .vector weapon_morph3angles;
 296 .float  weapon_morph3time;
 297 .vector weapon_morph4origin;
 298 .vector weapon_morph4angles;
 299 .float  weapon_morph4time;
 300 .string weaponname;
 301 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 302
 303 /*
 304  * supported formats:
 305  *
 306  * 1. simple animated model, muzzle flash handling on h_ model:
 307  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 308  *      tags:
 309  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 310  *        shell = casings ejection point (must be on the right hand side of the gun)
 311  *        weapon = attachment for v_tuba.md3
 312  *    v_tuba.md3 - first and third person model
 313  *    g_tuba.md3 - pickup model
 314  *
 315  * 2. simple animated model, muzzle flash handling on v_ model:
 316  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 317  *      tags:
 318  *        weapon = attachment for v_tuba.md3
 319  *    v_tuba.md3 - first and third person model
 320  *      tags:
 321  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 322  *        shell = casings ejection point (must be on the right hand side of the gun)
 323  *    g_tuba.md3 - pickup model
 324  *
 325  * 3. fully animated model, muzzle flash handling on h_ model:
 326  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 327  *      tags:
 328  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 329  *        shell = casings ejection point (must be on the right hand side of the gun)
 330  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 331  *    v_tuba.md3 - third person model
 332  *    g_tuba.md3 - pickup model
 333  *
 334  * 4. fully animated model, muzzle flash handling on v_ model:
 335  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 336  *      tags:
 337  *        shot = muzzle end (shot origin)
 338  *        shell = casings ejection point (must be on the right hand side of the gun)
 339  *    v_tuba.md3 - third person model
 340  *      tags:
 341  *        shot = muzzle end (for muzzle flashes)
 342  *    g_tuba.md3 - pickup model
 343  */
 344
 345 // writes:
 346 //   self.origin, self.angles
 347 //   self.weaponentity
 348 //   self.movedir, self.view_ofs
 349 //   attachment stuff
 350 //   anim stuff
 351 // to free:
 352 //   call again with ""
 353 //   remove the ent
 354 void CL_WeaponEntity_SetModel(string name)
 355 {
 356         string animfilename;
 357         float animfile;
 358         float v_shot_idx;
 359         if (name != "")
 360         {
 361                 // if there is a child entity, hide it until we're sure we use it
 362                 if (self.weaponentity)
 363                         self.weaponentity.model = "";
 364                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 365                 v_shot_idx = gettagindex(self, "shot"); // used later
 366                 if(!v_shot_idx)
 367                         v_shot_idx = gettagindex(self, "tag_shot");
 368
 369                 if(qcweaponanimation)
 370                 {
 371                         self.angles = '0 0 0';
 372                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 373                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 374                         self.movedir_x += 32;
 375                         self.spawnorigin = self.movedir;
 376                         // oldorigin - not calculated here
 377                 }
 378                 else
 379                 {
 380                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 381                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 382                         animfile = fopen(animfilename, FILE_READ);
 383                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 384                         self.anim_fire1  = '0 1 0.01';
 385                         self.anim_fire2  = '1 1 0.01';
 386                         self.anim_idle   = '2 1 0.01';
 387                         self.anim_reload = '3 1 0.01';
 388                         if (animfile >= 0)
 389                         {
 390                                 animparseerror = FALSE;
 391                                 self.anim_fire1  = animparseline(animfile);
 392                                 self.anim_fire2  = animparseline(animfile);
 393                                 self.anim_idle   = animparseline(animfile);
 394                                 self.anim_reload = animparseline(animfile);
 395                                 fclose(animfile);
 396                                 if (animparseerror)
 397                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 398                         }
 399
 400                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 401                         // if we don't, this is a "real" animated model
 402                         if(gettagindex(self, "weapon"))
 403                         {
 404                                 if (!self.weaponentity)
 405                                         self.weaponentity = spawn();
 406                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 407                                 setattachment(self.weaponentity, self, "weapon");
 408                         }
 409                         else if(gettagindex(self, "tag_weapon"))
 410                         {
 411                                 if (!self.weaponentity)
 412                                         self.weaponentity = spawn();
 413                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 414                                 setattachment(self.weaponentity, self, "tag_weapon");
 415                         }
 416                         else
 417                         {
 418                                 if(self.weaponentity)
 419                                         remove(self.weaponentity);
 420                                 self.weaponentity = world;
 421                         }
 422
 423                         setorigin(self,'0 0 0');
 424                         self.angles = '0 0 0';
 425                         self.frame = 0;
 426                         self.viewmodelforclient = world;
 427
 428                         float idx;
 429
 430                         if(v_shot_idx) // v_ model attached to invisible h_ model
 431                         {
 432                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 433                         }
 434                         else
 435                         {
 436                                 idx = gettagindex(self, "shot");
 437                                 if(!idx)
 438                                         idx = gettagindex(self, "tag_shot");
 439                                 if(idx)
 440                                         self.movedir = gettaginfo(self, idx);
 441                                 else
 442                                 {
 443                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 444                                         self.movedir = '0 0 0';
 445                                 }
 446                         }
 447
 448                         if(self.weaponentity) // v_ model attached to invisible h_ model
 449                         {
 450                                 idx = gettagindex(self.weaponentity, "shell");
 451                                 if(!idx)
 452                                         idx = gettagindex(self.weaponentity, "tag_shell");
 453                                 if(idx)
 454                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 455                         }
 456                         else
 457                                 idx = 0;
 458                         if(!idx)
 459                         {
 460                                 idx = gettagindex(self, "shell");
 461                                 if(!idx)
 462                                         idx = gettagindex(self, "tag_shell");
 463                                 if(idx)
 464                                         self.spawnorigin = gettaginfo(self, idx);
 465                                 else
 466                                 {
 467                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 468                                         self.spawnorigin = self.movedir;
 469                                 }
 470                         }
 471
 472                         if(v_shot_idx)
 473                         {
 474                                 self.oldorigin = '0 0 0'; // use regular attachment
 475                         }
 476                         else
 477                         {
 478                                 if(self.weaponentity)
 479                                 {
 480                                         idx = gettagindex(self, "weapon");
 481                                         if(!idx)
 482                                                 idx = gettagindex(self, "tag_weapon");
 483                                 }
 484                                 else
 485                                 {
 486                                         idx = gettagindex(self, "handle");
 487                                         if(!idx)
 488                                                 idx = gettagindex(self, "tag_handle");
 489                                 }
 490                                 if(idx)
 491                                 {
 492                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 493                                 }
 494                                 else
 495                                 {
 496                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 497                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 498                                 }
 499                         }
 500
 501                         self.viewmodelforclient = self.owner;
 502                 }
 503         }
 504         else
 505         {
 506                 self.model = "";
 507                 if(self.weaponentity)
 508                         remove(self.weaponentity);
 509                 self.weaponentity = world;
 510                 self.movedir = '0 0 0';
 511                 self.spawnorigin = '0 0 0';
 512                 self.oldorigin = '0 0 0';
 513                 self.anim_fire1  = '0 1 0.01';
 514                 self.anim_fire2  = '0 1 0.01';
 515                 self.anim_idle   = '0 1 0.01';
 516                 self.anim_reload = '0 1 0.01';
 517         }
 518
 519         self.view_ofs = '0 0 0';
 520
 521         if(self.movedir_x >= 0)
 522         {
 523                 vector v0;
 524                 v0 = self.movedir;
 525                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 526                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 527         }
 528         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 529         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 530
 531         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 532
 533         // check if an instant weapon switch occurred
 534         if (qcweaponanimation)
 535         {
 536                 if (self.state == WS_READY)
 537                 {
 538                         self.angles = '0 0 0';
 539                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 540                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 541                 }
 542         }
 543         else
 544                 setorigin(self, self.view_ofs);
 545         // reset animstate now
 546         self.wframe = WFRAME_IDLE;
 547         self.weapon_morph0time = 0;
 548         self.weapon_morph1time = 0;
 549         self.weapon_morph2time = 0;
 550         self.weapon_morph3time = 0;
 551         self.weapon_morph4time = 0;
 552         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 553 }
 554
 555 vector CL_Weapon_GetShotOrg(float wpn)
 556 {
 557         entity wi, oldself;
 558         vector ret;
 559         wi = get_weaponinfo(wpn);
 560         oldself = self;
 561         self = spawn();
 562         CL_WeaponEntity_SetModel(wi.mdl);
 563         ret = self.movedir;
 564         CL_WeaponEntity_SetModel("");
 565         remove(self);
 566         self = oldself;
 567         return ret;
 568 }
 569
 570 void CL_Weaponentity_Think()
 571 {
 572         float tb;
 573         self.nextthink = time;
 574         if (intermission_running)
 575                 self.frame = self.anim_idle_x;
 576         if (self.owner.weaponentity != self)
 577         {
 578                 if (self.weaponentity)
 579                         remove(self.weaponentity);
 580                 remove(self);
 581                 return;
 582         }
 583         if (self.owner.deadflag != DEAD_NO)
 584         {
 585                 self.model = "";
 586                 if (self.weaponentity)
 587                         self.weaponentity.model = "";
 588                 return;
 589         }
 590         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 591         {
 592                 self.cnt = self.owner.weapon;
 593                 self.dmg = self.owner.modelindex;
 594                 self.deadflag = self.owner.deadflag;
 595
 596                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 597         }
 598
 599         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 600         self.effects = self.owner.effects & EFMASK_CHEAP;
 601         self.effects &~= EF_LOWPRECISION;
 602         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 603         self.effects &~= EF_TELEPORT_BIT;
 604         self.effects &~= EF_RESTARTANIM_BIT;
 605         self.effects |= tb;
 606
 607         if(self.owner.alpha == default_player_alpha)
 608                 self.alpha = default_weapon_alpha;
 609         else if(self.owner.alpha != 0)
 610                 self.alpha = self.owner.alpha;
 611         else
 612                 self.alpha = 1;
 613
 614         self.colormap = self.owner.colormap;
 615         if (self.weaponentity)
 616         {
 617                 self.weaponentity.effects = self.effects;
 618                 self.weaponentity.alpha = self.alpha;
 619                 self.weaponentity.colormap = self.colormap;
 620         }
 621
 622         self.angles = '0 0 0';
 623         local float f;
 624         f = 0;
 625         if (self.state == WS_RAISE && !intermission_running)
 626         {
 627                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 628                 self.angles_x = -90 * f * f;
 629                 if (qcweaponanimation)
 630                 {
 631                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 632                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 633                 }
 634         }
 635         else if (self.state == WS_DROP && !intermission_running)
 636         {
 637                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 638                 self.angles_x = -90 * f * f;
 639                 if (qcweaponanimation)
 640                 {
 641                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 642                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 643                 }
 644         }
 645         else if (self.state == WS_CLEAR)
 646         {
 647                 f = 1;
 648                 self.angles_x = -90 * f * f;
 649                 if (qcweaponanimation)
 650                 {
 651                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 652                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 653                 }
 654         }
 655         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 656         {
 657                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 658                 f = 1 - pow(1 - f, 3);
 659                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 660                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 661         }
 662         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 663         {
 664                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 665                 f = 1 - pow(1 - f, 3);
 666                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 667                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 668         }
 669         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 670         {
 671                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 672                 f = 1 - pow(1 - f, 3);
 673                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 674                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 675         }
 676         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 677         {
 678                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 679                 f = 1 - pow(1 - f, 3);
 680                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 681                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 682         }
 683         else if (qcweaponanimation)
 684         {
 685                 // begin a new idle morph
 686                 self.owner.weapon_morph0time   = time;
 687                 self.owner.weapon_morph0angles = self.angles;
 688                 self.owner.weapon_morph0origin = self.origin;
 689
 690                 float r;
 691                 float t;
 692
 693                 r = random();
 694                 if (r < 0.1)
 695                 {
 696                         // turn gun to the left to look at it
 697                         t = 2;
 698                         self.owner.weapon_morph1time   = time + t * 0.2;
 699                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 700                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 701                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 702
 703                         self.owner.weapon_morph2time   = time + t * 0.6;
 704                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 705                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 706                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 707
 708                         self.owner.weapon_morph3time   = time + t;
 709                         self.owner.weapon_morph3angles = '0 0 0';
 710                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 711                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 712                 }
 713                 else if (r < 0.2)
 714                 {
 715                         // raise the gun a bit
 716                         t = 2;
 717                         self.owner.weapon_morph1time   = time + t * 0.2;
 718                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 719                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 720                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 721
 722                         self.owner.weapon_morph2time   = time + t * 0.5;
 723                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 724                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 725                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 726
 727                         self.owner.weapon_morph3time   = time + t;
 728                         self.owner.weapon_morph3angles = '0 0 0';
 729                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 730                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 731                 }
 732                 else if (r < 0.3)
 733                 {
 734                         // tweak it a bit
 735                         t = 5;
 736                         self.owner.weapon_morph1time   = time + t * 0.3;
 737                         self.owner.weapon_morph1angles = randomvec() * 6;
 738                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 739                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 740
 741                         self.owner.weapon_morph2time   = time + t * 0.7;
 742                         self.owner.weapon_morph2angles = randomvec() * 6;
 743                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 744                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 745
 746                         self.owner.weapon_morph3time   = time + t;
 747                         self.owner.weapon_morph3angles = '0 0 0';
 748                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 749                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 750                 }
 751                 else
 752                 {
 753                         // hold it mostly steady
 754                         t = random() * 6 + 4;
 755                         self.owner.weapon_morph1time   = time + t * 0.2;
 756                         self.owner.weapon_morph1angles = randomvec() * 1;
 757                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 758                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 759
 760                         self.owner.weapon_morph2time   = time + t * 0.5;
 761                         self.owner.weapon_morph2angles = randomvec() * 1;
 762                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 763                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 764
 765                         self.owner.weapon_morph3time   = time + t * 0.7;
 766                         self.owner.weapon_morph3angles = randomvec() * 1;
 767                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 768                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 769                 }
 770
 771                 self.owner.weapon_morph4time   = time + t;
 772                 self.owner.weapon_morph4angles = '0 0 0';
 773                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 774                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 775
 776         }
 777 };
 778
 779 void CL_ExteriorWeaponentity_Think()
 780 {
 781         float tag_found;
 782         vector ang;
 783         self.nextthink = time;
 784         if (self.owner.exteriorweaponentity != self)
 785         {
 786                 remove(self);
 787                 return;
 788         }
 789         if (self.owner.deadflag != DEAD_NO)
 790         {
 791                 self.model = "";
 792                 return;
 793         }
 794         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 795         {
 796                 self.cnt = self.owner.weapon;
 797                 self.dmg = self.owner.modelindex;
 798                 self.deadflag = self.owner.deadflag;
 799                 if (self.owner.weaponname != "")
 800                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 801                 else
 802                         self.model = "";
 803
 804                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 805                 {
 806                         self.tag_index = tag_found;
 807                         self.tag_entity = self.owner;
 808                 }
 809                 else
 810                         setattachment(self, self.owner, "bip01 r hand");
 811
 812                 // if that didn't find a tag, hide the exterior weapon model
 813                 if (!self.tag_index)
 814                         self.model = "";
 815         }
 816         self.effects = self.owner.effects;
 817         if(sv_pitch_min == sv_pitch_max)
 818                 self.effects |= EF_LOWPRECISION;
 819         else
 820                 self.effects &~= EF_LOWPRECISION;
 821         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 822         if(self.owner.alpha == default_player_alpha)
 823                 self.alpha = default_weapon_alpha;
 824         else if(self.owner.alpha != 0)
 825                 self.alpha = self.owner.alpha;
 826         else
 827                 self.alpha = 1;
 828
 829         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 830         ang_y = 0;
 831         ang_z = 0;
 832
 833         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 834         {
 835                 ang_y = self.owner.v_angle_y;
 836                 makevectors(ang);
 837                 var vector v = v_forward;
 838                 var float t = self.tag_entity.frame1time;
 839                 var float f = self.tag_entity.frame;
 840                 self.tag_entity.frame1time = time;
 841                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
 842                 gettaginfo(self.tag_entity, self.tag_index);
 843                 self.tag_entity.frame1time = t;
 844                 self.tag_entity.frame = f;
 845                 // untransform v according to this coordinate space
 846                 vector w;
 847                 w_x = v_forward * v;
 848                 w_y = -v_right * v;
 849                 w_z = v_up * v;
 850                 self.angles = vectoangles(w);
 851         }
 852         else
 853         {
 854                 ang_x = -/* don't ask */ang_x;
 855                 self.angles = ang;
 856         }
 857
 858         self.colormap = self.owner.colormap;
 859 };
 860
 861 // spawning weaponentity for client
 862 void CL_SpawnWeaponentity()
 863 {
 864         self.weaponentity = spawn();
 865         self.weaponentity.classname = "weaponentity";
 866         self.weaponentity.solid = SOLID_NOT;
 867         self.weaponentity.owner = self;
 868         setmodel(self.weaponentity, ""); // precision set when changed
 869         setorigin(self.weaponentity, '0 0 0');
 870         self.weaponentity.angles = '0 0 0';
 871         self.weaponentity.viewmodelforclient = self;
 872         self.weaponentity.flags = 0;
 873         self.weaponentity.think = CL_Weaponentity_Think;
 874         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 875         self.weaponentity.nextthink = time;
 876
 877         self.exteriorweaponentity = spawn();
 878         self.exteriorweaponentity.classname = "exteriorweaponentity";
 879         self.exteriorweaponentity.solid = SOLID_NOT;
 880         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 881         self.exteriorweaponentity.owner = self;
 882         setorigin(self.exteriorweaponentity, '0 0 0');
 883         self.exteriorweaponentity.angles = '0 0 0';
 884         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 885         self.exteriorweaponentity.nextthink = time;
 886 };
 887
 888 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 889 {
 890         msg_entity = e;
 891         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 892         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 893         WriteByte(MSG_ONE, wpn);
 894         WriteString(MSG_ONE, wpnname);
 895         WriteByte(MSG_ONE, type);
 896 }
 897
 898 .float hasweapon_complain_spam;
 899
 900 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 901 {
 902         local float weaponbit, f;
 903         local entity oldself;
 904
 905         if(time < self.hasweapon_complain_spam)
 906                 complain = 0;
 907         if(complain)
 908                 self.hasweapon_complain_spam = time + 0.2;
 909
 910         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 911         {
 912                 if (complain)
 913                         sprint(self, "Invalid weapon\n");
 914                 return FALSE;
 915         }
 916         weaponbit = W_WeaponBit(wpn);
 917         if (cl.weapons & weaponbit)
 918         {
 919                 if (andammo)
 920                 {
 921                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 922                         {
 923                                 f = 1;
 924                         }
 925                         else
 926                         {
 927                                 oldself = self;
 928                                 self = cl;
 929                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 930                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 931
 932                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 933                                 local entity mine;
 934                                 if(wpn == WEP_MINE_LAYER)
 935                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 936                                         f = 1;
 937
 938                                 self = oldself;
 939                         }
 940                         if (!f)
 941                         {
 942                                 if (complain)
 943                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 944                                 {
 945                                         play2(cl, "weapons/unavailable.wav");
 946                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 947                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 948                                 }
 949                                 return FALSE;
 950                         }
 951                 }
 952                 return TRUE;
 953         }
 954         if (complain)
 955         {
 956                 // DRESK - 3/16/07
 957                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 958                 if(weaponsInMap & weaponbit)
 959                 {
 960                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 961                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 962
 963                         if(cvar("g_showweaponspawns"))
 964                         {
 965                                 entity e;
 966                                 string s;
 967
 968                                 e = get_weaponinfo(wpn);
 969                                 s = e.model2;
 970
 971                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 972                                 {
 973                                         if(e.classname == "droppedweapon")
 974                                                 continue;
 975                                         if not(e.flags & FL_ITEM)
 976                                                 continue;
 977                                         WaypointSprite_Spawn(
 978                                                 s,
 979                                                 1, 0,
 980                                                 world, e.origin,
 981                                                 self, 0,
 982                                                 world, enemy,
 983                                                 0
 984                                         );
 985                                 }
 986                         }
 987                 }
 988                 else
 989                 {
 990                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 991                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 992                 }
 993
 994                 play2(cl, "weapons/unavailable.wav");
 995         }
 996         return FALSE;
 997 };
 998
 999 // Weapon subs
1000 void w_clear()
1001 {
1002         if (self.weapon != -1)
1003                 self.weapon = 0;
1004         if (self.weaponentity)
1005         {
1006                 self.weaponentity.state = WS_CLEAR;
1007                 self.weaponentity.effects = 0;
1008         }
1009 };
1010
1011 void w_ready()
1012 {
1013         if (self.weaponentity)
1014                 self.weaponentity.state = WS_READY;
1015         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1016 };
1017
1018 // Setup weapon for client (after this raise frame will be launched)
1019 void weapon_setup(float windex)
1020 {
1021         entity e;
1022         qcweaponanimation = cvar("sv_qcweaponanimation");
1023         e = get_weaponinfo(windex);
1024         self.items &~= IT_AMMO;
1025         self.items = self.items | e.items;
1026
1027         // the two weapon entities will notice this has changed and update their models
1028         self.weapon = windex;
1029         self.weaponname = e.mdl;
1030         self.bulletcounter = 0;
1031 };
1032
1033 // perform weapon to attack (weaponstate and attack_finished check is here)
1034 void W_SwitchToOtherWeapon(entity pl)
1035 {
1036         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1037         float w, ww;
1038         w = W_WeaponBit(pl.weapon);
1039         pl.weapons &~= w;
1040         ww = w_getbestweapon(pl);
1041         pl.weapons |= w;
1042         if(ww)
1043                 W_SwitchWeapon_Force(pl, ww);
1044 }
1045 .float prevdryfire;
1046 float weapon_prepareattack_checkammo(float secondary)
1047 {
1048         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1049         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1050         {
1051                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1052                 local entity mine;
1053                 if(self.weapon == WEP_MINE_LAYER)
1054                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1055                         return FALSE;
1056
1057                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1058                 {
1059                         sound (self, CHAN_AUTO, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1060                         self.prevdryfire = time;
1061                 }
1062
1063                 W_SwitchToOtherWeapon(self);
1064                 return FALSE;
1065         }
1066         return TRUE;
1067 }
1068 .float race_penalty;
1069 float weapon_prepareattack_check(float secondary, float attacktime)
1070 {
1071         if(!weapon_prepareattack_checkammo(secondary))
1072                 return FALSE;
1073
1074         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1075         //if all players readied up and the countdown is running
1076         if(time < game_starttime || time < self.race_penalty) {
1077                 return FALSE;
1078         }
1079
1080         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1081                 return FALSE;
1082
1083         // do not even think about shooting if switching
1084         if(self.switchweapon != self.weapon)
1085                 return FALSE;
1086
1087         if(attacktime >= 0)
1088         {
1089                 // don't fire if previous attack is not finished
1090                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1091                         return FALSE;
1092                 // don't fire while changing weapon
1093                 if (self.weaponentity.state != WS_READY)
1094                         return FALSE;
1095         }
1096
1097         return TRUE;
1098 }
1099 float weapon_prepareattack_do(float secondary, float attacktime)
1100 {
1101         self.weaponentity.state = WS_INUSE;
1102
1103         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1104
1105         // if the weapon hasn't been firing continuously, reset the timer
1106         if(attacktime >= 0)
1107         {
1108                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1109                 {
1110                         ATTACK_FINISHED(self) = time;
1111                         //dprint("resetting attack finished to ", ftos(time), "\n");
1112                 }
1113                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1114         }
1115         self.bulletcounter += 1;
1116         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1117         return TRUE;
1118 }
1119 float weapon_prepareattack(float secondary, float attacktime)
1120 {
1121         if(weapon_prepareattack_check(secondary, attacktime))
1122         {
1123                 weapon_prepareattack_do(secondary, attacktime);
1124                 return TRUE;
1125         }
1126         else
1127                 return FALSE;
1128 }
1129
1130 void weapon_thinkf(float fr, float t, void() func)
1131 {
1132         vector a;
1133         vector of, or, ou;
1134         float restartanim;
1135
1136         if(fr == WFRAME_DONTCHANGE)
1137         {
1138                 fr = self.weaponentity.wframe;
1139                 restartanim = FALSE;
1140         }
1141         else if (fr == WFRAME_IDLE)
1142                 restartanim = FALSE;
1143         else
1144                 restartanim = TRUE;
1145
1146         of = v_forward;
1147         or = v_right;
1148         ou = v_up;
1149
1150         if (self.weaponentity)
1151         {
1152                 self.weaponentity.wframe = fr;
1153                 if (qcweaponanimation)
1154                 {
1155                         if (fr != WFRAME_IDLE)
1156                         {
1157                                 self.weapon_morph0time = time;
1158                                 self.weapon_morph0angles = self.weaponentity.angles;
1159                                 self.weapon_morph0origin = self.weaponentity.origin;
1160
1161                                 self.weapon_morph1angles = '0 0 0';
1162                                 self.weapon_morph1time = time + t;
1163                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1164                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1165
1166                                 self.weapon_morph2angles = '0 0 0';
1167                                 self.weapon_morph2time = time + t;
1168                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1169                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1170
1171                                 self.weapon_morph3angles = '0 0 0';
1172                                 self.weapon_morph3time = time + t;
1173                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1174                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1175
1176                                 self.weapon_morph4angles = '0 0 0';
1177                                 self.weapon_morph4time = time + t;
1178                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1179                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1180
1181                                 if (fr == WFRAME_FIRE1)
1182                                 {
1183                                         self.weapon_morph1angles = '5 0 0';
1184                                         self.weapon_morph1time = time + t * 0.1;
1185                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1186                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1187                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1188                                 }
1189                                 else if (fr == WFRAME_FIRE2)
1190                                 {
1191                                         self.weapon_morph1angles = '10 0 0';
1192                                         self.weapon_morph1time = time + t * 0.1;
1193                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1194                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1195                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1196                                 }
1197                                 else if (fr == WFRAME_RELOAD)
1198                                 {
1199                                         self.weapon_morph1time = time + t * 0.05;
1200                                         self.weapon_morph1angles = '-10 40 0';
1201                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1202                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1203
1204                                         self.weapon_morph2time = time + t * 0.15;
1205                                         self.weapon_morph2angles = '-10 40 5';
1206                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1207                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1208
1209                                         self.weapon_morph3time = time + t * 0.25;
1210                                         self.weapon_morph3angles = '-10 40 0';
1211                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1212                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1213                                 }
1214                         }
1215                 }
1216                 else
1217                 {
1218                         if (fr == WFRAME_IDLE)
1219                                 a = self.weaponentity.anim_idle;
1220                         else if (fr == WFRAME_FIRE1)
1221                                 a = self.weaponentity.anim_fire1;
1222                         else if (fr == WFRAME_FIRE2)
1223                                 a = self.weaponentity.anim_fire2;
1224                         else if (fr == WFRAME_RELOAD)
1225                                 a = self.weaponentity.anim_reload;
1226                         a_z *= g_weaponratefactor;
1227                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1228                 }
1229         }
1230
1231         v_forward = of;
1232         v_right = or;
1233         v_up = ou;
1234
1235         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1236         {
1237                 backtrace("Tried to override initial weapon think function - should this really happen?");
1238         }
1239
1240         t *= W_WeaponRateFactor();
1241
1242         // VorteX: haste can be added here
1243         if (self.weapon_think == w_ready)
1244         {
1245                 self.weapon_nextthink = time;
1246                 //dprint("started firing at ", ftos(time), "\n");
1247         }
1248         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1249         {
1250                 self.weapon_nextthink = time;
1251                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1252         }
1253         self.weapon_nextthink = self.weapon_nextthink + t;
1254         self.weapon_think = func;
1255         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1256
1257         if (restartanim)
1258         if (t)
1259         if (!self.crouch) // shoot anim stands up, this looks bad
1260         {
1261                 local vector anim;
1262                 anim = self.anim_shoot;
1263                 anim_z = anim_y / (t + sys_frametime);
1264                 setanim(self, anim, FALSE, TRUE, TRUE);
1265         }
1266 };
1267
1268 void weapon_boblayer1(float spd, vector org)
1269 {
1270         // VorteX: haste can be added here
1271 };
1272
1273 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1274 {
1275         vector mdirection;
1276         float mspeed;
1277         float outspeed;
1278         float nstyle;
1279         vector outvelocity;
1280
1281         mvelocity = mvelocity * g_weaponspeedfactor;
1282
1283         mdirection = normalize(mvelocity);
1284         mspeed = vlen(mvelocity);
1285
1286         nstyle = cvar("g_projectiles_newton_style");
1287         if(nstyle == 0)
1288         {
1289                 // absolute velocity
1290                 outvelocity = mvelocity;
1291         }
1292         else if(nstyle == 1)
1293         {
1294                 // true Newtonian projectiles
1295                 outvelocity = pvelocity + mvelocity;
1296         }
1297         else if(nstyle == 2)
1298         {
1299                 // true Newtonian projectiles with automatic aim adjustment
1300                 //
1301                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1302                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1303                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1304                 // PLUS SIGN!
1305                 // not defined?
1306                 // then...
1307                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1308                 // velocity without mdirection component > mspeed
1309                 // fire at smallest possible mspeed that works?
1310                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1311
1312                 vector solution;
1313                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1314                 if(solution_z)
1315                         outspeed = solution_y; // the larger one
1316                 else
1317                 {
1318                         //outspeed = 0; // slowest possible shot
1319                         outspeed = solution_x; // the real part (that is, the average!)
1320                         //dprint("impossible shot, adjusting\n");
1321                 }
1322
1323                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1324                 outvelocity = mdirection * outspeed;
1325         }
1326         else if(nstyle == 3)
1327         {
1328                 // pseudo-Newtonian:
1329                 outspeed = mspeed + mdirection * pvelocity;
1330                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1331                 outvelocity = mdirection * outspeed;
1332         }
1333         else if(nstyle == 4)
1334         {
1335                 // tZorkian:
1336                 outspeed = mspeed + vlen(pvelocity);
1337                 outvelocity = mdirection * outspeed;
1338         }
1339         else
1340                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1341
1342         return outvelocity;
1343 }
1344
1345 void W_AttachToShotorg(entity flash, vector offset)
1346 {
1347         entity xflash;
1348         flash.owner = self;
1349         flash.angles_z = random() * 360;
1350         if(qcweaponanimation)
1351         {
1352                 setorigin(flash, w_shotorg + w_shotdir * 50);
1353                 flash.angles = vectoangles(w_shotdir);
1354                 flash.angles_z = random() * 360;
1355         }
1356         else
1357         {
1358                 if(gettagindex(self.weaponentity, "shot"))
1359                         setattachment(flash, self.weaponentity, "shot");
1360                 else
1361                         setattachment(flash, self.weaponentity, "tag_shot");
1362                 setorigin(flash, offset);
1363
1364                 xflash = spawn();
1365                 copyentity(flash, xflash);
1366
1367                 flash.viewmodelforclient = self;
1368
1369                 if(self.weaponentity.oldorigin_x > 0)
1370                 {
1371                         setattachment(xflash, self.exteriorweaponentity, "");
1372                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1373                 }
1374                 else
1375                 {
1376                         if(gettagindex(self.exteriorweaponentity, "shot"))
1377                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1378                         else
1379                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1380                         setorigin(xflash, offset);
1381                 }
1382         }
1383 }
1384
1385 vector cliptoplane(vector v, vector p)
1386 {
1387         return v - (v * p) * p;
1388 }
1389
1390 vector solve_cubic_pq(float p, float q)
1391 {
1392         float D, u, v, a;
1393         D = q*q/4.0 + p*p*p/27.0;
1394         if(D < 0)
1395         {
1396                 // irreducibilis
1397                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1398                 u = sqrt(-4.0/3.0 * p);
1399                 // a in range 0..pi/3
1400                 // cos(a)
1401                 // cos(a + 2pi/3)
1402                 // cos(a + 4pi/3)
1403                 return
1404                         u *
1405                         (
1406                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1407                                 +
1408                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1409                                 +
1410                                 '0 0 1' * cos(a)
1411                         );
1412         }
1413         else if(D == 0)
1414         {
1415                 // simple
1416                 if(p == 0)
1417                         return '0 0 0';
1418                 u = 3*q/p;
1419                 v = -u/2;
1420                 if(u >= v)
1421                         return '1 1 0' * v + '0 0 1' * u;
1422                 else
1423                         return '0 1 1' * v + '1 0 0' * u;
1424         }
1425         else
1426         {
1427                 // cardano
1428                 u = cbrt(-q/2.0 + sqrt(D));
1429                 v = cbrt(-q/2.0 - sqrt(D));
1430                 return '1 1 1' * (u + v);
1431         }
1432 }
1433 vector solve_cubic_abcd(float a, float b, float c, float d)
1434 {
1435         // y = 3*a*x + b
1436         // x = (y - b) / 3a
1437         float p, q;
1438         vector v;
1439         p = (9*a*c - 3*b*b);
1440         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1441         v = solve_cubic_pq(p, q);
1442         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1443         if(a < 0)
1444                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1445         return v;
1446 }
1447
1448 vector findperpendicular(vector v)
1449 {
1450         vector p;
1451         p_x = v_z;
1452         p_y = -v_x;
1453         p_z = v_y;
1454         return normalize(cliptoplane(p, v));
1455 }
1456
1457 vector W_CalculateProjectileSpread(vector forward, float spread)
1458 {
1459         float sigma;
1460         vector v1, v2;
1461         float dx, dy, r;
1462         float sstyle;
1463         spread *= g_weaponspreadfactor;
1464         if(spread <= 0)
1465                 return forward;
1466         sstyle = cvar("g_projectiles_spread_style");
1467
1468         if(sstyle == 0)
1469         {
1470                 // this is the baseline for the spread value!
1471                 // standard deviation: sqrt(2/5)
1472                 // density function: sqrt(1-r^2)
1473                 return forward + randomvec() * spread;
1474         }
1475         else if(sstyle == 1)
1476         {
1477                 // same thing, basically
1478                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1479         }
1480         else if(sstyle == 2)
1481         {
1482                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1483                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1484                 v1 = findperpendicular(forward);
1485                 v2 = cross(forward, v1);
1486                 // random point on unit circle
1487                 dx = random() * 2 * M_PI;
1488                 dy = sin(dx);
1489                 dx = cos(dx);
1490                 // radius in our dist function
1491                 r = random();
1492                 r = sqrt(r);
1493                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1494         }
1495         else if(sstyle == 3) // gauss 3d
1496         {
1497                 sigma = spread * 0.44721359549996; // match baseline stddev
1498                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1499                 v1 = forward;
1500                 v1_x += gsl_ran_gaussian(sigma);
1501                 v1_y += gsl_ran_gaussian(sigma);
1502                 v1_z += gsl_ran_gaussian(sigma);
1503                 return v1;
1504         }
1505         else if(sstyle == 4) // gauss 2d
1506         {
1507                 sigma = spread * 0.44721359549996; // match baseline stddev
1508                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1509                 v1_x = gsl_ran_gaussian(sigma);
1510                 v1_y = gsl_ran_gaussian(sigma);
1511                 v1_z = gsl_ran_gaussian(sigma);
1512                 return normalize(forward + cliptoplane(v1, forward));
1513         }
1514         else if(sstyle == 5) // 1-r
1515         {
1516                 sigma = spread * 1.154700538379252; // match baseline stddev
1517                 v1 = findperpendicular(forward);
1518                 v2 = cross(forward, v1);
1519                 // random point on unit circle
1520                 dx = random() * 2 * M_PI;
1521                 dy = sin(dx);
1522                 dx = cos(dx);
1523                 // radius in our dist function
1524                 r = random();
1525                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1526                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1527         }
1528         else if(sstyle == 6) // 1-r^2
1529         {
1530                 sigma = spread * 1.095445115010332; // match baseline stddev
1531                 v1 = findperpendicular(forward);
1532                 v2 = cross(forward, v1);
1533                 // random point on unit circle
1534                 dx = random() * 2 * M_PI;
1535                 dy = sin(dx);
1536                 dx = cos(dx);
1537                 // radius in our dist function
1538                 r = random();
1539                 r = sqrt(1 - r);
1540                 r = sqrt(1 - r);
1541                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1542         }
1543         else if(sstyle == 7) // (1-r) (2-r)
1544         {
1545                 sigma = spread * 1.224744871391589; // match baseline stddev
1546                 v1 = findperpendicular(forward);
1547                 v2 = cross(forward, v1);
1548                 // random point on unit circle
1549                 dx = random() * 2 * M_PI;
1550                 dy = sin(dx);
1551                 dx = cos(dx);
1552                 // radius in our dist function
1553                 r = random();
1554                 r = 1 - sqrt(r);
1555                 r = 1 - sqrt(r);
1556                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1557         }
1558         else
1559                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1560         return '0 0 0';
1561         /*
1562          * how to derive falloff functions:
1563          * rho(r) := (2-r) * (1-r);
1564          * a : 0;
1565          * b : 1;
1566          * rhor(r) := r * rho(r);
1567          * cr(t) := integrate(rhor(r), r, a, t);
1568          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1569          * variance : scr(b) / cr(b);
1570          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1571          * sqrt(0.4 / variance), numer;
1572          */
1573 }
1574
1575 #if 0
1576 float mspercallsum;
1577 float mspercallsstyle;
1578 float mspercallcount;
1579 #endif
1580 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)
1581 {
1582         if(missile.owner == world)
1583                 error("Unowned missile");
1584
1585         dir = dir + upDir * (pUpSpeed / pSpeed);
1586         dir_z += pZSpeed / pSpeed;
1587         pSpeed *= vlen(dir);
1588         dir = normalize(dir);
1589
1590 #if 0
1591         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1592         {
1593                 mspercallsum = mspercallcount = 0;
1594                 mspercallsstyle = cvar("g_projectiles_spread_style");
1595         }
1596         mspercallsum -= gettime(GETTIME_HIRES);
1597 #endif
1598         dir = W_CalculateProjectileSpread(dir, spread);
1599 #if 0
1600         mspercallsum += gettime(GETTIME_HIRES);
1601         mspercallcount += 1;
1602         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1603 #endif
1604
1605         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1606 }
1607
1608 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1609 {
1610         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);
1611 }
1612
1613 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))
1614 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))