qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include <server/gamelog.qh>
  24 #include "race.qh"
  25 #include "antilag.qh"
  26 #include "campaign.qh"
  27 #include "command/common.qh"
  28 #include "scores_rules.qh"
  29 #include "weapons/common.qh"
  30
  31 #include "bot/api.qh"
  32
  33 #include "../common/ent_cs.qh"
  34 #include "../common/wepent.qh"
  35 #include <common/state.qh>
  36
  37 #include "compat/quake3.qh"
  38
  39 #include <common/effects/qc/globalsound.qh>
  40
  41 #include "../common/mapobjects/func/conveyor.qh"
  42 #include <common/mapobjects/func/ladder.qh>
  43 #include "../common/mapobjects/teleporters.qh"
  44 #include "../common/mapobjects/target/spawnpoint.qh"
  45 #include <common/mapobjects/trigger/counter.qh>
  46 #include <common/mapobjects/trigger/swamp.qh>
  47
  48 #include "../common/vehicles/all.qh"
  49
  50 #include "weapons/hitplot.qh"
  51 #include "weapons/weaponsystem.qh"
  52
  53 #include "../common/net_notice.qh"
  54 #include "../common/net_linked.qh"
  55 #include "../common/physics/player.qh"
  56
  57 #include <common/vehicles/sv_vehicles.qh>
  58
  59 #include "../common/items/_mod.qh"
  60
  61 #include "../common/mutators/mutator/waypoints/all.qh"
  62 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  63 #include <common/gamemodes/_mod.qh>
  64
  65 #include "../common/mapobjects/subs.qh"
  66 #include "../common/mapobjects/triggers.qh"
  67 #include "../common/mapobjects/trigger/secret.qh"
  68
  69 #include "../common/minigames/sv_minigames.qh"
  70
  71 #include "../common/items/inventory.qh"
  72
  73 #include "../common/monsters/sv_monsters.qh"
  74
  75 #include "../lib/warpzone/server.qh"
  76
  77 #include <common/mutators/mutator/overkill/oknex.qh>
  78
  79 STATIC_METHOD(Client, Add, void(Client this, int _team))
  80 {
  81     ClientConnect(this);
  82     TRANSMUTE(Player, this);
  83     this.frame = 12; // 7
  84     this.team = _team;
  85     PutClientInServer(this);
  86 }
  87
  88 STATIC_METHOD(Client, Remove, void(Client this))
  89 {
  90     TRANSMUTE(Observer, this);
  91     PutClientInServer(this);
  92     ClientDisconnect(this);
  93 }
  94
  95 void send_CSQC_teamnagger() {
  96         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  97 }
  98
  99 int CountSpectators(entity player, entity to)
 100 {
 101         if(!player) { return 0; } // not sure how, but best to be safe
 102
 103         int spec_count = 0;
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 spec_count++;
 108         });
 109
 110         return spec_count;
 111 }
 112
 113 void WriteSpectators(entity player, entity to)
 114 {
 115         if(!player) { return; } // not sure how, but best to be safe
 116
 117         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 118         {
 119                 WriteByte(MSG_ENTITY, num_for_edict(it));
 120         });
 121 }
 122
 123 bool ClientData_Send(entity this, entity to, int sf)
 124 {
 125         assert(to == this.owner, return false);
 126
 127         entity e = to;
 128         if (IS_SPEC(e)) e = e.enemy;
 129
 130         sf = 0;
 131         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 132         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 133         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 134         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 135
 136         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 137         WriteByte(MSG_ENTITY, sf);
 138
 139         if (sf & BIT(1))
 140                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 141
 142         if(sf & BIT(4))
 143         {
 144                 float specs = CountSpectators(e, to);
 145                 WriteByte(MSG_ENTITY, specs);
 146                 WriteSpectators(e, to);
 147         }
 148
 149         return true;
 150 }
 151
 152 void ClientData_Attach(entity this)
 153 {
 154         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 155         CS(this).clientdata.drawonlytoclient = this;
 156         CS(this).clientdata.owner = this;
 157 }
 158
 159 void ClientData_Detach(entity this)
 160 {
 161         delete(CS(this).clientdata);
 162         CS(this).clientdata = NULL;
 163 }
 164
 165 void ClientData_Touch(entity e)
 166 {
 167         entity cd = CS(e).clientdata;
 168         if (cd) { cd.SendFlags = 1; }
 169
 170         // make it spectatable
 171         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 172         {
 173                 entity cd = CS(it).clientdata;
 174                 if (cd) { cd.SendFlags = 1; }
 175         });
 176 }
 177
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel;
 188 string CheckPlayerModel(string plyermodel) {
 189         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 190         {
 191                 // note: we cannot summon Don Strunzone here, some player may
 192                 // still have the model string set. In case anyone manages how
 193                 // to change a cvar default, we'll have a small leak here.
 194                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 195         }
 196         // only in right path
 197         if( substring(plyermodel,0,14) != "models/player/")
 198                 return FallbackPlayerModel;
 199         // only good file extensions
 200         if(substring(plyermodel,-4,4) != ".zym")
 201         if(substring(plyermodel,-4,4) != ".dpm")
 202         if(substring(plyermodel,-4,4) != ".iqm")
 203         if(substring(plyermodel,-4,4) != ".md3")
 204         if(substring(plyermodel,-4,4) != ".psk")
 205                 return FallbackPlayerModel;
 206         // forbid the LOD models
 207         if(substring(plyermodel, -9,5) == "_lod1")
 208                 return FallbackPlayerModel;
 209         if(substring(plyermodel, -9,5) == "_lod2")
 210                 return FallbackPlayerModel;
 211         if(plyermodel != strtolower(plyermodel))
 212                 return FallbackPlayerModel;
 213         // also, restrict to server models
 214         if(autocvar_sv_servermodelsonly)
 215         {
 216                 if(!fexists(plyermodel))
 217                         return FallbackPlayerModel;
 218         }
 219         return plyermodel;
 220 }
 221
 222 void setplayermodel(entity e, string modelname)
 223 {
 224         precache_model(modelname);
 225         _setmodel(e, modelname);
 226         player_setupanimsformodel(e);
 227         if(!autocvar_g_debug_globalsounds)
 228                 UpdatePlayerSounds(e);
 229 }
 230
 231 /** putting a client as observer in the server */
 232 void PutObserverInServer(entity this)
 233 {
 234     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 235         PlayerState_detach(this);
 236
 237         if (IS_PLAYER(this))
 238         {
 239                 if(GetResource(this, RES_HEALTH) >= 1)
 240                 {
 241                         // despawn effect
 242                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 243                 }
 244
 245                 // was a player, recount votes and ready status
 246                 if(IS_REAL_CLIENT(this))
 247                 {
 248                         if (vote_called) { VoteCount(false); }
 249                         ReadyCount();
 250                 }
 251     }
 252
 253     {
 254         entity spot = SelectSpawnPoint(this, true);
 255         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 256         this.angles = vec2(spot.angles);
 257         this.fixangle = true;
 258         // offset it so that the spectator spawns higher off the ground, looks better this way
 259         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 260         if (IS_REAL_CLIENT(this))
 261         {
 262             msg_entity = this;
 263             WriteByte(MSG_ONE, SVC_SETVIEW);
 264             WriteEntity(MSG_ONE, this);
 265         }
 266         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 267         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 268         if(!autocvar_g_debug_globalsounds)
 269         {
 270                 // needed for player sounds
 271                 this.model = "";
 272                 FixPlayermodel(this);
 273         }
 274         setmodel(this, MDL_Null);
 275         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 276         this.view_ofs = '0 0 0';
 277     }
 278
 279     RemoveGrapplingHooks(this);
 280         Portal_ClearAll(this);
 281         Unfreeze(this, false);
 282         SetSpectatee(this, NULL);
 283
 284         if (this.alivetime)
 285         {
 286                 if (!warmup_stage)
 287                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 288                 this.alivetime = 0;
 289         }
 290
 291         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 292
 293         WaypointSprite_PlayerDead(this);
 294
 295         if (CS(this).killcount != FRAGS_SPECTATOR)
 296         {
 297                 if(!game_stopped)
 298                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 299                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 300         }
 301
 302         accuracy_resend(this);
 303
 304         CS(this).spectatortime = time;
 305         if(this.bot_attack)
 306                 IL_REMOVE(g_bot_targets, this);
 307         this.bot_attack = false;
 308         if(this.monster_attack)
 309                 IL_REMOVE(g_monster_targets, this);
 310         this.monster_attack = false;
 311     STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.effects = 0;
 325         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         STAT(RESPAWN_TIME, this) = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         STAT(STRENGTH_FINISHED, this) = 0;
 340         STAT(INVINCIBLE_FINISHED, this) = 0;
 341         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 342         this.air_finished = 0;
 343         //this.dphitcontentsmask = 0;
 344         this.dphitcontentsmask = DPCONTENTS_SOLID;
 345         if (autocvar_g_playerclip_collisions)
 346                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         UNSET_DUCKED(this);
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355         this.draggable = drag_undraggable;
 356
 357         this.items = 0;
 358         STAT(WEAPONS, this) = '0 0 0';
 359         this.drawonlytoclient = this;
 360
 361         this.viewloc = NULL;
 362
 363         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 364
 365         this.weaponmodel = "";
 366         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 367         {
 368                 this.weaponentities[slot] = NULL;
 369         }
 370         this.exteriorweaponentity = NULL;
 371         CS(this).killcount = FRAGS_SPECTATOR;
 372         this.velocity = '0 0 0';
 373         this.avelocity = '0 0 0';
 374         this.punchangle = '0 0 0';
 375         this.punchvector = '0 0 0';
 376         this.oldvelocity = this.velocity;
 377         this.fire_endtime = -1;
 378         this.event_damage = func_null;
 379         this.event_heal = func_null;
 380
 381         for(int slot = 0; slot < MAX_AXH; ++slot)
 382         {
 383                 entity axh = this.(AuxiliaryXhair[slot]);
 384                 this.(AuxiliaryXhair[slot]) = NULL;
 385
 386                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 387                         delete(axh);
 388         }
 389
 390         if (mutator_returnvalue)
 391         {
 392                 // mutator prevents resetting teams+score
 393         }
 394         else
 395         {
 396                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 397                 this.frags = FRAGS_SPECTATOR;
 398         }
 399         if (CS(this).just_joined)
 400                 CS(this).just_joined = false;
 401 }
 402
 403 int player_getspecies(entity this)
 404 {
 405         get_model_parameters(this.model, this.skin);
 406         int s = get_model_parameters_species;
 407         get_model_parameters(string_null, 0);
 408         if (s < 0) return SPECIES_HUMAN;
 409         return s;
 410 }
 411
 412 .float model_randomizer;
 413 void FixPlayermodel(entity player)
 414 {
 415         string defaultmodel = "";
 416         int defaultskin = 0;
 417         if(autocvar_sv_defaultcharacter)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(defaultmodel == "")
 431                 {
 432                         defaultmodel = autocvar_sv_defaultplayermodel;
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434                 }
 435
 436                 int n = tokenize_console(defaultmodel);
 437                 if(n > 0)
 438                 {
 439                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 440                         // However, do NOT randomize if the player-selected model is in the list.
 441                         for (int i = 0; i < n; ++i)
 442                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 443                                         defaultmodel = argv(i);
 444                 }
 445
 446                 int i = strstrofs(defaultmodel, ":", 0);
 447                 if(i >= 0)
 448                 {
 449                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 450                         defaultmodel = substring(defaultmodel, 0, i);
 451                 }
 452         }
 453         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 454         {
 455                 if(teamplay)
 456                 {
 457                         switch(player.team)
 458                         {
 459                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 460                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 461                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 462                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 463                         }
 464                 }
 465
 466                 if(!defaultskin)
 467                         defaultskin = autocvar_sv_defaultplayerskin;
 468         }
 469
 470         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 471         defaultmodel = M_ARGV(0, string);
 472         defaultskin = M_ARGV(1, int);
 473
 474         bool chmdl = false;
 475         int oldskin;
 476         if(defaultmodel != "")
 477         {
 478                 if (defaultmodel != player.model)
 479                 {
 480                         vector m1 = player.mins;
 481                         vector m2 = player.maxs;
 482                         setplayermodel (player, defaultmodel);
 483                         setsize (player, m1, m2);
 484                         chmdl = true;
 485                 }
 486
 487                 oldskin = player.skin;
 488                 player.skin = defaultskin;
 489         } else {
 490                 if (player.playermodel != player.model || player.playermodel == "")
 491                 {
 492                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, player.playermodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 if(!autocvar_sv_defaultcharacterskin)
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = stof(player.playerskin);
 504                 }
 505                 else
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = defaultskin;
 509                 }
 510         }
 511
 512         if(chmdl || oldskin != player.skin) // model or skin has changed
 513         {
 514                 player.species = player_getspecies(player); // update species
 515                 if(!autocvar_g_debug_globalsounds)
 516                         UpdatePlayerSounds(player); // update skin sounds
 517         }
 518
 519         if(!teamplay)
 520                 if(strlen(autocvar_sv_defaultplayercolors))
 521                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 522                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 523 }
 524
 525 void PutPlayerInServer(entity this)
 526 {
 527         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 528
 529         PlayerState_attach(this);
 530         accuracy_resend(this);
 531
 532         if (this.team < 0)
 533                 TeamBalance_JoinBestTeam(this);
 534
 535         entity spot = SelectSpawnPoint(this, false);
 536         if (!spot) {
 537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 538                 return; // spawn failed
 539         }
 540
 541         TRANSMUTE(Player, this);
 542
 543         CS(this).wasplayer = true;
 544         this.iscreature = true;
 545         this.teleportable = TELEPORT_NORMAL;
 546         if(!this.damagedbycontents)
 547                 IL_PUSH(g_damagedbycontents, this);
 548         this.damagedbycontents = true;
 549         set_movetype(this, MOVETYPE_WALK);
 550         this.solid = SOLID_SLIDEBOX;
 551         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 552         if (autocvar_g_playerclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 554         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 556         this.frags = FRAGS_PLAYER;
 557         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 558         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 559         if (autocvar__notarget)
 560                 this.flags |= FL_NOTARGET;
 561         this.takedamage = DAMAGE_AIM;
 562         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 563
 564         if (warmup_stage) {
 565                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 566                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 567                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 568                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 569                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 570                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 571                 SetResource(this, RES_HEALTH, warmup_start_health);
 572                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 573                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 574         } else {
 575                 SetResource(this, RES_SHELLS, start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, start_health);
 582                 SetResource(this, RES_ARMOR, start_armorvalue);
 583                 STAT(WEAPONS, this) = start_weapons;
 584                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 585                 {
 586                         GiveRandomWeapons(this, random_start_weapons_count,
 587                                 autocvar_g_random_start_weapons, random_start_ammo);
 588                 }
 589         }
 590         SetSpectatee_status(this, 0);
 591
 592         PS(this).dual_weapons = '0 0 0';
 593
 594         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 595
 596         this.items = start_items;
 597
 598         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 599         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 600         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 601         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 602         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 603         if (!sv_ready_restart_after_countdown && time < game_starttime)
 604         {
 605                 float f = game_starttime - time;
 606                 this.spawnshieldtime += f;
 607                 this.pauserotarmor_finished += f;
 608                 this.pauserothealth_finished += f;
 609                 this.pauseregen_finished += f;
 610         }
 611
 612         this.damageforcescale = autocvar_g_player_damageforcescale;
 613         this.death_time = 0;
 614         this.respawn_flags = 0;
 615         this.respawn_time = 0;
 616         STAT(RESPAWN_TIME, this) = 0;
 617         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 618         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 619         this.fade_time = 0;
 620         this.pain_frame = 0;
 621         this.pain_finished = 0;
 622         this.pushltime = 0;
 623         setthink(this, func_null); // players have no think function
 624         this.nextthink = 0;
 625         this.dmg_team = 0;
 626         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 627
 628         this.deadflag = DEAD_NO;
 629
 630         this.angles = spot.angles;
 631         this.angles_z = 0; // never spawn tilted even if the spot says to
 632         if (IS_BOT_CLIENT(this))
 633         {
 634                 this.v_angle = this.angles;
 635                 bot_aim_reset(this);
 636         }
 637         this.fixangle = true; // turn this way immediately
 638         this.oldvelocity = this.velocity = '0 0 0';
 639         this.avelocity = '0 0 0';
 640         this.punchangle = '0 0 0';
 641         this.punchvector = '0 0 0';
 642
 643         STAT(STRENGTH_FINISHED, this) = 0;
 644         STAT(INVINCIBLE_FINISHED, this) = 0;
 645         this.fire_endtime = -1;
 646         STAT(REVIVE_PROGRESS, this) = 0;
 647         this.revival_time = 0;
 648
 649         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 650         STAT(BUFFS, this) = 0;
 651         STAT(BUFF_TIME, this) = 0;
 652
 653         this.air_finished = 0;
 654         this.waterlevel = WATERLEVEL_NONE;
 655         this.watertype = CONTENT_EMPTY;
 656
 657         entity spawnevent = new_pure(spawnevent);
 658         spawnevent.owner = this;
 659         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 660
 661         // Cut off any still running player sounds.
 662         stopsound(this, CH_PLAYER_SINGLE);
 663
 664         this.model = "";
 665         FixPlayermodel(this);
 666         this.drawonlytoclient = NULL;
 667
 668         this.viewloc = NULL;
 669
 670         for(int slot = 0; slot < MAX_AXH; ++slot)
 671         {
 672                 entity axh = this.(AuxiliaryXhair[slot]);
 673                 this.(AuxiliaryXhair[slot]) = NULL;
 674
 675                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 676                         delete(axh);
 677         }
 678
 679         this.spawnpoint_targ = NULL;
 680
 681         UNSET_DUCKED(this);
 682         this.view_ofs = STAT(PL_VIEW_OFS, this);
 683         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 684         this.spawnorigin = spot.origin;
 685         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 686         // don't reset back to last position, even if new position is stuck in solid
 687         this.oldorigin = this.origin;
 688         if(this.conveyor)
 689                 IL_REMOVE(g_conveyed, this);
 690         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 691         if(this.swampslug)
 692                 IL_REMOVE(g_swamped, this);
 693         this.swampslug = NULL;
 694         this.swamp_interval = 0;
 695         if(this.ladder_entity)
 696                 IL_REMOVE(g_ladderents, this);
 697         this.ladder_entity = NULL;
 698         IL_EACH(g_counters, it.realowner == this,
 699         {
 700                 delete(it);
 701         });
 702         STAT(HUD, this) = HUD_NORMAL;
 703
 704         this.event_damage = PlayerDamage;
 705         this.event_heal = PlayerHeal;
 706
 707         this.draggable = func_null;
 708
 709         if(!this.bot_attack)
 710                 IL_PUSH(g_bot_targets, this);
 711         this.bot_attack = true;
 712         if(!this.monster_attack)
 713                 IL_PUSH(g_monster_targets, this);
 714         this.monster_attack = true;
 715         navigation_dynamicgoal_init(this, false);
 716
 717         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 718
 719         // player was spectator
 720         if (CS(this).killcount == FRAGS_SPECTATOR) {
 721                 PlayerScore_Clear(this);
 722                 CS(this).killcount = 0;
 723                 CS(this).startplaytime = time;
 724         }
 725
 726         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 727         {
 728                 .entity weaponentity = weaponentities[slot];
 729                 CL_SpawnWeaponentity(this, weaponentity);
 730         }
 731         this.alpha = default_player_alpha;
 732         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 733         this.exteriorweaponentity.alpha = default_weapon_alpha;
 734
 735         this.speedrunning = false;
 736
 737         this.counter_cnt = 0;
 738         this.fragsfilter_cnt = 0;
 739
 740         target_voicescript_clear(this);
 741
 742         // reset fields the weapons may use
 743         FOREACH(Weapons, true, {
 744                 it.wr_resetplayer(it, this);
 745                         // reload all reloadable weapons
 746                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 747                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 748                         {
 749                                 .entity weaponentity = weaponentities[slot];
 750                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 751                         }
 752                 }
 753         });
 754
 755         {
 756                 string s = spot.target;
 757                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 758                         spot.target = string_null;
 759                 SUB_UseTargets(spot, this, NULL);
 760                 if(g_assault || g_race)
 761                         spot.target = s;
 762         }
 763
 764         Unfreeze(this, false);
 765
 766         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 767
 768         if (autocvar_spawn_debug)
 769         {
 770                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 771                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 772         }
 773
 774         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 775         {
 776                 .entity weaponentity = weaponentities[slot];
 777                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 778                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 779                 else
 780                         this.(weaponentity).m_switchweapon = WEP_Null;
 781                 this.(weaponentity).m_weapon = WEP_Null;
 782                 this.(weaponentity).weaponname = "";
 783                 this.(weaponentity).m_switchingweapon = WEP_Null;
 784                 this.(weaponentity).cnt = -1;
 785         }
 786
 787         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 788
 789         if (CS(this).impulse) ImpulseCommands(this);
 790
 791         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 792         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 793         {
 794                 .entity weaponentity = weaponentities[slot];
 795                 W_WeaponFrame(this, weaponentity);
 796         }
 797
 798         if (!warmup_stage && !this.alivetime)
 799                 this.alivetime = time;
 800
 801         antilag_clear(this, CS(this));
 802 }
 803
 804 /** Called when a client spawns in the server */
 805 void PutClientInServer(entity this)
 806 {
 807         if (IS_BOT_CLIENT(this)) {
 808                 TRANSMUTE(Player, this);
 809         } else if (IS_REAL_CLIENT(this)) {
 810                 msg_entity = this;
 811                 WriteByte(MSG_ONE, SVC_SETVIEW);
 812                 WriteEntity(MSG_ONE, this);
 813         }
 814         if (game_stopped)
 815                 TRANSMUTE(Observer, this);
 816
 817         SetSpectatee(this, NULL);
 818
 819         // reset player keys
 820         if(PS(this))
 821                 PS(this).itemkeys = 0;
 822
 823         MUTATOR_CALLHOOK(PutClientInServer, this);
 824
 825         if (IS_OBSERVER(this)) {
 826                 PutObserverInServer(this);
 827         } else if (IS_PLAYER(this)) {
 828                 PutPlayerInServer(this);
 829         }
 830 }
 831
 832 // TODO do we need all these fields, or should we stop autodetecting runtime
 833 // changes and just have a console command to update this?
 834 bool ClientInit_SendEntity(entity this, entity to, int sf)
 835 {
 836         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 837         return = true;
 838         msg_entity = to;
 839         // MSG_INIT replacement
 840         // TODO: make easier to use
 841         Registry_send_all();
 842         W_PROP_reload(MSG_ONE, to);
 843         ClientInit_misc(this);
 844         MUTATOR_CALLHOOK(Ent_Init);
 845 }
 846 void ClientInit_misc(entity this)
 847 {
 848         int channel = MSG_ONE;
 849         WriteHeader(channel, ENT_CLIENT_INIT);
 850         WriteByte(channel, g_nexball_meter_period * 32);
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 853         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 854         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 857         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 858         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 859
 860         if(sv_foginterval && world.fog != "")
 861                 WriteString(channel, world.fog);
 862         else
 863                 WriteString(channel, "");
 864         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 865         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 866         WriteByte(channel, serverflags);
 867         WriteCoord(channel, autocvar_g_trueaim_minrange);
 868 }
 869
 870 void ClientInit_CheckUpdate(entity this)
 871 {
 872         this.nextthink = time;
 873         if(this.count != autocvar_g_balance_armor_blockpercent)
 874         {
 875                 this.count = autocvar_g_balance_armor_blockpercent;
 876                 this.SendFlags |= 1;
 877         }
 878         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 879         {
 880                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 881                 this.SendFlags |= 1;
 882         }
 883 }
 884
 885 void ClientInit_Spawn()
 886 {
 887         entity e = new_pure(clientinit);
 888         setthink(e, ClientInit_CheckUpdate);
 889         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 890
 891         ClientInit_CheckUpdate(e);
 892 }
 893
 894 /*
 895 =============
 896 SetNewParms
 897 =============
 898 */
 899 void SetNewParms ()
 900 {
 901         // initialize parms for a new player
 902         parm1 = -(86400 * 366);
 903
 904         MUTATOR_CALLHOOK(SetNewParms);
 905 }
 906
 907 /*
 908 =============
 909 SetChangeParms
 910 =============
 911 */
 912 void SetChangeParms (entity this)
 913 {
 914         // save parms for level change
 915         parm1 = CS(this).parm_idlesince - time;
 916
 917         MUTATOR_CALLHOOK(SetChangeParms);
 918 }
 919
 920 /*
 921 =============
 922 DecodeLevelParms
 923 =============
 924 */
 925 void DecodeLevelParms(entity this)
 926 {
 927         // load parms
 928         CS(this).parm_idlesince = parm1;
 929         if (CS(this).parm_idlesince == -(86400 * 366))
 930                 CS(this).parm_idlesince = time;
 931
 932         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 933         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 934
 935         MUTATOR_CALLHOOK(DecodeLevelParms);
 936 }
 937
 938 void FixClientCvars(entity e)
 939 {
 940         // send prediction settings to the client
 941         stuffcmd(e, "\nin_bindmap 0 0\n");
 942         if(autocvar_g_antilag == 3) // client side hitscan
 943                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 944         if(autocvar_sv_gentle)
 945                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 946
 947         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 948         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 949
 950         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 951
 952         MUTATOR_CALLHOOK(FixClientCvars, e);
 953 }
 954
 955 bool findinlist_abbrev(string tofind, string list)
 956 {
 957         if(list == "" || tofind == "")
 958                 return false; // empty list or search, just return
 959
 960         // this function allows abbreviated strings!
 961         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 962         {
 963                 return true;
 964         });
 965
 966         return false;
 967 }
 968
 969 bool PlayerInIPList(entity p, string iplist)
 970 {
 971         // some safety checks (never allow local?)
 972         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 973                 return false;
 974
 975         return findinlist_abbrev(p.netaddress, iplist);
 976 }
 977
 978 bool PlayerInIDList(entity p, string idlist)
 979 {
 980         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 981         if(!p.crypto_idfp)
 982                 return false;
 983
 984         return findinlist_abbrev(p.crypto_idfp, idlist);
 985 }
 986
 987 bool PlayerInList(entity player, string list)
 988 {
 989         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 990 }
 991
 992 #ifdef DP_EXT_PRECONNECT
 993 /*
 994 =============
 995 ClientPreConnect
 996
 997 Called once (not at each match start) when a client begins a connection to the server
 998 =============
 999 */
