qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.dual_weapons = '0 0 0';
 342         this.drawonlytoclient = this;
 343
 344         this.weaponmodel = "";
 345         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 346         {
 347                 this.weaponentities[slot] = NULL;
 348         }
 349         this.exteriorweaponentity = NULL;
 350         this.killcount = FRAGS_SPECTATOR;
 351         this.velocity = '0 0 0';
 352         this.avelocity = '0 0 0';
 353         this.punchangle = '0 0 0';
 354         this.punchvector = '0 0 0';
 355         this.oldvelocity = this.velocity;
 356         this.fire_endtime = -1;
 357         this.event_damage = func_null;
 358
 359         for(int slot = 0; slot < MAX_AXH; ++slot)
 360         {
 361                 entity axh = this.(AuxiliaryXhair[slot]);
 362                 this.(AuxiliaryXhair[slot]) = NULL;
 363
 364                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 365                         delete(axh);
 366         }
 367 }
 368
 369 int player_getspecies(entity this)
 370 {
 371         get_model_parameters(this.model, this.skin);
 372         int s = get_model_parameters_species;
 373         get_model_parameters(string_null, 0);
 374         if (s < 0) return SPECIES_HUMAN;
 375         return s;
 376 }
 377
 378 .float model_randomizer;
 379 void FixPlayermodel(entity player)
 380 {
 381         string defaultmodel = "";
 382         int defaultskin = 0;
 383         if(autocvar_sv_defaultcharacter)
 384         {
 385                 if(teamplay)
 386                 {
 387                         switch(player.team)
 388                         {
 389                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 390                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 391                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 392                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 393                         }
 394                 }
 395
 396                 if(defaultmodel == "")
 397                 {
 398                         defaultmodel = autocvar_sv_defaultplayermodel;
 399                         defaultskin = autocvar_sv_defaultplayerskin;
 400                 }
 401
 402                 int n = tokenize_console(defaultmodel);
 403                 if(n > 0)
 404                 {
 405                         defaultmodel = argv(floor(n * player.model_randomizer));
 406                         // However, do NOT randomize if the player-selected model is in the list.
 407                         for (int i = 0; i < n; ++i)
 408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 409                                         defaultmodel = argv(i);
 410                 }
 411
 412                 int i = strstrofs(defaultmodel, ":", 0);
 413                 if(i >= 0)
 414                 {
 415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 416                         defaultmodel = substring(defaultmodel, 0, i);
 417                 }
 418         }
 419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 420         {
 421                 if(teamplay)
 422                 {
 423                         switch(player.team)
 424                         {
 425                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 426                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 427                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 428                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 429                         }
 430                 }
 431
 432                 if(!defaultskin)
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434         }
 435
 436         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 437         defaultmodel = M_ARGV(0, string);
 438         defaultskin = M_ARGV(1, int);
 439
 440         bool chmdl = false;
 441         int oldskin;
 442         if(defaultmodel != "")
 443         {
 444                 if (defaultmodel != player.model)
 445                 {
 446                         vector m1 = player.mins;
 447                         vector m2 = player.maxs;
 448                         setplayermodel (player, defaultmodel);
 449                         setsize (player, m1, m2);
 450                         chmdl = true;
 451                 }
 452
 453                 oldskin = player.skin;
 454                 player.skin = defaultskin;
 455         } else {
 456                 if (player.playermodel != player.model || player.playermodel == "")
 457                 {
 458                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 459                         vector m1 = player.mins;
 460                         vector m2 = player.maxs;
 461                         setplayermodel (player, player.playermodel);
 462                         setsize (player, m1, m2);
 463                         chmdl = true;
 464                 }
 465
 466                 if(!autocvar_sv_defaultcharacterskin)
 467                 {
 468                         oldskin = player.skin;
 469                         player.skin = stof(player.playerskin);
 470                 }
 471                 else
 472                 {
 473                         oldskin = player.skin;
 474                         player.skin = defaultskin;
 475                 }
 476         }
 477
 478         if(chmdl || oldskin != player.skin) // model or skin has changed
 479         {
 480                 player.species = player_getspecies(player); // update species
 481                 if(!autocvar_g_debug_globalsounds)
 482                         UpdatePlayerSounds(player); // update skin sounds
 483         }
 484
 485         if(!teamplay)
 486                 if(strlen(autocvar_sv_defaultplayercolors))
 487                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 488                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 489 }
 490
 491
 492 /** Called when a client spawns in the server */
 493 void PutClientInServer(entity this)
 494 {
 495         if (IS_BOT_CLIENT(this)) {
 496                 TRANSMUTE(Player, this);
 497         } else if (IS_REAL_CLIENT(this)) {
 498                 msg_entity = this;
 499                 WriteByte(MSG_ONE, SVC_SETVIEW);
 500                 WriteEntity(MSG_ONE, this);
 501         }
 502         if (game_stopped)
 503                 TRANSMUTE(Observer, this);
 504
 505         SetSpectatee(this, NULL);
 506
 507         // reset player keys
 508         this.itemkeys = 0;
 509
 510         MUTATOR_CALLHOOK(PutClientInServer, this);
 511
 512         if (IS_OBSERVER(this)) {
 513                 PutObserverInServer(this);
 514         } else if (IS_PLAYER(this)) {
 515                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 516
 517                 PlayerState_attach(this);
 518                 accuracy_resend(this);
 519
 520                 if (this.team < 0)
 521                         JoinBestTeam(this, false, true);
 522
 523                 entity spot = SelectSpawnPoint(this, false);
 524                 if (!spot) {
 525                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 526                         return; // spawn failed
 527                 }
 528
 529                 TRANSMUTE(Player, this);
 530
 531                 this.wasplayer = true;
 532                 this.iscreature = true;
 533                 this.teleportable = TELEPORT_NORMAL;
 534                 if(!this.damagedbycontents)
 535                         IL_PUSH(g_damagedbycontents, this);
 536                 this.damagedbycontents = true;
 537                 set_movetype(this, MOVETYPE_WALK);
 538                 this.solid = SOLID_SLIDEBOX;
 539                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 540                 if (autocvar_g_playerclip_collisions)
 541                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 542                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 543                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 544                 this.frags = FRAGS_PLAYER;
 545                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 546                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 547                 if (autocvar__notarget)
 548                         this.flags |= FL_NOTARGET;
 549                 this.takedamage = DAMAGE_AIM;
 550                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 551                 this.dmg = 2; // WTF
 552
 553                 if (warmup_stage) {
 554                         this.ammo_shells = warmup_start_ammo_shells;
 555                         this.ammo_nails = warmup_start_ammo_nails;
 556                         this.ammo_rockets = warmup_start_ammo_rockets;
 557                         this.ammo_cells = warmup_start_ammo_cells;
 558                         this.ammo_plasma = warmup_start_ammo_plasma;
 559                         this.ammo_fuel = warmup_start_ammo_fuel;
 560                         this.health = warmup_start_health;
 561                         this.armorvalue = warmup_start_armorvalue;
 562                         this.weapons = WARMUP_START_WEAPONS;
 563                 } else {
 564                         this.ammo_shells = start_ammo_shells;
 565                         this.ammo_nails = start_ammo_nails;
 566                         this.ammo_rockets = start_ammo_rockets;
 567                         this.ammo_cells = start_ammo_cells;
 568                         this.ammo_plasma = start_ammo_plasma;
 569                         this.ammo_fuel = start_ammo_fuel;
 570                         this.health = start_health;
 571                         this.armorvalue = start_armorvalue;
 572                         this.weapons = start_weapons;
 573                 }
 574                 SetSpectatee_status(this, 0);
 575
 576                 this.dual_weapons = '0 0 0';
 577
 578                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 579
 580                 this.items = start_items;
 581
 582                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 583                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 584                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 585                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 586                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 587                 // extend the pause of rotting if client was reset at the beginning of the countdown
 588                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 589                         float f = game_starttime - time;
 590                         this.spawnshieldtime += f;
 591                         this.pauserotarmor_finished += f;
 592                         this.pauserothealth_finished += f;
 593                         this.pauseregen_finished += f;
 594                 }
 595                 this.damageforcescale = 2;
 596                 this.death_time = 0;
 597                 this.respawn_flags = 0;
 598                 this.respawn_time = 0;
 599                 this.stat_respawn_time = 0;
 600                 this.scale = autocvar_sv_player_scale;
 601                 this.fade_time = 0;
 602                 this.pain_frame = 0;
 603                 this.pain_finished = 0;
 604                 this.pushltime = 0;
 605                 setthink(this, func_null); // players have no think function
 606                 this.nextthink = 0;
 607                 this.dmg_team = 0;
 608                 this.ballistics_density = autocvar_g_ballistics_density_player;
 609
 610                 this.deadflag = DEAD_NO;
 611
 612                 this.angles = spot.angles;
 613                 this.angles_z = 0; // never spawn tilted even if the spot says to
 614                 if (IS_BOT_CLIENT(this))
 615                         this.v_angle = this.angles;
 616                 this.fixangle = true; // turn this way immediately
 617                 this.oldvelocity = this.velocity = '0 0 0';
 618                 this.avelocity = '0 0 0';
 619                 this.punchangle = '0 0 0';
 620                 this.punchvector = '0 0 0';
 621
 622                 this.strength_finished = 0;
 623                 this.invincible_finished = 0;
 624                 this.fire_endtime = -1;
 625                 this.revive_progress = 0;
 626                 this.revival_time = 0;
 627                 this.air_finished = time + 12;
 628
 629                 entity spawnevent = new_pure(spawnevent);
 630                 spawnevent.owner = this;
 631                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 632
 633                 // Cut off any still running player sounds.
 634                 stopsound(this, CH_PLAYER_SINGLE);
 635
 636                 this.model = "";
 637                 FixPlayermodel(this);
 638                 this.drawonlytoclient = NULL;
 639
 640                 this.viewloc = NULL;
 641
 642                 this.crouch = false;
 643                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 644                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 645                 this.spawnorigin = spot.origin;
 646                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 647                 // don't reset back to last position, even if new position is stuck in solid
 648                 this.oldorigin = this.origin;
 649                 this.prevorigin = this.origin;
 650                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 651                 if(this.conveyor)
 652                         IL_REMOVE(g_conveyed, this);
 653                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 654                 this.hud = HUD_NORMAL;
 655
 656                 this.event_damage = PlayerDamage;
 657
 658                 if(!this.bot_attack)
 659                         IL_PUSH(g_bot_targets, this);
 660                 this.bot_attack = true;
 661                 this.monster_attack = true;
 662                 navigation_dynamicgoal_init(this, false);
 663
 664                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 665
 666                 if (this.killcount == FRAGS_SPECTATOR) {
 667                         PlayerScore_Clear(this);
 668                         this.killcount = 0;
 669                 }
 670
 671                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 672                 {
 673                         .entity weaponentity = weaponentities[slot];
 674                         entity oldwep = this.(weaponentity);
 675                         CL_SpawnWeaponentity(this, weaponentity);
 676                         if(oldwep && oldwep.owner == this)
 677                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 678                 }
 679                 this.alpha = default_player_alpha;
 680                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 681                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 682
 683                 this.speedrunning = false;
 684
 685                 target_voicescript_clear(this);
 686
 687                 // reset fields the weapons may use
 688                 FOREACH(Weapons, true, LAMBDA(
 689                         it.wr_resetplayer(it, this);
 690                         // reload all reloadable weapons
 691                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 692                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693                                 {
 694                                         .entity weaponentity = weaponentities[slot];
 695                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 696                                 }
 697                         }
 698                 ));
 699
 700                 {
 701                         string s = spot.target;
 702                         spot.target = string_null;
 703                         SUB_UseTargets(spot, this, NULL);
 704                         spot.target = s;
 705                 }
 706
 707                 Unfreeze(this);
 708
 709                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 710
 711                 if (autocvar_spawn_debug)
 712                 {
 713                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 714                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 715                 }
 716
 717                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718                 {
 719                         .entity weaponentity = weaponentities[slot];
 720                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 721                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 722                         else
 723                                 this.(weaponentity).m_switchweapon = WEP_Null;
 724                         this.(weaponentity).m_weapon = WEP_Null;
 725                         this.(weaponentity).weaponname = "";
 726                         this.(weaponentity).m_switchingweapon = WEP_Null;
 727                         this.(weaponentity).cnt = -1;
 728                 }
 729
 730                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 731
 732                 if (!warmup_stage && !this.alivetime)
 733                         this.alivetime = time;
 734
 735                 antilag_clear(this, CS(this));
 736         }
 737 }
 738
 739 void ClientInit_misc(entity this);
 740
 741 // TODO do we need all these fields, or should we stop autodetecting runtime
 742 // changes and just have a console command to update this?
 743 bool ClientInit_SendEntity(entity this, entity to, int sf)
 744 {
 745         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 746         return = true;
 747         msg_entity = to;
 748         // MSG_INIT replacement
 749         // TODO: make easier to use
 750         Registry_send_all();
 751         W_PROP_reload(MSG_ONE, to);
 752         ClientInit_misc(this);
 753         MUTATOR_CALLHOOK(Ent_Init);
 754 }
 755 void ClientInit_misc(entity this)
 756 {
 757         int channel = MSG_ONE;
 758         WriteHeader(channel, ENT_CLIENT_INIT);
 759         WriteByte(channel, g_nexball_meter_period * 32);
 760         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 764         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 768
 769         if(sv_foginterval && world.fog != "")
 770                 WriteString(channel, world.fog);
 771         else
 772                 WriteString(channel, "");
 773         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 774         WriteByte(channel, serverflags);
 775         WriteCoord(channel, autocvar_g_trueaim_minrange);
 776 }
 777
 778 void ClientInit_CheckUpdate(entity this)
 779 {
 780         this.nextthink = time;
 781         if(this.count != autocvar_g_balance_armor_blockpercent)
 782         {
 783                 this.count = autocvar_g_balance_armor_blockpercent;
 784                 this.SendFlags |= 1;
 785         }
 786 }
 787
 788 void ClientInit_Spawn()
 789 {
 790         entity e = new_pure(clientinit);
 791         setthink(e, ClientInit_CheckUpdate);
 792         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 793
 794         ClientInit_CheckUpdate(e);
 795 }
 796
 797 /*
 798 =============
 799 SetNewParms
 800 =============
 801 */
 802 void SetNewParms ()
 803 {
 804         // initialize parms for a new player
 805         parm1 = -(86400 * 366);
 806
 807         MUTATOR_CALLHOOK(SetNewParms);
 808 }
 809
 810 /*
 811 =============
 812 SetChangeParms
 813 =============
 814 */
 815 void SetChangeParms (entity this)
 816 {
 817         // save parms for level change
 818         parm1 = this.parm_idlesince - time;
 819
 820         MUTATOR_CALLHOOK(SetChangeParms);
 821 }
 822
 823 /*
 824 =============
 825 DecodeLevelParms
 826 =============
 827 */
 828 void DecodeLevelParms(entity this)
 829 {
 830         // load parms
 831         this.parm_idlesince = parm1;
 832         if (this.parm_idlesince == -(86400 * 366))
 833                 this.parm_idlesince = time;
 834
 835         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 836         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 837
 838         MUTATOR_CALLHOOK(DecodeLevelParms);
 839 }
 840
 841 /*
 842 =============
 843 ClientKill
 844
 845 Called when a client types 'kill' in the console
 846 =============
 847 */
 848
 849 .float clientkill_nexttime;
 850 void ClientKill_Now_TeamChange(entity this)
 851 {
 852         if(this.killindicator_teamchange == -1)
 853         {
 854                 JoinBestTeam( this, false, true );
 855         }
 856         else if(this.killindicator_teamchange == -2)
 857         {
 858                 if(blockSpectators)
 859                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 860                 PutObserverInServer(this);
 861         }
 862         else
 863                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 864         this.killindicator_teamchange = 0;
 865 }
 866
 867 void ClientKill_Now(entity this)
 868 {
 869         if(this.vehicle)
 870         {
 871             vehicles_exit(this.vehicle, VHEF_RELEASE);
 872             if(!this.killindicator_teamchange)
 873             {
 874             this.vehicle_health = -1;
 875             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 876             }
 877         }
 878
 879         if(this.killindicator && !wasfreed(this.killindicator))
 880                 delete(this.killindicator);
 881
 882         this.killindicator = NULL;
 883
 884         if(this.killindicator_teamchange)
 885                 ClientKill_Now_TeamChange(this);
 886
 887         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 888                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 889
 890         // now I am sure the player IS dead
 891 }
 892 void KillIndicator_Think(entity this)
 893 {
 894         if (game_stopped)
 895         {
 896                 this.owner.killindicator = NULL;
 897                 delete(this);
 898                 return;
 899         }
 900
 901         if (this.owner.alpha < 0 && !this.owner.vehicle)
 902         {
 903                 this.owner.killindicator = NULL;
 904                 delete(this);
 905                 return;
 906         }
 907
 908         if(this.cnt <= 0)
 909         {
 910                 ClientKill_Now(this.owner);
 911                 return;
 912         }
 913     else if(this.health == 1) // health == 1 means that it's silent
 914     {
 915         this.nextthink = time + 1;
 916         this.cnt -= 1;
 917     }
 918         else
 919         {
 920                 if(this.cnt <= 10)
 921                         setmodel(this, MDL_NUM(this.cnt));
 922                 if(IS_REAL_CLIENT(this.owner))
 923                 {
 924                         if(this.cnt <= 10)
 925                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 926                 }
 927                 this.nextthink = time + 1;
 928                 this.cnt -= 1;
 929         }
 930 }
 931
 932 float clientkilltime;
 933 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 934 {
 935         float killtime;
 936         float starttime;
 937
 938         if (game_stopped)
 939                 return;
 940
 941         killtime = autocvar_g_balance_kill_delay;
 942
 943     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 944         return;
 945     killtime = M_ARGV(1, float);
 946
 947         this.killindicator_teamchange = targetteam;
 948
 949     if(!this.killindicator)
 950         {
 951                 if(!IS_DEAD(this))
 952                 {
 953                         killtime = max(killtime, this.clientkill_nexttime - time);
 954                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 955                 }
 956
 957                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 958                 {
 959                         ClientKill_Now(this);
 960                 }
 961                 else
 962                 {
 963                         starttime = max(time, clientkilltime);
 964
 965                         this.killindicator = spawn();
 966                         this.killindicator.owner = this;
 967                         this.killindicator.scale = 0.5;
 968                         setattachment(this.killindicator, this, "");
 969                         setorigin(this.killindicator, '0 0 52');
 970                         setthink(this.killindicator, KillIndicator_Think);
 971                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 972                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 973                         this.killindicator.cnt = ceil(killtime);
 974                         this.killindicator.count = bound(0, ceil(killtime), 10);
 975                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 976
 977                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 978                         {
 979                                 it.killindicator = spawn();
 980                                 it.killindicator.owner = it;
 981                                 it.killindicator.scale = 0.5;
 982                                 setattachment(it.killindicator, it, "");
 983                                 setorigin(it.killindicator, '0 0 52');
 984                                 setthink(it.killindicator, KillIndicator_Think);
 985                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 986                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 987                                 it.killindicator.cnt = ceil(killtime);
 988                         });
 989                         this.lip = 0;
 990                 }
 991         }
 992         if(this.killindicator)
 993         {
 994                 if(targetteam == 0) // just die
 995                 {
 996                         this.killindicator.colormod = '0 0 0';
 997                         if(IS_REAL_CLIENT(this))
 998                         if(this.killindicator.cnt > 0)
 999                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1000                 }
1001                 else if(targetteam == -1) // auto
1002                 {
1003                         this.killindicator.colormod = '0 1 0';
1004                         if(IS_REAL_CLIENT(this))
1005                         if(this.killindicator.cnt > 0)
1006                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1007                 }
1008                 else if(targetteam == -2) // spectate
1009                 {
1010                         this.killindicator.colormod = '0.5 0.5 0.5';
1011                         if(IS_REAL_CLIENT(this))
1012                         if(this.killindicator.cnt > 0)
1013                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1014                 }
1015                 else
1016                 {
1017                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1018                         if(IS_REAL_CLIENT(this))
1019                         if(this.killindicator.cnt > 0)
1020                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1021                 }
1022         }
1023
1024 }
1025
1026 void ClientKill (entity this)
1027 {
1028         if(game_stopped) return;
1029         if(this.player_blocked) return;
1030         if(STAT(FROZEN, this)) return;
1031
1032         ClientKill_TeamChange(this, 0);
1033 }
1034
1035 void FixClientCvars(entity e)
1036 {
1037         // send prediction settings to the client
1038         stuffcmd(e, "\nin_bindmap 0 0\n");
1039         if(autocvar_g_antilag == 3) // client side hitscan
1040                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1041         if(autocvar_sv_gentle)
1042                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1043
1044         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1045         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1046
1047         MUTATOR_CALLHOOK(FixClientCvars, e);
1048 }
1049
1050 float PlayerInIDList(entity p, string idlist)
1051 {
1052         float n, i;
1053         string s;
1054
1055         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1056         if (!p.crypto_idfp)
1057                 return 0;
1058
1059         // this function allows abbreviated player IDs too!
1060         n = tokenize_console(idlist);
1061         for(i = 0; i < n; ++i)
1062         {
1063                 s = argv(i);
1064                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1065                         return 1;
1066         }
1067
1068         return 0;
1069 }
1070
1071 #ifdef DP_EXT_PRECONNECT
1072 /*
1073 =============
1074 ClientPreConnect
1075
1076 Called once (not at each match start) when a client begins a connection to the server
1077 =============
1078 */
1079 void ClientPreConnect(entity this)
1080 {
1081         if(autocvar_sv_eventlog)
1082         {
1083                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1084                         this.playerid,
1085                         etof(this),
1086                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1087                 ));
1088         }
1089 }
1090 #endif
1091
1092 /**
1093 =============
1094 ClientConnect
1095
1096 Called when a client connects to the server
1097 =============
1098 */
1099 void ClientConnect(entity this)
1100 {
1101         if (Ban_MaybeEnforceBanOnce(this)) return;
1102         assert(!IS_CLIENT(this), return);
1103         this.flags |= FL_CLIENT;
1104         assert(player_count >= 0, player_count = 0);
1105
1106 #ifdef WATERMARK
1107         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1108 #endif
1109         this.version_nagtime = time + 10 + random() * 10;
1110         TRANSMUTE(Client, this);
1111
1112         // identify the right forced team
1113         if (autocvar_g_campaign)
1114         {
1115                 if (IS_REAL_CLIENT(this)) // only players, not bots
1116                 {
1117                         switch (autocvar_g_campaign_forceteam)
1118                         {
1119                                 case 1: this.team_forced = NUM_TEAM_1; break;
1120                                 case 2: this.team_forced = NUM_TEAM_2; break;
1121                                 case 3: this.team_forced = NUM_TEAM_3; break;
1122                                 case 4: this.team_forced = NUM_TEAM_4; break;
1123                                 default: this.team_forced = 0;
1124                         }
1125                 }
1126         }
1127         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1128         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1129         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1130         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1131         else switch (autocvar_g_forced_team_otherwise)
1132         {
1133                 default: this.team_forced = 0; break;
1134                 case "red": this.team_forced = NUM_TEAM_1; break;
1135                 case "blue": this.team_forced = NUM_TEAM_2; break;
1136                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1137                 case "pink": this.team_forced = NUM_TEAM_4; break;
1138                 case "spectate":
1139                 case "spectator":
1140                         this.team_forced = -1;
1141                         break;
1142         }
1143         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1144
1145     {
1146         int id = this.playerid;
1147         this.playerid = 0; // silent
1148             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1149             this.playerid = id;
1150     }
1151
1152         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1153                 TRANSMUTE(Observer, this);
1154         } else {
1155                 if (!teamplay || autocvar_g_balance_teams) {
1156                         TRANSMUTE(Player, this);
1157                         campaign_bots_may_start = true;
1158                 } else {
1159                         TRANSMUTE(Observer, this); // do it anyway
1160                 }
1161         }
1162
1163         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1164
1165         // always track bots, don't ask for cl_allow_uidtracking
1166     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1167
1168         if (autocvar_sv_eventlog)
1169                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1170
1171         LogTeamchange(this.playerid, this.team, 1);
1172
1173         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1174
1175         this.netname_previous = strzone(this.netname);
1176
1177         if(teamplay && IS_PLAYER(this))
1178                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1179         else
1180                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1181
1182         stuffcmd(this, clientstuff, "\n");
1183         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1184
1185         FixClientCvars(this);
1186
1187         // get version info from player
1188         stuffcmd(this, "cmd clientversion $gameversion\n");
1189
1190         // notify about available teams
1191         if (teamplay)
1192         {
1193                 CheckAllowedTeams(this);
1194                 int t = 0;
1195                 if (c1 >= 0) t |= BIT(0);
1196                 if (c2 >= 0) t |= BIT(1);
1197                 if (c3 >= 0) t |= BIT(2);
1198                 if (c4 >= 0) t |= BIT(3);
1199                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1200         }
1201         else
1202         {
1203                 stuffcmd(this, "set _teams_available 0\n");
1204         }
1205
1206         bot_relinkplayerlist();
1207
1208         this.spectatortime = time;
1209         if (blockSpectators)
1210         {
1211                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1212         }
1213
1214         this.jointime = time;
1215         this.allowed_timeouts = autocvar_sv_timeout_number;
1216
1217         if (IS_REAL_CLIENT(this))
1218         {
1219                 if (g_weaponarena_weapons == WEPSET(TUBA))
1220                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1221         }
1222
1223         if (!sv_foginterval && world.fog != "")
1224                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1225
1226         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1227                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1228                         send_CSQC_teamnagger();
1229
1230         CSQCMODEL_AUTOINIT(this);
1231
1232         this.model_randomizer = random();
1233
1234         if (IS_REAL_CLIENT(this))
1235                 sv_notice_join(this);
1236
1237         // update physics stats (players can spawn before physics runs)
1238         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1239         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1240         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1241
1242         IL_EACH(g_initforplayer, it.init_for_player, {
1243                 it.init_for_player(it, this);
1244         });
1245
1246         MUTATOR_CALLHOOK(ClientConnect, this);
1247
1248         if (IS_REAL_CLIENT(this))
1249         {
1250                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1251                 {
1252                         this.motd_actived_time = -1;
1253                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1254                 }
1255         }
1256 }
1257 /*
1258 =============
1259 ClientDisconnect
1260
1261 Called when a client disconnects from the server
1262 =============
1263 */
1264 .entity chatbubbleentity;
1265 void ReadyCount();
1266 void ClientDisconnect(entity this)
1267 {
1268         assert(IS_CLIENT(this), return);
1269
1270         PlayerStats_GameReport_FinalizePlayer(this);
1271         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1272         if (this.active_minigame) part_minigame(this);
1273         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1274
1275         if (autocvar_sv_eventlog)
1276                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1277
1278         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1279
1280         if(IS_SPEC(this))
1281                 SetSpectatee(this, NULL);
1282
1283     MUTATOR_CALLHOOK(ClientDisconnect, this);
1284
1285         ClientState_detach(this);
1286
1287         Portal_ClearAll(this);
1288
1289         Unfreeze(this);
1290
1291         RemoveGrapplingHooks(this);
1292
1293         // Here, everything has been done that requires this player to be a client.
1294
1295         this.flags &= ~FL_CLIENT;
1296
1297         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1298         if (this.killindicator) delete(this.killindicator);
1299
1300         WaypointSprite_PlayerGone(this);
1301
1302         bot_relinkplayerlist();
1303
1304         if (this.netname_previous) strunzone(this.netname_previous);
1305         if (this.clientstatus) strunzone(this.clientstatus);
1306         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1307         if (this.personal) delete(this.personal);
1308
1309         this.playerid = 0;
1310         ReadyCount();
1311         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1312
1313         ONREMOVE(this);
1314 }
1315
1316 void ChatBubbleThink(entity this)
1317 {
1318         this.nextthink = time;
1319         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1320         {
1321                 if(this.owner) // but why can that ever be NULL?
1322                         this.owner.chatbubbleentity = NULL;
1323                 delete(this);
1324                 return;
1325         }
1326
1327         this.mdl = "";
1328
1329         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1330         {
1331                 if ( this.owner.active_minigame )
1332                         this.mdl = "models/sprites/minigame_busy.iqm";
1333                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1334                         this.mdl = "models/misc/chatbubble.spr";
1335         }
1336
1337         if ( this.model != this.mdl )
1338                 _setmodel(this, this.mdl);
1339
1340 }
1341
1342 void UpdateChatBubble(entity this)
1343 {
1344         if (this.alpha < 0)
1345                 return;
1346         // spawn a chatbubble entity if needed
1347         if (!this.chatbubbleentity)
1348         {
1349                 this.chatbubbleentity = new(chatbubbleentity);
1350                 this.chatbubbleentity.owner = this;
1351                 this.chatbubbleentity.exteriormodeltoclient = this;
1352                 setthink(this.chatbubbleentity, ChatBubbleThink);
1353                 this.chatbubbleentity.nextthink = time;
1354                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1355                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1356                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1357                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1358                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1359                 //this.chatbubbleentity.model = "";
1360                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1361         }
1362 }
1363
1364
1365 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1366 // added to the model skins
1367 /*void UpdateColorModHack()
1368 {
1369         float c;
1370         c = this.clientcolors & 15;
1371         // LordHavoc: only bothering to support white, green, red, yellow, blue
1372              if (!teamplay) this.colormod = '0 0 0';
1373         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1374         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1375         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1376         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1377         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1378         else this.colormod = '1 1 1';
1379 }*/
1380
1381 void respawn(entity this)
1382 {
1383         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1384         {
1385                 this.solid = SOLID_NOT;
1386                 this.takedamage = DAMAGE_NO;
1387                 set_movetype(this, MOVETYPE_FLY);
1388                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1389                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1390                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1391                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1392                 if(autocvar_g_respawn_ghosts_maxtime)
1393                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1394         }
1395
1396         CopyBody(this, 1);
1397
1398         this.effects |= EF_NODRAW; // prevent another CopyBody
1399         PutClientInServer(this);
1400 }
1401
1402 void play_countdown(entity this, float finished, Sound samp)
1403 {
1404     TC(Sound, samp);
1405         if(IS_REAL_CLIENT(this))
1406                 if(floor(finished - time - frametime) != floor(finished - time))
1407                         if(finished - time < 6)
1408                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1409 }
1410
1411 void player_powerups(entity this)
1412 {
1413         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1414         int items_prev = this.items;
1415
1416         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1417                 this.modelflags |= MF_ROCKET;
1418         else
1419                 this.modelflags &= ~MF_ROCKET;
1420
1421         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1422
1423         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1424                 return;
1425
1426         Fire_ApplyDamage(this);
1427         Fire_ApplyEffect(this);
1428
1429         if (!g_instagib)
1430         {
1431                 if (this.items & ITEM_Strength.m_itemid)
1432                 {
1433                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1434                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1435                         if (time > this.strength_finished)
1436                         {
1437                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1438                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1439                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1440                         }
1441                 }
1442                 else
1443                 {
1444                         if (time < this.strength_finished)
1445                         {
1446                                 this.items = this.items | ITEM_Strength.m_itemid;
1447                                 if(!g_cts)
1448                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1449                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1450                         }
1451                 }
1452                 if (this.items & ITEM_Shield.m_itemid)
1453                 {
1454                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1455                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1456                         if (time > this.invincible_finished)
1457                         {
1458                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1459                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1460                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1461                         }
1462                 }
1463                 else
1464                 {
1465                         if (time < this.invincible_finished)
1466                         {
1467                                 this.items = this.items | ITEM_Shield.m_itemid;
1468                                 if(!g_cts)
1469                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1470                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1471                         }
1472                 }
1473                 if (this.items & IT_SUPERWEAPON)
1474                 {
1475                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1476                         {
1477                                 this.superweapons_finished = 0;
1478                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1479                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1480                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1481                         }
1482                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1483                         {
1484                                 // don't let them run out
1485                         }
1486                         else
1487                         {
1488                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1489                                 if (time > this.superweapons_finished)
1490                                 {
1491                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1492                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1493                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1494                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1495                                 }
1496                         }
1497                 }
1498                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1499                 {
1500                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1501                         {
1502                                 this.items = this.items | IT_SUPERWEAPON;
1503                                 if(!g_cts)
1504                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1505                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1506                         }
1507                         else
1508                         {
1509                                 this.superweapons_finished = 0;
1510                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1511                         }
1512                 }
1513                 else
1514                 {
1515                         this.superweapons_finished = 0;
1516                 }
1517         }
1518
1519         if(autocvar_g_nodepthtestplayers)
1520                 this.effects = this.effects | EF_NODEPTHTEST;
1521
1522         if(autocvar_g_fullbrightplayers)
1523                 this.effects = this.effects | EF_FULLBRIGHT;
1524
1525         if (time >= game_starttime)
1526         if (time < this.spawnshieldtime)
1527                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1528
1529         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1530 }
1531
1532 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1533 {
1534         if(current > stable)
1535                 return current;
1536         else if(current > stable - 0.25) // when close enough, "snap"
1537                 return stable;
1538         else
1539                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1540 }
1541
1542 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1543 {
1544         if(current < stable)
1545                 return current;
1546         else if(current < stable + 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1550 }
1551
1552 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1553 {
1554         if(current > rotstable)
1555         {
1556                 if(rotframetime > 0)
1557                 {
1558                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1559                         current = max(rotstable, current - rotlinear * rotframetime);
1560                 }
1561         }
1562         else if(current < regenstable)
1563         {
1564                 if(regenframetime > 0)
1565                 {
1566                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1567                         current = min(regenstable, current + regenlinear * regenframetime);
1568                 }
1569         }
1570
1571         if(current > limit)
1572                 current = limit;
1573
1574         return current;
1575 }
1576
1577 void player_regen(entity this)
1578 {
1579         float max_mod, regen_mod, rot_mod, limit_mod;
1580         max_mod = regen_mod = rot_mod = limit_mod = 1;
1581
1582         float regen_health = autocvar_g_balance_health_regen;
1583         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1584         float regen_health_rot = autocvar_g_balance_health_rot;
1585         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1586         float regen_health_stable = autocvar_g_balance_health_regenstable;
1587         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1588         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1589                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1590         max_mod = M_ARGV(1, float);
1591         regen_mod = M_ARGV(2, float);
1592         rot_mod = M_ARGV(3, float);
1593         limit_mod = M_ARGV(4, float);
1594         regen_health = M_ARGV(5, float);
1595         regen_health_linear = M_ARGV(6, float);
1596         regen_health_rot = M_ARGV(7, float);
1597         regen_health_rotlinear = M_ARGV(8, float);
1598         regen_health_stable = M_ARGV(9, float);
1599         regen_health_rotstable = M_ARGV(10, float);
1600
1601
1602         if(!mutator_returnvalue)
1603         if(!STAT(FROZEN, this))
1604         {
1605                 float mina, maxa, limith, limita;
1606                 maxa = autocvar_g_balance_armor_rotstable;
1607                 mina = autocvar_g_balance_armor_regenstable;
1608                 limith = autocvar_g_balance_health_limit;
1609                 limita = autocvar_g_balance_armor_limit;
1610
1611                 regen_health_rotstable = regen_health_rotstable * max_mod;
1612                 regen_health_stable = regen_health_stable * max_mod;
1613                 limith = limith * limit_mod;
1614                 limita = limita * limit_mod;
1615
1616                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1617                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1618         }
1619
1620         // if player rotted to death...  die!
1621         // check this outside above checks, as player may still be able to rot to death
1622         if(this.health < 1)
1623         {
1624                 if(this.vehicle)
1625                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1626                 if(this.event_damage)
1627                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1628         }
1629
1630         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1631         {
1632                 float minf, maxf, limitf;
1633
1634                 maxf = autocvar_g_balance_fuel_rotstable;
1635                 minf = autocvar_g_balance_fuel_regenstable;
1636                 limitf = autocvar_g_balance_fuel_limit;
1637
1638                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1639         }
1640 }
1641
1642 bool zoomstate_set;
1643 void SetZoomState(entity this, float newzoom)
1644 {
1645         if(newzoom != this.zoomstate)
1646         {
1647                 this.zoomstate = newzoom;
1648                 ClientData_Touch(this);
1649         }
1650         zoomstate_set = true;
1651 }
1652
1653 void GetPressedKeys(entity this)
1654 {
1655         MUTATOR_CALLHOOK(GetPressedKeys, this);
1656         int keys = STAT(PRESSED_KEYS, this);
1657         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1658         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1659         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1660         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1661
1662         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1663         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1664         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1665         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1666         this.pressedkeys = keys; // store for other users
1667
1668         STAT(PRESSED_KEYS, this) = keys;
1669 }
1670
1671 /*
1672 ======================
1673 spectate mode routines
1674 ======================
1675 */
1676
1677 void SpectateCopy(entity this, entity spectatee)
1678 {
1679     TC(Client, this); TC(Client, spectatee);
1680
1681         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1682         PS(this) = PS(spectatee);
1683         this.armortype = spectatee.armortype;
1684         this.armorvalue = spectatee.armorvalue;
1685         this.ammo_cells = spectatee.ammo_cells;
1686         this.ammo_plasma = spectatee.ammo_plasma;
1687         this.ammo_shells = spectatee.ammo_shells;
1688         this.ammo_nails = spectatee.ammo_nails;
1689         this.ammo_rockets = spectatee.ammo_rockets;
1690         this.ammo_fuel = spectatee.ammo_fuel;
1691         this.clip_load = spectatee.clip_load;
1692         this.clip_size = spectatee.clip_size;
1693         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1694         this.health = spectatee.health;
1695         this.impulse = 0;
1696         this.items = spectatee.items;
1697         this.last_pickup = spectatee.last_pickup;
1698         this.hit_time = spectatee.hit_time;
1699         this.strength_finished = spectatee.strength_finished;
1700         this.invincible_finished = spectatee.invincible_finished;
1701         this.superweapons_finished = spectatee.superweapons_finished;
1702         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1703         this.weapons = spectatee.weapons;
1704         this.dual_weapons = spectatee.dual_weapons;
1705         this.vortex_charge = spectatee.vortex_charge;
1706         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1707         this.hagar_load = spectatee.hagar_load;
1708         this.arc_heat_percent = spectatee.arc_heat_percent;
1709         this.minelayer_mines = spectatee.minelayer_mines;
1710         this.punchangle = spectatee.punchangle;
1711         this.view_ofs = spectatee.view_ofs;
1712         this.velocity = spectatee.velocity;
1713         this.dmg_take = spectatee.dmg_take;
1714         this.dmg_save = spectatee.dmg_save;
1715         this.dmg_inflictor = spectatee.dmg_inflictor;
1716         this.v_angle = spectatee.v_angle;
1717         this.angles = spectatee.v_angle;
1718         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1719         this.revive_progress = spectatee.revive_progress;
1720         this.viewloc = spectatee.viewloc;
1721         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1722                 this.fixangle = true;
1723         setorigin(this, spectatee.origin);
1724         setsize(this, spectatee.mins, spectatee.maxs);
1725         SetZoomState(this, spectatee.zoomstate);
1726
1727         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1728         {
1729                 .entity weaponentity = weaponentities[slot];
1730                 this.(weaponentity) = spectatee.(weaponentity);
1731         }
1732
1733         for(int slot = 0; slot < MAX_AXH; ++slot)
1734         {
1735                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1736         }
1737
1738     anticheat_spectatecopy(this, spectatee);
1739         this.hud = spectatee.hud;
1740         if(spectatee.vehicle)
1741     {
1742         this.angles = spectatee.v_angle;
1743
1744         //this.fixangle = false;
1745         //this.velocity = spectatee.vehicle.velocity;
1746         this.vehicle_health = spectatee.vehicle_health;
1747         this.vehicle_shield = spectatee.vehicle_shield;
1748         this.vehicle_energy = spectatee.vehicle_energy;
1749         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1750         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1751         this.vehicle_reload1 = spectatee.vehicle_reload1;
1752         this.vehicle_reload2 = spectatee.vehicle_reload2;
1753
1754         //msg_entity = this;
1755
1756        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1757             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1758            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1759            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1760
1761         //WriteByte (MSG_ONE, SVC_SETVIEW);
1762         //    WriteEntity(MSG_ONE, this);
1763         //makevectors(spectatee.v_angle);
1764         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1765     }
1766 }
1767
1768 bool SpectateUpdate(entity this)
1769 {
1770         if(!this.enemy)
1771                 return false;
1772
1773         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1774         {
1775                 SetSpectatee(this, NULL);
1776                 return false;
1777         }
1778
1779         SpectateCopy(this, this.enemy);
1780
1781         return true;
1782 }
1783
1784 bool SpectateSet(entity this)
1785 {
1786         if(!IS_PLAYER(this.enemy))
1787                 return false;
1788
1789         ClientData_Touch(this.enemy);
1790
1791         msg_entity = this;
1792         WriteByte(MSG_ONE, SVC_SETVIEW);
1793         WriteEntity(MSG_ONE, this.enemy);
1794         set_movetype(this, MOVETYPE_NONE);
1795         accuracy_resend(this);
1796
1797         if(!SpectateUpdate(this))
1798                 PutObserverInServer(this);
1799
1800         return true;
1801 }
1802
1803 void SetSpectatee_status(entity this, int spectatee_num)
1804 {
1805         int oldspectatee_status = this.spectatee_status;
1806         this.spectatee_status = spectatee_num;
1807
1808         if (this.spectatee_status != oldspectatee_status)
1809         {
1810                 ClientData_Touch(this);
1811                 if (g_race || g_cts) race_InitSpectator();
1812         }
1813 }
1814
1815 void SetSpectatee(entity this, entity spectatee)
1816 {
1817         if(IS_BOT_CLIENT(this))
1818                 return; // bots abuse .enemy, this code is useless to them
1819
1820         entity old_spectatee = this.enemy;
1821
1822         this.enemy = spectatee;
1823
1824         // WEAPONTODO
1825         // these are required to fix the spectator bug with arc
1826         if(old_spectatee)
1827         {
1828                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1829                 {
1830                         .entity weaponentity = weaponentities[slot];
1831                         if(old_spectatee.(weaponentity).arc_beam)
1832                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1833                 }
1834         }
1835         if(this.enemy)
1836         {
1837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 {
1839                         .entity weaponentity = weaponentities[slot];
1840                         if(this.enemy.(weaponentity).arc_beam)
1841                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1842                 }
1843         }
1844
1845         if (this.enemy)
1846                 SetSpectatee_status(this, etof(this.enemy));
1847
1848         // needed to update spectator list
1849         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1850 }
1851
1852 bool Spectate(entity this, entity pl)
1853 {
1854         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1855                 return false;
1856         pl = M_ARGV(1, entity);
1857
1858         SetSpectatee(this, pl);
1859         return SpectateSet(this);
1860 }
1861
1862 bool SpectateNext(entity this)
1863 {
1864         entity ent = find(this.enemy, classname, STR_PLAYER);
1865
1866         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1867                 ent = M_ARGV(1, entity);
1868         else if (!ent)
1869                 ent = find(ent, classname, STR_PLAYER);
1870
1871         if(ent) { SetSpectatee(this, ent); }
1872
1873         return SpectateSet(this);
1874 }
1875
1876 bool SpectatePrev(entity this)
1877 {
1878         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1879         entity ent = findchain(classname, STR_PLAYER);
1880         if (!ent) // no player
1881                 return false;
1882
1883         entity first = ent;
1884         // skip players until current spectated player
1885         if(this.enemy)
1886         while(ent && ent != this.enemy)
1887                 ent = ent.chain;
1888
1889         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1890         {
1891                 case MUT_SPECPREV_FOUND:
1892                     ent = M_ARGV(1, entity);
1893                     break;
1894                 case MUT_SPECPREV_RETURN:
1895                     return true;
1896                 case MUT_SPECPREV_CONTINUE:
1897                 default:
1898                 {
1899                         if(ent.chain)
1900                                 ent = ent.chain;
1901                         else
1902                                 ent = first;
1903                         break;
1904                 }
1905         }
1906
1907         SetSpectatee(this, ent);
1908         return SpectateSet(this);
1909 }
1910
1911 /*
1912 =============
1913 ShowRespawnCountdown()
1914
1915 Update a respawn countdown display.
1916 =============
1917 */
1918 void ShowRespawnCountdown(entity this)
1919 {
1920         float number;
1921         if(!IS_DEAD(this)) // just respawned?
1922                 return;
1923         else
1924         {
1925                 number = ceil(this.respawn_time - time);
1926                 if(number <= 0)
1927                         return;
1928                 if(number <= this.respawn_countdown)
1929                 {
1930                         this.respawn_countdown = number - 1;
1931                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1932                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1933                 }
1934         }
1935 }
1936
1937 .bool team_selected;
1938 bool ShowTeamSelection(entity this)
1939 {
1940         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1941                 return false;
1942         stuffcmd(this, "menu_showteamselect\n");
1943         return true;
1944 }
1945 void Join(entity this)
1946 {
1947         TRANSMUTE(Player, this);
1948
1949         if(!this.team_selected)
1950         if(autocvar_g_campaign || autocvar_g_balance_teams)
1951                 JoinBestTeam(this, false, true);
1952
1953         if(autocvar_g_campaign)
1954                 campaign_bots_may_start = true;
1955
1956         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1957
1958         PutClientInServer(this);
1959
1960         if(IS_PLAYER(this))
1961         if(teamplay && this.team != -1)
1962                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1963         else
1964                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1965         this.team_selected = false;
1966 }
1967
1968 /**
1969  * Determines whether the player is allowed to join. This depends on cvar
1970  * g_maxplayers, if it isn't used this function always return true, otherwise
1971  * it checks whether the number of currently playing players exceeds g_maxplayers.
1972  * @return int number of free slots for players, 0 if none
1973  */
1974 int nJoinAllowed(entity this, entity ignore)
1975 {
1976         if(!ignore)
1977         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1978         // so report 0 free slots if restricted
1979         {
1980                 if(autocvar_g_forced_team_otherwise == "spectate")
1981                         return 0;
1982                 if(autocvar_g_forced_team_otherwise == "spectator")
1983                         return 0;
1984         }
1985
1986         if(this && this.team_forced < 0)
1987                 return 0; // forced spectators can never join
1988
1989         // TODO simplify this
1990         int totalClients = 0;
1991         int currentlyPlaying = 0;
1992         FOREACH_CLIENT(true, LAMBDA(
1993                 if(it != ignore)
1994                         ++totalClients;
1995                 if(IS_REAL_CLIENT(it))
1996                 if(IS_PLAYER(it) || it.caplayer)
1997                         ++currentlyPlaying;
1998         ));
1999
2000         float free_slots = 0;
2001         if (!autocvar_g_maxplayers)
2002                 free_slots = maxclients - totalClients;
2003         else if(currentlyPlaying < autocvar_g_maxplayers)
2004                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2005
2006         static float join_prevent_msg_time = 0;
2007         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2008         {
2009                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2010                 join_prevent_msg_time = time + 3;
2011         }
2012
2013         return free_slots;
2014 }
2015
2016 /**
2017  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2018  * g_maxplayers_spectator_blocktime seconds
2019  */
2020 void checkSpectatorBlock(entity this)
2021 {
2022         if(IS_SPEC(this) || IS_OBSERVER(this))
2023         if(!this.caplayer)
2024         if(IS_REAL_CLIENT(this))
2025         {
2026                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2027                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2028                         dropclient(this);
2029                 }
2030         }
2031 }
2032
2033 void PrintWelcomeMessage(entity this)
2034 {
2035         if(this.motd_actived_time == 0)
2036         {
2037                 if (autocvar_g_campaign) {
2038                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2039                                 this.motd_actived_time = time;
2040                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2041                         }
2042                 } else {
2043                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2044                                 this.motd_actived_time = time;
2045                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2046                         }
2047                 }
2048         }
2049         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2050         {
2051                 if (autocvar_g_campaign) {
2052                         if (PHYS_INPUT_BUTTON_INFO(this))
2053                                 this.motd_actived_time = time;
2054                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2055                                 this.motd_actived_time = 0;
2056                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2057                         }
2058                 } else {
2059                         if (PHYS_INPUT_BUTTON_INFO(this))
2060                                 this.motd_actived_time = time;
2061                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2062                                 this.motd_actived_time = 0;
2063                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2064                         }
2065                 }
2066         }
2067         else //if(this.motd_actived_time < 0) // just connected, motd is active
2068         {
2069                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2070                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2071                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2072                 {
2073                         // instanctly hide MOTD
2074                         this.motd_actived_time = 0;
2075                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2076                 }
2077         }
2078 }
2079
2080 bool joinAllowed(entity this)
2081 {
2082         if (this.version_mismatch) return false;
2083         if (!nJoinAllowed(this, this)) return false;
2084         if (teamplay && lockteams) return false;
2085         if (ShowTeamSelection(this)) return false;
2086         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2087         return true;
2088 }
2089
2090 void ObserverThink(entity this)
2091 {
2092         if ( this.impulse )
2093         {
2094                 MinigameImpulse(this, this.impulse);
2095                 this.impulse = 0;
2096         }
2097
2098         if (this.flags & FL_JUMPRELEASED) {
2099                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2100                         this.flags &= ~FL_JUMPRELEASED;
2101                         this.flags |= FL_SPAWNING;
2102                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2103                         this.flags &= ~FL_JUMPRELEASED;
2104                         if(SpectateNext(this)) {
2105                                 TRANSMUTE(Spectator, this);
2106                         }
2107                 } else {
2108                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2109                         set_movetype(this, preferred_movetype);
2110                 }
2111         } else {
2112                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2113                         this.flags |= FL_JUMPRELEASED;
2114                         if(this.flags & FL_SPAWNING)
2115                         {
2116                                 this.flags &= ~FL_SPAWNING;
2117                                 Join(this);
2118                                 return;
2119                         }
2120                 }
2121         }
2122 }
2123
2124 void SpectatorThink(entity this)
2125 {
2126         if ( this.impulse )
2127         {
2128                 if(MinigameImpulse(this, this.impulse))
2129                         this.impulse = 0;
2130
2131                 if (this.impulse == IMP_weapon_drop.impulse)
2132                 {
2133                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2134                         this.impulse = 0;
2135                         return;
2136                 }
2137         }
2138
2139         if (this.flags & FL_JUMPRELEASED) {
2140                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2141                         this.flags &= ~FL_JUMPRELEASED;
2142                         this.flags |= FL_SPAWNING;
2143                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2144                         this.flags &= ~FL_JUMPRELEASED;
2145                         if(SpectateNext(this)) {
2146                                 TRANSMUTE(Spectator, this);
2147                         } else {
2148                                 TRANSMUTE(Observer, this);
2149                                 PutClientInServer(this);
2150                         }
2151                         this.impulse = 0;
2152                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2153                         this.flags &= ~FL_JUMPRELEASED;
2154                         if(SpectatePrev(this)) {
2155                                 TRANSMUTE(Spectator, this);
2156                         } else {
2157                                 TRANSMUTE(Observer, this);
2158                                 PutClientInServer(this);
2159                         }
2160                         this.impulse = 0;
2161                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2162                         this.flags &= ~FL_JUMPRELEASED;
2163                         TRANSMUTE(Observer, this);
2164                         PutClientInServer(this);
2165                 } else {
2166                         if(!SpectateUpdate(this))
2167                                 PutObserverInServer(this);
2168                 }
2169         } else {
2170                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2171                         this.flags |= FL_JUMPRELEASED;
2172                         if(this.flags & FL_SPAWNING)
2173                         {
2174                                 this.flags &= ~FL_SPAWNING;
2175                                 Join(this);
2176                                 return;
2177                         }
2178                 }
2179                 if(!SpectateUpdate(this))
2180                         PutObserverInServer(this);
2181         }
2182
2183         this.flags |= FL_CLIENT | FL_NOTARGET;
2184 }
2185
2186 void vehicles_enter (entity pl, entity veh);
2187 void PlayerUseKey(entity this)
2188 {
2189         if (!IS_PLAYER(this))
2190                 return;
2191
2192         if(this.vehicle)
2193         {
2194                 if(!game_stopped)
2195                 {
2196                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2197                         return;
2198                 }
2199         }
2200         else if(autocvar_g_vehicles_enter)
2201         {
2202                 if(!STAT(FROZEN, this))
2203                 if(!IS_DEAD(this))
2204                 if(!game_stopped)
2205                 {
2206                         entity head, closest_target = NULL;
2207                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2208
2209                         while(head) // find the closest acceptable target to enter
2210                         {
2211                                 if(IS_VEHICLE(head))
2212                                 if(!IS_DEAD(head))
2213                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2214                                 if(head.takedamage != DAMAGE_NO)
2215                                 {
2216                                         if(closest_target)
2217                                         {
2218                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2219                                                 { closest_target = head; }
2220                                         }
2221                                         else { closest_target = head; }
2222                                 }
2223
2224                                 head = head.chain;
2225                         }
2226
2227                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2228                 }
2229         }
2230
2231         // a use key was pressed; call handlers
2232         MUTATOR_CALLHOOK(PlayerUseKey, this);
2233 }
2234
2235
2236 /*
2237 =============
2238 PlayerPreThink
2239
2240 Called every frame for each client before the physics are run
2241 =============
2242 */
2243 .float usekeypressed;
2244 .float last_vehiclecheck;
2245 .int items_added;
2246 void PlayerPreThink (entity this)
2247 {
2248         WarpZone_PlayerPhysics_FixVAngle(this);
2249
2250     STAT(GAMESTARTTIME, this) = game_starttime;
2251         STAT(ROUNDSTARTTIME, this) = round_starttime;
2252         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2253         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2254
2255         STAT(WEAPONSINMAP, this) = weaponsInMap;
2256
2257         if (frametime) {
2258                 // physics frames: update anticheat stuff
2259                 anticheat_prethink(this);
2260         }
2261
2262         if (blockSpectators && frametime) {
2263                 // WORKAROUND: only use dropclient in server frames (frametime set).
2264                 // Never use it in cl_movement frames (frametime zero).
2265                 checkSpectatorBlock(this);
2266     }
2267
2268         zoomstate_set = false;
2269
2270         // Check for nameless players
2271         if (isInvisibleString(this.netname)) {
2272                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2273                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2274         }
2275         if (this.netname != this.netname_previous) {
2276                 if (autocvar_sv_eventlog) {
2277                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2278         }
2279                 if (this.netname_previous) strunzone(this.netname_previous);
2280                 this.netname_previous = strzone(this.netname);
2281         }
2282
2283         // version nagging
2284         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2285         this.version_nagtime = 0;
2286         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2287             // git client
2288         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2289             // git server
2290             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2291         } else {
2292             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2293             if (r < 0) { // old client
2294                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2295             } else if (r > 0) { // old server
2296                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2297             }
2298         }
2299     }
2300
2301         // GOD MODE info
2302         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2303         {
2304                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2305                 this.max_armorvalue = 0;
2306         }
2307
2308         if (STAT(FROZEN, this) == 2)
2309         {
2310                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2311                 this.health = max(1, this.revive_progress * start_health);
2312                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2313
2314                 if (this.revive_progress >= 1)
2315                         Unfreeze(this);
2316         }
2317         else if (STAT(FROZEN, this) == 3)
2318         {
2319                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2320                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2321
2322                 if (this.health < 1)
2323                 {
2324                         if (this.vehicle)
2325                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2326                         if(this.event_damage)
2327                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2328                 }
2329                 else if (this.revive_progress <= 0)
2330                         Unfreeze(this);
2331         }
2332
2333         MUTATOR_CALLHOOK(PlayerPreThink, this);
2334
2335         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2336         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2337         {
2338                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2339                 {
2340                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2341                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2342                         {
2343                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2344                         }
2345                         else if(!it.owner)
2346                         {
2347                                 if(!it.team || SAME_TEAM(this, it))
2348                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2349                                 else if(autocvar_g_vehicles_steal)
2350                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2351                         }
2352                 });
2353
2354                 this.last_vehiclecheck = time + 1;
2355         }
2356
2357         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2358         {
2359                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2360                         PlayerUseKey(this);
2361                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2362         }
2363
2364         if (IS_REAL_CLIENT(this))
2365                 PrintWelcomeMessage(this);
2366
2367         if (IS_PLAYER(this)) {
2368                 CheckRules_Player(this);
2369
2370                 if (game_stopped || intermission_running) {
2371                         this.modelflags &= ~MF_ROCKET;
2372                         if(intermission_running)
2373                                 IntermissionThink(this);
2374                         return;
2375                 }
2376
2377                 if (timeout_status == TIMEOUT_ACTIVE) {
2378             // don't allow the player to turn around while game is paused
2379                         // FIXME turn this into CSQC stuff
2380                         this.v_angle = this.lastV_angle;
2381                         this.angles = this.lastV_angle;
2382                         this.fixangle = true;
2383                 }
2384
2385                 if (frametime) player_powerups(this);
2386
2387                 if (IS_DEAD(this)) {
2388                         if (this.personal && g_race_qualifying) {
2389                                 if (time > this.respawn_time) {
2390                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2391                                         respawn(this);
2392                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2393                                 }
2394                         } else {
2395                                 if (frametime) player_anim(this);
2396
2397                                 if (this.respawn_flags & RESPAWN_DENY)
2398                                 {
2399                                         STAT(RESPAWN_TIME, this) = 0;
2400                                         return;
2401                                 }
2402
2403                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2404
2405                                 switch(this.deadflag)
2406                                 {
2407                                         case DEAD_DYING:
2408                                         {
2409                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2410                                                         this.deadflag = DEAD_RESPAWNING;
2411                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2412                                                         this.deadflag = DEAD_DEAD;
2413                                                 break;
2414                                         }
2415                                         case DEAD_DEAD:
2416                                         {
2417                                                 if (button_pressed)
2418                                                         this.deadflag = DEAD_RESPAWNABLE;
2419                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2420                                                         this.deadflag = DEAD_RESPAWNING;
2421                                                 break;
2422                                         }
2423                                         case DEAD_RESPAWNABLE:
2424                                         {
2425                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2426                                                         this.deadflag = DEAD_RESPAWNING;
2427                                                 break;
2428                                         }
2429                                         case DEAD_RESPAWNING:
2430                                         {
2431                                                 if (time > this.respawn_time)
2432                                                 {
2433                                                         this.respawn_time = time + 1; // only retry once a second
2434                                                         this.respawn_time_max = this.respawn_time;
2435                                                         respawn(this);
2436                                                 }
2437                                                 break;
2438                                         }
2439                                 }
2440
2441                                 ShowRespawnCountdown(this);
2442
2443                                 if (this.respawn_flags & RESPAWN_SILENT)
2444                                         STAT(RESPAWN_TIME, this) = 0;
2445                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2446                                 {
2447                                         if (time < this.respawn_time)
2448                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2449                                         else if (this.deadflag != DEAD_RESPAWNING)
2450                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2451                                 }
2452                                 else
2453                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2454                         }
2455
2456                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2457                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2458                                 STAT(RESPAWN_TIME, this) *= -1;
2459
2460                         return;
2461                 }
2462
2463                 this.prevorigin = this.origin;
2464
2465                 bool have_hook = false;
2466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2467                 {
2468                         .entity weaponentity = weaponentities[slot];
2469                         if(this.(weaponentity).hook.state)
2470                         {
2471                                 have_hook = true;
2472                                 break;
2473                         }
2474                 }
2475                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2476                 if (have_hook) {
2477                         do_crouch = false;
2478                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2479                         do_crouch = false;
2480                 } else if (this.vehicle) {
2481                         do_crouch = false;
2482                 } else if (STAT(FROZEN, this)) {
2483                         do_crouch = false;
2484         }
2485
2486                 if (do_crouch) {
2487                         if (!this.crouch) {
2488                                 this.crouch = true;
2489                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2490                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2491                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2492                         }
2493                 } else if (this.crouch) {
2494             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2495             if (!trace_startsolid) {
2496                 this.crouch = false;
2497                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2498                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2499             }
2500                 }
2501
2502                 FixPlayermodel(this);
2503
2504                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2505                 //if(frametime)
2506                 {
2507                         this.items &= ~this.items_added;
2508
2509                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2510                         {
2511                                 .entity weaponentity = weaponentities[slot];
2512                                 W_WeaponFrame(this, weaponentity);
2513
2514                                 if(slot == 0)
2515                                 {
2516                                         this.clip_load = this.(weaponentity).clip_load;
2517                                         this.clip_size = this.(weaponentity).clip_size;
2518                                 }
2519                         }
2520
2521                         this.items_added = 0;
2522                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2523                 this.items_added |= IT_FUEL;
2524
2525                         this.items |= this.items_added;
2526                 }
2527
2528                 player_regen(this);
2529
2530                 // WEAPONTODO: Add a weapon request for this
2531                 // rot vortex charge to the charge limit
2532                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2533                 {
2534                         .entity weaponentity = weaponentities[slot];
2535                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2536                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2537                 }
2538
2539                 if (frametime) player_anim(this);
2540
2541                 // secret status
2542                 secrets_setstatus(this);
2543
2544                 // monsters status
2545                 monsters_setstatus(this);
2546
2547                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2548         }
2549         else if (game_stopped || intermission_running) {
2550                 if(intermission_running)
2551                         IntermissionThink(this);
2552                 return;
2553         }
2554         else if (IS_OBSERVER(this)) {
2555                 ObserverThink(this);
2556         }
2557         else if (IS_SPEC(this)) {
2558                 SpectatorThink(this);
2559         }
2560
2561         // WEAPONTODO: Add weapon request for this
2562         if (!zoomstate_set) {
2563                 bool wep_zoomed = false;
2564                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2565                 {
2566                         .entity weaponentity = weaponentities[slot];
2567                         Weapon thiswep = this.(weaponentity).m_weapon;
2568                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2569                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2570                 }
2571                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2572     }
2573
2574         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2575         {
2576                 this.teamkill_soundtime = 0;
2577
2578                 entity e = this.teamkill_soundsource;
2579                 entity oldpusher = e.pusher;
2580                 e.pusher = this;
2581                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2582                 e.pusher = oldpusher;
2583         }
2584
2585         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2586                 this.taunt_soundtime = 0;
2587                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2588         }
2589
2590         target_voicescript_next(this);
2591
2592         // WEAPONTODO: Move into weaponsystem somehow
2593         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2594         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2595         {
2596                 .entity weaponentity = weaponentities[slot];
2597                 if(this.(weaponentity).m_weapon == WEP_Null)
2598                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2599         }
2600 }
2601
2602 void DrownPlayer(entity this)
2603 {
2604         if(IS_DEAD(this))
2605                 return;
2606
2607         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2608         {
2609                 if(this.air_finished < time)
2610                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2611                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2612                 this.dmg = 2;
2613         }
2614         else if (this.air_finished < time)
2615         {       // drown!
2616                 if (this.pain_finished < time)
2617                 {
2618                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2619                         this.pain_finished = time + 0.5;
2620                 }
2621         }
2622 }
2623
2624 .bool move_qcphysics;
2625
2626 void Player_Physics(entity this)
2627 {
2628         set_movetype(this, this.move_movetype);
2629
2630         if(!this.move_qcphysics)
2631                 return;
2632
2633         if(!frametime && !this.pm_frametime)
2634                 return;
2635
2636         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2637
2638         this.pm_frametime = 0;
2639 }
2640
2641 /*
2642 =============
2643 PlayerPostThink
2644
2645 Called every frame for each client after the physics are run
2646 =============
2647 */
2648 .float idlekick_lasttimeleft;
2649 void PlayerPostThink (entity this)
2650 {
2651         Player_Physics(this);
2652
2653         if (sv_maxidle > 0)
2654         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2655         if (IS_REAL_CLIENT(this))
2656         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2657         {
2658                 int totalClients = 0;
2659                 if(sv_maxidle_slots > 0)
2660                 {
2661                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2662                         {
2663                                 ++totalClients;
2664                         });
2665                 }
2666
2667                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2668                 { /* do nothing */ }
2669                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2670                 {
2671                         if (this.idlekick_lasttimeleft)
2672                         {
2673                                 this.idlekick_lasttimeleft = 0;
2674                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2675                         }
2676                 }
2677                 else
2678                 {
2679                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2680                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2681                                 if (!this.idlekick_lasttimeleft)
2682                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2683                         }
2684                         if (timeleft <= 0) {
2685                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2686                                 dropclient(this);
2687                                 return;
2688                         }
2689                         else if (timeleft <= 10) {
2690                                 if (timeleft != this.idlekick_lasttimeleft) {
2691                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2692                 }
2693                                 this.idlekick_lasttimeleft = timeleft;
2694                         }
2695                 }
2696         }
2697
2698         CheatFrame(this);
2699
2700         //CheckPlayerJump();
2701         if (game_stopped)
2702         {
2703                 this.solid = SOLID_NOT;
2704                 this.takedamage = DAMAGE_NO;
2705                 set_movetype(this, MOVETYPE_NONE);
2706         }
2707
2708         if (IS_PLAYER(this)) {
2709                 DrownPlayer(this);
2710                 CheckRules_Player(this);
2711                 UpdateChatBubble(this);
2712                 if (this.impulse) ImpulseCommands(this);
2713                 if (game_stopped)
2714                 {
2715                         CSQCMODEL_AUTOUPDATE(this);
2716                         return;
2717                 }
2718                 GetPressedKeys(this);
2719         }
2720
2721         if (this.waypointsprite_attachedforcarrier) {
2722             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2723                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2724     }
2725
2726         playerdemo_write(this);
2727
2728         CSQCMODEL_AUTOUPDATE(this);
2729 }