209958389b1fa0f5057f75c54dbec7e395991fc1
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "clientkill.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28
29 #include "bot/api.qh"
30
31 #include "../common/ent_cs.qh"
32 #include "../common/wepent.qh"
33 #include <common/state.qh>
34
35 #include "compat/quake3.qh"
36
37 #include <common/effects/qc/globalsound.qh>
38
39 #include "../common/mapobjects/func/conveyor.qh"
40 #include "../common/mapobjects/teleporters.qh"
41 #include "../common/mapobjects/target/spawnpoint.qh"
42 #include <common/mapobjects/trigger/counter.qh>
43 #include <common/mapobjects/trigger/swamp.qh>
44
45 #include "../common/vehicles/all.qh"
46
47 #include "weapons/hitplot.qh"
48 #include "weapons/weaponsystem.qh"
49
50 #include "../common/net_notice.qh"
51 #include "../common/net_linked.qh"
52 #include "../common/physics/player.qh"
53
54 #include <common/vehicles/sv_vehicles.qh>
55
56 #include "../common/items/_mod.qh"
57
58 #include "../common/mutators/mutator/waypoints/all.qh"
59 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
60 #include <common/gamemodes/_mod.qh>
61
62 #include "../common/mapobjects/subs.qh"
63 #include "../common/mapobjects/triggers.qh"
64 #include "../common/mapobjects/trigger/secret.qh"
65
66 #include "../common/minigames/sv_minigames.qh"
67
68 #include "../common/items/inventory.qh"
69
70 #include "../common/monsters/sv_monsters.qh"
71
72 #include "../lib/warpzone/server.qh"
73
74 #include <common/mutators/mutator/overkill/oknex.qh>
75
76 STATIC_METHOD(Client, Add, void(Client this, int _team))
77 {
78     ClientConnect(this);
79     TRANSMUTE(Player, this);
80     this.frame = 12; // 7
81     this.team = _team;
82     PutClientInServer(this);
83 }
84
85 STATIC_METHOD(Client, Remove, void(Client this))
86 {
87     TRANSMUTE(Observer, this);
88     PutClientInServer(this);
89     ClientDisconnect(this);
90 }
91
92 void send_CSQC_teamnagger() {
93         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
94 }
95
96 int CountSpectators(entity player, entity to)
97 {
98         if(!player) { return 0; } // not sure how, but best to be safe
99
100         int spec_count = 0;
101
102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
103         {
104                 spec_count++;
105         });
106
107         return spec_count;
108 }
109
110 void WriteSpectators(entity player, entity to)
111 {
112         if(!player) { return; } // not sure how, but best to be safe
113
114         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
115         {
116                 WriteByte(MSG_ENTITY, num_for_edict(it));
117         });
118 }
119
120 bool ClientData_Send(entity this, entity to, int sf)
121 {
122         assert(to == this.owner, return false);
123
124         entity e = to;
125         if (IS_SPEC(e)) e = e.enemy;
126
127         sf = 0;
128         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
129         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
130         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
131         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
132
133         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
134         WriteByte(MSG_ENTITY, sf);
135
136         if (sf & BIT(1))
137                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
138
139         if(sf & BIT(4))
140         {
141                 float specs = CountSpectators(e, to);
142                 WriteByte(MSG_ENTITY, specs);
143                 WriteSpectators(e, to);
144         }
145
146         return true;
147 }
148
149 void ClientData_Attach(entity this)
150 {
151         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
152         CS(this).clientdata.drawonlytoclient = this;
153         CS(this).clientdata.owner = this;
154 }
155
156 void ClientData_Detach(entity this)
157 {
158         delete(CS(this).clientdata);
159         CS(this).clientdata = NULL;
160 }
161
162 void ClientData_Touch(entity e)
163 {
164         entity cd = CS(e).clientdata;
165         if (cd) { cd.SendFlags = 1; }
166
167         // make it spectatable
168         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
169         {
170                 entity cd = CS(it).clientdata;
171                 if (cd) { cd.SendFlags = 1; }
172         });
173 }
174
175
176 /*
177 =============
178 CheckPlayerModel
179
180 Checks if the argument string can be a valid playermodel.
181 Returns a valid one in doubt.
182 =============
183 */
184 string FallbackPlayerModel;
185 string CheckPlayerModel(string plyermodel) {
186         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
187         {
188                 // note: we cannot summon Don Strunzone here, some player may
189                 // still have the model string set. In case anyone manages how
190                 // to change a cvar default, we'll have a small leak here.
191                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
192         }
193         // only in right path
194         if( substring(plyermodel,0,14) != "models/player/")
195                 return FallbackPlayerModel;
196         // only good file extensions
197         if(substring(plyermodel,-4,4) != ".zym")
198         if(substring(plyermodel,-4,4) != ".dpm")
199         if(substring(plyermodel,-4,4) != ".iqm")
200         if(substring(plyermodel,-4,4) != ".md3")
201         if(substring(plyermodel,-4,4) != ".psk")
202                 return FallbackPlayerModel;
203         // forbid the LOD models
204         if(substring(plyermodel, -9,5) == "_lod1")
205                 return FallbackPlayerModel;
206         if(substring(plyermodel, -9,5) == "_lod2")
207                 return FallbackPlayerModel;
208         if(plyermodel != strtolower(plyermodel))
209                 return FallbackPlayerModel;
210         // also, restrict to server models
211         if(autocvar_sv_servermodelsonly)
212         {
213                 if(!fexists(plyermodel))
214                         return FallbackPlayerModel;
215         }
216         return plyermodel;
217 }
218
219 void setplayermodel(entity e, string modelname)
220 {
221         precache_model(modelname);
222         _setmodel(e, modelname);
223         player_setupanimsformodel(e);
224         if(!autocvar_g_debug_globalsounds)
225                 UpdatePlayerSounds(e);
226 }
227
228 /** putting a client as observer in the server */
229 void PutObserverInServer(entity this)
230 {
231     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
232         PlayerState_detach(this);
233
234         if (IS_PLAYER(this))
235         {
236                 if(GetResource(this, RES_HEALTH) >= 1)
237                 {
238                         // despawn effect
239                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
240                 }
241
242                 // was a player, recount votes and ready status
243                 if(IS_REAL_CLIENT(this))
244                 {
245                         if (vote_called) { VoteCount(false); }
246                         ReadyCount();
247                 }
248     }
249
250     {
251         entity spot = SelectSpawnPoint(this, true);
252         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
253         this.angles = vec2(spot.angles);
254         this.fixangle = true;
255         // offset it so that the spectator spawns higher off the ground, looks better this way
256         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
257         if (IS_REAL_CLIENT(this))
258         {
259             msg_entity = this;
260             WriteByte(MSG_ONE, SVC_SETVIEW);
261             WriteEntity(MSG_ONE, this);
262         }
263         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
264         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
265         if(!autocvar_g_debug_globalsounds)
266         {
267                 // needed for player sounds
268                 this.model = "";
269                 FixPlayermodel(this);
270         }
271         setmodel(this, MDL_Null);
272         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
273         this.view_ofs = '0 0 0';
274     }
275
276     RemoveGrapplingHooks(this);
277         Portal_ClearAll(this);
278         Unfreeze(this, false);
279         SetSpectatee(this, NULL);
280
281         if (this.alivetime)
282         {
283                 if (!warmup_stage)
284                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
285                 this.alivetime = 0;
286         }
287
288         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
289
290         WaypointSprite_PlayerDead(this);
291
292         if (CS(this).killcount != FRAGS_SPECTATOR)
293         {
294                 if(!game_stopped)
295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
297         }
298
299         accuracy_resend(this);
300
301         CS(this).spectatortime = time;
302         if(this.bot_attack)
303                 IL_REMOVE(g_bot_targets, this);
304         this.bot_attack = false;
305         if(this.monster_attack)
306                 IL_REMOVE(g_monster_targets, this);
307         this.monster_attack = false;
308     STAT(HUD, this) = HUD_NORMAL;
309         TRANSMUTE(Observer, this);
310         this.iscreature = false;
311         this.teleportable = TELEPORT_SIMPLE;
312         if(this.damagedbycontents)
313                 IL_REMOVE(g_damagedbycontents, this);
314         this.damagedbycontents = false;
315         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
316         SetSpectatee_status(this, etof(this));
317         this.takedamage = DAMAGE_NO;
318         this.solid = SOLID_NOT;
319         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
320         this.flags = FL_CLIENT | FL_NOTARGET;
321         this.effects = 0;
322         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
323         this.pauserotarmor_finished = 0;
324         this.pauserothealth_finished = 0;
325         this.pauseregen_finished = 0;
326         this.damageforcescale = 0;
327         this.death_time = 0;
328         this.respawn_flags = 0;
329         this.respawn_time = 0;
330         STAT(RESPAWN_TIME, this) = 0;
331         this.alpha = 0;
332         this.scale = 0;
333         this.fade_time = 0;
334         this.pain_frame = 0;
335         this.pain_finished = 0;
336         this.strength_finished = 0;
337         this.invincible_finished = 0;
338         this.superweapons_finished = 0;
339         //this.dphitcontentsmask = 0;
340         this.dphitcontentsmask = DPCONTENTS_SOLID;
341         if (autocvar_g_playerclip_collisions)
342                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
343         this.pushltime = 0;
344         this.istypefrag = 0;
345         setthink(this, func_null);
346         this.nextthink = 0;
347         this.deadflag = DEAD_NO;
348         this.crouch = false;
349         STAT(REVIVE_PROGRESS, this) = 0;
350         this.revival_time = 0;
351         this.draggable = drag_undraggable;
352
353         this.items = 0;
354         STAT(WEAPONS, this) = '0 0 0';
355         this.drawonlytoclient = this;
356
357         this.viewloc = NULL;
358
359         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
360
361         this.weaponmodel = "";
362         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
363         {
364                 this.weaponentities[slot] = NULL;
365         }
366         this.exteriorweaponentity = NULL;
367         CS(this).killcount = FRAGS_SPECTATOR;
368         this.velocity = '0 0 0';
369         this.avelocity = '0 0 0';
370         this.punchangle = '0 0 0';
371         this.punchvector = '0 0 0';
372         this.oldvelocity = this.velocity;
373         this.fire_endtime = -1;
374         this.event_damage = func_null;
375         this.event_heal = func_null;
376
377         for(int slot = 0; slot < MAX_AXH; ++slot)
378         {
379                 entity axh = this.(AuxiliaryXhair[slot]);
380                 this.(AuxiliaryXhair[slot]) = NULL;
381
382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
383                         delete(axh);
384         }
385
386         if (mutator_returnvalue)
387         {
388                 // mutator prevents resetting teams+score
389         }
390         else
391         {
392                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
393                 this.frags = FRAGS_SPECTATOR;
394         }
395         if (CS(this).just_joined)
396                 CS(this).just_joined = false;
397 }
398
399 int player_getspecies(entity this)
400 {
401         get_model_parameters(this.model, this.skin);
402         int s = get_model_parameters_species;
403         get_model_parameters(string_null, 0);
404         if (s < 0) return SPECIES_HUMAN;
405         return s;
406 }
407
408 .float model_randomizer;
409 void FixPlayermodel(entity player)
410 {
411         string defaultmodel = "";
412         int defaultskin = 0;
413         if(autocvar_sv_defaultcharacter)
414         {
415                 if(teamplay)
416                 {
417                         switch(player.team)
418                         {
419                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
420                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
421                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
422                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
423                         }
424                 }
425
426                 if(defaultmodel == "")
427                 {
428                         defaultmodel = autocvar_sv_defaultplayermodel;
429                         defaultskin = autocvar_sv_defaultplayerskin;
430                 }
431
432                 int n = tokenize_console(defaultmodel);
433                 if(n > 0)
434                 {
435                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
436                         // However, do NOT randomize if the player-selected model is in the list.
437                         for (int i = 0; i < n; ++i)
438                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
439                                         defaultmodel = argv(i);
440                 }
441
442                 int i = strstrofs(defaultmodel, ":", 0);
443                 if(i >= 0)
444                 {
445                         defaultskin = stof(substring(defaultmodel, i+1, -1));
446                         defaultmodel = substring(defaultmodel, 0, i);
447                 }
448         }
449         if(autocvar_sv_defaultcharacterskin && !defaultskin)
450         {
451                 if(teamplay)
452                 {
453                         switch(player.team)
454                         {
455                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
456                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
457                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
458                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
459                         }
460                 }
461
462                 if(!defaultskin)
463                         defaultskin = autocvar_sv_defaultplayerskin;
464         }
465
466         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
467         defaultmodel = M_ARGV(0, string);
468         defaultskin = M_ARGV(1, int);
469
470         bool chmdl = false;
471         int oldskin;
472         if(defaultmodel != "")
473         {
474                 if (defaultmodel != player.model)
475                 {
476                         vector m1 = player.mins;
477                         vector m2 = player.maxs;
478                         setplayermodel (player, defaultmodel);
479                         setsize (player, m1, m2);
480                         chmdl = true;
481                 }
482
483                 oldskin = player.skin;
484                 player.skin = defaultskin;
485         } else {
486                 if (player.playermodel != player.model || player.playermodel == "")
487                 {
488                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
489                         vector m1 = player.mins;
490                         vector m2 = player.maxs;
491                         setplayermodel (player, player.playermodel);
492                         setsize (player, m1, m2);
493                         chmdl = true;
494                 }
495
496                 if(!autocvar_sv_defaultcharacterskin)
497                 {
498                         oldskin = player.skin;
499                         player.skin = stof(player.playerskin);
500                 }
501                 else
502                 {
503                         oldskin = player.skin;
504                         player.skin = defaultskin;
505                 }
506         }
507
508         if(chmdl || oldskin != player.skin) // model or skin has changed
509         {
510                 player.species = player_getspecies(player); // update species
511                 if(!autocvar_g_debug_globalsounds)
512                         UpdatePlayerSounds(player); // update skin sounds
513         }
514
515         if(!teamplay)
516                 if(strlen(autocvar_sv_defaultplayercolors))
517                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
518                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
519 }
520
521 void PutPlayerInServer(entity this)
522 {
523         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
524
525         PlayerState_attach(this);
526         accuracy_resend(this);
527
528         if (this.team < 0)
529                 TeamBalance_JoinBestTeam(this);
530
531         entity spot = SelectSpawnPoint(this, false);
532         if (!spot) {
533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
534                 return; // spawn failed
535         }
536
537         TRANSMUTE(Player, this);
538
539         CS(this).wasplayer = true;
540         this.iscreature = true;
541         this.teleportable = TELEPORT_NORMAL;
542         if(!this.damagedbycontents)
543                 IL_PUSH(g_damagedbycontents, this);
544         this.damagedbycontents = true;
545         set_movetype(this, MOVETYPE_WALK);
546         this.solid = SOLID_SLIDEBOX;
547         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
548         if (autocvar_g_playerclip_collisions)
549                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
550         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
551                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
552         this.frags = FRAGS_PLAYER;
553         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
554         this.flags = FL_CLIENT | FL_PICKUPITEMS;
555         if (autocvar__notarget)
556                 this.flags |= FL_NOTARGET;
557         this.takedamage = DAMAGE_AIM;
558         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
559
560         if (warmup_stage) {
561                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
562                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
563                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
564                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
565                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
566                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
567                 SetResource(this, RES_HEALTH, warmup_start_health);
568                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
569                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
570         } else {
571                 SetResource(this, RES_SHELLS, start_ammo_shells);
572                 SetResource(this, RES_BULLETS, start_ammo_nails);
573                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
574                 SetResource(this, RES_CELLS, start_ammo_cells);
575                 SetResource(this, RES_PLASMA, start_ammo_plasma);
576                 SetResource(this, RES_FUEL, start_ammo_fuel);
577                 SetResource(this, RES_HEALTH, start_health);
578                 SetResource(this, RES_ARMOR, start_armorvalue);
579                 STAT(WEAPONS, this) = start_weapons;
580                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
581                 {
582                         GiveRandomWeapons(this, random_start_weapons_count,
583                                 autocvar_g_random_start_weapons, random_start_ammo);
584                 }
585         }
586         SetSpectatee_status(this, 0);
587
588         PS(this).dual_weapons = '0 0 0';
589
590         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
591
592         this.items = start_items;
593
594         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
595         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
596         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
597         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
598         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
599         if (!sv_ready_restart_after_countdown && time < game_starttime)
600         {
601                 float f = game_starttime - time;
602                 this.spawnshieldtime += f;
603                 this.pauserotarmor_finished += f;
604                 this.pauserothealth_finished += f;
605                 this.pauseregen_finished += f;
606         }
607
608         this.damageforcescale = autocvar_g_player_damageforcescale;
609         this.death_time = 0;
610         this.respawn_flags = 0;
611         this.respawn_time = 0;
612         STAT(RESPAWN_TIME, this) = 0;
613         this.scale = autocvar_sv_player_scale;
614         this.fade_time = 0;
615         this.pain_frame = 0;
616         this.pain_finished = 0;
617         this.pushltime = 0;
618         setthink(this, func_null); // players have no think function
619         this.nextthink = 0;
620         this.dmg_team = 0;
621         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
622
623         this.deadflag = DEAD_NO;
624
625         this.angles = spot.angles;
626         this.angles_z = 0; // never spawn tilted even if the spot says to
627         if (IS_BOT_CLIENT(this))
628         {
629                 this.v_angle = this.angles;
630                 bot_aim_reset(this);
631         }
632         this.fixangle = true; // turn this way immediately
633         this.oldvelocity = this.velocity = '0 0 0';
634         this.avelocity = '0 0 0';
635         this.punchangle = '0 0 0';
636         this.punchvector = '0 0 0';
637
638         this.strength_finished = 0;
639         this.invincible_finished = 0;
640         this.fire_endtime = -1;
641         STAT(REVIVE_PROGRESS, this) = 0;
642         this.revival_time = 0;
643
644         this.air_finished = time + 12;
645         this.waterlevel = WATERLEVEL_NONE;
646         this.watertype = CONTENT_EMPTY;
647
648         entity spawnevent = new_pure(spawnevent);
649         spawnevent.owner = this;
650         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
651
652         // Cut off any still running player sounds.
653         stopsound(this, CH_PLAYER_SINGLE);
654
655         this.model = "";
656         FixPlayermodel(this);
657         this.drawonlytoclient = NULL;
658
659         this.viewloc = NULL;
660
661         for(int slot = 0; slot < MAX_AXH; ++slot)
662         {
663                 entity axh = this.(AuxiliaryXhair[slot]);
664                 this.(AuxiliaryXhair[slot]) = NULL;
665
666                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
667                         delete(axh);
668         }
669
670         this.spawnpoint_targ = NULL;
671
672         this.crouch = false;
673         this.view_ofs = STAT(PL_VIEW_OFS, this);
674         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
675         this.spawnorigin = spot.origin;
676         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
677         // don't reset back to last position, even if new position is stuck in solid
678         this.oldorigin = this.origin;
679         if(this.conveyor)
680                 IL_REMOVE(g_conveyed, this);
681         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
682         if(this.swampslug)
683                 delete(this.swampslug);
684         this.in_swamp = false;
685         STAT(HUD, this) = HUD_NORMAL;
686
687         this.event_damage = PlayerDamage;
688         this.event_heal = PlayerHeal;
689
690         this.draggable = func_null;
691
692         if(!this.bot_attack)
693                 IL_PUSH(g_bot_targets, this);
694         this.bot_attack = true;
695         if(!this.monster_attack)
696                 IL_PUSH(g_monster_targets, this);
697         this.monster_attack = true;
698         navigation_dynamicgoal_init(this, false);
699
700         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
701
702         // player was spectator
703         if (CS(this).killcount == FRAGS_SPECTATOR) {
704                 PlayerScore_Clear(this);
705                 CS(this).killcount = 0;
706                 CS(this).startplaytime = time;
707         }
708
709         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
710         {
711                 .entity weaponentity = weaponentities[slot];
712                 entity oldwep = this.(weaponentity);
713                 CL_SpawnWeaponentity(this, weaponentity);
714                 if(oldwep && oldwep.owner == this)
715                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
716         }
717         this.alpha = default_player_alpha;
718         this.colormod = '1 1 1' * autocvar_g_player_brightness;
719         this.exteriorweaponentity.alpha = default_weapon_alpha;
720
721         this.speedrunning = false;
722
723         this.counter_cnt = 0;
724         this.fragsfilter_cnt = 0;
725
726         target_voicescript_clear(this);
727
728         // reset fields the weapons may use
729         FOREACH(Weapons, true, {
730                 it.wr_resetplayer(it, this);
731                         // reload all reloadable weapons
732                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
733                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
734                         {
735                                 .entity weaponentity = weaponentities[slot];
736                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
737                         }
738                 }
739         });
740
741         {
742                 string s = spot.target;
743                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
744                         spot.target = string_null;
745                 SUB_UseTargets(spot, this, NULL);
746                 if(g_assault || g_race)
747                         spot.target = s;
748         }
749
750         Unfreeze(this, false);
751
752         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
753
754         if (autocvar_spawn_debug)
755         {
756                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
757                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
758         }
759
760         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
761         {
762                 .entity weaponentity = weaponentities[slot];
763                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
764                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
765                 else
766                         this.(weaponentity).m_switchweapon = WEP_Null;
767                 this.(weaponentity).m_weapon = WEP_Null;
768                 this.(weaponentity).weaponname = "";
769                 this.(weaponentity).m_switchingweapon = WEP_Null;
770                 this.(weaponentity).cnt = -1;
771         }
772
773         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
774
775         if (CS(this).impulse) ImpulseCommands(this);
776
777         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
778         {
779                 .entity weaponentity = weaponentities[slot];
780                 W_WeaponFrame(this, weaponentity);
781         }
782
783         if (!warmup_stage && !this.alivetime)
784                 this.alivetime = time;
785
786         antilag_clear(this, CS(this));
787 }
788
789 /** Called when a client spawns in the server */
790 void PutClientInServer(entity this)
791 {
792         if (IS_BOT_CLIENT(this)) {
793                 TRANSMUTE(Player, this);
794         } else if (IS_REAL_CLIENT(this)) {
795                 msg_entity = this;
796                 WriteByte(MSG_ONE, SVC_SETVIEW);
797                 WriteEntity(MSG_ONE, this);
798         }
799         if (game_stopped)
800                 TRANSMUTE(Observer, this);
801
802         SetSpectatee(this, NULL);
803
804         // reset player keys
805         if(PS(this))
806                 PS(this).itemkeys = 0;
807
808         MUTATOR_CALLHOOK(PutClientInServer, this);
809
810         if (IS_OBSERVER(this)) {
811                 PutObserverInServer(this);
812         } else if (IS_PLAYER(this)) {
813                 PutPlayerInServer(this);
814         }
815 }
816
817 // TODO do we need all these fields, or should we stop autodetecting runtime
818 // changes and just have a console command to update this?
819 bool ClientInit_SendEntity(entity this, entity to, int sf)
820 {
821         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
822         return = true;
823         msg_entity = to;
824         // MSG_INIT replacement
825         // TODO: make easier to use
826         Registry_send_all();
827         W_PROP_reload(MSG_ONE, to);
828         ClientInit_misc(this);
829         MUTATOR_CALLHOOK(Ent_Init);
830 }
831 void ClientInit_misc(entity this)
832 {
833         int channel = MSG_ONE;
834         WriteHeader(channel, ENT_CLIENT_INIT);
835         WriteByte(channel, g_nexball_meter_period * 32);
836         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
837         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
838         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
839         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
840         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
841         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
842         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
843         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
844
845         if(sv_foginterval && world.fog != "")
846                 WriteString(channel, world.fog);
847         else
848                 WriteString(channel, "");
849         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
850         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
851         WriteByte(channel, serverflags);
852         WriteCoord(channel, autocvar_g_trueaim_minrange);
853 }
854
855 void ClientInit_CheckUpdate(entity this)
856 {
857         this.nextthink = time;
858         if(this.count != autocvar_g_balance_armor_blockpercent)
859         {
860                 this.count = autocvar_g_balance_armor_blockpercent;
861                 this.SendFlags |= 1;
862         }
863         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
864         {
865                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
866                 this.SendFlags |= 1;
867         }
868 }
869
870 void ClientInit_Spawn()
871 {
872         entity e = new_pure(clientinit);
873         setthink(e, ClientInit_CheckUpdate);
874         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
875
876         ClientInit_CheckUpdate(e);
877 }
878
879 /*
880 =============
881 SetNewParms
882 =============
883 */
884 void SetNewParms ()
885 {
886         // initialize parms for a new player
887         parm1 = -(86400 * 366);
888
889         MUTATOR_CALLHOOK(SetNewParms);
890 }
891
892 /*
893 =============
894 SetChangeParms
895 =============
896 */
897 void SetChangeParms (entity this)
898 {
899         // save parms for level change
900         parm1 = CS(this).parm_idlesince - time;
901
902         MUTATOR_CALLHOOK(SetChangeParms);
903 }
904
905 /*
906 =============
907 DecodeLevelParms
908 =============
909 */
910 void DecodeLevelParms(entity this)
911 {
912         // load parms
913         CS(this).parm_idlesince = parm1;
914         if (CS(this).parm_idlesince == -(86400 * 366))
915                 CS(this).parm_idlesince = time;
916
917         // whatever happens, allow 60 seconds of idling directly after connect for map loading
918         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
919
920         MUTATOR_CALLHOOK(DecodeLevelParms);
921 }
922
923 void FixClientCvars(entity e)
924 {
925         // send prediction settings to the client
926         stuffcmd(e, "\nin_bindmap 0 0\n");
927         if(autocvar_g_antilag == 3) // client side hitscan
928                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
929         if(autocvar_sv_gentle)
930                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
931
932         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
933         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
934
935         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
936
937         MUTATOR_CALLHOOK(FixClientCvars, e);
938 }
939
940 bool findinlist_abbrev(string tofind, string list)
941 {
942         if(list == "" || tofind == "")
943                 return false; // empty list or search, just return
944
945         // this function allows abbreviated strings!
946         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
947         {
948                 return true;
949         });
950
951         return false;
952 }
953
954 bool PlayerInIPList(entity p, string iplist)
955 {
956         // some safety checks (never allow local?)
957         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
958                 return false;
959
960         return findinlist_abbrev(p.netaddress, iplist);
961 }
962
963 bool PlayerInIDList(entity p, string idlist)
964 {
965         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
966         if(!p.crypto_idfp)
967                 return false;
968
969         return findinlist_abbrev(p.crypto_idfp, idlist);
970 }
971
972 bool PlayerInList(entity player, string list)
973 {
974         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
975 }
976
977 #ifdef DP_EXT_PRECONNECT
978 /*
979 =============
980 ClientPreConnect
981
982 Called once (not at each match start) when a client begins a connection to the server
983 =============
984 */
985 void ClientPreConnect(entity this)
986 {
987         if(autocvar_sv_eventlog)
988         {
989                 GameLogEcho(sprintf(":connect:%d:%d:%s",
990                         this.playerid,
991                         etof(this),
992                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
993                 ));
994         }
995 }
996 #endif
997
998 string GetClientVersionMessage(entity this)
999 {
1000         if (CS(this).version_mismatch) {
1001                 if(CS(this).version < autocvar_gameversion) {
1002                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1003                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1004                 } else {
1005                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1006                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1007                 }
1008         } else {
1009                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1010         }
1011 }
1012
1013 string getwelcomemessage(entity this)
1014 {
1015         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1016         string modifications = M_ARGV(0, string);
1017
1018         if(g_weaponarena)
1019         {
1020                 if(g_weaponarena_random)
1021                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1022                 else
1023                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1024         }
1025         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1026                 modifications = strcat(modifications, ", No start weapons");
1027         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1028                 modifications = strcat(modifications, ", Low gravity");
1029         if(g_weapon_stay && !g_cts)
1030                 modifications = strcat(modifications, ", Weapons stay");
1031         if(g_jetpack)
1032                 modifications = strcat(modifications, ", Jet pack");
1033         if(autocvar_g_powerups == 0)
1034                 modifications = strcat(modifications, ", No powerups");
1035         if(autocvar_g_powerups > 0)
1036                 modifications = strcat(modifications, ", Powerups");
1037         modifications = substring(modifications, 2, strlen(modifications) - 2);
1038
1039         string versionmessage = GetClientVersionMessage(this);
1040         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1041
1042         if(modifications != "")
1043                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1044
1045         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1046         {
1047                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1048                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1049         }
1050
1051         if (cache_mutatormsg != "") {
1052                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1053         }
1054
1055         string mutator_msg = "";
1056         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1057         mutator_msg = M_ARGV(0, string);
1058
1059         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1060
1061         string motd = autocvar_sv_motd;
1062         if (motd != "") {
1063                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1064         }
1065         return s;
1066 }
1067
1068 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1069
1070 /**
1071 =============
1072 ClientConnect
1073
1074 Called when a client connects to the server
1075 =============
1076 */
1077 void ClientConnect(entity this)
1078 {
1079         if (Ban_MaybeEnforceBanOnce(this)) return;
1080         assert(!IS_CLIENT(this), return);
1081         this.flags |= FL_CLIENT;
1082         assert(player_count >= 0, player_count = 0);
1083
1084 #ifdef WATERMARK
1085         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1086 #endif
1087         TRANSMUTE(Client, this);
1088         CS(this).version_nagtime = time + 10 + random() * 10;
1089
1090         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1091
1092         bot_clientconnect(this);
1093
1094         Player_DetermineForcedTeam(this);
1095
1096         TRANSMUTE(Observer, this);
1097
1098         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1099
1100         // always track bots, don't ask for cl_allow_uidtracking
1101         if (IS_BOT_CLIENT(this))
1102                 PlayerStats_GameReport_AddPlayer(this);
1103         else
1104                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1105
1106         if (autocvar_sv_eventlog)
1107                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1108
1109         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1110
1111         stuffcmd(this, clientstuff, "\n");
1112         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1113
1114         FixClientCvars(this);
1115
1116         // get version info from player
1117         stuffcmd(this, "cmd clientversion $gameversion\n");
1118
1119         // notify about available teams
1120         if (teamplay)
1121         {
1122                 entity balance = TeamBalance_CheckAllowedTeams(this);
1123                 int t = TeamBalance_GetAllowedTeams(balance);
1124                 TeamBalance_Destroy(balance);
1125                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1126         }
1127         else
1128         {
1129                 stuffcmd(this, "set _teams_available 0\n");
1130         }
1131
1132         bot_relinkplayerlist();
1133
1134         CS(this).spectatortime = time;
1135         if (blockSpectators)
1136         {
1137                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1138         }
1139
1140         CS(this).jointime = time;
1141
1142         if (IS_REAL_CLIENT(this))
1143         {
1144                 if (g_weaponarena_weapons == WEPSET(TUBA))
1145                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1146         }
1147
1148         if (!sv_foginterval && world.fog != "")
1149                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1150
1151         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1152                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1153                         send_CSQC_teamnagger();
1154
1155         CSQCMODEL_AUTOINIT(this);
1156
1157         CS(this).model_randomizer = random();
1158
1159         if (IS_REAL_CLIENT(this))
1160                 sv_notice_join(this);
1161
1162         this.move_qcphysics = autocvar_sv_qcphysics;
1163
1164         // update physics stats (players can spawn before physics runs)
1165         Physics_UpdateStats(this);
1166
1167         IL_EACH(g_initforplayer, it.init_for_player, {
1168                 it.init_for_player(it, this);
1169         });
1170
1171         Handicap_Initialize(this);
1172
1173         MUTATOR_CALLHOOK(ClientConnect, this);
1174
1175         if (IS_REAL_CLIENT(this))
1176         {
1177                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1178                 {
1179                         CS(this).motd_actived_time = -1;
1180                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1181                 }
1182         }
1183 }
1184 /*
1185 =============
1186 ClientDisconnect
1187
1188 Called when a client disconnects from the server
1189 =============
1190 */
1191 .entity chatbubbleentity;
1192 void ClientDisconnect(entity this)
1193 {
1194         assert(IS_CLIENT(this), return);
1195
1196         PlayerStats_GameReport_FinalizePlayer(this);
1197         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1198         if (CS(this).active_minigame) part_minigame(this);
1199         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1200
1201         if (autocvar_sv_eventlog)
1202                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1203
1204         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1205
1206         if(IS_SPEC(this))
1207                 SetSpectatee(this, NULL);
1208
1209     MUTATOR_CALLHOOK(ClientDisconnect, this);
1210
1211         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1212         strfree(CS(this).weaponorder_byimpulse);
1213         ClientState_detach(this);
1214
1215         Portal_ClearAll(this);
1216
1217         Unfreeze(this, false);
1218
1219         RemoveGrapplingHooks(this);
1220
1221         // Here, everything has been done that requires this player to be a client.
1222
1223         this.flags &= ~FL_CLIENT;
1224
1225         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1226         if (this.killindicator) delete(this.killindicator);
1227
1228         WaypointSprite_PlayerGone(this);
1229
1230         bot_relinkplayerlist();
1231
1232         strfree(this.clientstatus);
1233         if (this.personal) delete(this.personal);
1234
1235         this.playerid = 0;
1236         ReadyCount();
1237         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1238
1239         ONREMOVE(this);
1240 }
1241
1242 void ChatBubbleThink(entity this)
1243 {
1244         this.nextthink = time;
1245         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1246         {
1247                 if(this.owner) // but why can that ever be NULL?
1248                         this.owner.chatbubbleentity = NULL;
1249                 delete(this);
1250                 return;
1251         }
1252
1253         this.mdl = "";
1254
1255         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1256         {
1257                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1258                         this.mdl = "models/sprites/minigame_busy.iqm";
1259                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1260                         this.mdl = "models/misc/chatbubble.spr";
1261         }
1262
1263         if ( this.model != this.mdl )
1264                 _setmodel(this, this.mdl);
1265
1266 }
1267
1268 void UpdateChatBubble(entity this)
1269 {
1270         if (this.alpha < 0)
1271                 return;
1272         // spawn a chatbubble entity if needed
1273         if (!this.chatbubbleentity)
1274         {
1275                 this.chatbubbleentity = new(chatbubbleentity);
1276                 this.chatbubbleentity.owner = this;
1277                 this.chatbubbleentity.exteriormodeltoclient = this;
1278                 setthink(this.chatbubbleentity, ChatBubbleThink);
1279                 this.chatbubbleentity.nextthink = time;
1280                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1281                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1282                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1283                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1284                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1285                 //this.chatbubbleentity.model = "";
1286                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1287         }
1288 }
1289
1290
1291 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1292 // added to the model skins
1293 /*void UpdateColorModHack()
1294 {
1295         float c;
1296         c = this.clientcolors & 15;
1297         // LordHavoc: only bothering to support white, green, red, yellow, blue
1298              if (!teamplay) this.colormod = '0 0 0';
1299         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1300         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1301         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1302         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1303         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1304         else this.colormod = '1 1 1';
1305 }*/
1306
1307 void respawn(entity this)
1308 {
1309         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1310         {
1311                 this.solid = SOLID_NOT;
1312                 this.takedamage = DAMAGE_NO;
1313                 set_movetype(this, MOVETYPE_FLY);
1314                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1315                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1316                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1317                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1318                 if(autocvar_g_respawn_ghosts_maxtime)
1319                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1320         }
1321
1322         CopyBody(this, 1);
1323
1324         this.effects |= EF_NODRAW; // prevent another CopyBody
1325         PutClientInServer(this);
1326 }
1327
1328 ERASEABLE
1329 void PrintToChat(entity client, string text)
1330 {
1331         text = strcat("\{1}^7", text, "\n");
1332         sprint(client, text);
1333 }
1334
1335 ERASEABLE
1336 void DebugPrintToChat(entity client, string text)
1337 {
1338         if (autocvar_developer)
1339         {
1340                 PrintToChat(client, text);
1341         }
1342 }
1343
1344 ERASEABLE
1345 void PrintToChatAll(string text)
1346 {
1347         text = strcat("\{1}^7", text, "\n");
1348         bprint(text);
1349 }
1350
1351 ERASEABLE
1352 void DebugPrintToChatAll(string text)
1353 {
1354         if (autocvar_developer)
1355         {
1356                 PrintToChatAll(text);
1357         }
1358 }
1359
1360 ERASEABLE
1361 void PrintToChatTeam(int team_num, string text)
1362 {
1363         text = strcat("\{1}^7", text, "\n");
1364         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1365         {
1366                 if (it.team == team_num)
1367                 {
1368                         sprint(it, text);
1369                 }
1370         });
1371 }
1372
1373 ERASEABLE
1374 void DebugPrintToChatTeam(int team_num, string text)
1375 {
1376         if (autocvar_developer)
1377         {
1378                 PrintToChatTeam(team_num, text);
1379         }
1380 }
1381
1382 void play_countdown(entity this, float finished, Sound samp)
1383 {
1384         TC(Sound, samp);
1385         if(IS_REAL_CLIENT(this))
1386                 if(floor(finished - time - frametime) != floor(finished - time))
1387                         if(finished - time < 6)
1388                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1389 }
1390
1391 void player_powerups(entity this)
1392 {
1393         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1394         int items_prev = this.items;
1395
1396         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1397                 this.modelflags |= MF_ROCKET;
1398         else
1399                 this.modelflags &= ~MF_ROCKET;
1400
1401         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1402
1403         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1404                 return;
1405
1406         Fire_ApplyDamage(this);
1407         Fire_ApplyEffect(this);
1408
1409         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1410         {
1411                 if (this.items & ITEM_Strength.m_itemid)
1412                 {
1413                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1414                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1415                         if (time > this.strength_finished)
1416                         {
1417                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1418                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1419                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1420                         }
1421                 }
1422                 else
1423                 {
1424                         if (time < this.strength_finished)
1425                         {
1426                                 this.items = this.items | ITEM_Strength.m_itemid;
1427                                 if(!g_cts)
1428                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1429                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1430                         }
1431                 }
1432                 if (this.items & ITEM_Shield.m_itemid)
1433                 {
1434                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1435                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1436                         if (time > this.invincible_finished)
1437                         {
1438                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1439                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1440                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1441                         }
1442                 }
1443                 else
1444                 {
1445                         if (time < this.invincible_finished)
1446                         {
1447                                 this.items = this.items | ITEM_Shield.m_itemid;
1448                                 if(!g_cts)
1449                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1450                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1451                         }
1452                 }
1453                 if (this.items & IT_SUPERWEAPON)
1454                 {
1455                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1456                         {
1457                                 this.superweapons_finished = 0;
1458                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1459                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1460                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1461                         }
1462                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1463                         {
1464                                 // don't let them run out
1465                         }
1466                         else
1467                         {
1468                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1469                                 if (time > this.superweapons_finished)
1470                                 {
1471                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1472                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1473                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1474                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1475                                 }
1476                         }
1477                 }
1478                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1479                 {
1480                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1481                         {
1482                                 this.items = this.items | IT_SUPERWEAPON;
1483                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1484                                 {
1485                                         if(!g_cts)
1486                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1487                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1488                                 }
1489                         }
1490                         else
1491                         {
1492                                 this.superweapons_finished = 0;
1493                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1494                         }
1495                 }
1496                 else
1497                 {
1498                         this.superweapons_finished = 0;
1499                 }
1500         }
1501
1502         if(autocvar_g_nodepthtestplayers)
1503                 this.effects = this.effects | EF_NODEPTHTEST;
1504
1505         if(autocvar_g_fullbrightplayers)
1506                 this.effects = this.effects | EF_FULLBRIGHT;
1507
1508         if (time >= game_starttime)
1509         if (time < this.spawnshieldtime)
1510                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1511
1512         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1513 }
1514
1515 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1516 {
1517         if(current > stable)
1518                 return current;
1519         else if(current > stable - 0.25) // when close enough, "snap"
1520                 return stable;
1521         else
1522                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1523 }
1524
1525 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1526 {
1527         if(current < stable)
1528                 return current;
1529         else if(current < stable + 0.25) // when close enough, "snap"
1530                 return stable;
1531         else
1532                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1533 }
1534
1535 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1536 {
1537         if(current > rotstable)
1538         {
1539                 if(rotframetime > 0)
1540                 {
1541                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1542                         current = max(rotstable, current - rotlinear * rotframetime);
1543                 }
1544         }
1545         else if(current < regenstable)
1546         {
1547                 if(regenframetime > 0)
1548                 {
1549                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1550                         current = min(regenstable, current + regenlinear * regenframetime);
1551                 }
1552         }
1553
1554         if(current > limit)
1555                 current = limit;
1556
1557         return current;
1558 }
1559
1560 void player_regen(entity this)
1561 {
1562         float max_mod, regen_mod, rot_mod, limit_mod;
1563         max_mod = regen_mod = rot_mod = limit_mod = 1;
1564
1565         float regen_health = autocvar_g_balance_health_regen;
1566         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1567         float regen_health_rot = autocvar_g_balance_health_rot;
1568         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1569         float regen_health_stable = autocvar_g_balance_health_regenstable;
1570         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1571         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1572                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1573         max_mod = M_ARGV(1, float);
1574         regen_mod = M_ARGV(2, float);
1575         rot_mod = M_ARGV(3, float);
1576         limit_mod = M_ARGV(4, float);
1577         regen_health = M_ARGV(5, float);
1578         regen_health_linear = M_ARGV(6, float);
1579         regen_health_rot = M_ARGV(7, float);
1580         regen_health_rotlinear = M_ARGV(8, float);
1581         regen_health_stable = M_ARGV(9, float);
1582         regen_health_rotstable = M_ARGV(10, float);
1583
1584         if(!mutator_returnvalue)
1585         if(!STAT(FROZEN, this))
1586         {
1587                 float mina, maxa, limith, limita;
1588                 maxa = autocvar_g_balance_armor_rotstable;
1589                 mina = autocvar_g_balance_armor_regenstable;
1590                 limith = GetResourceLimit(this, RES_HEALTH);
1591                 limita = GetResourceLimit(this, RES_ARMOR);
1592
1593                 regen_health_rotstable = regen_health_rotstable * max_mod;
1594                 regen_health_stable = regen_health_stable * max_mod;
1595                 limith = limith * limit_mod;
1596                 limita = limita * limit_mod;
1597
1598                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 
1599                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1600                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1601                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1602                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1603                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1604         }
1605
1606         // if player rotted to death...  die!
1607         // check this outside above checks, as player may still be able to rot to death
1608         if(GetResource(this, RES_HEALTH) < 1)
1609         {
1610                 if(this.vehicle)
1611                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1612                 if(this.event_damage)
1613                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1614         }
1615
1616         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1617         {
1618                 float minf, maxf, limitf;
1619
1620                 maxf = autocvar_g_balance_fuel_rotstable;
1621                 minf = autocvar_g_balance_fuel_regenstable;
1622                 limitf = GetResourceLimit(this, RES_FUEL);
1623
1624                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, 
1625                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1626                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1627         }
1628 }
1629
1630 bool zoomstate_set;
1631 void SetZoomState(entity this, float newzoom)
1632 {
1633         if(newzoom != CS(this).zoomstate)
1634         {
1635                 CS(this).zoomstate = newzoom;
1636                 ClientData_Touch(this);
1637         }
1638         zoomstate_set = true;
1639 }
1640
1641 void GetPressedKeys(entity this)
1642 {
1643         MUTATOR_CALLHOOK(GetPressedKeys, this);
1644         int keys = STAT(PRESSED_KEYS, this);
1645         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1646         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1647         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1648         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1649
1650         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1651         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1652         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1653         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1654         CS(this).pressedkeys = keys; // store for other users
1655
1656         STAT(PRESSED_KEYS, this) = keys;
1657 }
1658
1659 /*
1660 ======================
1661 spectate mode routines
1662 ======================
1663 */
1664
1665 void SpectateCopy(entity this, entity spectatee)
1666 {
1667         TC(Client, this); TC(Client, spectatee);
1668
1669         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1670         PS(this) = PS(spectatee);
1671         this.armortype = spectatee.armortype;
1672         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1673         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1674         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1675         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1676         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1677         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1678         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1679         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1680         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1681         CS(this).impulse = 0;
1682         this.items = spectatee.items;
1683         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1684         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1685         this.strength_finished = spectatee.strength_finished;
1686         this.invincible_finished = spectatee.invincible_finished;
1687         this.superweapons_finished = spectatee.superweapons_finished;
1688         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1689         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1690         this.punchangle = spectatee.punchangle;
1691         this.view_ofs = spectatee.view_ofs;
1692         this.velocity = spectatee.velocity;
1693         this.dmg_take = spectatee.dmg_take;
1694         this.dmg_save = spectatee.dmg_save;
1695         this.dmg_inflictor = spectatee.dmg_inflictor;
1696         this.v_angle = spectatee.v_angle;
1697         this.angles = spectatee.v_angle;
1698         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1699         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1700         this.viewloc = spectatee.viewloc;
1701         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1702                 this.fixangle = true;
1703         setorigin(this, spectatee.origin);
1704         setsize(this, spectatee.mins, spectatee.maxs);
1705         SetZoomState(this, CS(spectatee).zoomstate);
1706
1707     anticheat_spectatecopy(this, spectatee);
1708         STAT(HUD, this) = STAT(HUD, spectatee);
1709         if(spectatee.vehicle)
1710     {
1711         this.angles = spectatee.v_angle;
1712
1713         //this.fixangle = false;
1714         //this.velocity = spectatee.vehicle.velocity;
1715         this.vehicle_health = spectatee.vehicle_health;
1716         this.vehicle_shield = spectatee.vehicle_shield;
1717         this.vehicle_energy = spectatee.vehicle_energy;
1718         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1719         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1720         this.vehicle_reload1 = spectatee.vehicle_reload1;
1721         this.vehicle_reload2 = spectatee.vehicle_reload2;
1722
1723         //msg_entity = this;
1724
1725        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1726             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1727            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1728            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1729
1730         //WriteByte (MSG_ONE, SVC_SETVIEW);
1731         //    WriteEntity(MSG_ONE, this);
1732         //makevectors(spectatee.v_angle);
1733         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1734     }
1735 }
1736
1737 bool SpectateUpdate(entity this)
1738 {
1739         if(!this.enemy)
1740                 return false;
1741
1742         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1743         {
1744                 SetSpectatee(this, NULL);
1745                 return false;
1746         }
1747
1748         SpectateCopy(this, this.enemy);
1749
1750         return true;
1751 }
1752
1753 bool SpectateSet(entity this)
1754 {
1755         if(!IS_PLAYER(this.enemy))
1756                 return false;
1757
1758         ClientData_Touch(this.enemy);
1759
1760         msg_entity = this;
1761         WriteByte(MSG_ONE, SVC_SETVIEW);
1762         WriteEntity(MSG_ONE, this.enemy);
1763         set_movetype(this, MOVETYPE_NONE);
1764         accuracy_resend(this);
1765
1766         if(!SpectateUpdate(this))
1767                 PutObserverInServer(this);
1768
1769         return true;
1770 }
1771
1772 void SetSpectatee_status(entity this, int spectatee_num)
1773 {
1774         int oldspectatee_status = CS(this).spectatee_status;
1775         CS(this).spectatee_status = spectatee_num;
1776
1777         if (CS(this).spectatee_status != oldspectatee_status)
1778         {
1779                 ClientData_Touch(this);
1780                 if (g_race || g_cts) race_InitSpectator();
1781         }
1782 }
1783
1784 void SetSpectatee(entity this, entity spectatee)
1785 {
1786         if(IS_BOT_CLIENT(this))
1787                 return; // bots abuse .enemy, this code is useless to them
1788
1789         entity old_spectatee = this.enemy;
1790
1791         this.enemy = spectatee;
1792
1793         // WEAPONTODO
1794         // these are required to fix the spectator bug with arc
1795         if(old_spectatee)
1796         {
1797                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1798                 {
1799                         .entity weaponentity = weaponentities[slot];
1800                         if(old_spectatee.(weaponentity).arc_beam)
1801                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1802                 }
1803         }
1804         if(this.enemy)
1805         {
1806                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1807                 {
1808                         .entity weaponentity = weaponentities[slot];
1809                         if(this.enemy.(weaponentity).arc_beam)
1810                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1811                 }
1812         }
1813
1814         if (this.enemy)
1815                 SetSpectatee_status(this, etof(this.enemy));
1816
1817         // needed to update spectator list
1818         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1819 }
1820
1821 bool Spectate(entity this, entity pl)
1822 {
1823         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1824                 return false;
1825         pl = M_ARGV(1, entity);
1826
1827         SetSpectatee(this, pl);
1828         return SpectateSet(this);
1829 }
1830
1831 bool SpectateNext(entity this)
1832 {
1833         entity ent = find(this.enemy, classname, STR_PLAYER);
1834
1835         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1836                 ent = M_ARGV(1, entity);
1837         else if (!ent)
1838                 ent = find(ent, classname, STR_PLAYER);
1839
1840         if(ent) { SetSpectatee(this, ent); }
1841
1842         return SpectateSet(this);
1843 }
1844
1845 bool SpectatePrev(entity this)
1846 {
1847         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1848         entity ent = findchain(classname, STR_PLAYER);
1849         if (!ent) // no player
1850                 return false;
1851
1852         entity first = ent;
1853         // skip players until current spectated player
1854         if(this.enemy)
1855         while(ent && ent != this.enemy)
1856                 ent = ent.chain;
1857
1858         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1859         {
1860                 case MUT_SPECPREV_FOUND:
1861                     ent = M_ARGV(1, entity);
1862                     break;
1863                 case MUT_SPECPREV_RETURN:
1864                     return true;
1865                 case MUT_SPECPREV_CONTINUE:
1866                 default:
1867                 {
1868                         if(ent.chain)
1869                                 ent = ent.chain;
1870                         else
1871                                 ent = first;
1872                         break;
1873                 }
1874         }
1875
1876         SetSpectatee(this, ent);
1877         return SpectateSet(this);
1878 }
1879
1880 /*
1881 =============
1882 ShowRespawnCountdown()
1883
1884 Update a respawn countdown display.
1885 =============
1886 */
1887 void ShowRespawnCountdown(entity this)
1888 {
1889         float number;
1890         if(!IS_DEAD(this)) // just respawned?
1891                 return;
1892         else
1893         {
1894                 number = ceil(this.respawn_time - time);
1895                 if(number <= 0)
1896                         return;
1897                 if(number <= this.respawn_countdown)
1898                 {
1899                         this.respawn_countdown = number - 1;
1900                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1901                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1902                 }
1903         }
1904 }
1905
1906 .bool team_selected;
1907 bool ShowTeamSelection(entity this)
1908 {
1909         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1910                 return false;
1911         stuffcmd(this, "menu_showteamselect\n");
1912         return true;
1913 }
1914 void Join(entity this)
1915 {
1916         TRANSMUTE(Player, this);
1917
1918         if(!this.team_selected)
1919         if(autocvar_g_campaign || autocvar_g_balance_teams)
1920                 TeamBalance_JoinBestTeam(this);
1921
1922         if(autocvar_g_campaign)
1923                 campaign_bots_may_start = true;
1924
1925         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1926
1927         PutClientInServer(this);
1928
1929         if(IS_PLAYER(this))
1930         if(teamplay && this.team != -1)
1931         {
1932         }
1933         else
1934                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1935         this.team_selected = false;
1936 }
1937
1938 int GetPlayerLimit()
1939 {
1940         int player_limit = autocvar_g_maxplayers;
1941         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1942         player_limit = M_ARGV(0, int);
1943         return player_limit;
1944 }
1945
1946 /**
1947  * Determines whether the player is allowed to join. This depends on cvar
1948  * g_maxplayers, if it isn't used this function always return true, otherwise
1949  * it checks whether the number of currently playing players exceeds g_maxplayers.
1950  * @return int number of free slots for players, 0 if none
1951  */
1952 int nJoinAllowed(entity this, entity ignore)
1953 {
1954         if(!ignore)
1955         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1956         // so report 0 free slots if restricted
1957         {
1958                 if(autocvar_g_forced_team_otherwise == "spectate")
1959                         return 0;
1960                 if(autocvar_g_forced_team_otherwise == "spectator")
1961                         return 0;
1962         }
1963
1964         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1965                 return 0; // forced spectators can never join
1966
1967         // TODO simplify this
1968         int totalClients = 0;
1969         int currentlyPlaying = 0;
1970         FOREACH_CLIENT(true, {
1971                 if(it != ignore)
1972                         ++totalClients;
1973                 if(IS_REAL_CLIENT(it))
1974                 if(IS_PLAYER(it) || it.caplayer)
1975                         ++currentlyPlaying;
1976         });
1977
1978         int player_limit = GetPlayerLimit();
1979
1980         float free_slots = 0;
1981         if (!player_limit)
1982                 free_slots = maxclients - totalClients;
1983         else if(currentlyPlaying < player_limit)
1984                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1985
1986         static float join_prevent_msg_time = 0;
1987         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1988         {
1989                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1990                 join_prevent_msg_time = time + 3;
1991         }
1992
1993         return free_slots;
1994 }
1995
1996 /**
1997  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1998  * g_maxplayers_spectator_blocktime seconds
1999  */
2000 void checkSpectatorBlock(entity this)
2001 {
2002         if(IS_SPEC(this) || IS_OBSERVER(this))
2003         if(!this.caplayer)
2004         if(IS_REAL_CLIENT(this))
2005         {
2006                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2007                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2008                         dropclient(this);
2009                 }
2010         }
2011 }
2012
2013 void PrintWelcomeMessage(entity this)
2014 {
2015         if(CS(this).motd_actived_time == 0)
2016         {
2017                 if (autocvar_g_campaign) {
2018                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2019                                 CS(this).motd_actived_time = time;
2020                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2021                         }
2022                 } else {
2023                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2024                                 CS(this).motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2026                         }
2027                 }
2028         }
2029         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2030         {
2031                 if (autocvar_g_campaign) {
2032                         if (PHYS_INPUT_BUTTON_INFO(this))
2033                                 CS(this).motd_actived_time = time;
2034                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2035                                 CS(this).motd_actived_time = 0;
2036                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2037                         }
2038                 } else {
2039                         if (PHYS_INPUT_BUTTON_INFO(this))
2040                                 CS(this).motd_actived_time = time;
2041                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2042                                 CS(this).motd_actived_time = 0;
2043                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2044                         }
2045                 }
2046         }
2047         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2048         {
2049                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2050                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2051                 else if (CS(this).motd_actived_time == -2)
2052                 {
2053                         // instantly hide MOTD
2054                         CS(this).motd_actived_time = 0;
2055                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2056                 }
2057                 else if (IS_PLAYER(this) || IS_SPEC(this))
2058                 {
2059                         // FIXME occasionally for some reason MOTD never goes away
2060                         // delay MOTD removal a little bit in the hope it fixes this bug
2061                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2062                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2063                         else //if (CS(this).motd_actived_time < -2)
2064                                 CS(this).motd_actived_time++;
2065                 }
2066         }
2067 }
2068
2069 const int MIN_SPEC_TIME = 1;
2070 bool joinAllowed(entity this)
2071 {
2072         if (CS(this).version_mismatch) return false;
2073         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2074         if (!nJoinAllowed(this, this)) return false;
2075         if (teamplay && lockteams) return false;
2076         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2077         if (ShowTeamSelection(this)) return false;
2078         return true;
2079 }
2080
2081 .int items_added;
2082 .string shootfromfixedorigin;
2083 bool PlayerThink(entity this)
2084 {
2085         if (game_stopped || intermission_running) {
2086                 this.modelflags &= ~MF_ROCKET;
2087                 if(intermission_running)
2088                         IntermissionThink(this);
2089                 return false;
2090         }
2091
2092         if (timeout_status == TIMEOUT_ACTIVE) {
2093         // don't allow the player to turn around while game is paused
2094                 // FIXME turn this into CSQC stuff
2095                 this.v_angle = this.lastV_angle;
2096                 this.angles = this.lastV_angle;
2097                 this.fixangle = true;
2098         }
2099
2100         if (frametime) player_powerups(this);
2101
2102         if (IS_DEAD(this)) {
2103                 if (this.personal && g_race_qualifying) {
2104                         if (time > this.respawn_time) {
2105                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2106                                 respawn(this);
2107                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2108                         }
2109                 } else {
2110                         if (frametime) player_anim(this);
2111
2112                         if (this.respawn_flags & RESPAWN_DENY)
2113                         {
2114                                 STAT(RESPAWN_TIME, this) = 0;
2115                                 return false;
2116                         }
2117
2118                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2119
2120                         switch(this.deadflag)
2121                         {
2122                                 case DEAD_DYING:
2123                                 {
2124                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2125                                                 this.deadflag = DEAD_RESPAWNING;
2126                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2127                                                 this.deadflag = DEAD_DEAD;
2128                                         break;
2129                                 }
2130                                 case DEAD_DEAD:
2131                                 {
2132                                         if (button_pressed)
2133                                                 this.deadflag = DEAD_RESPAWNABLE;
2134                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2135                                                 this.deadflag = DEAD_RESPAWNING;
2136                                         break;
2137                                 }
2138                                 case DEAD_RESPAWNABLE:
2139                                 {
2140                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2141                                                 this.deadflag = DEAD_RESPAWNING;
2142                                         break;
2143                                 }
2144                                 case DEAD_RESPAWNING:
2145                                 {
2146                                         if (time > this.respawn_time)
2147                                         {
2148                                                 this.respawn_time = time + 1; // only retry once a second
2149                                                 this.respawn_time_max = this.respawn_time;
2150                                                 respawn(this);
2151                                         }
2152                                         break;
2153                                 }
2154                         }
2155
2156                         ShowRespawnCountdown(this);
2157
2158                         if (this.respawn_flags & RESPAWN_SILENT)
2159                                 STAT(RESPAWN_TIME, this) = 0;
2160                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2161                         {
2162                                 if (time < this.respawn_time)
2163                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2164                                 else if (this.deadflag != DEAD_RESPAWNING)
2165                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2166                         }
2167                         else
2168                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2169                 }
2170
2171                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2172                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2173                         STAT(RESPAWN_TIME, this) *= -1;
2174
2175                 return false;
2176         }
2177
2178         FixPlayermodel(this);
2179
2180         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2181                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2182                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2183         }
2184
2185         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2186         //if(frametime)
2187         {
2188                 this.items &= ~this.items_added;
2189
2190                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2191                 {
2192                         .entity weaponentity = weaponentities[slot];
2193                         W_WeaponFrame(this, weaponentity);
2194                 }
2195
2196                 this.items_added = 0;
2197                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2198             this.items_added |= IT_FUEL;
2199
2200                 this.items |= this.items_added;
2201         }
2202
2203         player_regen(this);
2204
2205         // WEAPONTODO: Add a weapon request for this
2206         // rot vortex charge to the charge limit
2207         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2208         {
2209                 .entity weaponentity = weaponentities[slot];
2210                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2211                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2212         }
2213
2214         if (frametime) player_anim(this);
2215
2216         // secret status
2217         secrets_setstatus(this);
2218
2219         // monsters status
2220         monsters_setstatus(this);
2221
2222         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2223
2224         return true;
2225 }
2226
2227 .bool would_spectate;
2228 void ObserverThink(entity this)
2229 {
2230         if ( CS(this).impulse )
2231         {
2232                 MinigameImpulse(this, CS(this).impulse);
2233                 CS(this).impulse = 0;
2234         }
2235
2236         if (this.flags & FL_JUMPRELEASED) {
2237                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2238                         this.flags &= ~FL_JUMPRELEASED;
2239                         this.flags |= FL_SPAWNING;
2240                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2241                         this.flags &= ~FL_JUMPRELEASED;
2242                         if(SpectateNext(this)) {
2243                                 TRANSMUTE(Spectator, this);
2244                         }
2245                 } else {
2246                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2247                         set_movetype(this, preferred_movetype);
2248                 }
2249         } else {
2250                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2251                         this.flags |= FL_JUMPRELEASED;
2252                         if(this.flags & FL_SPAWNING)
2253                         {
2254                                 this.flags &= ~FL_SPAWNING;
2255                                 Join(this);
2256                                 return;
2257                         }
2258                 }
2259         }
2260 }
2261
2262 void SpectatorThink(entity this)
2263 {
2264         if ( CS(this).impulse )
2265         {
2266                 if(MinigameImpulse(this, CS(this).impulse))
2267                         CS(this).impulse = 0;
2268
2269                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2270                 {
2271                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2272                         CS(this).impulse = 0;
2273                         return;
2274                 }
2275         }
2276
2277         if (this.flags & FL_JUMPRELEASED) {
2278                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2279                         this.flags &= ~FL_JUMPRELEASED;
2280                         this.flags |= FL_SPAWNING;
2281                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2282                         this.flags &= ~FL_JUMPRELEASED;
2283                         if(SpectateNext(this)) {
2284                                 TRANSMUTE(Spectator, this);
2285                         } else {
2286                                 TRANSMUTE(Observer, this);
2287                                 PutClientInServer(this);
2288                         }
2289                         CS(this).impulse = 0;
2290                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2291                         this.flags &= ~FL_JUMPRELEASED;
2292                         if(SpectatePrev(this)) {
2293                                 TRANSMUTE(Spectator, this);
2294                         } else {
2295                                 TRANSMUTE(Observer, this);
2296                                 PutClientInServer(this);
2297                         }
2298                         CS(this).impulse = 0;
2299                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2300                         this.would_spectate = false;
2301                         this.flags &= ~FL_JUMPRELEASED;
2302                         TRANSMUTE(Observer, this);
2303                         PutClientInServer(this);
2304                 } else {
2305                         if(!SpectateUpdate(this))
2306                         {
2307                                 if(!SpectateNext(this))
2308                                 {
2309                                         PutObserverInServer(this);
2310                                         this.would_spectate = true;
2311                                 }
2312                         }
2313                 }
2314         } else {
2315                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2316                         this.flags |= FL_JUMPRELEASED;
2317                         if(this.flags & FL_SPAWNING)
2318                         {
2319                                 this.flags &= ~FL_SPAWNING;
2320                                 Join(this);
2321                                 return;
2322                         }
2323                 }
2324                 if(!SpectateUpdate(this))
2325                         PutObserverInServer(this);
2326         }
2327
2328         this.flags |= FL_CLIENT | FL_NOTARGET;
2329 }
2330
2331 void PlayerUseKey(entity this)
2332 {
2333         if (!IS_PLAYER(this))
2334                 return;
2335
2336         if(this.vehicle)
2337         {
2338                 if(!game_stopped)
2339                 {
2340                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2341                         return;
2342                 }
2343         }
2344         else if(autocvar_g_vehicles_enter)
2345         {
2346                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2347                 {
2348                         entity head, closest_target = NULL;
2349                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2350
2351                         while(head) // find the closest acceptable target to enter
2352                         {
2353                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2354                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2355                                 {
2356                                         if(closest_target)
2357                                         {
2358                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2359                                                 { closest_target = head; }
2360                                         }
2361                                         else { closest_target = head; }
2362                                 }
2363
2364                                 head = head.chain;
2365                         }
2366
2367                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2368                 }
2369         }
2370
2371         // a use key was pressed; call handlers
2372         MUTATOR_CALLHOOK(PlayerUseKey, this);
2373 }
2374
2375
2376 /*
2377 =============
2378 PlayerPreThink
2379
2380 Called every frame for each client before the physics are run
2381 =============
2382 */
2383 .float last_vehiclecheck;
2384 void PlayerPreThink (entity this)
2385 {
2386         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2387         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2388
2389         WarpZone_PlayerPhysics_FixVAngle(this);
2390
2391         if (frametime) {
2392                 // physics frames: update anticheat stuff
2393                 anticheat_prethink(this);
2394         }
2395
2396         if (blockSpectators && frametime) {
2397                 // WORKAROUND: only use dropclient in server frames (frametime set).
2398                 // Never use it in cl_movement frames (frametime zero).
2399                 checkSpectatorBlock(this);
2400         }
2401
2402         zoomstate_set = false;
2403
2404         // Check for nameless players
2405         if (this.netname == "" || this.netname != CS(this).netname_previous)
2406         {
2407                 bool assume_unchanged = (CS(this).netname_previous == "");
2408                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2409                 {
2410                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2411                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2412                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2413                         assume_unchanged = false;
2414                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2415                 }
2416                 if (isInvisibleString(this.netname))
2417                 {
2418                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2419                         sprint(this, "Warning: invisible names are not allowed.\n");
2420                         assume_unchanged = false;
2421                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2422                 }
2423                 if (!assume_unchanged && autocvar_sv_eventlog)
2424                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2425                 strcpy(CS(this).netname_previous, this.netname);
2426         }
2427
2428         // version nagging
2429         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2430         CS(this).version_nagtime = 0;
2431         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2432             // git client
2433         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2434             // git server
2435             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2436         } else {
2437             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2438             if (r < 0) { // old client
2439                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2440             } else if (r > 0) { // old server
2441                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2442             }
2443         }
2444     }
2445
2446         // GOD MODE info
2447         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2448         {
2449                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2450                 this.max_armorvalue = 0;
2451         }
2452
2453         if(IS_PLAYER(this))
2454         {
2455                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2456                 {
2457                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2458                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2459                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2460
2461                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2462                                 Unfreeze(this, false);
2463                 }
2464                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2465                 {
2466                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2467                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2468
2469                         if (GetResource(this, RES_HEALTH) < 1)
2470                         {
2471                                 if (this.vehicle)
2472                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2473                                 if(this.event_damage)
2474                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2475                         }
2476                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2477                                 Unfreeze(this, false);
2478                 }
2479         }
2480
2481         MUTATOR_CALLHOOK(PlayerPreThink, this);
2482
2483         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2484         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2485         {
2486                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2487                 {
2488                         if(!it.owner)
2489                         {
2490                                 if(!it.team || SAME_TEAM(this, it))
2491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2492                                 else if(autocvar_g_vehicles_steal)
2493                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2494                         }
2495                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2496                         {
2497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2498                         }
2499                 });
2500
2501                 this.last_vehiclecheck = time + 1;
2502         }
2503
2504         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2505         {
2506                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2507                         PlayerUseKey(this);
2508                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2509         }
2510
2511         if (IS_REAL_CLIENT(this))
2512                 PrintWelcomeMessage(this);
2513
2514         if (IS_PLAYER(this)) {
2515                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2516                         error("Client can't be spawned as player on connection!");
2517                 if(!PlayerThink(this))
2518                         return;
2519         }
2520         else if (game_stopped || intermission_running) {
2521                 if(intermission_running)
2522                         IntermissionThink(this);
2523                 return;
2524         }
2525         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2526         {
2527                 CS(this).autojoin_checked = true;
2528                 // don't do this in ClientConnect
2529                 // many things can go wrong if a client is spawned as player on connection
2530                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2531                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2532                                 && (!teamplay || autocvar_g_balance_teams)))
2533                 {
2534                         campaign_bots_may_start = true;
2535                         Join(this);
2536                         return;
2537                 }
2538         }
2539         else if (IS_OBSERVER(this)) {
2540                 ObserverThink(this);
2541         }
2542         else if (IS_SPEC(this)) {
2543                 SpectatorThink(this);
2544         }
2545
2546         // WEAPONTODO: Add weapon request for this
2547         if (!zoomstate_set) {
2548                 bool wep_zoomed = false;
2549                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2550                 {
2551                         .entity weaponentity = weaponentities[slot];
2552                         Weapon thiswep = this.(weaponentity).m_weapon;
2553                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2554                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2555                 }
2556                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2557     }
2558
2559         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2560         {
2561                 CS(this).teamkill_soundtime = 0;
2562
2563                 entity e = CS(this).teamkill_soundsource;
2564                 entity oldpusher = e.pusher;
2565                 e.pusher = this;
2566                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2567                 e.pusher = oldpusher;
2568         }
2569
2570         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2571                 CS(this).taunt_soundtime = 0;
2572                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2573         }
2574
2575         target_voicescript_next(this);
2576
2577         // WEAPONTODO: Move into weaponsystem somehow
2578         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2579         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2580         {
2581                 .entity weaponentity = weaponentities[slot];
2582                 if(this.(weaponentity).m_weapon == WEP_Null)
2583                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2584         }
2585 }
2586
2587 void DrownPlayer(entity this)
2588 {
2589         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2590                 return;
2591
2592         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2593         {
2594                 if(this.air_finished < time)
2595                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2596                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2597         }
2598         else if (this.air_finished < time)
2599         {       // drown!
2600                 if (this.pain_finished < time)
2601                 {
2602                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2603                         this.pain_finished = time + 0.5;
2604                 }
2605         }
2606 }
2607
2608 .bool move_qcphysics;
2609
2610 void Player_Physics(entity this)
2611 {
2612         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2613
2614         if(!this.move_qcphysics)
2615                 return;
2616
2617         if(!frametime && !CS(this).pm_frametime)
2618                 return;
2619
2620         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2621
2622         CS(this).pm_frametime = 0;
2623 }
2624
2625 /*
2626 =============
2627 PlayerPostThink
2628
2629 Called every frame for each client after the physics are run
2630 =============
2631 */
2632 void PlayerPostThink (entity this)
2633 {
2634         Player_Physics(this);
2635
2636         if (sv_maxidle > 0)
2637         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2638         if (IS_REAL_CLIENT(this))
2639         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2640         {
2641                 int totalClients = 0;
2642                 if(sv_maxidle_slots > 0)
2643                 {
2644                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2645                         {
2646                                 ++totalClients;
2647                         });
2648                 }
2649
2650                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2651                 { /* do nothing */ }
2652                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2653                 {
2654                         if (CS(this).idlekick_lasttimeleft)
2655                         {
2656                                 CS(this).idlekick_lasttimeleft = 0;
2657                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2658                         }
2659                 }
2660                 else
2661                 {
2662                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2663                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2664                                 if (!CS(this).idlekick_lasttimeleft)
2665                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2666                         }
2667                         if (timeleft <= 0) {
2668                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2669                                 dropclient(this);
2670                                 return;
2671                         }
2672                         else if (timeleft <= 10) {
2673                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2674                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2675                 }
2676                                 CS(this).idlekick_lasttimeleft = timeleft;
2677                         }
2678                 }
2679         }
2680
2681         CheatFrame(this);
2682
2683         if (game_stopped)
2684         {
2685                 this.solid = SOLID_NOT;
2686                 this.takedamage = DAMAGE_NO;
2687                 set_movetype(this, MOVETYPE_NONE);
2688         }
2689
2690         if (IS_PLAYER(this)) {
2691                 if(this.death_time == time && IS_DEAD(this))
2692                 {
2693                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2694                         // once all the damage events of this frame have been processed with normal size
2695                         this.maxs.z = 5;
2696                         setsize(this, this.mins, this.maxs);
2697                 }
2698                 DrownPlayer(this);
2699                 UpdateChatBubble(this);
2700                 if (CS(this).impulse) ImpulseCommands(this);
2701                 if (game_stopped)
2702                 {
2703                         CSQCMODEL_AUTOUPDATE(this);
2704                         return;
2705                 }
2706                 GetPressedKeys(this);
2707         }
2708
2709         if (this.waypointsprite_attachedforcarrier) {
2710                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2711                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2712         }
2713
2714         CSQCMODEL_AUTOUPDATE(this);
2715 }
2716
2717 /**
2718  * message "": do not say, just test flood control
2719  * return value:
2720  *   1 = accept
2721  *   0 = reject
2722  *  -1 = fake accept
2723  */
2724 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2725 {
2726         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2727                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2728
2729         if (source)
2730                 msgin = formatmessage(source, msgin);
2731
2732         string colorstr;
2733         if (!(IS_PLAYER(source) || source.caplayer))
2734                 colorstr = "^0"; // black for spectators
2735         else if(teamplay)
2736                 colorstr = Team_ColorCode(source.team);
2737         else
2738         {
2739                 colorstr = "";
2740                 teamsay = false;
2741         }
2742
2743         if (!source) {
2744                 colorstr = "";
2745                 teamsay = false;
2746         }
2747
2748         if(msgin != "")
2749                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2750
2751         /*
2752          * using bprint solves this... me stupid
2753         // how can we prevent the message from appearing in a listen server?
2754         // for now, just give "say" back and only handle say_team
2755         if(!teamsay)
2756         {
2757                 clientcommand(source, strcat("say ", msgin));
2758                 return;
2759         }
2760         */
2761
2762         string namestr = "";
2763         if (source)
2764                 namestr = playername(source, autocvar_g_chat_teamcolors);
2765
2766         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2767
2768         string msgstr = "", cmsgstr = "";
2769         string privatemsgprefix = string_null;
2770         int privatemsgprefixlen = 0;
2771         if (msgin != "")
2772         {
2773                 bool found_me = false;
2774                 if(strstrofs(msgin, "/me", 0) >= 0)
2775                 {
2776                         string newmsgin = "";
2777                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2778                         FOREACH_WORD(msgin, true,
2779                         {
2780                                 if(strdecolorize(it) == "/me")
2781                                 {
2782                                         found_me = true;
2783                                         newmsgin = cons(newmsgin, newnamestr);
2784                                 }
2785                                 else
2786                                         newmsgin = cons(newmsgin, it);
2787                         });
2788                         msgin = newmsgin;
2789                 }
2790
2791                 if(privatesay)
2792                 {
2793                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2794                         privatemsgprefixlen = strlen(msgstr);
2795                         msgstr = strcat(msgstr, msgin);
2796                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2797                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2798                 }
2799                 else if(teamsay)
2800                 {
2801                         if(found_me)
2802                         {
2803                                 //msgin = strreplace("/me", "", msgin);
2804                                 //msgin = substring(msgin, 3, strlen(msgin));
2805                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2806                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2807                         }
2808                         else
2809                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2810                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2811                 }
2812                 else
2813                 {
2814                         if(found_me)
2815                         {
2816                                 //msgin = strreplace("/me", "", msgin);
2817                                 //msgin = substring(msgin, 3, strlen(msgin));
2818                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2819                                 msgstr = strcat("\{1}^4* ^7", msgin);
2820                         }
2821                         else {
2822                                 msgstr = "\{1}";
2823                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2824                                 msgstr = strcat(msgstr, msgin);
2825                         }
2826                         cmsgstr = "";
2827                 }
2828                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2829         }
2830
2831         string fullmsgstr = msgstr;
2832         string fullcmsgstr = cmsgstr;
2833
2834         // FLOOD CONTROL
2835         int flood = 0;
2836         var .float flood_field = floodcontrol_chat;
2837         if(floodcontrol && source)
2838         {
2839                 float flood_spl;
2840                 float flood_burst;
2841                 float flood_lmax;
2842                 float lines;
2843                 if(privatesay)
2844                 {
2845                         flood_spl = autocvar_g_chat_flood_spl_tell;
2846                         flood_burst = autocvar_g_chat_flood_burst_tell;
2847                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2848                         flood_field = floodcontrol_chattell;
2849                 }
2850                 else if(teamsay)
2851                 {
2852                         flood_spl = autocvar_g_chat_flood_spl_team;
2853                         flood_burst = autocvar_g_chat_flood_burst_team;
2854                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2855                         flood_field = floodcontrol_chatteam;
2856                 }
2857                 else
2858                 {
2859                         flood_spl = autocvar_g_chat_flood_spl;
2860                         flood_burst = autocvar_g_chat_flood_burst;
2861                         flood_lmax = autocvar_g_chat_flood_lmax;
2862                         flood_field = floodcontrol_chat;
2863                 }
2864                 flood_burst = max(0, flood_burst - 1);
2865                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2866
2867                 // do flood control for the default line size
2868                 if(msgstr != "")
2869                 {
2870                         getWrappedLine_remaining = msgstr;
2871                         msgstr = "";
2872                         lines = 0;
2873                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2874                         {
2875                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2876                                 ++lines;
2877                         }
2878                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2879
2880                         if(getWrappedLine_remaining != "")
2881                         {
2882                                 msgstr = strcat(msgstr, "\n");
2883                                 flood = 2;
2884                         }
2885
2886                         if (time >= source.(flood_field))
2887                         {
2888                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2889                         }
2890                         else
2891                         {
2892                                 flood = 1;
2893                                 msgstr = fullmsgstr;
2894                         }
2895                 }
2896                 else
2897                 {
2898                         if (time >= source.(flood_field))
2899                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2900                         else
2901                                 flood = 1;
2902                 }
2903
2904                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2905                         source.(flood_field) = flood = 0;
2906         }
2907
2908         string sourcemsgstr, sourcecmsgstr;
2909         if(flood == 2) // cannot happen for empty msgstr
2910         {
2911                 if(autocvar_g_chat_flood_notify_flooder)
2912                 {
2913                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2914                         sourcecmsgstr = "";
2915                 }
2916                 else
2917                 {
2918                         sourcemsgstr = fullmsgstr;
2919                         sourcecmsgstr = fullcmsgstr;
2920                 }
2921                 cmsgstr = "";
2922         }
2923         else
2924         {
2925                 sourcemsgstr = msgstr;
2926                 sourcecmsgstr = cmsgstr;
2927         }
2928
2929         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2930         {
2931                 if (!game_stopped)
2932                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2933                         teamsay = -1; // spectators
2934         }
2935
2936         if(flood)
2937                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2938
2939         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2940         if(privatesay)
2941                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2942
2943         int ret;
2944         if(source && CS(source).muted)
2945         {
2946                 // always fake the message
2947                 ret = -1;
2948         }
2949         else if(flood == 1)
2950         {
2951                 if (autocvar_g_chat_flood_notify_flooder)
2952                 {
2953                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2954                         ret = 0;
2955                 }
2956                 else
2957                         ret = -1;
2958         }
2959         else
2960         {
2961                 ret = 1;
2962         }
2963
2964         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2965         {
2966                 if (!game_stopped)
2967                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2968                         ret = -1; // just hide the message completely
2969         }
2970
2971         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2972         ret = M_ARGV(1, int);
2973
2974         string event_log_msg = "";
2975
2976         if(sourcemsgstr != "" && ret != 0)
2977         {
2978                 if(ret < 0) // faked message, because the player is muted
2979                 {
2980                         sprint(source, sourcemsgstr);
2981                         if(sourcecmsgstr != "" && !privatesay)
2982                                 centerprint(source, sourcecmsgstr);
2983                 }
2984                 else if(privatesay) // private message, between 2 people only
2985                 {
2986                         sprint(source, sourcemsgstr);
2987                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2988                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2989                         {
2990                                 sprint(privatesay, msgstr);
2991                                 if(cmsgstr != "")
2992                                         centerprint(privatesay, cmsgstr);
2993                         }
2994                 }
2995                 else if ( teamsay && CS(source).active_minigame )
2996                 {
2997                         sprint(source, sourcemsgstr);
2998                         dedicated_print(msgstr); // send to server console too
2999                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3000                                 sprint(it, msgstr);
3001                         });
3002                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3003
3004                 }
3005                 else if(teamsay > 0) // team message, only sent to team mates
3006                 {
3007                         sprint(source, sourcemsgstr);
3008                         dedicated_print(msgstr); // send to server console too
3009                         if(sourcecmsgstr != "")
3010                                 centerprint(source, sourcecmsgstr);
3011                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3012                                 sprint(it, msgstr);
3013                                 if(cmsgstr != "")
3014                                         centerprint(it, cmsgstr);
3015                         });
3016                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3017                 }
3018                 else if(teamsay < 0) // spectator message, only sent to spectators
3019                 {
3020                         sprint(source, sourcemsgstr);
3021                         dedicated_print(msgstr); // send to server console too
3022                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3023                                 sprint(it, msgstr);
3024                         });
3025                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3026                 }
3027                 else
3028                 {
3029                         if (source) {
3030                                 sprint(source, sourcemsgstr);
3031                                 dedicated_print(msgstr); // send to server console too
3032                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3033                         }
3034                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3035                                 sprint(it, msgstr);
3036                         });
3037                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3038                 }
3039         }
3040
3041         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3042                 GameLogEcho(event_log_msg);
3043         }
3044
3045         return ret;
3046 }
3047
3048 // hack to copy the button fields from the client entity to the Client State
3049 void PM_UpdateButtons(entity this, entity store)
3050 {
3051         if(this.impulse)
3052                 store.impulse = this.impulse;
3053         this.impulse = 0;
3054
3055         bool typing = this.buttonchat || this.button12;
3056
3057         store.button0 = (typing) ? 0 : this.button0;
3058         //button1?!
3059         store.button2 = (typing) ? 0 : this.button2;
3060         store.button3 = (typing) ? 0 : this.button3;
3061         store.button4 = this.button4;
3062         store.button5 = (typing) ? 0 : this.button5;
3063         store.button6 = this.button6;
3064         store.button7 = this.button7;
3065         store.button8 = this.button8;
3066         store.button9 = this.button9;
3067         store.button10 = this.button10;
3068         store.button11 = this.button11;
3069         store.button12 = this.button12;
3070         store.button13 = this.button13;
3071         store.button14 = this.button14;
3072         store.button15 = this.button15;
3073         store.button16 = this.button16;
3074         store.buttonuse = this.buttonuse;
3075         store.buttonchat = this.buttonchat;
3076
3077         store.cursor_active = this.cursor_active;
3078         store.cursor_screen = this.cursor_screen;
3079         store.cursor_trace_start = this.cursor_trace_start;
3080         store.cursor_trace_endpos = this.cursor_trace_endpos;
3081         store.cursor_trace_ent = this.cursor_trace_ent;
3082
3083         store.ping = this.ping;
3084         store.ping_packetloss = this.ping_packetloss;
3085         store.ping_movementloss = this.ping_movementloss;
3086
3087         store.v_angle = this.v_angle;
3088         store.movement = (typing) ? '0 0 0' : this.movement;
3089 }
3090
3091 NET_HANDLE(fpsreport, bool)
3092 {
3093         int fps = ReadShort();
3094         PlayerScore_Set(sender, SP_FPS, fps);
3095         return true;
3096 }