1000 void ClientPreConnect(entity this)
1001 {
1002         if(autocvar_sv_eventlog)
1003         {
1004                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1005                         this.playerid,
1006                         etof(this),
1007                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1008                 ));
1009         }
1010 }
1011 #endif
1012
1013 string GetClientVersionMessage(entity this)
1014 {
1015         if (CS(this).version_mismatch) {
1016                 if(CS(this).version < autocvar_gameversion) {
1017                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1018                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1019                 } else {
1020                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1021                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1022                 }
1023         } else {
1024                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1025         }
1026 }
1027
1028 string getwelcomemessage(entity this)
1029 {
1030         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1031         string modifications = M_ARGV(0, string);
1032
1033         if(g_weaponarena)
1034         {
1035                 if(g_weaponarena_random)
1036                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1037                 else
1038                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1039         }
1040         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1041                 modifications = strcat(modifications, ", No start weapons");
1042         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1043                 modifications = strcat(modifications, ", Low gravity");
1044         if(g_weapon_stay && !g_cts)
1045                 modifications = strcat(modifications, ", Weapons stay");
1046         if(g_jetpack)
1047                 modifications = strcat(modifications, ", Jet pack");
1048         if(autocvar_g_powerups == 0)
1049                 modifications = strcat(modifications, ", No powerups");
1050         if(autocvar_g_powerups > 0)
1051                 modifications = strcat(modifications, ", Powerups");
1052         modifications = substring(modifications, 2, strlen(modifications) - 2);
1053
1054         string versionmessage = GetClientVersionMessage(this);
1055         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1056
1057         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1058
1059         if(modifications != "")
1060                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1061
1062         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1063         {
1064                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1065                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1066         }
1067
1068         if (cache_mutatormsg != "") {
1069                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1070         }
1071
1072         string mutator_msg = "";
1073         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1074         mutator_msg = M_ARGV(0, string);
1075
1076         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1077
1078         string motd = autocvar_sv_motd;
1079         if (motd != "") {
1080                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1081         }
1082         return s;
1083 }
1084
1085 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1086
1087 /**
1088 =============
1089 ClientConnect
1090
1091 Called when a client connects to the server
1092 =============
1093 */
1094 void ClientConnect(entity this)
1095 {
1096         if (Ban_MaybeEnforceBanOnce(this)) return;
1097         assert(!IS_CLIENT(this), return);
1098         this.flags |= FL_CLIENT;
1099         assert(player_count >= 0, player_count = 0);
1100
1101 #ifdef WATERMARK
1102         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1103 #endif
1104         TRANSMUTE(Client, this);
1105         CS(this).version_nagtime = time + 10 + random() * 10;
1106
1107         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1108
1109         bot_clientconnect(this);
1110
1111         Player_DetermineForcedTeam(this);
1112
1113         TRANSMUTE(Observer, this);
1114
1115         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1116
1117         // always track bots, don't ask for cl_allow_uidtracking
1118         if (IS_BOT_CLIENT(this))
1119                 PlayerStats_GameReport_AddPlayer(this);
1120         else
1121                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1122
1123         if (autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1125
1126         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1127
1128         stuffcmd(this, clientstuff, "\n");
1129         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1130
1131         FixClientCvars(this);
1132
1133         // get version info from player
1134         stuffcmd(this, "cmd clientversion $gameversion\n");
1135
1136         // notify about available teams
1137         if (teamplay)
1138         {
1139                 entity balance = TeamBalance_CheckAllowedTeams(this);
1140                 int t = TeamBalance_GetAllowedTeams(balance);
1141                 TeamBalance_Destroy(balance);
1142                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1143         }
1144         else
1145         {
1146                 stuffcmd(this, "set _teams_available 0\n");
1147         }
1148
1149         bot_relinkplayerlist();
1150
1151         CS(this).spectatortime = time;
1152         if (blockSpectators)
1153         {
1154                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1155         }
1156
1157         CS(this).jointime = time;
1158
1159         if (IS_REAL_CLIENT(this))
1160         {
1161                 if (g_weaponarena_weapons == WEPSET(TUBA))
1162                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1163         }
1164
1165         if (!sv_foginterval && world.fog != "")
1166                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1167
1168         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1169                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1170                         send_CSQC_teamnagger();
1171
1172         CSQCMODEL_AUTOINIT(this);
1173
1174         CS(this).model_randomizer = random();
1175
1176         if (IS_REAL_CLIENT(this))
1177                 sv_notice_join(this);
1178
1179         this.move_qcphysics = autocvar_sv_qcphysics;
1180
1181         // update physics stats (players can spawn before physics runs)
1182         Physics_UpdateStats(this);
1183
1184         IL_EACH(g_initforplayer, it.init_for_player, {
1185                 it.init_for_player(it, this);
1186         });
1187
1188         Handicap_Initialize(this);
1189
1190         MUTATOR_CALLHOOK(ClientConnect, this);
1191
1192         if (IS_REAL_CLIENT(this))
1193         {
1194                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1195                 {
1196                         CS(this).motd_actived_time = -1;
1197                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1198                 }
1199         }
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void ClientDisconnect(entity this)
1210 {
1211         assert(IS_CLIENT(this), return);
1212
1213         PlayerStats_GameReport_FinalizePlayer(this);
1214         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1215         if (CS(this).active_minigame) part_minigame(this);
1216         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1217
1218         if (autocvar_sv_eventlog)
1219                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1220
1221         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1222
1223         if(IS_SPEC(this))
1224                 SetSpectatee(this, NULL);
1225
1226     MUTATOR_CALLHOOK(ClientDisconnect, this);
1227
1228         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1229         strfree(CS(this).weaponorder_byimpulse);
1230         ClientState_detach(this);
1231
1232         Portal_ClearAll(this);
1233
1234         Unfreeze(this, false);
1235
1236         RemoveGrapplingHooks(this);
1237
1238         // Here, everything has been done that requires this player to be a client.
1239
1240         this.flags &= ~FL_CLIENT;
1241
1242         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1243         if (this.killindicator) delete(this.killindicator);
1244
1245         IL_EACH(g_counters, it.realowner == this,
1246         {
1247                 delete(it);
1248         });
1249
1250         WaypointSprite_PlayerGone(this);
1251
1252         bot_relinkplayerlist();
1253
1254         strfree(this.clientstatus);
1255         if (this.personal) delete(this.personal);
1256
1257         this.playerid = 0;
1258         ReadyCount();
1259         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1260
1261         ONREMOVE(this);
1262 }
1263
1264 void ChatBubbleThink(entity this)
1265 {
1266         this.nextthink = time;
1267         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1268         {
1269                 if(this.owner) // but why can that ever be NULL?
1270                         this.owner.chatbubbleentity = NULL;
1271                 delete(this);
1272                 return;
1273         }
1274
1275         this.mdl = "";
1276
1277         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1278         {
1279                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1280                         this.mdl = "models/sprites/minigame_busy.iqm";
1281                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1282                         this.mdl = "models/misc/chatbubble.spr";
1283         }
1284
1285         if ( this.model != this.mdl )
1286                 _setmodel(this, this.mdl);
1287
1288 }
1289
1290 void UpdateChatBubble(entity this)
1291 {
1292         if (this.alpha < 0)
1293                 return;
1294         // spawn a chatbubble entity if needed
1295         if (!this.chatbubbleentity)
1296         {
1297                 this.chatbubbleentity = new(chatbubbleentity);
1298                 this.chatbubbleentity.owner = this;
1299                 this.chatbubbleentity.exteriormodeltoclient = this;
1300                 setthink(this.chatbubbleentity, ChatBubbleThink);
1301                 this.chatbubbleentity.nextthink = time;
1302                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1303                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1304                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1305                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1306                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1307                 //this.chatbubbleentity.model = "";
1308                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1309         }
1310 }
1311
1312 void calculate_player_respawn_time(entity this)
1313 {
1314         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1315                 return;
1316
1317         float gametype_setting_tmp;
1318         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1319         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1320         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1321         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1322         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1323         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1324
1325         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1326         if (teamplay)
1327         {
1328                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1329                         if(it.team == this.team)
1330                                 ++pcount;
1331                 });
1332                 if (sdelay_small_count == 0)
1333                         sdelay_small_count = 1;
1334                 if (sdelay_large_count == 0)
1335                         sdelay_large_count = 1;
1336         }
1337         else
1338         {
1339                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1340                         ++pcount;
1341                 });
1342                 if (sdelay_small_count == 0)
1343                 {
1344                         if (IS_INDEPENDENT_PLAYER(this))
1345                         {
1346                                 // Players play independently. No point in requiring enemies.
1347                                 sdelay_small_count = 1;
1348                         }
1349                         else
1350                         {
1351                                 // Players play AGAINST each other. Enemies required.
1352                                 sdelay_small_count = 2;
1353                         }
1354                 }
1355                 if (sdelay_large_count == 0)
1356                 {
1357                         if (IS_INDEPENDENT_PLAYER(this))
1358                         {
1359                                 // Players play independently. No point in requiring enemies.
1360                                 sdelay_large_count = 1;
1361                         }
1362                         else
1363                         {
1364                                 // Players play AGAINST each other. Enemies required.
1365                                 sdelay_large_count = 2;
1366                         }
1367                 }
1368         }
1369
1370         float sdelay;
1371
1372         if (pcount <= sdelay_small_count)
1373                 sdelay = sdelay_small;
1374         else if (pcount >= sdelay_large_count)
1375                 sdelay = sdelay_large;
1376         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1377                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1378
1379         if(waves)
1380                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1381         else
1382                 this.respawn_time = time + sdelay;
1383
1384         if(sdelay < sdelay_max)
1385                 this.respawn_time_max = time + sdelay_max;
1386         else
1387                 this.respawn_time_max = this.respawn_time;
1388
1389         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1390                 this.respawn_countdown = 10; // first number to count down from is 10
1391         else
1392                 this.respawn_countdown = -1; // do not count down
1393
1394         if(autocvar_g_forced_respawn)
1395                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1396 }
1397
1398 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1399 // added to the model skins
1400 /*void UpdateColorModHack()
1401 {
1402         float c;
1403         c = this.clientcolors & 15;
1404         // LordHavoc: only bothering to support white, green, red, yellow, blue
1405              if (!teamplay) this.colormod = '0 0 0';
1406         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1407         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1408         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1409         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1410         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1411         else this.colormod = '1 1 1';
1412 }*/
1413
1414 void respawn(entity this)
1415 {
1416         bool damagedbycontents_prev = this.damagedbycontents;
1417         if(this.alpha >= 0)
1418         {
1419                 if(autocvar_g_respawn_ghosts)
1420                 {
1421                         this.solid = SOLID_NOT;
1422                         this.takedamage = DAMAGE_NO;
1423                         this.damagedbycontents = false;
1424                         set_movetype(this, MOVETYPE_FLY);
1425                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1426                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1427                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1428                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1429                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1430                         if(autocvar_g_respawn_ghosts_time > 0)
1431                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1432                 }
1433                 else
1434                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1435         }
1436
1437         CopyBody(this, 1);
1438         this.damagedbycontents = damagedbycontents_prev;
1439
1440         this.effects |= EF_NODRAW; // prevent another CopyBody
1441         PutClientInServer(this);
1442 }
1443
1444 ERASEABLE
1445 void PrintToChat(entity client, string text)
1446 {
1447         text = strcat("\{1}^7", text, "\n");
1448         sprint(client, text);
1449 }
1450
1451 ERASEABLE
1452 void DebugPrintToChat(entity client, string text)
1453 {
1454         if (autocvar_developer > 0)
1455         {
1456                 PrintToChat(client, text);
1457         }
1458 }
1459
1460 ERASEABLE
1461 void PrintToChatAll(string text)
1462 {
1463         text = strcat("\{1}^7", text, "\n");
1464         bprint(text);
1465 }
1466
1467 ERASEABLE
1468 void DebugPrintToChatAll(string text)
1469 {
1470         if (autocvar_developer > 0)
1471         {
1472                 PrintToChatAll(text);
1473         }
1474 }
1475
1476 ERASEABLE
1477 void PrintToChatTeam(int team_num, string text)
1478 {
1479         text = strcat("\{1}^7", text, "\n");
1480         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1481         {
1482                 if (it.team == team_num)
1483                 {
1484                         sprint(it, text);
1485                 }
1486         });
1487 }
1488
1489 ERASEABLE
1490 void DebugPrintToChatTeam(int team_num, string text)
1491 {
1492         if (autocvar_developer > 0)
1493         {
1494                 PrintToChatTeam(team_num, text);
1495         }
1496 }
1497
1498 void play_countdown(entity this, float finished, Sound samp)
1499 {
1500         TC(Sound, samp);
1501         if(IS_REAL_CLIENT(this))
1502                 if(floor(finished - time - frametime) != floor(finished - time))
1503                         if(finished - time < 6)
1504                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1505 }
1506
1507 void player_powerups(entity this)
1508 {
1509         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1510                 this.modelflags |= MF_ROCKET;
1511         else
1512                 this.modelflags &= ~MF_ROCKET;
1513
1514         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1515
1516         if (IS_DEAD(this))
1517         {
1518                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1519                 {
1520                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1521                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1522                         this.items &= ~ITEM_Strength.m_itemid;
1523                         this.items &= ~ITEM_Shield.m_itemid;
1524                         this.items -= (this.items & IT_SUPERWEAPON);
1525                 }
1526         }
1527
1528         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1529                 return;
1530
1531         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1532         int items_prev = this.items;
1533
1534         Fire_ApplyDamage(this);
1535         Fire_ApplyEffect(this);
1536
1537         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1538         {
1539                 if (this.items & ITEM_Strength.m_itemid)
1540                 {
1541                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1542                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1543                         if (time > STAT(STRENGTH_FINISHED, this))
1544                         {
1545                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1546                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1548                         }
1549                 }
1550                 else
1551                 {
1552                         if (time < STAT(STRENGTH_FINISHED, this))
1553                         {
1554                                 this.items = this.items | ITEM_Strength.m_itemid;
1555                                 if(!g_cts)
1556                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1557                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1558                         }
1559                 }
1560                 if (this.items & ITEM_Shield.m_itemid)
1561                 {
1562                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1563                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1564                         if (time > STAT(INVINCIBLE_FINISHED, this))
1565                         {
1566                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1567                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1568                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1569                         }
1570                 }
1571                 else
1572                 {
1573                         if (time < STAT(INVINCIBLE_FINISHED, this))
1574                         {
1575                                 this.items = this.items | ITEM_Shield.m_itemid;
1576                                 if(!g_cts)
1577                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1578                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1579                         }
1580                 }
1581                 if (this.items & IT_SUPERWEAPON)
1582                 {
1583                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1584                         {
1585                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1586                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1587                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1588                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1589                         }
1590                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1591                         {
1592                                 // don't let them run out
1593                         }
1594                         else
1595                         {
1596                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1597                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1598                                 {
1599                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1600                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1601                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1602                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1603                                 }
1604                         }
1605                 }
1606                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1607                 {
1608                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1609                         {
1610                                 this.items = this.items | IT_SUPERWEAPON;
1611                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1612                                 {
1613                                         if(!g_cts)
1614                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1615                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1616                                 }
1617                         }
1618                         else
1619                         {
1620                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1621                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1622                         }
1623                 }
1624                 else
1625                 {
1626                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1627                 }
1628         }
1629
1630         if(autocvar_g_nodepthtestplayers)
1631                 this.effects = this.effects | EF_NODEPTHTEST;
1632
1633         if(autocvar_g_fullbrightplayers)
1634                 this.effects = this.effects | EF_FULLBRIGHT;
1635
1636         if (time >= game_starttime)
1637         if (time < this.spawnshieldtime)
1638                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1639
1640         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1641 }
1642
1643 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1644 {
1645         if(current > stable)
1646                 return current;
1647         else if(current > stable - 0.25) // when close enough, "snap"
1648                 return stable;
1649         else
1650                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1651 }
1652
1653 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1654 {
1655         if(current < stable)
1656                 return current;
1657         else if(current < stable + 0.25) // when close enough, "snap"
1658                 return stable;
1659         else
1660                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1661 }
1662
1663 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1664 {
1665         float old = GetResource(this, res);
1666         float current = old;
1667         if(current > rotstable)
1668         {
1669                 if(rotframetime > 0)
1670                 {
1671                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1672                         current = max(rotstable, current - rotlinear * rotframetime);
1673                 }
1674         }
1675         else if(current < regenstable)
1676         {
1677                 if(regenframetime > 0)
1678                 {
1679                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1680                         current = min(regenstable, current + regenlinear * regenframetime);
1681                 }
1682         }
1683
1684         float limit = GetResourceLimit(this, res) * limit_mod;
1685         if(current > limit)
1686                 current = limit;
1687
1688         if (current != old)
1689                 SetResource(this, res, current);
1690 }
1691
1692 void player_regen(entity this)
1693 {
1694         float max_mod, regen_mod, rot_mod, limit_mod;
1695         max_mod = regen_mod = rot_mod = limit_mod = 1;
1696
1697         float regen_health = autocvar_g_balance_health_regen;
1698         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1699         float regen_health_rot = autocvar_g_balance_health_rot;
1700         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1701         float regen_health_stable = autocvar_g_balance_health_regenstable;
1702         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1703         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1704                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1705         max_mod = M_ARGV(1, float);
1706         regen_mod = M_ARGV(2, float);
1707         rot_mod = M_ARGV(3, float);
1708         limit_mod = M_ARGV(4, float);
1709         regen_health = M_ARGV(5, float);
1710         regen_health_linear = M_ARGV(6, float);
1711         regen_health_rot = M_ARGV(7, float);
1712         regen_health_rotlinear = M_ARGV(8, float);
1713         regen_health_stable = M_ARGV(9, float);
1714         regen_health_rotstable = M_ARGV(10, float);
1715
1716         if(!mutator_returnvalue)
1717         if(!STAT(FROZEN, this))
1718         {
1719                 float maxa = autocvar_g_balance_armor_rotstable;
1720                 float mina = autocvar_g_balance_armor_regenstable;
1721
1722                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1723                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1724                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1725
1726                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1727                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1728                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1729         }
1730
1731         // if player rotted to death...  die!
1732         // check this outside above checks, as player may still be able to rot to death
1733         if(GetResource(this, RES_HEALTH) < 1)
1734         {
1735                 if(this.vehicle)
1736                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1737                 if(this.event_damage)
1738                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1739         }
1740
1741         if (!(this.items & IT_UNLIMITED_AMMO))
1742         {
1743                 float maxf = autocvar_g_balance_fuel_rotstable;
1744                 float minf = autocvar_g_balance_fuel_regenstable;
1745
1746                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1747                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1748                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1749         }
1750 }
1751
1752 bool zoomstate_set;
1753 void SetZoomState(entity this, float newzoom)
1754 {
1755         if(newzoom != CS(this).zoomstate)
1756         {
1757                 CS(this).zoomstate = newzoom;
1758                 ClientData_Touch(this);
1759         }
1760         zoomstate_set = true;
1761 }
1762
1763 void GetPressedKeys(entity this)
1764 {
1765         MUTATOR_CALLHOOK(GetPressedKeys, this);
1766         int keys = STAT(PRESSED_KEYS, this);
1767         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1768         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1769         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1770         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1771
1772         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1773         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1774         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1775         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1776         CS(this).pressedkeys = keys; // store for other users
1777
1778         STAT(PRESSED_KEYS, this) = keys;
1779 }
1780
1781 /*
1782 ======================
1783 spectate mode routines
1784 ======================
1785 */
1786
1787 void SpectateCopy(entity this, entity spectatee)
1788 {
1789         TC(Client, this); TC(Client, spectatee);
1790
1791         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1792         PS(this) = PS(spectatee);
1793         this.armortype = spectatee.armortype;
1794         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1795         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1796         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1797         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1798         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1799         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1800         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1801         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1802         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1803         CS(this).impulse = 0;
1804         this.disableclientprediction = 1; // no need to run prediction on a spectator
1805         this.items = spectatee.items;
1806         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1807         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1808         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1809         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1810         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1811         this.air_finished = spectatee.air_finished;
1812         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1813         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1814         this.punchangle = spectatee.punchangle;
1815         this.view_ofs = spectatee.view_ofs;
1816         this.velocity = spectatee.velocity;
1817         this.dmg_take = spectatee.dmg_take;
1818         this.dmg_save = spectatee.dmg_save;
1819         this.dmg_inflictor = spectatee.dmg_inflictor;
1820         this.v_angle = spectatee.v_angle;
1821         this.angles = spectatee.v_angle;
1822         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1823         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1824         this.viewloc = spectatee.viewloc;
1825         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1826                 this.fixangle = true;
1827         setorigin(this, spectatee.origin);
1828         setsize(this, spectatee.mins, spectatee.maxs);
1829         SetZoomState(this, CS(spectatee).zoomstate);
1830
1831     anticheat_spectatecopy(this, spectatee);
1832         STAT(HUD, this) = STAT(HUD, spectatee);
1833         if(spectatee.vehicle)
1834     {
1835         this.angles = spectatee.v_angle;
1836
1837         //this.fixangle = false;
1838         //this.velocity = spectatee.vehicle.velocity;
1839         this.vehicle_health = spectatee.vehicle_health;
1840         this.vehicle_shield = spectatee.vehicle_shield;
1841         this.vehicle_energy = spectatee.vehicle_energy;
1842         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1843         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1844         this.vehicle_reload1 = spectatee.vehicle_reload1;
1845         this.vehicle_reload2 = spectatee.vehicle_reload2;
1846
1847         //msg_entity = this;
1848
1849        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1850             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1851            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1852            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1853
1854         //WriteByte (MSG_ONE, SVC_SETVIEW);
1855         //    WriteEntity(MSG_ONE, this);
1856         //makevectors(spectatee.v_angle);
1857         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1858     }
1859 }
1860
1861 bool SpectateUpdate(entity this)
1862 {
1863         if(!this.enemy)
1864                 return false;
1865
1866         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1867         {
1868                 SetSpectatee(this, NULL);
1869                 return false;
1870         }
1871
1872         SpectateCopy(this, this.enemy);
1873
1874         return true;
1875 }
1876
1877 bool SpectateSet(entity this)
1878 {
1879         if(!IS_PLAYER(this.enemy))
1880                 return false;
1881
1882         ClientData_Touch(this.enemy);
1883
1884         msg_entity = this;
1885         WriteByte(MSG_ONE, SVC_SETVIEW);
1886         WriteEntity(MSG_ONE, this.enemy);
1887         set_movetype(this, MOVETYPE_NONE);
1888         accuracy_resend(this);
1889
1890         if(!SpectateUpdate(this))
1891                 PutObserverInServer(this);
1892
1893         return true;
1894 }
1895
1896 void SetSpectatee_status(entity this, int spectatee_num)
1897 {
1898         int oldspectatee_status = CS(this).spectatee_status;
1899         CS(this).spectatee_status = spectatee_num;
1900
1901         if (CS(this).spectatee_status != oldspectatee_status)
1902         {
1903                 if (STAT(PRESSED_KEYS, this))
1904                 {
1905                         CS(this).pressedkeys = 0;
1906                         STAT(PRESSED_KEYS, this) = 0;
1907                 }
1908                 ClientData_Touch(this);
1909                 if (g_race || g_cts) race_InitSpectator();
1910         }
1911 }
1912
1913 void SetSpectatee(entity this, entity spectatee)
1914 {
1915         if(IS_BOT_CLIENT(this))
1916                 return; // bots abuse .enemy, this code is useless to them
1917
1918         entity old_spectatee = this.enemy;
1919
1920         this.enemy = spectatee;
1921
1922         // WEAPONTODO
1923         // these are required to fix the spectator bug with arc
1924         if(old_spectatee)
1925         {
1926                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1927                 {
1928                         .entity weaponentity = weaponentities[slot];
1929                         if(old_spectatee.(weaponentity).arc_beam)
1930                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1931                 }
1932         }
1933         if(this.enemy)
1934         {
1935                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1936                 {
1937                         .entity weaponentity = weaponentities[slot];
1938                         if(this.enemy.(weaponentity).arc_beam)
1939                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1940                 }
1941         }
1942
1943         if (this.enemy)
1944                 SetSpectatee_status(this, etof(this.enemy));
1945
1946         // needed to update spectator list
1947         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1948 }
1949
1950 bool Spectate(entity this, entity pl)
1951 {
1952         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1953                 return false;
1954         pl = M_ARGV(1, entity);
1955
1956         SetSpectatee(this, pl);
1957         return SpectateSet(this);
1958 }
1959
1960 bool SpectateNext(entity this)
1961 {
1962         entity ent = find(this.enemy, classname, STR_PLAYER);
1963
1964         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1965                 ent = M_ARGV(1, entity);
1966         else if (!ent)
1967                 ent = find(ent, classname, STR_PLAYER);
1968
1969         if(ent) { SetSpectatee(this, ent); }
1970
1971         return SpectateSet(this);
1972 }
1973
1974 bool SpectatePrev(entity this)
1975 {
1976         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1977         entity ent = findchain(classname, STR_PLAYER);
1978         if (!ent) // no player
1979                 return false;
1980
1981         entity first = ent;
1982         // skip players until current spectated player
1983         if(this.enemy)
1984         while(ent && ent != this.enemy)
1985                 ent = ent.chain;
1986
1987         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1988         {
1989                 case MUT_SPECPREV_FOUND:
1990                     ent = M_ARGV(1, entity);
1991                     break;
1992                 case MUT_SPECPREV_RETURN:
1993                     return true;
1994                 case MUT_SPECPREV_CONTINUE:
1995                 default:
1996                 {
1997                         if(ent.chain)
1998                                 ent = ent.chain;
1999                         else
2000                                 ent = first;
2001                         break;
2002                 }
2003         }
2004
2005         SetSpectatee(this, ent);
2006         return SpectateSet(this);
2007 }
2008
2009 /*
2010 =============
2011 ShowRespawnCountdown()
2012
2013 Update a respawn countdown display.
2014 =============
2015 */
2016 void ShowRespawnCountdown(entity this)
2017 {
2018         float number;
2019         if(!IS_DEAD(this)) // just respawned?
2020                 return;
2021         else
2022         {
2023                 number = ceil(this.respawn_time - time);
2024                 if(number <= 0)
2025                         return;
2026                 if(number <= this.respawn_countdown)
2027                 {
2028                         this.respawn_countdown = number - 1;
2029                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2030                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2031                 }
2032         }
2033 }
2034
2035 .bool team_selected;
2036 bool ShowTeamSelection(entity this)
2037 {
2038         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2039                 return false;
2040         stuffcmd(this, "menu_showteamselect\n");
2041         return true;
2042 }
2043 void Join(entity this)
2044 {
2045         TRANSMUTE(Player, this);
2046
2047         if(!this.team_selected)
2048         if(autocvar_g_campaign || autocvar_g_balance_teams)
2049                 TeamBalance_JoinBestTeam(this);
2050
2051         if(autocvar_g_campaign)
2052                 campaign_bots_may_start = true;
2053
2054         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2055
2056         PutClientInServer(this);
2057
2058         if(IS_PLAYER(this))
2059         if(teamplay && this.team != -1)
2060         {
2061         }
2062         else
2063                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2064         this.team_selected = false;
2065 }
2066
2067 int GetPlayerLimit()
2068 {
2069         if(g_duel)
2070                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2071         int player_limit = autocvar_g_maxplayers;
2072         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2073         player_limit = M_ARGV(0, int);
2074         return player_limit;
2075 }
2076
2077 /**
2078  * Determines whether the player is allowed to join. This depends on cvar
2079  * g_maxplayers, if it isn't used this function always return true, otherwise
2080  * it checks whether the number of currently playing players exceeds g_maxplayers.
2081  * @return int number of free slots for players, 0 if none
2082  */
2083 int nJoinAllowed(entity this, entity ignore)
2084 {
2085         if(!ignore)
2086         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2087         // so report 0 free slots if restricted
2088         {
2089                 if(autocvar_g_forced_team_otherwise == "spectate")
2090                         return 0;
2091                 if(autocvar_g_forced_team_otherwise == "spectator")
2092                         return 0;
2093         }
2094
2095         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2096                 return 0; // forced spectators can never join
2097
2098         // TODO simplify this
2099         int totalClients = 0;
2100         int currentlyPlaying = 0;
2101         FOREACH_CLIENT(true, {
2102                 if(it != ignore)
2103                         ++totalClients;
2104                 if(IS_REAL_CLIENT(it))
2105                 if(IS_PLAYER(it) || it.caplayer)
2106                         ++currentlyPlaying;
2107         });
2108
2109         int player_limit = GetPlayerLimit();
2110
2111         int free_slots = 0;
2112         if (!player_limit)
2113                 free_slots = maxclients - totalClients;
2114         else if(player_limit > 0 && currentlyPlaying < player_limit)
2115                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2116
2117         static float msg_time = 0;
2118         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2119         {
2120                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2121                 msg_time = time + 0.5;
2122         }
2123
2124         return free_slots;
2125 }
2126
2127 /**
2128  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2129  * g_maxplayers_spectator_blocktime seconds
2130  */
2131 void checkSpectatorBlock(entity this)
2132 {
2133         if(IS_SPEC(this) || IS_OBSERVER(this))
2134         if(!this.caplayer)
2135         if(IS_REAL_CLIENT(this))
2136         {
2137                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2138                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2139                         dropclient(this);
2140                 }
2141         }
2142 }
2143
2144 void PrintWelcomeMessage(entity this)
2145 {
2146         if(CS(this).motd_actived_time == 0)
2147         {
2148                 if (autocvar_g_campaign) {
2149                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2150                                 CS(this).motd_actived_time = time;
2151                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2152                         }
2153                 } else {
2154                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2155                                 CS(this).motd_actived_time = time;
2156                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2157                         }
2158                 }
2159         }
2160         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2161         {
2162                 if (autocvar_g_campaign) {
2163                         if (PHYS_INPUT_BUTTON_INFO(this))
2164                                 CS(this).motd_actived_time = time;
2165                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2166                                 CS(this).motd_actived_time = 0;
2167                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2168                         }
2169                 } else {
2170                         if (PHYS_INPUT_BUTTON_INFO(this))
2171                                 CS(this).motd_actived_time = time;
2172                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2173                                 CS(this).motd_actived_time = 0;
2174                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2175                         }
2176                 }
2177         }
2178         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2179         {
2180                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2181                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2182                 else if (CS(this).motd_actived_time == -2)
2183                 {
2184                         // instantly hide MOTD
2185                         CS(this).motd_actived_time = 0;
2186                         if (autocvar_g_campaign)
2187                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2188                         else
2189                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2190                 }
2191                 else if (IS_PLAYER(this) || IS_SPEC(this))
2192                 {
2193                         // FIXME occasionally for some reason MOTD never goes away
2194                         // delay MOTD removal a little bit in the hope it fixes this bug
2195                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2196                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2197                         else //if (CS(this).motd_actived_time < -2)
2198                                 CS(this).motd_actived_time++;
2199                 }
2200         }
2201 }
2202
2203 bool joinAllowed(entity this)
2204 {
2205         if (CS(this).version_mismatch) return false;
2206         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2207         if (!nJoinAllowed(this, this)) return false;
2208         if (teamplay && lockteams) return false;
2209         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2210         if (ShowTeamSelection(this)) return false;
2211         return true;
2212 }
2213
2214 .string shootfromfixedorigin;
2215 .bool dualwielding_prev;
2216 bool PlayerThink(entity this)
2217 {
2218         if (game_stopped || intermission_running) {
2219                 this.modelflags &= ~MF_ROCKET;
2220                 if(intermission_running)
2221                         IntermissionThink(this);
2222                 return false;
2223         }
2224
2225         if (timeout_status == TIMEOUT_ACTIVE) {
2226         // don't allow the player to turn around while game is paused
2227                 // FIXME turn this into CSQC stuff
2228                 this.v_angle = this.lastV_angle;
2229                 this.angles = this.lastV_angle;
2230                 this.fixangle = true;
2231         }
2232
2233         if (frametime) player_powerups(this);
2234
2235         if (IS_DEAD(this)) {
2236                 if (this.personal && g_race_qualifying) {
2237                         if (time > this.respawn_time) {
2238                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2239                                 respawn(this);
2240                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2241                         }
2242                 } else {
2243                         if (frametime) player_anim(this);
2244
2245                         if (this.respawn_flags & RESPAWN_DENY)
2246                         {
2247                                 STAT(RESPAWN_TIME, this) = 0;
2248                                 return false;
2249                         }
2250
2251                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2252
2253                         switch(this.deadflag)
2254                         {
2255                                 case DEAD_DYING:
2256                                 {
2257                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2258                                                 this.deadflag = DEAD_RESPAWNING;
2259                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2260                                                 this.deadflag = DEAD_DEAD;
2261                                         break;
2262                                 }
2263                                 case DEAD_DEAD:
2264                                 {
2265                                         if (button_pressed)
2266                                                 this.deadflag = DEAD_RESPAWNABLE;
2267                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2268                                                 this.deadflag = DEAD_RESPAWNING;
2269                                         break;
2270                                 }
2271                                 case DEAD_RESPAWNABLE:
2272                                 {
2273                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2274                                                 this.deadflag = DEAD_RESPAWNING;
2275                                         break;
2276                                 }
2277                                 case DEAD_RESPAWNING:
2278                                 {
2279                                         if (time > this.respawn_time)
2280                                         {
2281                                                 this.respawn_time = time + 1; // only retry once a second
2282                                                 this.respawn_time_max = this.respawn_time;
2283                                                 respawn(this);
2284                                         }
2285                                         break;
2286                                 }
2287                         }
2288
2289                         ShowRespawnCountdown(this);
2290
2291                         if (this.respawn_flags & RESPAWN_SILENT)
2292                                 STAT(RESPAWN_TIME, this) = 0;
2293                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2294                         {
2295                                 if (time < this.respawn_time)
2296                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2297                                 else if (this.deadflag != DEAD_RESPAWNING)
2298                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2299                         }
2300                         else
2301                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2302                 }
2303
2304                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2305                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2306                         STAT(RESPAWN_TIME, this) *= -1;
2307
2308                 return false;
2309         }
2310
2311         FixPlayermodel(this);
2312
2313         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2314                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2315                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2316         }
2317
2318         // reset gun alignment when dual wielding status changes
2319         // to ensure guns are always aligned right and left
2320         bool dualwielding = W_DualWielding(this);
2321         if(this.dualwielding_prev != dualwielding)
2322         {
2323                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2324                 this.dualwielding_prev = dualwielding;
2325         }
2326
2327         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2328         //if(frametime)
2329         {
2330                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2331                 {
2332                         .entity weaponentity = weaponentities[slot];
2333                         if(WEP_CVAR(vortex, charge_always))
2334                                 W_Vortex_Charge(this, weaponentity, frametime);
2335                         W_WeaponFrame(this, weaponentity);
2336                 }
2337         }
2338
2339         if (frametime)
2340         {
2341                 // WEAPONTODO: Add a weapon request for this
2342                 // rot vortex charge to the charge limit
2343                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2344                 {
2345                         .entity weaponentity = weaponentities[slot];
2346                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2347                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2348                 }
2349
2350                 player_regen(this);
2351                 player_anim(this);
2352                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2353         }
2354
2355         monsters_setstatus(this);
2356
2357         return true;
2358 }
2359
2360 .bool would_spectate;
2361 void ObserverOrSpectatorThink(entity this)
2362 {
2363         bool is_spec = IS_SPEC(this);
2364         if ( CS(this).impulse )
2365         {
2366                 int r = MinigameImpulse(this, CS(this).impulse);
2367                 if (!is_spec || r)
2368                         CS(this).impulse = 0;
2369
2370                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2371                 {
2372                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2373                         CS(this).impulse = 0;
2374                         return;
2375                 }
2376         }
2377
2378         if (this.flags & FL_JUMPRELEASED) {
2379                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2380                         this.flags &= ~FL_JUMPRELEASED;
2381                         this.flags |= FL_SPAWNING;
2382                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2383                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2384                         this.flags &= ~FL_JUMPRELEASED;
2385                         if(SpectateNext(this)) {
2386                                 TRANSMUTE(Spectator, this);
2387                         } else if (is_spec) {
2388                                 TRANSMUTE(Observer, this);
2389                                 PutClientInServer(this);
2390                         }
2391                         if (is_spec)
2392                                 CS(this).impulse = 0;
2393                 } else if (is_spec) {
2394                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2395                                 this.flags &= ~FL_JUMPRELEASED;
2396                                 if(SpectatePrev(this)) {
2397                                         TRANSMUTE(Spectator, this);
2398                                 } else {
2399                                         TRANSMUTE(Observer, this);
2400                                         PutClientInServer(this);
2401                                 }
2402                                 CS(this).impulse = 0;
2403                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2404                                 this.would_spectate = false;
2405                                 this.flags &= ~FL_JUMPRELEASED;
2406                                 TRANSMUTE(Observer, this);
2407                                 PutClientInServer(this);
2408                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2409                                 PutObserverInServer(this);
2410                                 this.would_spectate = true;
2411                         }
2412                 }
2413                 else {
2414                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2415                         set_movetype(this, preferred_movetype);
2416                 }
2417         } else {
2418                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2419                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2420                         this.flags |= FL_JUMPRELEASED;
2421                         if(this.flags & FL_SPAWNING)
2422                         {
2423                                 this.flags &= ~FL_SPAWNING;
2424                                 if(joinAllowed(this))
2425                                         Join(this);
2426                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2427                                         CS(this).autojoin_checked = -1;
2428                                 return;
2429                         }
2430                 }
2431                 if(is_spec && !SpectateUpdate(this))
2432                         PutObserverInServer(this);
2433         }
2434         if (is_spec)
2435                 this.flags |= FL_CLIENT | FL_NOTARGET;
2436 }
2437
2438 void PlayerUseKey(entity this)
2439 {
2440         if (!IS_PLAYER(this))
2441                 return;
2442
2443         if(this.vehicle)
2444         {
2445                 if(!game_stopped)
2446                 {
2447                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2448                         return;
2449                 }
2450         }
2451         else if(autocvar_g_vehicles_enter)
2452         {
2453                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2454                 {
2455                         entity head, closest_target = NULL;
2456                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2457
2458                         while(head) // find the closest acceptable target to enter
2459                         {
2460                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2461                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2462                                 {
2463                                         if(closest_target)
2464                                         {
2465                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2466                                                 { closest_target = head; }
2467                                         }
2468                                         else { closest_target = head; }
2469                                 }
2470
2471                                 head = head.chain;
2472                         }
2473
2474                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2475                 }
2476         }
2477
2478         // a use key was pressed; call handlers
2479         MUTATOR_CALLHOOK(PlayerUseKey, this);
2480 }
2481
2482
2483 /*
2484 =============
2485 PlayerPreThink
2486
2487 Called every frame for each client before the physics are run
2488 =============
2489 */
2490 .float last_vehiclecheck;
2491 void PlayerPreThink (entity this)
2492 {
2493         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2494         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2495
2496         WarpZone_PlayerPhysics_FixVAngle(this);
2497
2498         if (frametime) {
2499                 // physics frames: update anticheat stuff
2500                 anticheat_prethink(this);
2501         }
2502
2503         if (blockSpectators && frametime) {
2504                 // WORKAROUND: only use dropclient in server frames (frametime set).
2505                 // Never use it in cl_movement frames (frametime zero).
2506                 checkSpectatorBlock(this);
2507         }
2508
2509         zoomstate_set = false;
2510
2511         // Check for nameless players
2512         if (this.netname == "" || this.netname != CS(this).netname_previous)
2513         {
2514                 bool assume_unchanged = (CS(this).netname_previous == "");
2515                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2516                 {
2517                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2518                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2519                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2520                         assume_unchanged = false;
2521                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2522                 }
2523                 if (isInvisibleString(this.netname))
2524                 {
2525                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2526                         sprint(this, "Warning: invisible names are not allowed.\n");
2527                         assume_unchanged = false;
2528                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2529                 }
2530                 if (!assume_unchanged && autocvar_sv_eventlog)
2531                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2532                 strcpy(CS(this).netname_previous, this.netname);
2533         }
2534
2535         // version nagging
2536         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2537         CS(this).version_nagtime = 0;
2538         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2539             // git client
2540         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2541             // git server
2542             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2543         } else {
2544             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2545             if (r < 0) { // old client
2546                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2547             } else if (r > 0) { // old server
2548                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2549             }
2550         }
2551     }
2552
2553         // GOD MODE info
2554         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2555         {
2556                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2557                 this.max_armorvalue = 0;
2558         }
2559
2560         if (frametime && IS_PLAYER(this))
2561         {
2562                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2563                 {
2564                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2565                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2566                         if (this.iceblock)
2567                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2568
2569                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2570                                 Unfreeze(this, false);
2571                 }
2572                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2573                 {
2574                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2575                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2576
2577                         if (GetResource(this, RES_HEALTH) < 1)
2578                         {
2579                                 if (this.vehicle)
2580                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2581                                 if(this.event_damage)
2582                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2583                         }
2584                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2585                                 Unfreeze(this, false);
2586                 }
2587         }
2588
2589         MUTATOR_CALLHOOK(PlayerPreThink, this);
2590
2591         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2592         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2593         {
2594                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2595                 {
2596                         if(!it.owner)
2597                         {
2598                                 if(!it.team || SAME_TEAM(this, it))
2599                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2600                                 else if(autocvar_g_vehicles_steal)
2601                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2602                         }
2603                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2604                         {
2605                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2606                         }
2607                 });
2608
2609                 this.last_vehiclecheck = time + 1;
2610         }
2611
2612         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2613         {
2614                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2615                         PlayerUseKey(this);
2616                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2617         }
2618
2619         if (IS_REAL_CLIENT(this))
2620                 PrintWelcomeMessage(this);
2621
2622         if (IS_PLAYER(this)) {
2623                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2624                         error("Client can't be spawned as player on connection!");
2625                 if(!PlayerThink(this))
2626                         return;
2627         }
2628         else if (game_stopped || intermission_running) {
2629                 if(intermission_running)
2630                         IntermissionThink(this);
2631                 return;
2632         }
2633         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2634         {
2635                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2636                 CS(this).autojoin_checked = 1;
2637                 // don't do this in ClientConnect
2638                 // many things can go wrong if a client is spawned as player on connection
2639                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2640                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2641                                 && (!teamplay || autocvar_g_balance_teams)))
2642                 {
2643                         campaign_bots_may_start = true;
2644                         if(joinAllowed(this))
2645                                 Join(this);
2646                         return;
2647                 }
2648         }
2649         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2650                 ObserverOrSpectatorThink(this);
2651         }
2652
2653         // WEAPONTODO: Add weapon request for this
2654         if (!zoomstate_set) {
2655                 bool wep_zoomed = false;
2656                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2657                 {
2658                         .entity weaponentity = weaponentities[slot];
2659                         Weapon thiswep = this.(weaponentity).m_weapon;
2660                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2661                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2662                 }
2663                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2664         }
2665
2666         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2667         {
2668                 CS(this).teamkill_soundtime = 0;
2669
2670                 entity e = CS(this).teamkill_soundsource;
2671                 entity oldpusher = e.pusher;
2672                 e.pusher = this;
2673                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2674                 e.pusher = oldpusher;
2675         }
2676
2677         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2678                 CS(this).taunt_soundtime = 0;
2679                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2680         }
2681
2682         target_voicescript_next(this);
2683
2684         // WEAPONTODO: Move into weaponsystem somehow
2685         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2686         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2687         {
2688                 .entity weaponentity = weaponentities[slot];
2689                 if(this.(weaponentity).m_weapon == WEP_Null)
2690                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2691         }
2692 }
2693
2694 void DrownPlayer(entity this)
2695 {
2696         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2697                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2698         {
2699                 this.air_finished = 0;
2700                 return;
2701         }
2702
2703         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2704         {
2705                 if(this.air_finished && this.air_finished < time)
2706                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2707                 this.air_finished = 0;
2708         }
2709         else
2710         {
2711                 if (!this.air_finished)
2712                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2713                 if (this.air_finished < time)
2714                 {       // drown!
2715                         if (this.pain_finished < time)
2716                         {
2717                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2718                                 this.pain_finished = time + 0.5;
2719                         }
2720                 }
2721         }
2722 }
2723
2724 .bool move_qcphysics;
2725
2726 void Player_Physics(entity this)
2727 {
2728         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2729
2730         if(!this.move_qcphysics)
2731                 return;
2732
2733         if(!frametime && !CS(this).pm_frametime)
2734                 return;
2735
2736         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2737
2738         CS(this).pm_frametime = 0;
2739 }
2740
2741 /*
2742 =============
2743 PlayerPostThink
2744
2745 Called every frame for each client after the physics are run
2746 =============
2747 */
2748 void PlayerPostThink (entity this)
2749 {
2750         Player_Physics(this);
2751
2752         if (sv_maxidle > 0)
2753         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2754         if (IS_REAL_CLIENT(this))
2755         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2756         {
2757                 int totalClients = 0;
2758                 if(sv_maxidle_slots > 0)
2759                 {
2760                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2761                         {
2762                                 ++totalClients;
2763                         });
2764                 }
2765
2766                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2767                 { /* do nothing */ }
2768                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2769                 {
2770                         if (CS(this).idlekick_lasttimeleft)
2771                         {
2772                                 CS(this).idlekick_lasttimeleft = 0;
2773                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2774                         }
2775                 }
2776                 else
2777                 {
2778                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2779                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2780                                 if (!CS(this).idlekick_lasttimeleft)
2781                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2782                         }
2783                         if (timeleft <= 0) {
2784                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2785                                 dropclient(this);
2786                                 return;
2787                         }
2788                         else if (timeleft <= 10) {
2789                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2790                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2791                 }
2792                                 CS(this).idlekick_lasttimeleft = timeleft;
2793                         }
2794                 }
2795         }
2796
2797         CheatFrame(this);
2798
2799         if (game_stopped)
2800         {
2801                 this.solid = SOLID_NOT;
2802                 this.takedamage = DAMAGE_NO;
2803                 set_movetype(this, MOVETYPE_NONE);
2804                 CS(this).teamkill_complain = 0;
2805                 CS(this).teamkill_soundtime = 0;
2806                 CS(this).teamkill_soundsource = NULL;
2807         }
2808
2809         if (IS_PLAYER(this)) {
2810                 if(this.death_time == time && IS_DEAD(this))
2811                 {
2812                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2813                         // once all the damage events of this frame have been processed with normal size
2814                         this.maxs.z = 5;
2815                         setsize(this, this.mins, this.maxs);
2816                 }
2817                 DrownPlayer(this);
2818                 UpdateChatBubble(this);
2819                 if (CS(this).impulse) ImpulseCommands(this);
2820                 if (game_stopped)
2821                 {
2822                         CSQCMODEL_AUTOUPDATE(this);
2823                         return;
2824                 }
2825                 GetPressedKeys(this);
2826         }
2827         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2828         {
2829                 CS(this).pressedkeys = 0;
2830                 STAT(PRESSED_KEYS, this) = 0;
2831         }
2832
2833         if (this.waypointsprite_attachedforcarrier) {
2834                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2835                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2836         }
2837
2838         CSQCMODEL_AUTOUPDATE(this);
2839 }
2840
2841 /**
2842  * message "": do not say, just test flood control
2843  * return value:
2844  *   1 = accept
2845  *   0 = reject
2846  *  -1 = fake accept
2847  */
2848 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2849 {
2850         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2851                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2852
2853         if (source)
2854                 msgin = formatmessage(source, msgin);
2855
2856         string colorstr;
2857         if (!(IS_PLAYER(source) || source.caplayer))
2858                 colorstr = "^0"; // black for spectators
2859         else if(teamplay)
2860                 colorstr = Team_ColorCode(source.team);
2861         else
2862         {
2863                 colorstr = "";
2864                 teamsay = false;
2865         }
2866
2867         if (!source) {
2868                 colorstr = "";
2869                 teamsay = false;
2870         }
2871
2872         if(msgin != "")
2873                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2874
2875         /*
2876          * using bprint solves this... me stupid
2877         // how can we prevent the message from appearing in a listen server?
2878         // for now, just give "say" back and only handle say_team
2879         if(!teamsay)
2880         {
2881                 clientcommand(source, strcat("say ", msgin));
2882                 return;
2883         }
2884         */
2885
2886         string namestr = "";
2887         if (source)
2888                 namestr = playername(source, autocvar_g_chat_teamcolors);
2889
2890         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2891
2892         string msgstr = "", cmsgstr = "";
2893         string privatemsgprefix = string_null;
2894         int privatemsgprefixlen = 0;
2895         if (msgin != "")
2896         {
2897                 bool found_me = false;
2898                 if(strstrofs(msgin, "/me", 0) >= 0)
2899                 {
2900                         string newmsgin = "";
2901                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2902                         FOREACH_WORD(msgin, true,
2903                         {
2904                                 if(strdecolorize(it) == "/me")
2905                                 {
2906                                         found_me = true;
2907                                         newmsgin = cons(newmsgin, newnamestr);
2908                                 }
2909                                 else
2910                                         newmsgin = cons(newmsgin, it);
2911                         });
2912                         msgin = newmsgin;
2913                 }
2914
2915                 if(privatesay)
2916                 {
2917                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2918                         privatemsgprefixlen = strlen(msgstr);
2919                         msgstr = strcat(msgstr, msgin);
2920                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2921                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2922                 }
2923                 else if(teamsay)
2924                 {
2925                         if(found_me)
2926                         {
2927                                 //msgin = strreplace("/me", "", msgin);
2928                                 //msgin = substring(msgin, 3, strlen(msgin));
2929                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2930                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2931                         }
2932                         else
2933                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2934                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2935                 }
2936                 else
2937                 {
2938                         if(found_me)
2939                         {
2940                                 //msgin = strreplace("/me", "", msgin);
2941                                 //msgin = substring(msgin, 3, strlen(msgin));
2942                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2943                                 msgstr = strcat("\{1}^4* ^7", msgin);
2944                         }
2945                         else {
2946                                 msgstr = "\{1}";
2947                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2948                                 msgstr = strcat(msgstr, msgin);
2949                         }
2950                         cmsgstr = "";
2951                 }
2952                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2953         }
2954
2955         string fullmsgstr = msgstr;
2956         string fullcmsgstr = cmsgstr;
2957
2958         // FLOOD CONTROL
2959         int flood = 0;
2960         var .float flood_field = floodcontrol_chat;
2961         if(floodcontrol && source)
2962         {
2963                 float flood_spl;
2964                 float flood_burst;
2965                 float flood_lmax;
2966                 float lines;
2967                 if(privatesay)
2968                 {
2969                         flood_spl = autocvar_g_chat_flood_spl_tell;
2970                         flood_burst = autocvar_g_chat_flood_burst_tell;
2971                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2972                         flood_field = floodcontrol_chattell;
2973                 }
2974                 else if(teamsay)
2975                 {
2976                         flood_spl = autocvar_g_chat_flood_spl_team;
2977                         flood_burst = autocvar_g_chat_flood_burst_team;
2978                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2979                         flood_field = floodcontrol_chatteam;
2980                 }
2981                 else
2982                 {
2983                         flood_spl = autocvar_g_chat_flood_spl;
2984                         flood_burst = autocvar_g_chat_flood_burst;
2985                         flood_lmax = autocvar_g_chat_flood_lmax;
2986                         flood_field = floodcontrol_chat;
2987                 }
2988                 flood_burst = max(0, flood_burst - 1);
2989                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2990
2991                 // do flood control for the default line size
2992                 if(msgstr != "")
2993                 {
2994                         getWrappedLine_remaining = msgstr;
2995                         msgstr = "";
2996                         lines = 0;
2997                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2998                         {
2999                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3000                                 ++lines;
3001                         }
3002                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3003
3004                         if(getWrappedLine_remaining != "")
3005                         {
3006                                 msgstr = strcat(msgstr, "\n");
3007                                 flood = 2;
3008                         }
3009
3010                         if (time >= source.(flood_field))
3011                         {
3012                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3013                         }
3014                         else
3015                         {
3016                                 flood = 1;
3017                                 msgstr = fullmsgstr;
3018                         }
3019                 }
3020                 else
3021                 {
3022                         if (time >= source.(flood_field))
3023                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3024                         else
3025                                 flood = 1;
3026                 }
3027
3028                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3029                         source.(flood_field) = flood = 0;
3030         }
3031
3032         string sourcemsgstr, sourcecmsgstr;
3033         if(flood == 2) // cannot happen for empty msgstr
3034         {
3035                 if(autocvar_g_chat_flood_notify_flooder)
3036                 {
3037                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3038                         sourcecmsgstr = "";
3039                 }
3040                 else
3041                 {
3042                         sourcemsgstr = fullmsgstr;
3043                         sourcecmsgstr = fullcmsgstr;
3044                 }
3045                 cmsgstr = "";
3046         }
3047         else
3048         {
3049                 sourcemsgstr = msgstr;
3050                 sourcecmsgstr = cmsgstr;
3051         }
3052
3053         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3054         {
3055                 if (!game_stopped)
3056                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
3057                         teamsay = -1; // spectators
3058         }
3059
3060         if(flood)
3061                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3062
3063         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3064         if(privatesay)
3065                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3066
3067         int ret;
3068         if(source && CS(source).muted)
3069         {
3070                 // always fake the message
3071                 ret = -1;
3072         }
3073         else if(flood == 1)
3074         {
3075                 if (autocvar_g_chat_flood_notify_flooder)
3076                 {
3077                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3078                         ret = 0;
3079                 }
3080                 else
3081                         ret = -1;
3082         }
3083         else
3084         {
3085                 ret = 1;
3086         }
3087
3088         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3089         {
3090                 if (!game_stopped)
3091                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3092                         ret = -1; // just hide the message completely
3093         }
3094
3095         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3096         ret = M_ARGV(1, int);
3097
3098         string event_log_msg = "";
3099
3100         if(sourcemsgstr != "" && ret != 0)
3101         {
3102                 if(ret < 0) // faked message, because the player is muted
3103                 {
3104                         sprint(source, sourcemsgstr);
3105                         if(sourcecmsgstr != "" && !privatesay)
3106                                 centerprint(source, sourcecmsgstr);
3107                 }
3108                 else if(privatesay) // private message, between 2 people only
3109                 {
3110                         sprint(source, sourcemsgstr);
3111                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3112                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3113                         {
3114                                 sprint(privatesay, msgstr);
3115                                 if(cmsgstr != "")
3116                                         centerprint(privatesay, cmsgstr);
3117                         }
3118                 }
3119                 else if ( teamsay && CS(source).active_minigame )
3120                 {
3121                         sprint(source, sourcemsgstr);
3122                         dedicated_print(msgstr); // send to server console too
3123                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3124                                 sprint(it, msgstr);
3125                         });
3126                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3127
3128                 }
3129                 else if(teamsay > 0) // team message, only sent to team mates
3130                 {
3131                         sprint(source, sourcemsgstr);
3132                         dedicated_print(msgstr); // send to server console too
3133                         if(sourcecmsgstr != "")
3134                                 centerprint(source, sourcecmsgstr);
3135                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3136                                 sprint(it, msgstr);
3137                                 if(cmsgstr != "")
3138                                         centerprint(it, cmsgstr);
3139                         });
3140                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3141                 }
3142                 else if(teamsay < 0) // spectator message, only sent to spectators
3143                 {
3144                         sprint(source, sourcemsgstr);
3145                         dedicated_print(msgstr); // send to server console too
3146                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3147                                 sprint(it, msgstr);
3148                         });
3149                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3150                 }
3151                 else
3152                 {
3153                         if (source) {
3154                                 sprint(source, sourcemsgstr);
3155                                 dedicated_print(msgstr); // send to server console too
3156                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3157                         }
3158                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3159                                 sprint(it, msgstr);
3160                         });
3161                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3162                 }
3163         }
3164
3165         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3166                 GameLogEcho(event_log_msg);
3167         }
3168
3169         return ret;
3170 }
3171
3172 // hack to copy the button fields from the client entity to the Client State
3173 void PM_UpdateButtons(entity this, entity store)
3174 {
3175         if(this.impulse)
3176                 store.impulse = this.impulse;
3177         this.impulse = 0;
3178
3179         bool typing = this.buttonchat || this.button12;
3180
3181         store.button0 = (typing) ? 0 : this.button0;
3182         //button1?!
3183         store.button2 = (typing) ? 0 : this.button2;
3184         store.button3 = (typing) ? 0 : this.button3;
3185         store.button4 = this.button4;
3186         store.button5 = (typing) ? 0 : this.button5;
3187         store.button6 = this.button6;
3188         store.button7 = this.button7;
3189         store.button8 = this.button8;
3190         store.button9 = this.button9;
3191         store.button10 = this.button10;
3192         store.button11 = this.button11;
3193         store.button12 = this.button12;
3194         store.button13 = this.button13;
3195         store.button14 = this.button14;
3196         store.button15 = this.button15;
3197         store.button16 = this.button16;
3198         store.buttonuse = this.buttonuse;
3199         store.buttonchat = this.buttonchat;
3200
3201         store.cursor_active = this.cursor_active;
3202         store.cursor_screen = this.cursor_screen;
3203         store.cursor_trace_start = this.cursor_trace_start;
3204         store.cursor_trace_endpos = this.cursor_trace_endpos;
3205         store.cursor_trace_ent = this.cursor_trace_ent;
3206
3207         store.ping = this.ping;
3208         store.ping_packetloss = this.ping_packetloss;
3209         store.ping_movementloss = this.ping_movementloss;
3210
3211         store.v_angle = this.v_angle;
3212         store.movement = this.movement;
3213 }
3214
3215 NET_HANDLE(fpsreport, bool)
3216 {
3217         int fps = ReadShort();
3218         PlayerScore_Set(sender, SP_FPS, fps);
3219         return true;
3220 }