qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "cheats.qh"
  20 #include "g_world.qh"
  21 #include "race.qh"
  22 #include "antilag.qh"
  23 #include "campaign.qh"
  24 #include "command/common.qh"
  25 #include "scores_rules.qh"
  26
  27 #include "bot/api.qh"
  28
  29 #include "../common/ent_cs.qh"
  30 #include "../common/wepent.qh"
  31 #include <common/state.qh>
  32
  33 #include <common/effects/qc/globalsound.qh>
  34
  35 #include "../common/triggers/func/conveyor.qh"
  36 #include "../common/triggers/teleporters.qh"
  37
  38 #include "../common/vehicles/all.qh"
  39
  40 #include "weapons/hitplot.qh"
  41 #include "weapons/weaponsystem.qh"
  42
  43 #include "../common/net_notice.qh"
  44 #include "../common/net_linked.qh"
  45 #include "../common/physics/player.qh"
  46
  47 #include "../common/items/_mod.qh"
  48
  49 #include "../common/mutators/mutator/waypoints/all.qh"
  50
  51 #include "../common/triggers/subs.qh"
  52 #include "../common/triggers/triggers.qh"
  53 #include "../common/triggers/trigger/secret.qh"
  54
  55 #include "../common/minigames/sv_minigames.qh"
  56
  57 #include "../common/items/inventory.qh"
  58
  59 #include "../common/monsters/sv_monsters.qh"
  60
  61 #include "../lib/warpzone/server.qh"
  62
  63 #include <common/mutators/mutator/overkill/okvortex.qh>
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this) && this.health >= 1) {
 225         // despawn effect
 226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 227     }
 228
 229     {
 230         entity spot = SelectSpawnPoint(this, true);
 231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 232         this.angles = vec2(spot.angles);
 233         this.fixangle = true;
 234         // offset it so that the spectator spawns higher off the ground, looks better this way
 235         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (CS(this).killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(!CS(this).just_joined)
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 else
 289                         CS(this).just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         CS(this).spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         CS(this).killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357
 358         for(int slot = 0; slot < MAX_AXH; ++slot)
 359         {
 360                 entity axh = this.(AuxiliaryXhair[slot]);
 361                 this.(AuxiliaryXhair[slot]) = NULL;
 362
 363                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 364                         delete(axh);
 365         }
 366 }
 367
 368 int player_getspecies(entity this)
 369 {
 370         get_model_parameters(this.model, this.skin);
 371         int s = get_model_parameters_species;
 372         get_model_parameters(string_null, 0);
 373         if (s < 0) return SPECIES_HUMAN;
 374         return s;
 375 }
 376
 377 .float model_randomizer;
 378 void FixPlayermodel(entity player)
 379 {
 380         string defaultmodel = "";
 381         int defaultskin = 0;
 382         if(autocvar_sv_defaultcharacter)
 383         {
 384                 if(teamplay)
 385                 {
 386                         switch(player.team)
 387                         {
 388                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 389                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 390                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 391                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 392                         }
 393                 }
 394
 395                 if(defaultmodel == "")
 396                 {
 397                         defaultmodel = autocvar_sv_defaultplayermodel;
 398                         defaultskin = autocvar_sv_defaultplayerskin;
 399                 }
 400
 401                 int n = tokenize_console(defaultmodel);
 402                 if(n > 0)
 403                 {
 404                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 405                         // However, do NOT randomize if the player-selected model is in the list.
 406                         for (int i = 0; i < n; ++i)
 407                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 408                                         defaultmodel = argv(i);
 409                 }
 410
 411                 int i = strstrofs(defaultmodel, ":", 0);
 412                 if(i >= 0)
 413                 {
 414                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 415                         defaultmodel = substring(defaultmodel, 0, i);
 416                 }
 417         }
 418         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 419         {
 420                 if(teamplay)
 421                 {
 422                         switch(player.team)
 423                         {
 424                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 425                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 426                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 427                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 428                         }
 429                 }
 430
 431                 if(!defaultskin)
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433         }
 434
 435         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 436         defaultmodel = M_ARGV(0, string);
 437         defaultskin = M_ARGV(1, int);
 438
 439         bool chmdl = false;
 440         int oldskin;
 441         if(defaultmodel != "")
 442         {
 443                 if (defaultmodel != player.model)
 444                 {
 445                         vector m1 = player.mins;
 446                         vector m2 = player.maxs;
 447                         setplayermodel (player, defaultmodel);
 448                         setsize (player, m1, m2);
 449                         chmdl = true;
 450                 }
 451
 452                 oldskin = player.skin;
 453                 player.skin = defaultskin;
 454         } else {
 455                 if (player.playermodel != player.model || player.playermodel == "")
 456                 {
 457                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 458                         vector m1 = player.mins;
 459                         vector m2 = player.maxs;
 460                         setplayermodel (player, player.playermodel);
 461                         setsize (player, m1, m2);
 462                         chmdl = true;
 463                 }
 464
 465                 if(!autocvar_sv_defaultcharacterskin)
 466                 {
 467                         oldskin = player.skin;
 468                         player.skin = stof(player.playerskin);
 469                 }
 470                 else
 471                 {
 472                         oldskin = player.skin;
 473                         player.skin = defaultskin;
 474                 }
 475         }
 476
 477         if(chmdl || oldskin != player.skin) // model or skin has changed
 478         {
 479                 player.species = player_getspecies(player); // update species
 480                 if(!autocvar_g_debug_globalsounds)
 481                         UpdatePlayerSounds(player); // update skin sounds
 482         }
 483
 484         if(!teamplay)
 485                 if(strlen(autocvar_sv_defaultplayercolors))
 486                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 487                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 488 }
 489
 490 void PutPlayerInServer(entity this)
 491 {
 492         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 493
 494         PlayerState_attach(this);
 495         accuracy_resend(this);
 496
 497         if (this.team < 0)
 498                 JoinBestTeam(this, false, true);
 499
 500         entity spot = SelectSpawnPoint(this, false);
 501         if (!spot) {
 502                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 503                 return; // spawn failed
 504         }
 505
 506         TRANSMUTE(Player, this);
 507
 508         CS(this).wasplayer = true;
 509         this.iscreature = true;
 510         this.teleportable = TELEPORT_NORMAL;
 511         if(!this.damagedbycontents)
 512                 IL_PUSH(g_damagedbycontents, this);
 513         this.damagedbycontents = true;
 514         set_movetype(this, MOVETYPE_WALK);
 515         this.solid = SOLID_SLIDEBOX;
 516         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 517         if (autocvar_g_playerclip_collisions)
 518                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 519         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 520                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 521         this.frags = FRAGS_PLAYER;
 522         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 523         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 524         if (autocvar__notarget)
 525                 this.flags |= FL_NOTARGET;
 526         this.takedamage = DAMAGE_AIM;
 527         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 528         this.dmg = 2; // WTF
 529
 530         if (warmup_stage) {
 531                 this.ammo_shells = warmup_start_ammo_shells;
 532                 this.ammo_nails = warmup_start_ammo_nails;
 533                 this.ammo_rockets = warmup_start_ammo_rockets;
 534                 this.ammo_cells = warmup_start_ammo_cells;
 535                 this.ammo_plasma = warmup_start_ammo_plasma;
 536                 this.ammo_fuel = warmup_start_ammo_fuel;
 537                 this.health = warmup_start_health;
 538                 this.armorvalue = warmup_start_armorvalue;
 539                 this.weapons = WARMUP_START_WEAPONS;
 540         } else {
 541                 this.ammo_shells = start_ammo_shells;
 542                 this.ammo_nails = start_ammo_nails;
 543                 this.ammo_rockets = start_ammo_rockets;
 544                 this.ammo_cells = start_ammo_cells;
 545                 this.ammo_plasma = start_ammo_plasma;
 546                 this.ammo_fuel = start_ammo_fuel;
 547                 this.health = start_health;
 548                 this.armorvalue = start_armorvalue;
 549                 this.weapons = start_weapons;
 550         }
 551         SetSpectatee_status(this, 0);
 552
 553         PS(this).dual_weapons = '0 0 0';
 554
 555         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 556
 557         this.items = start_items;
 558
 559         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 560         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 561         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 562         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 563         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 564         // extend the pause of rotting if client was reset at the beginning of the countdown
 565         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 566                 float f = game_starttime - time;
 567                 this.spawnshieldtime += f;
 568                 this.pauserotarmor_finished += f;
 569                 this.pauserothealth_finished += f;
 570                 this.pauseregen_finished += f;
 571         }
 572         this.damageforcescale = 2;
 573         this.death_time = 0;
 574         this.respawn_flags = 0;
 575         this.respawn_time = 0;
 576         this.stat_respawn_time = 0;
 577         this.scale = autocvar_sv_player_scale;
 578         this.fade_time = 0;
 579         this.pain_frame = 0;
 580         this.pain_finished = 0;
 581         this.pushltime = 0;
 582         setthink(this, func_null); // players have no think function
 583         this.nextthink = 0;
 584         this.dmg_team = 0;
 585         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 586
 587         this.deadflag = DEAD_NO;
 588
 589         this.angles = spot.angles;
 590         this.angles_z = 0; // never spawn tilted even if the spot says to
 591         if (IS_BOT_CLIENT(this))
 592                 this.v_angle = this.angles;
 593         this.fixangle = true; // turn this way immediately
 594         this.oldvelocity = this.velocity = '0 0 0';
 595         this.avelocity = '0 0 0';
 596         this.punchangle = '0 0 0';
 597         this.punchvector = '0 0 0';
 598
 599         this.strength_finished = 0;
 600         this.invincible_finished = 0;
 601         this.fire_endtime = -1;
 602         this.revive_progress = 0;
 603         this.revival_time = 0;
 604         this.air_finished = time + 12;
 605
 606         entity spawnevent = new_pure(spawnevent);
 607         spawnevent.owner = this;
 608         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 609
 610         // Cut off any still running player sounds.
 611         stopsound(this, CH_PLAYER_SINGLE);
 612
 613         this.model = "";
 614         FixPlayermodel(this);
 615         this.drawonlytoclient = NULL;
 616
 617         this.viewloc = NULL;
 618
 619         this.crouch = false;
 620         this.view_ofs = STAT(PL_VIEW_OFS, this);
 621         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 622         this.spawnorigin = spot.origin;
 623         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 624         // don't reset back to last position, even if new position is stuck in solid
 625         this.oldorigin = this.origin;
 626         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 627         if(this.conveyor)
 628                 IL_REMOVE(g_conveyed, this);
 629         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 630         this.hud = HUD_NORMAL;
 631
 632         this.event_damage = PlayerDamage;
 633
 634         if(!this.bot_attack)
 635                 IL_PUSH(g_bot_targets, this);
 636         this.bot_attack = true;
 637         if(!this.monster_attack)
 638                 IL_PUSH(g_monster_targets, this);
 639         this.monster_attack = true;
 640         navigation_dynamicgoal_init(this, false);
 641
 642         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 643
 644         if (CS(this).killcount == FRAGS_SPECTATOR) {
 645                 PlayerScore_Clear(this);
 646                 CS(this).killcount = 0;
 647         }
 648
 649         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 650         {
 651                 .entity weaponentity = weaponentities[slot];
 652                 entity oldwep = this.(weaponentity);
 653                 CL_SpawnWeaponentity(this, weaponentity);
 654                 if(oldwep && oldwep.owner == this)
 655                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 656         }
 657         this.alpha = default_player_alpha;
 658         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 659         this.exteriorweaponentity.alpha = default_weapon_alpha;
 660
 661         this.speedrunning = false;
 662
 663         target_voicescript_clear(this);
 664
 665         // reset fields the weapons may use
 666         FOREACH(Weapons, true, {
 667                 it.wr_resetplayer(it, this);
 668                         // reload all reloadable weapons
 669                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 670                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 671                         {
 672                                 .entity weaponentity = weaponentities[slot];
 673                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 674                         }
 675                 }
 676         });
 677
 678         {
 679                 string s = spot.target;
 680                 spot.target = string_null;
 681                 SUB_UseTargets(spot, this, NULL);
 682                 spot.target = s;
 683         }
 684
 685         Unfreeze(this);
 686
 687         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 688
 689         if (autocvar_spawn_debug)
 690         {
 691                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 692                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 693         }
 694
 695         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696         {
 697                 .entity weaponentity = weaponentities[slot];
 698                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 699                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 700                 else
 701                         this.(weaponentity).m_switchweapon = WEP_Null;
 702                 this.(weaponentity).m_weapon = WEP_Null;
 703                 this.(weaponentity).weaponname = "";
 704                 this.(weaponentity).m_switchingweapon = WEP_Null;
 705                 this.(weaponentity).cnt = -1;
 706         }
 707
 708         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 709
 710         if (!warmup_stage && !this.alivetime)
 711                 this.alivetime = time;
 712
 713         antilag_clear(this, CS(this));
 714 }
 715
 716 /** Called when a client spawns in the server */
 717 void PutClientInServer(entity this)
 718 {
 719         if (IS_BOT_CLIENT(this)) {
 720                 TRANSMUTE(Player, this);
 721         } else if (IS_REAL_CLIENT(this)) {
 722                 msg_entity = this;
 723                 WriteByte(MSG_ONE, SVC_SETVIEW);
 724                 WriteEntity(MSG_ONE, this);
 725         }
 726         if (game_stopped)
 727                 TRANSMUTE(Observer, this);
 728
 729         SetSpectatee(this, NULL);
 730
 731         // reset player keys
 732         if(PS(this))
 733                 PS(this).itemkeys = 0;
 734
 735         MUTATOR_CALLHOOK(PutClientInServer, this);
 736
 737         if (IS_OBSERVER(this)) {
 738                 PutObserverInServer(this);
 739         } else if (IS_PLAYER(this)) {
 740                 PutPlayerInServer(this);
 741         }
 742 }
 743
 744 void ClientInit_misc(entity this);
 745
 746 // TODO do we need all these fields, or should we stop autodetecting runtime
 747 // changes and just have a console command to update this?
 748 bool ClientInit_SendEntity(entity this, entity to, int sf)
 749 {
 750         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 751         return = true;
 752         msg_entity = to;
 753         // MSG_INIT replacement
 754         // TODO: make easier to use
 755         Registry_send_all();
 756         W_PROP_reload(MSG_ONE, to);
 757         ClientInit_misc(this);
 758         MUTATOR_CALLHOOK(Ent_Init);
 759 }
 760 void ClientInit_misc(entity this)
 761 {
 762         int channel = MSG_ONE;
 763         WriteHeader(channel, ENT_CLIENT_INIT);
 764         WriteByte(channel, g_nexball_meter_period * 32);
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 768         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 772         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 773
 774         if(sv_foginterval && world.fog != "")
 775                 WriteString(channel, world.fog);
 776         else
 777                 WriteString(channel, "");
 778         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 779         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 780         WriteByte(channel, serverflags);
 781         WriteCoord(channel, autocvar_g_trueaim_minrange);
 782 }
 783
 784 void ClientInit_CheckUpdate(entity this)
 785 {
 786         this.nextthink = time;
 787         if(this.count != autocvar_g_balance_armor_blockpercent)
 788         {
 789                 this.count = autocvar_g_balance_armor_blockpercent;
 790                 this.SendFlags |= 1;
 791         }
 792         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 793         {
 794                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 795                 this.SendFlags |= 1;
 796         }
 797 }
 798
 799 void ClientInit_Spawn()
 800 {
 801         entity e = new_pure(clientinit);
 802         setthink(e, ClientInit_CheckUpdate);
 803         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 804
 805         ClientInit_CheckUpdate(e);
 806 }
 807
 808 /*
 809 =============
 810 SetNewParms
 811 =============
 812 */
 813 void SetNewParms ()
 814 {
 815         // initialize parms for a new player
 816         parm1 = -(86400 * 366);
 817
 818         MUTATOR_CALLHOOK(SetNewParms);
 819 }
 820
 821 /*
 822 =============
 823 SetChangeParms
 824 =============
 825 */
 826 void SetChangeParms (entity this)
 827 {
 828         // save parms for level change
 829         parm1 = CS(this).parm_idlesince - time;
 830
 831         MUTATOR_CALLHOOK(SetChangeParms);
 832 }
 833
 834 /*
 835 =============
 836 DecodeLevelParms
 837 =============
 838 */
 839 void DecodeLevelParms(entity this)
 840 {
 841         // load parms
 842         CS(this).parm_idlesince = parm1;
 843         if (CS(this).parm_idlesince == -(86400 * 366))
 844                 CS(this).parm_idlesince = time;
 845
 846         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 847         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 848
 849         MUTATOR_CALLHOOK(DecodeLevelParms);
 850 }
 851
 852 /*
 853 =============
 854 ClientKill
 855
 856 Called when a client types 'kill' in the console
 857 =============
 858 */
 859
 860 .float clientkill_nexttime;
 861 void ClientKill_Now_TeamChange(entity this)
 862 {
 863         if(CS(this).killindicator_teamchange == -1)
 864         {
 865                 JoinBestTeam( this, false, true );
 866         }
 867         else if(CS(this).killindicator_teamchange == -2)
 868         {
 869                 if(blockSpectators)
 870                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 871                 PutObserverInServer(this);
 872         }
 873         else
 874                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 875         CS(this).killindicator_teamchange = 0;
 876 }
 877
 878 void ClientKill_Now(entity this)
 879 {
 880         if(this.vehicle)
 881         {
 882             vehicles_exit(this.vehicle, VHEF_RELEASE);
 883             if(!CS(this).killindicator_teamchange)
 884             {
 885             this.vehicle_health = -1;
 886             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 887             }
 888         }
 889
 890         if(this.killindicator && !wasfreed(this.killindicator))
 891                 delete(this.killindicator);
 892
 893         this.killindicator = NULL;
 894
 895         if(CS(this).killindicator_teamchange)
 896                 ClientKill_Now_TeamChange(this);
 897
 898         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 899                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 900
 901         // now I am sure the player IS dead
 902 }
 903 void KillIndicator_Think(entity this)
 904 {
 905         if (game_stopped)
 906         {
 907                 this.owner.killindicator = NULL;
 908                 delete(this);
 909                 return;
 910         }
 911
 912         if (this.owner.alpha < 0 && !this.owner.vehicle)
 913         {
 914                 this.owner.killindicator = NULL;
 915                 delete(this);
 916                 return;
 917         }
 918
 919         if(this.cnt <= 0)
 920         {
 921                 ClientKill_Now(this.owner);
 922                 return;
 923         }
 924     else if(this.health == 1) // health == 1 means that it's silent
 925     {
 926         this.nextthink = time + 1;
 927         this.cnt -= 1;
 928     }
 929         else
 930         {
 931                 if(this.cnt <= 10)
 932                         setmodel(this, MDL_NUM(this.cnt));
 933                 if(IS_REAL_CLIENT(this.owner))
 934                 {
 935                         if(this.cnt <= 10)
 936                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 937                 }
 938                 this.nextthink = time + 1;
 939                 this.cnt -= 1;
 940         }
 941 }
 942
 943 float clientkilltime;
 944 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 945 {
 946         float killtime;
 947         float starttime;
 948
 949         if (game_stopped)
 950                 return;
 951
 952         killtime = autocvar_g_balance_kill_delay;
 953
 954     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 955         return;
 956     killtime = M_ARGV(1, float);
 957
 958         CS(this).killindicator_teamchange = targetteam;
 959
 960     if(!this.killindicator)
 961         {
 962                 if(!IS_DEAD(this))
 963                 {
 964                         killtime = max(killtime, this.clientkill_nexttime - time);
 965                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 966                 }
 967
 968                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 969                 {
 970                         ClientKill_Now(this);
 971                 }
 972                 else
 973                 {
 974                         starttime = max(time, clientkilltime);
 975
 976                         this.killindicator = spawn();
 977                         this.killindicator.owner = this;
 978                         this.killindicator.scale = 0.5;
 979                         setattachment(this.killindicator, this, "");
 980                         setorigin(this.killindicator, '0 0 52');
 981                         setthink(this.killindicator, KillIndicator_Think);
 982                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 983                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 984                         this.killindicator.cnt = ceil(killtime);
 985                         this.killindicator.count = bound(0, ceil(killtime), 10);
 986                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 987
 988                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 989                         {
 990                                 it.killindicator = spawn();
 991                                 it.killindicator.owner = it;
 992                                 it.killindicator.scale = 0.5;
 993                                 setattachment(it.killindicator, it, "");
 994                                 setorigin(it.killindicator, '0 0 52');
 995                                 setthink(it.killindicator, KillIndicator_Think);
 996                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 997                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 998                                 it.killindicator.cnt = ceil(killtime);
 999                         });
1000                         this.lip = 0;
1001                 }
1002         }
1003         if(this.killindicator)
1004         {
1005                 if(targetteam == 0) // just die
1006                 {
1007                         this.killindicator.colormod = '0 0 0';
1008                         if(IS_REAL_CLIENT(this))
1009                         if(this.killindicator.cnt > 0)
1010                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1011                 }
1012                 else if(targetteam == -1) // auto
1013                 {
1014                         this.killindicator.colormod = '0 1 0';
1015                         if(IS_REAL_CLIENT(this))
1016                         if(this.killindicator.cnt > 0)
1017                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1018                 }
1019                 else if(targetteam == -2) // spectate
1020                 {
1021                         this.killindicator.colormod = '0.5 0.5 0.5';
1022                         if(IS_REAL_CLIENT(this))
1023                         if(this.killindicator.cnt > 0)
1024                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1025                 }
1026                 else
1027                 {
1028                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1029                         if(IS_REAL_CLIENT(this))
1030                         if(this.killindicator.cnt > 0)
1031                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1032                 }
1033         }
1034
1035 }
1036
1037 void ClientKill (entity this)
1038 {
1039         if(game_stopped) return;
1040         if(this.player_blocked) return;
1041         if(STAT(FROZEN, this)) return;
1042
1043         ClientKill_TeamChange(this, 0);
1044 }
1045
1046 void FixClientCvars(entity e)
1047 {
1048         // send prediction settings to the client
1049         stuffcmd(e, "\nin_bindmap 0 0\n");
1050         if(autocvar_g_antilag == 3) // client side hitscan
1051                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1052         if(autocvar_sv_gentle)
1053                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1054
1055         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1056         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1057
1058         MUTATOR_CALLHOOK(FixClientCvars, e);
1059 }
1060
1061 bool findinlist_abbrev(string tofind, string list)
1062 {
1063         if(list == "" || tofind == "")
1064                 return false; // empty list or search, just return
1065
1066         // this function allows abbreviated strings!
1067         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1068         {
1069                 return true;
1070         });
1071
1072         return false;
1073 }
1074
1075 bool PlayerInIPList(entity p, string iplist)
1076 {
1077         // some safety checks (never allow local?)
1078         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1079                 return false;
1080
1081         return findinlist_abbrev(p.netaddress, iplist);
1082 }
1083
1084 bool PlayerInIDList(entity p, string idlist)
1085 {
1086         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1087         if(!p.crypto_idfp)
1088                 return false;
1089
1090         return findinlist_abbrev(p.crypto_idfp, idlist);
1091 }
1092
1093 bool PlayerInList(entity player, string list)
1094 {
1095         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1096 }
1097
1098 #ifdef DP_EXT_PRECONNECT
1099 /*
1100 =============
1101 ClientPreConnect
1102
1103 Called once (not at each match start) when a client begins a connection to the server
1104 =============
1105 */
1106 void ClientPreConnect(entity this)
1107 {
1108         if(autocvar_sv_eventlog)
1109         {
1110                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1111                         this.playerid,
1112                         etof(this),
1113                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1114                 ));
1115         }
1116 }
1117 #endif
1118
1119 /**
1120 =============
1121 ClientConnect
1122
1123 Called when a client connects to the server
1124 =============
1125 */
1126 void ClientConnect(entity this)
1127 {
1128         if (Ban_MaybeEnforceBanOnce(this)) return;
1129         assert(!IS_CLIENT(this), return);
1130         this.flags |= FL_CLIENT;
1131         assert(player_count >= 0, player_count = 0);
1132
1133 #ifdef WATERMARK
1134         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1135 #endif
1136         TRANSMUTE(Client, this);
1137         CS(this).version_nagtime = time + 10 + random() * 10;
1138
1139         // identify the right forced team
1140         if (autocvar_g_campaign)
1141         {
1142                 if (IS_REAL_CLIENT(this)) // only players, not bots
1143                 {
1144                         switch (autocvar_g_campaign_forceteam)
1145                         {
1146                                 case 1: this.team_forced = NUM_TEAM_1; break;
1147                                 case 2: this.team_forced = NUM_TEAM_2; break;
1148                                 case 3: this.team_forced = NUM_TEAM_3; break;
1149                                 case 4: this.team_forced = NUM_TEAM_4; break;
1150                                 default: this.team_forced = 0;
1151                         }
1152                 }
1153         }
1154         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1155         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1156         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1157         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1158         else switch (autocvar_g_forced_team_otherwise)
1159         {
1160                 default: this.team_forced = 0; break;
1161                 case "red": this.team_forced = NUM_TEAM_1; break;
1162                 case "blue": this.team_forced = NUM_TEAM_2; break;
1163                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1164                 case "pink": this.team_forced = NUM_TEAM_4; break;
1165                 case "spectate":
1166                 case "spectator":
1167                         this.team_forced = -1;
1168                         break;
1169         }
1170         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1171
1172     {
1173         int id = this.playerid;
1174         this.playerid = 0; // silent
1175             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1176             this.playerid = id;
1177     }
1178
1179         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1180                 TRANSMUTE(Observer, this);
1181         } else {
1182                 if (!teamplay || autocvar_g_balance_teams) {
1183                         TRANSMUTE(Player, this);
1184                         campaign_bots_may_start = true;
1185                 } else {
1186                         TRANSMUTE(Observer, this); // do it anyway
1187                 }
1188         }
1189
1190         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1191
1192         // always track bots, don't ask for cl_allow_uidtracking
1193         if (IS_BOT_CLIENT(this))
1194                 PlayerStats_GameReport_AddPlayer(this);
1195         else
1196                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1197
1198         if (autocvar_sv_eventlog)
1199                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1200
1201         LogTeamchange(this.playerid, this.team, 1);
1202
1203         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1204
1205         CS(this).netname_previous = strzone(this.netname);
1206
1207         if(teamplay && IS_PLAYER(this))
1208                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1209         else
1210                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1211
1212         stuffcmd(this, clientstuff, "\n");
1213         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1214
1215         FixClientCvars(this);
1216
1217         // get version info from player
1218         stuffcmd(this, "cmd clientversion $gameversion\n");
1219
1220         // notify about available teams
1221         if (teamplay)
1222         {
1223                 CheckAllowedTeams(this);
1224                 int t = 0;
1225                 if (c1 >= 0) t |= BIT(0);
1226                 if (c2 >= 0) t |= BIT(1);
1227                 if (c3 >= 0) t |= BIT(2);
1228                 if (c4 >= 0) t |= BIT(3);
1229                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1230         }
1231         else
1232         {
1233                 stuffcmd(this, "set _teams_available 0\n");
1234         }
1235
1236         bot_relinkplayerlist();
1237
1238         CS(this).spectatortime = time;
1239         if (blockSpectators)
1240         {
1241                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1242         }
1243
1244         CS(this).jointime = time;
1245
1246         if (IS_REAL_CLIENT(this))
1247         {
1248                 if (g_weaponarena_weapons == WEPSET(TUBA))
1249                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1250         }
1251
1252         if (!sv_foginterval && world.fog != "")
1253                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1254
1255         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1256                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1257                         send_CSQC_teamnagger();
1258
1259         CSQCMODEL_AUTOINIT(this);
1260
1261         CS(this).model_randomizer = random();
1262
1263         if (IS_REAL_CLIENT(this))
1264                 sv_notice_join(this);
1265
1266         // update physics stats (players can spawn before physics runs)
1267         Physics_UpdateStats(this);
1268
1269         IL_EACH(g_initforplayer, it.init_for_player, {
1270                 it.init_for_player(it, this);
1271         });
1272
1273         MUTATOR_CALLHOOK(ClientConnect, this);
1274
1275         if (IS_REAL_CLIENT(this))
1276         {
1277                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1278                 {
1279                         CS(this).motd_actived_time = -1;
1280                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1281                 }
1282         }
1283 }
1284 /*
1285 =============
1286 ClientDisconnect
1287
1288 Called when a client disconnects from the server
1289 =============
1290 */
1291 .entity chatbubbleentity;
1292 void ReadyCount();
1293 void ClientDisconnect(entity this)
1294 {
1295         assert(IS_CLIENT(this), return);
1296
1297         PlayerStats_GameReport_FinalizePlayer(this);
1298         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1299         if (CS(this).active_minigame) part_minigame(this);
1300         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1301
1302         if (autocvar_sv_eventlog)
1303                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1304
1305         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1306
1307         if(IS_SPEC(this))
1308                 SetSpectatee(this, NULL);
1309
1310     MUTATOR_CALLHOOK(ClientDisconnect, this);
1311
1312         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1313         ClientState_detach(this);
1314
1315         Portal_ClearAll(this);
1316
1317         Unfreeze(this);
1318
1319         RemoveGrapplingHooks(this);
1320
1321         // Here, everything has been done that requires this player to be a client.
1322
1323         this.flags &= ~FL_CLIENT;
1324
1325         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1326         if (this.killindicator) delete(this.killindicator);
1327
1328         WaypointSprite_PlayerGone(this);
1329
1330         bot_relinkplayerlist();
1331
1332         if (this.clientstatus) strunzone(this.clientstatus);
1333         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1334         if (this.personal) delete(this.personal);
1335
1336         this.playerid = 0;
1337         ReadyCount();
1338         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1339
1340         ONREMOVE(this);
1341 }
1342
1343 void ChatBubbleThink(entity this)
1344 {
1345         this.nextthink = time;
1346         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1347         {
1348                 if(this.owner) // but why can that ever be NULL?
1349                         this.owner.chatbubbleentity = NULL;
1350                 delete(this);
1351                 return;
1352         }
1353
1354         this.mdl = "";
1355
1356         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1357         {
1358                 if ( CS(this.owner).active_minigame )
1359                         this.mdl = "models/sprites/minigame_busy.iqm";
1360                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1361                         this.mdl = "models/misc/chatbubble.spr";
1362         }
1363
1364         if ( this.model != this.mdl )
1365                 _setmodel(this, this.mdl);
1366
1367 }
1368
1369 void UpdateChatBubble(entity this)
1370 {
1371         if (this.alpha < 0)
1372                 return;
1373         // spawn a chatbubble entity if needed
1374         if (!this.chatbubbleentity)
1375         {
1376                 this.chatbubbleentity = new(chatbubbleentity);
1377                 this.chatbubbleentity.owner = this;
1378                 this.chatbubbleentity.exteriormodeltoclient = this;
1379                 setthink(this.chatbubbleentity, ChatBubbleThink);
1380                 this.chatbubbleentity.nextthink = time;
1381                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1382                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1383                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1384                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1385                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1386                 //this.chatbubbleentity.model = "";
1387                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1388         }
1389 }
1390
1391
1392 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1393 // added to the model skins
1394 /*void UpdateColorModHack()
1395 {
1396         float c;
1397         c = this.clientcolors & 15;
1398         // LordHavoc: only bothering to support white, green, red, yellow, blue
1399              if (!teamplay) this.colormod = '0 0 0';
1400         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1401         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1402         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1403         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1404         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1405         else this.colormod = '1 1 1';
1406 }*/
1407
1408 void respawn(entity this)
1409 {
1410         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1411         {
1412                 this.solid = SOLID_NOT;
1413                 this.takedamage = DAMAGE_NO;
1414                 set_movetype(this, MOVETYPE_FLY);
1415                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1416                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1417                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1418                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1419                 if(autocvar_g_respawn_ghosts_maxtime)
1420                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1421         }
1422
1423         CopyBody(this, 1);
1424
1425         this.effects |= EF_NODRAW; // prevent another CopyBody
1426         PutClientInServer(this);
1427 }
1428
1429 void play_countdown(entity this, float finished, Sound samp)
1430 {
1431     TC(Sound, samp);
1432         if(IS_REAL_CLIENT(this))
1433                 if(floor(finished - time - frametime) != floor(finished - time))
1434                         if(finished - time < 6)
1435                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1436 }
1437
1438 void player_powerups(entity this)
1439 {
1440         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1441         int items_prev = this.items;
1442
1443         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1444                 this.modelflags |= MF_ROCKET;
1445         else
1446                 this.modelflags &= ~MF_ROCKET;
1447
1448         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1449
1450         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1451                 return;
1452
1453         Fire_ApplyDamage(this);
1454         Fire_ApplyEffect(this);
1455
1456         if (!g_instagib)
1457         {
1458                 if (this.items & ITEM_Strength.m_itemid)
1459                 {
1460                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1461                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1462                         if (time > this.strength_finished)
1463                         {
1464                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1465                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1466                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1467                         }
1468                 }
1469                 else
1470                 {
1471                         if (time < this.strength_finished)
1472                         {
1473                                 this.items = this.items | ITEM_Strength.m_itemid;
1474                                 if(!g_cts)
1475                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1476                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1477                         }
1478                 }
1479                 if (this.items & ITEM_Shield.m_itemid)
1480                 {
1481                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1482                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1483                         if (time > this.invincible_finished)
1484                         {
1485                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1486                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < this.invincible_finished)
1493                         {
1494                                 this.items = this.items | ITEM_Shield.m_itemid;
1495                                 if(!g_cts)
1496                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1498                         }
1499                 }
1500                 if (this.items & IT_SUPERWEAPON)
1501                 {
1502                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1503                         {
1504                                 this.superweapons_finished = 0;
1505                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1506                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1508                         }
1509                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1510                         {
1511                                 // don't let them run out
1512                         }
1513                         else
1514                         {
1515                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1516                                 if (time > this.superweapons_finished)
1517                                 {
1518                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1519                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1520                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1521                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1522                                 }
1523                         }
1524                 }
1525                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1526                 {
1527                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1528                         {
1529                                 this.items = this.items | IT_SUPERWEAPON;
1530                                 if(!g_cts)
1531                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1532                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1533                         }
1534                         else
1535                         {
1536                                 this.superweapons_finished = 0;
1537                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1538                         }
1539                 }
1540                 else
1541                 {
1542                         this.superweapons_finished = 0;
1543                 }
1544         }
1545
1546         if(autocvar_g_nodepthtestplayers)
1547                 this.effects = this.effects | EF_NODEPTHTEST;
1548
1549         if(autocvar_g_fullbrightplayers)
1550                 this.effects = this.effects | EF_FULLBRIGHT;
1551
1552         if (time >= game_starttime)
1553         if (time < this.spawnshieldtime)
1554                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1555
1556         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1557 }
1558
1559 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1560 {
1561         if(current > stable)
1562                 return current;
1563         else if(current > stable - 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1567 }
1568
1569 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1570 {
1571         if(current < stable)
1572                 return current;
1573         else if(current < stable + 0.25) // when close enough, "snap"
1574                 return stable;
1575         else
1576                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1577 }
1578
1579 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1580 {
1581         if(current > rotstable)
1582         {
1583                 if(rotframetime > 0)
1584                 {
1585                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1586                         current = max(rotstable, current - rotlinear * rotframetime);
1587                 }
1588         }
1589         else if(current < regenstable)
1590         {
1591                 if(regenframetime > 0)
1592                 {
1593                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1594                         current = min(regenstable, current + regenlinear * regenframetime);
1595                 }
1596         }
1597
1598         if(current > limit)
1599                 current = limit;
1600
1601         return current;
1602 }
1603
1604 void player_regen(entity this)
1605 {
1606         float max_mod, regen_mod, rot_mod, limit_mod;
1607         max_mod = regen_mod = rot_mod = limit_mod = 1;
1608
1609         float regen_health = autocvar_g_balance_health_regen;
1610         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1611         float regen_health_rot = autocvar_g_balance_health_rot;
1612         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1613         float regen_health_stable = autocvar_g_balance_health_regenstable;
1614         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1615         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1616                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1617         max_mod = M_ARGV(1, float);
1618         regen_mod = M_ARGV(2, float);
1619         rot_mod = M_ARGV(3, float);
1620         limit_mod = M_ARGV(4, float);
1621         regen_health = M_ARGV(5, float);
1622         regen_health_linear = M_ARGV(6, float);
1623         regen_health_rot = M_ARGV(7, float);
1624         regen_health_rotlinear = M_ARGV(8, float);
1625         regen_health_stable = M_ARGV(9, float);
1626         regen_health_rotstable = M_ARGV(10, float);
1627
1628         if(!mutator_returnvalue)
1629         if(!STAT(FROZEN, this))
1630         {
1631                 float mina, maxa, limith, limita;
1632                 maxa = autocvar_g_balance_armor_rotstable;
1633                 mina = autocvar_g_balance_armor_regenstable;
1634                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1635                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1636
1637                 regen_health_rotstable = regen_health_rotstable * max_mod;
1638                 regen_health_stable = regen_health_stable * max_mod;
1639                 limith = limith * limit_mod;
1640                 limita = limita * limit_mod;
1641
1642                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1643                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1644         }
1645
1646         // if player rotted to death...  die!
1647         // check this outside above checks, as player may still be able to rot to death
1648         if(this.health < 1)
1649         {
1650                 if(this.vehicle)
1651                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1652                 if(this.event_damage)
1653                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1654         }
1655
1656         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1657         {
1658                 float minf, maxf, limitf;
1659
1660                 maxf = autocvar_g_balance_fuel_rotstable;
1661                 minf = autocvar_g_balance_fuel_regenstable;
1662                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1663
1664                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1665         }
1666         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1667         // TODO: Remove this hack when all code uses GivePlayerHealth and
1668         // GivePlayerArmor.
1669         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1670         {
1671                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1672         }
1673         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1674         {
1675                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1676         }
1677         // End hack.
1678 }
1679
1680 bool zoomstate_set;
1681 void SetZoomState(entity this, float newzoom)
1682 {
1683         if(newzoom != CS(this).zoomstate)
1684         {
1685                 CS(this).zoomstate = newzoom;
1686                 ClientData_Touch(this);
1687         }
1688         zoomstate_set = true;
1689 }
1690
1691 void GetPressedKeys(entity this)
1692 {
1693         MUTATOR_CALLHOOK(GetPressedKeys, this);
1694         int keys = STAT(PRESSED_KEYS, this);
1695         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1696         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1697         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1698         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1699
1700         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1701         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1702         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1703         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1704         CS(this).pressedkeys = keys; // store for other users
1705
1706         STAT(PRESSED_KEYS, this) = keys;
1707 }
1708
1709 /*
1710 ======================
1711 spectate mode routines
1712 ======================
1713 */
1714
1715 void SpectateCopy(entity this, entity spectatee)
1716 {
1717     TC(Client, this); TC(Client, spectatee);
1718
1719         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1720         PS(this) = PS(spectatee);
1721         this.armortype = spectatee.armortype;
1722         this.armorvalue = spectatee.armorvalue;
1723         this.ammo_cells = spectatee.ammo_cells;
1724         this.ammo_plasma = spectatee.ammo_plasma;
1725         this.ammo_shells = spectatee.ammo_shells;
1726         this.ammo_nails = spectatee.ammo_nails;
1727         this.ammo_rockets = spectatee.ammo_rockets;
1728         this.ammo_fuel = spectatee.ammo_fuel;
1729         this.clip_load = spectatee.clip_load;
1730         this.clip_size = spectatee.clip_size;
1731         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1732         this.health = spectatee.health;
1733         CS(this).impulse = 0;
1734         this.items = spectatee.items;
1735         this.last_pickup = spectatee.last_pickup;
1736         this.hit_time = spectatee.hit_time;
1737         this.strength_finished = spectatee.strength_finished;
1738         this.invincible_finished = spectatee.invincible_finished;
1739         this.superweapons_finished = spectatee.superweapons_finished;
1740         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1741         this.weapons = spectatee.weapons;
1742         this.vortex_charge = spectatee.vortex_charge;
1743         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1744         this.okvortex_charge = spectatee.okvortex_charge;
1745         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1746         this.hagar_load = spectatee.hagar_load;
1747         this.arc_heat_percent = spectatee.arc_heat_percent;
1748         this.minelayer_mines = spectatee.minelayer_mines;
1749         this.punchangle = spectatee.punchangle;
1750         this.view_ofs = spectatee.view_ofs;
1751         this.velocity = spectatee.velocity;
1752         this.dmg_take = spectatee.dmg_take;
1753         this.dmg_save = spectatee.dmg_save;
1754         this.dmg_inflictor = spectatee.dmg_inflictor;
1755         this.v_angle = spectatee.v_angle;
1756         this.angles = spectatee.v_angle;
1757         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1758         this.revive_progress = spectatee.revive_progress;
1759         this.viewloc = spectatee.viewloc;
1760         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1761                 this.fixangle = true;
1762         setorigin(this, spectatee.origin);
1763         setsize(this, spectatee.mins, spectatee.maxs);
1764         SetZoomState(this, CS(spectatee).zoomstate);
1765
1766         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1767         {
1768                 .entity weaponentity = weaponentities[slot];
1769                 this.(weaponentity) = spectatee.(weaponentity);
1770         }
1771
1772         for(int slot = 0; slot < MAX_AXH; ++slot)
1773         {
1774                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1775         }
1776
1777     anticheat_spectatecopy(this, spectatee);
1778         this.hud = spectatee.hud;
1779         if(spectatee.vehicle)
1780     {
1781         this.angles = spectatee.v_angle;
1782
1783         //this.fixangle = false;
1784         //this.velocity = spectatee.vehicle.velocity;
1785         this.vehicle_health = spectatee.vehicle_health;
1786         this.vehicle_shield = spectatee.vehicle_shield;
1787         this.vehicle_energy = spectatee.vehicle_energy;
1788         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1789         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1790         this.vehicle_reload1 = spectatee.vehicle_reload1;
1791         this.vehicle_reload2 = spectatee.vehicle_reload2;
1792
1793         //msg_entity = this;
1794
1795        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1796             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1797            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1798            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1799
1800         //WriteByte (MSG_ONE, SVC_SETVIEW);
1801         //    WriteEntity(MSG_ONE, this);
1802         //makevectors(spectatee.v_angle);
1803         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1804     }
1805 }
1806
1807 bool SpectateUpdate(entity this)
1808 {
1809         if(!this.enemy)
1810                 return false;
1811
1812         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1813         {
1814                 SetSpectatee(this, NULL);
1815                 return false;
1816         }
1817
1818         SpectateCopy(this, this.enemy);
1819
1820         return true;
1821 }
1822
1823 bool SpectateSet(entity this)
1824 {
1825         if(!IS_PLAYER(this.enemy))
1826                 return false;
1827
1828         ClientData_Touch(this.enemy);
1829
1830         msg_entity = this;
1831         WriteByte(MSG_ONE, SVC_SETVIEW);
1832         WriteEntity(MSG_ONE, this.enemy);
1833         set_movetype(this, MOVETYPE_NONE);
1834         accuracy_resend(this);
1835
1836         if(!SpectateUpdate(this))
1837                 PutObserverInServer(this);
1838
1839         return true;
1840 }
1841
1842 void SetSpectatee_status(entity this, int spectatee_num)
1843 {
1844         int oldspectatee_status = CS(this).spectatee_status;
1845         CS(this).spectatee_status = spectatee_num;
1846
1847         if (CS(this).spectatee_status != oldspectatee_status)
1848         {
1849                 ClientData_Touch(this);
1850                 if (g_race || g_cts) race_InitSpectator();
1851         }
1852 }
1853
1854 void SetSpectatee(entity this, entity spectatee)
1855 {
1856         if(IS_BOT_CLIENT(this))
1857                 return; // bots abuse .enemy, this code is useless to them
1858
1859         entity old_spectatee = this.enemy;
1860
1861         this.enemy = spectatee;
1862
1863         // WEAPONTODO
1864         // these are required to fix the spectator bug with arc
1865         if(old_spectatee)
1866         {
1867                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1868                 {
1869                         .entity weaponentity = weaponentities[slot];
1870                         if(old_spectatee.(weaponentity).arc_beam)
1871                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1872                 }
1873         }
1874         if(this.enemy)
1875         {
1876                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1877                 {
1878                         .entity weaponentity = weaponentities[slot];
1879                         if(this.enemy.(weaponentity).arc_beam)
1880                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1881                 }
1882         }
1883
1884         if (this.enemy)
1885                 SetSpectatee_status(this, etof(this.enemy));
1886
1887         // needed to update spectator list
1888         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1889 }
1890
1891 bool Spectate(entity this, entity pl)
1892 {
1893         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1894                 return false;
1895         pl = M_ARGV(1, entity);
1896
1897         SetSpectatee(this, pl);
1898         return SpectateSet(this);
1899 }
1900
1901 bool SpectateNext(entity this)
1902 {
1903         entity ent = find(this.enemy, classname, STR_PLAYER);
1904
1905         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1906                 ent = M_ARGV(1, entity);
1907         else if (!ent)
1908                 ent = find(ent, classname, STR_PLAYER);
1909
1910         if(ent) { SetSpectatee(this, ent); }
1911
1912         return SpectateSet(this);
1913 }
1914
1915 bool SpectatePrev(entity this)
1916 {
1917         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1918         entity ent = findchain(classname, STR_PLAYER);
1919         if (!ent) // no player
1920                 return false;
1921
1922         entity first = ent;
1923         // skip players until current spectated player
1924         if(this.enemy)
1925         while(ent && ent != this.enemy)
1926                 ent = ent.chain;
1927
1928         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1929         {
1930                 case MUT_SPECPREV_FOUND:
1931                     ent = M_ARGV(1, entity);
1932                     break;
1933                 case MUT_SPECPREV_RETURN:
1934                     return true;
1935                 case MUT_SPECPREV_CONTINUE:
1936                 default:
1937                 {
1938                         if(ent.chain)
1939                                 ent = ent.chain;
1940                         else
1941                                 ent = first;
1942                         break;
1943                 }
1944         }
1945
1946         SetSpectatee(this, ent);
1947         return SpectateSet(this);
1948 }
1949
1950 /*
1951 =============
1952 ShowRespawnCountdown()
1953
1954 Update a respawn countdown display.
1955 =============
1956 */
1957 void ShowRespawnCountdown(entity this)
1958 {
1959         float number;
1960         if(!IS_DEAD(this)) // just respawned?
1961                 return;
1962         else
1963         {
1964                 number = ceil(this.respawn_time - time);
1965                 if(number <= 0)
1966                         return;
1967                 if(number <= this.respawn_countdown)
1968                 {
1969                         this.respawn_countdown = number - 1;
1970                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1971                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1972                 }
1973         }
1974 }
1975
1976 .bool team_selected;
1977 bool ShowTeamSelection(entity this)
1978 {
1979         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1980                 return false;
1981         stuffcmd(this, "menu_showteamselect\n");
1982         return true;
1983 }
1984 void Join(entity this)
1985 {
1986         TRANSMUTE(Player, this);
1987
1988         if(!this.team_selected)
1989         if(autocvar_g_campaign || autocvar_g_balance_teams)
1990                 JoinBestTeam(this, false, true);
1991
1992         if(autocvar_g_campaign)
1993                 campaign_bots_may_start = true;
1994
1995         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1996
1997         PutClientInServer(this);
1998
1999         if(IS_PLAYER(this))
2000         if(teamplay && this.team != -1)
2001                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2002         else
2003                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2004         this.team_selected = false;
2005 }
2006
2007 /**
2008  * Determines whether the player is allowed to join. This depends on cvar
2009  * g_maxplayers, if it isn't used this function always return true, otherwise
2010  * it checks whether the number of currently playing players exceeds g_maxplayers.
2011  * @return int number of free slots for players, 0 if none
2012  */
2013 int nJoinAllowed(entity this, entity ignore)
2014 {
2015         if(!ignore)
2016         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2017         // so report 0 free slots if restricted
2018         {
2019                 if(autocvar_g_forced_team_otherwise == "spectate")
2020                         return 0;
2021                 if(autocvar_g_forced_team_otherwise == "spectator")
2022                         return 0;
2023         }
2024
2025         if(this && this.team_forced < 0)
2026                 return 0; // forced spectators can never join
2027
2028         // TODO simplify this
2029         int totalClients = 0;
2030         int currentlyPlaying = 0;
2031         FOREACH_CLIENT(true, {
2032                 if(it != ignore)
2033                         ++totalClients;
2034                 if(IS_REAL_CLIENT(it))
2035                 if(IS_PLAYER(it) || it.caplayer)
2036                         ++currentlyPlaying;
2037         });
2038
2039         float free_slots = 0;
2040         if (!autocvar_g_maxplayers)
2041                 free_slots = maxclients - totalClients;
2042         else if(currentlyPlaying < autocvar_g_maxplayers)
2043                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2044
2045         static float join_prevent_msg_time = 0;
2046         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2047         {
2048                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2049                 join_prevent_msg_time = time + 3;
2050         }
2051
2052         return free_slots;
2053 }
2054
2055 /**
2056  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2057  * g_maxplayers_spectator_blocktime seconds
2058  */
2059 void checkSpectatorBlock(entity this)
2060 {
2061         if(IS_SPEC(this) || IS_OBSERVER(this))
2062         if(!this.caplayer)
2063         if(IS_REAL_CLIENT(this))
2064         {
2065                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2066                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2067                         dropclient(this);
2068                 }
2069         }
2070 }
2071
2072 void PrintWelcomeMessage(entity this)
2073 {
2074         if(CS(this).motd_actived_time == 0)
2075         {
2076                 if (autocvar_g_campaign) {
2077                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2078                                 CS(this).motd_actived_time = time;
2079                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2080                         }
2081                 } else {
2082                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2083                                 CS(this).motd_actived_time = time;
2084                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2085                         }
2086                 }
2087         }
2088         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2089         {
2090                 if (autocvar_g_campaign) {
2091                         if (PHYS_INPUT_BUTTON_INFO(this))
2092                                 CS(this).motd_actived_time = time;
2093                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2094                                 CS(this).motd_actived_time = 0;
2095                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2096                         }
2097                 } else {
2098                         if (PHYS_INPUT_BUTTON_INFO(this))
2099                                 CS(this).motd_actived_time = time;
2100                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2101                                 CS(this).motd_actived_time = 0;
2102                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2103                         }
2104                 }
2105         }
2106         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2107         {
2108                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2109                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2110                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2111                 {
2112                         // instanctly hide MOTD
2113                         CS(this).motd_actived_time = 0;
2114                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2115                 }
2116         }
2117 }
2118
2119 bool joinAllowed(entity this)
2120 {
2121         if (CS(this).version_mismatch) return false;
2122         if (!nJoinAllowed(this, this)) return false;
2123         if (teamplay && lockteams) return false;
2124         if (ShowTeamSelection(this)) return false;
2125         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2126         return true;
2127 }
2128
2129 .int items_added;
2130 bool PlayerThink(entity this)
2131 {
2132         if (game_stopped || intermission_running) {
2133                 this.modelflags &= ~MF_ROCKET;
2134                 if(intermission_running)
2135                         IntermissionThink(this);
2136                 return false;
2137         }
2138
2139         if (timeout_status == TIMEOUT_ACTIVE) {
2140         // don't allow the player to turn around while game is paused
2141                 // FIXME turn this into CSQC stuff
2142                 this.v_angle = this.lastV_angle;
2143                 this.angles = this.lastV_angle;
2144                 this.fixangle = true;
2145         }
2146
2147         if (frametime) player_powerups(this);
2148
2149         if (IS_DEAD(this)) {
2150                 if (this.personal && g_race_qualifying) {
2151                         if (time > this.respawn_time) {
2152                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2153                                 respawn(this);
2154                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2155                         }
2156                 } else {
2157                         if (frametime) player_anim(this);
2158
2159                         if (this.respawn_flags & RESPAWN_DENY)
2160                         {
2161                                 STAT(RESPAWN_TIME, this) = 0;
2162                                 return false;
2163                         }
2164
2165                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2166
2167                         switch(this.deadflag)
2168                         {
2169                                 case DEAD_DYING:
2170                                 {
2171                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2172                                                 this.deadflag = DEAD_RESPAWNING;
2173                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2174                                                 this.deadflag = DEAD_DEAD;
2175                                         break;
2176                                 }
2177                                 case DEAD_DEAD:
2178                                 {
2179                                         if (button_pressed)
2180                                                 this.deadflag = DEAD_RESPAWNABLE;
2181                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2182                                                 this.deadflag = DEAD_RESPAWNING;
2183                                         break;
2184                                 }
2185                                 case DEAD_RESPAWNABLE:
2186                                 {
2187                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2188                                                 this.deadflag = DEAD_RESPAWNING;
2189                                         break;
2190                                 }
2191                                 case DEAD_RESPAWNING:
2192                                 {
2193                                         if (time > this.respawn_time)
2194                                         {
2195                                                 this.respawn_time = time + 1; // only retry once a second
2196                                                 this.respawn_time_max = this.respawn_time;
2197                                                 respawn(this);
2198                                         }
2199                                         break;
2200                                 }
2201                         }
2202
2203                         ShowRespawnCountdown(this);
2204
2205                         if (this.respawn_flags & RESPAWN_SILENT)
2206                                 STAT(RESPAWN_TIME, this) = 0;
2207                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2208                         {
2209                                 if (time < this.respawn_time)
2210                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2211                                 else if (this.deadflag != DEAD_RESPAWNING)
2212                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2213                         }
2214                         else
2215                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2216                 }
2217
2218                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2219                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2220                         STAT(RESPAWN_TIME, this) *= -1;
2221
2222                 return false;
2223         }
2224
2225         bool have_hook = false;
2226         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2227         {
2228                 .entity weaponentity = weaponentities[slot];
2229                 if(this.(weaponentity).hook.state)
2230                 {
2231                         have_hook = true;
2232                         break;
2233                 }
2234         }
2235         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2236         if (have_hook) {
2237                 do_crouch = false;
2238         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2239                 do_crouch = false;
2240         } else if (this.vehicle) {
2241                 do_crouch = false;
2242         } else if (STAT(FROZEN, this)) {
2243                 do_crouch = false;
2244     }
2245
2246         if (do_crouch) {
2247                 if (!this.crouch) {
2248                         this.crouch = true;
2249                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2250                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2251                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2252                 }
2253         } else if (this.crouch) {
2254         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2255         if (!trace_startsolid) {
2256             this.crouch = false;
2257             this.view_ofs = STAT(PL_VIEW_OFS, this);
2258             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2259         }
2260         }
2261
2262         FixPlayermodel(this);
2263
2264         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2265         //if(frametime)
2266         {
2267                 this.items &= ~this.items_added;
2268
2269                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2270                 {
2271                         .entity weaponentity = weaponentities[slot];
2272                         W_WeaponFrame(this, weaponentity);
2273
2274                         if(slot == 0)
2275                         {
2276                                 this.clip_load = this.(weaponentity).clip_load;
2277                                 this.clip_size = this.(weaponentity).clip_size;
2278                         }
2279                 }
2280
2281                 this.items_added = 0;
2282                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2283             this.items_added |= IT_FUEL;
2284
2285                 this.items |= this.items_added;
2286         }
2287
2288         player_regen(this);
2289
2290         // WEAPONTODO: Add a weapon request for this
2291         // rot vortex charge to the charge limit
2292         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2293         {
2294                 .entity weaponentity = weaponentities[slot];
2295                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2296                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2297         }
2298
2299         if (frametime) player_anim(this);
2300
2301         // secret status
2302         secrets_setstatus(this);
2303
2304         // monsters status
2305         monsters_setstatus(this);
2306
2307         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2308
2309         return true;
2310 }
2311
2312 void ObserverThink(entity this)
2313 {
2314         if ( CS(this).impulse )
2315         {
2316                 MinigameImpulse(this, CS(this).impulse);
2317                 CS(this).impulse = 0;
2318         }
2319
2320         if (this.flags & FL_JUMPRELEASED) {
2321                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2322                         this.flags &= ~FL_JUMPRELEASED;
2323                         this.flags |= FL_SPAWNING;
2324                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2325                         this.flags &= ~FL_JUMPRELEASED;
2326                         if(SpectateNext(this)) {
2327                                 TRANSMUTE(Spectator, this);
2328                         }
2329                 } else {
2330                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2331                         set_movetype(this, preferred_movetype);
2332                 }
2333         } else {
2334                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2335                         this.flags |= FL_JUMPRELEASED;
2336                         if(this.flags & FL_SPAWNING)
2337                         {
2338                                 this.flags &= ~FL_SPAWNING;
2339                                 Join(this);
2340                                 return;
2341                         }
2342                 }
2343         }
2344 }
2345
2346 void SpectatorThink(entity this)
2347 {
2348         if ( CS(this).impulse )
2349         {
2350                 if(MinigameImpulse(this, CS(this).impulse))
2351                         CS(this).impulse = 0;
2352
2353                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2354                 {
2355                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2356                         CS(this).impulse = 0;
2357                         return;
2358                 }
2359         }
2360
2361         if (this.flags & FL_JUMPRELEASED) {
2362                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2363                         this.flags &= ~FL_JUMPRELEASED;
2364                         this.flags |= FL_SPAWNING;
2365                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2366                         this.flags &= ~FL_JUMPRELEASED;
2367                         if(SpectateNext(this)) {
2368                                 TRANSMUTE(Spectator, this);
2369                         } else {
2370                                 TRANSMUTE(Observer, this);
2371                                 PutClientInServer(this);
2372                         }
2373                         CS(this).impulse = 0;
2374                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2375                         this.flags &= ~FL_JUMPRELEASED;
2376                         if(SpectatePrev(this)) {
2377                                 TRANSMUTE(Spectator, this);
2378                         } else {
2379                                 TRANSMUTE(Observer, this);
2380                                 PutClientInServer(this);
2381                         }
2382                         CS(this).impulse = 0;
2383                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2384                         this.flags &= ~FL_JUMPRELEASED;
2385                         TRANSMUTE(Observer, this);
2386                         PutClientInServer(this);
2387                 } else {
2388                         if(!SpectateUpdate(this))
2389                                 PutObserverInServer(this);
2390                 }
2391         } else {
2392                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2393                         this.flags |= FL_JUMPRELEASED;
2394                         if(this.flags & FL_SPAWNING)
2395                         {
2396                                 this.flags &= ~FL_SPAWNING;
2397                                 Join(this);
2398                                 return;
2399                         }
2400                 }
2401                 if(!SpectateUpdate(this))
2402                         PutObserverInServer(this);
2403         }
2404
2405         this.flags |= FL_CLIENT | FL_NOTARGET;
2406 }
2407
2408 void vehicles_enter (entity pl, entity veh);
2409 void PlayerUseKey(entity this)
2410 {
2411         if (!IS_PLAYER(this))
2412                 return;
2413
2414         if(this.vehicle)
2415         {
2416                 if(!game_stopped)
2417                 {
2418                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2419                         return;
2420                 }
2421         }
2422         else if(autocvar_g_vehicles_enter)
2423         {
2424                 if(!STAT(FROZEN, this))
2425                 if(!IS_DEAD(this))
2426                 if(!game_stopped)
2427                 {
2428                         entity head, closest_target = NULL;
2429                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2430
2431                         while(head) // find the closest acceptable target to enter
2432                         {
2433                                 if(IS_VEHICLE(head))
2434                                 if(!IS_DEAD(head))
2435                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2436                                 if(head.takedamage != DAMAGE_NO)
2437                                 {
2438                                         if(closest_target)
2439                                         {
2440                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2441                                                 { closest_target = head; }
2442                                         }
2443                                         else { closest_target = head; }
2444                                 }
2445
2446                                 head = head.chain;
2447                         }
2448
2449                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2450                 }
2451         }
2452
2453         // a use key was pressed; call handlers
2454         MUTATOR_CALLHOOK(PlayerUseKey, this);
2455 }
2456
2457
2458 /*
2459 =============
2460 PlayerPreThink
2461
2462 Called every frame for each client before the physics are run
2463 =============
2464 */
2465 .float last_vehiclecheck;
2466 void PlayerPreThink (entity this)
2467 {
2468         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2469         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2470
2471         WarpZone_PlayerPhysics_FixVAngle(this);
2472
2473         if (frametime) {
2474                 // physics frames: update anticheat stuff
2475                 anticheat_prethink(this);
2476         }
2477
2478         if (blockSpectators && frametime) {
2479                 // WORKAROUND: only use dropclient in server frames (frametime set).
2480                 // Never use it in cl_movement frames (frametime zero).
2481                 checkSpectatorBlock(this);
2482     }
2483
2484         zoomstate_set = false;
2485
2486         // Check for nameless players
2487         if (isInvisibleString(this.netname)) {
2488                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2489                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2490         }
2491         if (this.netname != CS(this).netname_previous) {
2492                 if (autocvar_sv_eventlog) {
2493                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2494         }
2495                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2496                 CS(this).netname_previous = strzone(this.netname);
2497         }
2498
2499         // version nagging
2500         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2501         CS(this).version_nagtime = 0;
2502         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2503             // git client
2504         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2505             // git server
2506             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2507         } else {
2508             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2509             if (r < 0) { // old client
2510                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2511             } else if (r > 0) { // old server
2512                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2513             }
2514         }
2515     }
2516
2517         // GOD MODE info
2518         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2519         {
2520                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2521                 this.max_armorvalue = 0;
2522         }
2523
2524         if(IS_PLAYER(this))
2525         {
2526                 if (STAT(FROZEN, this) == 2)
2527                 {
2528                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2529                         this.health = max(1, this.revive_progress * start_health);
2530                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2531
2532                         if (this.revive_progress >= 1)
2533                                 Unfreeze(this);
2534                 }
2535                 else if (STAT(FROZEN, this) == 3)
2536                 {
2537                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2538                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2539
2540                         if (this.health < 1)
2541                         {
2542                                 if (this.vehicle)
2543                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2544                                 if(this.event_damage)
2545                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2546                         }
2547                         else if (this.revive_progress <= 0)
2548                                 Unfreeze(this);
2549                 }
2550         }
2551
2552         MUTATOR_CALLHOOK(PlayerPreThink, this);
2553
2554         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2555         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2556         {
2557                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2558                 {
2559                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2560                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2561                         {
2562                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2563                         }
2564                         else if(!it.owner)
2565                         {
2566                                 if(!it.team || SAME_TEAM(this, it))
2567                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2568                                 else if(autocvar_g_vehicles_steal)
2569                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2570                         }
2571                 });
2572
2573                 this.last_vehiclecheck = time + 1;
2574         }
2575
2576         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2577         {
2578                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2579                         PlayerUseKey(this);
2580                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2581         }
2582
2583         if (IS_REAL_CLIENT(this))
2584                 PrintWelcomeMessage(this);
2585
2586         if (IS_PLAYER(this)) {
2587                 if(!PlayerThink(this))
2588                         return;
2589         }
2590         else if (game_stopped || intermission_running) {
2591                 if(intermission_running)
2592                         IntermissionThink(this);
2593                 return;
2594         }
2595         else if (IS_OBSERVER(this)) {
2596                 ObserverThink(this);
2597         }
2598         else if (IS_SPEC(this)) {
2599                 SpectatorThink(this);
2600         }
2601
2602         // WEAPONTODO: Add weapon request for this
2603         if (!zoomstate_set) {
2604                 bool wep_zoomed = false;
2605                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2606                 {
2607                         .entity weaponentity = weaponentities[slot];
2608                         Weapon thiswep = this.(weaponentity).m_weapon;
2609                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2610                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2611                 }
2612                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2613     }
2614
2615         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2616         {
2617                 CS(this).teamkill_soundtime = 0;
2618
2619                 entity e = CS(this).teamkill_soundsource;
2620                 entity oldpusher = e.pusher;
2621                 e.pusher = this;
2622                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2623                 e.pusher = oldpusher;
2624         }
2625
2626         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2627                 CS(this).taunt_soundtime = 0;
2628                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2629         }
2630
2631         target_voicescript_next(this);
2632
2633         // WEAPONTODO: Move into weaponsystem somehow
2634         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2635         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2636         {
2637                 .entity weaponentity = weaponentities[slot];
2638                 if(this.(weaponentity).m_weapon == WEP_Null)
2639                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2640         }
2641 }
2642
2643 void DrownPlayer(entity this)
2644 {
2645         if(IS_DEAD(this))
2646                 return;
2647
2648         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2649         {
2650                 if(this.air_finished < time)
2651                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2652                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2653                 this.dmg = 2;
2654         }
2655         else if (this.air_finished < time)
2656         {       // drown!
2657                 if (this.pain_finished < time)
2658                 {
2659                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2660                         this.pain_finished = time + 0.5;
2661                 }
2662         }
2663 }
2664
2665 .bool move_qcphysics;
2666
2667 void Player_Physics(entity this)
2668 {
2669         set_movetype(this, this.move_movetype);
2670
2671         if(!this.move_qcphysics)
2672                 return;
2673
2674         if(!frametime && !CS(this).pm_frametime)
2675                 return;
2676
2677         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2678
2679         CS(this).pm_frametime = 0;
2680 }
2681
2682 /*
2683 =============
2684 PlayerPostThink
2685
2686 Called every frame for each client after the physics are run
2687 =============
2688 */
2689 void PlayerPostThink (entity this)
2690 {
2691         Player_Physics(this);
2692
2693         if (sv_maxidle > 0)
2694         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2695         if (IS_REAL_CLIENT(this))
2696         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2697         {
2698                 int totalClients = 0;
2699                 if(sv_maxidle_slots > 0)
2700                 {
2701                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2702                         {
2703                                 ++totalClients;
2704                         });
2705                 }
2706
2707                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2708                 { /* do nothing */ }
2709                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2710                 {
2711                         if (CS(this).idlekick_lasttimeleft)
2712                         {
2713                                 CS(this).idlekick_lasttimeleft = 0;
2714                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2715                         }
2716                 }
2717                 else
2718                 {
2719                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2720                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2721                                 if (!CS(this).idlekick_lasttimeleft)
2722                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2723                         }
2724                         if (timeleft <= 0) {
2725                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2726                                 dropclient(this);
2727                                 return;
2728                         }
2729                         else if (timeleft <= 10) {
2730                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2731                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2732                 }
2733                                 CS(this).idlekick_lasttimeleft = timeleft;
2734                         }
2735                 }
2736         }
2737
2738         CheatFrame(this);
2739
2740         if (game_stopped)
2741         {
2742                 this.solid = SOLID_NOT;
2743                 this.takedamage = DAMAGE_NO;
2744                 set_movetype(this, MOVETYPE_NONE);
2745         }
2746
2747         if (IS_PLAYER(this)) {
2748                 DrownPlayer(this);
2749                 UpdateChatBubble(this);
2750                 if (CS(this).impulse) ImpulseCommands(this);
2751                 if (game_stopped)
2752                 {
2753                         CSQCMODEL_AUTOUPDATE(this);
2754                         return;
2755                 }
2756                 GetPressedKeys(this);
2757         }
2758
2759         if (this.waypointsprite_attachedforcarrier) {
2760             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2761                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2762     }
2763
2764         playerdemo_write(this);
2765
2766         CSQCMODEL_AUTOUPDATE(this);
2767 }
2768
2769 // hack to copy the button fields from the client entity to the Client State
2770 void PM_UpdateButtons(entity this, entity store)
2771 {
2772         if(this.impulse)
2773                 store.impulse = this.impulse;
2774         this.impulse = 0;
2775
2776         store.button0 = this.button0;
2777         store.button2 = this.button2;
2778         store.button3 = this.button3;
2779         store.button4 = this.button4;
2780         store.button5 = this.button5;
2781         store.button6 = this.button6;
2782         store.button7 = this.button7;
2783         store.button8 = this.button8;
2784         store.button9 = this.button9;
2785         store.button10 = this.button10;
2786         store.button11 = this.button11;
2787         store.button12 = this.button12;
2788         store.button13 = this.button13;
2789         store.button14 = this.button14;
2790         store.button15 = this.button15;
2791         store.button16 = this.button16;
2792         store.buttonuse = this.buttonuse;
2793         store.buttonchat = this.buttonchat;
2794
2795         store.cursor_active = this.cursor_active;
2796         store.cursor_screen = this.cursor_screen;
2797         store.cursor_trace_start = this.cursor_trace_start;
2798         store.cursor_trace_endpos = this.cursor_trace_endpos;
2799         store.cursor_trace_ent = this.cursor_trace_ent;
2800
2801         store.ping = this.ping;
2802         store.ping_packetloss = this.ping_packetloss;
2803         store.ping_movementloss = this.ping_movementloss;
2804
2805         store.v_angle = this.v_angle;
2806         store.movement = this.movement;
2807 }