qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include "compat/quake3.qh"
  36
  37 #include <common/effects/qc/globalsound.qh>
  38
  39 #include "../common/mapobjects/func/conveyor.qh"
  40 #include "../common/mapobjects/teleporters.qh"
  41 #include "../common/mapobjects/target/spawnpoint.qh"
  42 #include <common/mapobjects/trigger/counter.qh>
  43
  44 #include "../common/vehicles/all.qh"
  45
  46 #include "weapons/hitplot.qh"
  47 #include "weapons/weaponsystem.qh"
  48
  49 #include "../common/net_notice.qh"
  50 #include "../common/net_linked.qh"
  51 #include "../common/physics/player.qh"
  52
  53 #include <common/vehicles/sv_vehicles.qh>
  54
  55 #include "../common/items/_mod.qh"
  56
  57 #include "../common/mutators/mutator/waypoints/all.qh"
  58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  59 #include <common/gamemodes/_mod.qh>
  60
  61 #include "../common/mapobjects/subs.qh"
  62 #include "../common/mapobjects/triggers.qh"
  63 #include "../common/mapobjects/trigger/secret.qh"
  64
  65 #include "../common/minigames/sv_minigames.qh"
  66
  67 #include "../common/items/inventory.qh"
  68
  69 #include "../common/monsters/sv_monsters.qh"
  70
  71 #include "../lib/warpzone/server.qh"
  72
  73 #include <common/mutators/mutator/overkill/oknex.qh>
  74
  75 STATIC_METHOD(Client, Add, void(Client this, int _team))
  76 {
  77     ClientConnect(this);
  78     TRANSMUTE(Player, this);
  79     this.frame = 12; // 7
  80     this.team = _team;
  81     PutClientInServer(this);
  82 }
  83
  84 STATIC_METHOD(Client, Remove, void(Client this))
  85 {
  86     TRANSMUTE(Observer, this);
  87     PutClientInServer(this);
  88     ClientDisconnect(this);
  89 }
  90
  91 void send_CSQC_teamnagger() {
  92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  93 }
  94
  95 int CountSpectators(entity player, entity to)
  96 {
  97         if(!player) { return 0; } // not sure how, but best to be safe
  98
  99         int spec_count = 0;
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 spec_count++;
 104         });
 105
 106         return spec_count;
 107 }
 108
 109 void WriteSpectators(entity player, entity to)
 110 {
 111         if(!player) { return; } // not sure how, but best to be safe
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 WriteByte(MSG_ENTITY, num_for_edict(it));
 116         });
 117 }
 118
 119 bool ClientData_Send(entity this, entity to, int sf)
 120 {
 121         assert(to == this.owner, return false);
 122
 123         entity e = to;
 124         if (IS_SPEC(e)) e = e.enemy;
 125
 126         sf = 0;
 127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 131
 132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 133         WriteByte(MSG_ENTITY, sf);
 134
 135         if (sf & BIT(1))
 136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 137
 138         if(sf & BIT(4))
 139         {
 140                 float specs = CountSpectators(e, to);
 141                 WriteByte(MSG_ENTITY, specs);
 142                 WriteSpectators(e, to);
 143         }
 144
 145         return true;
 146 }
 147
 148 void ClientData_Attach(entity this)
 149 {
 150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 151         CS(this).clientdata.drawonlytoclient = this;
 152         CS(this).clientdata.owner = this;
 153 }
 154
 155 void ClientData_Detach(entity this)
 156 {
 157         delete(CS(this).clientdata);
 158         CS(this).clientdata = NULL;
 159 }
 160
 161 void ClientData_Touch(entity e)
 162 {
 163         entity cd = CS(e).clientdata;
 164         if (cd) { cd.SendFlags = 1; }
 165
 166         // make it spectatable
 167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 168         {
 169                 entity cd = CS(it).clientdata;
 170                 if (cd) { cd.SendFlags = 1; }
 171         });
 172 }
 173
 174
 175 /*
 176 =============
 177 CheckPlayerModel
 178
 179 Checks if the argument string can be a valid playermodel.
 180 Returns a valid one in doubt.
 181 =============
 182 */
 183 string FallbackPlayerModel;
 184 string CheckPlayerModel(string plyermodel) {
 185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 186         {
 187                 // note: we cannot summon Don Strunzone here, some player may
 188                 // still have the model string set. In case anyone manages how
 189                 // to change a cvar default, we'll have a small leak here.
 190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 191         }
 192         // only in right path
 193         if( substring(plyermodel,0,14) != "models/player/")
 194                 return FallbackPlayerModel;
 195         // only good file extensions
 196         if(substring(plyermodel,-4,4) != ".zym")
 197         if(substring(plyermodel,-4,4) != ".dpm")
 198         if(substring(plyermodel,-4,4) != ".iqm")
 199         if(substring(plyermodel,-4,4) != ".md3")
 200         if(substring(plyermodel,-4,4) != ".psk")
 201                 return FallbackPlayerModel;
 202         // forbid the LOD models
 203         if(substring(plyermodel, -9,5) == "_lod1")
 204                 return FallbackPlayerModel;
 205         if(substring(plyermodel, -9,5) == "_lod2")
 206                 return FallbackPlayerModel;
 207         if(plyermodel != strtolower(plyermodel))
 208                 return FallbackPlayerModel;
 209         // also, restrict to server models
 210         if(autocvar_sv_servermodelsonly)
 211         {
 212                 if(!fexists(plyermodel))
 213                         return FallbackPlayerModel;
 214         }
 215         return plyermodel;
 216 }
 217
 218 void setplayermodel(entity e, string modelname)
 219 {
 220         precache_model(modelname);
 221         _setmodel(e, modelname);
 222         player_setupanimsformodel(e);
 223         if(!autocvar_g_debug_globalsounds)
 224                 UpdatePlayerSounds(e);
 225 }
 226
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this, false);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 if(!game_stopped)
 294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 296         }
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307     STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_frame = 0;
 334         this.pain_finished = 0;
 335         this.strength_finished = 0;
 336         this.invincible_finished = 0;
 337         this.superweapons_finished = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350         this.draggable = drag_undraggable;
 351
 352         this.items = 0;
 353         STAT(WEAPONS, this) = '0 0 0';
 354         this.drawonlytoclient = this;
 355
 356         this.viewloc = NULL;
 357
 358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 359
 360         this.weaponmodel = "";
 361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 362         {
 363                 this.weaponentities[slot] = NULL;
 364         }
 365         this.exteriorweaponentity = NULL;
 366         CS(this).killcount = FRAGS_SPECTATOR;
 367         this.velocity = '0 0 0';
 368         this.avelocity = '0 0 0';
 369         this.punchangle = '0 0 0';
 370         this.punchvector = '0 0 0';
 371         this.oldvelocity = this.velocity;
 372         this.fire_endtime = -1;
 373         this.event_damage = func_null;
 374         this.event_heal = func_null;
 375
 376         for(int slot = 0; slot < MAX_AXH; ++slot)
 377         {
 378                 entity axh = this.(AuxiliaryXhair[slot]);
 379                 this.(AuxiliaryXhair[slot]) = NULL;
 380
 381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 382                         delete(axh);
 383         }
 384
 385         if (mutator_returnvalue)
 386         {
 387                 // mutator prevents resetting teams+score
 388         }
 389         else
 390         {
 391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 392                 this.frags = FRAGS_SPECTATOR;
 393     }
 394 }
 395
 396 int player_getspecies(entity this)
 397 {
 398         get_model_parameters(this.model, this.skin);
 399         int s = get_model_parameters_species;
 400         get_model_parameters(string_null, 0);
 401         if (s < 0) return SPECIES_HUMAN;
 402         return s;
 403 }
 404
 405 .float model_randomizer;
 406 void FixPlayermodel(entity player)
 407 {
 408         string defaultmodel = "";
 409         int defaultskin = 0;
 410         if(autocvar_sv_defaultcharacter)
 411         {
 412                 if(teamplay)
 413                 {
 414                         switch(player.team)
 415                         {
 416                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 417                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 418                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 419                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 420                         }
 421                 }
 422
 423                 if(defaultmodel == "")
 424                 {
 425                         defaultmodel = autocvar_sv_defaultplayermodel;
 426                         defaultskin = autocvar_sv_defaultplayerskin;
 427                 }
 428
 429                 int n = tokenize_console(defaultmodel);
 430                 if(n > 0)
 431                 {
 432                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 433                         // However, do NOT randomize if the player-selected model is in the list.
 434                         for (int i = 0; i < n; ++i)
 435                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 436                                         defaultmodel = argv(i);
 437                 }
 438
 439                 int i = strstrofs(defaultmodel, ":", 0);
 440                 if(i >= 0)
 441                 {
 442                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 443                         defaultmodel = substring(defaultmodel, 0, i);
 444                 }
 445         }
 446         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 447         {
 448                 if(teamplay)
 449                 {
 450                         switch(player.team)
 451                         {
 452                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 453                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 454                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 455                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 456                         }
 457                 }
 458
 459                 if(!defaultskin)
 460                         defaultskin = autocvar_sv_defaultplayerskin;
 461         }
 462
 463         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 464         defaultmodel = M_ARGV(0, string);
 465         defaultskin = M_ARGV(1, int);
 466
 467         bool chmdl = false;
 468         int oldskin;
 469         if(defaultmodel != "")
 470         {
 471                 if (defaultmodel != player.model)
 472                 {
 473                         vector m1 = player.mins;
 474                         vector m2 = player.maxs;
 475                         setplayermodel (player, defaultmodel);
 476                         setsize (player, m1, m2);
 477                         chmdl = true;
 478                 }
 479
 480                 oldskin = player.skin;
 481                 player.skin = defaultskin;
 482         } else {
 483                 if (player.playermodel != player.model || player.playermodel == "")
 484                 {
 485                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 486                         vector m1 = player.mins;
 487                         vector m2 = player.maxs;
 488                         setplayermodel (player, player.playermodel);
 489                         setsize (player, m1, m2);
 490                         chmdl = true;
 491                 }
 492
 493                 if(!autocvar_sv_defaultcharacterskin)
 494                 {
 495                         oldskin = player.skin;
 496                         player.skin = stof(player.playerskin);
 497                 }
 498                 else
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = defaultskin;
 502                 }
 503         }
 504
 505         if(chmdl || oldskin != player.skin) // model or skin has changed
 506         {
 507                 player.species = player_getspecies(player); // update species
 508                 if(!autocvar_g_debug_globalsounds)
 509                         UpdatePlayerSounds(player); // update skin sounds
 510         }
 511
 512         if(!teamplay)
 513                 if(strlen(autocvar_sv_defaultplayercolors))
 514                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 515                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 516 }
 517
 518 void PutPlayerInServer(entity this)
 519 {
 520         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 521
 522         PlayerState_attach(this);
 523         accuracy_resend(this);
 524
 525         if (this.team < 0)
 526                 TeamBalance_JoinBestTeam(this);
 527
 528         entity spot = SelectSpawnPoint(this, false);
 529         if (!spot) {
 530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 531                 return; // spawn failed
 532         }
 533
 534         TRANSMUTE(Player, this);
 535
 536         CS(this).wasplayer = true;
 537         this.iscreature = true;
 538         this.teleportable = TELEPORT_NORMAL;
 539         if(!this.damagedbycontents)
 540                 IL_PUSH(g_damagedbycontents, this);
 541         this.damagedbycontents = true;
 542         set_movetype(this, MOVETYPE_WALK);
 543         this.solid = SOLID_SLIDEBOX;
 544         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 545         if (autocvar_g_playerclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 547         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 549         this.frags = FRAGS_PLAYER;
 550         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 551         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 552         if (autocvar__notarget)
 553                 this.flags |= FL_NOTARGET;
 554         this.takedamage = DAMAGE_AIM;
 555         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 556
 557         if (warmup_stage) {
 558                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 559                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 560                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 561                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 562                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 563                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 564                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 565                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 566                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 567         } else {
 568                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 569                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 570                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 571                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 572                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 573                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 574                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 575                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 576                 STAT(WEAPONS, this) = start_weapons;
 577                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 578                 {
 579                         GiveRandomWeapons(this, random_start_weapons_count,
 580                                 autocvar_g_random_start_weapons, random_start_ammo);
 581                 }
 582         }
 583         SetSpectatee_status(this, 0);
 584
 585         PS(this).dual_weapons = '0 0 0';
 586
 587         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 588
 589         this.items = start_items;
 590
 591         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 592         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 593         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 594         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 595         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 596         if (!sv_ready_restart_after_countdown && time < game_starttime)
 597         {
 598                 float f = game_starttime - time;
 599                 this.spawnshieldtime += f;
 600                 this.pauserotarmor_finished += f;
 601                 this.pauserothealth_finished += f;
 602                 this.pauseregen_finished += f;
 603         }
 604
 605         this.damageforcescale = 2;
 606         this.death_time = 0;
 607         this.respawn_flags = 0;
 608         this.respawn_time = 0;
 609         STAT(RESPAWN_TIME, this) = 0;
 610         this.scale = autocvar_sv_player_scale;
 611         this.fade_time = 0;
 612         this.pain_frame = 0;
 613         this.pain_finished = 0;
 614         this.pushltime = 0;
 615         setthink(this, func_null); // players have no think function
 616         this.nextthink = 0;
 617         this.dmg_team = 0;
 618         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 619
 620         this.deadflag = DEAD_NO;
 621
 622         this.angles = spot.angles;
 623         this.angles_z = 0; // never spawn tilted even if the spot says to
 624         if (IS_BOT_CLIENT(this))
 625         {
 626                 this.v_angle = this.angles;
 627                 bot_aim_reset(this);
 628         }
 629         this.fixangle = true; // turn this way immediately
 630         this.oldvelocity = this.velocity = '0 0 0';
 631         this.avelocity = '0 0 0';
 632         this.punchangle = '0 0 0';
 633         this.punchvector = '0 0 0';
 634
 635         this.strength_finished = 0;
 636         this.invincible_finished = 0;
 637         this.fire_endtime = -1;
 638         STAT(REVIVE_PROGRESS, this) = 0;
 639         this.revival_time = 0;
 640
 641         this.air_finished = time + 12;
 642         this.waterlevel = WATERLEVEL_NONE;
 643         this.watertype = CONTENT_EMPTY;
 644
 645         entity spawnevent = new_pure(spawnevent);
 646         spawnevent.owner = this;
 647         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 648
 649         // Cut off any still running player sounds.
 650         stopsound(this, CH_PLAYER_SINGLE);
 651
 652         this.model = "";
 653         FixPlayermodel(this);
 654         this.drawonlytoclient = NULL;
 655
 656         this.viewloc = NULL;
 657
 658         for(int slot = 0; slot < MAX_AXH; ++slot)
 659         {
 660                 entity axh = this.(AuxiliaryXhair[slot]);
 661                 this.(AuxiliaryXhair[slot]) = NULL;
 662
 663                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 664                         delete(axh);
 665         }
 666
 667         this.spawnpoint_targ = NULL;
 668
 669         this.crouch = false;
 670         this.view_ofs = STAT(PL_VIEW_OFS, this);
 671         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 672         this.spawnorigin = spot.origin;
 673         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 674         // don't reset back to last position, even if new position is stuck in solid
 675         this.oldorigin = this.origin;
 676         if(this.conveyor)
 677                 IL_REMOVE(g_conveyed, this);
 678         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 679         STAT(HUD, this) = HUD_NORMAL;
 680
 681         this.event_damage = PlayerDamage;
 682         this.event_heal = PlayerHeal;
 683
 684         this.draggable = func_null;
 685
 686         if(!this.bot_attack)
 687                 IL_PUSH(g_bot_targets, this);
 688         this.bot_attack = true;
 689         if(!this.monster_attack)
 690                 IL_PUSH(g_monster_targets, this);
 691         this.monster_attack = true;
 692         navigation_dynamicgoal_init(this, false);
 693
 694         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 695
 696         // player was spectator
 697         if (CS(this).killcount == FRAGS_SPECTATOR) {
 698                 PlayerScore_Clear(this);
 699                 CS(this).killcount = 0;
 700                 CS(this).startplaytime = time;
 701         }
 702
 703         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 704         {
 705                 .entity weaponentity = weaponentities[slot];
 706                 entity oldwep = this.(weaponentity);
 707                 CL_SpawnWeaponentity(this, weaponentity);
 708                 if(oldwep && oldwep.owner == this)
 709                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 710         }
 711         this.alpha = default_player_alpha;
 712         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 713         this.exteriorweaponentity.alpha = default_weapon_alpha;
 714
 715         this.speedrunning = false;
 716
 717         this.counter_cnt = 0;
 718         this.fragsfilter_cnt = 0;
 719
 720         target_voicescript_clear(this);
 721
 722         // reset fields the weapons may use
 723         FOREACH(Weapons, true, {
 724                 it.wr_resetplayer(it, this);
 725                         // reload all reloadable weapons
 726                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 727                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 728                         {
 729                                 .entity weaponentity = weaponentities[slot];
 730                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 731                         }
 732                 }
 733         });
 734
 735         {
 736                 //string s = spot.target;
 737                 //spot.target = string_null;
 738                 SUB_UseTargets(spot, this, NULL);
 739                 //spot.target = s;
 740         }
 741
 742         Unfreeze(this, false);
 743
 744         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 745
 746         if (autocvar_spawn_debug)
 747         {
 748                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 749                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 750         }
 751
 752         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753         {
 754                 .entity weaponentity = weaponentities[slot];
 755                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 756                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 757                 else
 758                         this.(weaponentity).m_switchweapon = WEP_Null;
 759                 this.(weaponentity).m_weapon = WEP_Null;
 760                 this.(weaponentity).weaponname = "";
 761                 this.(weaponentity).m_switchingweapon = WEP_Null;
 762                 this.(weaponentity).cnt = -1;
 763         }
 764
 765         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 766
 767         if (CS(this).impulse) ImpulseCommands(this);
 768
 769         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770         {
 771                 .entity weaponentity = weaponentities[slot];
 772                 W_WeaponFrame(this, weaponentity);
 773         }
 774
 775         if (!warmup_stage && !this.alivetime)
 776                 this.alivetime = time;
 777
 778         antilag_clear(this, CS(this));
 779 }
 780
 781 /** Called when a client spawns in the server */
 782 void PutClientInServer(entity this)
 783 {
 784         if (IS_BOT_CLIENT(this)) {
 785                 TRANSMUTE(Player, this);
 786         } else if (IS_REAL_CLIENT(this)) {
 787                 msg_entity = this;
 788                 WriteByte(MSG_ONE, SVC_SETVIEW);
 789                 WriteEntity(MSG_ONE, this);
 790         }
 791         if (game_stopped)
 792                 TRANSMUTE(Observer, this);
 793
 794         SetSpectatee(this, NULL);
 795
 796         // reset player keys
 797         if(PS(this))
 798                 PS(this).itemkeys = 0;
 799
 800         MUTATOR_CALLHOOK(PutClientInServer, this);
 801
 802         if (IS_OBSERVER(this)) {
 803                 PutObserverInServer(this);
 804         } else if (IS_PLAYER(this)) {
 805                 PutPlayerInServer(this);
 806         }
 807 }
 808
 809 // TODO do we need all these fields, or should we stop autodetecting runtime
 810 // changes and just have a console command to update this?
 811 bool ClientInit_SendEntity(entity this, entity to, int sf)
 812 {
 813         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 814         return = true;
 815         msg_entity = to;
 816         // MSG_INIT replacement
 817         // TODO: make easier to use
 818         Registry_send_all();
 819         W_PROP_reload(MSG_ONE, to);
 820         ClientInit_misc(this);
 821         MUTATOR_CALLHOOK(Ent_Init);
 822 }
 823 void ClientInit_misc(entity this)
 824 {
 825         int channel = MSG_ONE;
 826         WriteHeader(channel, ENT_CLIENT_INIT);
 827         WriteByte(channel, g_nexball_meter_period * 32);
 828         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 829         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 830         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 831         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 832         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 833         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 834         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 835         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 836
 837         if(sv_foginterval && world.fog != "")
 838                 WriteString(channel, world.fog);
 839         else
 840                 WriteString(channel, "");
 841         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 842         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 843         WriteByte(channel, serverflags);
 844         WriteCoord(channel, autocvar_g_trueaim_minrange);
 845 }
 846
 847 void ClientInit_CheckUpdate(entity this)
 848 {
 849         this.nextthink = time;
 850         if(this.count != autocvar_g_balance_armor_blockpercent)
 851         {
 852                 this.count = autocvar_g_balance_armor_blockpercent;
 853                 this.SendFlags |= 1;
 854         }
 855         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 856         {
 857                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 858                 this.SendFlags |= 1;
 859         }
 860 }
 861
 862 void ClientInit_Spawn()
 863 {
 864         entity e = new_pure(clientinit);
 865         setthink(e, ClientInit_CheckUpdate);
 866         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 867
 868         ClientInit_CheckUpdate(e);
 869 }
 870
 871 /*
 872 =============
 873 SetNewParms
 874 =============
 875 */
 876 void SetNewParms ()
 877 {
 878         // initialize parms for a new player
 879         parm1 = -(86400 * 366);
 880
 881         MUTATOR_CALLHOOK(SetNewParms);
 882 }
 883
 884 /*
 885 =============
 886 SetChangeParms
 887 =============
 888 */
 889 void SetChangeParms (entity this)
 890 {
 891         // save parms for level change
 892         parm1 = CS(this).parm_idlesince - time;
 893
 894         MUTATOR_CALLHOOK(SetChangeParms);
 895 }
 896
 897 /*
 898 =============
 899 DecodeLevelParms
 900 =============
 901 */
 902 void DecodeLevelParms(entity this)
 903 {
 904         // load parms
 905         CS(this).parm_idlesince = parm1;
 906         if (CS(this).parm_idlesince == -(86400 * 366))
 907                 CS(this).parm_idlesince = time;
 908
 909         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 910         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 911
 912         MUTATOR_CALLHOOK(DecodeLevelParms);
 913 }
 914
 915 void FixClientCvars(entity e)
 916 {
 917         // send prediction settings to the client
 918         stuffcmd(e, "\nin_bindmap 0 0\n");
 919         if(autocvar_g_antilag == 3) // client side hitscan
 920                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 921         if(autocvar_sv_gentle)
 922                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 923
 924         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 925         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 926
 927         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 928
 929         MUTATOR_CALLHOOK(FixClientCvars, e);
 930 }
 931
 932 bool findinlist_abbrev(string tofind, string list)
 933 {
 934         if(list == "" || tofind == "")
 935                 return false; // empty list or search, just return
 936
 937         // this function allows abbreviated strings!
 938         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 939         {
 940                 return true;
 941         });
 942
 943         return false;
 944 }
 945
 946 bool PlayerInIPList(entity p, string iplist)
 947 {
 948         // some safety checks (never allow local?)
 949         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 950                 return false;
 951
 952         return findinlist_abbrev(p.netaddress, iplist);
 953 }
 954
 955 bool PlayerInIDList(entity p, string idlist)
 956 {
 957         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 958         if(!p.crypto_idfp)
 959                 return false;
 960
 961         return findinlist_abbrev(p.crypto_idfp, idlist);
 962 }
 963
 964 bool PlayerInList(entity player, string list)
 965 {
 966         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 967 }
 968
 969 #ifdef DP_EXT_PRECONNECT
 970 /*
 971 =============
 972 ClientPreConnect
 973
 974 Called once (not at each match start) when a client begins a connection to the server
 975 =============
 976 */
 977 void ClientPreConnect(entity this)
 978 {
 979         if(autocvar_sv_eventlog)
 980         {
 981                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 982                         this.playerid,
 983                         etof(this),
 984                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 985                 ));
 986         }
 987 }
 988 #endif
 989
 990 string GetClientVersionMessage(entity this)
 991 {
 992         if (CS(this).version_mismatch) {
 993                 if(CS(this).version < autocvar_gameversion) {
 994                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 995                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 996                 } else {
 997                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 998                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 999                 }
1000         } else {
1001                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1002         }
1003 }
1004
1005 string getwelcomemessage(entity this)
1006 {
1007         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1008         string modifications = M_ARGV(0, string);
1009
1010         if(g_weaponarena)
1011         {
1012                 if(g_weaponarena_random)
1013                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1014                 else
1015                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1016         }
1017         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1018                 modifications = strcat(modifications, ", No start weapons");
1019         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1020                 modifications = strcat(modifications, ", Low gravity");
1021         if(g_weapon_stay && !g_cts)
1022                 modifications = strcat(modifications, ", Weapons stay");
1023         if(g_jetpack)
1024                 modifications = strcat(modifications, ", Jet pack");
1025         if(autocvar_g_powerups == 0)
1026                 modifications = strcat(modifications, ", No powerups");
1027         if(autocvar_g_powerups > 0)
1028                 modifications = strcat(modifications, ", Powerups");
1029         modifications = substring(modifications, 2, strlen(modifications) - 2);
1030
1031         string versionmessage = GetClientVersionMessage(this);
1032         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1033
1034         if(modifications != "")
1035                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1036
1037         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1038         {
1039                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1040                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1041         }
1042
1043         if (cache_mutatormsg != "") {
1044                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1045         }
1046
1047         string mutator_msg = "";
1048         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1049         mutator_msg = M_ARGV(0, string);
1050
1051         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1052
1053         string motd = autocvar_sv_motd;
1054         if (motd != "") {
1055                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1056         }
1057         return s;
1058 }
1059
1060 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1061
1062 /**
1063 =============
1064 ClientConnect
1065
1066 Called when a client connects to the server
1067 =============
1068 */
1069 void ClientConnect(entity this)
1070 {
1071         if (Ban_MaybeEnforceBanOnce(this)) return;
1072         assert(!IS_CLIENT(this), return);
1073         this.flags |= FL_CLIENT;
1074         assert(player_count >= 0, player_count = 0);
1075
1076 #ifdef WATERMARK
1077         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1078 #endif
1079         TRANSMUTE(Client, this);
1080         CS(this).version_nagtime = time + 10 + random() * 10;
1081
1082         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1083
1084         bot_clientconnect(this);
1085
1086         Player_DetermineForcedTeam(this);
1087
1088         TRANSMUTE(Observer, this);
1089
1090         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1091
1092         // always track bots, don't ask for cl_allow_uidtracking
1093         if (IS_BOT_CLIENT(this))
1094                 PlayerStats_GameReport_AddPlayer(this);
1095         else
1096                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1097
1098         if (autocvar_sv_eventlog)
1099                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1100
1101         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1102
1103         stuffcmd(this, clientstuff, "\n");
1104         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1105
1106         FixClientCvars(this);
1107
1108         // get version info from player
1109         stuffcmd(this, "cmd clientversion $gameversion\n");
1110
1111         // notify about available teams
1112         if (teamplay)
1113         {
1114                 entity balance = TeamBalance_CheckAllowedTeams(this);
1115                 int t = TeamBalance_GetAllowedTeams(balance);
1116                 TeamBalance_Destroy(balance);
1117                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1118         }
1119         else
1120         {
1121                 stuffcmd(this, "set _teams_available 0\n");
1122         }
1123
1124         bot_relinkplayerlist();
1125
1126         CS(this).spectatortime = time;
1127         if (blockSpectators)
1128         {
1129                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1130         }
1131
1132         CS(this).jointime = time;
1133
1134         if (IS_REAL_CLIENT(this))
1135         {
1136                 if (g_weaponarena_weapons == WEPSET(TUBA))
1137                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1138         }
1139
1140         if (!sv_foginterval && world.fog != "")
1141                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1142
1143         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1144                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1145                         send_CSQC_teamnagger();
1146
1147         CSQCMODEL_AUTOINIT(this);
1148
1149         CS(this).model_randomizer = random();
1150
1151         if (IS_REAL_CLIENT(this))
1152                 sv_notice_join(this);
1153
1154         this.move_qcphysics = autocvar_sv_qcphysics;
1155
1156         // update physics stats (players can spawn before physics runs)
1157         Physics_UpdateStats(this);
1158
1159         IL_EACH(g_initforplayer, it.init_for_player, {
1160                 it.init_for_player(it, this);
1161         });
1162
1163         Handicap_Initialize(this);
1164
1165         MUTATOR_CALLHOOK(ClientConnect, this);
1166
1167         if (IS_REAL_CLIENT(this))
1168         {
1169                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1170                 {
1171                         CS(this).motd_actived_time = -1;
1172                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1173                 }
1174         }
1175 }
1176 /*
1177 =============
1178 ClientDisconnect
1179
1180 Called when a client disconnects from the server
1181 =============
1182 */
1183 .entity chatbubbleentity;
1184 void ClientDisconnect(entity this)
1185 {
1186         assert(IS_CLIENT(this), return);
1187
1188         PlayerStats_GameReport_FinalizePlayer(this);
1189         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1190         if (CS(this).active_minigame) part_minigame(this);
1191         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1192
1193         if (autocvar_sv_eventlog)
1194                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1195
1196         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1197
1198         if(IS_SPEC(this))
1199                 SetSpectatee(this, NULL);
1200
1201     MUTATOR_CALLHOOK(ClientDisconnect, this);
1202
1203         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1204         strfree(CS(this).weaponorder_byimpulse);
1205         ClientState_detach(this);
1206
1207         Portal_ClearAll(this);
1208
1209         Unfreeze(this, false);
1210
1211         RemoveGrapplingHooks(this);
1212
1213         // Here, everything has been done that requires this player to be a client.
1214
1215         this.flags &= ~FL_CLIENT;
1216
1217         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1218         if (this.killindicator) delete(this.killindicator);
1219
1220         WaypointSprite_PlayerGone(this);
1221
1222         bot_relinkplayerlist();
1223
1224         strfree(this.clientstatus);
1225         if (this.personal) delete(this.personal);
1226
1227         this.playerid = 0;
1228         ReadyCount();
1229         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1230
1231         ONREMOVE(this);
1232 }
1233
1234 void ChatBubbleThink(entity this)
1235 {
1236         this.nextthink = time;
1237         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1238         {
1239                 if(this.owner) // but why can that ever be NULL?
1240                         this.owner.chatbubbleentity = NULL;
1241                 delete(this);
1242                 return;
1243         }
1244
1245         this.mdl = "";
1246
1247         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1248         {
1249                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1250                         this.mdl = "models/sprites/minigame_busy.iqm";
1251                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1252                         this.mdl = "models/misc/chatbubble.spr";
1253         }
1254
1255         if ( this.model != this.mdl )
1256                 _setmodel(this, this.mdl);
1257
1258 }
1259
1260 void UpdateChatBubble(entity this)
1261 {
1262         if (this.alpha < 0)
1263                 return;
1264         // spawn a chatbubble entity if needed
1265         if (!this.chatbubbleentity)
1266         {
1267                 this.chatbubbleentity = new(chatbubbleentity);
1268                 this.chatbubbleentity.owner = this;
1269                 this.chatbubbleentity.exteriormodeltoclient = this;
1270                 setthink(this.chatbubbleentity, ChatBubbleThink);
1271                 this.chatbubbleentity.nextthink = time;
1272                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1273                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1274                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1275                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1276                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1277                 //this.chatbubbleentity.model = "";
1278                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1279         }
1280 }
1281
1282
1283 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1284 // added to the model skins
1285 /*void UpdateColorModHack()
1286 {
1287         float c;
1288         c = this.clientcolors & 15;
1289         // LordHavoc: only bothering to support white, green, red, yellow, blue
1290              if (!teamplay) this.colormod = '0 0 0';
1291         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1292         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1293         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1294         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1295         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1296         else this.colormod = '1 1 1';
1297 }*/
1298
1299 void respawn(entity this)
1300 {
1301         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1302         {
1303                 this.solid = SOLID_NOT;
1304                 this.takedamage = DAMAGE_NO;
1305                 set_movetype(this, MOVETYPE_FLY);
1306                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1307                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1308                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1309                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1310                 if(autocvar_g_respawn_ghosts_maxtime)
1311                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1312         }
1313
1314         CopyBody(this, 1);
1315
1316         this.effects |= EF_NODRAW; // prevent another CopyBody
1317         PutClientInServer(this);
1318 }
1319
1320 void PrintToChat(entity client, string text)
1321 {
1322         text = strcat("\{1}^7", text, "\n");
1323         sprint(client, text);
1324 }
1325
1326 void DebugPrintToChat(entity client, string text)
1327 {
1328         if (autocvar_developer)
1329         {
1330                 PrintToChat(client, text);
1331         }
1332 }
1333
1334 void PrintToChatAll(string text)
1335 {
1336         text = strcat("\{1}^7", text, "\n");
1337         bprint(text);
1338 }
1339
1340 void DebugPrintToChatAll(string text)
1341 {
1342         if (autocvar_developer)
1343         {
1344                 PrintToChatAll(text);
1345         }
1346 }
1347
1348 void PrintToChatTeam(int team_num, string text)
1349 {
1350         text = strcat("\{1}^7", text, "\n");
1351         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1352         {
1353                 if (it.team == team_num)
1354                 {
1355                         sprint(it, text);
1356                 }
1357         });
1358 }
1359
1360 void DebugPrintToChatTeam(int team_num, string text)
1361 {
1362         if (autocvar_developer)
1363         {
1364                 PrintToChatTeam(team_num, text);
1365         }
1366 }
1367
1368 void play_countdown(entity this, float finished, Sound samp)
1369 {
1370         TC(Sound, samp);
1371         if(IS_REAL_CLIENT(this))
1372                 if(floor(finished - time - frametime) != floor(finished - time))
1373                         if(finished - time < 6)
1374                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1375 }
1376
1377 void player_powerups(entity this)
1378 {
1379         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1380         int items_prev = this.items;
1381
1382         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1383                 this.modelflags |= MF_ROCKET;
1384         else
1385                 this.modelflags &= ~MF_ROCKET;
1386
1387         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1388
1389         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1390                 return;
1391
1392         Fire_ApplyDamage(this);
1393         Fire_ApplyEffect(this);
1394
1395         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1396         {
1397                 if (this.items & ITEM_Strength.m_itemid)
1398                 {
1399                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1400                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1401                         if (time > this.strength_finished)
1402                         {
1403                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1404                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1405                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1406                         }
1407                 }
1408                 else
1409                 {
1410                         if (time < this.strength_finished)
1411                         {
1412                                 this.items = this.items | ITEM_Strength.m_itemid;
1413                                 if(!g_cts)
1414                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1415                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1416                         }
1417                 }
1418                 if (this.items & ITEM_Shield.m_itemid)
1419                 {
1420                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1421                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1422                         if (time > this.invincible_finished)
1423                         {
1424                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1425                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1427                         }
1428                 }
1429                 else
1430                 {
1431                         if (time < this.invincible_finished)
1432                         {
1433                                 this.items = this.items | ITEM_Shield.m_itemid;
1434                                 if(!g_cts)
1435                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1437                         }
1438                 }
1439                 if (this.items & IT_SUPERWEAPON)
1440                 {
1441                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1442                         {
1443                                 this.superweapons_finished = 0;
1444                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1445                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1447                         }
1448                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1449                         {
1450                                 // don't let them run out
1451                         }
1452                         else
1453                         {
1454                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1455                                 if (time > this.superweapons_finished)
1456                                 {
1457                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1458                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1459                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1460                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1461                                 }
1462                         }
1463                 }
1464                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1465                 {
1466                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1467                         {
1468                                 this.items = this.items | IT_SUPERWEAPON;
1469                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1470                                 {
1471                                         if(!g_cts)
1472                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1473                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1474                                 }
1475                         }
1476                         else
1477                         {
1478                                 this.superweapons_finished = 0;
1479                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1480                         }
1481                 }
1482                 else
1483                 {
1484                         this.superweapons_finished = 0;
1485                 }
1486         }
1487
1488         if(autocvar_g_nodepthtestplayers)
1489                 this.effects = this.effects | EF_NODEPTHTEST;
1490
1491         if(autocvar_g_fullbrightplayers)
1492                 this.effects = this.effects | EF_FULLBRIGHT;
1493
1494         if (time >= game_starttime)
1495         if (time < this.spawnshieldtime)
1496                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1497
1498         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1499 }
1500
1501 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1502 {
1503         if(current > stable)
1504                 return current;
1505         else if(current > stable - 0.25) // when close enough, "snap"
1506                 return stable;
1507         else
1508                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1509 }
1510
1511 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1512 {
1513         if(current < stable)
1514                 return current;
1515         else if(current < stable + 0.25) // when close enough, "snap"
1516                 return stable;
1517         else
1518                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1519 }
1520
1521 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1522 {
1523         if(current > rotstable)
1524         {
1525                 if(rotframetime > 0)
1526                 {
1527                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1528                         current = max(rotstable, current - rotlinear * rotframetime);
1529                 }
1530         }
1531         else if(current < regenstable)
1532         {
1533                 if(regenframetime > 0)
1534                 {
1535                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1536                         current = min(regenstable, current + regenlinear * regenframetime);
1537                 }
1538         }
1539
1540         if(current > limit)
1541                 current = limit;
1542
1543         return current;
1544 }
1545
1546 void player_regen(entity this)
1547 {
1548         float max_mod, regen_mod, rot_mod, limit_mod;
1549         max_mod = regen_mod = rot_mod = limit_mod = 1;
1550
1551         float regen_health = autocvar_g_balance_health_regen;
1552         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1553         float regen_health_rot = autocvar_g_balance_health_rot;
1554         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1555         float regen_health_stable = autocvar_g_balance_health_regenstable;
1556         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1557         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1558                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1559         max_mod = M_ARGV(1, float);
1560         regen_mod = M_ARGV(2, float);
1561         rot_mod = M_ARGV(3, float);
1562         limit_mod = M_ARGV(4, float);
1563         regen_health = M_ARGV(5, float);
1564         regen_health_linear = M_ARGV(6, float);
1565         regen_health_rot = M_ARGV(7, float);
1566         regen_health_rotlinear = M_ARGV(8, float);
1567         regen_health_stable = M_ARGV(9, float);
1568         regen_health_rotstable = M_ARGV(10, float);
1569
1570         if(!mutator_returnvalue)
1571         if(!STAT(FROZEN, this))
1572         {
1573                 float mina, maxa, limith, limita;
1574                 maxa = autocvar_g_balance_armor_rotstable;
1575                 mina = autocvar_g_balance_armor_regenstable;
1576                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1577                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1578
1579                 regen_health_rotstable = regen_health_rotstable * max_mod;
1580                 regen_health_stable = regen_health_stable * max_mod;
1581                 limith = limith * limit_mod;
1582                 limita = limita * limit_mod;
1583
1584                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1585                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1586                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1587                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1588                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1589                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1590         }
1591
1592         // if player rotted to death...  die!
1593         // check this outside above checks, as player may still be able to rot to death
1594         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1595         {
1596                 if(this.vehicle)
1597                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1598                 if(this.event_damage)
1599                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1600         }
1601
1602         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1603         {
1604                 float minf, maxf, limitf;
1605
1606                 maxf = autocvar_g_balance_fuel_rotstable;
1607                 minf = autocvar_g_balance_fuel_regenstable;
1608                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1609
1610                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1611                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1612                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1613         }
1614 }
1615
1616 bool zoomstate_set;
1617 void SetZoomState(entity this, float newzoom)
1618 {
1619         if(newzoom != CS(this).zoomstate)
1620         {
1621                 CS(this).zoomstate = newzoom;
1622                 ClientData_Touch(this);
1623         }
1624         zoomstate_set = true;
1625 }
1626
1627 void GetPressedKeys(entity this)
1628 {
1629         MUTATOR_CALLHOOK(GetPressedKeys, this);
1630         int keys = STAT(PRESSED_KEYS, this);
1631         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1632         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1633         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1634         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1635
1636         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1637         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1638         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1639         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1640         CS(this).pressedkeys = keys; // store for other users
1641
1642         STAT(PRESSED_KEYS, this) = keys;
1643 }
1644
1645 /*
1646 ======================
1647 spectate mode routines
1648 ======================
1649 */
1650
1651 void SpectateCopy(entity this, entity spectatee)
1652 {
1653         TC(Client, this); TC(Client, spectatee);
1654
1655         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1656         PS(this) = PS(spectatee);
1657         this.armortype = spectatee.armortype;
1658         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1659         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1660         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1661         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1662         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1663         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1664         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1665         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1666         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1667         CS(this).impulse = 0;
1668         this.items = spectatee.items;
1669         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1670         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1671         this.strength_finished = spectatee.strength_finished;
1672         this.invincible_finished = spectatee.invincible_finished;
1673         this.superweapons_finished = spectatee.superweapons_finished;
1674         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1675         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1676         this.punchangle = spectatee.punchangle;
1677         this.view_ofs = spectatee.view_ofs;
1678         this.velocity = spectatee.velocity;
1679         this.dmg_take = spectatee.dmg_take;
1680         this.dmg_save = spectatee.dmg_save;
1681         this.dmg_inflictor = spectatee.dmg_inflictor;
1682         this.v_angle = spectatee.v_angle;
1683         this.angles = spectatee.v_angle;
1684         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1685         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1686         this.viewloc = spectatee.viewloc;
1687         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1688                 this.fixangle = true;
1689         setorigin(this, spectatee.origin);
1690         setsize(this, spectatee.mins, spectatee.maxs);
1691         SetZoomState(this, CS(spectatee).zoomstate);
1692
1693     anticheat_spectatecopy(this, spectatee);
1694         STAT(HUD, this) = STAT(HUD, spectatee);
1695         if(spectatee.vehicle)
1696     {
1697         this.angles = spectatee.v_angle;
1698
1699         //this.fixangle = false;
1700         //this.velocity = spectatee.vehicle.velocity;
1701         this.vehicle_health = spectatee.vehicle_health;
1702         this.vehicle_shield = spectatee.vehicle_shield;
1703         this.vehicle_energy = spectatee.vehicle_energy;
1704         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1705         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1706         this.vehicle_reload1 = spectatee.vehicle_reload1;
1707         this.vehicle_reload2 = spectatee.vehicle_reload2;
1708
1709         //msg_entity = this;
1710
1711        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1712             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1713            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1714            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1715
1716         //WriteByte (MSG_ONE, SVC_SETVIEW);
1717         //    WriteEntity(MSG_ONE, this);
1718         //makevectors(spectatee.v_angle);
1719         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1720     }
1721 }
1722
1723 bool SpectateUpdate(entity this)
1724 {
1725         if(!this.enemy)
1726                 return false;
1727
1728         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1729         {
1730                 SetSpectatee(this, NULL);
1731                 return false;
1732         }
1733
1734         SpectateCopy(this, this.enemy);
1735
1736         return true;
1737 }
1738
1739 bool SpectateSet(entity this)
1740 {
1741         if(!IS_PLAYER(this.enemy))
1742                 return false;
1743
1744         ClientData_Touch(this.enemy);
1745
1746         msg_entity = this;
1747         WriteByte(MSG_ONE, SVC_SETVIEW);
1748         WriteEntity(MSG_ONE, this.enemy);
1749         set_movetype(this, MOVETYPE_NONE);
1750         accuracy_resend(this);
1751
1752         if(!SpectateUpdate(this))
1753                 PutObserverInServer(this);
1754
1755         return true;
1756 }
1757
1758 void SetSpectatee_status(entity this, int spectatee_num)
1759 {
1760         int oldspectatee_status = CS(this).spectatee_status;
1761         CS(this).spectatee_status = spectatee_num;
1762
1763         if (CS(this).spectatee_status != oldspectatee_status)
1764         {
1765                 ClientData_Touch(this);
1766                 if (g_race || g_cts) race_InitSpectator();
1767         }
1768 }
1769
1770 void SetSpectatee(entity this, entity spectatee)
1771 {
1772         if(IS_BOT_CLIENT(this))
1773                 return; // bots abuse .enemy, this code is useless to them
1774
1775         entity old_spectatee = this.enemy;
1776
1777         this.enemy = spectatee;
1778
1779         // WEAPONTODO
1780         // these are required to fix the spectator bug with arc
1781         if(old_spectatee)
1782         {
1783                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1784                 {
1785                         .entity weaponentity = weaponentities[slot];
1786                         if(old_spectatee.(weaponentity).arc_beam)
1787                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1788                 }
1789         }
1790         if(this.enemy)
1791         {
1792                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1793                 {
1794                         .entity weaponentity = weaponentities[slot];
1795                         if(this.enemy.(weaponentity).arc_beam)
1796                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1797                 }
1798         }
1799
1800         if (this.enemy)
1801                 SetSpectatee_status(this, etof(this.enemy));
1802
1803         // needed to update spectator list
1804         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1805 }
1806
1807 bool Spectate(entity this, entity pl)
1808 {
1809         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1810                 return false;
1811         pl = M_ARGV(1, entity);
1812
1813         SetSpectatee(this, pl);
1814         return SpectateSet(this);
1815 }
1816
1817 bool SpectateNext(entity this)
1818 {
1819         entity ent = find(this.enemy, classname, STR_PLAYER);
1820
1821         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1822                 ent = M_ARGV(1, entity);
1823         else if (!ent)
1824                 ent = find(ent, classname, STR_PLAYER);
1825
1826         if(ent) { SetSpectatee(this, ent); }
1827
1828         return SpectateSet(this);
1829 }
1830
1831 bool SpectatePrev(entity this)
1832 {
1833         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1834         entity ent = findchain(classname, STR_PLAYER);
1835         if (!ent) // no player
1836                 return false;
1837
1838         entity first = ent;
1839         // skip players until current spectated player
1840         if(this.enemy)
1841         while(ent && ent != this.enemy)
1842                 ent = ent.chain;
1843
1844         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1845         {
1846                 case MUT_SPECPREV_FOUND:
1847                     ent = M_ARGV(1, entity);
1848                     break;
1849                 case MUT_SPECPREV_RETURN:
1850                     return true;
1851                 case MUT_SPECPREV_CONTINUE:
1852                 default:
1853                 {
1854                         if(ent.chain)
1855                                 ent = ent.chain;
1856                         else
1857                                 ent = first;
1858                         break;
1859                 }
1860         }
1861
1862         SetSpectatee(this, ent);
1863         return SpectateSet(this);
1864 }
1865
1866 /*
1867 =============
1868 ShowRespawnCountdown()
1869
1870 Update a respawn countdown display.
1871 =============
1872 */
1873 void ShowRespawnCountdown(entity this)
1874 {
1875         float number;
1876         if(!IS_DEAD(this)) // just respawned?
1877                 return;
1878         else
1879         {
1880                 number = ceil(this.respawn_time - time);
1881                 if(number <= 0)
1882                         return;
1883                 if(number <= this.respawn_countdown)
1884                 {
1885                         this.respawn_countdown = number - 1;
1886                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1887                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1888                 }
1889         }
1890 }
1891
1892 .bool team_selected;
1893 bool ShowTeamSelection(entity this)
1894 {
1895         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1896                 return false;
1897         stuffcmd(this, "menu_showteamselect\n");
1898         return true;
1899 }
1900 void Join(entity this)
1901 {
1902         TRANSMUTE(Player, this);
1903
1904         if(!this.team_selected)
1905         if(autocvar_g_campaign || autocvar_g_balance_teams)
1906                 TeamBalance_JoinBestTeam(this);
1907
1908         if(autocvar_g_campaign)
1909                 campaign_bots_may_start = true;
1910
1911         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1912
1913         PutClientInServer(this);
1914
1915         if(IS_PLAYER(this))
1916         if(teamplay && this.team != -1)
1917         {
1918         }
1919         else
1920                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1921         this.team_selected = false;
1922 }
1923
1924 int GetPlayerLimit()
1925 {
1926         int player_limit = autocvar_g_maxplayers;
1927         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1928         player_limit = M_ARGV(0, int);
1929         return player_limit;
1930 }
1931
1932 /**
1933  * Determines whether the player is allowed to join. This depends on cvar
1934  * g_maxplayers, if it isn't used this function always return true, otherwise
1935  * it checks whether the number of currently playing players exceeds g_maxplayers.
1936  * @return int number of free slots for players, 0 if none
1937  */
1938 int nJoinAllowed(entity this, entity ignore)
1939 {
1940         if(!ignore)
1941         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1942         // so report 0 free slots if restricted
1943         {
1944                 if(autocvar_g_forced_team_otherwise == "spectate")
1945                         return 0;
1946                 if(autocvar_g_forced_team_otherwise == "spectator")
1947                         return 0;
1948         }
1949
1950         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1951                 return 0; // forced spectators can never join
1952
1953         // TODO simplify this
1954         int totalClients = 0;
1955         int currentlyPlaying = 0;
1956         FOREACH_CLIENT(true, {
1957                 if(it != ignore)
1958                         ++totalClients;
1959                 if(IS_REAL_CLIENT(it))
1960                 if(IS_PLAYER(it) || it.caplayer)
1961                         ++currentlyPlaying;
1962         });
1963
1964         int player_limit = GetPlayerLimit();
1965
1966         float free_slots = 0;
1967         if (!player_limit)
1968                 free_slots = maxclients - totalClients;
1969         else if(currentlyPlaying < player_limit)
1970                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1971
1972         static float join_prevent_msg_time = 0;
1973         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1974         {
1975                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1976                 join_prevent_msg_time = time + 3;
1977         }
1978
1979         return free_slots;
1980 }
1981
1982 /**
1983  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1984  * g_maxplayers_spectator_blocktime seconds
1985  */
1986 void checkSpectatorBlock(entity this)
1987 {
1988         if(IS_SPEC(this) || IS_OBSERVER(this))
1989         if(!this.caplayer)
1990         if(IS_REAL_CLIENT(this))
1991         {
1992                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1993                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1994                         dropclient(this);
1995                 }
1996         }
1997 }
1998
1999 void PrintWelcomeMessage(entity this)
2000 {
2001         if(CS(this).motd_actived_time == 0)
2002         {
2003                 if (autocvar_g_campaign) {
2004                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2005                                 CS(this).motd_actived_time = time;
2006                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2007                         }
2008                 } else {
2009                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2010                                 CS(this).motd_actived_time = time;
2011                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2012                         }
2013                 }
2014         }
2015         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2016         {
2017                 if (autocvar_g_campaign) {
2018                         if (PHYS_INPUT_BUTTON_INFO(this))
2019                                 CS(this).motd_actived_time = time;
2020                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2021                                 CS(this).motd_actived_time = 0;
2022                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2023                         }
2024                 } else {
2025                         if (PHYS_INPUT_BUTTON_INFO(this))
2026                                 CS(this).motd_actived_time = time;
2027                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2028                                 CS(this).motd_actived_time = 0;
2029                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2030                         }
2031                 }
2032         }
2033         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2034         {
2035                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2036                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2037                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2038                 {
2039                         // instanctly hide MOTD
2040                         CS(this).motd_actived_time = 0;
2041                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2042                 }
2043         }
2044 }
2045
2046 const int MIN_SPEC_TIME = 1;
2047 bool joinAllowed(entity this)
2048 {
2049         if (CS(this).version_mismatch) return false;
2050         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2051         if (!nJoinAllowed(this, this)) return false;
2052         if (teamplay && lockteams) return false;
2053         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2054         if (ShowTeamSelection(this)) return false;
2055         return true;
2056 }
2057
2058 .int items_added;
2059 .string shootfromfixedorigin;
2060 bool PlayerThink(entity this)
2061 {
2062         if (game_stopped || intermission_running) {
2063                 this.modelflags &= ~MF_ROCKET;
2064                 if(intermission_running)
2065                         IntermissionThink(this);
2066                 return false;
2067         }
2068
2069         if (timeout_status == TIMEOUT_ACTIVE) {
2070         // don't allow the player to turn around while game is paused
2071                 // FIXME turn this into CSQC stuff
2072                 this.v_angle = this.lastV_angle;
2073                 this.angles = this.lastV_angle;
2074                 this.fixangle = true;
2075         }
2076
2077         if (frametime) player_powerups(this);
2078
2079         if (IS_DEAD(this)) {
2080                 if (this.personal && g_race_qualifying) {
2081                         if (time > this.respawn_time) {
2082                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2083                                 respawn(this);
2084                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2085                         }
2086                 } else {
2087                         if (frametime) player_anim(this);
2088
2089                         if (this.respawn_flags & RESPAWN_DENY)
2090                         {
2091                                 STAT(RESPAWN_TIME, this) = 0;
2092                                 return false;
2093                         }
2094
2095                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2096
2097                         switch(this.deadflag)
2098                         {
2099                                 case DEAD_DYING:
2100                                 {
2101                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2102                                                 this.deadflag = DEAD_RESPAWNING;
2103                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2104                                                 this.deadflag = DEAD_DEAD;
2105                                         break;
2106                                 }
2107                                 case DEAD_DEAD:
2108                                 {
2109                                         if (button_pressed)
2110                                                 this.deadflag = DEAD_RESPAWNABLE;
2111                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2112                                                 this.deadflag = DEAD_RESPAWNING;
2113                                         break;
2114                                 }
2115                                 case DEAD_RESPAWNABLE:
2116                                 {
2117                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2118                                                 this.deadflag = DEAD_RESPAWNING;
2119                                         break;
2120                                 }
2121                                 case DEAD_RESPAWNING:
2122                                 {
2123                                         if (time > this.respawn_time)
2124                                         {
2125                                                 this.respawn_time = time + 1; // only retry once a second
2126                                                 this.respawn_time_max = this.respawn_time;
2127                                                 respawn(this);
2128                                         }
2129                                         break;
2130                                 }
2131                         }
2132
2133                         ShowRespawnCountdown(this);
2134
2135                         if (this.respawn_flags & RESPAWN_SILENT)
2136                                 STAT(RESPAWN_TIME, this) = 0;
2137                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2138                         {
2139                                 if (time < this.respawn_time)
2140                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2141                                 else if (this.deadflag != DEAD_RESPAWNING)
2142                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2143                         }
2144                         else
2145                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2146                 }
2147
2148                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2149                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2150                         STAT(RESPAWN_TIME, this) *= -1;
2151
2152                 return false;
2153         }
2154
2155         FixPlayermodel(this);
2156
2157         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2158                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2159                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2160         }
2161
2162         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2163         //if(frametime)
2164         {
2165                 this.items &= ~this.items_added;
2166
2167                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2168                 {
2169                         .entity weaponentity = weaponentities[slot];
2170                         W_WeaponFrame(this, weaponentity);
2171                 }
2172
2173                 this.items_added = 0;
2174                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2175             this.items_added |= IT_FUEL;
2176
2177                 this.items |= this.items_added;
2178         }
2179
2180         player_regen(this);
2181
2182         // WEAPONTODO: Add a weapon request for this
2183         // rot vortex charge to the charge limit
2184         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2185         {
2186                 .entity weaponentity = weaponentities[slot];
2187                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2188                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2189         }
2190
2191         if (frametime) player_anim(this);
2192
2193         // secret status
2194         secrets_setstatus(this);
2195
2196         // monsters status
2197         monsters_setstatus(this);
2198
2199         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2200
2201         return true;
2202 }
2203
2204 .bool would_spectate;
2205 void ObserverThink(entity this)
2206 {
2207         if ( CS(this).impulse )
2208         {
2209                 MinigameImpulse(this, CS(this).impulse);
2210                 CS(this).impulse = 0;
2211         }
2212
2213         if (this.flags & FL_JUMPRELEASED) {
2214                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2215                         this.flags &= ~FL_JUMPRELEASED;
2216                         this.flags |= FL_SPAWNING;
2217                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2218                         this.flags &= ~FL_JUMPRELEASED;
2219                         if(SpectateNext(this)) {
2220                                 TRANSMUTE(Spectator, this);
2221                         }
2222                 } else {
2223                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2224                         set_movetype(this, preferred_movetype);
2225                 }
2226         } else {
2227                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2228                         this.flags |= FL_JUMPRELEASED;
2229                         if(this.flags & FL_SPAWNING)
2230                         {
2231                                 this.flags &= ~FL_SPAWNING;
2232                                 Join(this);
2233                                 return;
2234                         }
2235                 }
2236         }
2237 }
2238
2239 void SpectatorThink(entity this)
2240 {
2241         if ( CS(this).impulse )
2242         {
2243                 if(MinigameImpulse(this, CS(this).impulse))
2244                         CS(this).impulse = 0;
2245
2246                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2247                 {
2248                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2249                         CS(this).impulse = 0;
2250                         return;
2251                 }
2252         }
2253
2254         if (this.flags & FL_JUMPRELEASED) {
2255                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2256                         this.flags &= ~FL_JUMPRELEASED;
2257                         this.flags |= FL_SPAWNING;
2258                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2259                         this.flags &= ~FL_JUMPRELEASED;
2260                         if(SpectateNext(this)) {
2261                                 TRANSMUTE(Spectator, this);
2262                         } else {
2263                                 TRANSMUTE(Observer, this);
2264                                 PutClientInServer(this);
2265                         }
2266                         CS(this).impulse = 0;
2267                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2268                         this.flags &= ~FL_JUMPRELEASED;
2269                         if(SpectatePrev(this)) {
2270                                 TRANSMUTE(Spectator, this);
2271                         } else {
2272                                 TRANSMUTE(Observer, this);
2273                                 PutClientInServer(this);
2274                         }
2275                         CS(this).impulse = 0;
2276                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2277                         this.would_spectate = false;
2278                         this.flags &= ~FL_JUMPRELEASED;
2279                         TRANSMUTE(Observer, this);
2280                         PutClientInServer(this);
2281                 } else {
2282                         if(!SpectateUpdate(this))
2283                         {
2284                                 if(!SpectateNext(this))
2285                                 {
2286                                         PutObserverInServer(this);
2287                                         this.would_spectate = true;
2288                                 }
2289                         }
2290                 }
2291         } else {
2292                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2293                         this.flags |= FL_JUMPRELEASED;
2294                         if(this.flags & FL_SPAWNING)
2295                         {
2296                                 this.flags &= ~FL_SPAWNING;
2297                                 Join(this);
2298                                 return;
2299                         }
2300                 }
2301                 if(!SpectateUpdate(this))
2302                         PutObserverInServer(this);
2303         }
2304
2305         this.flags |= FL_CLIENT | FL_NOTARGET;
2306 }
2307
2308 void PlayerUseKey(entity this)
2309 {
2310         if (!IS_PLAYER(this))
2311                 return;
2312
2313         if(this.vehicle)
2314         {
2315                 if(!game_stopped)
2316                 {
2317                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2318                         return;
2319                 }
2320         }
2321         else if(autocvar_g_vehicles_enter)
2322         {
2323                 if(!STAT(FROZEN, this))
2324                 if(!IS_DEAD(this))
2325                 if(!game_stopped)
2326                 {
2327                         entity head, closest_target = NULL;
2328                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2329
2330                         while(head) // find the closest acceptable target to enter
2331                         {
2332                                 if(IS_VEHICLE(head))
2333                                 if(!IS_DEAD(head))
2334                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2335                                 if(head.takedamage != DAMAGE_NO)
2336                                 {
2337                                         if(closest_target)
2338                                         {
2339                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2340                                                 { closest_target = head; }
2341                                         }
2342                                         else { closest_target = head; }
2343                                 }
2344
2345                                 head = head.chain;
2346                         }
2347
2348                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2349                 }
2350         }
2351
2352         // a use key was pressed; call handlers
2353         MUTATOR_CALLHOOK(PlayerUseKey, this);
2354 }
2355
2356
2357 /*
2358 =============
2359 PlayerPreThink
2360
2361 Called every frame for each client before the physics are run
2362 =============
2363 */
2364 .float last_vehiclecheck;
2365 void PlayerPreThink (entity this)
2366 {
2367         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2368         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2369
2370         WarpZone_PlayerPhysics_FixVAngle(this);
2371
2372         if (frametime) {
2373                 // physics frames: update anticheat stuff
2374                 anticheat_prethink(this);
2375         }
2376
2377         if (blockSpectators && frametime) {
2378                 // WORKAROUND: only use dropclient in server frames (frametime set).
2379                 // Never use it in cl_movement frames (frametime zero).
2380                 checkSpectatorBlock(this);
2381         }
2382
2383         zoomstate_set = false;
2384
2385         // Check for nameless players
2386         if (this.netname == "" || this.netname != CS(this).netname_previous)
2387         {
2388                 bool assume_unchanged = (CS(this).netname_previous == "");
2389                 if (isInvisibleString(this.netname))
2390                 {
2391                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2392                         assume_unchanged = false;
2393                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2394                 }
2395                 if (!assume_unchanged && autocvar_sv_eventlog)
2396                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2397                 strcpy(CS(this).netname_previous, this.netname);
2398         }
2399
2400         // version nagging
2401         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2402         CS(this).version_nagtime = 0;
2403         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2404             // git client
2405         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2406             // git server
2407             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2408         } else {
2409             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2410             if (r < 0) { // old client
2411                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2412             } else if (r > 0) { // old server
2413                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2414             }
2415         }
2416     }
2417
2418         // GOD MODE info
2419         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2420         {
2421                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2422                 this.max_armorvalue = 0;
2423         }
2424
2425         if(IS_PLAYER(this))
2426         {
2427                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2428                 {
2429                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2430                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2431                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2432
2433                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2434                                 Unfreeze(this, false);
2435                 }
2436                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2437                 {
2438                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2439                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2440
2441                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2442                         {
2443                                 if (this.vehicle)
2444                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2445                                 if(this.event_damage)
2446                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2447                         }
2448                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2449                                 Unfreeze(this, false);
2450                 }
2451         }
2452
2453         MUTATOR_CALLHOOK(PlayerPreThink, this);
2454
2455         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2456         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2457         {
2458                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2459                 {
2460                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2461                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2462                         {
2463                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2464                         }
2465                         else if(!it.owner)
2466                         {
2467                                 if(!it.team || SAME_TEAM(this, it))
2468                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2469                                 else if(autocvar_g_vehicles_steal)
2470                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2471                         }
2472                 });
2473
2474                 this.last_vehiclecheck = time + 1;
2475         }
2476
2477         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2478         {
2479                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2480                         PlayerUseKey(this);
2481                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2482         }
2483
2484         if (IS_REAL_CLIENT(this))
2485                 PrintWelcomeMessage(this);
2486
2487         if (IS_PLAYER(this)) {
2488                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2489                         error("Client can't be spawned as player on connection!");
2490                 if(!PlayerThink(this))
2491                         return;
2492         }
2493         else if (game_stopped || intermission_running) {
2494                 if(intermission_running)
2495                         IntermissionThink(this);
2496                 return;
2497         }
2498         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2499         {
2500                 CS(this).autojoin_checked = true;
2501                 // don't do this in ClientConnect
2502                 // many things can go wrong if a client is spawned as player on connection
2503                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2504                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2505                                 && (!teamplay || autocvar_g_balance_teams)))
2506                 {
2507                         campaign_bots_may_start = true;
2508                         Join(this);
2509                         return;
2510                 }
2511         }
2512         else if (IS_OBSERVER(this)) {
2513                 ObserverThink(this);
2514         }
2515         else if (IS_SPEC(this)) {
2516                 SpectatorThink(this);
2517         }
2518
2519         // WEAPONTODO: Add weapon request for this
2520         if (!zoomstate_set) {
2521                 bool wep_zoomed = false;
2522                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2523                 {
2524                         .entity weaponentity = weaponentities[slot];
2525                         Weapon thiswep = this.(weaponentity).m_weapon;
2526                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2527                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2528                 }
2529                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2530     }
2531
2532         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2533         {
2534                 CS(this).teamkill_soundtime = 0;
2535
2536                 entity e = CS(this).teamkill_soundsource;
2537                 entity oldpusher = e.pusher;
2538                 e.pusher = this;
2539                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2540                 e.pusher = oldpusher;
2541         }
2542
2543         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2544                 CS(this).taunt_soundtime = 0;
2545                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2546         }
2547
2548         target_voicescript_next(this);
2549
2550         // WEAPONTODO: Move into weaponsystem somehow
2551         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2552         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2553         {
2554                 .entity weaponentity = weaponentities[slot];
2555                 if(this.(weaponentity).m_weapon == WEP_Null)
2556                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2557         }
2558 }
2559
2560 void DrownPlayer(entity this)
2561 {
2562         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2563                 return;
2564
2565         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2566         {
2567                 if(this.air_finished < time)
2568                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2569                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2570         }
2571         else if (this.air_finished < time)
2572         {       // drown!
2573                 if (this.pain_finished < time)
2574                 {
2575                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2576                         this.pain_finished = time + 0.5;
2577                 }
2578         }
2579 }
2580
2581 .bool move_qcphysics;
2582
2583 void Player_Physics(entity this)
2584 {
2585         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2586
2587         if(!this.move_qcphysics)
2588                 return;
2589
2590         if(!frametime && !CS(this).pm_frametime)
2591                 return;
2592
2593         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2594
2595         CS(this).pm_frametime = 0;
2596 }
2597
2598 /*
2599 =============
2600 PlayerPostThink
2601
2602 Called every frame for each client after the physics are run
2603 =============
2604 */
2605 void PlayerPostThink (entity this)
2606 {
2607         Player_Physics(this);
2608
2609         if (sv_maxidle > 0)
2610         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2611         if (IS_REAL_CLIENT(this))
2612         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2613         {
2614                 int totalClients = 0;
2615                 if(sv_maxidle_slots > 0)
2616                 {
2617                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2618                         {
2619                                 ++totalClients;
2620                         });
2621                 }
2622
2623                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2624                 { /* do nothing */ }
2625                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2626                 {
2627                         if (CS(this).idlekick_lasttimeleft)
2628                         {
2629                                 CS(this).idlekick_lasttimeleft = 0;
2630                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2631                         }
2632                 }
2633                 else
2634                 {
2635                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2636                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2637                                 if (!CS(this).idlekick_lasttimeleft)
2638                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2639                         }
2640                         if (timeleft <= 0) {
2641                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2642                                 dropclient(this);
2643                                 return;
2644                         }
2645                         else if (timeleft <= 10) {
2646                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2647                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2648                 }
2649                                 CS(this).idlekick_lasttimeleft = timeleft;
2650                         }
2651                 }
2652         }
2653
2654         CheatFrame(this);
2655
2656         if (game_stopped)
2657         {
2658                 this.solid = SOLID_NOT;
2659                 this.takedamage = DAMAGE_NO;
2660                 set_movetype(this, MOVETYPE_NONE);
2661         }
2662
2663         if (IS_PLAYER(this)) {
2664                 if(this.death_time == time && IS_DEAD(this))
2665                 {
2666                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2667                         // once all the damage events of this frame have been processed with normal size
2668                         this.maxs.z = 5;
2669                         setsize(this, this.mins, this.maxs);
2670                 }
2671                 DrownPlayer(this);
2672                 UpdateChatBubble(this);
2673                 if (CS(this).impulse) ImpulseCommands(this);
2674                 if (game_stopped)
2675                 {
2676                         CSQCMODEL_AUTOUPDATE(this);
2677                         return;
2678                 }
2679                 GetPressedKeys(this);
2680         }
2681
2682         if (this.waypointsprite_attachedforcarrier) {
2683             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2684                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2685     }
2686
2687         CSQCMODEL_AUTOUPDATE(this);
2688 }
2689
2690 /**
2691  * message "": do not say, just test flood control
2692  * return value:
2693  *   1 = accept
2694  *   0 = reject
2695  *  -1 = fake accept
2696  */
2697 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2698 {
2699         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2700                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2701
2702         if (source)
2703                 msgin = formatmessage(source, msgin);
2704
2705         string colorstr;
2706         if (!(IS_PLAYER(source) || source.caplayer))
2707                 colorstr = "^0"; // black for spectators
2708         else if(teamplay)
2709                 colorstr = Team_ColorCode(source.team);
2710         else
2711         {
2712                 colorstr = "";
2713                 teamsay = false;
2714         }
2715
2716         if(game_stopped)
2717                 teamsay = false;
2718
2719         if (!source) {
2720                 colorstr = "";
2721                 teamsay = false;
2722         }
2723
2724         if(msgin != "")
2725                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2726
2727         /*
2728          * using bprint solves this... me stupid
2729         // how can we prevent the message from appearing in a listen server?
2730         // for now, just give "say" back and only handle say_team
2731         if(!teamsay)
2732         {
2733                 clientcommand(source, strcat("say ", msgin));
2734                 return;
2735         }
2736         */
2737
2738         string namestr = "";
2739         if (source)
2740                 namestr = playername(source, autocvar_g_chat_teamcolors);
2741
2742         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2743
2744         string msgstr = "", cmsgstr = "";
2745         string privatemsgprefix = string_null;
2746         int privatemsgprefixlen = 0;
2747         if (msgin != "")
2748         {
2749                 if(privatesay)
2750                 {
2751                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2752                         privatemsgprefixlen = strlen(msgstr);
2753                         msgstr = strcat(msgstr, msgin);
2754                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2755                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2756                 }
2757                 else if(teamsay)
2758                 {
2759                         if(strstrofs(msgin, "/me", 0) >= 0)
2760                         {
2761                                 //msgin = strreplace("/me", "", msgin);
2762                                 //msgin = substring(msgin, 3, strlen(msgin));
2763                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2764                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2765                         }
2766                         else
2767                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2768                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2769                 }
2770                 else
2771                 {
2772                         if(strstrofs(msgin, "/me", 0) >= 0)
2773                         {
2774                                 //msgin = strreplace("/me", "", msgin);
2775                                 //msgin = substring(msgin, 3, strlen(msgin));
2776                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2777                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
2778                         }
2779                         else {
2780                                 msgstr = "\{1}";
2781                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2782                                 msgstr = strcat(msgstr, msgin);
2783                         }
2784                         cmsgstr = "";
2785                 }
2786                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2787         }
2788
2789         string fullmsgstr = msgstr;
2790         string fullcmsgstr = cmsgstr;
2791
2792         // FLOOD CONTROL
2793         int flood = 0;
2794         var .float flood_field = floodcontrol_chat;
2795         if(floodcontrol && source)
2796         {
2797                 float flood_spl;
2798                 float flood_burst;
2799                 float flood_lmax;
2800                 float lines;
2801                 if(privatesay)
2802                 {
2803                         flood_spl = autocvar_g_chat_flood_spl_tell;
2804                         flood_burst = autocvar_g_chat_flood_burst_tell;
2805                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2806                         flood_field = floodcontrol_chattell;
2807                 }
2808                 else if(teamsay)
2809                 {
2810                         flood_spl = autocvar_g_chat_flood_spl_team;
2811                         flood_burst = autocvar_g_chat_flood_burst_team;
2812                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2813                         flood_field = floodcontrol_chatteam;
2814                 }
2815                 else
2816                 {
2817                         flood_spl = autocvar_g_chat_flood_spl;
2818                         flood_burst = autocvar_g_chat_flood_burst;
2819                         flood_lmax = autocvar_g_chat_flood_lmax;
2820                         flood_field = floodcontrol_chat;
2821                 }
2822                 flood_burst = max(0, flood_burst - 1);
2823                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2824
2825                 // do flood control for the default line size
2826                 if(msgstr != "")
2827                 {
2828                         getWrappedLine_remaining = msgstr;
2829                         msgstr = "";
2830                         lines = 0;
2831                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2832                         {
2833                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2834                                 ++lines;
2835                         }
2836                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2837
2838                         if(getWrappedLine_remaining != "")
2839                         {
2840                                 msgstr = strcat(msgstr, "\n");
2841                                 flood = 2;
2842                         }
2843
2844                         if (time >= source.(flood_field))
2845                         {
2846                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2847                         }
2848                         else
2849                         {
2850                                 flood = 1;
2851                                 msgstr = fullmsgstr;
2852                         }
2853                 }
2854                 else
2855                 {
2856                         if (time >= source.(flood_field))
2857                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2858                         else
2859                                 flood = 1;
2860                 }
2861
2862                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2863                         source.(flood_field) = flood = 0;
2864         }
2865
2866         string sourcemsgstr, sourcecmsgstr;
2867         if(flood == 2) // cannot happen for empty msgstr
2868         {
2869                 if(autocvar_g_chat_flood_notify_flooder)
2870                 {
2871                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2872                         sourcecmsgstr = "";
2873                 }
2874                 else
2875                 {
2876                         sourcemsgstr = fullmsgstr;
2877                         sourcecmsgstr = fullcmsgstr;
2878                 }
2879                 cmsgstr = "";
2880         }
2881         else
2882         {
2883                 sourcemsgstr = msgstr;
2884                 sourcecmsgstr = cmsgstr;
2885         }
2886
2887         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2888         {
2889                 if (!game_stopped)
2890                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2891                         teamsay = -1; // spectators
2892         }
2893
2894         if(flood)
2895                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2896
2897         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2898         if(privatesay)
2899                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2900
2901         int ret;
2902         if(source && CS(source).muted)
2903         {
2904                 // always fake the message
2905                 ret = -1;
2906         }
2907         else if(flood == 1)
2908         {
2909                 if (autocvar_g_chat_flood_notify_flooder)
2910                 {
2911                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2912                         ret = 0;
2913                 }
2914                 else
2915                         ret = -1;
2916         }
2917         else
2918         {
2919                 ret = 1;
2920         }
2921
2922         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2923         {
2924                 if (!game_stopped)
2925                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2926                         ret = -1; // just hide the message completely
2927         }
2928
2929         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2930         ret = M_ARGV(1, int);
2931
2932         if(sourcemsgstr != "" && ret != 0)
2933         {
2934                 if(ret < 0) // faked message, because the player is muted
2935                 {
2936                         sprint(source, sourcemsgstr);
2937                         if(sourcecmsgstr != "" && !privatesay)
2938                                 centerprint(source, sourcecmsgstr);
2939                 }
2940                 else if(privatesay) // private message, between 2 people only
2941                 {
2942                         sprint(source, sourcemsgstr);
2943                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2944                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2945                         {
2946                                 sprint(privatesay, msgstr);
2947                                 if(cmsgstr != "")
2948                                         centerprint(privatesay, cmsgstr);
2949                         }
2950                 }
2951                 else if ( teamsay && CS(source).active_minigame )
2952                 {
2953                         sprint(source, sourcemsgstr);
2954                         dedicated_print(msgstr); // send to server console too
2955                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2956                                 sprint(it, msgstr);
2957                         });
2958                 }
2959                 else if(teamsay > 0) // team message, only sent to team mates
2960                 {
2961                         sprint(source, sourcemsgstr);
2962                         dedicated_print(msgstr); // send to server console too
2963                         if(sourcecmsgstr != "")
2964                                 centerprint(source, sourcecmsgstr);
2965                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2966                                 sprint(it, msgstr);
2967                                 if(cmsgstr != "")
2968                                         centerprint(it, cmsgstr);
2969                         });
2970                 }
2971                 else if(teamsay < 0) // spectator message, only sent to spectators
2972                 {
2973                         sprint(source, sourcemsgstr);
2974                         dedicated_print(msgstr); // send to server console too
2975                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2976                                 sprint(it, msgstr);
2977                         });
2978                 }
2979                 else
2980                 {
2981                         if (source) {
2982                                 sprint(source, sourcemsgstr);
2983                                 dedicated_print(msgstr); // send to server console too
2984                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
2985                         }
2986                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2987                                 sprint(it, msgstr);
2988                         });
2989                 }
2990         }
2991
2992         return ret;
2993 }
2994
2995 // hack to copy the button fields from the client entity to the Client State
2996 void PM_UpdateButtons(entity this, entity store)
2997 {
2998         if(this.impulse)
2999                 store.impulse = this.impulse;
3000         this.impulse = 0;
3001
3002         bool typing = this.buttonchat || this.button14;
3003
3004         store.button0 = (typing) ? 0 : this.button0;
3005         //button1?!
3006         store.button2 = (typing) ? 0 : this.button2;
3007         store.button3 = (typing) ? 0 : this.button3;
3008         store.button4 = this.button4;
3009         store.button5 = (typing) ? 0 : this.button5;
3010         store.button6 = this.button6;
3011         store.button7 = this.button7;
3012         store.button8 = this.button8;
3013         store.button9 = this.button9;
3014         store.button10 = this.button10;
3015         store.button11 = this.button11;
3016         store.button12 = this.button12;
3017         store.button13 = this.button13;
3018         store.button14 = this.button14;
3019         store.button15 = this.button15;
3020         store.button16 = this.button16;
3021         store.buttonuse = this.buttonuse;
3022         store.buttonchat = this.buttonchat;
3023
3024         store.cursor_active = this.cursor_active;
3025         store.cursor_screen = this.cursor_screen;
3026         store.cursor_trace_start = this.cursor_trace_start;
3027         store.cursor_trace_endpos = this.cursor_trace_endpos;
3028         store.cursor_trace_ent = this.cursor_trace_ent;
3029
3030         store.ping = this.ping;
3031         store.ping_packetloss = this.ping_packetloss;
3032         store.ping_movementloss = this.ping_movementloss;
3033
3034         store.v_angle = this.v_angle;
3035         store.movement = (typing) ? '0 0 0' : this.movement;
3036 }
3037
3038 NET_HANDLE(fpsreport, bool)
3039 {
3040         int fps = ReadShort();
3041         PlayerScore_Set(sender, SP_FPS, fps);
3042         return true;
3043 }