Fix include order of new replicate.qh file
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <common/weapons/_all.qh>
4 #include <common/stats.qh>
5 #include <server/miscfunctions.qh>
6 #include <common/effects/all.qh>
7 #include "anticheat.qh"
8 #include "impulse.qh"
9 #include "player.qh"
10 #include "ipban.qh"
11 #include "miscfunctions.qh"
12 #include "portals.qh"
13 #include "teamplay.qh"
14 #include "spawnpoints.qh"
15 #include "resources.qh"
16 #include "g_damage.qh"
17 #include "handicap.qh"
18 #include "g_hook.qh"
19 #include "command/common.qh"
20 #include "command/vote.qh"
21 #include "clientkill.qh"
22 #include "cheats.qh"
23 #include "g_world.qh"
24 #include <server/gamelog.qh>
25 #include "race.qh"
26 #include <server/sv_main.qh>
27 #include "antilag.qh"
28 #include "campaign.qh"
29 #include "command/common.qh"
30 #include "scores_rules.qh"
31 #include "weapons/common.qh"
32
33 #include "bot/api.qh"
34
35 #include "../common/ent_cs.qh"
36 #include "../common/wepent.qh"
37 #include <common/state.qh>
38
39 #include "compat/quake3.qh"
40
41 #include <common/effects/qc/globalsound.qh>
42
43 #include "../common/mapobjects/func/conveyor.qh"
44 #include <common/mapobjects/func/ladder.qh>
45 #include "../common/mapobjects/teleporters.qh"
46 #include "../common/mapobjects/target/spawnpoint.qh"
47 #include <common/mapobjects/trigger/counter.qh>
48 #include <common/mapobjects/trigger/swamp.qh>
49
50 #include "../common/vehicles/all.qh"
51
52 #include "weapons/hitplot.qh"
53 #include "weapons/selection.qh"
54 #include "weapons/weaponsystem.qh"
55
56 #include "../common/net_notice.qh"
57 #include "../common/net_linked.qh"
58 #include "../common/physics/player.qh"
59
60 #include <common/vehicles/sv_vehicles.qh>
61
62 #include "../common/items/_mod.qh"
63
64 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
65
66 #include "../common/mutators/mutator/waypoints/all.qh"
67 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
68 #include <common/gamemodes/_mod.qh>
69
70 #include "../common/mapobjects/subs.qh"
71 #include "../common/mapobjects/triggers.qh"
72 #include "../common/mapobjects/trigger/secret.qh"
73
74 #include "../common/minigames/sv_minigames.qh"
75
76 #include "../common/items/inventory.qh"
77
78 #include "../common/monsters/sv_monsters.qh"
79
80 #include "../lib/warpzone/server.qh"
81
82 #include <common/mutators/mutator/overkill/oknex.qh>
83
84 #include <common/weapons/weapon/vortex.qh>
85
86 STATIC_METHOD(Client, Add, void(Client this, int _team))
87 {
88     ClientConnect(this);
89     TRANSMUTE(Player, this);
90     this.frame = 12; // 7
91     this.team = _team;
92     PutClientInServer(this);
93 }
94
95 STATIC_METHOD(Client, Remove, void(Client this))
96 {
97     TRANSMUTE(Observer, this);
98     PutClientInServer(this);
99     ClientDisconnect(this);
100 }
101
102 void send_CSQC_teamnagger() {
103         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
104 }
105
106 int CountSpectators(entity player, entity to)
107 {
108         if(!player) { return 0; } // not sure how, but best to be safe
109
110         int spec_count = 0;
111
112         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
113         {
114                 spec_count++;
115         });
116
117         return spec_count;
118 }
119
120 void WriteSpectators(entity player, entity to)
121 {
122         if(!player) { return; } // not sure how, but best to be safe
123
124         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
125         {
126                 WriteByte(MSG_ENTITY, num_for_edict(it));
127         });
128 }
129
130 bool ClientData_Send(entity this, entity to, int sf)
131 {
132         assert(to == this.owner, return false);
133
134         entity e = to;
135         if (IS_SPEC(e)) e = e.enemy;
136
137         sf = 0;
138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
141         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
142
143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
144         WriteByte(MSG_ENTITY, sf);
145
146         if (sf & BIT(1))
147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
148
149         if(sf & BIT(4))
150         {
151                 float specs = CountSpectators(e, to);
152                 WriteByte(MSG_ENTITY, specs);
153                 WriteSpectators(e, to);
154         }
155
156         return true;
157 }
158
159 void ClientData_Attach(entity this)
160 {
161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
162         CS(this).clientdata.drawonlytoclient = this;
163         CS(this).clientdata.owner = this;
164 }
165
166 void ClientData_Detach(entity this)
167 {
168         delete(CS(this).clientdata);
169         CS(this).clientdata = NULL;
170 }
171
172 void ClientData_Touch(entity e)
173 {
174         entity cd = CS(e).clientdata;
175         if (cd) { cd.SendFlags = 1; }
176
177         // make it spectatable
178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
179         {
180                 entity cd = CS(it).clientdata;
181                 if (cd) { cd.SendFlags = 1; }
182         });
183 }
184
185
186 /*
187 =============
188 CheckPlayerModel
189
190 Checks if the argument string can be a valid playermodel.
191 Returns a valid one in doubt.
192 =============
193 */
194 string FallbackPlayerModel;
195 string CheckPlayerModel(string plyermodel) {
196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
197         {
198                 // note: we cannot summon Don Strunzone here, some player may
199                 // still have the model string set. In case anyone manages how
200                 // to change a cvar default, we'll have a small leak here.
201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
202         }
203         // only in right path
204         if( substring(plyermodel,0,14) != "models/player/")
205                 return FallbackPlayerModel;
206         // only good file extensions
207         if(substring(plyermodel,-4,4) != ".zym")
208         if(substring(plyermodel,-4,4) != ".dpm")
209         if(substring(plyermodel,-4,4) != ".iqm")
210         if(substring(plyermodel,-4,4) != ".md3")
211         if(substring(plyermodel,-4,4) != ".psk")
212                 return FallbackPlayerModel;
213         // forbid the LOD models
214         if(substring(plyermodel, -9,5) == "_lod1")
215                 return FallbackPlayerModel;
216         if(substring(plyermodel, -9,5) == "_lod2")
217                 return FallbackPlayerModel;
218         if(plyermodel != strtolower(plyermodel))
219                 return FallbackPlayerModel;
220         // also, restrict to server models
221         if(autocvar_sv_servermodelsonly)
222         {
223                 if(!fexists(plyermodel))
224                         return FallbackPlayerModel;
225         }
226         return plyermodel;
227 }
228
229 void setplayermodel(entity e, string modelname)
230 {
231         precache_model(modelname);
232         _setmodel(e, modelname);
233         player_setupanimsformodel(e);
234         if(!autocvar_g_debug_globalsounds)
235                 UpdatePlayerSounds(e);
236 }
237
238 /** putting a client as observer in the server */
239 void PutObserverInServer(entity this)
240 {
241     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
242         PlayerState_detach(this);
243
244         if (IS_PLAYER(this))
245         {
246                 if(GetResource(this, RES_HEALTH) >= 1)
247                 {
248                         // despawn effect
249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
250                 }
251
252                 // was a player, recount votes and ready status
253                 if(IS_REAL_CLIENT(this))
254                 {
255                         if (vote_called) { VoteCount(false); }
256                         ReadyCount();
257                 }
258     }
259
260     {
261         entity spot = SelectSpawnPoint(this, true);
262         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
263         this.angles = vec2(spot.angles);
264         this.fixangle = true;
265         // offset it so that the spectator spawns higher off the ground, looks better this way
266         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
267         if (IS_REAL_CLIENT(this))
268         {
269             msg_entity = this;
270             WriteByte(MSG_ONE, SVC_SETVIEW);
271             WriteEntity(MSG_ONE, this);
272         }
273         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
274         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
275         if(!autocvar_g_debug_globalsounds)
276         {
277                 // needed for player sounds
278                 this.model = "";
279                 FixPlayermodel(this);
280         }
281         setmodel(this, MDL_Null);
282         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
283         this.view_ofs = '0 0 0';
284     }
285
286     RemoveGrapplingHooks(this);
287         Portal_ClearAll(this);
288         Unfreeze(this, false);
289         SetSpectatee(this, NULL);
290
291         if (this.alivetime)
292         {
293                 if (!warmup_stage)
294                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
295                 this.alivetime = 0;
296         }
297
298         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
299
300         WaypointSprite_PlayerDead(this);
301
302         if (CS(this).killcount != FRAGS_SPECTATOR)
303         {
304                 if(!game_stopped)
305                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
306                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
307         }
308
309         accuracy_resend(this);
310
311         CS(this).spectatortime = time;
312         if(this.bot_attack)
313                 IL_REMOVE(g_bot_targets, this);
314         this.bot_attack = false;
315         if(this.monster_attack)
316                 IL_REMOVE(g_monster_targets, this);
317         this.monster_attack = false;
318     STAT(HUD, this) = HUD_NORMAL;
319         TRANSMUTE(Observer, this);
320         this.iscreature = false;
321         this.teleportable = TELEPORT_SIMPLE;
322         if(this.damagedbycontents)
323                 IL_REMOVE(g_damagedbycontents, this);
324         this.damagedbycontents = false;
325         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
326         SetSpectatee_status(this, etof(this));
327         this.takedamage = DAMAGE_NO;
328         this.solid = SOLID_NOT;
329         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
330         this.flags = FL_CLIENT | FL_NOTARGET;
331         this.effects = 0;
332         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
333         this.pauserotarmor_finished = 0;
334         this.pauserothealth_finished = 0;
335         this.pauseregen_finished = 0;
336         this.damageforcescale = 0;
337         this.death_time = 0;
338         this.respawn_flags = 0;
339         this.respawn_time = 0;
340         STAT(RESPAWN_TIME, this) = 0;
341         this.alpha = 0;
342         this.scale = 0;
343         this.fade_time = 0;
344         this.pain_finished = 0;
345         STAT(STRENGTH_FINISHED, this) = 0;
346         STAT(INVINCIBLE_FINISHED, this) = 0;
347         STAT(SUPERWEAPONS_FINISHED, this) = 0;
348         STAT(AIR_FINISHED, this) = 0;
349         //this.dphitcontentsmask = 0;
350         this.dphitcontentsmask = DPCONTENTS_SOLID;
351         if (autocvar_g_playerclip_collisions)
352                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
353         this.pushltime = 0;
354         this.istypefrag = 0;
355         setthink(this, func_null);
356         this.nextthink = 0;
357         this.deadflag = DEAD_NO;
358         UNSET_DUCKED(this);
359         STAT(REVIVE_PROGRESS, this) = 0;
360         this.revival_time = 0;
361         this.draggable = drag_undraggable;
362
363         this.items = 0;
364         STAT(WEAPONS, this) = '0 0 0';
365         this.drawonlytoclient = this;
366
367         this.viewloc = NULL;
368
369         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
370
371         this.weaponmodel = "";
372         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
373         {
374                 this.weaponentities[slot] = NULL;
375         }
376         this.exteriorweaponentity = NULL;
377         CS(this).killcount = FRAGS_SPECTATOR;
378         this.velocity = '0 0 0';
379         this.avelocity = '0 0 0';
380         this.punchangle = '0 0 0';
381         this.punchvector = '0 0 0';
382         this.oldvelocity = this.velocity;
383         this.fire_endtime = -1;
384         this.event_damage = func_null;
385         this.event_heal = func_null;
386
387         for(int slot = 0; slot < MAX_AXH; ++slot)
388         {
389                 entity axh = this.(AuxiliaryXhair[slot]);
390                 this.(AuxiliaryXhair[slot]) = NULL;
391
392                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
393                         delete(axh);
394         }
395
396         if (mutator_returnvalue)
397         {
398                 // mutator prevents resetting teams+score
399         }
400         else
401         {
402                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
403                 this.frags = FRAGS_SPECTATOR;
404         }
405         if (CS(this).just_joined)
406                 CS(this).just_joined = false;
407 }
408
409 int player_getspecies(entity this)
410 {
411         get_model_parameters(this.model, this.skin);
412         int s = get_model_parameters_species;
413         get_model_parameters(string_null, 0);
414         if (s < 0) return SPECIES_HUMAN;
415         return s;
416 }
417
418 .float model_randomizer;
419 void FixPlayermodel(entity player)
420 {
421         string defaultmodel = "";
422         int defaultskin = 0;
423         if(autocvar_sv_defaultcharacter)
424         {
425                 if(teamplay)
426                 {
427                         switch(player.team)
428                         {
429                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
430                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
431                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
432                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
433                         }
434                 }
435
436                 if(defaultmodel == "")
437                 {
438                         defaultmodel = autocvar_sv_defaultplayermodel;
439                         defaultskin = autocvar_sv_defaultplayerskin;
440                 }
441
442                 int n = tokenize_console(defaultmodel);
443                 if(n > 0)
444                 {
445                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
446                         // However, do NOT randomize if the player-selected model is in the list.
447                         for (int i = 0; i < n; ++i)
448                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
449                                         defaultmodel = argv(i);
450                 }
451
452                 int i = strstrofs(defaultmodel, ":", 0);
453                 if(i >= 0)
454                 {
455                         defaultskin = stof(substring(defaultmodel, i+1, -1));
456                         defaultmodel = substring(defaultmodel, 0, i);
457                 }
458         }
459         if(autocvar_sv_defaultcharacterskin && !defaultskin)
460         {
461                 if(teamplay)
462                 {
463                         switch(player.team)
464                         {
465                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
466                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
467                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
468                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
469                         }
470                 }
471
472                 if(!defaultskin)
473                         defaultskin = autocvar_sv_defaultplayerskin;
474         }
475
476         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
477         defaultmodel = M_ARGV(0, string);
478         defaultskin = M_ARGV(1, int);
479
480         bool chmdl = false;
481         int oldskin;
482         if(defaultmodel != "")
483         {
484                 if (defaultmodel != player.model)
485                 {
486                         vector m1 = player.mins;
487                         vector m2 = player.maxs;
488                         setplayermodel (player, defaultmodel);
489                         setsize (player, m1, m2);
490                         chmdl = true;
491                 }
492
493                 oldskin = player.skin;
494                 player.skin = defaultskin;
495         } else {
496                 if (player.playermodel != player.model || player.playermodel == "")
497                 {
498                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
499                         vector m1 = player.mins;
500                         vector m2 = player.maxs;
501                         setplayermodel (player, player.playermodel);
502                         setsize (player, m1, m2);
503                         chmdl = true;
504                 }
505
506                 if(!autocvar_sv_defaultcharacterskin)
507                 {
508                         oldskin = player.skin;
509                         player.skin = stof(player.playerskin);
510                 }
511                 else
512                 {
513                         oldskin = player.skin;
514                         player.skin = defaultskin;
515                 }
516         }
517
518         if(chmdl || oldskin != player.skin) // model or skin has changed
519         {
520                 player.species = player_getspecies(player); // update species
521                 if(!autocvar_g_debug_globalsounds)
522                         UpdatePlayerSounds(player); // update skin sounds
523         }
524
525         if(!teamplay)
526                 if(strlen(autocvar_sv_defaultplayercolors))
527                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
528                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
529 }
530
531 void PutPlayerInServer(entity this)
532 {
533         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
534
535         PlayerState_attach(this);
536         accuracy_resend(this);
537
538         if (this.team < 0)
539                 TeamBalance_JoinBestTeam(this);
540
541         entity spot = SelectSpawnPoint(this, false);
542         if (!spot) {
543                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
544                 return; // spawn failed
545         }
546
547         TRANSMUTE(Player, this);
548
549         CS(this).wasplayer = true;
550         this.iscreature = true;
551         this.teleportable = TELEPORT_NORMAL;
552         if(!this.damagedbycontents)
553                 IL_PUSH(g_damagedbycontents, this);
554         this.damagedbycontents = true;
555         set_movetype(this, MOVETYPE_WALK);
556         this.solid = SOLID_SLIDEBOX;
557         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
558         if (autocvar_g_playerclip_collisions)
559                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
560         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
561                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
562         this.frags = FRAGS_PLAYER;
563         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
564         this.flags = FL_CLIENT | FL_PICKUPITEMS;
565         if (autocvar__notarget)
566                 this.flags |= FL_NOTARGET;
567         this.takedamage = DAMAGE_AIM;
568         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
569
570         if (warmup_stage) {
571                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
572                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
573                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
574                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
575                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
576                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
577                 SetResource(this, RES_HEALTH, warmup_start_health);
578                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
579                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
580         } else {
581                 SetResource(this, RES_SHELLS, start_ammo_shells);
582                 SetResource(this, RES_BULLETS, start_ammo_nails);
583                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
584                 SetResource(this, RES_CELLS, start_ammo_cells);
585                 SetResource(this, RES_PLASMA, start_ammo_plasma);
586                 SetResource(this, RES_FUEL, start_ammo_fuel);
587                 SetResource(this, RES_HEALTH, start_health);
588                 SetResource(this, RES_ARMOR, start_armorvalue);
589                 STAT(WEAPONS, this) = start_weapons;
590                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
591                 {
592                         GiveRandomWeapons(this, random_start_weapons_count,
593                                 autocvar_g_random_start_weapons, random_start_ammo);
594                 }
595         }
596         SetSpectatee_status(this, 0);
597
598         PS(this).dual_weapons = '0 0 0';
599
600         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
601
602         this.items = start_items;
603
604         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
605         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
606         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
607         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
608         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
609         if (!sv_ready_restart_after_countdown && time < game_starttime)
610         {
611                 float f = game_starttime - time;
612                 this.spawnshieldtime += f;
613                 this.pauserotarmor_finished += f;
614                 this.pauserothealth_finished += f;
615                 this.pauseregen_finished += f;
616         }
617
618         this.damageforcescale = autocvar_g_player_damageforcescale;
619         this.death_time = 0;
620         this.respawn_flags = 0;
621         this.respawn_time = 0;
622         STAT(RESPAWN_TIME, this) = 0;
623         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
624         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
625         this.fade_time = 0;
626         this.pain_finished = 0;
627         this.pushltime = 0;
628         setthink(this, func_null); // players have no think function
629         this.nextthink = 0;
630         this.dmg_team = 0;
631         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
632
633         this.deadflag = DEAD_NO;
634
635         this.angles = spot.angles;
636         this.angles_z = 0; // never spawn tilted even if the spot says to
637         if (IS_BOT_CLIENT(this))
638         {
639                 this.v_angle = this.angles;
640                 bot_aim_reset(this);
641         }
642         this.fixangle = true; // turn this way immediately
643         this.oldvelocity = this.velocity = '0 0 0';
644         this.avelocity = '0 0 0';
645         this.punchangle = '0 0 0';
646         this.punchvector = '0 0 0';
647
648         STAT(STRENGTH_FINISHED, this) = 0;
649         STAT(INVINCIBLE_FINISHED, this) = 0;
650         this.fire_endtime = -1;
651         STAT(REVIVE_PROGRESS, this) = 0;
652         this.revival_time = 0;
653
654         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
655         STAT(BUFFS, this) = 0;
656         STAT(BUFF_TIME, this) = 0;
657
658         STAT(AIR_FINISHED, this) = 0;
659         this.waterlevel = WATERLEVEL_NONE;
660         this.watertype = CONTENT_EMPTY;
661
662         entity spawnevent = new_pure(spawnevent);
663         spawnevent.owner = this;
664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
665
666         // Cut off any still running player sounds.
667         stopsound(this, CH_PLAYER_SINGLE);
668
669         this.model = "";
670         FixPlayermodel(this);
671         this.drawonlytoclient = NULL;
672
673         this.viewloc = NULL;
674
675         for(int slot = 0; slot < MAX_AXH; ++slot)
676         {
677                 entity axh = this.(AuxiliaryXhair[slot]);
678                 this.(AuxiliaryXhair[slot]) = NULL;
679
680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
681                         delete(axh);
682         }
683
684         this.spawnpoint_targ = NULL;
685
686         UNSET_DUCKED(this);
687         this.view_ofs = STAT(PL_VIEW_OFS, this);
688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
689         this.spawnorigin = spot.origin;
690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
691         // don't reset back to last position, even if new position is stuck in solid
692         this.oldorigin = this.origin;
693         if(this.conveyor)
694                 IL_REMOVE(g_conveyed, this);
695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
696         if(this.swampslug)
697                 IL_REMOVE(g_swamped, this);
698         this.swampslug = NULL;
699         this.swamp_interval = 0;
700         if(this.ladder_entity)
701                 IL_REMOVE(g_ladderents, this);
702         this.ladder_entity = NULL;
703         IL_EACH(g_counters, it.realowner == this,
704         {
705                 delete(it);
706         });
707         STAT(HUD, this) = HUD_NORMAL;
708
709         this.event_damage = PlayerDamage;
710         this.event_heal = PlayerHeal;
711
712         this.draggable = func_null;
713
714         if(!this.bot_attack)
715                 IL_PUSH(g_bot_targets, this);
716         this.bot_attack = true;
717         if(!this.monster_attack)
718                 IL_PUSH(g_monster_targets, this);
719         this.monster_attack = true;
720         navigation_dynamicgoal_init(this, false);
721
722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
723
724         // player was spectator
725         if (CS(this).killcount == FRAGS_SPECTATOR) {
726                 PlayerScore_Clear(this);
727                 CS(this).killcount = 0;
728                 CS(this).startplaytime = time;
729         }
730
731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
732         {
733                 .entity weaponentity = weaponentities[slot];
734                 CL_SpawnWeaponentity(this, weaponentity);
735         }
736         this.alpha = default_player_alpha;
737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
738         this.exteriorweaponentity.alpha = default_weapon_alpha;
739
740         this.speedrunning = false;
741
742         this.counter_cnt = 0;
743         this.fragsfilter_cnt = 0;
744
745         target_voicescript_clear(this);
746
747         // reset fields the weapons may use
748         FOREACH(Weapons, true, {
749                 it.wr_resetplayer(it, this);
750                         // reload all reloadable weapons
751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
753                         {
754                                 .entity weaponentity = weaponentities[slot];
755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
756                         }
757                 }
758         });
759
760         {
761                 string s = spot.target;
762                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
763                         spot.target = string_null;
764                 SUB_UseTargets(spot, this, NULL);
765                 if(g_assault || g_race)
766                         spot.target = s;
767         }
768
769         Unfreeze(this, false);
770
771         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
772
773         if (autocvar_spawn_debug)
774         {
775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
777         }
778
779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
780         {
781                 .entity weaponentity = weaponentities[slot];
782                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
783                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
784                 else
785                         this.(weaponentity).m_switchweapon = WEP_Null;
786                 this.(weaponentity).m_weapon = WEP_Null;
787                 this.(weaponentity).weaponname = "";
788                 this.(weaponentity).m_switchingweapon = WEP_Null;
789                 this.(weaponentity).cnt = -1;
790         }
791
792         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
793
794         if (CS(this).impulse) ImpulseCommands(this);
795
796         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
797         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
798         {
799                 .entity weaponentity = weaponentities[slot];
800                 W_WeaponFrame(this, weaponentity);
801         }
802
803         if (!warmup_stage && !this.alivetime)
804                 this.alivetime = time;
805
806         antilag_clear(this, CS(this));
807 }
808
809 /** Called when a client spawns in the server */
810 void PutClientInServer(entity this)
811 {
812         if (IS_BOT_CLIENT(this)) {
813                 TRANSMUTE(Player, this);
814         } else if (IS_REAL_CLIENT(this)) {
815                 msg_entity = this;
816                 WriteByte(MSG_ONE, SVC_SETVIEW);
817                 WriteEntity(MSG_ONE, this);
818         }
819         if (game_stopped)
820                 TRANSMUTE(Observer, this);
821
822         SetSpectatee(this, NULL);
823
824         // reset player keys
825         if(PS(this))
826                 PS(this).itemkeys = 0;
827
828         MUTATOR_CALLHOOK(PutClientInServer, this);
829
830         if (IS_OBSERVER(this)) {
831                 PutObserverInServer(this);
832         } else if (IS_PLAYER(this)) {
833                 PutPlayerInServer(this);
834         }
835 }
836
837 // TODO do we need all these fields, or should we stop autodetecting runtime
838 // changes and just have a console command to update this?
839 bool ClientInit_SendEntity(entity this, entity to, int sf)
840 {
841         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
842         return = true;
843         msg_entity = to;
844         // MSG_INIT replacement
845         // TODO: make easier to use
846         Registry_send_all();
847         W_PROP_reload(MSG_ONE, to);
848         ClientInit_misc(this);
849         MUTATOR_CALLHOOK(Ent_Init);
850 }
851 void ClientInit_misc(entity this)
852 {
853         int channel = MSG_ONE;
854         WriteHeader(channel, ENT_CLIENT_INIT);
855         WriteByte(channel, g_nexball_meter_period * 32);
856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
859         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
863         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
864
865         if(sv_foginterval && world.fog != "")
866                 WriteString(channel, world.fog);
867         else
868                 WriteString(channel, "");
869         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
870         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
871         WriteByte(channel, serverflags);
872         WriteCoord(channel, autocvar_g_trueaim_minrange);
873 }
874
875 void ClientInit_CheckUpdate(entity this)
876 {
877         this.nextthink = time;
878         if(this.count != autocvar_g_balance_armor_blockpercent)
879         {
880                 this.count = autocvar_g_balance_armor_blockpercent;
881                 this.SendFlags |= 1;
882         }
883         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
884         {
885                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
886                 this.SendFlags |= 1;
887         }
888 }
889
890 void ClientInit_Spawn()
891 {
892         entity e = new_pure(clientinit);
893         setthink(e, ClientInit_CheckUpdate);
894         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
895
896         ClientInit_CheckUpdate(e);
897 }
898
899 /*
900 =============
901 SetNewParms
902 =============
903 */
904 void SetNewParms ()
905 {
906         // initialize parms for a new player
907         parm1 = -(86400 * 366);
908
909         MUTATOR_CALLHOOK(SetNewParms);
910 }
911
912 /*
913 =============
914 SetChangeParms
915 =============
916 */
917 void SetChangeParms (entity this)
918 {
919         // save parms for level change
920         parm1 = CS(this).parm_idlesince - time;
921
922         MUTATOR_CALLHOOK(SetChangeParms);
923 }
924
925 /*
926 =============
927 DecodeLevelParms
928 =============
929 */
930 void DecodeLevelParms(entity this)
931 {
932         // load parms
933         CS(this).parm_idlesince = parm1;
934         if (CS(this).parm_idlesince == -(86400 * 366))
935                 CS(this).parm_idlesince = time;
936
937         // whatever happens, allow 60 seconds of idling directly after connect for map loading
938         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
939
940         MUTATOR_CALLHOOK(DecodeLevelParms);
941 }
942
943 void FixClientCvars(entity e)
944 {
945         // send prediction settings to the client
946         stuffcmd(e, "\nin_bindmap 0 0\n");
947         if(autocvar_g_antilag == 3) // client side hitscan
948                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
949         if(autocvar_sv_gentle)
950                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
951
952         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
953         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
954
955         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
956
957         MUTATOR_CALLHOOK(FixClientCvars, e);
958 }
959
960 bool findinlist_abbrev(string tofind, string list)
961 {
962         if(list == "" || tofind == "")
963                 return false; // empty list or search, just return
964
965         // this function allows abbreviated strings!
966         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
967         {
968                 return true;
969         });
970
971         return false;
972 }
973
974 bool PlayerInIPList(entity p, string iplist)
975 {
976         // some safety checks (never allow local?)
977         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
978                 return false;
979
980         return findinlist_abbrev(p.netaddress, iplist);
981 }
982
983 bool PlayerInIDList(entity p, string idlist)
984 {
985         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
986         if(!p.crypto_idfp)
987                 return false;
988
989         return findinlist_abbrev(p.crypto_idfp, idlist);
990 }
991
992 bool PlayerInList(entity player, string list)
993 {
994         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
995 }
996
997 #ifdef DP_EXT_PRECONNECT
998 /*
999 =============
1000 ClientPreConnect
1001
1002 Called once (not at each match start) when a client begins a connection to the server
1003 =============
1004 */
1005 void ClientPreConnect(entity this)
1006 {
1007         if(autocvar_sv_eventlog)
1008         {
1009                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1010                         this.playerid,
1011                         etof(this),
1012                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1013                 ));
1014         }
1015 }
1016 #endif
1017
1018 string GetClientVersionMessage(entity this)
1019 {
1020         if (CS(this).version_mismatch) {
1021                 if(CS(this).version < autocvar_gameversion) {
1022                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1023                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1024                 } else {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1027                 }
1028         } else {
1029                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1030         }
1031 }
1032
1033 string getwelcomemessage(entity this)
1034 {
1035         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1036         string modifications = M_ARGV(0, string);
1037
1038         if(g_weaponarena)
1039         {
1040                 if(g_weaponarena_random)
1041                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1042                 else
1043                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1044         }
1045         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1046                 modifications = strcat(modifications, ", No start weapons");
1047         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1048                 modifications = strcat(modifications, ", Low gravity");
1049         if(g_weapon_stay && !g_cts)
1050                 modifications = strcat(modifications, ", Weapons stay");
1051         if(g_jetpack)
1052                 modifications = strcat(modifications, ", Jet pack");
1053         if(autocvar_g_powerups == 0)
1054                 modifications = strcat(modifications, ", No powerups");
1055         if(autocvar_g_powerups > 0)
1056                 modifications = strcat(modifications, ", Powerups");
1057         modifications = substring(modifications, 2, strlen(modifications) - 2);
1058
1059         string versionmessage = GetClientVersionMessage(this);
1060         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1061
1062         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1063
1064         if(modifications != "")
1065                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1066
1067         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1068         {
1069                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1070                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1071         }
1072
1073         if (cache_mutatormsg != "") {
1074                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1075         }
1076
1077         string mutator_msg = "";
1078         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1079         mutator_msg = M_ARGV(0, string);
1080
1081         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1082
1083         string motd = autocvar_sv_motd;
1084         if (motd != "") {
1085                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1086         }
1087         return s;
1088 }
1089
1090 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1091
1092 /**
1093 =============
1094 ClientConnect
1095
1096 Called when a client connects to the server
1097 =============
1098 */
1099 void ClientConnect(entity this)
1100 {
1101         if (Ban_MaybeEnforceBanOnce(this)) return;
1102         assert(!IS_CLIENT(this), return);
1103         this.flags |= FL_CLIENT;
1104         assert(player_count >= 0, player_count = 0);
1105
1106 #ifdef WATERMARK
1107         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1108 #endif
1109         TRANSMUTE(Client, this);
1110         CS(this).version_nagtime = time + 10 + random() * 10;
1111
1112         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1113
1114         bot_clientconnect(this);
1115
1116         Player_DetermineForcedTeam(this);
1117
1118         TRANSMUTE(Observer, this);
1119
1120         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1121
1122         // always track bots, don't ask for cl_allow_uidtracking
1123         if (IS_BOT_CLIENT(this))
1124                 PlayerStats_GameReport_AddPlayer(this);
1125         else
1126                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1127
1128         if (autocvar_sv_eventlog)
1129                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1130
1131         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1132
1133         stuffcmd(this, clientstuff, "\n");
1134         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1135
1136         FixClientCvars(this);
1137
1138         // get version info from player
1139         stuffcmd(this, "cmd clientversion $gameversion\n");
1140
1141         // notify about available teams
1142         if (teamplay)
1143         {
1144                 entity balance = TeamBalance_CheckAllowedTeams(this);
1145                 int t = TeamBalance_GetAllowedTeams(balance);
1146                 TeamBalance_Destroy(balance);
1147                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1148         }
1149         else
1150         {
1151                 stuffcmd(this, "set _teams_available 0\n");
1152         }
1153
1154         bot_relinkplayerlist();
1155
1156         CS(this).spectatortime = time;
1157         if (blockSpectators)
1158         {
1159                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1160         }
1161
1162         CS(this).jointime = time;
1163
1164         if (IS_REAL_CLIENT(this))
1165         {
1166                 if (g_weaponarena_weapons == WEPSET(TUBA))
1167                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1168         }
1169
1170         if (!sv_foginterval && world.fog != "")
1171                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1172
1173         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1174                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1175                         send_CSQC_teamnagger();
1176
1177         CSQCMODEL_AUTOINIT(this);
1178
1179         CS(this).model_randomizer = random();
1180
1181         if (IS_REAL_CLIENT(this))
1182                 sv_notice_join(this);
1183
1184         this.move_qcphysics = autocvar_sv_qcphysics;
1185
1186         // update physics stats (players can spawn before physics runs)
1187         Physics_UpdateStats(this);
1188
1189         IL_EACH(g_initforplayer, it.init_for_player, {
1190                 it.init_for_player(it, this);
1191         });
1192
1193         Handicap_Initialize(this);
1194
1195         MUTATOR_CALLHOOK(ClientConnect, this);
1196
1197         if (IS_REAL_CLIENT(this))
1198         {
1199                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1200                 {
1201                         CS(this).motd_actived_time = -1;
1202                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1203                 }
1204         }
1205 }
1206 /*
1207 =============
1208 ClientDisconnect
1209
1210 Called when a client disconnects from the server
1211 =============
1212 */
1213 .entity chatbubbleentity;
1214 void ClientDisconnect(entity this)
1215 {
1216         assert(IS_CLIENT(this), return);
1217
1218         PlayerStats_GameReport_FinalizePlayer(this);
1219         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1220         if (CS(this).active_minigame) part_minigame(this);
1221         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1222
1223         if (autocvar_sv_eventlog)
1224                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1225
1226         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1227
1228         if(IS_SPEC(this))
1229                 SetSpectatee(this, NULL);
1230
1231     MUTATOR_CALLHOOK(ClientDisconnect, this);
1232
1233         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1234         strfree(CS(this).weaponorder_byimpulse);
1235         ClientState_detach(this);
1236
1237         Portal_ClearAll(this);
1238
1239         Unfreeze(this, false);
1240
1241         RemoveGrapplingHooks(this);
1242
1243         // Here, everything has been done that requires this player to be a client.
1244
1245         this.flags &= ~FL_CLIENT;
1246
1247         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1248         if (this.killindicator) delete(this.killindicator);
1249
1250         IL_EACH(g_counters, it.realowner == this,
1251         {
1252                 delete(it);
1253         });
1254
1255         WaypointSprite_PlayerGone(this);
1256
1257         bot_relinkplayerlist();
1258
1259         strfree(this.clientstatus);
1260         if (this.personal) delete(this.personal);
1261
1262         this.playerid = 0;
1263         ReadyCount();
1264         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1265
1266         ONREMOVE(this);
1267 }
1268
1269 void ChatBubbleThink(entity this)
1270 {
1271         this.nextthink = time;
1272         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1273         {
1274                 if(this.owner) // but why can that ever be NULL?
1275                         this.owner.chatbubbleentity = NULL;
1276                 delete(this);
1277                 return;
1278         }
1279
1280         this.mdl = "";
1281
1282         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1283         {
1284                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1285                         this.mdl = "models/sprites/minigame_busy.iqm";
1286                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1287                         this.mdl = "models/misc/chatbubble.spr";
1288         }
1289
1290         if ( this.model != this.mdl )
1291                 _setmodel(this, this.mdl);
1292
1293 }
1294
1295 void UpdateChatBubble(entity this)
1296 {
1297         if (this.alpha < 0)
1298                 return;
1299         // spawn a chatbubble entity if needed
1300         if (!this.chatbubbleentity)
1301         {
1302                 this.chatbubbleentity = new(chatbubbleentity);
1303                 this.chatbubbleentity.owner = this;
1304                 this.chatbubbleentity.exteriormodeltoclient = this;
1305                 setthink(this.chatbubbleentity, ChatBubbleThink);
1306                 this.chatbubbleentity.nextthink = time;
1307                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1308                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1309                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1310                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1311                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1312                 //this.chatbubbleentity.model = "";
1313                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1314         }
1315 }
1316
1317 void calculate_player_respawn_time(entity this)
1318 {
1319         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1320                 return;
1321
1322         float gametype_setting_tmp;
1323         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1324         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1325         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1326         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1327         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1328         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1329
1330         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1331         if (teamplay)
1332         {
1333                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1334                         if(it.team == this.team)
1335                                 ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                         sdelay_small_count = 1;
1339                 if (sdelay_large_count == 0)
1340                         sdelay_large_count = 1;
1341         }
1342         else
1343         {
1344                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1345                         ++pcount;
1346                 });
1347                 if (sdelay_small_count == 0)
1348                 {
1349                         if (IS_INDEPENDENT_PLAYER(this))
1350                         {
1351                                 // Players play independently. No point in requiring enemies.
1352                                 sdelay_small_count = 1;
1353                         }
1354                         else
1355                         {
1356                                 // Players play AGAINST each other. Enemies required.
1357                                 sdelay_small_count = 2;
1358                         }
1359                 }
1360                 if (sdelay_large_count == 0)
1361                 {
1362                         if (IS_INDEPENDENT_PLAYER(this))
1363                         {
1364                                 // Players play independently. No point in requiring enemies.
1365                                 sdelay_large_count = 1;
1366                         }
1367                         else
1368                         {
1369                                 // Players play AGAINST each other. Enemies required.
1370                                 sdelay_large_count = 2;
1371                         }
1372                 }
1373         }
1374
1375         float sdelay;
1376
1377         if (pcount <= sdelay_small_count)
1378                 sdelay = sdelay_small;
1379         else if (pcount >= sdelay_large_count)
1380                 sdelay = sdelay_large;
1381         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1382                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1383
1384         if(waves)
1385                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1386         else
1387                 this.respawn_time = time + sdelay;
1388
1389         if(sdelay < sdelay_max)
1390                 this.respawn_time_max = time + sdelay_max;
1391         else
1392                 this.respawn_time_max = this.respawn_time;
1393
1394         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1395                 this.respawn_countdown = 10; // first number to count down from is 10
1396         else
1397                 this.respawn_countdown = -1; // do not count down
1398
1399         if(autocvar_g_forced_respawn)
1400                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1401 }
1402
1403 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1404 // added to the model skins
1405 /*void UpdateColorModHack()
1406 {
1407         float c;
1408         c = this.clientcolors & 15;
1409         // LordHavoc: only bothering to support white, green, red, yellow, blue
1410              if (!teamplay) this.colormod = '0 0 0';
1411         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1412         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1413         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1414         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1415         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1416         else this.colormod = '1 1 1';
1417 }*/
1418
1419 void respawn(entity this)
1420 {
1421         bool damagedbycontents_prev = this.damagedbycontents;
1422         if(this.alpha >= 0)
1423         {
1424                 if(autocvar_g_respawn_ghosts)
1425                 {
1426                         this.solid = SOLID_NOT;
1427                         this.takedamage = DAMAGE_NO;
1428                         this.damagedbycontents = false;
1429                         set_movetype(this, MOVETYPE_FLY);
1430                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1431                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1432                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1433                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1434                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1435                         if(autocvar_g_respawn_ghosts_time > 0)
1436                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1437                 }
1438                 else
1439                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1440         }
1441
1442         CopyBody(this, 1);
1443         this.damagedbycontents = damagedbycontents_prev;
1444
1445         this.effects |= EF_NODRAW; // prevent another CopyBody
1446         PutClientInServer(this);
1447 }
1448
1449 ERASEABLE
1450 void PrintToChat(entity client, string text)
1451 {
1452         text = strcat("\{1}^7", text, "\n");
1453         sprint(client, text);
1454 }
1455
1456 ERASEABLE
1457 void DebugPrintToChat(entity client, string text)
1458 {
1459         if (autocvar_developer > 0)
1460         {
1461                 PrintToChat(client, text);
1462         }
1463 }
1464
1465 ERASEABLE
1466 void PrintToChatAll(string text)
1467 {
1468         text = strcat("\{1}^7", text, "\n");
1469         bprint(text);
1470 }
1471
1472 ERASEABLE
1473 void DebugPrintToChatAll(string text)
1474 {
1475         if (autocvar_developer > 0)
1476         {
1477                 PrintToChatAll(text);
1478         }
1479 }
1480
1481 ERASEABLE
1482 void PrintToChatTeam(int team_num, string text)
1483 {
1484         text = strcat("\{1}^7", text, "\n");
1485         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1486         {
1487                 if (it.team == team_num)
1488                 {
1489                         sprint(it, text);
1490                 }
1491         });
1492 }
1493
1494 ERASEABLE
1495 void DebugPrintToChatTeam(int team_num, string text)
1496 {
1497         if (autocvar_developer > 0)
1498         {
1499                 PrintToChatTeam(team_num, text);
1500         }
1501 }
1502
1503 void play_countdown(entity this, float finished, Sound samp)
1504 {
1505         TC(Sound, samp);
1506         if(IS_REAL_CLIENT(this))
1507                 if(floor(finished - time - frametime) != floor(finished - time))
1508                         if(finished - time < 6)
1509                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1510 }
1511
1512 void player_powerups(entity this)
1513 {
1514         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1515                 this.modelflags |= MF_ROCKET;
1516         else
1517                 this.modelflags &= ~MF_ROCKET;
1518
1519         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1520
1521         if (IS_DEAD(this))
1522         {
1523                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1524                 {
1525                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1526                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1527                         this.items &= ~ITEM_Strength.m_itemid;
1528                         this.items &= ~ITEM_Shield.m_itemid;
1529                         this.items -= (this.items & IT_SUPERWEAPON);
1530                 }
1531         }
1532
1533         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1534                 return;
1535
1536         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1537         int items_prev = this.items;
1538
1539         Fire_ApplyDamage(this);
1540         Fire_ApplyEffect(this);
1541
1542         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1543         {
1544                 if (this.items & ITEM_Strength.m_itemid)
1545                 {
1546                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1547                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1548                         if (time > STAT(STRENGTH_FINISHED, this))
1549                         {
1550                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1551                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1553                         }
1554                 }
1555                 else
1556                 {
1557                         if (time < STAT(STRENGTH_FINISHED, this))
1558                         {
1559                                 this.items = this.items | ITEM_Strength.m_itemid;
1560                                 if(!g_cts)
1561                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1562                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1563                         }
1564                 }
1565                 if (this.items & ITEM_Shield.m_itemid)
1566                 {
1567                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1568                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1569                         if (time > STAT(INVINCIBLE_FINISHED, this))
1570                         {
1571                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1572                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1573                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1574                         }
1575                 }
1576                 else
1577                 {
1578                         if (time < STAT(INVINCIBLE_FINISHED, this))
1579                         {
1580                                 this.items = this.items | ITEM_Shield.m_itemid;
1581                                 if(!g_cts)
1582                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1583                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1584                         }
1585                 }
1586                 if (this.items & IT_SUPERWEAPON)
1587                 {
1588                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1589                         {
1590                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1591                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1592                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1593                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1594                         }
1595                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1596                         {
1597                                 // don't let them run out
1598                         }
1599                         else
1600                         {
1601                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1602                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1603                                 {
1604                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1605                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1606                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1607                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1608                                 }
1609                         }
1610                 }
1611                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1612                 {
1613                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1614                         {
1615                                 this.items = this.items | IT_SUPERWEAPON;
1616                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1617                                 {
1618                                         if(!g_cts)
1619                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1620                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1621                                 }
1622                         }
1623                         else
1624                         {
1625                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1626                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1627                         }
1628                 }
1629                 else
1630                 {
1631                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1632                 }
1633         }
1634
1635         if(autocvar_g_nodepthtestplayers)
1636                 this.effects = this.effects | EF_NODEPTHTEST;
1637
1638         if(autocvar_g_fullbrightplayers)
1639                 this.effects = this.effects | EF_FULLBRIGHT;
1640
1641         if (time >= game_starttime)
1642         if (time < this.spawnshieldtime)
1643                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1644
1645         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1646 }
1647
1648 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1649 {
1650         if(current > stable)
1651                 return current;
1652         else if(current > stable - 0.25) // when close enough, "snap"
1653                 return stable;
1654         else
1655                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1656 }
1657
1658 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1659 {
1660         if(current < stable)
1661                 return current;
1662         else if(current < stable + 0.25) // when close enough, "snap"
1663                 return stable;
1664         else
1665                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1666 }
1667
1668 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1669 {
1670         float old = GetResource(this, res);
1671         float current = old;
1672         if(current > rotstable)
1673         {
1674                 if(rotframetime > 0)
1675                 {
1676                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1677                         current = max(rotstable, current - rotlinear * rotframetime);
1678                 }
1679         }
1680         else if(current < regenstable)
1681         {
1682                 if(regenframetime > 0)
1683                 {
1684                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1685                         current = min(regenstable, current + regenlinear * regenframetime);
1686                 }
1687         }
1688
1689         float limit = GetResourceLimit(this, res) * limit_mod;
1690         if(current > limit)
1691                 current = limit;
1692
1693         if (current != old)
1694                 SetResource(this, res, current);
1695 }
1696
1697 void player_regen(entity this)
1698 {
1699         float max_mod, regen_mod, rot_mod, limit_mod;
1700         max_mod = regen_mod = rot_mod = limit_mod = 1;
1701
1702         float regen_health = autocvar_g_balance_health_regen;
1703         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1704         float regen_health_rot = autocvar_g_balance_health_rot;
1705         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1706         float regen_health_stable = autocvar_g_balance_health_regenstable;
1707         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1708         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1709                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1710         max_mod = M_ARGV(1, float);
1711         regen_mod = M_ARGV(2, float);
1712         rot_mod = M_ARGV(3, float);
1713         limit_mod = M_ARGV(4, float);
1714         regen_health = M_ARGV(5, float);
1715         regen_health_linear = M_ARGV(6, float);
1716         regen_health_rot = M_ARGV(7, float);
1717         regen_health_rotlinear = M_ARGV(8, float);
1718         regen_health_stable = M_ARGV(9, float);
1719         regen_health_rotstable = M_ARGV(10, float);
1720
1721         if(!mutator_returnvalue)
1722         if(!STAT(FROZEN, this))
1723         {
1724                 float maxa = autocvar_g_balance_armor_rotstable;
1725                 float mina = autocvar_g_balance_armor_regenstable;
1726
1727                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1728                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1729                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1730
1731                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1732                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1733                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1734         }
1735
1736         // if player rotted to death...  die!
1737         // check this outside above checks, as player may still be able to rot to death
1738         if(GetResource(this, RES_HEALTH) < 1)
1739         {
1740                 if(this.vehicle)
1741                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1742                 if(this.event_damage)
1743                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1744         }
1745
1746         if (!(this.items & IT_UNLIMITED_AMMO))
1747         {
1748                 float maxf = autocvar_g_balance_fuel_rotstable;
1749                 float minf = autocvar_g_balance_fuel_regenstable;
1750
1751                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1752                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1753                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1754         }
1755 }
1756
1757 bool zoomstate_set;
1758 void SetZoomState(entity this, float newzoom)
1759 {
1760         if(newzoom != CS(this).zoomstate)
1761         {
1762                 CS(this).zoomstate = newzoom;
1763                 ClientData_Touch(this);
1764         }
1765         zoomstate_set = true;
1766 }
1767
1768 void GetPressedKeys(entity this)
1769 {
1770         MUTATOR_CALLHOOK(GetPressedKeys, this);
1771         int keys = STAT(PRESSED_KEYS, this);
1772         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1773         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1774         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1775         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1776
1777         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1778         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1779         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1780         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1781         CS(this).pressedkeys = keys; // store for other users
1782
1783         STAT(PRESSED_KEYS, this) = keys;
1784 }
1785
1786 /*
1787 ======================
1788 spectate mode routines
1789 ======================
1790 */
1791
1792 void SpectateCopy(entity this, entity spectatee)
1793 {
1794         TC(Client, this); TC(Client, spectatee);
1795
1796         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1797         PS(this) = PS(spectatee);
1798         this.armortype = spectatee.armortype;
1799         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1800         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1801         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1802         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1803         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1804         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1805         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1806         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1807         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1808         CS(this).impulse = 0;
1809         this.disableclientprediction = 1; // no need to run prediction on a spectator
1810         this.items = spectatee.items;
1811         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1812         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1813         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1814         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1815         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1816         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1817         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1818         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1819         this.punchangle = spectatee.punchangle;
1820         this.view_ofs = spectatee.view_ofs;
1821         this.velocity = spectatee.velocity;
1822         this.dmg_take = spectatee.dmg_take;
1823         this.dmg_save = spectatee.dmg_save;
1824         this.dmg_inflictor = spectatee.dmg_inflictor;
1825         this.v_angle = spectatee.v_angle;
1826         this.angles = spectatee.v_angle;
1827         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1828         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1829         this.viewloc = spectatee.viewloc;
1830         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1831                 this.fixangle = true;
1832         setorigin(this, spectatee.origin);
1833         setsize(this, spectatee.mins, spectatee.maxs);
1834         SetZoomState(this, CS(spectatee).zoomstate);
1835
1836     anticheat_spectatecopy(this, spectatee);
1837         STAT(HUD, this) = STAT(HUD, spectatee);
1838         if(spectatee.vehicle)
1839     {
1840         this.angles = spectatee.v_angle;
1841
1842         //this.fixangle = false;
1843         //this.velocity = spectatee.vehicle.velocity;
1844         this.vehicle_health = spectatee.vehicle_health;
1845         this.vehicle_shield = spectatee.vehicle_shield;
1846         this.vehicle_energy = spectatee.vehicle_energy;
1847         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1848         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1849         this.vehicle_reload1 = spectatee.vehicle_reload1;
1850         this.vehicle_reload2 = spectatee.vehicle_reload2;
1851
1852         //msg_entity = this;
1853
1854        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1855             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1856            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1857            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1858
1859         //WriteByte (MSG_ONE, SVC_SETVIEW);
1860         //    WriteEntity(MSG_ONE, this);
1861         //makevectors(spectatee.v_angle);
1862         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1863     }
1864 }
1865
1866 bool SpectateUpdate(entity this)
1867 {
1868         if(!this.enemy)
1869                 return false;
1870
1871         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1872         {
1873                 SetSpectatee(this, NULL);
1874                 return false;
1875         }
1876
1877         SpectateCopy(this, this.enemy);
1878
1879         return true;
1880 }
1881
1882 bool SpectateSet(entity this)
1883 {
1884         if(!IS_PLAYER(this.enemy))
1885                 return false;
1886
1887         ClientData_Touch(this.enemy);
1888
1889         msg_entity = this;
1890         WriteByte(MSG_ONE, SVC_SETVIEW);
1891         WriteEntity(MSG_ONE, this.enemy);
1892         set_movetype(this, MOVETYPE_NONE);
1893         accuracy_resend(this);
1894
1895         if(!SpectateUpdate(this))
1896                 PutObserverInServer(this);
1897
1898         return true;
1899 }
1900
1901 void SetSpectatee_status(entity this, int spectatee_num)
1902 {
1903         int oldspectatee_status = CS(this).spectatee_status;
1904         CS(this).spectatee_status = spectatee_num;
1905
1906         if (CS(this).spectatee_status != oldspectatee_status)
1907         {
1908                 if (STAT(PRESSED_KEYS, this))
1909                 {
1910                         CS(this).pressedkeys = 0;
1911                         STAT(PRESSED_KEYS, this) = 0;
1912                 }
1913                 ClientData_Touch(this);
1914                 if (g_race || g_cts) race_InitSpectator();
1915         }
1916 }
1917
1918 void SetSpectatee(entity this, entity spectatee)
1919 {
1920         if(IS_BOT_CLIENT(this))
1921                 return; // bots abuse .enemy, this code is useless to them
1922
1923         entity old_spectatee = this.enemy;
1924
1925         this.enemy = spectatee;
1926
1927         // WEAPONTODO
1928         // these are required to fix the spectator bug with arc
1929         if(old_spectatee)
1930         {
1931                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1932                 {
1933                         .entity weaponentity = weaponentities[slot];
1934                         if(old_spectatee.(weaponentity).arc_beam)
1935                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1936                 }
1937         }
1938         if(this.enemy)
1939         {
1940                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1941                 {
1942                         .entity weaponentity = weaponentities[slot];
1943                         if(this.enemy.(weaponentity).arc_beam)
1944                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1945                 }
1946         }
1947
1948         if (this.enemy)
1949                 SetSpectatee_status(this, etof(this.enemy));
1950
1951         // needed to update spectator list
1952         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1953 }
1954
1955 bool Spectate(entity this, entity pl)
1956 {
1957         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1958                 return false;
1959         pl = M_ARGV(1, entity);
1960
1961         SetSpectatee(this, pl);
1962         return SpectateSet(this);
1963 }
1964
1965 bool SpectateNext(entity this)
1966 {
1967         entity ent = find(this.enemy, classname, STR_PLAYER);
1968
1969         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1970                 ent = M_ARGV(1, entity);
1971         else if (!ent)
1972                 ent = find(ent, classname, STR_PLAYER);
1973
1974         if(ent) { SetSpectatee(this, ent); }
1975
1976         return SpectateSet(this);
1977 }
1978
1979 bool SpectatePrev(entity this)
1980 {
1981         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1982         entity ent = findchain(classname, STR_PLAYER);
1983         if (!ent) // no player
1984                 return false;
1985
1986         entity first = ent;
1987         // skip players until current spectated player
1988         if(this.enemy)
1989         while(ent && ent != this.enemy)
1990                 ent = ent.chain;
1991
1992         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1993         {
1994                 case MUT_SPECPREV_FOUND:
1995                     ent = M_ARGV(1, entity);
1996                     break;
1997                 case MUT_SPECPREV_RETURN:
1998                     return true;
1999                 case MUT_SPECPREV_CONTINUE:
2000                 default:
2001                 {
2002                         if(ent.chain)
2003                                 ent = ent.chain;
2004                         else
2005                                 ent = first;
2006                         break;
2007                 }
2008         }
2009
2010         SetSpectatee(this, ent);
2011         return SpectateSet(this);
2012 }
2013
2014 /*
2015 =============
2016 ShowRespawnCountdown()
2017
2018 Update a respawn countdown display.
2019 =============
2020 */
2021 void ShowRespawnCountdown(entity this)
2022 {
2023         float number;
2024         if(!IS_DEAD(this)) // just respawned?
2025                 return;
2026         else
2027         {
2028                 number = ceil(this.respawn_time - time);
2029                 if(number <= 0)
2030                         return;
2031                 if(number <= this.respawn_countdown)
2032                 {
2033                         this.respawn_countdown = number - 1;
2034                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2035                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2036                 }
2037         }
2038 }
2039
2040 .bool team_selected;
2041 bool ShowTeamSelection(entity this)
2042 {
2043         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2044                 return false;
2045         stuffcmd(this, "menu_showteamselect\n");
2046         return true;
2047 }
2048 void Join(entity this)
2049 {
2050         TRANSMUTE(Player, this);
2051
2052         if(!this.team_selected)
2053         if(autocvar_g_campaign || autocvar_g_balance_teams)
2054                 TeamBalance_JoinBestTeam(this);
2055
2056         if(autocvar_g_campaign)
2057                 campaign_bots_may_start = true;
2058
2059         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2060
2061         PutClientInServer(this);
2062
2063         if(IS_PLAYER(this))
2064         if(teamplay && this.team != -1)
2065         {
2066         }
2067         else
2068                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2069         this.team_selected = false;
2070 }
2071
2072 int GetPlayerLimit()
2073 {
2074         if(g_duel)
2075                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2076         int player_limit = autocvar_g_maxplayers;
2077         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2078         player_limit = M_ARGV(0, int);
2079         return player_limit;
2080 }
2081
2082 /**
2083  * Determines whether the player is allowed to join. This depends on cvar
2084  * g_maxplayers, if it isn't used this function always return true, otherwise
2085  * it checks whether the number of currently playing players exceeds g_maxplayers.
2086  * @return int number of free slots for players, 0 if none
2087  */
2088 int nJoinAllowed(entity this, entity ignore)
2089 {
2090         if(!ignore)
2091         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2092         // so report 0 free slots if restricted
2093         {
2094                 if(autocvar_g_forced_team_otherwise == "spectate")
2095                         return 0;
2096                 if(autocvar_g_forced_team_otherwise == "spectator")
2097                         return 0;
2098         }
2099
2100         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2101                 return 0; // forced spectators can never join
2102
2103         // TODO simplify this
2104         int totalClients = 0;
2105         int currentlyPlaying = 0;
2106         FOREACH_CLIENT(true, {
2107                 if(it != ignore)
2108                         ++totalClients;
2109                 if(IS_REAL_CLIENT(it))
2110                 if(IS_PLAYER(it) || it.caplayer)
2111                         ++currentlyPlaying;
2112         });
2113
2114         int player_limit = GetPlayerLimit();
2115
2116         int free_slots = 0;
2117         if (!player_limit)
2118                 free_slots = maxclients - totalClients;
2119         else if(player_limit > 0 && currentlyPlaying < player_limit)
2120                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2121
2122         static float msg_time = 0;
2123         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2124         {
2125                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2126                 msg_time = time + 0.5;
2127         }
2128
2129         return free_slots;
2130 }
2131
2132 /**
2133  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2134  * g_maxplayers_spectator_blocktime seconds
2135  */
2136 void checkSpectatorBlock(entity this)
2137 {
2138         if(IS_SPEC(this) || IS_OBSERVER(this))
2139         if(!this.caplayer)
2140         if(IS_REAL_CLIENT(this))
2141         {
2142                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2143                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2144                         dropclient(this);
2145                 }
2146         }
2147 }
2148
2149 void PrintWelcomeMessage(entity this)
2150 {
2151         if(CS(this).motd_actived_time == 0)
2152         {
2153                 if (autocvar_g_campaign) {
2154                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2155                                 CS(this).motd_actived_time = time;
2156                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2157                         }
2158                 } else {
2159                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2160                                 CS(this).motd_actived_time = time;
2161                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2162                         }
2163                 }
2164         }
2165         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2166         {
2167                 if (autocvar_g_campaign) {
2168                         if (PHYS_INPUT_BUTTON_INFO(this))
2169                                 CS(this).motd_actived_time = time;
2170                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2171                                 CS(this).motd_actived_time = 0;
2172                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2173                         }
2174                 } else {
2175                         if (PHYS_INPUT_BUTTON_INFO(this))
2176                                 CS(this).motd_actived_time = time;
2177                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2178                                 CS(this).motd_actived_time = 0;
2179                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2180                         }
2181                 }
2182         }
2183         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2184         {
2185                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2186                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2187                 else if (CS(this).motd_actived_time == -2)
2188                 {
2189                         // instantly hide MOTD
2190                         CS(this).motd_actived_time = 0;
2191                         if (autocvar_g_campaign)
2192                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2193                         else
2194                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2195                 }
2196                 else if (IS_PLAYER(this) || IS_SPEC(this))
2197                 {
2198                         // FIXME occasionally for some reason MOTD never goes away
2199                         // delay MOTD removal a little bit in the hope it fixes this bug
2200                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2201                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2202                         else //if (CS(this).motd_actived_time < -2)
2203                                 CS(this).motd_actived_time++;
2204                 }
2205         }
2206 }
2207
2208 bool joinAllowed(entity this)
2209 {
2210         if (CS(this).version_mismatch) return false;
2211         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2212         if (!nJoinAllowed(this, this)) return false;
2213         if (teamplay && lockteams) return false;
2214         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2215         if (ShowTeamSelection(this)) return false;
2216         return true;
2217 }
2218
2219 .string shootfromfixedorigin;
2220 .bool dualwielding_prev;
2221 bool PlayerThink(entity this)
2222 {
2223         if (game_stopped || intermission_running) {
2224                 this.modelflags &= ~MF_ROCKET;
2225                 if(intermission_running)
2226                         IntermissionThink(this);
2227                 return false;
2228         }
2229
2230         if (timeout_status == TIMEOUT_ACTIVE) {
2231         // don't allow the player to turn around while game is paused
2232                 // FIXME turn this into CSQC stuff
2233                 this.v_angle = this.lastV_angle;
2234                 this.angles = this.lastV_angle;
2235                 this.fixangle = true;
2236         }
2237
2238         if (frametime) player_powerups(this);
2239
2240         if (IS_DEAD(this)) {
2241                 if (this.personal && g_race_qualifying) {
2242                         if (time > this.respawn_time) {
2243                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2244                                 respawn(this);
2245                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2246                         }
2247                 } else {
2248                         if (frametime) player_anim(this);
2249
2250                         if (this.respawn_flags & RESPAWN_DENY)
2251                         {
2252                                 STAT(RESPAWN_TIME, this) = 0;
2253                                 return false;
2254                         }
2255
2256                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2257
2258                         switch(this.deadflag)
2259                         {
2260                                 case DEAD_DYING:
2261                                 {
2262                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2263                                                 this.deadflag = DEAD_RESPAWNING;
2264                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2265                                                 this.deadflag = DEAD_DEAD;
2266                                         break;
2267                                 }
2268                                 case DEAD_DEAD:
2269                                 {
2270                                         if (button_pressed)
2271                                                 this.deadflag = DEAD_RESPAWNABLE;
2272                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2273                                                 this.deadflag = DEAD_RESPAWNING;
2274                                         break;
2275                                 }
2276                                 case DEAD_RESPAWNABLE:
2277                                 {
2278                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2279                                                 this.deadflag = DEAD_RESPAWNING;
2280                                         break;
2281                                 }
2282                                 case DEAD_RESPAWNING:
2283                                 {
2284                                         if (time > this.respawn_time)
2285                                         {
2286                                                 this.respawn_time = time + 1; // only retry once a second
2287                                                 this.respawn_time_max = this.respawn_time;
2288                                                 respawn(this);
2289                                         }
2290                                         break;
2291                                 }
2292                         }
2293
2294                         ShowRespawnCountdown(this);
2295
2296                         if (this.respawn_flags & RESPAWN_SILENT)
2297                                 STAT(RESPAWN_TIME, this) = 0;
2298                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2299                         {
2300                                 if (time < this.respawn_time)
2301                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2302                                 else if (this.deadflag != DEAD_RESPAWNING)
2303                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2304                         }
2305                         else
2306                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2307                 }
2308
2309                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2310                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2311                         STAT(RESPAWN_TIME, this) *= -1;
2312
2313                 return false;
2314         }
2315
2316         FixPlayermodel(this);
2317
2318         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2319                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2320                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2321         }
2322
2323         // reset gun alignment when dual wielding status changes
2324         // to ensure guns are always aligned right and left
2325         bool dualwielding = W_DualWielding(this);
2326         if(this.dualwielding_prev != dualwielding)
2327         {
2328                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2329                 this.dualwielding_prev = dualwielding;
2330         }
2331
2332         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2333         //if(frametime)
2334         {
2335                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2336                 {
2337                         .entity weaponentity = weaponentities[slot];
2338                         if(WEP_CVAR(vortex, charge_always))
2339                                 W_Vortex_Charge(this, weaponentity, frametime);
2340                         W_WeaponFrame(this, weaponentity);
2341                 }
2342         }
2343
2344         if (frametime)
2345         {
2346                 // WEAPONTODO: Add a weapon request for this
2347                 // rot vortex charge to the charge limit
2348                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2349                 {
2350                         .entity weaponentity = weaponentities[slot];
2351                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2352                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2353                 }
2354
2355                 player_regen(this);
2356                 player_anim(this);
2357                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2358         }
2359
2360         monsters_setstatus(this);
2361
2362         return true;
2363 }
2364
2365 .bool would_spectate;
2366 void ObserverOrSpectatorThink(entity this)
2367 {
2368         bool is_spec = IS_SPEC(this);
2369         if ( CS(this).impulse )
2370         {
2371                 int r = MinigameImpulse(this, CS(this).impulse);
2372                 if (!is_spec || r)
2373                         CS(this).impulse = 0;
2374
2375                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2376                 {
2377                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2378                         CS(this).impulse = 0;
2379                         return;
2380                 }
2381         }
2382
2383         if (this.flags & FL_JUMPRELEASED) {
2384                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2385                         this.flags &= ~FL_JUMPRELEASED;
2386                         this.flags |= FL_SPAWNING;
2387                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2388                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2389                         this.flags &= ~FL_JUMPRELEASED;
2390                         if(SpectateNext(this)) {
2391                                 TRANSMUTE(Spectator, this);
2392                         } else if (is_spec) {
2393                                 TRANSMUTE(Observer, this);
2394                                 PutClientInServer(this);
2395                         }
2396                         if (is_spec)
2397                                 CS(this).impulse = 0;
2398                 } else if (is_spec) {
2399                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2400                                 this.flags &= ~FL_JUMPRELEASED;
2401                                 if(SpectatePrev(this)) {
2402                                         TRANSMUTE(Spectator, this);
2403                                 } else {
2404                                         TRANSMUTE(Observer, this);
2405                                         PutClientInServer(this);
2406                                 }
2407                                 CS(this).impulse = 0;
2408                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2409                                 this.would_spectate = false;
2410                                 this.flags &= ~FL_JUMPRELEASED;
2411                                 TRANSMUTE(Observer, this);
2412                                 PutClientInServer(this);
2413                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2414                                 PutObserverInServer(this);
2415                                 this.would_spectate = true;
2416                         }
2417                 }
2418                 else {
2419                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2420                         set_movetype(this, preferred_movetype);
2421                 }
2422         } else {
2423                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2424                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2425                         this.flags |= FL_JUMPRELEASED;
2426                         if(this.flags & FL_SPAWNING)
2427                         {
2428                                 this.flags &= ~FL_SPAWNING;
2429                                 if(joinAllowed(this))
2430                                         Join(this);
2431                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2432                                         CS(this).autojoin_checked = -1;
2433                                 return;
2434                         }
2435                 }
2436                 if(is_spec && !SpectateUpdate(this))
2437                         PutObserverInServer(this);
2438         }
2439         if (is_spec)
2440                 this.flags |= FL_CLIENT | FL_NOTARGET;
2441 }
2442
2443 void PlayerUseKey(entity this)
2444 {
2445         if (!IS_PLAYER(this))
2446                 return;
2447
2448         if(this.vehicle)
2449         {
2450                 if(!game_stopped)
2451                 {
2452                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2453                         return;
2454                 }
2455         }
2456         else if(autocvar_g_vehicles_enter)
2457         {
2458                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2459                 {
2460                         entity head, closest_target = NULL;
2461                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2462
2463                         while(head) // find the closest acceptable target to enter
2464                         {
2465                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2466                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2467                                 {
2468                                         if(closest_target)
2469                                         {
2470                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2471                                                 { closest_target = head; }
2472                                         }
2473                                         else { closest_target = head; }
2474                                 }
2475
2476                                 head = head.chain;
2477                         }
2478
2479                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2480                 }
2481         }
2482
2483         // a use key was pressed; call handlers
2484         MUTATOR_CALLHOOK(PlayerUseKey, this);
2485 }
2486
2487
2488 /*
2489 =============
2490 PlayerPreThink
2491
2492 Called every frame for each client before the physics are run
2493 =============
2494 */
2495 .float last_vehiclecheck;
2496 void PlayerPreThink (entity this)
2497 {
2498         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2499         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2500
2501         WarpZone_PlayerPhysics_FixVAngle(this);
2502
2503         if (frametime) {
2504                 // physics frames: update anticheat stuff
2505                 anticheat_prethink(this);
2506         }
2507
2508         if (blockSpectators && frametime) {
2509                 // WORKAROUND: only use dropclient in server frames (frametime set).
2510                 // Never use it in cl_movement frames (frametime zero).
2511                 checkSpectatorBlock(this);
2512         }
2513
2514         zoomstate_set = false;
2515
2516         // Check for nameless players
2517         if (this.netname == "" || this.netname != CS(this).netname_previous)
2518         {
2519                 bool assume_unchanged = (CS(this).netname_previous == "");
2520                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2521                 {
2522                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2523                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2524                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2525                         assume_unchanged = false;
2526                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2527                 }
2528                 if (isInvisibleString(this.netname))
2529                 {
2530                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2531                         sprint(this, "Warning: invisible names are not allowed.\n");
2532                         assume_unchanged = false;
2533                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2534                 }
2535                 if (!assume_unchanged && autocvar_sv_eventlog)
2536                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2537                 strcpy(CS(this).netname_previous, this.netname);
2538         }
2539
2540         // version nagging
2541         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2542         CS(this).version_nagtime = 0;
2543         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2544             // git client
2545         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2546             // git server
2547             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2548         } else {
2549             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2550             if (r < 0) { // old client
2551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2552             } else if (r > 0) { // old server
2553                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2554             }
2555         }
2556     }
2557
2558         // GOD MODE info
2559         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2560         {
2561                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2562                 this.max_armorvalue = 0;
2563         }
2564
2565         if (frametime && IS_PLAYER(this))
2566         {
2567                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2568                 {
2569                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2570                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2571                         if (this.iceblock)
2572                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2573
2574                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2575                                 Unfreeze(this, false);
2576                 }
2577                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2578                 {
2579                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2580                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2581
2582                         if (GetResource(this, RES_HEALTH) < 1)
2583                         {
2584                                 if (this.vehicle)
2585                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2586                                 if(this.event_damage)
2587                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2588                         }
2589                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2590                                 Unfreeze(this, false);
2591                 }
2592         }
2593
2594         MUTATOR_CALLHOOK(PlayerPreThink, this);
2595
2596         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2597         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2598         {
2599                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2600                 {
2601                         if(!it.owner)
2602                         {
2603                                 if(!it.team || SAME_TEAM(this, it))
2604                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2605                                 else if(autocvar_g_vehicles_steal)
2606                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2607                         }
2608                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2609                         {
2610                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2611                         }
2612                 });
2613
2614                 this.last_vehiclecheck = time + 1;
2615         }
2616
2617         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2618         {
2619                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2620                         PlayerUseKey(this);
2621                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2622         }
2623
2624         if (IS_REAL_CLIENT(this))
2625                 PrintWelcomeMessage(this);
2626
2627         if (IS_PLAYER(this)) {
2628                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2629                         error("Client can't be spawned as player on connection!");
2630                 if(!PlayerThink(this))
2631                         return;
2632         }
2633         else if (game_stopped || intermission_running) {
2634                 if(intermission_running)
2635                         IntermissionThink(this);
2636                 return;
2637         }
2638         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2639         {
2640                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2641                 CS(this).autojoin_checked = 1;
2642                 // don't do this in ClientConnect
2643                 // many things can go wrong if a client is spawned as player on connection
2644                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2645                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2646                                 && (!teamplay || autocvar_g_balance_teams)))
2647                 {
2648                         campaign_bots_may_start = true;
2649                         if(joinAllowed(this))
2650                                 Join(this);
2651                         return;
2652                 }
2653         }
2654         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2655                 ObserverOrSpectatorThink(this);
2656         }
2657
2658         // WEAPONTODO: Add weapon request for this
2659         if (!zoomstate_set) {
2660                 bool wep_zoomed = false;
2661                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2662                 {
2663                         .entity weaponentity = weaponentities[slot];
2664                         Weapon thiswep = this.(weaponentity).m_weapon;
2665                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2666                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2667                 }
2668                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2669         }
2670
2671         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2672         {
2673                 CS(this).teamkill_soundtime = 0;
2674
2675                 entity e = CS(this).teamkill_soundsource;
2676                 entity oldpusher = e.pusher;
2677                 e.pusher = this;
2678                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2679                 e.pusher = oldpusher;
2680         }
2681
2682         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2683                 CS(this).taunt_soundtime = 0;
2684                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2685         }
2686
2687         target_voicescript_next(this);
2688
2689         // WEAPONTODO: Move into weaponsystem somehow
2690         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2691         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2692         {
2693                 .entity weaponentity = weaponentities[slot];
2694                 if(this.(weaponentity).m_weapon == WEP_Null)
2695                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2696         }
2697 }
2698
2699 void DrownPlayer(entity this)
2700 {
2701         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2702                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2703         {
2704                 STAT(AIR_FINISHED, this) = 0;
2705                 return;
2706         }
2707
2708         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2709         {
2710                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2711                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2712                 STAT(AIR_FINISHED, this) = 0;
2713         }
2714         else
2715         {
2716                 if (!STAT(AIR_FINISHED, this))
2717                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2718                 if (STAT(AIR_FINISHED, this) < time)
2719                 {       // drown!
2720                         if (this.pain_finished < time)
2721                         {
2722                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2723                                 this.pain_finished = time + 0.5;
2724                         }
2725                 }
2726         }
2727 }
2728
2729 .bool move_qcphysics;
2730
2731 void Player_Physics(entity this)
2732 {
2733         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2734
2735         if(!this.move_qcphysics)
2736                 return;
2737
2738         if(!frametime && !CS(this).pm_frametime)
2739                 return;
2740
2741         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2742
2743         CS(this).pm_frametime = 0;
2744 }
2745
2746 /*
2747 =============
2748 PlayerPostThink
2749
2750 Called every frame for each client after the physics are run
2751 =============
2752 */
2753 void PlayerPostThink (entity this)
2754 {
2755         Player_Physics(this);
2756
2757         if (sv_maxidle > 0)
2758         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2759         if (IS_REAL_CLIENT(this))
2760         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2761         {
2762                 int totalClients = 0;
2763                 if(sv_maxidle_slots > 0)
2764                 {
2765                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2766                         {
2767                                 ++totalClients;
2768                         });
2769                 }
2770
2771                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2772                 { /* do nothing */ }
2773                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2774                 {
2775                         if (CS(this).idlekick_lasttimeleft)
2776                         {
2777                                 CS(this).idlekick_lasttimeleft = 0;
2778                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2779                         }
2780                 }
2781                 else
2782                 {
2783                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2784                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2785                                 if (!CS(this).idlekick_lasttimeleft)
2786                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2787                         }
2788                         if (timeleft <= 0) {
2789                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2790                                 dropclient(this);
2791                                 return;
2792                         }
2793                         else if (timeleft <= 10) {
2794                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2795                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2796                 }
2797                                 CS(this).idlekick_lasttimeleft = timeleft;
2798                         }
2799                 }
2800         }
2801
2802         CheatFrame(this);
2803
2804         if (game_stopped)
2805         {
2806                 this.solid = SOLID_NOT;
2807                 this.takedamage = DAMAGE_NO;
2808                 set_movetype(this, MOVETYPE_NONE);
2809                 CS(this).teamkill_complain = 0;
2810                 CS(this).teamkill_soundtime = 0;
2811                 CS(this).teamkill_soundsource = NULL;
2812         }
2813
2814         if (IS_PLAYER(this)) {
2815                 if(this.death_time == time && IS_DEAD(this))
2816                 {
2817                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2818                         // once all the damage events of this frame have been processed with normal size
2819                         this.maxs.z = 5;
2820                         setsize(this, this.mins, this.maxs);
2821                 }
2822                 DrownPlayer(this);
2823                 UpdateChatBubble(this);
2824                 if (CS(this).impulse) ImpulseCommands(this);
2825                 if (game_stopped)
2826                 {
2827                         CSQCMODEL_AUTOUPDATE(this);
2828                         return;
2829                 }
2830                 GetPressedKeys(this);
2831         }
2832         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2833         {
2834                 CS(this).pressedkeys = 0;
2835                 STAT(PRESSED_KEYS, this) = 0;
2836         }
2837
2838         if (this.waypointsprite_attachedforcarrier) {
2839                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2840                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2841         }
2842
2843         CSQCMODEL_AUTOUPDATE(this);
2844 }
2845
2846 /**
2847  * message "": do not say, just test flood control
2848  * return value:
2849  *   1 = accept
2850  *   0 = reject
2851  *  -1 = fake accept
2852  */
2853 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2854 {
2855         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2856                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2857
2858         if (source)
2859                 msgin = formatmessage(source, msgin);
2860
2861         string colorstr;
2862         if (!(IS_PLAYER(source) || source.caplayer))
2863                 colorstr = "^0"; // black for spectators
2864         else if(teamplay)
2865                 colorstr = Team_ColorCode(source.team);
2866         else
2867         {
2868                 colorstr = "";
2869                 teamsay = false;
2870         }
2871
2872         if (!source) {
2873                 colorstr = "";
2874                 teamsay = false;
2875         }
2876
2877         if(msgin != "")
2878                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2879
2880         /*
2881          * using bprint solves this... me stupid
2882         // how can we prevent the message from appearing in a listen server?
2883         // for now, just give "say" back and only handle say_team
2884         if(!teamsay)
2885         {
2886                 clientcommand(source, strcat("say ", msgin));
2887                 return;
2888         }
2889         */
2890
2891         string namestr = "";
2892         if (source)
2893                 namestr = playername(source, autocvar_g_chat_teamcolors);
2894
2895         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2896
2897         string msgstr = "", cmsgstr = "";
2898         string privatemsgprefix = string_null;
2899         int privatemsgprefixlen = 0;
2900         if (msgin != "")
2901         {
2902                 bool found_me = false;
2903                 if(strstrofs(msgin, "/me", 0) >= 0)
2904                 {
2905                         string newmsgin = "";
2906                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2907                         FOREACH_WORD(msgin, true,
2908                         {
2909                                 if(strdecolorize(it) == "/me")
2910                                 {
2911                                         found_me = true;
2912                                         newmsgin = cons(newmsgin, newnamestr);
2913                                 }
2914                                 else
2915                                         newmsgin = cons(newmsgin, it);
2916                         });
2917                         msgin = newmsgin;
2918                 }
2919
2920                 if(privatesay)
2921                 {
2922                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2923                         privatemsgprefixlen = strlen(msgstr);
2924                         msgstr = strcat(msgstr, msgin);
2925                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2926                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2927                 }
2928                 else if(teamsay)
2929                 {
2930                         if(found_me)
2931                         {
2932                                 //msgin = strreplace("/me", "", msgin);
2933                                 //msgin = substring(msgin, 3, strlen(msgin));
2934                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2935                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2936                         }
2937                         else
2938                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2939                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2940                 }
2941                 else
2942                 {
2943                         if(found_me)
2944                         {
2945                                 //msgin = strreplace("/me", "", msgin);
2946                                 //msgin = substring(msgin, 3, strlen(msgin));
2947                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2948                                 msgstr = strcat("\{1}^4* ^7", msgin);
2949                         }
2950                         else {
2951                                 msgstr = "\{1}";
2952                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2953                                 msgstr = strcat(msgstr, msgin);
2954                         }
2955                         cmsgstr = "";
2956                 }
2957                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2958         }
2959
2960         string fullmsgstr = msgstr;
2961         string fullcmsgstr = cmsgstr;
2962
2963         // FLOOD CONTROL
2964         int flood = 0;
2965         var .float flood_field = floodcontrol_chat;
2966         if(floodcontrol && source)
2967         {
2968                 float flood_spl;
2969                 float flood_burst;
2970                 float flood_lmax;
2971                 float lines;
2972                 if(privatesay)
2973                 {
2974                         flood_spl = autocvar_g_chat_flood_spl_tell;
2975                         flood_burst = autocvar_g_chat_flood_burst_tell;
2976                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2977                         flood_field = floodcontrol_chattell;
2978                 }
2979                 else if(teamsay)
2980                 {
2981                         flood_spl = autocvar_g_chat_flood_spl_team;
2982                         flood_burst = autocvar_g_chat_flood_burst_team;
2983                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2984                         flood_field = floodcontrol_chatteam;
2985                 }
2986                 else
2987                 {
2988                         flood_spl = autocvar_g_chat_flood_spl;
2989                         flood_burst = autocvar_g_chat_flood_burst;
2990                         flood_lmax = autocvar_g_chat_flood_lmax;
2991                         flood_field = floodcontrol_chat;
2992                 }
2993                 flood_burst = max(0, flood_burst - 1);
2994                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2995
2996                 // do flood control for the default line size
2997                 if(msgstr != "")
2998                 {
2999                         getWrappedLine_remaining = msgstr;
3000                         msgstr = "";
3001                         lines = 0;
3002                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
3003                         {
3004                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3005                                 ++lines;
3006                         }
3007                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3008
3009                         if(getWrappedLine_remaining != "")
3010                         {
3011                                 msgstr = strcat(msgstr, "\n");
3012                                 flood = 2;
3013                         }
3014
3015                         if (time >= source.(flood_field))
3016                         {
3017                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3018                         }
3019                         else
3020                         {
3021                                 flood = 1;
3022                                 msgstr = fullmsgstr;
3023                         }
3024                 }
3025                 else
3026                 {
3027                         if (time >= source.(flood_field))
3028                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3029                         else
3030                                 flood = 1;
3031                 }
3032
3033                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3034                         source.(flood_field) = flood = 0;
3035         }
3036
3037         string sourcemsgstr, sourcecmsgstr;
3038         if(flood == 2) // cannot happen for empty msgstr
3039         {
3040                 if(autocvar_g_chat_flood_notify_flooder)
3041                 {
3042                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3043                         sourcecmsgstr = "";
3044                 }
3045                 else
3046                 {
3047                         sourcemsgstr = fullmsgstr;
3048                         sourcecmsgstr = fullcmsgstr;
3049                 }
3050                 cmsgstr = "";
3051         }
3052         else
3053         {
3054                 sourcemsgstr = msgstr;
3055                 sourcecmsgstr = cmsgstr;
3056         }
3057
3058         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3059         {
3060                 if (!game_stopped)
3061                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
3062                         teamsay = -1; // spectators
3063         }
3064
3065         if(flood)
3066                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3067
3068         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3069         if(privatesay)
3070                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3071
3072         int ret;
3073         if(source && CS(source).muted)
3074         {
3075                 // always fake the message
3076                 ret = -1;
3077         }
3078         else if(flood == 1)
3079         {
3080                 if (autocvar_g_chat_flood_notify_flooder)
3081                 {
3082                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3083                         ret = 0;
3084                 }
3085                 else
3086                         ret = -1;
3087         }
3088         else
3089         {
3090                 ret = 1;
3091         }
3092
3093         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3094         {
3095                 if (!game_stopped)
3096                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3097                         ret = -1; // just hide the message completely
3098         }
3099
3100         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3101         ret = M_ARGV(1, int);
3102
3103         string event_log_msg = "";
3104
3105         if(sourcemsgstr != "" && ret != 0)
3106         {
3107                 if(ret < 0) // faked message, because the player is muted
3108                 {
3109                         sprint(source, sourcemsgstr);
3110                         if(sourcecmsgstr != "" && !privatesay)
3111                                 centerprint(source, sourcecmsgstr);
3112                 }
3113                 else if(privatesay) // private message, between 2 people only
3114                 {