qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (mutator_returnvalue) {
 289             // mutator prevents resetting teams+score
 290         } else {
 291                 int oldteam = this.team;
 292                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 293                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 294         this.frags = FRAGS_SPECTATOR;
 295         PlayerScore_Clear(this);  // clear scores when needed
 296     }
 297
 298         if (CS(this).killcount != FRAGS_SPECTATOR)
 299         {
 300                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 301                 if(!game_stopped)
 302                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 303                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 304
 305                 if(!CS(this).just_joined)
 306                         LogTeamchange(this.playerid, -1, 4);
 307                 else
 308                         CS(this).just_joined = false;
 309         }
 310
 311         accuracy_resend(this);
 312
 313         CS(this).spectatortime = time;
 314         if(this.bot_attack)
 315                 IL_REMOVE(g_bot_targets, this);
 316         this.bot_attack = false;
 317         if(this.monster_attack)
 318                 IL_REMOVE(g_monster_targets, this);
 319         this.monster_attack = false;
 320     STAT(HUD, this) = HUD_NORMAL;
 321         TRANSMUTE(Observer, this);
 322         this.iscreature = false;
 323         this.teleportable = TELEPORT_SIMPLE;
 324         if(this.damagedbycontents)
 325                 IL_REMOVE(g_damagedbycontents, this);
 326         this.damagedbycontents = false;
 327         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 328         SetSpectatee_status(this, etof(this));
 329         this.takedamage = DAMAGE_NO;
 330         this.solid = SOLID_NOT;
 331         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 332         this.flags = FL_CLIENT | FL_NOTARGET;
 333         this.effects = 0;
 334         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 335         this.pauserotarmor_finished = 0;
 336         this.pauserothealth_finished = 0;
 337         this.pauseregen_finished = 0;
 338         this.damageforcescale = 0;
 339         this.death_time = 0;
 340         this.respawn_flags = 0;
 341         this.respawn_time = 0;
 342         STAT(RESPAWN_TIME, this) = 0;
 343         this.alpha = 0;
 344         this.scale = 0;
 345         this.fade_time = 0;
 346         this.pain_frame = 0;
 347         this.pain_finished = 0;
 348         this.strength_finished = 0;
 349         this.invincible_finished = 0;
 350         this.superweapons_finished = 0;
 351         this.dphitcontentsmask = 0;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         this.crouch = false;
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360
 361         this.items = 0;
 362         STAT(WEAPONS, this) = '0 0 0';
 363         this.drawonlytoclient = this;
 364
 365         this.viewloc = NULL;
 366
 367         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 368
 369         this.weaponmodel = "";
 370         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         {
 372                 this.weaponentities[slot] = NULL;
 373         }
 374         this.exteriorweaponentity = NULL;
 375         CS(this).killcount = FRAGS_SPECTATOR;
 376         this.velocity = '0 0 0';
 377         this.avelocity = '0 0 0';
 378         this.punchangle = '0 0 0';
 379         this.punchvector = '0 0 0';
 380         this.oldvelocity = this.velocity;
 381         this.fire_endtime = -1;
 382         this.event_damage = func_null;
 383
 384         for(int slot = 0; slot < MAX_AXH; ++slot)
 385         {
 386                 entity axh = this.(AuxiliaryXhair[slot]);
 387                 this.(AuxiliaryXhair[slot]) = NULL;
 388
 389                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 390                         delete(axh);
 391         }
 392 }
 393
 394 int player_getspecies(entity this)
 395 {
 396         get_model_parameters(this.model, this.skin);
 397         int s = get_model_parameters_species;
 398         get_model_parameters(string_null, 0);
 399         if (s < 0) return SPECIES_HUMAN;
 400         return s;
 401 }
 402
 403 .float model_randomizer;
 404 void FixPlayermodel(entity player)
 405 {
 406         string defaultmodel = "";
 407         int defaultskin = 0;
 408         if(autocvar_sv_defaultcharacter)
 409         {
 410                 if(teamplay)
 411                 {
 412                         switch(player.team)
 413                         {
 414                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 415                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 416                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 417                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 418                         }
 419                 }
 420
 421                 if(defaultmodel == "")
 422                 {
 423                         defaultmodel = autocvar_sv_defaultplayermodel;
 424                         defaultskin = autocvar_sv_defaultplayerskin;
 425                 }
 426
 427                 int n = tokenize_console(defaultmodel);
 428                 if(n > 0)
 429                 {
 430                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 431                         // However, do NOT randomize if the player-selected model is in the list.
 432                         for (int i = 0; i < n; ++i)
 433                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 434                                         defaultmodel = argv(i);
 435                 }
 436
 437                 int i = strstrofs(defaultmodel, ":", 0);
 438                 if(i >= 0)
 439                 {
 440                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 441                         defaultmodel = substring(defaultmodel, 0, i);
 442                 }
 443         }
 444         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 445         {
 446                 if(teamplay)
 447                 {
 448                         switch(player.team)
 449                         {
 450                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 451                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 452                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 453                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 454                         }
 455                 }
 456
 457                 if(!defaultskin)
 458                         defaultskin = autocvar_sv_defaultplayerskin;
 459         }
 460
 461         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 462         defaultmodel = M_ARGV(0, string);
 463         defaultskin = M_ARGV(1, int);
 464
 465         bool chmdl = false;
 466         int oldskin;
 467         if(defaultmodel != "")
 468         {
 469                 if (defaultmodel != player.model)
 470                 {
 471                         vector m1 = player.mins;
 472                         vector m2 = player.maxs;
 473                         setplayermodel (player, defaultmodel);
 474                         setsize (player, m1, m2);
 475                         chmdl = true;
 476                 }
 477
 478                 oldskin = player.skin;
 479                 player.skin = defaultskin;
 480         } else {
 481                 if (player.playermodel != player.model || player.playermodel == "")
 482                 {
 483                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 484                         vector m1 = player.mins;
 485                         vector m2 = player.maxs;
 486                         setplayermodel (player, player.playermodel);
 487                         setsize (player, m1, m2);
 488                         chmdl = true;
 489                 }
 490
 491                 if(!autocvar_sv_defaultcharacterskin)
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = stof(player.playerskin);
 495                 }
 496                 else
 497                 {
 498                         oldskin = player.skin;
 499                         player.skin = defaultskin;
 500                 }
 501         }
 502
 503         if(chmdl || oldskin != player.skin) // model or skin has changed
 504         {
 505                 player.species = player_getspecies(player); // update species
 506                 if(!autocvar_g_debug_globalsounds)
 507                         UpdatePlayerSounds(player); // update skin sounds
 508         }
 509
 510         if(!teamplay)
 511                 if(strlen(autocvar_sv_defaultplayercolors))
 512                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 513                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 514 }
 515
 516 void PutPlayerInServer(entity this)
 517 {
 518         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 519
 520         PlayerState_attach(this);
 521         accuracy_resend(this);
 522
 523         if (this.team < 0)
 524                 JoinBestTeam(this, true);
 525
 526         entity spot = SelectSpawnPoint(this, false);
 527         if (!spot) {
 528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 529                 return; // spawn failed
 530         }
 531
 532         TRANSMUTE(Player, this);
 533
 534         CS(this).wasplayer = true;
 535         this.iscreature = true;
 536         this.teleportable = TELEPORT_NORMAL;
 537         if(!this.damagedbycontents)
 538                 IL_PUSH(g_damagedbycontents, this);
 539         this.damagedbycontents = true;
 540         set_movetype(this, MOVETYPE_WALK);
 541         this.solid = SOLID_SLIDEBOX;
 542         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 543         if (autocvar_g_playerclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 545         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 547         this.frags = FRAGS_PLAYER;
 548         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 549         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 550         if (autocvar__notarget)
 551                 this.flags |= FL_NOTARGET;
 552         this.takedamage = DAMAGE_AIM;
 553         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 554
 555         if (warmup_stage) {
 556                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 557                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 558                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 559                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 560                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 561                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 562                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 563                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 564                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 565         } else {
 566                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 567                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 568                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 569                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 570                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 571                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 572                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 573                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 574                 STAT(WEAPONS, this) = start_weapons;
 575                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 576                 {
 577                         GiveRandomWeapons(this, random_start_weapons_count,
 578                                 autocvar_g_random_start_weapons, random_start_ammo);
 579                 }
 580         }
 581         SetSpectatee_status(this, 0);
 582
 583         PS(this).dual_weapons = '0 0 0';
 584
 585         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 586
 587         this.items = start_items;
 588
 589         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 590         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 591         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 592         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 593         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 594         if (!sv_ready_restart_after_countdown && time < game_starttime)
 595         {
 596                 float f = game_starttime - time;
 597                 this.spawnshieldtime += f;
 598                 this.pauserotarmor_finished += f;
 599                 this.pauserothealth_finished += f;
 600                 this.pauseregen_finished += f;
 601         }
 602
 603         this.damageforcescale = 2;
 604         this.death_time = 0;
 605         this.respawn_flags = 0;
 606         this.respawn_time = 0;
 607         STAT(RESPAWN_TIME, this) = 0;
 608         this.scale = autocvar_sv_player_scale;
 609         this.fade_time = 0;
 610         this.pain_frame = 0;
 611         this.pain_finished = 0;
 612         this.pushltime = 0;
 613         setthink(this, func_null); // players have no think function
 614         this.nextthink = 0;
 615         this.dmg_team = 0;
 616         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 617
 618         this.deadflag = DEAD_NO;
 619
 620         this.angles = spot.angles;
 621         this.angles_z = 0; // never spawn tilted even if the spot says to
 622         if (IS_BOT_CLIENT(this))
 623                 this.v_angle = this.angles;
 624         this.fixangle = true; // turn this way immediately
 625         this.oldvelocity = this.velocity = '0 0 0';
 626         this.avelocity = '0 0 0';
 627         this.punchangle = '0 0 0';
 628         this.punchvector = '0 0 0';
 629
 630         this.strength_finished = 0;
 631         this.invincible_finished = 0;
 632         this.fire_endtime = -1;
 633         STAT(REVIVE_PROGRESS, this) = 0;
 634         this.revival_time = 0;
 635
 636         this.air_finished = time + 12;
 637         this.waterlevel = WATERLEVEL_NONE;
 638         this.watertype = CONTENT_EMPTY;
 639
 640         entity spawnevent = new_pure(spawnevent);
 641         spawnevent.owner = this;
 642         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 643
 644         // Cut off any still running player sounds.
 645         stopsound(this, CH_PLAYER_SINGLE);
 646
 647         this.model = "";
 648         FixPlayermodel(this);
 649         this.drawonlytoclient = NULL;
 650
 651         this.viewloc = NULL;
 652
 653         for(int slot = 0; slot < MAX_AXH; ++slot)
 654         {
 655                 entity axh = this.(AuxiliaryXhair[slot]);
 656                 this.(AuxiliaryXhair[slot]) = NULL;
 657
 658                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 659                         delete(axh);
 660         }
 661
 662         this.spawnpoint_targ = NULL;
 663
 664         this.crouch = false;
 665         this.view_ofs = STAT(PL_VIEW_OFS, this);
 666         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 667         this.spawnorigin = spot.origin;
 668         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 669         // don't reset back to last position, even if new position is stuck in solid
 670         this.oldorigin = this.origin;
 671         if(this.conveyor)
 672                 IL_REMOVE(g_conveyed, this);
 673         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 674         STAT(HUD, this) = HUD_NORMAL;
 675
 676         this.event_damage = PlayerDamage;
 677
 678         if(!this.bot_attack)
 679                 IL_PUSH(g_bot_targets, this);
 680         this.bot_attack = true;
 681         if(!this.monster_attack)
 682                 IL_PUSH(g_monster_targets, this);
 683         this.monster_attack = true;
 684         navigation_dynamicgoal_init(this, false);
 685
 686         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 687
 688         // player was spectator
 689         if (CS(this).killcount == FRAGS_SPECTATOR) {
 690                 PlayerScore_Clear(this);
 691                 CS(this).killcount = 0;
 692                 CS(this).startplaytime = time;
 693         }
 694
 695         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696         {
 697                 .entity weaponentity = weaponentities[slot];
 698                 entity oldwep = this.(weaponentity);
 699                 CL_SpawnWeaponentity(this, weaponentity);
 700                 if(oldwep && oldwep.owner == this)
 701                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 702         }
 703         this.alpha = default_player_alpha;
 704         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 705         this.exteriorweaponentity.alpha = default_weapon_alpha;
 706
 707         this.speedrunning = false;
 708
 709         target_voicescript_clear(this);
 710
 711         // reset fields the weapons may use
 712         FOREACH(Weapons, true, {
 713                 it.wr_resetplayer(it, this);
 714                         // reload all reloadable weapons
 715                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 716                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717                         {
 718                                 .entity weaponentity = weaponentities[slot];
 719                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 720                         }
 721                 }
 722         });
 723
 724         {
 725                 string s = spot.target;
 726                 spot.target = string_null;
 727                 SUB_UseTargets(spot, this, NULL);
 728                 spot.target = s;
 729         }
 730
 731         Unfreeze(this);
 732
 733         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 734
 735         if (autocvar_spawn_debug)
 736         {
 737                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 738                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 739         }
 740
 741         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742         {
 743                 .entity weaponentity = weaponentities[slot];
 744                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 745                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 746                 else
 747                         this.(weaponentity).m_switchweapon = WEP_Null;
 748                 this.(weaponentity).m_weapon = WEP_Null;
 749                 this.(weaponentity).weaponname = "";
 750                 this.(weaponentity).m_switchingweapon = WEP_Null;
 751                 this.(weaponentity).cnt = -1;
 752         }
 753
 754         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 755
 756         if (!warmup_stage && !this.alivetime)
 757                 this.alivetime = time;
 758
 759         antilag_clear(this, CS(this));
 760 }
 761
 762 /** Called when a client spawns in the server */
 763 void PutClientInServer(entity this)
 764 {
 765         if (IS_BOT_CLIENT(this)) {
 766                 TRANSMUTE(Player, this);
 767         } else if (IS_REAL_CLIENT(this)) {
 768                 msg_entity = this;
 769                 WriteByte(MSG_ONE, SVC_SETVIEW);
 770                 WriteEntity(MSG_ONE, this);
 771         }
 772         if (game_stopped)
 773                 TRANSMUTE(Observer, this);
 774
 775         SetSpectatee(this, NULL);
 776
 777         // reset player keys
 778         if(PS(this))
 779                 PS(this).itemkeys = 0;
 780
 781         MUTATOR_CALLHOOK(PutClientInServer, this);
 782
 783         if (IS_OBSERVER(this)) {
 784                 PutObserverInServer(this);
 785         } else if (IS_PLAYER(this)) {
 786                 PutPlayerInServer(this);
 787         }
 788 }
 789
 790 // TODO do we need all these fields, or should we stop autodetecting runtime
 791 // changes and just have a console command to update this?
 792 bool ClientInit_SendEntity(entity this, entity to, int sf)
 793 {
 794         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 795         return = true;
 796         msg_entity = to;
 797         // MSG_INIT replacement
 798         // TODO: make easier to use
 799         Registry_send_all();
 800         W_PROP_reload(MSG_ONE, to);
 801         ClientInit_misc(this);
 802         MUTATOR_CALLHOOK(Ent_Init);
 803 }
 804 void ClientInit_misc(entity this)
 805 {
 806         int channel = MSG_ONE;
 807         WriteHeader(channel, ENT_CLIENT_INIT);
 808         WriteByte(channel, g_nexball_meter_period * 32);
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 810         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 811         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 812         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 814         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 815         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 816         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 817
 818         if(sv_foginterval && world.fog != "")
 819                 WriteString(channel, world.fog);
 820         else
 821                 WriteString(channel, "");
 822         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 823         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 824         WriteByte(channel, serverflags);
 825         WriteCoord(channel, autocvar_g_trueaim_minrange);
 826 }
 827
 828 void ClientInit_CheckUpdate(entity this)
 829 {
 830         this.nextthink = time;
 831         if(this.count != autocvar_g_balance_armor_blockpercent)
 832         {
 833                 this.count = autocvar_g_balance_armor_blockpercent;
 834                 this.SendFlags |= 1;
 835         }
 836         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 837         {
 838                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 839                 this.SendFlags |= 1;
 840         }
 841 }
 842
 843 void ClientInit_Spawn()
 844 {
 845         entity e = new_pure(clientinit);
 846         setthink(e, ClientInit_CheckUpdate);
 847         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 848
 849         ClientInit_CheckUpdate(e);
 850 }
 851
 852 /*
 853 =============
 854 SetNewParms
 855 =============
 856 */
 857 void SetNewParms ()
 858 {
 859         // initialize parms for a new player
 860         parm1 = -(86400 * 366);
 861
 862         MUTATOR_CALLHOOK(SetNewParms);
 863 }
 864
 865 /*
 866 =============
 867 SetChangeParms
 868 =============
 869 */
 870 void SetChangeParms (entity this)
 871 {
 872         // save parms for level change
 873         parm1 = CS(this).parm_idlesince - time;
 874
 875         MUTATOR_CALLHOOK(SetChangeParms);
 876 }
 877
 878 /*
 879 =============
 880 DecodeLevelParms
 881 =============
 882 */
 883 void DecodeLevelParms(entity this)
 884 {
 885         // load parms
 886         CS(this).parm_idlesince = parm1;
 887         if (CS(this).parm_idlesince == -(86400 * 366))
 888                 CS(this).parm_idlesince = time;
 889
 890         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 891         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 892
 893         MUTATOR_CALLHOOK(DecodeLevelParms);
 894 }
 895
 896 /*
 897 =============
 898 ClientKill
 899
 900 Called when a client types 'kill' in the console
 901 =============
 902 */
 903
 904 .float clientkill_nexttime;
 905 void ClientKill_Now_TeamChange(entity this)
 906 {
 907         if(this.killindicator_teamchange == -1)
 908         {
 909                 JoinBestTeam( this, true );
 910         }
 911         else if(this.killindicator_teamchange == -2)
 912         {
 913                 if(blockSpectators)
 914                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 915                 PutObserverInServer(this);
 916         }
 917         else
 918                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 919         this.killindicator_teamchange = 0;
 920 }
 921
 922 void ClientKill_Now(entity this)
 923 {
 924         if(this.vehicle)
 925         {
 926             vehicles_exit(this.vehicle, VHEF_RELEASE);
 927             if(!this.killindicator_teamchange)
 928             {
 929             this.vehicle_health = -1;
 930             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 931             }
 932         }
 933
 934         if(this.killindicator && !wasfreed(this.killindicator))
 935                 delete(this.killindicator);
 936
 937         this.killindicator = NULL;
 938
 939         if(this.killindicator_teamchange)
 940                 ClientKill_Now_TeamChange(this);
 941
 942         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 943         {
 944                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 945         }
 946
 947         // now I am sure the player IS dead
 948 }
 949 void KillIndicator_Think(entity this)
 950 {
 951         if (game_stopped)
 952         {
 953                 this.owner.killindicator = NULL;
 954                 delete(this);
 955                 return;
 956         }
 957
 958         if (this.owner.alpha < 0 && !this.owner.vehicle)
 959         {
 960                 this.owner.killindicator = NULL;
 961                 delete(this);
 962                 return;
 963         }
 964
 965         if(this.cnt <= 0)
 966         {
 967                 ClientKill_Now(this.owner);
 968                 return;
 969         }
 970     else if(this.count == 1) // count == 1 means that it's silent
 971     {
 972         this.nextthink = time + 1;
 973         this.cnt -= 1;
 974     }
 975         else
 976         {
 977                 if(this.cnt <= 10)
 978                         setmodel(this, MDL_NUM(this.cnt));
 979                 if(IS_REAL_CLIENT(this.owner))
 980                 {
 981                         if(this.cnt <= 10)
 982                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 983                 }
 984                 this.nextthink = time + 1;
 985                 this.cnt -= 1;
 986         }
 987 }
 988
 989 float clientkilltime;
 990 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 991 {
 992         float killtime;
 993         float starttime;
 994
 995         if (game_stopped)
 996                 return;
 997
 998         killtime = autocvar_g_balance_kill_delay;
 999
1000     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1001         return;
1002     killtime = M_ARGV(1, float);
1003
1004         this.killindicator_teamchange = targetteam;
1005
1006     if(!this.killindicator)
1007         {
1008                 if(!IS_DEAD(this))
1009                 {
1010                         killtime = max(killtime, this.clientkill_nexttime - time);
1011                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1012                 }
1013
1014                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1015                 {
1016                         ClientKill_Now(this);
1017                 }
1018                 else
1019                 {
1020                         starttime = max(time, clientkilltime);
1021
1022                         this.killindicator = spawn();
1023                         this.killindicator.owner = this;
1024                         this.killindicator.scale = 0.5;
1025                         setattachment(this.killindicator, this, "");
1026                         setorigin(this.killindicator, '0 0 52');
1027                         setthink(this.killindicator, KillIndicator_Think);
1028                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1029                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1030                         this.killindicator.cnt = ceil(killtime);
1031                         this.killindicator.count = bound(0, ceil(killtime), 10);
1032                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1033
1034                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1035                         {
1036                                 it.killindicator = spawn();
1037                                 it.killindicator.owner = it;
1038                                 it.killindicator.scale = 0.5;
1039                                 setattachment(it.killindicator, it, "");
1040                                 setorigin(it.killindicator, '0 0 52');
1041                                 setthink(it.killindicator, KillIndicator_Think);
1042                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1043                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1044                                 it.killindicator.cnt = ceil(killtime);
1045                         });
1046                         this.lip = 0;
1047                 }
1048         }
1049         if(this.killindicator)
1050         {
1051                 if(targetteam == 0) // just die
1052                 {
1053                         this.killindicator.colormod = '0 0 0';
1054                         if(IS_REAL_CLIENT(this))
1055                         if(this.killindicator.cnt > 0)
1056                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1057                 }
1058                 else if(targetteam == -1) // auto
1059                 {
1060                         this.killindicator.colormod = '0 1 0';
1061                         if(IS_REAL_CLIENT(this))
1062                         if(this.killindicator.cnt > 0)
1063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1064                 }
1065                 else if(targetteam == -2) // spectate
1066                 {
1067                         this.killindicator.colormod = '0.5 0.5 0.5';
1068                         if(IS_REAL_CLIENT(this))
1069                         if(this.killindicator.cnt > 0)
1070                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1071                 }
1072                 else
1073                 {
1074                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1075                         if(IS_REAL_CLIENT(this))
1076                         if(this.killindicator.cnt > 0)
1077                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1078                 }
1079         }
1080
1081 }
1082
1083 void ClientKill (entity this)
1084 {
1085         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1086
1087         if(game_stopped) return;
1088         if(this.player_blocked) return;
1089         if(STAT(FROZEN, this)) return;
1090
1091         ClientKill_TeamChange(this, 0);
1092 }
1093
1094 void FixClientCvars(entity e)
1095 {
1096         // send prediction settings to the client
1097         stuffcmd(e, "\nin_bindmap 0 0\n");
1098         if(autocvar_g_antilag == 3) // client side hitscan
1099                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1100         if(autocvar_sv_gentle)
1101                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1102
1103         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1104         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1105
1106         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1107
1108         MUTATOR_CALLHOOK(FixClientCvars, e);
1109 }
1110
1111 bool findinlist_abbrev(string tofind, string list)
1112 {
1113         if(list == "" || tofind == "")
1114                 return false; // empty list or search, just return
1115
1116         // this function allows abbreviated strings!
1117         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1118         {
1119                 return true;
1120         });
1121
1122         return false;
1123 }
1124
1125 bool PlayerInIPList(entity p, string iplist)
1126 {
1127         // some safety checks (never allow local?)
1128         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1129                 return false;
1130
1131         return findinlist_abbrev(p.netaddress, iplist);
1132 }
1133
1134 bool PlayerInIDList(entity p, string idlist)
1135 {
1136         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1137         if(!p.crypto_idfp)
1138                 return false;
1139
1140         return findinlist_abbrev(p.crypto_idfp, idlist);
1141 }
1142
1143 bool PlayerInList(entity player, string list)
1144 {
1145         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1146 }
1147
1148 #ifdef DP_EXT_PRECONNECT
1149 /*
1150 =============
1151 ClientPreConnect
1152
1153 Called once (not at each match start) when a client begins a connection to the server
1154 =============
1155 */
1156 void ClientPreConnect(entity this)
1157 {
1158         if(autocvar_sv_eventlog)
1159         {
1160                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1161                         this.playerid,
1162                         etof(this),
1163                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1164                 ));
1165         }
1166 }
1167 #endif
1168
1169 /**
1170 =============
1171 ClientConnect
1172
1173 Called when a client connects to the server
1174 =============
1175 */
1176 void ClientConnect(entity this)
1177 {
1178         if (Ban_MaybeEnforceBanOnce(this)) return;
1179         assert(!IS_CLIENT(this), return);
1180         this.flags |= FL_CLIENT;
1181         assert(player_count >= 0, player_count = 0);
1182
1183 #ifdef WATERMARK
1184         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1185 #endif
1186         TRANSMUTE(Client, this);
1187         CS(this).version_nagtime = time + 10 + random() * 10;
1188
1189         // identify the right forced team
1190         if (autocvar_g_campaign)
1191         {
1192                 if (IS_REAL_CLIENT(this)) // only players, not bots
1193                 {
1194                         switch (autocvar_g_campaign_forceteam)
1195                         {
1196                                 case 1: this.team_forced = NUM_TEAM_1; break;
1197                                 case 2: this.team_forced = NUM_TEAM_2; break;
1198                                 case 3: this.team_forced = NUM_TEAM_3; break;
1199                                 case 4: this.team_forced = NUM_TEAM_4; break;
1200                                 default: this.team_forced = 0;
1201                         }
1202                 }
1203         }
1204         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1205         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1206         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1207         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1208         else switch (autocvar_g_forced_team_otherwise)
1209         {
1210                 default: this.team_forced = 0; break;
1211                 case "red": this.team_forced = NUM_TEAM_1; break;
1212                 case "blue": this.team_forced = NUM_TEAM_2; break;
1213                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1214                 case "pink": this.team_forced = NUM_TEAM_4; break;
1215                 case "spectate":
1216                 case "spectator":
1217                         this.team_forced = -1;
1218                         break;
1219         }
1220         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1221
1222         int playerid_save = this.playerid;
1223         this.playerid = 0; // silent
1224         JoinBestTeam(this, false); // if the team number is valid, keep it
1225         this.playerid = playerid_save;
1226
1227         TRANSMUTE(Observer, this);
1228
1229         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1230
1231         // always track bots, don't ask for cl_allow_uidtracking
1232         if (IS_BOT_CLIENT(this))
1233                 PlayerStats_GameReport_AddPlayer(this);
1234         else
1235                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1236
1237         if (autocvar_sv_eventlog)
1238                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1239
1240         LogTeamchange(this.playerid, this.team, 1);
1241
1242         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1243
1244         if(teamplay && IS_PLAYER(this))
1245                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1246         else
1247                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1248
1249         stuffcmd(this, clientstuff, "\n");
1250         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1251
1252         FixClientCvars(this);
1253
1254         // get version info from player
1255         stuffcmd(this, "cmd clientversion $gameversion\n");
1256
1257         // notify about available teams
1258         if (teamplay)
1259         {
1260                 CheckAllowedTeams(this);
1261                 int t = 0;
1262                 if (c1 >= 0) t |= BIT(0);
1263                 if (c2 >= 0) t |= BIT(1);
1264                 if (c3 >= 0) t |= BIT(2);
1265                 if (c4 >= 0) t |= BIT(3);
1266                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1267         }
1268         else
1269         {
1270                 stuffcmd(this, "set _teams_available 0\n");
1271         }
1272
1273         bot_relinkplayerlist();
1274
1275         CS(this).spectatortime = time;
1276         if (blockSpectators)
1277         {
1278                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1279         }
1280
1281         CS(this).jointime = time;
1282
1283         if (IS_REAL_CLIENT(this))
1284         {
1285                 if (g_weaponarena_weapons == WEPSET(TUBA))
1286                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1287         }
1288
1289         if (!sv_foginterval && world.fog != "")
1290                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1291
1292         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1293                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1294                         send_CSQC_teamnagger();
1295
1296         CSQCMODEL_AUTOINIT(this);
1297
1298         CS(this).model_randomizer = random();
1299
1300         if (IS_REAL_CLIENT(this))
1301                 sv_notice_join(this);
1302
1303         // update physics stats (players can spawn before physics runs)
1304         Physics_UpdateStats(this);
1305
1306         IL_EACH(g_initforplayer, it.init_for_player, {
1307                 it.init_for_player(it, this);
1308         });
1309
1310         Handicap_Initialize(this);
1311
1312         MUTATOR_CALLHOOK(ClientConnect, this);
1313
1314         if (IS_REAL_CLIENT(this))
1315         {
1316                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1317                 {
1318                         CS(this).motd_actived_time = -1;
1319                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1320                 }
1321         }
1322 }
1323 /*
1324 =============
1325 ClientDisconnect
1326
1327 Called when a client disconnects from the server
1328 =============
1329 */
1330 .entity chatbubbleentity;
1331 void ClientDisconnect(entity this)
1332 {
1333         assert(IS_CLIENT(this), return);
1334
1335         PlayerStats_GameReport_FinalizePlayer(this);
1336         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1337         if (CS(this).active_minigame) part_minigame(this);
1338         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1339
1340         if (autocvar_sv_eventlog)
1341                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1342
1343         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1344
1345         if(IS_SPEC(this))
1346                 SetSpectatee(this, NULL);
1347
1348     MUTATOR_CALLHOOK(ClientDisconnect, this);
1349
1350         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1351         strfree(CS(this).weaponorder_byimpulse);
1352         ClientState_detach(this);
1353
1354         Portal_ClearAll(this);
1355
1356         Unfreeze(this);
1357
1358         RemoveGrapplingHooks(this);
1359
1360         // Here, everything has been done that requires this player to be a client.
1361
1362         this.flags &= ~FL_CLIENT;
1363
1364         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1365         if (this.killindicator) delete(this.killindicator);
1366
1367         WaypointSprite_PlayerGone(this);
1368
1369         bot_relinkplayerlist();
1370
1371         strfree(this.clientstatus);
1372         if (this.personal) delete(this.personal);
1373
1374         this.playerid = 0;
1375         ReadyCount();
1376         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1377
1378         ONREMOVE(this);
1379 }
1380
1381 void ChatBubbleThink(entity this)
1382 {
1383         this.nextthink = time;
1384         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1385         {
1386                 if(this.owner) // but why can that ever be NULL?
1387                         this.owner.chatbubbleentity = NULL;
1388                 delete(this);
1389                 return;
1390         }
1391
1392         this.mdl = "";
1393
1394         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1395         {
1396                 if ( CS(this.owner).active_minigame )
1397                         this.mdl = "models/sprites/minigame_busy.iqm";
1398                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1399                         this.mdl = "models/misc/chatbubble.spr";
1400         }
1401
1402         if ( this.model != this.mdl )
1403                 _setmodel(this, this.mdl);
1404
1405 }
1406
1407 void UpdateChatBubble(entity this)
1408 {
1409         if (this.alpha < 0)
1410                 return;
1411         // spawn a chatbubble entity if needed
1412         if (!this.chatbubbleentity)
1413         {
1414                 this.chatbubbleentity = new(chatbubbleentity);
1415                 this.chatbubbleentity.owner = this;
1416                 this.chatbubbleentity.exteriormodeltoclient = this;
1417                 setthink(this.chatbubbleentity, ChatBubbleThink);
1418                 this.chatbubbleentity.nextthink = time;
1419                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1420                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1421                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1422                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1423                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1424                 //this.chatbubbleentity.model = "";
1425                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1426         }
1427 }
1428
1429
1430 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1431 // added to the model skins
1432 /*void UpdateColorModHack()
1433 {
1434         float c;
1435         c = this.clientcolors & 15;
1436         // LordHavoc: only bothering to support white, green, red, yellow, blue
1437              if (!teamplay) this.colormod = '0 0 0';
1438         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1439         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1440         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1441         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1442         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1443         else this.colormod = '1 1 1';
1444 }*/
1445
1446 void respawn(entity this)
1447 {
1448         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1449         {
1450                 this.solid = SOLID_NOT;
1451                 this.takedamage = DAMAGE_NO;
1452                 set_movetype(this, MOVETYPE_FLY);
1453                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1454                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1455                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1456                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1457                 if(autocvar_g_respawn_ghosts_maxtime)
1458                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1459         }
1460
1461         CopyBody(this, 1);
1462
1463         this.effects |= EF_NODRAW; // prevent another CopyBody
1464         PutClientInServer(this);
1465 }
1466
1467 void PrintToChat(entity client, string text)
1468 {
1469         text = strcat("\{1}^7", text, "\n");
1470         sprint(client, text);
1471 }
1472
1473 void DebugPrintToChat(entity client, string text)
1474 {
1475         if (autocvar_developer)
1476         {
1477                 PrintToChat(client, text);
1478         }
1479 }
1480
1481 void PrintToChatAll(string text)
1482 {
1483         text = strcat("\{1}^7", text, "\n");
1484         bprint(text);
1485 }
1486
1487 void DebugPrintToChatAll(string text)
1488 {
1489         if (autocvar_developer)
1490         {
1491                 PrintToChatAll(text);
1492         }
1493 }
1494
1495 void PrintToChatTeam(int team_num, string text)
1496 {
1497         text = strcat("\{1}^7", text, "\n");
1498         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1499         {
1500                 if (it.team == team_num)
1501                 {
1502                         sprint(it, text);
1503                 }
1504         });
1505 }
1506
1507 void DebugPrintToChatTeam(int team_num, string text)
1508 {
1509         if (autocvar_developer)
1510         {
1511                 PrintToChatTeam(team_num, text);
1512         }
1513 }
1514
1515 void play_countdown(entity this, float finished, Sound samp)
1516 {
1517     TC(Sound, samp);
1518         if(IS_REAL_CLIENT(this))
1519                 if(floor(finished - time - frametime) != floor(finished - time))
1520                         if(finished - time < 6)
1521                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1522 }
1523
1524 void player_powerups(entity this)
1525 {
1526         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1527         int items_prev = this.items;
1528
1529         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1530                 this.modelflags |= MF_ROCKET;
1531         else
1532                 this.modelflags &= ~MF_ROCKET;
1533
1534         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1535
1536         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1537                 return;
1538
1539         Fire_ApplyDamage(this);
1540         Fire_ApplyEffect(this);
1541
1542         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1543         {
1544                 if (this.items & ITEM_Strength.m_itemid)
1545                 {
1546                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1547                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1548                         if (time > this.strength_finished)
1549                         {
1550                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1551                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1553                         }
1554                 }
1555                 else
1556                 {
1557                         if (time < this.strength_finished)
1558                         {
1559                                 this.items = this.items | ITEM_Strength.m_itemid;
1560                                 if(!g_cts)
1561                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1562                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1563                         }
1564                 }
1565                 if (this.items & ITEM_Shield.m_itemid)
1566                 {
1567                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1568                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1569                         if (time > this.invincible_finished)
1570                         {
1571                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1572                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1573                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1574                         }
1575                 }
1576                 else
1577                 {
1578                         if (time < this.invincible_finished)
1579                         {
1580                                 this.items = this.items | ITEM_Shield.m_itemid;
1581                                 if(!g_cts)
1582                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1583                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1584                         }
1585                 }
1586                 if (this.items & IT_SUPERWEAPON)
1587                 {
1588                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1589                         {
1590                                 this.superweapons_finished = 0;
1591                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1592                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1593                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1594                         }
1595                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1596                         {
1597                                 // don't let them run out
1598                         }
1599                         else
1600                         {
1601                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1602                                 if (time > this.superweapons_finished)
1603                                 {
1604                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1605                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1606                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1607                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1608                                 }
1609                         }
1610                 }
1611                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1612                 {
1613                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1614                         {
1615                                 this.items = this.items | IT_SUPERWEAPON;
1616                                 if(!g_cts)
1617                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1618                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1619                         }
1620                         else
1621                         {
1622                                 this.superweapons_finished = 0;
1623                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1624                         }
1625                 }
1626                 else
1627                 {
1628                         this.superweapons_finished = 0;
1629                 }
1630         }
1631
1632         if(autocvar_g_nodepthtestplayers)
1633                 this.effects = this.effects | EF_NODEPTHTEST;
1634
1635         if(autocvar_g_fullbrightplayers)
1636                 this.effects = this.effects | EF_FULLBRIGHT;
1637
1638         if (time >= game_starttime)
1639         if (time < this.spawnshieldtime)
1640                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1641
1642         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1643 }
1644
1645 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1646 {
1647         if(current > stable)
1648                 return current;
1649         else if(current > stable - 0.25) // when close enough, "snap"
1650                 return stable;
1651         else
1652                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1653 }
1654
1655 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1656 {
1657         if(current < stable)
1658                 return current;
1659         else if(current < stable + 0.25) // when close enough, "snap"
1660                 return stable;
1661         else
1662                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1663 }
1664
1665 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1666 {
1667         if(current > rotstable)
1668         {
1669                 if(rotframetime > 0)
1670                 {
1671                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1672                         current = max(rotstable, current - rotlinear * rotframetime);
1673                 }
1674         }
1675         else if(current < regenstable)
1676         {
1677                 if(regenframetime > 0)
1678                 {
1679                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1680                         current = min(regenstable, current + regenlinear * regenframetime);
1681                 }
1682         }
1683
1684         if(current > limit)
1685                 current = limit;
1686
1687         return current;
1688 }
1689
1690 void player_regen(entity this)
1691 {
1692         float max_mod, regen_mod, rot_mod, limit_mod;
1693         max_mod = regen_mod = rot_mod = limit_mod = 1;
1694
1695         float regen_health = autocvar_g_balance_health_regen;
1696         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1697         float regen_health_rot = autocvar_g_balance_health_rot;
1698         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1699         float regen_health_stable = autocvar_g_balance_health_regenstable;
1700         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1701         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1702                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1703         max_mod = M_ARGV(1, float);
1704         regen_mod = M_ARGV(2, float);
1705         rot_mod = M_ARGV(3, float);
1706         limit_mod = M_ARGV(4, float);
1707         regen_health = M_ARGV(5, float);
1708         regen_health_linear = M_ARGV(6, float);
1709         regen_health_rot = M_ARGV(7, float);
1710         regen_health_rotlinear = M_ARGV(8, float);
1711         regen_health_stable = M_ARGV(9, float);
1712         regen_health_rotstable = M_ARGV(10, float);
1713
1714         if(!mutator_returnvalue)
1715         if(!STAT(FROZEN, this))
1716         {
1717                 float mina, maxa, limith, limita;
1718                 maxa = autocvar_g_balance_armor_rotstable;
1719                 mina = autocvar_g_balance_armor_regenstable;
1720                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1721                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1722
1723                 regen_health_rotstable = regen_health_rotstable * max_mod;
1724                 regen_health_stable = regen_health_stable * max_mod;
1725                 limith = limith * limit_mod;
1726                 limita = limita * limit_mod;
1727
1728                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1729                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1730                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1731                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1732                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1733                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1734         }
1735
1736         // if player rotted to death...  die!
1737         // check this outside above checks, as player may still be able to rot to death
1738         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1739         {
1740                 if(this.vehicle)
1741                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1742                 if(this.event_damage)
1743                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1744         }
1745
1746         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1747         {
1748                 float minf, maxf, limitf;
1749
1750                 maxf = autocvar_g_balance_fuel_rotstable;
1751                 minf = autocvar_g_balance_fuel_regenstable;
1752                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1753
1754                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1755                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1756                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1757         }
1758 }
1759
1760 bool zoomstate_set;
1761 void SetZoomState(entity this, float newzoom)
1762 {
1763         if(newzoom != CS(this).zoomstate)
1764         {
1765                 CS(this).zoomstate = newzoom;
1766                 ClientData_Touch(this);
1767         }
1768         zoomstate_set = true;
1769 }
1770
1771 void GetPressedKeys(entity this)
1772 {
1773         MUTATOR_CALLHOOK(GetPressedKeys, this);
1774         int keys = STAT(PRESSED_KEYS, this);
1775         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1776         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1777         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1778         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1779
1780         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1781         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1782         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1783         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1784         CS(this).pressedkeys = keys; // store for other users
1785
1786         STAT(PRESSED_KEYS, this) = keys;
1787 }
1788
1789 /*
1790 ======================
1791 spectate mode routines
1792 ======================
1793 */
1794
1795 void SpectateCopy(entity this, entity spectatee)
1796 {
1797     TC(Client, this); TC(Client, spectatee);
1798
1799         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1800         PS(this) = PS(spectatee);
1801         this.armortype = spectatee.armortype;
1802         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1803         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1804         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1805         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1806         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1807         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1808         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1809         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1810         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1811         CS(this).impulse = 0;
1812         this.items = spectatee.items;
1813         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1814         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1815         this.strength_finished = spectatee.strength_finished;
1816         this.invincible_finished = spectatee.invincible_finished;
1817         this.superweapons_finished = spectatee.superweapons_finished;
1818         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1819         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1820         this.punchangle = spectatee.punchangle;
1821         this.view_ofs = spectatee.view_ofs;
1822         this.velocity = spectatee.velocity;
1823         this.dmg_take = spectatee.dmg_take;
1824         this.dmg_save = spectatee.dmg_save;
1825         this.dmg_inflictor = spectatee.dmg_inflictor;
1826         this.v_angle = spectatee.v_angle;
1827         this.angles = spectatee.v_angle;
1828         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1829         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1830         this.viewloc = spectatee.viewloc;
1831         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1832                 this.fixangle = true;
1833         setorigin(this, spectatee.origin);
1834         setsize(this, spectatee.mins, spectatee.maxs);
1835         SetZoomState(this, CS(spectatee).zoomstate);
1836
1837     anticheat_spectatecopy(this, spectatee);
1838         STAT(HUD, this) = STAT(HUD, spectatee);
1839         if(spectatee.vehicle)
1840     {
1841         this.angles = spectatee.v_angle;
1842
1843         //this.fixangle = false;
1844         //this.velocity = spectatee.vehicle.velocity;
1845         this.vehicle_health = spectatee.vehicle_health;
1846         this.vehicle_shield = spectatee.vehicle_shield;
1847         this.vehicle_energy = spectatee.vehicle_energy;
1848         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1849         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1850         this.vehicle_reload1 = spectatee.vehicle_reload1;
1851         this.vehicle_reload2 = spectatee.vehicle_reload2;
1852
1853         //msg_entity = this;
1854
1855        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1856             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1857            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1858            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1859
1860         //WriteByte (MSG_ONE, SVC_SETVIEW);
1861         //    WriteEntity(MSG_ONE, this);
1862         //makevectors(spectatee.v_angle);
1863         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1864     }
1865 }
1866
1867 bool SpectateUpdate(entity this)
1868 {
1869         if(!this.enemy)
1870                 return false;
1871
1872         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1873         {
1874                 SetSpectatee(this, NULL);
1875                 return false;
1876         }
1877
1878         SpectateCopy(this, this.enemy);
1879
1880         return true;
1881 }
1882
1883 bool SpectateSet(entity this)
1884 {
1885         if(!IS_PLAYER(this.enemy))
1886                 return false;
1887
1888         ClientData_Touch(this.enemy);
1889
1890         msg_entity = this;
1891         WriteByte(MSG_ONE, SVC_SETVIEW);
1892         WriteEntity(MSG_ONE, this.enemy);
1893         set_movetype(this, MOVETYPE_NONE);
1894         accuracy_resend(this);
1895
1896         if(!SpectateUpdate(this))
1897                 PutObserverInServer(this);
1898
1899         return true;
1900 }
1901
1902 void SetSpectatee_status(entity this, int spectatee_num)
1903 {
1904         int oldspectatee_status = CS(this).spectatee_status;
1905         CS(this).spectatee_status = spectatee_num;
1906
1907         if (CS(this).spectatee_status != oldspectatee_status)
1908         {
1909                 ClientData_Touch(this);
1910                 if (g_race || g_cts) race_InitSpectator();
1911         }
1912 }
1913
1914 void SetSpectatee(entity this, entity spectatee)
1915 {
1916         if(IS_BOT_CLIENT(this))
1917                 return; // bots abuse .enemy, this code is useless to them
1918
1919         entity old_spectatee = this.enemy;
1920
1921         this.enemy = spectatee;
1922
1923         // WEAPONTODO
1924         // these are required to fix the spectator bug with arc
1925         if(old_spectatee)
1926         {
1927                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1928                 {
1929                         .entity weaponentity = weaponentities[slot];
1930                         if(old_spectatee.(weaponentity).arc_beam)
1931                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1932                 }
1933         }
1934         if(this.enemy)
1935         {
1936                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1937                 {
1938                         .entity weaponentity = weaponentities[slot];
1939                         if(this.enemy.(weaponentity).arc_beam)
1940                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1941                 }
1942         }
1943
1944         if (this.enemy)
1945                 SetSpectatee_status(this, etof(this.enemy));
1946
1947         // needed to update spectator list
1948         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1949 }
1950
1951 bool Spectate(entity this, entity pl)
1952 {
1953         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1954                 return false;
1955         pl = M_ARGV(1, entity);
1956
1957         SetSpectatee(this, pl);
1958         return SpectateSet(this);
1959 }
1960
1961 bool SpectateNext(entity this)
1962 {
1963         entity ent = find(this.enemy, classname, STR_PLAYER);
1964
1965         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1966                 ent = M_ARGV(1, entity);
1967         else if (!ent)
1968                 ent = find(ent, classname, STR_PLAYER);
1969
1970         if(ent) { SetSpectatee(this, ent); }
1971
1972         return SpectateSet(this);
1973 }
1974
1975 bool SpectatePrev(entity this)
1976 {
1977         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1978         entity ent = findchain(classname, STR_PLAYER);
1979         if (!ent) // no player
1980                 return false;
1981
1982         entity first = ent;
1983         // skip players until current spectated player
1984         if(this.enemy)
1985         while(ent && ent != this.enemy)
1986                 ent = ent.chain;
1987
1988         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1989         {
1990                 case MUT_SPECPREV_FOUND:
1991                     ent = M_ARGV(1, entity);
1992                     break;
1993                 case MUT_SPECPREV_RETURN:
1994                     return true;
1995                 case MUT_SPECPREV_CONTINUE:
1996                 default:
1997                 {
1998                         if(ent.chain)
1999                                 ent = ent.chain;
2000                         else
2001                                 ent = first;
2002                         break;
2003                 }
2004         }
2005
2006         SetSpectatee(this, ent);
2007         return SpectateSet(this);
2008 }
2009
2010 /*
2011 =============
2012 ShowRespawnCountdown()
2013
2014 Update a respawn countdown display.
2015 =============
2016 */
2017 void ShowRespawnCountdown(entity this)
2018 {
2019         float number;
2020         if(!IS_DEAD(this)) // just respawned?
2021                 return;
2022         else
2023         {
2024                 number = ceil(this.respawn_time - time);
2025                 if(number <= 0)
2026                         return;
2027                 if(number <= this.respawn_countdown)
2028                 {
2029                         this.respawn_countdown = number - 1;
2030                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2031                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2032                 }
2033         }
2034 }
2035
2036 .bool team_selected;
2037 bool ShowTeamSelection(entity this)
2038 {
2039         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2040                 return false;
2041         stuffcmd(this, "menu_showteamselect\n");
2042         return true;
2043 }
2044 void Join(entity this)
2045 {
2046         TRANSMUTE(Player, this);
2047
2048         if(!this.team_selected)
2049         if(autocvar_g_campaign || autocvar_g_balance_teams)
2050                 JoinBestTeam(this, true);
2051
2052         if(autocvar_g_campaign)
2053                 campaign_bots_may_start = true;
2054
2055         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2056
2057         PutClientInServer(this);
2058
2059         if(IS_PLAYER(this))
2060         if(teamplay && this.team != -1)
2061                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2062         else
2063                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2064         this.team_selected = false;
2065 }
2066
2067 /**
2068  * Determines whether the player is allowed to join. This depends on cvar
2069  * g_maxplayers, if it isn't used this function always return true, otherwise
2070  * it checks whether the number of currently playing players exceeds g_maxplayers.
2071  * @return int number of free slots for players, 0 if none
2072  */
2073 int nJoinAllowed(entity this, entity ignore)
2074 {
2075         if(!ignore)
2076         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2077         // so report 0 free slots if restricted
2078         {
2079                 if(autocvar_g_forced_team_otherwise == "spectate")
2080                         return 0;
2081                 if(autocvar_g_forced_team_otherwise == "spectator")
2082                         return 0;
2083         }
2084
2085         if(this && this.team_forced < 0)
2086                 return 0; // forced spectators can never join
2087
2088         // TODO simplify this
2089         int totalClients = 0;
2090         int currentlyPlaying = 0;
2091         FOREACH_CLIENT(true, {
2092                 if(it != ignore)
2093                         ++totalClients;
2094                 if(IS_REAL_CLIENT(it))
2095                 if(IS_PLAYER(it) || it.caplayer)
2096                         ++currentlyPlaying;
2097         });
2098
2099         float free_slots = 0;
2100         if (!autocvar_g_maxplayers)
2101                 free_slots = maxclients - totalClients;
2102         else if(currentlyPlaying < autocvar_g_maxplayers)
2103                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2104
2105         static float join_prevent_msg_time = 0;
2106         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2107         {
2108                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2109                 join_prevent_msg_time = time + 3;
2110         }
2111
2112         return free_slots;
2113 }
2114
2115 /**
2116  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2117  * g_maxplayers_spectator_blocktime seconds
2118  */
2119 void checkSpectatorBlock(entity this)
2120 {
2121         if(IS_SPEC(this) || IS_OBSERVER(this))
2122         if(!this.caplayer)
2123         if(IS_REAL_CLIENT(this))
2124         {
2125                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2126                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2127                         dropclient(this);
2128                 }
2129         }
2130 }
2131
2132 void PrintWelcomeMessage(entity this)
2133 {
2134         if(CS(this).motd_actived_time == 0)
2135         {
2136                 if (autocvar_g_campaign) {
2137                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2138                                 CS(this).motd_actived_time = time;
2139                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2140                         }
2141                 } else {
2142                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2143                                 CS(this).motd_actived_time = time;
2144                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2145                         }
2146                 }
2147         }
2148         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2149         {
2150                 if (autocvar_g_campaign) {
2151                         if (PHYS_INPUT_BUTTON_INFO(this))
2152                                 CS(this).motd_actived_time = time;
2153                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2154                                 CS(this).motd_actived_time = 0;
2155                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2156                         }
2157                 } else {
2158                         if (PHYS_INPUT_BUTTON_INFO(this))
2159                                 CS(this).motd_actived_time = time;
2160                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2161                                 CS(this).motd_actived_time = 0;
2162                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2163                         }
2164                 }
2165         }
2166         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2167         {
2168                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2169                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2170                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2171                 {
2172                         // instanctly hide MOTD
2173                         CS(this).motd_actived_time = 0;
2174                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2175                 }
2176         }
2177 }
2178
2179 const int MIN_SPEC_TIME = 1;
2180 bool joinAllowed(entity this)
2181 {
2182         if (CS(this).version_mismatch) return false;
2183         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2184         if (!nJoinAllowed(this, this)) return false;
2185         if (teamplay && lockteams) return false;
2186         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2187         if (ShowTeamSelection(this)) return false;
2188         return true;
2189 }
2190
2191 .int items_added;
2192 .string shootfromfixedorigin;
2193 bool PlayerThink(entity this)
2194 {
2195         if (game_stopped || intermission_running) {
2196                 this.modelflags &= ~MF_ROCKET;
2197                 if(intermission_running)
2198                         IntermissionThink(this);
2199                 return false;
2200         }
2201
2202         if (timeout_status == TIMEOUT_ACTIVE) {
2203         // don't allow the player to turn around while game is paused
2204                 // FIXME turn this into CSQC stuff
2205                 this.v_angle = this.lastV_angle;
2206                 this.angles = this.lastV_angle;
2207                 this.fixangle = true;
2208         }
2209
2210         if (frametime) player_powerups(this);
2211
2212         if (IS_DEAD(this)) {
2213                 if (this.personal && g_race_qualifying) {
2214                         if (time > this.respawn_time) {
2215                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2216                                 respawn(this);
2217                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2218                         }
2219                 } else {
2220                         if (frametime) player_anim(this);
2221
2222                         if (this.respawn_flags & RESPAWN_DENY)
2223                         {
2224                                 STAT(RESPAWN_TIME, this) = 0;
2225                                 return false;
2226                         }
2227
2228                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2229
2230                         switch(this.deadflag)
2231                         {
2232                                 case DEAD_DYING:
2233                                 {
2234                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2235                                                 this.deadflag = DEAD_RESPAWNING;
2236                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2237                                                 this.deadflag = DEAD_DEAD;
2238                                         break;
2239                                 }
2240                                 case DEAD_DEAD:
2241                                 {
2242                                         if (button_pressed)
2243                                                 this.deadflag = DEAD_RESPAWNABLE;
2244                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2245                                                 this.deadflag = DEAD_RESPAWNING;
2246                                         break;
2247                                 }
2248                                 case DEAD_RESPAWNABLE:
2249                                 {
2250                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2251                                                 this.deadflag = DEAD_RESPAWNING;
2252                                         break;
2253                                 }
2254                                 case DEAD_RESPAWNING:
2255                                 {
2256                                         if (time > this.respawn_time)
2257                                         {
2258                                                 this.respawn_time = time + 1; // only retry once a second
2259                                                 this.respawn_time_max = this.respawn_time;
2260                                                 respawn(this);
2261                                         }
2262                                         break;
2263                                 }
2264                         }
2265
2266                         ShowRespawnCountdown(this);
2267
2268                         if (this.respawn_flags & RESPAWN_SILENT)
2269                                 STAT(RESPAWN_TIME, this) = 0;
2270                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2271                         {
2272                                 if (time < this.respawn_time)
2273                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2274                                 else if (this.deadflag != DEAD_RESPAWNING)
2275                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2276                         }
2277                         else
2278                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2279                 }
2280
2281                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2282                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2283                         STAT(RESPAWN_TIME, this) *= -1;
2284
2285                 return false;
2286         }
2287
2288         FixPlayermodel(this);
2289
2290         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2291                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2292                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2293         }
2294
2295         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2296         //if(frametime)
2297         {
2298                 this.items &= ~this.items_added;
2299
2300                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2301                 {
2302                         .entity weaponentity = weaponentities[slot];
2303                         W_WeaponFrame(this, weaponentity);
2304                 }
2305
2306                 this.items_added = 0;
2307                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2308             this.items_added |= IT_FUEL;
2309
2310                 this.items |= this.items_added;
2311         }
2312
2313         player_regen(this);
2314
2315         // WEAPONTODO: Add a weapon request for this
2316         // rot vortex charge to the charge limit
2317         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2318         {
2319                 .entity weaponentity = weaponentities[slot];
2320                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2321                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2322         }
2323
2324         if (frametime) player_anim(this);
2325
2326         // secret status
2327         secrets_setstatus(this);
2328
2329         // monsters status
2330         monsters_setstatus(this);
2331
2332         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2333
2334         return true;
2335 }
2336
2337 .bool would_spectate;
2338 void ObserverThink(entity this)
2339 {
2340         if ( CS(this).impulse )
2341         {
2342                 MinigameImpulse(this, CS(this).impulse);
2343                 CS(this).impulse = 0;
2344         }
2345
2346         if (this.flags & FL_JUMPRELEASED) {
2347                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2348                         this.flags &= ~FL_JUMPRELEASED;
2349                         this.flags |= FL_SPAWNING;
2350                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2351                         this.flags &= ~FL_JUMPRELEASED;
2352                         if(SpectateNext(this)) {
2353                                 TRANSMUTE(Spectator, this);
2354                         }
2355                 } else {
2356                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2357                         set_movetype(this, preferred_movetype);
2358                 }
2359         } else {
2360                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2361                         this.flags |= FL_JUMPRELEASED;
2362                         if(this.flags & FL_SPAWNING)
2363                         {
2364                                 this.flags &= ~FL_SPAWNING;
2365                                 Join(this);
2366                                 return;
2367                         }
2368                 }
2369         }
2370 }
2371
2372 void SpectatorThink(entity this)
2373 {
2374         if ( CS(this).impulse )
2375         {
2376                 if(MinigameImpulse(this, CS(this).impulse))
2377                         CS(this).impulse = 0;
2378
2379                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2380                 {
2381                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2382                         CS(this).impulse = 0;
2383                         return;
2384                 }
2385         }
2386
2387         if (this.flags & FL_JUMPRELEASED) {
2388                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2389                         this.flags &= ~FL_JUMPRELEASED;
2390                         this.flags |= FL_SPAWNING;
2391                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2392                         this.flags &= ~FL_JUMPRELEASED;
2393                         if(SpectateNext(this)) {
2394                                 TRANSMUTE(Spectator, this);
2395                         } else {
2396                                 TRANSMUTE(Observer, this);
2397                                 PutClientInServer(this);
2398                         }
2399                         CS(this).impulse = 0;
2400                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2401                         this.flags &= ~FL_JUMPRELEASED;
2402                         if(SpectatePrev(this)) {
2403                                 TRANSMUTE(Spectator, this);
2404                         } else {
2405                                 TRANSMUTE(Observer, this);
2406                                 PutClientInServer(this);
2407                         }
2408                         CS(this).impulse = 0;
2409                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2410                         this.would_spectate = false;
2411                         this.flags &= ~FL_JUMPRELEASED;
2412                         TRANSMUTE(Observer, this);
2413                         PutClientInServer(this);
2414                 } else {
2415                         if(!SpectateUpdate(this))
2416                         {
2417                                 if(!SpectateNext(this))
2418                                 {
2419                                         PutObserverInServer(this);
2420                                         this.would_spectate = true;
2421                                 }
2422                         }
2423                 }
2424         } else {
2425                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2426                         this.flags |= FL_JUMPRELEASED;
2427                         if(this.flags & FL_SPAWNING)
2428                         {
2429                                 this.flags &= ~FL_SPAWNING;
2430                                 Join(this);
2431                                 return;
2432                         }
2433                 }
2434                 if(!SpectateUpdate(this))
2435                         PutObserverInServer(this);
2436         }
2437
2438         this.flags |= FL_CLIENT | FL_NOTARGET;
2439 }
2440
2441 void PlayerUseKey(entity this)
2442 {
2443         if (!IS_PLAYER(this))
2444                 return;
2445
2446         if(this.vehicle)
2447         {
2448                 if(!game_stopped)
2449                 {
2450                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2451                         return;
2452                 }
2453         }
2454         else if(autocvar_g_vehicles_enter)
2455         {
2456                 if(!STAT(FROZEN, this))
2457                 if(!IS_DEAD(this))
2458                 if(!game_stopped)
2459                 {
2460                         entity head, closest_target = NULL;
2461                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2462
2463                         while(head) // find the closest acceptable target to enter
2464                         {
2465                                 if(IS_VEHICLE(head))
2466                                 if(!IS_DEAD(head))
2467                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2468                                 if(head.takedamage != DAMAGE_NO)
2469                                 {
2470                                         if(closest_target)
2471                                         {
2472                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2473                                                 { closest_target = head; }
2474                                         }
2475                                         else { closest_target = head; }
2476                                 }
2477
2478                                 head = head.chain;
2479                         }
2480
2481                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2482                 }
2483         }
2484
2485         // a use key was pressed; call handlers
2486         MUTATOR_CALLHOOK(PlayerUseKey, this);
2487 }
2488
2489
2490 /*
2491 =============
2492 PlayerPreThink
2493
2494 Called every frame for each client before the physics are run
2495 =============
2496 */
2497 .float last_vehiclecheck;
2498 void PlayerPreThink (entity this)
2499 {
2500         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2501         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2502
2503         WarpZone_PlayerPhysics_FixVAngle(this);
2504
2505         if (frametime) {
2506                 // physics frames: update anticheat stuff
2507                 anticheat_prethink(this);
2508         }
2509
2510         if (blockSpectators && frametime) {
2511                 // WORKAROUND: only use dropclient in server frames (frametime set).
2512                 // Never use it in cl_movement frames (frametime zero).
2513                 checkSpectatorBlock(this);
2514         }
2515
2516         zoomstate_set = false;
2517
2518         // Check for nameless players
2519         if (this.netname == "" || this.netname != CS(this).netname_previous)
2520         {
2521                 bool assume_unchanged = (CS(this).netname_previous == "");
2522                 if (isInvisibleString(this.netname))
2523                 {
2524                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2525                         assume_unchanged = false;
2526                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2527                 }
2528                 if (!assume_unchanged && autocvar_sv_eventlog)
2529                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2530                 strcpy(CS(this).netname_previous, this.netname);
2531         }
2532
2533         // version nagging
2534         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2535         CS(this).version_nagtime = 0;
2536         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2537             // git client
2538         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2539             // git server
2540             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2541         } else {
2542             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2543             if (r < 0) { // old client
2544                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2545             } else if (r > 0) { // old server
2546                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2547             }
2548         }
2549     }
2550
2551         // GOD MODE info
2552         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2553         {
2554                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2555                 this.max_armorvalue = 0;
2556         }
2557
2558         if(IS_PLAYER(this))
2559         {
2560                 if (STAT(FROZEN, this) == 2)
2561                 {
2562                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2563                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2564                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2565
2566                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2567                                 Unfreeze(this);
2568                 }
2569                 else if (STAT(FROZEN, this) == 3)
2570                 {
2571                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2572                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2573
2574                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2575                         {
2576                                 if (this.vehicle)
2577                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2578                                 if(this.event_damage)
2579                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2580                         }
2581                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2582                                 Unfreeze(this);
2583                 }
2584         }
2585
2586         MUTATOR_CALLHOOK(PlayerPreThink, this);
2587
2588         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2589         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2590         {
2591                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2592                 {
2593                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2594                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2595                         {
2596                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2597                         }
2598                         else if(!it.owner)
2599                         {
2600                                 if(!it.team || SAME_TEAM(this, it))
2601                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2602                                 else if(autocvar_g_vehicles_steal)
2603                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2604                         }
2605                 });
2606
2607                 this.last_vehiclecheck = time + 1;
2608         }
2609
2610         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2611         {
2612                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2613                         PlayerUseKey(this);
2614                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2615         }
2616
2617         if (IS_REAL_CLIENT(this))
2618                 PrintWelcomeMessage(this);
2619
2620         if (IS_PLAYER(this)) {
2621                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2622                         error("Client can't be spawned as player on connection!");
2623                 if(!PlayerThink(this))
2624                         return;
2625         }
2626         else if (game_stopped || intermission_running) {
2627                 if(intermission_running)
2628                         IntermissionThink(this);
2629                 return;
2630         }
2631         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2632         {
2633                 CS(this).autojoin_checked = true;
2634                 // don't do this in ClientConnect
2635                 // many things can go wrong if a client is spawned as player on connection
2636                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2637                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2638                                 && (!teamplay || autocvar_g_balance_teams)))
2639                 {
2640                         campaign_bots_may_start = true;
2641                         Join(this);
2642                         return;
2643                 }
2644         }
2645         else if (IS_OBSERVER(this)) {
2646                 ObserverThink(this);
2647         }
2648         else if (IS_SPEC(this)) {
2649                 SpectatorThink(this);
2650         }
2651
2652         // WEAPONTODO: Add weapon request for this
2653         if (!zoomstate_set) {
2654                 bool wep_zoomed = false;
2655                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2656                 {
2657                         .entity weaponentity = weaponentities[slot];
2658                         Weapon thiswep = this.(weaponentity).m_weapon;
2659                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2660                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2661                 }
2662                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2663     }
2664
2665         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2666         {
2667                 CS(this).teamkill_soundtime = 0;
2668
2669                 entity e = CS(this).teamkill_soundsource;
2670                 entity oldpusher = e.pusher;
2671                 e.pusher = this;
2672                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2673                 e.pusher = oldpusher;
2674         }
2675
2676         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2677                 CS(this).taunt_soundtime = 0;
2678                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2679         }
2680
2681         target_voicescript_next(this);
2682
2683         // WEAPONTODO: Move into weaponsystem somehow
2684         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2685         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2686         {
2687                 .entity weaponentity = weaponentities[slot];
2688                 if(this.(weaponentity).m_weapon == WEP_Null)
2689                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2690         }
2691 }
2692
2693 void DrownPlayer(entity this)
2694 {
2695         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2696                 return;
2697
2698         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2699         {
2700                 if(this.air_finished < time)
2701                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2702                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2703         }
2704         else if (this.air_finished < time)
2705         {       // drown!
2706                 if (this.pain_finished < time)
2707                 {
2708                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2709                         this.pain_finished = time + 0.5;
2710                 }
2711         }
2712 }
2713
2714 .bool move_qcphysics;
2715
2716 void Player_Physics(entity this)
2717 {
2718         set_movetype(this, this.move_movetype);
2719
2720         if(!this.move_qcphysics)
2721                 return;
2722
2723         if(!frametime && !CS(this).pm_frametime)
2724                 return;
2725
2726         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2727
2728         CS(this).pm_frametime = 0;
2729 }
2730
2731 /*
2732 =============
2733 PlayerPostThink
2734
2735 Called every frame for each client after the physics are run
2736 =============
2737 */
2738 void PlayerPostThink (entity this)
2739 {
2740         Player_Physics(this);
2741
2742         if (sv_maxidle > 0)
2743         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2744         if (IS_REAL_CLIENT(this))
2745         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2746         {
2747                 int totalClients = 0;
2748                 if(sv_maxidle_slots > 0)
2749                 {
2750                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2751                         {
2752                                 ++totalClients;
2753                         });
2754                 }
2755
2756                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2757                 { /* do nothing */ }
2758                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2759                 {
2760                         if (CS(this).idlekick_lasttimeleft)
2761                         {
2762                                 CS(this).idlekick_lasttimeleft = 0;
2763                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2764                         }
2765                 }
2766                 else
2767                 {
2768                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2769                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2770                                 if (!CS(this).idlekick_lasttimeleft)
2771                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2772                         }
2773                         if (timeleft <= 0) {
2774                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2775                                 dropclient(this);
2776                                 return;
2777                         }
2778                         else if (timeleft <= 10) {
2779                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2780                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2781                 }
2782                                 CS(this).idlekick_lasttimeleft = timeleft;
2783                         }
2784                 }
2785         }
2786
2787         CheatFrame(this);
2788
2789         if (game_stopped)
2790         {
2791                 this.solid = SOLID_NOT;
2792                 this.takedamage = DAMAGE_NO;
2793                 set_movetype(this, MOVETYPE_NONE);
2794         }
2795
2796         if (IS_PLAYER(this)) {
2797                 if(this.death_time == time && IS_DEAD(this))
2798                 {
2799                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2800                         // once all the damage events of this frame have been processed with normal size
2801                         this.maxs.z = 5;
2802                         setsize(this, this.mins, this.maxs);
2803                 }
2804                 DrownPlayer(this);
2805                 UpdateChatBubble(this);
2806                 if (CS(this).impulse) ImpulseCommands(this);
2807                 if (game_stopped)
2808                 {
2809                         CSQCMODEL_AUTOUPDATE(this);
2810                         return;
2811                 }
2812                 GetPressedKeys(this);
2813         }
2814
2815         if (this.waypointsprite_attachedforcarrier) {
2816             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2817                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2818     }
2819
2820         playerdemo_write(this);
2821
2822         CSQCMODEL_AUTOUPDATE(this);
2823 }
2824
2825 // hack to copy the button fields from the client entity to the Client State
2826 void PM_UpdateButtons(entity this, entity store)
2827 {
2828         if(this.impulse)
2829                 store.impulse = this.impulse;
2830         this.impulse = 0;
2831
2832         bool typing = this.buttonchat;
2833
2834         store.button0 = (typing) ? 0 : this.button0;
2835         //button1?!
2836         store.button2 = (typing) ? 0 : this.button2;
2837         store.button3 = (typing) ? 0 : this.button3;
2838         store.button4 = this.button4;
2839         store.button5 = (typing) ? 0 : this.button5;
2840         store.button6 = this.button6;
2841         store.button7 = this.button7;
2842         store.button8 = this.button8;
2843         store.button9 = this.button9;
2844         store.button10 = this.button10;
2845         store.button11 = this.button11;
2846         store.button12 = this.button12;
2847         store.button13 = this.button13;
2848         store.button14 = this.button14;
2849         store.button15 = this.button15;
2850         store.button16 = this.button16;
2851         store.buttonuse = this.buttonuse;
2852         store.buttonchat = this.buttonchat;
2853
2854         store.cursor_active = this.cursor_active;
2855         store.cursor_screen = this.cursor_screen;
2856         store.cursor_trace_start = this.cursor_trace_start;
2857         store.cursor_trace_endpos = this.cursor_trace_endpos;
2858         store.cursor_trace_ent = this.cursor_trace_ent;
2859
2860         store.ping = this.ping;
2861         store.ping_packetloss = this.ping_packetloss;
2862         store.ping_movementloss = this.ping_movementloss;
2863
2864         store.v_angle = this.v_angle;
2865         store.movement = (typing) ? '0 0 0' : this.movement;
2866 }
2867
2868 NET_HANDLE(fpsreport, bool)
2869 {
2870         int fps = ReadShort();
2871         PlayerScore_Set(sender, SP_FPS, fps);
2872         return true;
2873 }