Merge branch 'master' into Lyberta/TeamplayOverhaul
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "playerdemo.qh"
14 #include "spawnpoints.qh"
15 #include "resources.qh"
16 #include "g_damage.qh"
17 #include "handicap.qh"
18 #include "g_hook.qh"
19 #include "command/common.qh"
20 #include "command/vote.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28
29 #include "bot/api.qh"
30
31 #include "../common/ent_cs.qh"
32 #include "../common/wepent.qh"
33 #include <common/state.qh>
34
35 #include <common/effects/qc/globalsound.qh>
36
37 #include "../common/mapobjects/func/conveyor.qh"
38 #include "../common/mapobjects/teleporters.qh"
39 #include "../common/mapobjects/target/spawnpoint.qh"
40
41 #include "../common/vehicles/all.qh"
42
43 #include "weapons/hitplot.qh"
44 #include "weapons/weaponsystem.qh"
45
46 #include "../common/net_notice.qh"
47 #include "../common/net_linked.qh"
48 #include "../common/physics/player.qh"
49
50 #include <common/vehicles/sv_vehicles.qh>
51
52 #include "../common/items/_mod.qh"
53
54 #include "../common/mutators/mutator/waypoints/all.qh"
55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
56 #include <common/gamemodes/_mod.qh>
57
58 #include "../common/mapobjects/subs.qh"
59 #include "../common/mapobjects/triggers.qh"
60 #include "../common/mapobjects/trigger/secret.qh"
61
62 #include "../common/minigames/sv_minigames.qh"
63
64 #include "../common/items/inventory.qh"
65
66 #include "../common/monsters/sv_monsters.qh"
67
68 #include "../lib/warpzone/server.qh"
69
70 #include <common/mutators/mutator/overkill/oknex.qh>
71
72 STATIC_METHOD(Client, Add, void(Client this, int _team))
73 {
74     ClientConnect(this);
75     TRANSMUTE(Player, this);
76     this.frame = 12; // 7
77     this.team = _team;
78     PutClientInServer(this);
79 }
80
81 STATIC_METHOD(Client, Remove, void(Client this))
82 {
83     TRANSMUTE(Observer, this);
84     PutClientInServer(this);
85     ClientDisconnect(this);
86 }
87
88 void send_CSQC_teamnagger() {
89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
90 }
91
92 int CountSpectators(entity player, entity to)
93 {
94         if(!player) { return 0; } // not sure how, but best to be safe
95
96         int spec_count = 0;
97
98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
99         {
100                 spec_count++;
101         });
102
103         return spec_count;
104 }
105
106 void WriteSpectators(entity player, entity to)
107 {
108         if(!player) { return; } // not sure how, but best to be safe
109
110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
111         {
112                 WriteByte(MSG_ENTITY, num_for_edict(it));
113         });
114 }
115
116 bool ClientData_Send(entity this, entity to, int sf)
117 {
118         assert(to == this.owner, return false);
119
120         entity e = to;
121         if (IS_SPEC(e)) e = e.enemy;
122
123         sf = 0;
124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
128
129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
130         WriteByte(MSG_ENTITY, sf);
131
132         if (sf & BIT(1))
133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
134
135         if(sf & BIT(4))
136         {
137                 float specs = CountSpectators(e, to);
138                 WriteByte(MSG_ENTITY, specs);
139                 WriteSpectators(e, to);
140         }
141
142         return true;
143 }
144
145 void ClientData_Attach(entity this)
146 {
147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
148         CS(this).clientdata.drawonlytoclient = this;
149         CS(this).clientdata.owner = this;
150 }
151
152 void ClientData_Detach(entity this)
153 {
154         delete(CS(this).clientdata);
155         CS(this).clientdata = NULL;
156 }
157
158 void ClientData_Touch(entity e)
159 {
160         entity cd = CS(e).clientdata;
161         if (cd) { cd.SendFlags = 1; }
162
163         // make it spectatable
164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
165         {
166                 entity cd = CS(it).clientdata;
167                 if (cd) { cd.SendFlags = 1; }
168         });
169 }
170
171
172 /*
173 =============
174 CheckPlayerModel
175
176 Checks if the argument string can be a valid playermodel.
177 Returns a valid one in doubt.
178 =============
179 */
180 string FallbackPlayerModel;
181 string CheckPlayerModel(string plyermodel) {
182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
183         {
184                 // note: we cannot summon Don Strunzone here, some player may
185                 // still have the model string set. In case anyone manages how
186                 // to change a cvar default, we'll have a small leak here.
187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
188         }
189         // only in right path
190         if( substring(plyermodel,0,14) != "models/player/")
191                 return FallbackPlayerModel;
192         // only good file extensions
193         if(substring(plyermodel,-4,4) != ".zym")
194         if(substring(plyermodel,-4,4) != ".dpm")
195         if(substring(plyermodel,-4,4) != ".iqm")
196         if(substring(plyermodel,-4,4) != ".md3")
197         if(substring(plyermodel,-4,4) != ".psk")
198                 return FallbackPlayerModel;
199         // forbid the LOD models
200         if(substring(plyermodel, -9,5) == "_lod1")
201                 return FallbackPlayerModel;
202         if(substring(plyermodel, -9,5) == "_lod2")
203                 return FallbackPlayerModel;
204         if(plyermodel != strtolower(plyermodel))
205                 return FallbackPlayerModel;
206         // also, restrict to server models
207         if(autocvar_sv_servermodelsonly)
208         {
209                 if(!fexists(plyermodel))
210                         return FallbackPlayerModel;
211         }
212         return plyermodel;
213 }
214
215 void setplayermodel(entity e, string modelname)
216 {
217         precache_model(modelname);
218         _setmodel(e, modelname);
219         player_setupanimsformodel(e);
220         if(!autocvar_g_debug_globalsounds)
221                 UpdatePlayerSounds(e);
222 }
223
224 /** putting a client as observer in the server */
225 void PutObserverInServer(entity this)
226 {
227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
228         PlayerState_detach(this);
229
230         if (IS_PLAYER(this))
231         {
232                 if(this.health >= 1)
233                 {
234                         // despawn effect
235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
236                 }
237
238                 // was a player, recount votes and ready status
239                 if(IS_REAL_CLIENT(this))
240                 {
241                         if (vote_called) { VoteCount(false); }
242                         ReadyCount();
243                 }
244     }
245
246     {
247         entity spot = SelectSpawnPoint(this, true);
248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
249         this.angles = vec2(spot.angles);
250         this.fixangle = true;
251         // offset it so that the spectator spawns higher off the ground, looks better this way
252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
253         if (IS_REAL_CLIENT(this))
254         {
255             msg_entity = this;
256             WriteByte(MSG_ONE, SVC_SETVIEW);
257             WriteEntity(MSG_ONE, this);
258         }
259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
261         if(!autocvar_g_debug_globalsounds)
262         {
263                 // needed for player sounds
264                 this.model = "";
265                 FixPlayermodel(this);
266         }
267         setmodel(this, MDL_Null);
268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
269         this.view_ofs = '0 0 0';
270     }
271
272     RemoveGrapplingHooks(this);
273         Portal_ClearAll(this);
274         Unfreeze(this);
275         SetSpectatee(this, NULL);
276
277         if (this.alivetime)
278         {
279                 if (!warmup_stage)
280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
281                 this.alivetime = 0;
282         }
283
284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
285
286         WaypointSprite_PlayerDead(this);
287
288         if (mutator_returnvalue) {
289             // mutator prevents resetting teams+score
290         } else {
291                 Player_SetTeamIndex(this, -1);
292                 this.frags = FRAGS_SPECTATOR;
293         PlayerScore_Clear(this);  // clear scores when needed
294     }
295
296         if (CS(this).killcount != FRAGS_SPECTATOR)
297         {
298                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
299                 if(!game_stopped)
300                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
301                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
302
303                 if(!CS(this).just_joined)
304                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
305                 else
306                         CS(this).just_joined = false;
307         }
308
309         accuracy_resend(this);
310
311         CS(this).spectatortime = time;
312         if(this.bot_attack)
313                 IL_REMOVE(g_bot_targets, this);
314         this.bot_attack = false;
315         if(this.monster_attack)
316                 IL_REMOVE(g_monster_targets, this);
317         this.monster_attack = false;
318     STAT(HUD, this) = HUD_NORMAL;
319         TRANSMUTE(Observer, this);
320         this.iscreature = false;
321         this.teleportable = TELEPORT_SIMPLE;
322         if(this.damagedbycontents)
323                 IL_REMOVE(g_damagedbycontents, this);
324         this.damagedbycontents = false;
325         this.health = FRAGS_SPECTATOR;
326         SetSpectatee_status(this, etof(this));
327         this.takedamage = DAMAGE_NO;
328         this.solid = SOLID_NOT;
329         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
330         this.flags = FL_CLIENT | FL_NOTARGET;
331         this.armorvalue = 666;
332         this.effects = 0;
333         this.armorvalue = autocvar_g_balance_armor_start;
334         this.pauserotarmor_finished = 0;
335         this.pauserothealth_finished = 0;
336         this.pauseregen_finished = 0;
337         this.damageforcescale = 0;
338         this.death_time = 0;
339         this.respawn_flags = 0;
340         this.respawn_time = 0;
341         STAT(RESPAWN_TIME, this) = 0;
342         this.alpha = 0;
343         this.scale = 0;
344         this.fade_time = 0;
345         this.pain_frame = 0;
346         this.pain_finished = 0;
347         this.strength_finished = 0;
348         this.invincible_finished = 0;
349         this.superweapons_finished = 0;
350         this.dphitcontentsmask = 0;
351         this.pushltime = 0;
352         this.istypefrag = 0;
353         setthink(this, func_null);
354         this.nextthink = 0;
355         this.deadflag = DEAD_NO;
356         this.crouch = false;
357         STAT(REVIVE_PROGRESS, this) = 0;
358         this.revival_time = 0;
359
360         this.items = 0;
361         STAT(WEAPONS, this) = '0 0 0';
362         this.drawonlytoclient = this;
363
364         this.viewloc = NULL;
365
366         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
367
368         this.weaponmodel = "";
369         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
370         {
371                 this.weaponentities[slot] = NULL;
372         }
373         this.exteriorweaponentity = NULL;
374         CS(this).killcount = FRAGS_SPECTATOR;
375         this.velocity = '0 0 0';
376         this.avelocity = '0 0 0';
377         this.punchangle = '0 0 0';
378         this.punchvector = '0 0 0';
379         this.oldvelocity = this.velocity;
380         this.fire_endtime = -1;
381         this.event_damage = func_null;
382
383         for(int slot = 0; slot < MAX_AXH; ++slot)
384         {
385                 entity axh = this.(AuxiliaryXhair[slot]);
386                 this.(AuxiliaryXhair[slot]) = NULL;
387
388                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
389                         delete(axh);
390         }
391 }
392
393 int player_getspecies(entity this)
394 {
395         get_model_parameters(this.model, this.skin);
396         int s = get_model_parameters_species;
397         get_model_parameters(string_null, 0);
398         if (s < 0) return SPECIES_HUMAN;
399         return s;
400 }
401
402 .float model_randomizer;
403 void FixPlayermodel(entity player)
404 {
405         string defaultmodel = "";
406         int defaultskin = 0;
407         if(autocvar_sv_defaultcharacter)
408         {
409                 if(teamplay)
410                 {
411                         switch(player.team)
412                         {
413                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
414                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
415                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
416                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
417                         }
418                 }
419
420                 if(defaultmodel == "")
421                 {
422                         defaultmodel = autocvar_sv_defaultplayermodel;
423                         defaultskin = autocvar_sv_defaultplayerskin;
424                 }
425
426                 int n = tokenize_console(defaultmodel);
427                 if(n > 0)
428                 {
429                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
430                         // However, do NOT randomize if the player-selected model is in the list.
431                         for (int i = 0; i < n; ++i)
432                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
433                                         defaultmodel = argv(i);
434                 }
435
436                 int i = strstrofs(defaultmodel, ":", 0);
437                 if(i >= 0)
438                 {
439                         defaultskin = stof(substring(defaultmodel, i+1, -1));
440                         defaultmodel = substring(defaultmodel, 0, i);
441                 }
442         }
443         if(autocvar_sv_defaultcharacterskin && !defaultskin)
444         {
445                 if(teamplay)
446                 {
447                         switch(player.team)
448                         {
449                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
450                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
451                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
452                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
453                         }
454                 }
455
456                 if(!defaultskin)
457                         defaultskin = autocvar_sv_defaultplayerskin;
458         }
459
460         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
461         defaultmodel = M_ARGV(0, string);
462         defaultskin = M_ARGV(1, int);
463
464         bool chmdl = false;
465         int oldskin;
466         if(defaultmodel != "")
467         {
468                 if (defaultmodel != player.model)
469                 {
470                         vector m1 = player.mins;
471                         vector m2 = player.maxs;
472                         setplayermodel (player, defaultmodel);
473                         setsize (player, m1, m2);
474                         chmdl = true;
475                 }
476
477                 oldskin = player.skin;
478                 player.skin = defaultskin;
479         } else {
480                 if (player.playermodel != player.model || player.playermodel == "")
481                 {
482                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
483                         vector m1 = player.mins;
484                         vector m2 = player.maxs;
485                         setplayermodel (player, player.playermodel);
486                         setsize (player, m1, m2);
487                         chmdl = true;
488                 }
489
490                 if(!autocvar_sv_defaultcharacterskin)
491                 {
492                         oldskin = player.skin;
493                         player.skin = stof(player.playerskin);
494                 }
495                 else
496                 {
497                         oldskin = player.skin;
498                         player.skin = defaultskin;
499                 }
500         }
501
502         if(chmdl || oldskin != player.skin) // model or skin has changed
503         {
504                 player.species = player_getspecies(player); // update species
505                 if(!autocvar_g_debug_globalsounds)
506                         UpdatePlayerSounds(player); // update skin sounds
507         }
508
509         if(!teamplay)
510                 if(strlen(autocvar_sv_defaultplayercolors))
511                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
512                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
513 }
514
515 void PutPlayerInServer(entity this)
516 {
517         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
518
519         PlayerState_attach(this);
520         accuracy_resend(this);
521
522         if (this.team < 0)
523                 TeamBalance_JoinBestTeam(this, true);
524
525         entity spot = SelectSpawnPoint(this, false);
526         if (!spot) {
527                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
528                 return; // spawn failed
529         }
530
531         TRANSMUTE(Player, this);
532
533         CS(this).wasplayer = true;
534         this.iscreature = true;
535         this.teleportable = TELEPORT_NORMAL;
536         if(!this.damagedbycontents)
537                 IL_PUSH(g_damagedbycontents, this);
538         this.damagedbycontents = true;
539         set_movetype(this, MOVETYPE_WALK);
540         this.solid = SOLID_SLIDEBOX;
541         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
542         if (autocvar_g_playerclip_collisions)
543                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
544         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
545                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
546         this.frags = FRAGS_PLAYER;
547         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
548         this.flags = FL_CLIENT | FL_PICKUPITEMS;
549         if (autocvar__notarget)
550                 this.flags |= FL_NOTARGET;
551         this.takedamage = DAMAGE_AIM;
552         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
553
554         if (warmup_stage) {
555                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
556                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
557                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
558                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
559                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
560                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
561                 this.health = warmup_start_health;
562                 this.armorvalue = warmup_start_armorvalue;
563                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
564         } else {
565                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
566                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
567                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
568                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
569                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
570                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
571                 this.health = start_health;
572                 this.armorvalue = start_armorvalue;
573                 STAT(WEAPONS, this) = start_weapons;
574                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
575                 {
576                         GiveRandomWeapons(this, random_start_weapons_count,
577                                 autocvar_g_random_start_weapons, random_start_ammo);
578                 }
579         }
580         SetSpectatee_status(this, 0);
581
582         PS(this).dual_weapons = '0 0 0';
583
584         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
585
586         this.items = start_items;
587
588         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
589         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
590         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
591         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
592         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
593         if (!sv_ready_restart_after_countdown && time < game_starttime)
594         {
595                 float f = game_starttime - time;
596                 this.spawnshieldtime += f;
597                 this.pauserotarmor_finished += f;
598                 this.pauserothealth_finished += f;
599                 this.pauseregen_finished += f;
600         }
601
602         this.damageforcescale = 2;
603         this.death_time = 0;
604         this.respawn_flags = 0;
605         this.respawn_time = 0;
606         STAT(RESPAWN_TIME, this) = 0;
607         this.scale = autocvar_sv_player_scale;
608         this.fade_time = 0;
609         this.pain_frame = 0;
610         this.pain_finished = 0;
611         this.pushltime = 0;
612         setthink(this, func_null); // players have no think function
613         this.nextthink = 0;
614         this.dmg_team = 0;
615         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
616
617         this.deadflag = DEAD_NO;
618
619         this.angles = spot.angles;
620         this.angles_z = 0; // never spawn tilted even if the spot says to
621         if (IS_BOT_CLIENT(this))
622                 this.v_angle = this.angles;
623         this.fixangle = true; // turn this way immediately
624         this.oldvelocity = this.velocity = '0 0 0';
625         this.avelocity = '0 0 0';
626         this.punchangle = '0 0 0';
627         this.punchvector = '0 0 0';
628
629         this.strength_finished = 0;
630         this.invincible_finished = 0;
631         this.fire_endtime = -1;
632         STAT(REVIVE_PROGRESS, this) = 0;
633         this.revival_time = 0;
634
635         this.air_finished = time + 12;
636         this.waterlevel = WATERLEVEL_NONE;
637         this.watertype = CONTENT_EMPTY;
638
639         entity spawnevent = new_pure(spawnevent);
640         spawnevent.owner = this;
641         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
642
643         // Cut off any still running player sounds.
644         stopsound(this, CH_PLAYER_SINGLE);
645
646         this.model = "";
647         FixPlayermodel(this);
648         this.drawonlytoclient = NULL;
649
650         this.viewloc = NULL;
651
652         for(int slot = 0; slot < MAX_AXH; ++slot)
653         {
654                 entity axh = this.(AuxiliaryXhair[slot]);
655                 this.(AuxiliaryXhair[slot]) = NULL;
656
657                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
658                         delete(axh);
659         }
660
661         this.spawnpoint_targ = NULL;
662
663         this.crouch = false;
664         this.view_ofs = STAT(PL_VIEW_OFS, this);
665         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
666         this.spawnorigin = spot.origin;
667         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
668         // don't reset back to last position, even if new position is stuck in solid
669         this.oldorigin = this.origin;
670         if(this.conveyor)
671                 IL_REMOVE(g_conveyed, this);
672         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
673         STAT(HUD, this) = HUD_NORMAL;
674
675         this.event_damage = PlayerDamage;
676
677         if(!this.bot_attack)
678                 IL_PUSH(g_bot_targets, this);
679         this.bot_attack = true;
680         if(!this.monster_attack)
681                 IL_PUSH(g_monster_targets, this);
682         this.monster_attack = true;
683         navigation_dynamicgoal_init(this, false);
684
685         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
686
687         // player was spectator
688         if (CS(this).killcount == FRAGS_SPECTATOR) {
689                 PlayerScore_Clear(this);
690                 CS(this).killcount = 0;
691                 CS(this).startplaytime = time;
692         }
693
694         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
695         {
696                 .entity weaponentity = weaponentities[slot];
697                 entity oldwep = this.(weaponentity);
698                 CL_SpawnWeaponentity(this, weaponentity);
699                 if(oldwep && oldwep.owner == this)
700                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
701         }
702         this.alpha = default_player_alpha;
703         this.colormod = '1 1 1' * autocvar_g_player_brightness;
704         this.exteriorweaponentity.alpha = default_weapon_alpha;
705
706         this.speedrunning = false;
707
708         target_voicescript_clear(this);
709
710         // reset fields the weapons may use
711         FOREACH(Weapons, true, {
712                 it.wr_resetplayer(it, this);
713                         // reload all reloadable weapons
714                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
715                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
716                         {
717                                 .entity weaponentity = weaponentities[slot];
718                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
719                         }
720                 }
721         });
722
723         {
724                 string s = spot.target;
725                 spot.target = string_null;
726                 SUB_UseTargets(spot, this, NULL);
727                 spot.target = s;
728         }
729
730         Unfreeze(this);
731
732         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
733
734         if (autocvar_spawn_debug)
735         {
736                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
737                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
738         }
739
740         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
741         {
742                 .entity weaponentity = weaponentities[slot];
743                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
744                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
745                 else
746                         this.(weaponentity).m_switchweapon = WEP_Null;
747                 this.(weaponentity).m_weapon = WEP_Null;
748                 this.(weaponentity).weaponname = "";
749                 this.(weaponentity).m_switchingweapon = WEP_Null;
750                 this.(weaponentity).cnt = -1;
751         }
752
753         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
754
755         if (!warmup_stage && !this.alivetime)
756                 this.alivetime = time;
757
758         antilag_clear(this, CS(this));
759 }
760
761 /** Called when a client spawns in the server */
762 void PutClientInServer(entity this)
763 {
764         if (IS_BOT_CLIENT(this)) {
765                 TRANSMUTE(Player, this);
766         } else if (IS_REAL_CLIENT(this)) {
767                 msg_entity = this;
768                 WriteByte(MSG_ONE, SVC_SETVIEW);
769                 WriteEntity(MSG_ONE, this);
770         }
771         if (game_stopped)
772                 TRANSMUTE(Observer, this);
773
774         SetSpectatee(this, NULL);
775
776         // reset player keys
777         if(PS(this))
778                 PS(this).itemkeys = 0;
779
780         MUTATOR_CALLHOOK(PutClientInServer, this);
781
782         if (IS_OBSERVER(this)) {
783                 PutObserverInServer(this);
784         } else if (IS_PLAYER(this)) {
785                 PutPlayerInServer(this);
786         }
787 }
788
789 // TODO do we need all these fields, or should we stop autodetecting runtime
790 // changes and just have a console command to update this?
791 bool ClientInit_SendEntity(entity this, entity to, int sf)
792 {
793         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
794         return = true;
795         msg_entity = to;
796         // MSG_INIT replacement
797         // TODO: make easier to use
798         Registry_send_all();
799         W_PROP_reload(MSG_ONE, to);
800         ClientInit_misc(this);
801         MUTATOR_CALLHOOK(Ent_Init);
802 }
803 void ClientInit_misc(entity this)
804 {
805         int channel = MSG_ONE;
806         WriteHeader(channel, ENT_CLIENT_INIT);
807         WriteByte(channel, g_nexball_meter_period * 32);
808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
810         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
811         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
814         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
815         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
816
817         if(sv_foginterval && world.fog != "")
818                 WriteString(channel, world.fog);
819         else
820                 WriteString(channel, "");
821         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
822         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
823         WriteByte(channel, serverflags);
824         WriteCoord(channel, autocvar_g_trueaim_minrange);
825 }
826
827 void ClientInit_CheckUpdate(entity this)
828 {
829         this.nextthink = time;
830         if(this.count != autocvar_g_balance_armor_blockpercent)
831         {
832                 this.count = autocvar_g_balance_armor_blockpercent;
833                 this.SendFlags |= 1;
834         }
835         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
836         {
837                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
838                 this.SendFlags |= 1;
839         }
840 }
841
842 void ClientInit_Spawn()
843 {
844         entity e = new_pure(clientinit);
845         setthink(e, ClientInit_CheckUpdate);
846         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
847
848         ClientInit_CheckUpdate(e);
849 }
850
851 /*
852 =============
853 SetNewParms
854 =============
855 */
856 void SetNewParms ()
857 {
858         // initialize parms for a new player
859         parm1 = -(86400 * 366);
860
861         MUTATOR_CALLHOOK(SetNewParms);
862 }
863
864 /*
865 =============
866 SetChangeParms
867 =============
868 */
869 void SetChangeParms (entity this)
870 {
871         // save parms for level change
872         parm1 = CS(this).parm_idlesince - time;
873
874         MUTATOR_CALLHOOK(SetChangeParms);
875 }
876
877 /*
878 =============
879 DecodeLevelParms
880 =============
881 */
882 void DecodeLevelParms(entity this)
883 {
884         // load parms
885         CS(this).parm_idlesince = parm1;
886         if (CS(this).parm_idlesince == -(86400 * 366))
887                 CS(this).parm_idlesince = time;
888
889         // whatever happens, allow 60 seconds of idling directly after connect for map loading
890         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
891
892         MUTATOR_CALLHOOK(DecodeLevelParms);
893 }
894
895 /*
896 =============
897 ClientKill
898
899 Called when a client types 'kill' in the console
900 =============
901 */
902
903 .float clientkill_nexttime;
904 void ClientKill_Now_TeamChange(entity this)
905 {
906         if(this.killindicator_teamchange == -1)
907         {
908                 TeamBalance_JoinBestTeam(this, true);
909         }
910         else if(this.killindicator_teamchange == -2)
911         {
912                 if(blockSpectators)
913                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
914                 PutObserverInServer(this);
915         }
916         else
917                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
918         this.killindicator_teamchange = 0;
919 }
920
921 void ClientKill_Now(entity this)
922 {
923         if(this.vehicle)
924         {
925             vehicles_exit(this.vehicle, VHEF_RELEASE);
926             if(!this.killindicator_teamchange)
927             {
928             this.vehicle_health = -1;
929             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
930             }
931         }
932
933         if(this.killindicator && !wasfreed(this.killindicator))
934                 delete(this.killindicator);
935
936         this.killindicator = NULL;
937
938         if(this.killindicator_teamchange)
939                 ClientKill_Now_TeamChange(this);
940
941         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
942         {
943                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
944         }
945
946         // now I am sure the player IS dead
947 }
948 void KillIndicator_Think(entity this)
949 {
950         if (game_stopped)
951         {
952                 this.owner.killindicator = NULL;
953                 delete(this);
954                 return;
955         }
956
957         if (this.owner.alpha < 0 && !this.owner.vehicle)
958         {
959                 this.owner.killindicator = NULL;
960                 delete(this);
961                 return;
962         }
963
964         if(this.cnt <= 0)
965         {
966                 ClientKill_Now(this.owner);
967                 return;
968         }
969     else if(this.health == 1) // health == 1 means that it's silent
970     {
971         this.nextthink = time + 1;
972         this.cnt -= 1;
973     }
974         else
975         {
976                 if(this.cnt <= 10)
977                         setmodel(this, MDL_NUM(this.cnt));
978                 if(IS_REAL_CLIENT(this.owner))
979                 {
980                         if(this.cnt <= 10)
981                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
982                 }
983                 this.nextthink = time + 1;
984                 this.cnt -= 1;
985         }
986 }
987
988 float clientkilltime;
989 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
990 {
991         float killtime;
992         float starttime;
993
994         if (game_stopped)
995                 return;
996
997         killtime = autocvar_g_balance_kill_delay;
998
999     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1000         return;
1001     killtime = M_ARGV(1, float);
1002
1003         this.killindicator_teamchange = targetteam;
1004
1005     if(!this.killindicator)
1006         {
1007                 if(!IS_DEAD(this))
1008                 {
1009                         killtime = max(killtime, this.clientkill_nexttime - time);
1010                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1011                 }
1012
1013                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1014                 {
1015                         ClientKill_Now(this);
1016                 }
1017                 else
1018                 {
1019                         starttime = max(time, clientkilltime);
1020
1021                         this.killindicator = spawn();
1022                         this.killindicator.owner = this;
1023                         this.killindicator.scale = 0.5;
1024                         setattachment(this.killindicator, this, "");
1025                         setorigin(this.killindicator, '0 0 52');
1026                         setthink(this.killindicator, KillIndicator_Think);
1027                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1028                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1029                         this.killindicator.cnt = ceil(killtime);
1030                         this.killindicator.count = bound(0, ceil(killtime), 10);
1031                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1032
1033                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1034                         {
1035                                 it.killindicator = spawn();
1036                                 it.killindicator.owner = it;
1037                                 it.killindicator.scale = 0.5;
1038                                 setattachment(it.killindicator, it, "");
1039                                 setorigin(it.killindicator, '0 0 52');
1040                                 setthink(it.killindicator, KillIndicator_Think);
1041                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1042                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1043                                 it.killindicator.cnt = ceil(killtime);
1044                         });
1045                         this.lip = 0;
1046                 }
1047         }
1048         if(this.killindicator)
1049         {
1050                 if(targetteam == 0) // just die
1051                 {
1052                         this.killindicator.colormod = '0 0 0';
1053                         if(IS_REAL_CLIENT(this))
1054                         if(this.killindicator.cnt > 0)
1055                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1056                 }
1057                 else if(targetteam == -1) // auto
1058                 {
1059                         this.killindicator.colormod = '0 1 0';
1060                         if(IS_REAL_CLIENT(this))
1061                         if(this.killindicator.cnt > 0)
1062                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1063                 }
1064                 else if(targetteam == -2) // spectate
1065                 {
1066                         this.killindicator.colormod = '0.5 0.5 0.5';
1067                         if(IS_REAL_CLIENT(this))
1068                         if(this.killindicator.cnt > 0)
1069                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1070                 }
1071                 else
1072                 {
1073                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1074                         if(IS_REAL_CLIENT(this))
1075                         if(this.killindicator.cnt > 0)
1076                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1077                 }
1078         }
1079
1080 }
1081
1082 void ClientKill (entity this)
1083 {
1084         if(game_stopped) return;
1085         if(this.player_blocked) return;
1086         if(STAT(FROZEN, this)) return;
1087
1088         ClientKill_TeamChange(this, 0);
1089 }
1090
1091 void FixClientCvars(entity e)
1092 {
1093         // send prediction settings to the client
1094         stuffcmd(e, "\nin_bindmap 0 0\n");
1095         if(autocvar_g_antilag == 3) // client side hitscan
1096                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1097         if(autocvar_sv_gentle)
1098                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1099
1100         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1101         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1102
1103         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1104
1105         MUTATOR_CALLHOOK(FixClientCvars, e);
1106 }
1107
1108 bool findinlist_abbrev(string tofind, string list)
1109 {
1110         if(list == "" || tofind == "")
1111                 return false; // empty list or search, just return
1112
1113         // this function allows abbreviated strings!
1114         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1115         {
1116                 return true;
1117         });
1118
1119         return false;
1120 }
1121
1122 bool PlayerInIPList(entity p, string iplist)
1123 {
1124         // some safety checks (never allow local?)
1125         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1126                 return false;
1127
1128         return findinlist_abbrev(p.netaddress, iplist);
1129 }
1130
1131 bool PlayerInIDList(entity p, string idlist)
1132 {
1133         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1134         if(!p.crypto_idfp)
1135                 return false;
1136
1137         return findinlist_abbrev(p.crypto_idfp, idlist);
1138 }
1139
1140 bool PlayerInList(entity player, string list)
1141 {
1142         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1143 }
1144
1145 #ifdef DP_EXT_PRECONNECT
1146 /*
1147 =============
1148 ClientPreConnect
1149
1150 Called once (not at each match start) when a client begins a connection to the server
1151 =============
1152 */
1153 void ClientPreConnect(entity this)
1154 {
1155         if(autocvar_sv_eventlog)
1156         {
1157                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1158                         this.playerid,
1159                         etof(this),
1160                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1161                 ));
1162         }
1163 }
1164 #endif
1165
1166 string GetClientVersionMessage(entity this)
1167 {
1168         if (CS(this).version_mismatch) {
1169                 if(CS(this).version < autocvar_gameversion) {
1170                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1171                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1172                 } else {
1173                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1174                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1175                 }
1176         } else {
1177                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1178         }
1179 }
1180
1181 string getwelcomemessage(entity this)
1182 {
1183         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1184         string modifications = M_ARGV(0, string);
1185
1186         if(g_weaponarena)
1187         {
1188                 if(g_weaponarena_random)
1189                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1190                 else
1191                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1192         }
1193         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1194                 modifications = strcat(modifications, ", No start weapons");
1195         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1196                 modifications = strcat(modifications, ", Low gravity");
1197         if(g_weapon_stay && !g_cts)
1198                 modifications = strcat(modifications, ", Weapons stay");
1199         if(g_jetpack)
1200                 modifications = strcat(modifications, ", Jet pack");
1201         if(autocvar_g_powerups == 0)
1202                 modifications = strcat(modifications, ", No powerups");
1203         if(autocvar_g_powerups > 0)
1204                 modifications = strcat(modifications, ", Powerups");
1205         modifications = substring(modifications, 2, strlen(modifications) - 2);
1206
1207         string versionmessage = GetClientVersionMessage(this);
1208         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1209
1210         if(modifications != "")
1211                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1212
1213         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1214         {
1215                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1216                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1217         }
1218
1219         if (cache_mutatormsg != "") {
1220                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1221         }
1222
1223         string mutator_msg = "";
1224         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1225         mutator_msg = M_ARGV(0, string);
1226
1227         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1228
1229         string motd = autocvar_sv_motd;
1230         if (motd != "") {
1231                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1232         }
1233         return s;
1234 }
1235
1236 /**
1237 =============
1238 ClientConnect
1239
1240 Called when a client connects to the server
1241 =============
1242 */
1243 void ClientConnect(entity this)
1244 {
1245         if (Ban_MaybeEnforceBanOnce(this)) return;
1246         assert(!IS_CLIENT(this), return);
1247         this.flags |= FL_CLIENT;
1248         assert(player_count >= 0, player_count = 0);
1249
1250 #ifdef WATERMARK
1251         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1252 #endif
1253         TRANSMUTE(Client, this);
1254         CS(this).version_nagtime = time + 10 + random() * 10;
1255
1256         // identify the right forced team
1257         if (autocvar_g_campaign)
1258         {
1259                 if (IS_REAL_CLIENT(this)) // only players, not bots
1260                 {
1261                         switch (autocvar_g_campaign_forceteam)
1262                         {
1263                                 case 1: this.team_forced = NUM_TEAM_1; break;
1264                                 case 2: this.team_forced = NUM_TEAM_2; break;
1265                                 case 3: this.team_forced = NUM_TEAM_3; break;
1266                                 case 4: this.team_forced = NUM_TEAM_4; break;
1267                                 default: this.team_forced = 0;
1268                         }
1269                 }
1270         }
1271         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1272         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1273         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1274         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1275         else switch (autocvar_g_forced_team_otherwise)
1276         {
1277                 default: this.team_forced = 0; break;
1278                 case "red": this.team_forced = NUM_TEAM_1; break;
1279                 case "blue": this.team_forced = NUM_TEAM_2; break;
1280                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1281                 case "pink": this.team_forced = NUM_TEAM_4; break;
1282                 case "spectate":
1283                 case "spectator":
1284                         this.team_forced = -1;
1285                         break;
1286         }
1287         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1288
1289         int playerid_save = this.playerid;
1290         this.playerid = 0; // silent
1291         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1292         this.playerid = playerid_save;
1293
1294         TRANSMUTE(Observer, this);
1295
1296         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1297
1298         // always track bots, don't ask for cl_allow_uidtracking
1299         if (IS_BOT_CLIENT(this))
1300                 PlayerStats_GameReport_AddPlayer(this);
1301         else
1302                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1303
1304         if (autocvar_sv_eventlog)
1305                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1306
1307         LogTeamchange(this.playerid, this.team, TEAM_CHANGE_CONNECT);
1308
1309         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1310
1311         if(teamplay && IS_PLAYER(this))
1312                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1313         else
1314                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1315
1316         stuffcmd(this, clientstuff, "\n");
1317         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1318
1319         FixClientCvars(this);
1320
1321         // get version info from player
1322         stuffcmd(this, "cmd clientversion $gameversion\n");
1323
1324         // notify about available teams
1325         if (teamplay)
1326         {
1327                 entity balance = TeamBalance_CheckAllowedTeams(this);
1328                 int t = TeamBalance_GetAllowedTeams(balance);
1329                 TeamBalance_Destroy(balance);
1330                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1331         }
1332         else
1333         {
1334                 stuffcmd(this, "set _teams_available 0\n");
1335         }
1336
1337         bot_relinkplayerlist();
1338
1339         CS(this).spectatortime = time;
1340         if (blockSpectators)
1341         {
1342                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1343         }
1344
1345         CS(this).jointime = time;
1346
1347         if (IS_REAL_CLIENT(this))
1348         {
1349                 if (g_weaponarena_weapons == WEPSET(TUBA))
1350                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1351         }
1352
1353         if (!sv_foginterval && world.fog != "")
1354                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1355
1356         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1357                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1358                         send_CSQC_teamnagger();
1359
1360         CSQCMODEL_AUTOINIT(this);
1361
1362         CS(this).model_randomizer = random();
1363
1364         if (IS_REAL_CLIENT(this))
1365                 sv_notice_join(this);
1366
1367         // update physics stats (players can spawn before physics runs)
1368         Physics_UpdateStats(this);
1369
1370         IL_EACH(g_initforplayer, it.init_for_player, {
1371                 it.init_for_player(it, this);
1372         });
1373
1374         Handicap_Initialize(this);
1375
1376         MUTATOR_CALLHOOK(ClientConnect, this);
1377
1378         if (IS_REAL_CLIENT(this))
1379         {
1380                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1381                 {
1382                         CS(this).motd_actived_time = -1;
1383                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1384                 }
1385         }
1386 }
1387 /*
1388 =============
1389 ClientDisconnect
1390
1391 Called when a client disconnects from the server
1392 =============
1393 */
1394 .entity chatbubbleentity;
1395 void ClientDisconnect(entity this)
1396 {
1397         assert(IS_CLIENT(this), return);
1398
1399         PlayerStats_GameReport_FinalizePlayer(this);
1400         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1401         if (CS(this).active_minigame) part_minigame(this);
1402         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1403
1404         if (autocvar_sv_eventlog)
1405                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1406
1407         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1408
1409         if(IS_SPEC(this))
1410                 SetSpectatee(this, NULL);
1411
1412     MUTATOR_CALLHOOK(ClientDisconnect, this);
1413
1414         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1415         strfree(CS(this).weaponorder_byimpulse);
1416         ClientState_detach(this);
1417
1418         Portal_ClearAll(this);
1419
1420         Unfreeze(this);
1421
1422         RemoveGrapplingHooks(this);
1423
1424         // Here, everything has been done that requires this player to be a client.
1425
1426         this.flags &= ~FL_CLIENT;
1427
1428         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1429         if (this.killindicator) delete(this.killindicator);
1430
1431         WaypointSprite_PlayerGone(this);
1432
1433         bot_relinkplayerlist();
1434
1435         strfree(this.clientstatus);
1436         if (this.personal) delete(this.personal);
1437
1438         this.playerid = 0;
1439         ReadyCount();
1440         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1441
1442         ONREMOVE(this);
1443 }
1444
1445 void ChatBubbleThink(entity this)
1446 {
1447         this.nextthink = time;
1448         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1449         {
1450                 if(this.owner) // but why can that ever be NULL?
1451                         this.owner.chatbubbleentity = NULL;
1452                 delete(this);
1453                 return;
1454         }
1455
1456         this.mdl = "";
1457
1458         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1459         {
1460                 if ( CS(this.owner).active_minigame )
1461                         this.mdl = "models/sprites/minigame_busy.iqm";
1462                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1463                         this.mdl = "models/misc/chatbubble.spr";
1464         }
1465
1466         if ( this.model != this.mdl )
1467                 _setmodel(this, this.mdl);
1468
1469 }
1470
1471 void UpdateChatBubble(entity this)
1472 {
1473         if (this.alpha < 0)
1474                 return;
1475         // spawn a chatbubble entity if needed
1476         if (!this.chatbubbleentity)
1477         {
1478                 this.chatbubbleentity = new(chatbubbleentity);
1479                 this.chatbubbleentity.owner = this;
1480                 this.chatbubbleentity.exteriormodeltoclient = this;
1481                 setthink(this.chatbubbleentity, ChatBubbleThink);
1482                 this.chatbubbleentity.nextthink = time;
1483                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1484                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1485                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1486                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1487                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1488                 //this.chatbubbleentity.model = "";
1489                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1490         }
1491 }
1492
1493
1494 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1495 // added to the model skins
1496 /*void UpdateColorModHack()
1497 {
1498         float c;
1499         c = this.clientcolors & 15;
1500         // LordHavoc: only bothering to support white, green, red, yellow, blue
1501              if (!teamplay) this.colormod = '0 0 0';
1502         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1503         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1504         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1505         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1506         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1507         else this.colormod = '1 1 1';
1508 }*/
1509
1510 void respawn(entity this)
1511 {
1512         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1513         {
1514                 this.solid = SOLID_NOT;
1515                 this.takedamage = DAMAGE_NO;
1516                 set_movetype(this, MOVETYPE_FLY);
1517                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1518                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1519                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1520                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1521                 if(autocvar_g_respawn_ghosts_maxtime)
1522                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1523         }
1524
1525         CopyBody(this, 1);
1526
1527         this.effects |= EF_NODRAW; // prevent another CopyBody
1528         PutClientInServer(this);
1529 }
1530
1531 void PrintToChat(entity client, string text)
1532 {
1533         text = strcat("\{1}^7", text, "\n");
1534         sprint(client, text);
1535 }
1536
1537 void DebugPrintToChat(entity client, string text)
1538 {
1539         if (autocvar_developer)
1540         {
1541                 PrintToChat(client, text);
1542         }
1543 }
1544
1545 void PrintToChatAll(string text)
1546 {
1547         text = strcat("\{1}^7", text, "\n");
1548         bprint(text);
1549 }
1550
1551 void DebugPrintToChatAll(string text)
1552 {
1553         if (autocvar_developer)
1554         {
1555                 PrintToChatAll(text);
1556         }
1557 }
1558
1559 void PrintToChatTeam(int team_num, string text)
1560 {
1561         text = strcat("\{1}^7", text, "\n");
1562         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1563         {
1564                 if (it.team == team_num)
1565                 {
1566                         sprint(it, text);
1567                 }
1568         });
1569 }
1570
1571 void DebugPrintToChatTeam(int team_num, string text)
1572 {
1573         if (autocvar_developer)
1574         {
1575                 PrintToChatTeam(team_num, text);
1576         }
1577 }
1578
1579 void play_countdown(entity this, float finished, Sound samp)
1580 {
1581     TC(Sound, samp);
1582         if(IS_REAL_CLIENT(this))
1583                 if(floor(finished - time - frametime) != floor(finished - time))
1584                         if(finished - time < 6)
1585                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1586 }
1587
1588 void player_powerups(entity this)
1589 {
1590         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1591         int items_prev = this.items;
1592
1593         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1594                 this.modelflags |= MF_ROCKET;
1595         else
1596                 this.modelflags &= ~MF_ROCKET;
1597
1598         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1599
1600         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1601                 return;
1602
1603         Fire_ApplyDamage(this);
1604         Fire_ApplyEffect(this);
1605
1606         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1607         {
1608                 if (this.items & ITEM_Strength.m_itemid)
1609                 {
1610                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1611                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1612                         if (time > this.strength_finished)
1613                         {
1614                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1615                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1616                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1617                         }
1618                 }
1619                 else
1620                 {
1621                         if (time < this.strength_finished)
1622                         {
1623                                 this.items = this.items | ITEM_Strength.m_itemid;
1624                                 if(!g_cts)
1625                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1626                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1627                         }
1628                 }
1629                 if (this.items & ITEM_Shield.m_itemid)
1630                 {
1631                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1632                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1633                         if (time > this.invincible_finished)
1634                         {
1635                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1636                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1637                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1638                         }
1639                 }
1640                 else
1641                 {
1642                         if (time < this.invincible_finished)
1643                         {
1644                                 this.items = this.items | ITEM_Shield.m_itemid;
1645                                 if(!g_cts)
1646                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1647                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1648                         }
1649                 }
1650                 if (this.items & IT_SUPERWEAPON)
1651                 {
1652                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1653                         {
1654                                 this.superweapons_finished = 0;
1655                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1656                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1657                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1658                         }
1659                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1660                         {
1661                                 // don't let them run out
1662                         }
1663                         else
1664                         {
1665                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1666                                 if (time > this.superweapons_finished)
1667                                 {
1668                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1669                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1670                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1671                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1672                                 }
1673                         }
1674                 }
1675                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1676                 {
1677                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1678                         {
1679                                 this.items = this.items | IT_SUPERWEAPON;
1680                                 if(!g_cts)
1681                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1682                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1683                         }
1684                         else
1685                         {
1686                                 this.superweapons_finished = 0;
1687                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1688                         }
1689                 }
1690                 else
1691                 {
1692                         this.superweapons_finished = 0;
1693                 }
1694         }
1695
1696         if(autocvar_g_nodepthtestplayers)
1697                 this.effects = this.effects | EF_NODEPTHTEST;
1698
1699         if(autocvar_g_fullbrightplayers)
1700                 this.effects = this.effects | EF_FULLBRIGHT;
1701
1702         if (time >= game_starttime)
1703         if (time < this.spawnshieldtime)
1704                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1705
1706         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1707 }
1708
1709 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1710 {
1711         if(current > stable)
1712                 return current;
1713         else if(current > stable - 0.25) // when close enough, "snap"
1714                 return stable;
1715         else
1716                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1717 }
1718
1719 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1720 {
1721         if(current < stable)
1722                 return current;
1723         else if(current < stable + 0.25) // when close enough, "snap"
1724                 return stable;
1725         else
1726                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1727 }
1728
1729 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1730 {
1731         if(current > rotstable)
1732         {
1733                 if(rotframetime > 0)
1734                 {
1735                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1736                         current = max(rotstable, current - rotlinear * rotframetime);
1737                 }
1738         }
1739         else if(current < regenstable)
1740         {
1741                 if(regenframetime > 0)
1742                 {
1743                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1744                         current = min(regenstable, current + regenlinear * regenframetime);
1745                 }
1746         }
1747
1748         if(current > limit)
1749                 current = limit;
1750
1751         return current;
1752 }
1753
1754 void player_regen(entity this)
1755 {
1756         float max_mod, regen_mod, rot_mod, limit_mod;
1757         max_mod = regen_mod = rot_mod = limit_mod = 1;
1758
1759         float regen_health = autocvar_g_balance_health_regen;
1760         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1761         float regen_health_rot = autocvar_g_balance_health_rot;
1762         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1763         float regen_health_stable = autocvar_g_balance_health_regenstable;
1764         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1765         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1766                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1767         max_mod = M_ARGV(1, float);
1768         regen_mod = M_ARGV(2, float);
1769         rot_mod = M_ARGV(3, float);
1770         limit_mod = M_ARGV(4, float);
1771         regen_health = M_ARGV(5, float);
1772         regen_health_linear = M_ARGV(6, float);
1773         regen_health_rot = M_ARGV(7, float);
1774         regen_health_rotlinear = M_ARGV(8, float);
1775         regen_health_stable = M_ARGV(9, float);
1776         regen_health_rotstable = M_ARGV(10, float);
1777
1778         if(!mutator_returnvalue)
1779         if(!STAT(FROZEN, this))
1780         {
1781                 float mina, maxa, limith, limita;
1782                 maxa = autocvar_g_balance_armor_rotstable;
1783                 mina = autocvar_g_balance_armor_regenstable;
1784                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1785                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1786
1787                 regen_health_rotstable = regen_health_rotstable * max_mod;
1788                 regen_health_stable = regen_health_stable * max_mod;
1789                 limith = limith * limit_mod;
1790                 limita = limita * limit_mod;
1791
1792                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1793                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1794         }
1795
1796         // if player rotted to death...  die!
1797         // check this outside above checks, as player may still be able to rot to death
1798         if(this.health < 1)
1799         {
1800                 if(this.vehicle)
1801                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1802                 if(this.event_damage)
1803                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1804         }
1805
1806         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1807         {
1808                 float minf, maxf, limitf;
1809
1810                 maxf = autocvar_g_balance_fuel_rotstable;
1811                 minf = autocvar_g_balance_fuel_regenstable;
1812                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1813
1814                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1815         }
1816         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1817         // TODO: Remove this hack when all code uses GivePlayerHealth and
1818         // GivePlayerArmor.
1819         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1820         {
1821                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1822         }
1823         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1824         {
1825                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1826         }
1827         // End hack.
1828 }
1829
1830 bool zoomstate_set;
1831 void SetZoomState(entity this, float newzoom)
1832 {
1833         if(newzoom != CS(this).zoomstate)
1834         {
1835                 CS(this).zoomstate = newzoom;
1836                 ClientData_Touch(this);
1837         }
1838         zoomstate_set = true;
1839 }
1840
1841 void GetPressedKeys(entity this)
1842 {
1843         MUTATOR_CALLHOOK(GetPressedKeys, this);
1844         int keys = STAT(PRESSED_KEYS, this);
1845         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1846         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1847         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1848         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1849
1850         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1851         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1852         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1853         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1854         CS(this).pressedkeys = keys; // store for other users
1855
1856         STAT(PRESSED_KEYS, this) = keys;
1857 }
1858
1859 /*
1860 ======================
1861 spectate mode routines
1862 ======================
1863 */
1864
1865 void SpectateCopy(entity this, entity spectatee)
1866 {
1867     TC(Client, this); TC(Client, spectatee);
1868
1869         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1870         PS(this) = PS(spectatee);
1871         this.armortype = spectatee.armortype;
1872         this.armorvalue = spectatee.armorvalue;
1873         this.ammo_cells = spectatee.ammo_cells; // TODO: these will be a part of inventory, so no need to worry about setting them later!
1874         this.ammo_plasma = spectatee.ammo_plasma;
1875         this.ammo_shells = spectatee.ammo_shells;
1876         this.ammo_nails = spectatee.ammo_nails;
1877         this.ammo_rockets = spectatee.ammo_rockets;
1878         this.ammo_fuel = spectatee.ammo_fuel;
1879         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1880         this.health = spectatee.health;
1881         CS(this).impulse = 0;
1882         this.items = spectatee.items;
1883         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1884         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1885         this.strength_finished = spectatee.strength_finished;
1886         this.invincible_finished = spectatee.invincible_finished;
1887         this.superweapons_finished = spectatee.superweapons_finished;
1888         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1889         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1890         this.punchangle = spectatee.punchangle;
1891         this.view_ofs = spectatee.view_ofs;
1892         this.velocity = spectatee.velocity;
1893         this.dmg_take = spectatee.dmg_take;
1894         this.dmg_save = spectatee.dmg_save;
1895         this.dmg_inflictor = spectatee.dmg_inflictor;
1896         this.v_angle = spectatee.v_angle;
1897         this.angles = spectatee.v_angle;
1898         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1899         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1900         this.viewloc = spectatee.viewloc;
1901         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1902                 this.fixangle = true;
1903         setorigin(this, spectatee.origin);
1904         setsize(this, spectatee.mins, spectatee.maxs);
1905         SetZoomState(this, CS(spectatee).zoomstate);
1906
1907     anticheat_spectatecopy(this, spectatee);
1908         STAT(HUD, this) = STAT(HUD, spectatee);
1909         if(spectatee.vehicle)
1910     {
1911         this.angles = spectatee.v_angle;
1912
1913         //this.fixangle = false;
1914         //this.velocity = spectatee.vehicle.velocity;
1915         this.vehicle_health = spectatee.vehicle_health;
1916         this.vehicle_shield = spectatee.vehicle_shield;
1917         this.vehicle_energy = spectatee.vehicle_energy;
1918         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1919         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1920         this.vehicle_reload1 = spectatee.vehicle_reload1;
1921         this.vehicle_reload2 = spectatee.vehicle_reload2;
1922
1923         //msg_entity = this;
1924
1925        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1926             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1927            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1928            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1929
1930         //WriteByte (MSG_ONE, SVC_SETVIEW);
1931         //    WriteEntity(MSG_ONE, this);
1932         //makevectors(spectatee.v_angle);
1933         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1934     }
1935 }
1936
1937 bool SpectateUpdate(entity this)
1938 {
1939         if(!this.enemy)
1940                 return false;
1941
1942         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1943         {
1944                 SetSpectatee(this, NULL);
1945                 return false;
1946         }
1947
1948         SpectateCopy(this, this.enemy);
1949
1950         return true;
1951 }
1952
1953 bool SpectateSet(entity this)
1954 {
1955         if(!IS_PLAYER(this.enemy))
1956                 return false;
1957
1958         ClientData_Touch(this.enemy);
1959
1960         msg_entity = this;
1961         WriteByte(MSG_ONE, SVC_SETVIEW);
1962         WriteEntity(MSG_ONE, this.enemy);
1963         set_movetype(this, MOVETYPE_NONE);
1964         accuracy_resend(this);
1965
1966         if(!SpectateUpdate(this))
1967                 PutObserverInServer(this);
1968
1969         return true;
1970 }
1971
1972 void SetSpectatee_status(entity this, int spectatee_num)
1973 {
1974         int oldspectatee_status = CS(this).spectatee_status;
1975         CS(this).spectatee_status = spectatee_num;
1976
1977         if (CS(this).spectatee_status != oldspectatee_status)
1978         {
1979                 ClientData_Touch(this);
1980                 if (g_race || g_cts) race_InitSpectator();
1981         }
1982 }
1983
1984 void SetSpectatee(entity this, entity spectatee)
1985 {
1986         if(IS_BOT_CLIENT(this))
1987                 return; // bots abuse .enemy, this code is useless to them
1988
1989         entity old_spectatee = this.enemy;
1990
1991         this.enemy = spectatee;
1992
1993         // WEAPONTODO
1994         // these are required to fix the spectator bug with arc
1995         if(old_spectatee)
1996         {
1997                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1998                 {
1999                         .entity weaponentity = weaponentities[slot];
2000                         if(old_spectatee.(weaponentity).arc_beam)
2001                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
2002                 }
2003         }
2004         if(this.enemy)
2005         {
2006                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2007                 {
2008                         .entity weaponentity = weaponentities[slot];
2009                         if(this.enemy.(weaponentity).arc_beam)
2010                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
2011                 }
2012         }
2013
2014         if (this.enemy)
2015                 SetSpectatee_status(this, etof(this.enemy));
2016
2017         // needed to update spectator list
2018         if(old_spectatee) { ClientData_Touch(old_spectatee); }
2019 }
2020
2021 bool Spectate(entity this, entity pl)
2022 {
2023         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
2024                 return false;
2025         pl = M_ARGV(1, entity);
2026
2027         SetSpectatee(this, pl);
2028         return SpectateSet(this);
2029 }
2030
2031 bool SpectateNext(entity this)
2032 {
2033         entity ent = find(this.enemy, classname, STR_PLAYER);
2034
2035         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2036                 ent = M_ARGV(1, entity);
2037         else if (!ent)
2038                 ent = find(ent, classname, STR_PLAYER);
2039
2040         if(ent) { SetSpectatee(this, ent); }
2041
2042         return SpectateSet(this);
2043 }
2044
2045 bool SpectatePrev(entity this)
2046 {
2047         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2048         entity ent = findchain(classname, STR_PLAYER);
2049         if (!ent) // no player
2050                 return false;
2051
2052         entity first = ent;
2053         // skip players until current spectated player
2054         if(this.enemy)
2055         while(ent && ent != this.enemy)
2056                 ent = ent.chain;
2057
2058         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2059         {
2060                 case MUT_SPECPREV_FOUND:
2061                     ent = M_ARGV(1, entity);
2062                     break;
2063                 case MUT_SPECPREV_RETURN:
2064                     return true;
2065                 case MUT_SPECPREV_CONTINUE:
2066                 default:
2067                 {
2068                         if(ent.chain)
2069                                 ent = ent.chain;
2070                         else
2071                                 ent = first;
2072                         break;
2073                 }
2074         }
2075
2076         SetSpectatee(this, ent);
2077         return SpectateSet(this);
2078 }
2079
2080 /*
2081 =============
2082 ShowRespawnCountdown()
2083
2084 Update a respawn countdown display.
2085 =============
2086 */
2087 void ShowRespawnCountdown(entity this)
2088 {
2089         float number;
2090         if(!IS_DEAD(this)) // just respawned?
2091                 return;
2092         else
2093         {
2094                 number = ceil(this.respawn_time - time);
2095                 if(number <= 0)
2096                         return;
2097                 if(number <= this.respawn_countdown)
2098                 {
2099                         this.respawn_countdown = number - 1;
2100                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2101                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2102                 }
2103         }
2104 }
2105
2106 .bool team_selected;
2107 bool ShowTeamSelection(entity this)
2108 {
2109         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2110                 return false;
2111         stuffcmd(this, "menu_showteamselect\n");
2112         return true;
2113 }
2114 void Join(entity this)
2115 {
2116         TRANSMUTE(Player, this);
2117
2118         if(!this.team_selected)
2119         if(autocvar_g_campaign || autocvar_g_balance_teams)
2120                 TeamBalance_JoinBestTeam(this, true);
2121
2122         if(autocvar_g_campaign)
2123                 campaign_bots_may_start = true;
2124
2125         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2126
2127         PutClientInServer(this);
2128
2129         if(IS_PLAYER(this))
2130         if(teamplay && this.team != -1)
2131         {
2132                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2133         }
2134         else
2135                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2136         this.team_selected = false;
2137 }
2138
2139 /**
2140  * Determines whether the player is allowed to join. This depends on cvar
2141  * g_maxplayers, if it isn't used this function always return true, otherwise
2142  * it checks whether the number of currently playing players exceeds g_maxplayers.
2143  * @return int number of free slots for players, 0 if none
2144  */
2145 int nJoinAllowed(entity this, entity ignore)
2146 {
2147         if(!ignore)
2148         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2149         // so report 0 free slots if restricted
2150         {
2151                 if(autocvar_g_forced_team_otherwise == "spectate")
2152                         return 0;
2153                 if(autocvar_g_forced_team_otherwise == "spectator")
2154                         return 0;
2155         }
2156
2157         if(this && this.team_forced < 0)
2158                 return 0; // forced spectators can never join
2159
2160         // TODO simplify this
2161         int totalClients = 0;
2162         int currentlyPlaying = 0;
2163         FOREACH_CLIENT(true, {
2164                 if(it != ignore)
2165                         ++totalClients;
2166                 if(IS_REAL_CLIENT(it))
2167                 if(IS_PLAYER(it) || it.caplayer)
2168                         ++currentlyPlaying;
2169         });
2170
2171         float free_slots = 0;
2172         if (!autocvar_g_maxplayers)
2173                 free_slots = maxclients - totalClients;
2174         else if(currentlyPlaying < autocvar_g_maxplayers)
2175                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2176
2177         static float join_prevent_msg_time = 0;
2178         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2179         {
2180                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2181                 join_prevent_msg_time = time + 3;
2182         }
2183
2184         return free_slots;
2185 }
2186
2187 /**
2188  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2189  * g_maxplayers_spectator_blocktime seconds
2190  */
2191 void checkSpectatorBlock(entity this)
2192 {
2193         if(IS_SPEC(this) || IS_OBSERVER(this))
2194         if(!this.caplayer)
2195         if(IS_REAL_CLIENT(this))
2196         {
2197                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2198                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2199                         dropclient(this);
2200                 }
2201         }
2202 }
2203
2204 void PrintWelcomeMessage(entity this)
2205 {
2206         if(CS(this).motd_actived_time == 0)
2207         {
2208                 if (autocvar_g_campaign) {
2209                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2210                                 CS(this).motd_actived_time = time;
2211                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2212                         }
2213                 } else {
2214                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2215                                 CS(this).motd_actived_time = time;
2216                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2217                         }
2218                 }
2219         }
2220         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2221         {
2222                 if (autocvar_g_campaign) {
2223                         if (PHYS_INPUT_BUTTON_INFO(this))
2224                                 CS(this).motd_actived_time = time;
2225                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2226                                 CS(this).motd_actived_time = 0;
2227                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2228                         }
2229                 } else {
2230                         if (PHYS_INPUT_BUTTON_INFO(this))
2231                                 CS(this).motd_actived_time = time;
2232                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2233                                 CS(this).motd_actived_time = 0;
2234                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2235                         }
2236                 }
2237         }
2238         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2239         {
2240                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2241                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2242                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2243                 {
2244                         // instanctly hide MOTD
2245                         CS(this).motd_actived_time = 0;
2246                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2247                 }
2248         }
2249 }
2250
2251 const int MIN_SPEC_TIME = 1;
2252 bool joinAllowed(entity this)
2253 {
2254         if (CS(this).version_mismatch) return false;
2255         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2256         if (!nJoinAllowed(this, this)) return false;
2257         if (teamplay && lockteams) return false;
2258         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2259         if (ShowTeamSelection(this)) return false;
2260         return true;
2261 }
2262
2263 .int items_added;
2264 .string shootfromfixedorigin;
2265 bool PlayerThink(entity this)
2266 {
2267         if (game_stopped || intermission_running) {
2268                 this.modelflags &= ~MF_ROCKET;
2269                 if(intermission_running)
2270                         IntermissionThink(this);
2271                 return false;
2272         }
2273
2274         if (timeout_status == TIMEOUT_ACTIVE) {
2275         // don't allow the player to turn around while game is paused
2276                 // FIXME turn this into CSQC stuff
2277                 this.v_angle = this.lastV_angle;
2278                 this.angles = this.lastV_angle;
2279                 this.fixangle = true;
2280         }
2281
2282         if (frametime) player_powerups(this);
2283
2284         if (IS_DEAD(this)) {
2285                 if (this.personal && g_race_qualifying) {
2286                         if (time > this.respawn_time) {
2287                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2288                                 respawn(this);
2289                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2290                         }
2291                 } else {
2292                         if (frametime) player_anim(this);
2293
2294                         if (this.respawn_flags & RESPAWN_DENY)
2295                         {
2296                                 STAT(RESPAWN_TIME, this) = 0;
2297                                 return false;
2298                         }
2299
2300                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2301
2302                         switch(this.deadflag)
2303                         {
2304                                 case DEAD_DYING:
2305                                 {
2306                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2307                                                 this.deadflag = DEAD_RESPAWNING;
2308                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2309                                                 this.deadflag = DEAD_DEAD;
2310                                         break;
2311                                 }
2312                                 case DEAD_DEAD:
2313                                 {
2314                                         if (button_pressed)
2315                                                 this.deadflag = DEAD_RESPAWNABLE;
2316                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2317                                                 this.deadflag = DEAD_RESPAWNING;
2318                                         break;
2319                                 }
2320                                 case DEAD_RESPAWNABLE:
2321                                 {
2322                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2323                                                 this.deadflag = DEAD_RESPAWNING;
2324                                         break;
2325                                 }
2326                                 case DEAD_RESPAWNING:
2327                                 {
2328                                         if (time > this.respawn_time)
2329                                         {
2330                                                 this.respawn_time = time + 1; // only retry once a second
2331                                                 this.respawn_time_max = this.respawn_time;
2332                                                 respawn(this);
2333                                         }
2334                                         break;
2335                                 }
2336                         }
2337
2338                         ShowRespawnCountdown(this);
2339
2340                         if (this.respawn_flags & RESPAWN_SILENT)
2341                                 STAT(RESPAWN_TIME, this) = 0;
2342                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2343                         {
2344                                 if (time < this.respawn_time)
2345                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2346                                 else if (this.deadflag != DEAD_RESPAWNING)
2347                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2348                         }
2349                         else
2350                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2351                 }
2352
2353                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2354                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2355                         STAT(RESPAWN_TIME, this) *= -1;
2356
2357                 return false;
2358         }
2359
2360         FixPlayermodel(this);
2361
2362         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2363                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2364                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2365         }
2366
2367         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2368         //if(frametime)
2369         {
2370                 this.items &= ~this.items_added;
2371
2372                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2373                 {
2374                         .entity weaponentity = weaponentities[slot];
2375                         W_WeaponFrame(this, weaponentity);
2376                 }
2377
2378                 this.items_added = 0;
2379                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2380             this.items_added |= IT_FUEL;
2381
2382                 this.items |= this.items_added;
2383         }
2384
2385         player_regen(this);
2386
2387         // WEAPONTODO: Add a weapon request for this
2388         // rot vortex charge to the charge limit
2389         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2390         {
2391                 .entity weaponentity = weaponentities[slot];
2392                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2393                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2394         }
2395
2396         if (frametime) player_anim(this);
2397
2398         // secret status
2399         secrets_setstatus(this);
2400
2401         // monsters status
2402         monsters_setstatus(this);
2403
2404         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2405
2406         return true;
2407 }
2408
2409 .bool would_spectate;
2410 void ObserverThink(entity this)
2411 {
2412         if ( CS(this).impulse )
2413         {
2414                 MinigameImpulse(this, CS(this).impulse);
2415                 CS(this).impulse = 0;
2416         }
2417
2418         if (this.flags & FL_JUMPRELEASED) {
2419                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2420                         this.flags &= ~FL_JUMPRELEASED;
2421                         this.flags |= FL_SPAWNING;
2422                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2423                         this.flags &= ~FL_JUMPRELEASED;
2424                         if(SpectateNext(this)) {
2425                                 TRANSMUTE(Spectator, this);
2426                         }
2427                 } else {
2428                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2429                         set_movetype(this, preferred_movetype);
2430                 }
2431         } else {
2432                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2433                         this.flags |= FL_JUMPRELEASED;
2434                         if(this.flags & FL_SPAWNING)
2435                         {
2436                                 this.flags &= ~FL_SPAWNING;
2437                                 Join(this);
2438                                 return;
2439                         }
2440                 }
2441         }
2442 }
2443
2444 void SpectatorThink(entity this)
2445 {
2446         if ( CS(this).impulse )
2447         {
2448                 if(MinigameImpulse(this, CS(this).impulse))
2449                         CS(this).impulse = 0;
2450
2451                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2452                 {
2453                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2454                         CS(this).impulse = 0;
2455                         return;
2456                 }
2457         }
2458
2459         if (this.flags & FL_JUMPRELEASED) {
2460                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2461                         this.flags &= ~FL_JUMPRELEASED;
2462                         this.flags |= FL_SPAWNING;
2463                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2464                         this.flags &= ~FL_JUMPRELEASED;
2465                         if(SpectateNext(this)) {
2466                                 TRANSMUTE(Spectator, this);
2467                         } else {
2468                                 TRANSMUTE(Observer, this);
2469                                 PutClientInServer(this);
2470                         }
2471                         CS(this).impulse = 0;
2472                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2473                         this.flags &= ~FL_JUMPRELEASED;
2474                         if(SpectatePrev(this)) {
2475                                 TRANSMUTE(Spectator, this);
2476                         } else {
2477                                 TRANSMUTE(Observer, this);
2478                                 PutClientInServer(this);
2479                         }
2480                         CS(this).impulse = 0;
2481                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2482                         this.would_spectate = false;
2483                         this.flags &= ~FL_JUMPRELEASED;
2484                         TRANSMUTE(Observer, this);
2485                         PutClientInServer(this);
2486                 } else {
2487                         if(!SpectateUpdate(this))
2488                         {
2489                                 if(!SpectateNext(this))
2490                                 {
2491                                         PutObserverInServer(this);
2492                                         this.would_spectate = true;
2493                                 }
2494                         }
2495                 }
2496         } else {
2497                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2498                         this.flags |= FL_JUMPRELEASED;
2499                         if(this.flags & FL_SPAWNING)
2500                         {
2501                                 this.flags &= ~FL_SPAWNING;
2502                                 Join(this);
2503                                 return;
2504                         }
2505                 }
2506                 if(!SpectateUpdate(this))
2507                         PutObserverInServer(this);
2508         }
2509
2510         this.flags |= FL_CLIENT | FL_NOTARGET;
2511 }
2512
2513 void PlayerUseKey(entity this)
2514 {
2515         if (!IS_PLAYER(this))
2516                 return;
2517
2518         if(this.vehicle)
2519         {
2520                 if(!game_stopped)
2521                 {
2522                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2523                         return;
2524                 }
2525         }
2526         else if(autocvar_g_vehicles_enter)
2527         {
2528                 if(!STAT(FROZEN, this))
2529                 if(!IS_DEAD(this))
2530                 if(!game_stopped)
2531                 {
2532                         entity head, closest_target = NULL;
2533                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2534
2535                         while(head) // find the closest acceptable target to enter
2536                         {
2537                                 if(IS_VEHICLE(head))
2538                                 if(!IS_DEAD(head))
2539                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2540                                 if(head.takedamage != DAMAGE_NO)
2541                                 {
2542                                         if(closest_target)
2543                                         {
2544                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2545                                                 { closest_target = head; }
2546                                         }
2547                                         else { closest_target = head; }
2548                                 }
2549
2550                                 head = head.chain;
2551                         }
2552
2553                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2554                 }
2555         }
2556
2557         // a use key was pressed; call handlers
2558         MUTATOR_CALLHOOK(PlayerUseKey, this);
2559 }
2560
2561
2562 /*
2563 =============
2564 PlayerPreThink
2565
2566 Called every frame for each client before the physics are run
2567 =============
2568 */
2569 .float last_vehiclecheck;
2570 void PlayerPreThink (entity this)
2571 {
2572         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2573         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2574
2575         WarpZone_PlayerPhysics_FixVAngle(this);
2576
2577         if (frametime) {
2578                 // physics frames: update anticheat stuff
2579                 anticheat_prethink(this);
2580         }
2581
2582         if (blockSpectators && frametime) {
2583                 // WORKAROUND: only use dropclient in server frames (frametime set).
2584                 // Never use it in cl_movement frames (frametime zero).
2585                 checkSpectatorBlock(this);
2586         }
2587
2588         zoomstate_set = false;
2589
2590         // Check for nameless players
2591         if (this.netname == "" || this.netname != CS(this).netname_previous)
2592         {
2593                 bool assume_unchanged = (CS(this).netname_previous == "");
2594                 if (isInvisibleString(this.netname))
2595                 {
2596                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2597                         assume_unchanged = false;
2598                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2599                 }
2600                 if (!assume_unchanged && autocvar_sv_eventlog)
2601                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2602                 strcpy(CS(this).netname_previous, this.netname);
2603         }
2604
2605         // version nagging
2606         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2607         CS(this).version_nagtime = 0;
2608         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2609             // git client
2610         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2611             // git server
2612             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2613         } else {
2614             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2615             if (r < 0) { // old client
2616                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2617             } else if (r > 0) { // old server
2618                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2619             }
2620         }
2621     }
2622
2623         // GOD MODE info
2624         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2625         {
2626                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2627                 this.max_armorvalue = 0;
2628         }
2629
2630         if(IS_PLAYER(this))
2631         {
2632                 if (STAT(FROZEN, this) == 2)
2633                 {
2634                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2635                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2636                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2637
2638                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2639                                 Unfreeze(this);
2640                 }
2641                 else if (STAT(FROZEN, this) == 3)
2642                 {
2643                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2644                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2645
2646                         if (this.health < 1)
2647                         {
2648                                 if (this.vehicle)
2649                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2650                                 if(this.event_damage)
2651                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2652                         }
2653                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2654                                 Unfreeze(this);
2655                 }
2656         }
2657
2658         MUTATOR_CALLHOOK(PlayerPreThink, this);
2659
2660         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2661         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2662         {
2663                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2664                 {
2665                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2666                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2667                         {
2668                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2669                         }
2670                         else if(!it.owner)
2671                         {
2672                                 if(!it.team || SAME_TEAM(this, it))
2673                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2674                                 else if(autocvar_g_vehicles_steal)
2675                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2676                         }
2677                 });
2678
2679                 this.last_vehiclecheck = time + 1;
2680         }
2681
2682         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2683         {
2684                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2685                         PlayerUseKey(this);
2686                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2687         }
2688
2689         if (IS_REAL_CLIENT(this))
2690                 PrintWelcomeMessage(this);
2691
2692         if (IS_PLAYER(this)) {
2693                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2694                         error("Client can't be spawned as player on connection!");
2695                 if(!PlayerThink(this))
2696                         return;
2697         }
2698         else if (game_stopped || intermission_running) {
2699                 if(intermission_running)
2700                         IntermissionThink(this);
2701                 return;
2702         }
2703         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2704         {
2705                 CS(this).autojoin_checked = true;
2706                 // don't do this in ClientConnect
2707                 // many things can go wrong if a client is spawned as player on connection
2708                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2709                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2710                                 && (!teamplay || autocvar_g_balance_teams)))
2711                 {
2712                         campaign_bots_may_start = true;
2713                         Join(this);
2714                         return;
2715                 }
2716         }
2717         else if (IS_OBSERVER(this)) {
2718                 ObserverThink(this);
2719         }
2720         else if (IS_SPEC(this)) {
2721                 SpectatorThink(this);
2722         }
2723
2724         // WEAPONTODO: Add weapon request for this
2725         if (!zoomstate_set) {
2726                 bool wep_zoomed = false;
2727                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2728                 {
2729                         .entity weaponentity = weaponentities[slot];
2730                         Weapon thiswep = this.(weaponentity).m_weapon;
2731                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2732                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2733                 }
2734                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2735     }
2736
2737         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2738         {
2739                 CS(this).teamkill_soundtime = 0;
2740
2741                 entity e = CS(this).teamkill_soundsource;
2742                 entity oldpusher = e.pusher;
2743                 e.pusher = this;
2744                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2745                 e.pusher = oldpusher;
2746         }
2747
2748         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2749                 CS(this).taunt_soundtime = 0;
2750                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2751         }
2752
2753         target_voicescript_next(this);
2754
2755         // WEAPONTODO: Move into weaponsystem somehow
2756         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2757         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2758         {
2759                 .entity weaponentity = weaponentities[slot];
2760                 if(this.(weaponentity).m_weapon == WEP_Null)
2761                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2762         }
2763 }
2764
2765 void DrownPlayer(entity this)
2766 {
2767         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2768                 return;
2769
2770         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2771         {
2772                 if(this.air_finished < time)
2773                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2774                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2775         }
2776         else if (this.air_finished < time)
2777         {       // drown!
2778                 if (this.pain_finished < time)
2779                 {
2780                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2781                         this.pain_finished = time + 0.5;
2782                 }
2783         }
2784 }
2785
2786 .bool move_qcphysics;
2787
2788 void Player_Physics(entity this)
2789 {
2790         set_movetype(this, this.move_movetype);
2791
2792         if(!this.move_qcphysics)
2793                 return;
2794
2795         if(!frametime && !CS(this).pm_frametime)
2796                 return;
2797
2798         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2799
2800         CS(this).pm_frametime = 0;
2801 }
2802
2803 /*
2804 =============
2805 PlayerPostThink
2806
2807 Called every frame for each client after the physics are run
2808 =============
2809 */
2810 void PlayerPostThink (entity this)
2811 {
2812         Player_Physics(this);
2813
2814         if (sv_maxidle > 0)
2815         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2816         if (IS_REAL_CLIENT(this))
2817         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2818         {
2819                 int totalClients = 0;
2820                 if(sv_maxidle_slots > 0)
2821                 {
2822                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2823                         {
2824                                 ++totalClients;
2825                         });
2826                 }
2827
2828                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2829                 { /* do nothing */ }
2830                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2831                 {
2832                         if (CS(this).idlekick_lasttimeleft)
2833                         {
2834                                 CS(this).idlekick_lasttimeleft = 0;
2835                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2836                         }
2837                 }
2838                 else
2839                 {
2840                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2841                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2842                                 if (!CS(this).idlekick_lasttimeleft)
2843                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2844                         }
2845                         if (timeleft <= 0) {
2846                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2847                                 dropclient(this);
2848                                 return;
2849                         }
2850                         else if (timeleft <= 10) {
2851                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2852                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2853                 }
2854                                 CS(this).idlekick_lasttimeleft = timeleft;
2855                         }
2856                 }
2857         }
2858
2859         CheatFrame(this);
2860
2861         if (game_stopped)
2862         {
2863                 this.solid = SOLID_NOT;
2864                 this.takedamage = DAMAGE_NO;
2865                 set_movetype(this, MOVETYPE_NONE);
2866         }
2867
2868         if (IS_PLAYER(this)) {
2869                 if(this.death_time == time && IS_DEAD(this))
2870                 {
2871                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2872                         // once all the damage events of this frame have been processed with normal size
2873                         this.maxs.z = 5;
2874                         setsize(this, this.mins, this.maxs);
2875                 }
2876                 DrownPlayer(this);
2877                 UpdateChatBubble(this);
2878                 if (CS(this).impulse) ImpulseCommands(this);
2879                 if (game_stopped)
2880                 {
2881                         CSQCMODEL_AUTOUPDATE(this);
2882                         return;
2883                 }
2884                 GetPressedKeys(this);
2885         }
2886
2887         if (this.waypointsprite_attachedforcarrier) {
2888             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2889                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2890     }
2891
2892         playerdemo_write(this);
2893
2894         CSQCMODEL_AUTOUPDATE(this);
2895 }
2896
2897 // hack to copy the button fields from the client entity to the Client State
2898 void PM_UpdateButtons(entity this, entity store)
2899 {
2900         if(this.impulse)
2901                 store.impulse = this.impulse;
2902         this.impulse = 0;
2903
2904         bool typing = this.buttonchat;
2905
2906         store.button0 = (typing) ? 0 : this.button0;
2907         //button1?!
2908         store.button2 = (typing) ? 0 : this.button2;
2909         store.button3 = (typing) ? 0 : this.button3;
2910         store.button4 = this.button4;
2911         store.button5 = (typing) ? 0 : this.button5;
2912         store.button6 = this.button6;
2913         store.button7 = this.button7;
2914         store.button8 = this.button8;
2915         store.button9 = this.button9;
2916         store.button10 = this.button10;
2917         store.button11 = this.button11;
2918         store.button12 = this.button12;
2919         store.button13 = this.button13;
2920         store.button14 = this.button14;
2921         store.button15 = this.button15;
2922         store.button16 = this.button16;
2923         store.buttonuse = this.buttonuse;
2924         store.buttonchat = this.buttonchat;
2925
2926         store.cursor_active = this.cursor_active;
2927         store.cursor_screen = this.cursor_screen;
2928         store.cursor_trace_start = this.cursor_trace_start;
2929         store.cursor_trace_endpos = this.cursor_trace_endpos;
2930         store.cursor_trace_ent = this.cursor_trace_ent;
2931
2932         store.ping = this.ping;
2933         store.ping_packetloss = this.ping_packetloss;
2934         store.ping_movementloss = this.ping_movementloss;
2935
2936         store.v_angle = this.v_angle;
2937         store.movement = (typing) ? '0 0 0' : this.movement;
2938 }
2939
2940 NET_HANDLE(fpsreport, bool)
2941 {
2942         int fps = ReadShort();
2943         PlayerScore_Set(sender, SP_FPS, fps);
2944         return true;
2945 }