qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage, float range)
 134 {
 135         float nudge = 1; // added to traceline target and subtracted from result
 136         local float oldsolid;
 137         vector vecs, dv;
 138         oldsolid = ent.dphitcontentsmask;
 139         if(ent.weapon == WEP_CAMPINGRIFLE)
 140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 141         else
 142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         if(antilag)
 144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 145                 // passing world, because we do NOT want it to touch dphitcontentsmask
 146         else
 147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 149
 150         vector vf, vr, vu;
 151         vf = v_forward;
 152         vr = v_right;
 153         vu = v_up;
 154         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 155         v_forward = vf;
 156         v_right = vr;
 157         v_up = vu;
 158
 159         // track max damage
 160         if not(inWarmupStage) {
 161                 entity w;
 162                 w = get_weaponinfo(ent.weapon);
 163                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage
 164                         ent.stats_fired[ent.weapon - 1] += maxdamage;
 165                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
 166                 }
 167         }
 168
 169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 170
 171         if(ent.weaponentity.movedir_x > 0)
 172                 vecs = ent.weaponentity.movedir;
 173         else
 174                 vecs = '0 0 0';
 175         if(debug_shotorg != '0 0 0')
 176                 vecs = debug_shotorg;
 177
 178         dv = v_right * -vecs_y + v_up * vecs_z;
 179         w_shotorg = ent.origin + ent.view_ofs + dv;
 180
 181         // now move the shotorg forward as much as requested if possible
 182         if(antilag)
 183         {
 184                 if(ent.antilag_debug)
 185                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 186                 else
 187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 188         }
 189         else
 190                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 191         w_shotorg = trace_endpos - v_forward * nudge;
 192         // calculate the shotdir from the chosen shotorg
 193         w_shotdir = normalize(w_shotend - w_shotorg);
 194
 195         if (antilag)
 196         if (!ent.cvar_cl_noantilag)
 197         {
 198                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 199                 {
 200                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 201                         if (!trace_ent.takedamage)
 202                         {
 203                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 204                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 205                                 {
 206                                         entity e;
 207                                         e = trace_ent;
 208                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 209                                         if(trace_ent == e)
 210                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 211                                 }
 212                         }
 213                 }
 214                 else if(cvar("g_antilag") == 3) // client side hitscan
 215                 {
 216                         // this part MUST use prydon cursor
 217                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 218                         if (ent.cursor_trace_ent != ent)         // just to make sure
 219                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 220                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 221                         {
 222                                 // verify that the shot would miss without antilag
 223                                 // (avoids an issue where guns would always shoot at their origin)
 224                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 225                                 if (!trace_ent.takedamage)
 226                                 {
 227                                         // verify that the shot would hit if altered
 228                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 229                                         if (trace_ent == ent.cursor_trace_ent)
 230                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 231                                         else
 232                                                 print("antilag fail\n");
 233                                 }
 234                         }
 235                 }
 236         }
 237
 238         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 239
 240         if (!g_norecoil)
 241                 ent.punchangle_x = recoil * -1;
 242
 243         if (snd != "")
 244         {
 245                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 246         }
 247
 248         if (ent.items & IT_STRENGTH)
 249         if (!g_minstagib)
 250                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 251
 252         // nudge w_shotend so a trace to w_shotend hits
 253         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 254 };
 255
 256 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, maxdamage, MAX_SHOT_DISTANCE)
 257 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 258 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 259 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 260 #define W_SetupShot_Range(ent,antilag,recoil,snd,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage, range)
 261
 262 void LaserTarget_Think()
 263 {
 264         entity e;
 265         vector offset;
 266         float uselaser;
 267         uselaser = 0;
 268
 269         // list of weapons that will use the laser, and the options that enable it
 270         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 271                 uselaser = 1;
 272         // example
 273         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 274         //      uselaser = 1;
 275
 276
 277
 278         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 279         if(!uselaser)
 280         {
 281                 // rocket launcher isn't selected, so no laser target.
 282                 if(self.lasertarget != world)
 283                 {
 284                         remove(self.lasertarget);
 285                         self.lasertarget = world;
 286                 }
 287                 return;
 288         }
 289
 290         if(!self.lasertarget)
 291         {
 292                 // we don't have a lasertarget entity, so spawn one
 293                 //bprint("create laser target\n");
 294                 e = self.lasertarget = spawn();
 295                 e.owner = self.owner;                   // Its owner is my owner
 296                 e.classname = "laser_target";
 297                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 298                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 299                 e.scale = 1.25;                         // make it larger
 300                 e.alpha = 0.25;                         // transparency
 301                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 302                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 303                 // make it dynamically glow
 304                 // you should avoid over-using this, as it can slow down the player's computer.
 305                 e.glow_color = 251; // red color
 306                 e.glow_size = 12;
 307         }
 308         else
 309                 e = self.lasertarget;
 310
 311         // move the laser dot to where the player is looking
 312
 313         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 314         offset = '0 0 26' + v_right*3;
 315         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 316         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 317         if(trace_plane_normal != '0 0 0')
 318                 e.angles = vectoangles(trace_plane_normal);
 319         else
 320                 e.angles = vectoangles(v_forward);
 321 }
 322
 323 float CL_Weaponentity_CustomizeEntityForClient()
 324 {
 325         self.viewmodelforclient = self.owner;
 326         if(other.classname == "spectator")
 327                 if(other.enemy == self.owner)
 328                         self.viewmodelforclient = other;
 329         return TRUE;
 330 }
 331
 332 float qcweaponanimation;
 333 vector weapon_offset = '0 -10 0';
 334 vector weapon_adjust = '10 0 -15';
 335 .vector weapon_morph0origin;
 336 .vector weapon_morph0angles;
 337 .float  weapon_morph0time;
 338 .vector weapon_morph1origin;
 339 .vector weapon_morph1angles;
 340 .float  weapon_morph1time;
 341 .vector weapon_morph2origin;
 342 .vector weapon_morph2angles;
 343 .float  weapon_morph2time;
 344 .vector weapon_morph3origin;
 345 .vector weapon_morph3angles;
 346 .float  weapon_morph3time;
 347 .vector weapon_morph4origin;
 348 .vector weapon_morph4angles;
 349 .float  weapon_morph4time;
 350 .string weaponname;
 351 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 352
 353 /*
 354  * supported formats:
 355  *
 356  * 1. simple animated model, muzzle flash handling on h_ model:
 357  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 358  *      tags:
 359  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 360  *        shell = casings ejection point (must be on the right hand side of the gun)
 361  *        weapon = attachment for v_tuba.md3
 362  *    v_tuba.md3 - first and third person model
 363  *    g_tuba.md3 - pickup model
 364  *
 365  * 2. simple animated model, muzzle flash handling on v_ model:
 366  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 367  *      tags:
 368  *        weapon = attachment for v_tuba.md3
 369  *    v_tuba.md3 - first and third person model
 370  *      tags:
 371  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 372  *        shell = casings ejection point (must be on the right hand side of the gun)
 373  *    g_tuba.md3 - pickup model
 374  *
 375  * 3. fully animated model, muzzle flash handling on h_ model:
 376  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 377  *      tags:
 378  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 379  *        shell = casings ejection point (must be on the right hand side of the gun)
 380  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 381  *    v_tuba.md3 - third person model
 382  *    g_tuba.md3 - pickup model
 383  *
 384  * 4. fully animated model, muzzle flash handling on v_ model:
 385  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 386  *      tags:
 387  *        shot = muzzle end (shot origin)
 388  *        shell = casings ejection point (must be on the right hand side of the gun)
 389  *    v_tuba.md3 - third person model
 390  *      tags:
 391  *        shot = muzzle end (for muzzle flashes)
 392  *    g_tuba.md3 - pickup model
 393  */
 394
 395 // writes:
 396 //   self.origin, self.angles
 397 //   self.weaponentity
 398 //   self.movedir, self.view_ofs
 399 //   attachment stuff
 400 //   anim stuff
 401 // to free:
 402 //   call again with ""
 403 //   remove the ent
 404 void CL_WeaponEntity_SetModel(string name)
 405 {
 406         string animfilename;
 407         float animfile;
 408         float v_shot_idx;
 409         if (name != "")
 410         {
 411                 // if there is a child entity, hide it until we're sure we use it
 412                 if (self.weaponentity)
 413                         self.weaponentity.model = "";
 414                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 415                 v_shot_idx = gettagindex(self, "shot"); // used later
 416                 if(!v_shot_idx)
 417                         v_shot_idx = gettagindex(self, "tag_shot");
 418
 419                 if(qcweaponanimation)
 420                 {
 421                         self.angles = '0 0 0';
 422                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 423                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 424                         self.movedir_x += 32;
 425                         self.spawnorigin = self.movedir;
 426                         // oldorigin - not calculated here
 427                 }
 428                 else
 429                 {
 430                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 431                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 432                         animfile = fopen(animfilename, FILE_READ);
 433                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 434                         self.anim_fire1  = '0 1 0.01';
 435                         self.anim_fire2  = '1 1 0.01';
 436                         self.anim_idle   = '2 1 0.01';
 437                         self.anim_reload = '3 1 0.01';
 438                         if (animfile >= 0)
 439                         {
 440                                 animparseerror = FALSE;
 441                                 self.anim_fire1  = animparseline(animfile);
 442                                 self.anim_fire2  = animparseline(animfile);
 443                                 self.anim_idle   = animparseline(animfile);
 444                                 self.anim_reload = animparseline(animfile);
 445                                 fclose(animfile);
 446                                 if (animparseerror)
 447                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 448                         }
 449
 450                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 451                         // if we don't, this is a "real" animated model
 452                         if(gettagindex(self, "weapon"))
 453                         {
 454                                 if (!self.weaponentity)
 455                                         self.weaponentity = spawn();
 456                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 457                                 setattachment(self.weaponentity, self, "weapon");
 458                         }
 459                         else if(gettagindex(self, "tag_weapon"))
 460                         {
 461                                 if (!self.weaponentity)
 462                                         self.weaponentity = spawn();
 463                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 464                                 setattachment(self.weaponentity, self, "tag_weapon");
 465                         }
 466                         else
 467                         {
 468                                 if(self.weaponentity)
 469                                         remove(self.weaponentity);
 470                                 self.weaponentity = world;
 471                         }
 472
 473                         setorigin(self,'0 0 0');
 474                         self.angles = '0 0 0';
 475                         self.frame = 0;
 476                         self.viewmodelforclient = world;
 477
 478                         float idx;
 479
 480                         if(v_shot_idx) // v_ model attached to invisible h_ model
 481                         {
 482                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 483                         }
 484                         else
 485                         {
 486                                 idx = gettagindex(self, "shot");
 487                                 if(!idx)
 488                                         idx = gettagindex(self, "tag_shot");
 489                                 if(idx)
 490                                         self.movedir = gettaginfo(self, idx);
 491                                 else
 492                                 {
 493                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 494                                         self.movedir = '0 0 0';
 495                                 }
 496                         }
 497
 498                         if(self.weaponentity) // v_ model attached to invisible h_ model
 499                         {
 500                                 idx = gettagindex(self.weaponentity, "shell");
 501                                 if(!idx)
 502                                         idx = gettagindex(self.weaponentity, "tag_shell");
 503                                 if(idx)
 504                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 505                         }
 506                         else
 507                                 idx = 0;
 508                         if(!idx)
 509                         {
 510                                 idx = gettagindex(self, "shell");
 511                                 if(!idx)
 512                                         idx = gettagindex(self, "tag_shell");
 513                                 if(idx)
 514                                         self.spawnorigin = gettaginfo(self, idx);
 515                                 else
 516                                 {
 517                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 518                                         self.spawnorigin = self.movedir;
 519                                 }
 520                         }
 521
 522                         if(v_shot_idx)
 523                         {
 524                                 self.oldorigin = '0 0 0'; // use regular attachment
 525                         }
 526                         else
 527                         {
 528                                 if(self.weaponentity)
 529                                 {
 530                                         idx = gettagindex(self, "weapon");
 531                                         if(!idx)
 532                                                 idx = gettagindex(self, "tag_weapon");
 533                                 }
 534                                 else
 535                                 {
 536                                         idx = gettagindex(self, "handle");
 537                                         if(!idx)
 538                                                 idx = gettagindex(self, "tag_handle");
 539                                 }
 540                                 if(idx)
 541                                 {
 542                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 543                                 }
 544                                 else
 545                                 {
 546                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 547                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 548                                 }
 549                         }
 550
 551                         self.viewmodelforclient = self.owner;
 552                 }
 553         }
 554         else
 555         {
 556                 self.model = "";
 557                 if(self.weaponentity)
 558                         remove(self.weaponentity);
 559                 self.weaponentity = world;
 560                 self.movedir = '0 0 0';
 561                 self.spawnorigin = '0 0 0';
 562                 self.oldorigin = '0 0 0';
 563                 self.anim_fire1  = '0 1 0.01';
 564                 self.anim_fire2  = '0 1 0.01';
 565                 self.anim_idle   = '0 1 0.01';
 566                 self.anim_reload = '0 1 0.01';
 567         }
 568
 569         self.view_ofs = '0 0 0';
 570
 571         if(self.movedir_x >= 0)
 572         {
 573                 vector v0;
 574                 v0 = self.movedir;
 575                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 576                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 577         }
 578         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 579         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 580
 581         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 582
 583         // check if an instant weapon switch occurred
 584         if (qcweaponanimation)
 585         {
 586                 if (self.state == WS_READY)
 587                 {
 588                         self.angles = '0 0 0';
 589                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 590                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 591                 }
 592         }
 593         else
 594                 setorigin(self, self.view_ofs);
 595         // reset animstate now
 596         self.wframe = WFRAME_IDLE;
 597         self.weapon_morph0time = 0;
 598         self.weapon_morph1time = 0;
 599         self.weapon_morph2time = 0;
 600         self.weapon_morph3time = 0;
 601         self.weapon_morph4time = 0;
 602         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 603 }
 604
 605 vector CL_Weapon_GetShotOrg(float wpn)
 606 {
 607         entity wi, oldself;
 608         vector ret;
 609         wi = get_weaponinfo(wpn);
 610         oldself = self;
 611         self = spawn();
 612         CL_WeaponEntity_SetModel(wi.mdl);
 613         ret = self.movedir;
 614         CL_WeaponEntity_SetModel("");
 615         remove(self);
 616         self = oldself;
 617         return ret;
 618 }
 619
 620 void CL_Weaponentity_Think()
 621 {
 622         float tb;
 623         self.nextthink = time;
 624         if (intermission_running)
 625                 self.frame = self.anim_idle_x;
 626         if (self.owner.weaponentity != self)
 627         {
 628                 if (self.weaponentity)
 629                         remove(self.weaponentity);
 630                 remove(self);
 631                 return;
 632         }
 633         if (self.owner.deadflag != DEAD_NO)
 634         {
 635                 self.model = "";
 636                 if (self.weaponentity)
 637                         self.weaponentity.model = "";
 638                 return;
 639         }
 640         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 641         {
 642                 self.cnt = self.owner.weapon;
 643                 self.dmg = self.owner.modelindex;
 644                 self.deadflag = self.owner.deadflag;
 645
 646                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 647         }
 648
 649         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 650         self.effects = self.owner.effects & EFMASK_CHEAP;
 651         self.effects &~= EF_LOWPRECISION;
 652         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 653         self.effects &~= EF_TELEPORT_BIT;
 654         self.effects &~= EF_RESTARTANIM_BIT;
 655         self.effects |= tb;
 656
 657         if(self.owner.alpha == default_player_alpha)
 658                 self.alpha = default_weapon_alpha;
 659         else if(self.owner.alpha != 0)
 660                 self.alpha = self.owner.alpha;
 661         else
 662                 self.alpha = 1;
 663
 664         self.colormap = self.owner.colormap;
 665         if (self.weaponentity)
 666         {
 667                 self.weaponentity.effects = self.effects;
 668                 self.weaponentity.alpha = self.alpha;
 669                 self.weaponentity.colormap = self.colormap;
 670         }
 671
 672         self.angles = '0 0 0';
 673         local float f;
 674         f = 0;
 675         if (self.state == WS_RAISE && !intermission_running)
 676         {
 677                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 678                 self.angles_x = -90 * f * f;
 679                 if (qcweaponanimation)
 680                 {
 681                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 682                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 683                 }
 684         }
 685         else if (self.state == WS_DROP && !intermission_running)
 686         {
 687                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 688                 self.angles_x = -90 * f * f;
 689                 if (qcweaponanimation)
 690                 {
 691                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 692                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 693                 }
 694         }
 695         else if (self.state == WS_CLEAR)
 696         {
 697                 f = 1;
 698                 self.angles_x = -90 * f * f;
 699                 if (qcweaponanimation)
 700                 {
 701                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 702                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 703                 }
 704         }
 705         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 706         {
 707                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 708                 f = 1 - pow(1 - f, 3);
 709                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 710                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 711         }
 712         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 713         {
 714                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 715                 f = 1 - pow(1 - f, 3);
 716                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 717                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 718         }
 719         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 720         {
 721                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 722                 f = 1 - pow(1 - f, 3);
 723                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 724                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 725         }
 726         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 727         {
 728                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 729                 f = 1 - pow(1 - f, 3);
 730                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 731                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 732         }
 733         else if (qcweaponanimation)
 734         {
 735                 // begin a new idle morph
 736                 self.owner.weapon_morph0time   = time;
 737                 self.owner.weapon_morph0angles = self.angles;
 738                 self.owner.weapon_morph0origin = self.origin;
 739
 740                 float r;
 741                 float t;
 742
 743                 r = random();
 744                 if (r < 0.1)
 745                 {
 746                         // turn gun to the left to look at it
 747                         t = 2;
 748                         self.owner.weapon_morph1time   = time + t * 0.2;
 749                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 750                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 751                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 752
 753                         self.owner.weapon_morph2time   = time + t * 0.6;
 754                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 755                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 756                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 757
 758                         self.owner.weapon_morph3time   = time + t;
 759                         self.owner.weapon_morph3angles = '0 0 0';
 760                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 761                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 762                 }
 763                 else if (r < 0.2)
 764                 {
 765                         // raise the gun a bit
 766                         t = 2;
 767                         self.owner.weapon_morph1time   = time + t * 0.2;
 768                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 769                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 770                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 771
 772                         self.owner.weapon_morph2time   = time + t * 0.5;
 773                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 774                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 775                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 776
 777                         self.owner.weapon_morph3time   = time + t;
 778                         self.owner.weapon_morph3angles = '0 0 0';
 779                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 780                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 781                 }
 782                 else if (r < 0.3)
 783                 {
 784                         // tweak it a bit
 785                         t = 5;
 786                         self.owner.weapon_morph1time   = time + t * 0.3;
 787                         self.owner.weapon_morph1angles = randomvec() * 6;
 788                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 789                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 790
 791                         self.owner.weapon_morph2time   = time + t * 0.7;
 792                         self.owner.weapon_morph2angles = randomvec() * 6;
 793                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 794                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 795
 796                         self.owner.weapon_morph3time   = time + t;
 797                         self.owner.weapon_morph3angles = '0 0 0';
 798                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 799                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 800                 }
 801                 else
 802                 {
 803                         // hold it mostly steady
 804                         t = random() * 6 + 4;
 805                         self.owner.weapon_morph1time   = time + t * 0.2;
 806                         self.owner.weapon_morph1angles = randomvec() * 1;
 807                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 808                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 809
 810                         self.owner.weapon_morph2time   = time + t * 0.5;
 811                         self.owner.weapon_morph2angles = randomvec() * 1;
 812                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 813                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 814
 815                         self.owner.weapon_morph3time   = time + t * 0.7;
 816                         self.owner.weapon_morph3angles = randomvec() * 1;
 817                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 818                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 819                 }
 820
 821                 self.owner.weapon_morph4time   = time + t;
 822                 self.owner.weapon_morph4angles = '0 0 0';
 823                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 824                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 825
 826         }
 827
 828         // create or update the lasertarget entity
 829         LaserTarget_Think();
 830 };
 831
 832 void CL_ExteriorWeaponentity_Think()
 833 {
 834         float tag_found;
 835         vector ang;
 836         self.nextthink = time;
 837         if (self.owner.exteriorweaponentity != self)
 838         {
 839                 remove(self);
 840                 return;
 841         }
 842         if (self.owner.deadflag != DEAD_NO)
 843         {
 844                 self.model = "";
 845                 return;
 846         }
 847         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 848         {
 849                 self.cnt = self.owner.weapon;
 850                 self.dmg = self.owner.modelindex;
 851                 self.deadflag = self.owner.deadflag;
 852                 if (self.owner.weaponname != "")
 853                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 854                 else
 855                         self.model = "";
 856
 857                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 858                 {
 859                         self.tag_index = tag_found;
 860                         self.tag_entity = self.owner;
 861                 }
 862                 else
 863                         setattachment(self, self.owner, "bip01 r hand");
 864
 865                 // if that didn't find a tag, hide the exterior weapon model
 866                 if (!self.tag_index)
 867                         self.model = "";
 868         }
 869         self.effects = self.owner.effects;
 870         if(sv_pitch_min == sv_pitch_max)
 871                 self.effects |= EF_LOWPRECISION;
 872         else
 873                 self.effects &~= EF_LOWPRECISION;
 874         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 875         if(self.owner.alpha == default_player_alpha)
 876                 self.alpha = default_weapon_alpha;
 877         else if(self.owner.alpha != 0)
 878                 self.alpha = self.owner.alpha;
 879         else
 880                 self.alpha = 1;
 881
 882         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 883         ang_y = 0;
 884         ang_z = 0;
 885
 886         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 887         {
 888                 ang_y = self.owner.v_angle_y;
 889                 makevectors(ang);
 890                 var vector v = v_forward;
 891                 var float t = self.tag_entity.frame1time;
 892                 var float f = self.tag_entity.frame;
 893                 self.tag_entity.frame1time = time;
 894                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
 895                 gettaginfo(self.tag_entity, self.tag_index);
 896                 self.tag_entity.frame1time = t;
 897                 self.tag_entity.frame = f;
 898                 // untransform v according to this coordinate space
 899                 vector w;
 900                 w_x = v_forward * v;
 901                 w_y = -v_right * v;
 902                 w_z = v_up * v;
 903                 self.angles = vectoangles(w);
 904         }
 905         else
 906         {
 907                 ang_x = -/* don't ask */ang_x;
 908                 self.angles = ang;
 909         }
 910
 911         self.colormap = self.owner.colormap;
 912 };
 913
 914 // spawning weaponentity for client
 915 void CL_SpawnWeaponentity()
 916 {
 917         self.weaponentity = spawn();
 918         self.weaponentity.classname = "weaponentity";
 919         self.weaponentity.solid = SOLID_NOT;
 920         self.weaponentity.owner = self;
 921         setmodel(self.weaponentity, ""); // precision set when changed
 922         setorigin(self.weaponentity, '0 0 0');
 923         self.weaponentity.angles = '0 0 0';
 924         self.weaponentity.viewmodelforclient = self;
 925         self.weaponentity.flags = 0;
 926         self.weaponentity.think = CL_Weaponentity_Think;
 927         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 928         self.weaponentity.nextthink = time;
 929
 930         self.exteriorweaponentity = spawn();
 931         self.exteriorweaponentity.classname = "exteriorweaponentity";
 932         self.exteriorweaponentity.solid = SOLID_NOT;
 933         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 934         self.exteriorweaponentity.owner = self;
 935         setorigin(self.exteriorweaponentity, '0 0 0');
 936         self.exteriorweaponentity.angles = '0 0 0';
 937         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 938         self.exteriorweaponentity.nextthink = time;
 939 };
 940
 941 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 942 {
 943         msg_entity = e;
 944         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 945         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 946         WriteByte(MSG_ONE, wpn);
 947         WriteString(MSG_ONE, wpnname);
 948         WriteByte(MSG_ONE, type);
 949 }
 950
 951 .float hasweapon_complain_spam;
 952
 953 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 954 {
 955         local float weaponbit, f;
 956         local entity oldself;
 957
 958         if(time < self.hasweapon_complain_spam)
 959                 complain = 0;
 960         if(complain)
 961                 self.hasweapon_complain_spam = time + 0.2;
 962
 963         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 964         {
 965                 if (complain)
 966                         sprint(self, "Invalid weapon\n");
 967                 return FALSE;
 968         }
 969         weaponbit = W_WeaponBit(wpn);
 970         if (cl.weapons & weaponbit)
 971         {
 972                 if (andammo)
 973                 {
 974                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 975                         {
 976                                 f = 1;
 977                         }
 978                         else
 979                         {
 980                                 oldself = self;
 981                                 self = cl;
 982                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 983                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 984                                 self = oldself;
 985                         }
 986                         if (!f)
 987                         {
 988                                 if (complain)
 989                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 990                                 {
 991                                         play2(cl, "weapons/unavailable.wav");
 992                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 993                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 994                                 }
 995                                 return FALSE;
 996                         }
 997                 }
 998                 return TRUE;
 999         }
1000         if (complain)
1001         {
1002                 // DRESK - 3/16/07
1003                 // Report Proper Weapon Status / Modified Weapon Ownership Message
1004                 if(weaponsInMap & weaponbit)
1005                 {
1006                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
1007                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
1008
1009                         if(cvar("g_showweaponspawns"))
1010                         {
1011                                 entity e;
1012                                 string s;
1013
1014                                 e = get_weaponinfo(wpn);
1015                                 s = e.model2;
1016
1017                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
1018                                 {
1019                                         if(e.classname == "droppedweapon")
1020                                                 continue;
1021                                         if not(e.flags & FL_ITEM)
1022                                                 continue;
1023                                         WaypointSprite_Spawn(
1024                                                 s,
1025                                                 1, 0,
1026                                                 world, e.origin,
1027                                                 self, 0,
1028                                                 world, enemy,
1029                                                 0
1030                                         );
1031                                 }
1032                         }
1033                 }
1034                 else
1035                 {
1036                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1037                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1038                 }
1039
1040                 play2(cl, "weapons/unavailable.wav");
1041         }
1042         return FALSE;
1043 };
1044
1045 // Weapon subs
1046 void w_clear()
1047 {
1048         if (self.weapon != -1)
1049                 self.weapon = 0;
1050         if (self.weaponentity)
1051         {
1052                 self.weaponentity.state = WS_CLEAR;
1053                 self.weaponentity.effects = 0;
1054         }
1055 };
1056
1057 void w_ready()
1058 {
1059         if (self.weaponentity)
1060                 self.weaponentity.state = WS_READY;
1061         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1062 };
1063
1064 // Setup weapon for client (after this raise frame will be launched)
1065 void weapon_setup(float windex)
1066 {
1067         entity e;
1068         qcweaponanimation = cvar("sv_qcweaponanimation");
1069         e = get_weaponinfo(windex);
1070         self.items &~= IT_AMMO;
1071         self.items = self.items | e.items;
1072
1073         // the two weapon entities will notice this has changed and update their models
1074         self.weapon = windex;
1075         self.weaponname = e.mdl;
1076         self.bulletcounter = 0;
1077 };
1078
1079 // perform weapon to attack (weaponstate and attack_finished check is here)
1080 void W_SwitchToOtherWeapon(entity pl)
1081 {
1082         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1083         float w, ww;
1084         w = W_WeaponBit(pl.weapon);
1085         pl.weapons &~= w;
1086         ww = w_getbestweapon(pl);
1087         pl.weapons |= w;
1088         if(ww)
1089                 W_SwitchWeapon_Force(pl, ww);
1090 }
1091 float weapon_prepareattack_checkammo(float secondary)
1092 {
1093         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1094         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1095         {
1096                 W_SwitchToOtherWeapon(self);
1097                 return FALSE;
1098         }
1099         return TRUE;
1100 }
1101 .float race_penalty;
1102 float weapon_prepareattack_check(float secondary, float attacktime)
1103 {
1104         if(!weapon_prepareattack_checkammo(secondary))
1105                 return FALSE;
1106
1107         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1108         //if all players readied up and the countdown is running
1109         if(time < game_starttime || time < self.race_penalty) {
1110                 return FALSE;
1111         }
1112
1113         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1114                 return FALSE;
1115
1116         // do not even think about shooting if switching
1117         if(self.switchweapon != self.weapon)
1118                 return FALSE;
1119
1120         if(attacktime >= 0)
1121         {
1122                 // don't fire if previous attack is not finished
1123                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1124                         return FALSE;
1125                 // don't fire while changing weapon
1126                 if (self.weaponentity.state != WS_READY)
1127                         return FALSE;
1128         }
1129
1130         return TRUE;
1131 }
1132 float weapon_prepareattack_do(float secondary, float attacktime)
1133 {
1134         self.weaponentity.state = WS_INUSE;
1135
1136         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1137
1138         // if the weapon hasn't been firing continuously, reset the timer
1139         if(attacktime >= 0)
1140         {
1141                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1142                 {
1143                         ATTACK_FINISHED(self) = time;
1144                         //dprint("resetting attack finished to ", ftos(time), "\n");
1145                 }
1146                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1147         }
1148         self.bulletcounter += 1;
1149         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1150         return TRUE;
1151 }
1152 float weapon_prepareattack(float secondary, float attacktime)
1153 {
1154         if(weapon_prepareattack_check(secondary, attacktime))
1155         {
1156                 weapon_prepareattack_do(secondary, attacktime);
1157                 return TRUE;
1158         }
1159         else
1160                 return FALSE;
1161 }
1162
1163 void weapon_thinkf(float fr, float t, void() func)
1164 {
1165         vector a;
1166         vector of, or, ou;
1167         float restartanim;
1168
1169         if(fr == WFRAME_DONTCHANGE)
1170         {
1171                 fr = self.weaponentity.wframe;
1172                 restartanim = FALSE;
1173         }
1174         else if (fr == WFRAME_IDLE)
1175                 restartanim = FALSE;
1176         else
1177                 restartanim = TRUE;
1178
1179         of = v_forward;
1180         or = v_right;
1181         ou = v_up;
1182
1183         if (self.weaponentity)
1184         {
1185                 self.weaponentity.wframe = fr;
1186                 if (qcweaponanimation)
1187                 {
1188                         if (fr != WFRAME_IDLE)
1189                         {
1190                                 self.weapon_morph0time = time;
1191                                 self.weapon_morph0angles = self.weaponentity.angles;
1192                                 self.weapon_morph0origin = self.weaponentity.origin;
1193
1194                                 self.weapon_morph1angles = '0 0 0';
1195                                 self.weapon_morph1time = time + t;
1196                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1197                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1198
1199                                 self.weapon_morph2angles = '0 0 0';
1200                                 self.weapon_morph2time = time + t;
1201                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1202                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1203
1204                                 self.weapon_morph3angles = '0 0 0';
1205                                 self.weapon_morph3time = time + t;
1206                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1207                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1208
1209                                 self.weapon_morph4angles = '0 0 0';
1210                                 self.weapon_morph4time = time + t;
1211                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1212                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1213
1214                                 if (fr == WFRAME_FIRE1)
1215                                 {
1216                                         self.weapon_morph1angles = '5 0 0';
1217                                         self.weapon_morph1time = time + t * 0.1;
1218                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1219                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1220                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1221                                 }
1222                                 else if (fr == WFRAME_FIRE2)
1223                                 {
1224                                         self.weapon_morph1angles = '10 0 0';
1225                                         self.weapon_morph1time = time + t * 0.1;
1226                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1227                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1228                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1229                                 }
1230                                 else if (fr == WFRAME_RELOAD)
1231                                 {
1232                                         self.weapon_morph1time = time + t * 0.05;
1233                                         self.weapon_morph1angles = '-10 40 0';
1234                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1235                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1236
1237                                         self.weapon_morph2time = time + t * 0.15;
1238                                         self.weapon_morph2angles = '-10 40 5';
1239                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1240                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1241
1242                                         self.weapon_morph3time = time + t * 0.25;
1243                                         self.weapon_morph3angles = '-10 40 0';
1244                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1245                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1246                                 }
1247                         }
1248                 }
1249                 else
1250                 {
1251                         if (fr == WFRAME_IDLE)
1252                                 a = self.weaponentity.anim_idle;
1253                         else if (fr == WFRAME_FIRE1)
1254                                 a = self.weaponentity.anim_fire1;
1255                         else if (fr == WFRAME_FIRE2)
1256                                 a = self.weaponentity.anim_fire2;
1257                         else if (fr == WFRAME_RELOAD)
1258                                 a = self.weaponentity.anim_reload;
1259                         a_z *= g_weaponratefactor;
1260                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1261                 }
1262         }
1263
1264         v_forward = of;
1265         v_right = or;
1266         v_up = ou;
1267
1268         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1269         {
1270                 backtrace("Tried to override initial weapon think function - should this really happen?");
1271         }
1272
1273         t *= W_WeaponRateFactor();
1274
1275         // VorteX: haste can be added here
1276         if (self.weapon_think == w_ready)
1277         {
1278                 self.weapon_nextthink = time;
1279                 //dprint("started firing at ", ftos(time), "\n");
1280         }
1281         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1282         {
1283                 self.weapon_nextthink = time;
1284                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1285         }
1286         self.weapon_nextthink = self.weapon_nextthink + t;
1287         self.weapon_think = func;
1288         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1289
1290         if (restartanim)
1291         if (t)
1292         if (!self.crouch) // shoot anim stands up, this looks bad
1293         {
1294                 local vector anim;
1295                 anim = self.anim_shoot;
1296                 anim_z = anim_y / (t + sys_frametime);
1297                 setanim(self, anim, FALSE, TRUE, TRUE);
1298         }
1299 };
1300
1301 void weapon_boblayer1(float spd, vector org)
1302 {
1303         // VorteX: haste can be added here
1304 };
1305
1306 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1307 {
1308         vector mdirection;
1309         float mspeed;
1310         float outspeed;
1311         float nstyle;
1312         vector outvelocity;
1313
1314         mvelocity = mvelocity * g_weaponspeedfactor;
1315
1316         mdirection = normalize(mvelocity);
1317         mspeed = vlen(mvelocity);
1318
1319         nstyle = cvar("g_projectiles_newton_style");
1320         if(nstyle == 0)
1321         {
1322                 // absolute velocity
1323                 outvelocity = mvelocity;
1324         }
1325         else if(nstyle == 1)
1326         {
1327                 // true Newtonian projectiles
1328                 outvelocity = pvelocity + mvelocity;
1329         }
1330         else if(nstyle == 2)
1331         {
1332                 // true Newtonian projectiles with automatic aim adjustment
1333                 //
1334                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1335                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1336                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1337                 // PLUS SIGN!
1338                 // not defined?
1339                 // then...
1340                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1341                 // velocity without mdirection component > mspeed
1342                 // fire at smallest possible mspeed that works?
1343                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1344
1345                 vector solution;
1346                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1347                 if(solution_z)
1348                         outspeed = solution_y; // the larger one
1349                 else
1350                 {
1351                         //outspeed = 0; // slowest possible shot
1352                         outspeed = solution_x; // the real part (that is, the average!)
1353                         //dprint("impossible shot, adjusting\n");
1354                 }
1355
1356                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1357                 outvelocity = mdirection * outspeed;
1358         }
1359         else if(nstyle == 3)
1360         {
1361                 // pseudo-Newtonian:
1362                 outspeed = mspeed + mdirection * pvelocity;
1363                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1364                 outvelocity = mdirection * outspeed;
1365         }
1366         else if(nstyle == 4)
1367         {
1368                 // tZorkian:
1369                 outspeed = mspeed + vlen(pvelocity);
1370                 outvelocity = mdirection * outspeed;
1371         }
1372         else
1373                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1374
1375         return outvelocity;
1376 }
1377
1378 void W_AttachToShotorg(entity flash, vector offset)
1379 {
1380         entity xflash;
1381         flash.owner = self;
1382         flash.angles_z = random() * 360;
1383         if(qcweaponanimation)
1384         {
1385                 setorigin(flash, w_shotorg + w_shotdir * 50);
1386                 flash.angles = vectoangles(w_shotdir);
1387                 flash.angles_z = random() * 360;
1388         }
1389         else
1390         {
1391                 if(gettagindex(self.weaponentity, "shot"))
1392                         setattachment(flash, self.weaponentity, "shot");
1393                 else
1394                         setattachment(flash, self.weaponentity, "tag_shot");
1395                 setorigin(flash, offset);
1396
1397                 xflash = spawn();
1398                 copyentity(flash, xflash);
1399
1400                 flash.viewmodelforclient = self;
1401
1402                 if(self.weaponentity.oldorigin_x > 0)
1403                 {
1404                         setattachment(xflash, self.exteriorweaponentity, "");
1405                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1406                 }
1407                 else
1408                 {
1409                         if(gettagindex(self.exteriorweaponentity, "shot"))
1410                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1411                         else
1412                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1413                         setorigin(xflash, offset);
1414                 }
1415         }
1416 }
1417
1418 vector cliptoplane(vector v, vector p)
1419 {
1420         return v - (v * p) * p;
1421 }
1422
1423 vector solve_cubic_pq(float p, float q)
1424 {
1425         float D, u, v, a;
1426         D = q*q/4.0 + p*p*p/27.0;
1427         if(D < 0)
1428         {
1429                 // irreducibilis
1430                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1431                 u = sqrt(-4.0/3.0 * p);
1432                 // a in range 0..pi/3
1433                 // cos(a)
1434                 // cos(a + 2pi/3)
1435                 // cos(a + 4pi/3)
1436                 return
1437                         u *
1438                         (
1439                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1440                                 +
1441                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1442                                 +
1443                                 '0 0 1' * cos(a)
1444                         );
1445         }
1446         else if(D == 0)
1447         {
1448                 // simple
1449                 if(p == 0)
1450                         return '0 0 0';
1451                 u = 3*q/p;
1452                 v = -u/2;
1453                 if(u >= v)
1454                         return '1 1 0' * v + '0 0 1' * u;
1455                 else
1456                         return '0 1 1' * v + '1 0 0' * u;
1457         }
1458         else
1459         {
1460                 // cardano
1461                 u = cbrt(-q/2.0 + sqrt(D));
1462                 v = cbrt(-q/2.0 - sqrt(D));
1463                 return '1 1 1' * (u + v);
1464         }
1465 }
1466 vector solve_cubic_abcd(float a, float b, float c, float d)
1467 {
1468         // y = 3*a*x + b
1469         // x = (y - b) / 3a
1470         float p, q;
1471         vector v;
1472         p = (9*a*c - 3*b*b);
1473         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1474         v = solve_cubic_pq(p, q);
1475         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1476         if(a < 0)
1477                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1478         return v;
1479 }
1480
1481 vector findperpendicular(vector v)
1482 {
1483         vector p;
1484         p_x = v_z;
1485         p_y = -v_x;
1486         p_z = v_y;
1487         return normalize(cliptoplane(p, v));
1488 }
1489
1490 vector W_CalculateProjectileSpread(vector forward, float spread)
1491 {
1492         float sigma;
1493         vector v1, v2;
1494         float dx, dy, r;
1495         float sstyle;
1496         spread *= g_weaponspreadfactor;
1497         if(spread <= 0)
1498                 return forward;
1499         sstyle = cvar("g_projectiles_spread_style");
1500
1501         if(sstyle == 0)
1502         {
1503                 // this is the baseline for the spread value!
1504                 // standard deviation: sqrt(2/5)
1505                 // density function: sqrt(1-r^2)
1506                 return forward + randomvec() * spread;
1507         }
1508         else if(sstyle == 1)
1509         {
1510                 // same thing, basically
1511                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1512         }
1513         else if(sstyle == 2)
1514         {
1515                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1516                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1517                 v1 = findperpendicular(forward);
1518                 v2 = cross(forward, v1);
1519                 // random point on unit circle
1520                 dx = random() * 2 * M_PI;
1521                 dy = sin(dx);
1522                 dx = cos(dx);
1523                 // radius in our dist function
1524                 r = random();
1525                 r = sqrt(r);
1526                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1527         }
1528         else if(sstyle == 3) // gauss 3d
1529         {
1530                 sigma = spread * 0.44721359549996; // match baseline stddev
1531                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1532                 v1 = forward;
1533                 v1_x += gsl_ran_gaussian(sigma);
1534                 v1_y += gsl_ran_gaussian(sigma);
1535                 v1_z += gsl_ran_gaussian(sigma);
1536                 return v1;
1537         }
1538         else if(sstyle == 4) // gauss 2d
1539         {
1540                 sigma = spread * 0.44721359549996; // match baseline stddev
1541                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1542                 v1_x = gsl_ran_gaussian(sigma);
1543                 v1_y = gsl_ran_gaussian(sigma);
1544                 v1_z = gsl_ran_gaussian(sigma);
1545                 return normalize(forward + cliptoplane(v1, forward));
1546         }
1547         else if(sstyle == 5) // 1-r
1548         {
1549                 sigma = spread * 1.154700538379252; // match baseline stddev
1550                 v1 = findperpendicular(forward);
1551                 v2 = cross(forward, v1);
1552                 // random point on unit circle
1553                 dx = random() * 2 * M_PI;
1554                 dy = sin(dx);
1555                 dx = cos(dx);
1556                 // radius in our dist function
1557                 r = random();
1558                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1559                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1560         }
1561         else if(sstyle == 6) // 1-r^2
1562         {
1563                 sigma = spread * 1.095445115010332; // match baseline stddev
1564                 v1 = findperpendicular(forward);
1565                 v2 = cross(forward, v1);
1566                 // random point on unit circle
1567                 dx = random() * 2 * M_PI;
1568                 dy = sin(dx);
1569                 dx = cos(dx);
1570                 // radius in our dist function
1571                 r = random();
1572                 r = sqrt(1 - r);
1573                 r = sqrt(1 - r);
1574                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1575         }
1576         else if(sstyle == 7) // (1-r) (2-r)
1577         {
1578                 sigma = spread * 1.224744871391589; // match baseline stddev
1579                 v1 = findperpendicular(forward);
1580                 v2 = cross(forward, v1);
1581                 // random point on unit circle
1582                 dx = random() * 2 * M_PI;
1583                 dy = sin(dx);
1584                 dx = cos(dx);
1585                 // radius in our dist function
1586                 r = random();
1587                 r = 1 - sqrt(r);
1588                 r = 1 - sqrt(r);
1589                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1590         }
1591         else
1592                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1593         return '0 0 0';
1594         /*
1595          * how to derive falloff functions:
1596          * rho(r) := (2-r) * (1-r);
1597          * a : 0;
1598          * b : 1;
1599          * rhor(r) := r * rho(r);
1600          * cr(t) := integrate(rhor(r), r, a, t);
1601          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1602          * variance : scr(b) / cr(b);
1603          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1604          * sqrt(0.4 / variance), numer;
1605          */
1606 }
1607
1608 #if 0
1609 float mspercallsum;
1610 float mspercallsstyle;
1611 float mspercallcount;
1612 #endif
1613 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)
1614 {
1615         if(missile.owner == world)
1616                 error("Unowned missile");
1617
1618         dir = dir + upDir * (pUpSpeed / pSpeed);
1619         dir_z += pZSpeed / pSpeed;
1620         pSpeed *= vlen(dir);
1621         dir = normalize(dir);
1622
1623 #if 0
1624         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1625         {
1626                 mspercallsum = mspercallcount = 0;
1627                 mspercallsstyle = cvar("g_projectiles_spread_style");
1628         }
1629         mspercallsum -= gettime(GETTIME_HIRES);
1630 #endif
1631         dir = W_CalculateProjectileSpread(dir, spread);
1632 #if 0
1633         mspercallsum += gettime(GETTIME_HIRES);
1634         mspercallcount += 1;
1635         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1636 #endif
1637
1638         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1639 }
1640
1641 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1642 {
1643         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);
1644 }
1645
1646 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))
1647 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))