Merge branch 'martin-t/cvar-prefixes' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "clientkill.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28
29 #include "bot/api.qh"
30
31 #include "../common/ent_cs.qh"
32 #include "../common/wepent.qh"
33 #include <common/state.qh>
34
35 #include "compat/quake3.qh"
36
37 #include <common/effects/qc/globalsound.qh>
38
39 #include "../common/mapobjects/func/conveyor.qh"
40 #include "../common/mapobjects/teleporters.qh"
41 #include "../common/mapobjects/target/spawnpoint.qh"
42 #include <common/mapobjects/trigger/counter.qh>
43
44 #include "../common/vehicles/all.qh"
45
46 #include "weapons/hitplot.qh"
47 #include "weapons/weaponsystem.qh"
48
49 #include "../common/net_notice.qh"
50 #include "../common/net_linked.qh"
51 #include "../common/physics/player.qh"
52
53 #include <common/vehicles/sv_vehicles.qh>
54
55 #include "../common/items/_mod.qh"
56
57 #include "../common/mutators/mutator/waypoints/all.qh"
58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
59 #include <common/gamemodes/_mod.qh>
60
61 #include "../common/mapobjects/subs.qh"
62 #include "../common/mapobjects/triggers.qh"
63 #include "../common/mapobjects/trigger/secret.qh"
64
65 #include "../common/minigames/sv_minigames.qh"
66
67 #include "../common/items/inventory.qh"
68
69 #include "../common/monsters/sv_monsters.qh"
70
71 #include "../lib/warpzone/server.qh"
72
73 #include <common/mutators/mutator/overkill/oknex.qh>
74
75 STATIC_METHOD(Client, Add, void(Client this, int _team))
76 {
77     ClientConnect(this);
78     TRANSMUTE(Player, this);
79     this.frame = 12; // 7
80     this.team = _team;
81     PutClientInServer(this);
82 }
83
84 STATIC_METHOD(Client, Remove, void(Client this))
85 {
86     TRANSMUTE(Observer, this);
87     PutClientInServer(this);
88     ClientDisconnect(this);
89 }
90
91 void send_CSQC_teamnagger() {
92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
93 }
94
95 int CountSpectators(entity player, entity to)
96 {
97         if(!player) { return 0; } // not sure how, but best to be safe
98
99         int spec_count = 0;
100
101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
102         {
103                 spec_count++;
104         });
105
106         return spec_count;
107 }
108
109 void WriteSpectators(entity player, entity to)
110 {
111         if(!player) { return; } // not sure how, but best to be safe
112
113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
114         {
115                 WriteByte(MSG_ENTITY, num_for_edict(it));
116         });
117 }
118
119 bool ClientData_Send(entity this, entity to, int sf)
120 {
121         assert(to == this.owner, return false);
122
123         entity e = to;
124         if (IS_SPEC(e)) e = e.enemy;
125
126         sf = 0;
127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
131
132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
133         WriteByte(MSG_ENTITY, sf);
134
135         if (sf & BIT(1))
136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
137
138         if(sf & BIT(4))
139         {
140                 float specs = CountSpectators(e, to);
141                 WriteByte(MSG_ENTITY, specs);
142                 WriteSpectators(e, to);
143         }
144
145         return true;
146 }
147
148 void ClientData_Attach(entity this)
149 {
150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
151         CS(this).clientdata.drawonlytoclient = this;
152         CS(this).clientdata.owner = this;
153 }
154
155 void ClientData_Detach(entity this)
156 {
157         delete(CS(this).clientdata);
158         CS(this).clientdata = NULL;
159 }
160
161 void ClientData_Touch(entity e)
162 {
163         entity cd = CS(e).clientdata;
164         if (cd) { cd.SendFlags = 1; }
165
166         // make it spectatable
167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
168         {
169                 entity cd = CS(it).clientdata;
170                 if (cd) { cd.SendFlags = 1; }
171         });
172 }
173
174
175 /*
176 =============
177 CheckPlayerModel
178
179 Checks if the argument string can be a valid playermodel.
180 Returns a valid one in doubt.
181 =============
182 */
183 string FallbackPlayerModel;
184 string CheckPlayerModel(string plyermodel) {
185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
186         {
187                 // note: we cannot summon Don Strunzone here, some player may
188                 // still have the model string set. In case anyone manages how
189                 // to change a cvar default, we'll have a small leak here.
190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
191         }
192         // only in right path
193         if( substring(plyermodel,0,14) != "models/player/")
194                 return FallbackPlayerModel;
195         // only good file extensions
196         if(substring(plyermodel,-4,4) != ".zym")
197         if(substring(plyermodel,-4,4) != ".dpm")
198         if(substring(plyermodel,-4,4) != ".iqm")
199         if(substring(plyermodel,-4,4) != ".md3")
200         if(substring(plyermodel,-4,4) != ".psk")
201                 return FallbackPlayerModel;
202         // forbid the LOD models
203         if(substring(plyermodel, -9,5) == "_lod1")
204                 return FallbackPlayerModel;
205         if(substring(plyermodel, -9,5) == "_lod2")
206                 return FallbackPlayerModel;
207         if(plyermodel != strtolower(plyermodel))
208                 return FallbackPlayerModel;
209         // also, restrict to server models
210         if(autocvar_sv_servermodelsonly)
211         {
212                 if(!fexists(plyermodel))
213                         return FallbackPlayerModel;
214         }
215         return plyermodel;
216 }
217
218 void setplayermodel(entity e, string modelname)
219 {
220         precache_model(modelname);
221         _setmodel(e, modelname);
222         player_setupanimsformodel(e);
223         if(!autocvar_g_debug_globalsounds)
224                 UpdatePlayerSounds(e);
225 }
226
227 /** putting a client as observer in the server */
228 void PutObserverInServer(entity this)
229 {
230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
231         PlayerState_detach(this);
232
233         if (IS_PLAYER(this))
234         {
235                 if(GetResource(this, RES_HEALTH) >= 1)
236                 {
237                         // despawn effect
238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
239                 }
240
241                 // was a player, recount votes and ready status
242                 if(IS_REAL_CLIENT(this))
243                 {
244                         if (vote_called) { VoteCount(false); }
245                         ReadyCount();
246                 }
247     }
248
249     {
250         entity spot = SelectSpawnPoint(this, true);
251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
252         this.angles = vec2(spot.angles);
253         this.fixangle = true;
254         // offset it so that the spectator spawns higher off the ground, looks better this way
255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
256         if (IS_REAL_CLIENT(this))
257         {
258             msg_entity = this;
259             WriteByte(MSG_ONE, SVC_SETVIEW);
260             WriteEntity(MSG_ONE, this);
261         }
262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
264         if(!autocvar_g_debug_globalsounds)
265         {
266                 // needed for player sounds
267                 this.model = "";
268                 FixPlayermodel(this);
269         }
270         setmodel(this, MDL_Null);
271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
272         this.view_ofs = '0 0 0';
273     }
274
275     RemoveGrapplingHooks(this);
276         Portal_ClearAll(this);
277         Unfreeze(this, false);
278         SetSpectatee(this, NULL);
279
280         if (this.alivetime)
281         {
282                 if (!warmup_stage)
283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
284                 this.alivetime = 0;
285         }
286
287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
288
289         WaypointSprite_PlayerDead(this);
290
291         if (CS(this).killcount != FRAGS_SPECTATOR)
292         {
293                 if(!game_stopped)
294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
296         }
297
298         accuracy_resend(this);
299
300         CS(this).spectatortime = time;
301         if(this.bot_attack)
302                 IL_REMOVE(g_bot_targets, this);
303         this.bot_attack = false;
304         if(this.monster_attack)
305                 IL_REMOVE(g_monster_targets, this);
306         this.monster_attack = false;
307     STAT(HUD, this) = HUD_NORMAL;
308         TRANSMUTE(Observer, this);
309         this.iscreature = false;
310         this.teleportable = TELEPORT_SIMPLE;
311         if(this.damagedbycontents)
312                 IL_REMOVE(g_damagedbycontents, this);
313         this.damagedbycontents = false;
314         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
315         SetSpectatee_status(this, etof(this));
316         this.takedamage = DAMAGE_NO;
317         this.solid = SOLID_NOT;
318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
319         this.flags = FL_CLIENT | FL_NOTARGET;
320         this.effects = 0;
321         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
322         this.pauserotarmor_finished = 0;
323         this.pauserothealth_finished = 0;
324         this.pauseregen_finished = 0;
325         this.damageforcescale = 0;
326         this.death_time = 0;
327         this.respawn_flags = 0;
328         this.respawn_time = 0;
329         STAT(RESPAWN_TIME, this) = 0;
330         this.alpha = 0;
331         this.scale = 0;
332         this.fade_time = 0;
333         this.pain_frame = 0;
334         this.pain_finished = 0;
335         this.strength_finished = 0;
336         this.invincible_finished = 0;
337         this.superweapons_finished = 0;
338         //this.dphitcontentsmask = 0;
339         this.dphitcontentsmask = DPCONTENTS_SOLID;
340         if (autocvar_g_playerclip_collisions)
341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
342         this.pushltime = 0;
343         this.istypefrag = 0;
344         setthink(this, func_null);
345         this.nextthink = 0;
346         this.deadflag = DEAD_NO;
347         this.crouch = false;
348         STAT(REVIVE_PROGRESS, this) = 0;
349         this.revival_time = 0;
350         this.draggable = drag_undraggable;
351
352         this.items = 0;
353         STAT(WEAPONS, this) = '0 0 0';
354         this.drawonlytoclient = this;
355
356         this.viewloc = NULL;
357
358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
359
360         this.weaponmodel = "";
361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
362         {
363                 this.weaponentities[slot] = NULL;
364         }
365         this.exteriorweaponentity = NULL;
366         CS(this).killcount = FRAGS_SPECTATOR;
367         this.velocity = '0 0 0';
368         this.avelocity = '0 0 0';
369         this.punchangle = '0 0 0';
370         this.punchvector = '0 0 0';
371         this.oldvelocity = this.velocity;
372         this.fire_endtime = -1;
373         this.event_damage = func_null;
374         this.event_heal = func_null;
375
376         for(int slot = 0; slot < MAX_AXH; ++slot)
377         {
378                 entity axh = this.(AuxiliaryXhair[slot]);
379                 this.(AuxiliaryXhair[slot]) = NULL;
380
381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
382                         delete(axh);
383         }
384
385         if (mutator_returnvalue)
386         {
387                 // mutator prevents resetting teams+score
388         }
389         else
390         {
391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
392                 this.frags = FRAGS_SPECTATOR;
393         }
394         if (CS(this).just_joined)
395                 CS(this).just_joined = false;
396 }
397
398 int player_getspecies(entity this)
399 {
400         get_model_parameters(this.model, this.skin);
401         int s = get_model_parameters_species;
402         get_model_parameters(string_null, 0);
403         if (s < 0) return SPECIES_HUMAN;
404         return s;
405 }
406
407 .float model_randomizer;
408 void FixPlayermodel(entity player)
409 {
410         string defaultmodel = "";
411         int defaultskin = 0;
412         if(autocvar_sv_defaultcharacter)
413         {
414                 if(teamplay)
415                 {
416                         switch(player.team)
417                         {
418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
422                         }
423                 }
424
425                 if(defaultmodel == "")
426                 {
427                         defaultmodel = autocvar_sv_defaultplayermodel;
428                         defaultskin = autocvar_sv_defaultplayerskin;
429                 }
430
431                 int n = tokenize_console(defaultmodel);
432                 if(n > 0)
433                 {
434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
435                         // However, do NOT randomize if the player-selected model is in the list.
436                         for (int i = 0; i < n; ++i)
437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
438                                         defaultmodel = argv(i);
439                 }
440
441                 int i = strstrofs(defaultmodel, ":", 0);
442                 if(i >= 0)
443                 {
444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
445                         defaultmodel = substring(defaultmodel, 0, i);
446                 }
447         }
448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
449         {
450                 if(teamplay)
451                 {
452                         switch(player.team)
453                         {
454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
458                         }
459                 }
460
461                 if(!defaultskin)
462                         defaultskin = autocvar_sv_defaultplayerskin;
463         }
464
465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
466         defaultmodel = M_ARGV(0, string);
467         defaultskin = M_ARGV(1, int);
468
469         bool chmdl = false;
470         int oldskin;
471         if(defaultmodel != "")
472         {
473                 if (defaultmodel != player.model)
474                 {
475                         vector m1 = player.mins;
476                         vector m2 = player.maxs;
477                         setplayermodel (player, defaultmodel);
478                         setsize (player, m1, m2);
479                         chmdl = true;
480                 }
481
482                 oldskin = player.skin;
483                 player.skin = defaultskin;
484         } else {
485                 if (player.playermodel != player.model || player.playermodel == "")
486                 {
487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
488                         vector m1 = player.mins;
489                         vector m2 = player.maxs;
490                         setplayermodel (player, player.playermodel);
491                         setsize (player, m1, m2);
492                         chmdl = true;
493                 }
494
495                 if(!autocvar_sv_defaultcharacterskin)
496                 {
497                         oldskin = player.skin;
498                         player.skin = stof(player.playerskin);
499                 }
500                 else
501                 {
502                         oldskin = player.skin;
503                         player.skin = defaultskin;
504                 }
505         }
506
507         if(chmdl || oldskin != player.skin) // model or skin has changed
508         {
509                 player.species = player_getspecies(player); // update species
510                 if(!autocvar_g_debug_globalsounds)
511                         UpdatePlayerSounds(player); // update skin sounds
512         }
513
514         if(!teamplay)
515                 if(strlen(autocvar_sv_defaultplayercolors))
516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
518 }
519
520 void PutPlayerInServer(entity this)
521 {
522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
523
524         PlayerState_attach(this);
525         accuracy_resend(this);
526
527         if (this.team < 0)
528                 TeamBalance_JoinBestTeam(this);
529
530         entity spot = SelectSpawnPoint(this, false);
531         if (!spot) {
532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
533                 return; // spawn failed
534         }
535
536         TRANSMUTE(Player, this);
537
538         CS(this).wasplayer = true;
539         this.iscreature = true;
540         this.teleportable = TELEPORT_NORMAL;
541         if(!this.damagedbycontents)
542                 IL_PUSH(g_damagedbycontents, this);
543         this.damagedbycontents = true;
544         set_movetype(this, MOVETYPE_WALK);
545         this.solid = SOLID_SLIDEBOX;
546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
547         if (autocvar_g_playerclip_collisions)
548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
551         this.frags = FRAGS_PLAYER;
552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
554         if (autocvar__notarget)
555                 this.flags |= FL_NOTARGET;
556         this.takedamage = DAMAGE_AIM;
557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
558
559         if (warmup_stage) {
560                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
561                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
562                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
563                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
564                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
565                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
566                 SetResource(this, RES_HEALTH, warmup_start_health);
567                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
569         } else {
570                 SetResource(this, RES_SHELLS, start_ammo_shells);
571                 SetResource(this, RES_BULLETS, start_ammo_nails);
572                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
573                 SetResource(this, RES_CELLS, start_ammo_cells);
574                 SetResource(this, RES_PLASMA, start_ammo_plasma);
575                 SetResource(this, RES_FUEL, start_ammo_fuel);
576                 SetResource(this, RES_HEALTH, start_health);
577                 SetResource(this, RES_ARMOR, start_armorvalue);
578                 STAT(WEAPONS, this) = start_weapons;
579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
580                 {
581                         GiveRandomWeapons(this, random_start_weapons_count,
582                                 autocvar_g_random_start_weapons, random_start_ammo);
583                 }
584         }
585         SetSpectatee_status(this, 0);
586
587         PS(this).dual_weapons = '0 0 0';
588
589         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
590
591         this.items = start_items;
592
593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
598         if (!sv_ready_restart_after_countdown && time < game_starttime)
599         {
600                 float f = game_starttime - time;
601                 this.spawnshieldtime += f;
602                 this.pauserotarmor_finished += f;
603                 this.pauserothealth_finished += f;
604                 this.pauseregen_finished += f;
605         }
606
607         this.damageforcescale = 2;
608         this.death_time = 0;
609         this.respawn_flags = 0;
610         this.respawn_time = 0;
611         STAT(RESPAWN_TIME, this) = 0;
612         this.scale = autocvar_sv_player_scale;
613         this.fade_time = 0;
614         this.pain_frame = 0;
615         this.pain_finished = 0;
616         this.pushltime = 0;
617         setthink(this, func_null); // players have no think function
618         this.nextthink = 0;
619         this.dmg_team = 0;
620         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
621
622         this.deadflag = DEAD_NO;
623
624         this.angles = spot.angles;
625         this.angles_z = 0; // never spawn tilted even if the spot says to
626         if (IS_BOT_CLIENT(this))
627         {
628                 this.v_angle = this.angles;
629                 bot_aim_reset(this);
630         }
631         this.fixangle = true; // turn this way immediately
632         this.oldvelocity = this.velocity = '0 0 0';
633         this.avelocity = '0 0 0';
634         this.punchangle = '0 0 0';
635         this.punchvector = '0 0 0';
636
637         this.strength_finished = 0;
638         this.invincible_finished = 0;
639         this.fire_endtime = -1;
640         STAT(REVIVE_PROGRESS, this) = 0;
641         this.revival_time = 0;
642
643         this.air_finished = time + 12;
644         this.waterlevel = WATERLEVEL_NONE;
645         this.watertype = CONTENT_EMPTY;
646
647         entity spawnevent = new_pure(spawnevent);
648         spawnevent.owner = this;
649         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
650
651         // Cut off any still running player sounds.
652         stopsound(this, CH_PLAYER_SINGLE);
653
654         this.model = "";
655         FixPlayermodel(this);
656         this.drawonlytoclient = NULL;
657
658         this.viewloc = NULL;
659
660         for(int slot = 0; slot < MAX_AXH; ++slot)
661         {
662                 entity axh = this.(AuxiliaryXhair[slot]);
663                 this.(AuxiliaryXhair[slot]) = NULL;
664
665                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
666                         delete(axh);
667         }
668
669         this.spawnpoint_targ = NULL;
670
671         this.crouch = false;
672         this.view_ofs = STAT(PL_VIEW_OFS, this);
673         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
674         this.spawnorigin = spot.origin;
675         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
676         // don't reset back to last position, even if new position is stuck in solid
677         this.oldorigin = this.origin;
678         if(this.conveyor)
679                 IL_REMOVE(g_conveyed, this);
680         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
681         STAT(HUD, this) = HUD_NORMAL;
682
683         this.event_damage = PlayerDamage;
684         this.event_heal = PlayerHeal;
685
686         this.draggable = func_null;
687
688         if(!this.bot_attack)
689                 IL_PUSH(g_bot_targets, this);
690         this.bot_attack = true;
691         if(!this.monster_attack)
692                 IL_PUSH(g_monster_targets, this);
693         this.monster_attack = true;
694         navigation_dynamicgoal_init(this, false);
695
696         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
697
698         // player was spectator
699         if (CS(this).killcount == FRAGS_SPECTATOR) {
700                 PlayerScore_Clear(this);
701                 CS(this).killcount = 0;
702                 CS(this).startplaytime = time;
703         }
704
705         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
706         {
707                 .entity weaponentity = weaponentities[slot];
708                 entity oldwep = this.(weaponentity);
709                 CL_SpawnWeaponentity(this, weaponentity);
710                 if(oldwep && oldwep.owner == this)
711                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
712         }
713         this.alpha = default_player_alpha;
714         this.colormod = '1 1 1' * autocvar_g_player_brightness;
715         this.exteriorweaponentity.alpha = default_weapon_alpha;
716
717         this.speedrunning = false;
718
719         this.counter_cnt = 0;
720         this.fragsfilter_cnt = 0;
721
722         target_voicescript_clear(this);
723
724         // reset fields the weapons may use
725         FOREACH(Weapons, true, {
726                 it.wr_resetplayer(it, this);
727                         // reload all reloadable weapons
728                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
729                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
730                         {
731                                 .entity weaponentity = weaponentities[slot];
732                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
733                         }
734                 }
735         });
736
737         {
738                 string s = spot.target;
739                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
740                         spot.target = string_null;
741                 SUB_UseTargets(spot, this, NULL);
742                 if(g_assault || g_race)
743                         spot.target = s;
744         }
745
746         Unfreeze(this, false);
747
748         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
749
750         if (autocvar_spawn_debug)
751         {
752                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
753                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
754         }
755
756         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757         {
758                 .entity weaponentity = weaponentities[slot];
759                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
760                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
761                 else
762                         this.(weaponentity).m_switchweapon = WEP_Null;
763                 this.(weaponentity).m_weapon = WEP_Null;
764                 this.(weaponentity).weaponname = "";
765                 this.(weaponentity).m_switchingweapon = WEP_Null;
766                 this.(weaponentity).cnt = -1;
767         }
768
769         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
770
771         if (CS(this).impulse) ImpulseCommands(this);
772
773         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
774         {
775                 .entity weaponentity = weaponentities[slot];
776                 W_WeaponFrame(this, weaponentity);
777         }
778
779         if (!warmup_stage && !this.alivetime)
780                 this.alivetime = time;
781
782         antilag_clear(this, CS(this));
783 }
784
785 /** Called when a client spawns in the server */
786 void PutClientInServer(entity this)
787 {
788         if (IS_BOT_CLIENT(this)) {
789                 TRANSMUTE(Player, this);
790         } else if (IS_REAL_CLIENT(this)) {
791                 msg_entity = this;
792                 WriteByte(MSG_ONE, SVC_SETVIEW);
793                 WriteEntity(MSG_ONE, this);
794         }
795         if (game_stopped)
796                 TRANSMUTE(Observer, this);
797
798         SetSpectatee(this, NULL);
799
800         // reset player keys
801         if(PS(this))
802                 PS(this).itemkeys = 0;
803
804         MUTATOR_CALLHOOK(PutClientInServer, this);
805
806         if (IS_OBSERVER(this)) {
807                 PutObserverInServer(this);
808         } else if (IS_PLAYER(this)) {
809                 PutPlayerInServer(this);
810         }
811 }
812
813 // TODO do we need all these fields, or should we stop autodetecting runtime
814 // changes and just have a console command to update this?
815 bool ClientInit_SendEntity(entity this, entity to, int sf)
816 {
817         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
818         return = true;
819         msg_entity = to;
820         // MSG_INIT replacement
821         // TODO: make easier to use
822         Registry_send_all();
823         W_PROP_reload(MSG_ONE, to);
824         ClientInit_misc(this);
825         MUTATOR_CALLHOOK(Ent_Init);
826 }
827 void ClientInit_misc(entity this)
828 {
829         int channel = MSG_ONE;
830         WriteHeader(channel, ENT_CLIENT_INIT);
831         WriteByte(channel, g_nexball_meter_period * 32);
832         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
833         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
834         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
835         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
836         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
837         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
838         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
839         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
840
841         if(sv_foginterval && world.fog != "")
842                 WriteString(channel, world.fog);
843         else
844                 WriteString(channel, "");
845         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
846         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
847         WriteByte(channel, serverflags);
848         WriteCoord(channel, autocvar_g_trueaim_minrange);
849 }
850
851 void ClientInit_CheckUpdate(entity this)
852 {
853         this.nextthink = time;
854         if(this.count != autocvar_g_balance_armor_blockpercent)
855         {
856                 this.count = autocvar_g_balance_armor_blockpercent;
857                 this.SendFlags |= 1;
858         }
859         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
860         {
861                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
862                 this.SendFlags |= 1;
863         }
864 }
865
866 void ClientInit_Spawn()
867 {
868         entity e = new_pure(clientinit);
869         setthink(e, ClientInit_CheckUpdate);
870         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
871
872         ClientInit_CheckUpdate(e);
873 }
874
875 /*
876 =============
877 SetNewParms
878 =============
879 */
880 void SetNewParms ()
881 {
882         // initialize parms for a new player
883         parm1 = -(86400 * 366);
884
885         MUTATOR_CALLHOOK(SetNewParms);
886 }
887
888 /*
889 =============
890 SetChangeParms
891 =============
892 */
893 void SetChangeParms (entity this)
894 {
895         // save parms for level change
896         parm1 = CS(this).parm_idlesince - time;
897
898         MUTATOR_CALLHOOK(SetChangeParms);
899 }
900
901 /*
902 =============
903 DecodeLevelParms
904 =============
905 */
906 void DecodeLevelParms(entity this)
907 {
908         // load parms
909         CS(this).parm_idlesince = parm1;
910         if (CS(this).parm_idlesince == -(86400 * 366))
911                 CS(this).parm_idlesince = time;
912
913         // whatever happens, allow 60 seconds of idling directly after connect for map loading
914         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
915
916         MUTATOR_CALLHOOK(DecodeLevelParms);
917 }
918
919 void FixClientCvars(entity e)
920 {
921         // send prediction settings to the client
922         stuffcmd(e, "\nin_bindmap 0 0\n");
923         if(autocvar_g_antilag == 3) // client side hitscan
924                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
925         if(autocvar_sv_gentle)
926                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
927
928         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
929         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
930
931         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
932
933         MUTATOR_CALLHOOK(FixClientCvars, e);
934 }
935
936 bool findinlist_abbrev(string tofind, string list)
937 {
938         if(list == "" || tofind == "")
939                 return false; // empty list or search, just return
940
941         // this function allows abbreviated strings!
942         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
943         {
944                 return true;
945         });
946
947         return false;
948 }
949
950 bool PlayerInIPList(entity p, string iplist)
951 {
952         // some safety checks (never allow local?)
953         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
954                 return false;
955
956         return findinlist_abbrev(p.netaddress, iplist);
957 }
958
959 bool PlayerInIDList(entity p, string idlist)
960 {
961         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
962         if(!p.crypto_idfp)
963                 return false;
964
965         return findinlist_abbrev(p.crypto_idfp, idlist);
966 }
967
968 bool PlayerInList(entity player, string list)
969 {
970         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
971 }
972
973 #ifdef DP_EXT_PRECONNECT
974 /*
975 =============
976 ClientPreConnect
977
978 Called once (not at each match start) when a client begins a connection to the server
979 =============
980 */
981 void ClientPreConnect(entity this)
982 {
983         if(autocvar_sv_eventlog)
984         {
985                 GameLogEcho(sprintf(":connect:%d:%d:%s",
986                         this.playerid,
987                         etof(this),
988                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
989                 ));
990         }
991 }
992 #endif
993
994 string GetClientVersionMessage(entity this)
995 {
996         if (CS(this).version_mismatch) {
997                 if(CS(this).version < autocvar_gameversion) {
998                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
999                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1000                 } else {
1001                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1002                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1003                 }
1004         } else {
1005                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1006         }
1007 }
1008
1009 string getwelcomemessage(entity this)
1010 {
1011         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1012         string modifications = M_ARGV(0, string);
1013
1014         if(g_weaponarena)
1015         {
1016                 if(g_weaponarena_random)
1017                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1018                 else
1019                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1020         }
1021         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1022                 modifications = strcat(modifications, ", No start weapons");
1023         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1024                 modifications = strcat(modifications, ", Low gravity");
1025         if(g_weapon_stay && !g_cts)
1026                 modifications = strcat(modifications, ", Weapons stay");
1027         if(g_jetpack)
1028                 modifications = strcat(modifications, ", Jet pack");
1029         if(autocvar_g_powerups == 0)
1030                 modifications = strcat(modifications, ", No powerups");
1031         if(autocvar_g_powerups > 0)
1032                 modifications = strcat(modifications, ", Powerups");
1033         modifications = substring(modifications, 2, strlen(modifications) - 2);
1034
1035         string versionmessage = GetClientVersionMessage(this);
1036         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1037
1038         if(modifications != "")
1039                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1040
1041         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1042         {
1043                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1044                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1045         }
1046
1047         if (cache_mutatormsg != "") {
1048                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1049         }
1050
1051         string mutator_msg = "";
1052         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1053         mutator_msg = M_ARGV(0, string);
1054
1055         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1056
1057         string motd = autocvar_sv_motd;
1058         if (motd != "") {
1059                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1060         }
1061         return s;
1062 }
1063
1064 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1065
1066 /**
1067 =============
1068 ClientConnect
1069
1070 Called when a client connects to the server
1071 =============
1072 */
1073 void ClientConnect(entity this)
1074 {
1075         if (Ban_MaybeEnforceBanOnce(this)) return;
1076         assert(!IS_CLIENT(this), return);
1077         this.flags |= FL_CLIENT;
1078         assert(player_count >= 0, player_count = 0);
1079
1080 #ifdef WATERMARK
1081         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1082 #endif
1083         TRANSMUTE(Client, this);
1084         CS(this).version_nagtime = time + 10 + random() * 10;
1085
1086         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1087
1088         bot_clientconnect(this);
1089
1090         Player_DetermineForcedTeam(this);
1091
1092         TRANSMUTE(Observer, this);
1093
1094         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1095
1096         // always track bots, don't ask for cl_allow_uidtracking
1097         if (IS_BOT_CLIENT(this))
1098                 PlayerStats_GameReport_AddPlayer(this);
1099         else
1100                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1101
1102         if (autocvar_sv_eventlog)
1103                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1104
1105         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1106
1107         stuffcmd(this, clientstuff, "\n");
1108         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1109
1110         FixClientCvars(this);
1111
1112         // get version info from player
1113         stuffcmd(this, "cmd clientversion $gameversion\n");
1114
1115         // notify about available teams
1116         if (teamplay)
1117         {
1118                 entity balance = TeamBalance_CheckAllowedTeams(this);
1119                 int t = TeamBalance_GetAllowedTeams(balance);
1120                 TeamBalance_Destroy(balance);
1121                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1122         }
1123         else
1124         {
1125                 stuffcmd(this, "set _teams_available 0\n");
1126         }
1127
1128         bot_relinkplayerlist();
1129
1130         CS(this).spectatortime = time;
1131         if (blockSpectators)
1132         {
1133                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1134         }
1135
1136         CS(this).jointime = time;
1137
1138         if (IS_REAL_CLIENT(this))
1139         {
1140                 if (g_weaponarena_weapons == WEPSET(TUBA))
1141                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1142         }
1143
1144         if (!sv_foginterval && world.fog != "")
1145                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1146
1147         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1148                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1149                         send_CSQC_teamnagger();
1150
1151         CSQCMODEL_AUTOINIT(this);
1152
1153         CS(this).model_randomizer = random();
1154
1155         if (IS_REAL_CLIENT(this))
1156                 sv_notice_join(this);
1157
1158         this.move_qcphysics = autocvar_sv_qcphysics;
1159
1160         // update physics stats (players can spawn before physics runs)
1161         Physics_UpdateStats(this);
1162
1163         IL_EACH(g_initforplayer, it.init_for_player, {
1164                 it.init_for_player(it, this);
1165         });
1166
1167         Handicap_Initialize(this);
1168
1169         MUTATOR_CALLHOOK(ClientConnect, this);
1170
1171         if (IS_REAL_CLIENT(this))
1172         {
1173                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1174                 {
1175                         CS(this).motd_actived_time = -1;
1176                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1177                 }
1178         }
1179 }
1180 /*
1181 =============
1182 ClientDisconnect
1183
1184 Called when a client disconnects from the server
1185 =============
1186 */
1187 .entity chatbubbleentity;
1188 void ClientDisconnect(entity this)
1189 {
1190         assert(IS_CLIENT(this), return);
1191
1192         PlayerStats_GameReport_FinalizePlayer(this);
1193         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1194         if (CS(this).active_minigame) part_minigame(this);
1195         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1196
1197         if (autocvar_sv_eventlog)
1198                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1199
1200         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1201
1202         if(IS_SPEC(this))
1203                 SetSpectatee(this, NULL);
1204
1205     MUTATOR_CALLHOOK(ClientDisconnect, this);
1206
1207         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1208         strfree(CS(this).weaponorder_byimpulse);
1209         ClientState_detach(this);
1210
1211         Portal_ClearAll(this);
1212
1213         Unfreeze(this, false);
1214
1215         RemoveGrapplingHooks(this);
1216
1217         // Here, everything has been done that requires this player to be a client.
1218
1219         this.flags &= ~FL_CLIENT;
1220
1221         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1222         if (this.killindicator) delete(this.killindicator);
1223
1224         WaypointSprite_PlayerGone(this);
1225
1226         bot_relinkplayerlist();
1227
1228         strfree(this.clientstatus);
1229         if (this.personal) delete(this.personal);
1230
1231         this.playerid = 0;
1232         ReadyCount();
1233         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1234
1235         ONREMOVE(this);
1236 }
1237
1238 void ChatBubbleThink(entity this)
1239 {
1240         this.nextthink = time;
1241         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1242         {
1243                 if(this.owner) // but why can that ever be NULL?
1244                         this.owner.chatbubbleentity = NULL;
1245                 delete(this);
1246                 return;
1247         }
1248
1249         this.mdl = "";
1250
1251         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1252         {
1253                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1254                         this.mdl = "models/sprites/minigame_busy.iqm";
1255                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1256                         this.mdl = "models/misc/chatbubble.spr";
1257         }
1258
1259         if ( this.model != this.mdl )
1260                 _setmodel(this, this.mdl);
1261
1262 }
1263
1264 void UpdateChatBubble(entity this)
1265 {
1266         if (this.alpha < 0)
1267                 return;
1268         // spawn a chatbubble entity if needed
1269         if (!this.chatbubbleentity)
1270         {
1271                 this.chatbubbleentity = new(chatbubbleentity);
1272                 this.chatbubbleentity.owner = this;
1273                 this.chatbubbleentity.exteriormodeltoclient = this;
1274                 setthink(this.chatbubbleentity, ChatBubbleThink);
1275                 this.chatbubbleentity.nextthink = time;
1276                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1277                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1278                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1279                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1280                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1281                 //this.chatbubbleentity.model = "";
1282                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1283         }
1284 }
1285
1286
1287 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1288 // added to the model skins
1289 /*void UpdateColorModHack()
1290 {
1291         float c;
1292         c = this.clientcolors & 15;
1293         // LordHavoc: only bothering to support white, green, red, yellow, blue
1294              if (!teamplay) this.colormod = '0 0 0';
1295         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1296         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1297         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1298         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1299         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1300         else this.colormod = '1 1 1';
1301 }*/
1302
1303 void respawn(entity this)
1304 {
1305         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1306         {
1307                 this.solid = SOLID_NOT;
1308                 this.takedamage = DAMAGE_NO;
1309                 set_movetype(this, MOVETYPE_FLY);
1310                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1311                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1312                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1313                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1314                 if(autocvar_g_respawn_ghosts_maxtime)
1315                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1316         }
1317
1318         CopyBody(this, 1);
1319
1320         this.effects |= EF_NODRAW; // prevent another CopyBody
1321         PutClientInServer(this);
1322 }
1323
1324 ERASEABLE
1325 void PrintToChat(entity client, string text)
1326 {
1327         text = strcat("\{1}^7", text, "\n");
1328         sprint(client, text);
1329 }
1330
1331 ERASEABLE
1332 void DebugPrintToChat(entity client, string text)
1333 {
1334         if (autocvar_developer)
1335         {
1336                 PrintToChat(client, text);
1337         }
1338 }
1339
1340 ERASEABLE
1341 void PrintToChatAll(string text)
1342 {
1343         text = strcat("\{1}^7", text, "\n");
1344         bprint(text);
1345 }
1346
1347 ERASEABLE
1348 void DebugPrintToChatAll(string text)
1349 {
1350         if (autocvar_developer)
1351         {
1352                 PrintToChatAll(text);
1353         }
1354 }
1355
1356 ERASEABLE
1357 void PrintToChatTeam(int team_num, string text)
1358 {
1359         text = strcat("\{1}^7", text, "\n");
1360         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1361         {
1362                 if (it.team == team_num)
1363                 {
1364                         sprint(it, text);
1365                 }
1366         });
1367 }
1368
1369 ERASEABLE
1370 void DebugPrintToChatTeam(int team_num, string text)
1371 {
1372         if (autocvar_developer)
1373         {
1374                 PrintToChatTeam(team_num, text);
1375         }
1376 }
1377
1378 void play_countdown(entity this, float finished, Sound samp)
1379 {
1380         TC(Sound, samp);
1381         if(IS_REAL_CLIENT(this))
1382                 if(floor(finished - time - frametime) != floor(finished - time))
1383                         if(finished - time < 6)
1384                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1385 }
1386
1387 void player_powerups(entity this)
1388 {
1389         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1390         int items_prev = this.items;
1391
1392         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1393                 this.modelflags |= MF_ROCKET;
1394         else
1395                 this.modelflags &= ~MF_ROCKET;
1396
1397         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1398
1399         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1400                 return;
1401
1402         Fire_ApplyDamage(this);
1403         Fire_ApplyEffect(this);
1404
1405         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1406         {
1407                 if (this.items & ITEM_Strength.m_itemid)
1408                 {
1409                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1410                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1411                         if (time > this.strength_finished)
1412                         {
1413                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1414                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1415                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1416                         }
1417                 }
1418                 else
1419                 {
1420                         if (time < this.strength_finished)
1421                         {
1422                                 this.items = this.items | ITEM_Strength.m_itemid;
1423                                 if(!g_cts)
1424                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1425                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1426                         }
1427                 }
1428                 if (this.items & ITEM_Shield.m_itemid)
1429                 {
1430                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1431                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1432                         if (time > this.invincible_finished)
1433                         {
1434                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1435                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1437                         }
1438                 }
1439                 else
1440                 {
1441                         if (time < this.invincible_finished)
1442                         {
1443                                 this.items = this.items | ITEM_Shield.m_itemid;
1444                                 if(!g_cts)
1445                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1447                         }
1448                 }
1449                 if (this.items & IT_SUPERWEAPON)
1450                 {
1451                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1452                         {
1453                                 this.superweapons_finished = 0;
1454                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1455                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1456                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1457                         }
1458                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1459                         {
1460                                 // don't let them run out
1461                         }
1462                         else
1463                         {
1464                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1465                                 if (time > this.superweapons_finished)
1466                                 {
1467                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1468                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1469                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1470                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1471                                 }
1472                         }
1473                 }
1474                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1475                 {
1476                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1477                         {
1478                                 this.items = this.items | IT_SUPERWEAPON;
1479                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1480                                 {
1481                                         if(!g_cts)
1482                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1483                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1484                                 }
1485                         }
1486                         else
1487                         {
1488                                 this.superweapons_finished = 0;
1489                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1490                         }
1491                 }
1492                 else
1493                 {
1494                         this.superweapons_finished = 0;
1495                 }
1496         }
1497
1498         if(autocvar_g_nodepthtestplayers)
1499                 this.effects = this.effects | EF_NODEPTHTEST;
1500
1501         if(autocvar_g_fullbrightplayers)
1502                 this.effects = this.effects | EF_FULLBRIGHT;
1503
1504         if (time >= game_starttime)
1505         if (time < this.spawnshieldtime)
1506                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1507
1508         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1509 }
1510
1511 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1512 {
1513         if(current > stable)
1514                 return current;
1515         else if(current > stable - 0.25) // when close enough, "snap"
1516                 return stable;
1517         else
1518                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1519 }
1520
1521 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1522 {
1523         if(current < stable)
1524                 return current;
1525         else if(current < stable + 0.25) // when close enough, "snap"
1526                 return stable;
1527         else
1528                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1529 }
1530
1531 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1532 {
1533         if(current > rotstable)
1534         {
1535                 if(rotframetime > 0)
1536                 {
1537                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1538                         current = max(rotstable, current - rotlinear * rotframetime);
1539                 }
1540         }
1541         else if(current < regenstable)
1542         {
1543                 if(regenframetime > 0)
1544                 {
1545                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1546                         current = min(regenstable, current + regenlinear * regenframetime);
1547                 }
1548         }
1549
1550         if(current > limit)
1551                 current = limit;
1552
1553         return current;
1554 }
1555
1556 void player_regen(entity this)
1557 {
1558         float max_mod, regen_mod, rot_mod, limit_mod;
1559         max_mod = regen_mod = rot_mod = limit_mod = 1;
1560
1561         float regen_health = autocvar_g_balance_health_regen;
1562         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1563         float regen_health_rot = autocvar_g_balance_health_rot;
1564         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1565         float regen_health_stable = autocvar_g_balance_health_regenstable;
1566         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1567         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1568                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1569         max_mod = M_ARGV(1, float);
1570         regen_mod = M_ARGV(2, float);
1571         rot_mod = M_ARGV(3, float);
1572         limit_mod = M_ARGV(4, float);
1573         regen_health = M_ARGV(5, float);
1574         regen_health_linear = M_ARGV(6, float);
1575         regen_health_rot = M_ARGV(7, float);
1576         regen_health_rotlinear = M_ARGV(8, float);
1577         regen_health_stable = M_ARGV(9, float);
1578         regen_health_rotstable = M_ARGV(10, float);
1579
1580         if(!mutator_returnvalue)
1581         if(!STAT(FROZEN, this))
1582         {
1583                 float mina, maxa, limith, limita;
1584                 maxa = autocvar_g_balance_armor_rotstable;
1585                 mina = autocvar_g_balance_armor_regenstable;
1586                 limith = GetResourceLimit(this, RES_HEALTH);
1587                 limita = GetResourceLimit(this, RES_ARMOR);
1588
1589                 regen_health_rotstable = regen_health_rotstable * max_mod;
1590                 regen_health_stable = regen_health_stable * max_mod;
1591                 limith = limith * limit_mod;
1592                 limita = limita * limit_mod;
1593
1594                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 
1595                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1596                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1597                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1598                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1599                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1600         }
1601
1602         // if player rotted to death...  die!
1603         // check this outside above checks, as player may still be able to rot to death
1604         if(GetResource(this, RES_HEALTH) < 1)
1605         {
1606                 if(this.vehicle)
1607                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1608                 if(this.event_damage)
1609                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1610         }
1611
1612         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1613         {
1614                 float minf, maxf, limitf;
1615
1616                 maxf = autocvar_g_balance_fuel_rotstable;
1617                 minf = autocvar_g_balance_fuel_regenstable;
1618                 limitf = GetResourceLimit(this, RES_FUEL);
1619
1620                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, 
1621                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1622                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1623         }
1624 }
1625
1626 bool zoomstate_set;
1627 void SetZoomState(entity this, float newzoom)
1628 {
1629         if(newzoom != CS(this).zoomstate)
1630         {
1631                 CS(this).zoomstate = newzoom;
1632                 ClientData_Touch(this);
1633         }
1634         zoomstate_set = true;
1635 }
1636
1637 void GetPressedKeys(entity this)
1638 {
1639         MUTATOR_CALLHOOK(GetPressedKeys, this);
1640         int keys = STAT(PRESSED_KEYS, this);
1641         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1642         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1643         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1644         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1645
1646         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1647         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1648         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1649         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1650         CS(this).pressedkeys = keys; // store for other users
1651
1652         STAT(PRESSED_KEYS, this) = keys;
1653 }
1654
1655 /*
1656 ======================
1657 spectate mode routines
1658 ======================
1659 */
1660
1661 void SpectateCopy(entity this, entity spectatee)
1662 {
1663         TC(Client, this); TC(Client, spectatee);
1664
1665         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1666         PS(this) = PS(spectatee);
1667         this.armortype = spectatee.armortype;
1668         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1669         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1670         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1671         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1672         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1673         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1674         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1675         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1676         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1677         CS(this).impulse = 0;
1678         this.items = spectatee.items;
1679         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1680         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1681         this.strength_finished = spectatee.strength_finished;
1682         this.invincible_finished = spectatee.invincible_finished;
1683         this.superweapons_finished = spectatee.superweapons_finished;
1684         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1685         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1686         this.punchangle = spectatee.punchangle;
1687         this.view_ofs = spectatee.view_ofs;
1688         this.velocity = spectatee.velocity;
1689         this.dmg_take = spectatee.dmg_take;
1690         this.dmg_save = spectatee.dmg_save;
1691         this.dmg_inflictor = spectatee.dmg_inflictor;
1692         this.v_angle = spectatee.v_angle;
1693         this.angles = spectatee.v_angle;
1694         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1695         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1696         this.viewloc = spectatee.viewloc;
1697         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1698                 this.fixangle = true;
1699         setorigin(this, spectatee.origin);
1700         setsize(this, spectatee.mins, spectatee.maxs);
1701         SetZoomState(this, CS(spectatee).zoomstate);
1702
1703     anticheat_spectatecopy(this, spectatee);
1704         STAT(HUD, this) = STAT(HUD, spectatee);
1705         if(spectatee.vehicle)
1706     {
1707         this.angles = spectatee.v_angle;
1708
1709         //this.fixangle = false;
1710         //this.velocity = spectatee.vehicle.velocity;
1711         this.vehicle_health = spectatee.vehicle_health;
1712         this.vehicle_shield = spectatee.vehicle_shield;
1713         this.vehicle_energy = spectatee.vehicle_energy;
1714         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1715         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1716         this.vehicle_reload1 = spectatee.vehicle_reload1;
1717         this.vehicle_reload2 = spectatee.vehicle_reload2;
1718
1719         //msg_entity = this;
1720
1721        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1722             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1723            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1724            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1725
1726         //WriteByte (MSG_ONE, SVC_SETVIEW);
1727         //    WriteEntity(MSG_ONE, this);
1728         //makevectors(spectatee.v_angle);
1729         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1730     }
1731 }
1732
1733 bool SpectateUpdate(entity this)
1734 {
1735         if(!this.enemy)
1736                 return false;
1737
1738         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1739         {
1740                 SetSpectatee(this, NULL);
1741                 return false;
1742         }
1743
1744         SpectateCopy(this, this.enemy);
1745
1746         return true;
1747 }
1748
1749 bool SpectateSet(entity this)
1750 {
1751         if(!IS_PLAYER(this.enemy))
1752                 return false;
1753
1754         ClientData_Touch(this.enemy);
1755
1756         msg_entity = this;
1757         WriteByte(MSG_ONE, SVC_SETVIEW);
1758         WriteEntity(MSG_ONE, this.enemy);
1759         set_movetype(this, MOVETYPE_NONE);
1760         accuracy_resend(this);
1761
1762         if(!SpectateUpdate(this))
1763                 PutObserverInServer(this);
1764
1765         return true;
1766 }
1767
1768 void SetSpectatee_status(entity this, int spectatee_num)
1769 {
1770         int oldspectatee_status = CS(this).spectatee_status;
1771         CS(this).spectatee_status = spectatee_num;
1772
1773         if (CS(this).spectatee_status != oldspectatee_status)
1774         {
1775                 ClientData_Touch(this);
1776                 if (g_race || g_cts) race_InitSpectator();
1777         }
1778 }
1779
1780 void SetSpectatee(entity this, entity spectatee)
1781 {
1782         if(IS_BOT_CLIENT(this))
1783                 return; // bots abuse .enemy, this code is useless to them
1784
1785         entity old_spectatee = this.enemy;
1786
1787         this.enemy = spectatee;
1788
1789         // WEAPONTODO
1790         // these are required to fix the spectator bug with arc
1791         if(old_spectatee)
1792         {
1793                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1794                 {
1795                         .entity weaponentity = weaponentities[slot];
1796                         if(old_spectatee.(weaponentity).arc_beam)
1797                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1798                 }
1799         }
1800         if(this.enemy)
1801         {
1802                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1803                 {
1804                         .entity weaponentity = weaponentities[slot];
1805                         if(this.enemy.(weaponentity).arc_beam)
1806                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1807                 }
1808         }
1809
1810         if (this.enemy)
1811                 SetSpectatee_status(this, etof(this.enemy));
1812
1813         // needed to update spectator list
1814         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1815 }
1816
1817 bool Spectate(entity this, entity pl)
1818 {
1819         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1820                 return false;
1821         pl = M_ARGV(1, entity);
1822
1823         SetSpectatee(this, pl);
1824         return SpectateSet(this);
1825 }
1826
1827 bool SpectateNext(entity this)
1828 {
1829         entity ent = find(this.enemy, classname, STR_PLAYER);
1830
1831         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1832                 ent = M_ARGV(1, entity);
1833         else if (!ent)
1834                 ent = find(ent, classname, STR_PLAYER);
1835
1836         if(ent) { SetSpectatee(this, ent); }
1837
1838         return SpectateSet(this);
1839 }
1840
1841 bool SpectatePrev(entity this)
1842 {
1843         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1844         entity ent = findchain(classname, STR_PLAYER);
1845         if (!ent) // no player
1846                 return false;
1847
1848         entity first = ent;
1849         // skip players until current spectated player
1850         if(this.enemy)
1851         while(ent && ent != this.enemy)
1852                 ent = ent.chain;
1853
1854         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1855         {
1856                 case MUT_SPECPREV_FOUND:
1857                     ent = M_ARGV(1, entity);
1858                     break;
1859                 case MUT_SPECPREV_RETURN:
1860                     return true;
1861                 case MUT_SPECPREV_CONTINUE:
1862                 default:
1863                 {
1864                         if(ent.chain)
1865                                 ent = ent.chain;
1866                         else
1867                                 ent = first;
1868                         break;
1869                 }
1870         }
1871
1872         SetSpectatee(this, ent);
1873         return SpectateSet(this);
1874 }
1875
1876 /*
1877 =============
1878 ShowRespawnCountdown()
1879
1880 Update a respawn countdown display.
1881 =============
1882 */
1883 void ShowRespawnCountdown(entity this)
1884 {
1885         float number;
1886         if(!IS_DEAD(this)) // just respawned?
1887                 return;
1888         else
1889         {
1890                 number = ceil(this.respawn_time - time);
1891                 if(number <= 0)
1892                         return;
1893                 if(number <= this.respawn_countdown)
1894                 {
1895                         this.respawn_countdown = number - 1;
1896                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1897                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1898                 }
1899         }
1900 }
1901
1902 .bool team_selected;
1903 bool ShowTeamSelection(entity this)
1904 {
1905         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1906                 return false;
1907         stuffcmd(this, "menu_showteamselect\n");
1908         return true;
1909 }
1910 void Join(entity this)
1911 {
1912         TRANSMUTE(Player, this);
1913
1914         if(!this.team_selected)
1915         if(autocvar_g_campaign || autocvar_g_balance_teams)
1916                 TeamBalance_JoinBestTeam(this);
1917
1918         if(autocvar_g_campaign)
1919                 campaign_bots_may_start = true;
1920
1921         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1922
1923         PutClientInServer(this);
1924
1925         if(IS_PLAYER(this))
1926         if(teamplay && this.team != -1)
1927         {
1928         }
1929         else
1930                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1931         this.team_selected = false;
1932 }
1933
1934 int GetPlayerLimit()
1935 {
1936         int player_limit = autocvar_g_maxplayers;
1937         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1938         player_limit = M_ARGV(0, int);
1939         return player_limit;
1940 }
1941
1942 /**
1943  * Determines whether the player is allowed to join. This depends on cvar
1944  * g_maxplayers, if it isn't used this function always return true, otherwise
1945  * it checks whether the number of currently playing players exceeds g_maxplayers.
1946  * @return int number of free slots for players, 0 if none
1947  */
1948 int nJoinAllowed(entity this, entity ignore)
1949 {
1950         if(!ignore)
1951         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1952         // so report 0 free slots if restricted
1953         {
1954                 if(autocvar_g_forced_team_otherwise == "spectate")
1955                         return 0;
1956                 if(autocvar_g_forced_team_otherwise == "spectator")
1957                         return 0;
1958         }
1959
1960         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1961                 return 0; // forced spectators can never join
1962
1963         // TODO simplify this
1964         int totalClients = 0;
1965         int currentlyPlaying = 0;
1966         FOREACH_CLIENT(true, {
1967                 if(it != ignore)
1968                         ++totalClients;
1969                 if(IS_REAL_CLIENT(it))
1970                 if(IS_PLAYER(it) || it.caplayer)
1971                         ++currentlyPlaying;
1972         });
1973
1974         int player_limit = GetPlayerLimit();
1975
1976         float free_slots = 0;
1977         if (!player_limit)
1978                 free_slots = maxclients - totalClients;
1979         else if(currentlyPlaying < player_limit)
1980                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1981
1982         static float join_prevent_msg_time = 0;
1983         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1984         {
1985                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1986                 join_prevent_msg_time = time + 3;
1987         }
1988
1989         return free_slots;
1990 }
1991
1992 /**
1993  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1994  * g_maxplayers_spectator_blocktime seconds
1995  */
1996 void checkSpectatorBlock(entity this)
1997 {
1998         if(IS_SPEC(this) || IS_OBSERVER(this))
1999         if(!this.caplayer)
2000         if(IS_REAL_CLIENT(this))
2001         {
2002                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2003                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2004                         dropclient(this);
2005                 }
2006         }
2007 }
2008
2009 void PrintWelcomeMessage(entity this)
2010 {
2011         if(CS(this).motd_actived_time == 0)
2012         {
2013                 if (autocvar_g_campaign) {
2014                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2015                                 CS(this).motd_actived_time = time;
2016                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2017                         }
2018                 } else {
2019                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2020                                 CS(this).motd_actived_time = time;
2021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2022                         }
2023                 }
2024         }
2025         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2026         {
2027                 if (autocvar_g_campaign) {
2028                         if (PHYS_INPUT_BUTTON_INFO(this))
2029                                 CS(this).motd_actived_time = time;
2030                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2031                                 CS(this).motd_actived_time = 0;
2032                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2033                         }
2034                 } else {
2035                         if (PHYS_INPUT_BUTTON_INFO(this))
2036                                 CS(this).motd_actived_time = time;
2037                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2038                                 CS(this).motd_actived_time = 0;
2039                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2040                         }
2041                 }
2042         }
2043         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2044         {
2045                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2046                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2047                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2048                 {
2049                         // instantly hide MOTD
2050                         CS(this).motd_actived_time = 0;
2051                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2052                 }
2053         }
2054 }
2055
2056 const int MIN_SPEC_TIME = 1;
2057 bool joinAllowed(entity this)
2058 {
2059         if (CS(this).version_mismatch) return false;
2060         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2061         if (!nJoinAllowed(this, this)) return false;
2062         if (teamplay && lockteams) return false;
2063         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2064         if (ShowTeamSelection(this)) return false;
2065         return true;
2066 }
2067
2068 .int items_added;
2069 .string shootfromfixedorigin;
2070 bool PlayerThink(entity this)
2071 {
2072         if (game_stopped || intermission_running) {
2073                 this.modelflags &= ~MF_ROCKET;
2074                 if(intermission_running)
2075                         IntermissionThink(this);
2076                 return false;
2077         }
2078
2079         if (timeout_status == TIMEOUT_ACTIVE) {
2080         // don't allow the player to turn around while game is paused
2081                 // FIXME turn this into CSQC stuff
2082                 this.v_angle = this.lastV_angle;
2083                 this.angles = this.lastV_angle;
2084                 this.fixangle = true;
2085         }
2086
2087         if (frametime) player_powerups(this);
2088
2089         if (IS_DEAD(this)) {
2090                 if (this.personal && g_race_qualifying) {
2091                         if (time > this.respawn_time) {
2092                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2093                                 respawn(this);
2094                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2095                         }
2096                 } else {
2097                         if (frametime) player_anim(this);
2098
2099                         if (this.respawn_flags & RESPAWN_DENY)
2100                         {
2101                                 STAT(RESPAWN_TIME, this) = 0;
2102                                 return false;
2103                         }
2104
2105                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2106
2107                         switch(this.deadflag)
2108                         {
2109                                 case DEAD_DYING:
2110                                 {
2111                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2112                                                 this.deadflag = DEAD_RESPAWNING;
2113                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2114                                                 this.deadflag = DEAD_DEAD;
2115                                         break;
2116                                 }
2117                                 case DEAD_DEAD:
2118                                 {
2119                                         if (button_pressed)
2120                                                 this.deadflag = DEAD_RESPAWNABLE;
2121                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2122                                                 this.deadflag = DEAD_RESPAWNING;
2123                                         break;
2124                                 }
2125                                 case DEAD_RESPAWNABLE:
2126                                 {
2127                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2128                                                 this.deadflag = DEAD_RESPAWNING;
2129                                         break;
2130                                 }
2131                                 case DEAD_RESPAWNING:
2132                                 {
2133                                         if (time > this.respawn_time)
2134                                         {
2135                                                 this.respawn_time = time + 1; // only retry once a second
2136                                                 this.respawn_time_max = this.respawn_time;
2137                                                 respawn(this);
2138                                         }
2139                                         break;
2140                                 }
2141                         }
2142
2143                         ShowRespawnCountdown(this);
2144
2145                         if (this.respawn_flags & RESPAWN_SILENT)
2146                                 STAT(RESPAWN_TIME, this) = 0;
2147                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2148                         {
2149                                 if (time < this.respawn_time)
2150                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2151                                 else if (this.deadflag != DEAD_RESPAWNING)
2152                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2153                         }
2154                         else
2155                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2156                 }
2157
2158                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2159                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2160                         STAT(RESPAWN_TIME, this) *= -1;
2161
2162                 return false;
2163         }
2164
2165         FixPlayermodel(this);
2166
2167         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2168                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2169                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2170         }
2171
2172         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2173         //if(frametime)
2174         {
2175                 this.items &= ~this.items_added;
2176
2177                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2178                 {
2179                         .entity weaponentity = weaponentities[slot];
2180                         W_WeaponFrame(this, weaponentity);
2181                 }
2182
2183                 this.items_added = 0;
2184                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2185             this.items_added |= IT_FUEL;
2186
2187                 this.items |= this.items_added;
2188         }
2189
2190         player_regen(this);
2191
2192         // WEAPONTODO: Add a weapon request for this
2193         // rot vortex charge to the charge limit
2194         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2195         {
2196                 .entity weaponentity = weaponentities[slot];
2197                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2198                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2199         }
2200
2201         if (frametime) player_anim(this);
2202
2203         // secret status
2204         secrets_setstatus(this);
2205
2206         // monsters status
2207         monsters_setstatus(this);
2208
2209         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2210
2211         return true;
2212 }
2213
2214 .bool would_spectate;
2215 void ObserverThink(entity this)
2216 {
2217         if ( CS(this).impulse )
2218         {
2219                 MinigameImpulse(this, CS(this).impulse);
2220                 CS(this).impulse = 0;
2221         }
2222
2223         if (this.flags & FL_JUMPRELEASED) {
2224                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2225                         this.flags &= ~FL_JUMPRELEASED;
2226                         this.flags |= FL_SPAWNING;
2227                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2228                         this.flags &= ~FL_JUMPRELEASED;
2229                         if(SpectateNext(this)) {
2230                                 TRANSMUTE(Spectator, this);
2231                         }
2232                 } else {
2233                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2234                         set_movetype(this, preferred_movetype);
2235                 }
2236         } else {
2237                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2238                         this.flags |= FL_JUMPRELEASED;
2239                         if(this.flags & FL_SPAWNING)
2240                         {
2241                                 this.flags &= ~FL_SPAWNING;
2242                                 Join(this);
2243                                 return;
2244                         }
2245                 }
2246         }
2247 }
2248
2249 void SpectatorThink(entity this)
2250 {
2251         if ( CS(this).impulse )
2252         {
2253                 if(MinigameImpulse(this, CS(this).impulse))
2254                         CS(this).impulse = 0;
2255
2256                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2257                 {
2258                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2259                         CS(this).impulse = 0;
2260                         return;
2261                 }
2262         }
2263
2264         if (this.flags & FL_JUMPRELEASED) {
2265                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2266                         this.flags &= ~FL_JUMPRELEASED;
2267                         this.flags |= FL_SPAWNING;
2268                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2269                         this.flags &= ~FL_JUMPRELEASED;
2270                         if(SpectateNext(this)) {
2271                                 TRANSMUTE(Spectator, this);
2272                         } else {
2273                                 TRANSMUTE(Observer, this);
2274                                 PutClientInServer(this);
2275                         }
2276                         CS(this).impulse = 0;
2277                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2278                         this.flags &= ~FL_JUMPRELEASED;
2279                         if(SpectatePrev(this)) {
2280                                 TRANSMUTE(Spectator, this);
2281                         } else {
2282                                 TRANSMUTE(Observer, this);
2283                                 PutClientInServer(this);
2284                         }
2285                         CS(this).impulse = 0;
2286                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2287                         this.would_spectate = false;
2288                         this.flags &= ~FL_JUMPRELEASED;
2289                         TRANSMUTE(Observer, this);
2290                         PutClientInServer(this);
2291                 } else {
2292                         if(!SpectateUpdate(this))
2293                         {
2294                                 if(!SpectateNext(this))
2295                                 {
2296                                         PutObserverInServer(this);
2297                                         this.would_spectate = true;
2298                                 }
2299                         }
2300                 }
2301         } else {
2302                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2303                         this.flags |= FL_JUMPRELEASED;
2304                         if(this.flags & FL_SPAWNING)
2305                         {
2306                                 this.flags &= ~FL_SPAWNING;
2307                                 Join(this);
2308                                 return;
2309                         }
2310                 }
2311                 if(!SpectateUpdate(this))
2312                         PutObserverInServer(this);
2313         }
2314
2315         this.flags |= FL_CLIENT | FL_NOTARGET;
2316 }
2317
2318 void PlayerUseKey(entity this)
2319 {
2320         if (!IS_PLAYER(this))
2321                 return;
2322
2323         if(this.vehicle)
2324         {
2325                 if(!game_stopped)
2326                 {
2327                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2328                         return;
2329                 }
2330         }
2331         else if(autocvar_g_vehicles_enter)
2332         {
2333                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2334                 {
2335                         entity head, closest_target = NULL;
2336                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2337
2338                         while(head) // find the closest acceptable target to enter
2339                         {
2340                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2341                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2342                                 {
2343                                         if(closest_target)
2344                                         {
2345                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2346                                                 { closest_target = head; }
2347                                         }
2348                                         else { closest_target = head; }
2349                                 }
2350
2351                                 head = head.chain;
2352                         }
2353
2354                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2355                 }
2356         }
2357
2358         // a use key was pressed; call handlers
2359         MUTATOR_CALLHOOK(PlayerUseKey, this);
2360 }
2361
2362
2363 /*
2364 =============
2365 PlayerPreThink
2366
2367 Called every frame for each client before the physics are run
2368 =============
2369 */
2370 .float last_vehiclecheck;
2371 void PlayerPreThink (entity this)
2372 {
2373         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2374         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2375
2376         WarpZone_PlayerPhysics_FixVAngle(this);
2377
2378         if (frametime) {
2379                 // physics frames: update anticheat stuff
2380                 anticheat_prethink(this);
2381         }
2382
2383         if (blockSpectators && frametime) {
2384                 // WORKAROUND: only use dropclient in server frames (frametime set).
2385                 // Never use it in cl_movement frames (frametime zero).
2386                 checkSpectatorBlock(this);
2387         }
2388
2389         zoomstate_set = false;
2390
2391         // Check for nameless players
2392         if (this.netname == "" || this.netname != CS(this).netname_previous)
2393         {
2394                 bool assume_unchanged = (CS(this).netname_previous == "");
2395                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2396                 {
2397                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2398                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2399                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2400                         assume_unchanged = false;
2401                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2402                 }
2403                 if (isInvisibleString(this.netname))
2404                 {
2405                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2406                         sprint(this, "Warning: invisible names are not allowed.\n");
2407                         assume_unchanged = false;
2408                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2409                 }
2410                 if (!assume_unchanged && autocvar_sv_eventlog)
2411                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2412                 strcpy(CS(this).netname_previous, this.netname);
2413         }
2414
2415         // version nagging
2416         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2417         CS(this).version_nagtime = 0;
2418         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2419             // git client
2420         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2421             // git server
2422             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2423         } else {
2424             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2425             if (r < 0) { // old client
2426                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2427             } else if (r > 0) { // old server
2428                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2429             }
2430         }
2431     }
2432
2433         // GOD MODE info
2434         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2435         {
2436                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2437                 this.max_armorvalue = 0;
2438         }
2439
2440         if(IS_PLAYER(this))
2441         {
2442                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2443                 {
2444                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2445                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2446                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2447
2448                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2449                                 Unfreeze(this, false);
2450                 }
2451                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2452                 {
2453                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2454                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2455
2456                         if (GetResource(this, RES_HEALTH) < 1)
2457                         {
2458                                 if (this.vehicle)
2459                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2460                                 if(this.event_damage)
2461                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2462                         }
2463                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2464                                 Unfreeze(this, false);
2465                 }
2466         }
2467
2468         MUTATOR_CALLHOOK(PlayerPreThink, this);
2469
2470         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2471         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2472         {
2473                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2474                 {
2475                         if(!it.owner)
2476                         {
2477                                 if(!it.team || SAME_TEAM(this, it))
2478                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2479                                 else if(autocvar_g_vehicles_steal)
2480                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2481                         }
2482                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2483                         {
2484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2485                         }
2486                 });
2487
2488                 this.last_vehiclecheck = time + 1;
2489         }
2490
2491         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2492         {
2493                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2494                         PlayerUseKey(this);
2495                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2496         }
2497
2498         if (IS_REAL_CLIENT(this))
2499                 PrintWelcomeMessage(this);
2500
2501         if (IS_PLAYER(this)) {
2502                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2503                         error("Client can't be spawned as player on connection!");
2504                 if(!PlayerThink(this))
2505                         return;
2506         }
2507         else if (game_stopped || intermission_running) {
2508                 if(intermission_running)
2509                         IntermissionThink(this);
2510                 return;
2511         }
2512         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2513         {
2514                 CS(this).autojoin_checked = true;
2515                 // don't do this in ClientConnect
2516                 // many things can go wrong if a client is spawned as player on connection
2517                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2518                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2519                                 && (!teamplay || autocvar_g_balance_teams)))
2520                 {
2521                         campaign_bots_may_start = true;
2522                         Join(this);
2523                         return;
2524                 }
2525         }
2526         else if (IS_OBSERVER(this)) {
2527                 ObserverThink(this);
2528         }
2529         else if (IS_SPEC(this)) {
2530                 SpectatorThink(this);
2531         }
2532
2533         // WEAPONTODO: Add weapon request for this
2534         if (!zoomstate_set) {
2535                 bool wep_zoomed = false;
2536                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2537                 {
2538                         .entity weaponentity = weaponentities[slot];
2539                         Weapon thiswep = this.(weaponentity).m_weapon;
2540                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2541                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2542                 }
2543                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2544     }
2545
2546         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2547         {
2548                 CS(this).teamkill_soundtime = 0;
2549
2550                 entity e = CS(this).teamkill_soundsource;
2551                 entity oldpusher = e.pusher;
2552                 e.pusher = this;
2553                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2554                 e.pusher = oldpusher;
2555         }
2556
2557         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2558                 CS(this).taunt_soundtime = 0;
2559                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2560         }
2561
2562         target_voicescript_next(this);
2563
2564         // WEAPONTODO: Move into weaponsystem somehow
2565         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2566         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2567         {
2568                 .entity weaponentity = weaponentities[slot];
2569                 if(this.(weaponentity).m_weapon == WEP_Null)
2570                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2571         }
2572 }
2573
2574 void DrownPlayer(entity this)
2575 {
2576         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2577                 return;
2578
2579         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2580         {
2581                 if(this.air_finished < time)
2582                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2583                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2584         }
2585         else if (this.air_finished < time)
2586         {       // drown!
2587                 if (this.pain_finished < time)
2588                 {
2589                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2590                         this.pain_finished = time + 0.5;
2591                 }
2592         }
2593 }
2594
2595 .bool move_qcphysics;
2596
2597 void Player_Physics(entity this)
2598 {
2599         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2600
2601         if(!this.move_qcphysics)
2602                 return;
2603
2604         if(!frametime && !CS(this).pm_frametime)
2605                 return;
2606
2607         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2608
2609         CS(this).pm_frametime = 0;
2610 }
2611
2612 /*
2613 =============
2614 PlayerPostThink
2615
2616 Called every frame for each client after the physics are run
2617 =============
2618 */
2619 void PlayerPostThink (entity this)
2620 {
2621         Player_Physics(this);
2622
2623         if (sv_maxidle > 0)
2624         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2625         if (IS_REAL_CLIENT(this))
2626         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2627         {
2628                 int totalClients = 0;
2629                 if(sv_maxidle_slots > 0)
2630                 {
2631                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2632                         {
2633                                 ++totalClients;
2634                         });
2635                 }
2636
2637                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2638                 { /* do nothing */ }
2639                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2640                 {
2641                         if (CS(this).idlekick_lasttimeleft)
2642                         {
2643                                 CS(this).idlekick_lasttimeleft = 0;
2644                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2645                         }
2646                 }
2647                 else
2648                 {
2649                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2650                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2651                                 if (!CS(this).idlekick_lasttimeleft)
2652                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2653                         }
2654                         if (timeleft <= 0) {
2655                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2656                                 dropclient(this);
2657                                 return;
2658                         }
2659                         else if (timeleft <= 10) {
2660                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2661                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2662                 }
2663                                 CS(this).idlekick_lasttimeleft = timeleft;
2664                         }
2665                 }
2666         }
2667
2668         CheatFrame(this);
2669
2670         if (game_stopped)
2671         {
2672                 this.solid = SOLID_NOT;
2673                 this.takedamage = DAMAGE_NO;
2674                 set_movetype(this, MOVETYPE_NONE);
2675         }
2676
2677         if (IS_PLAYER(this)) {
2678                 if(this.death_time == time && IS_DEAD(this))
2679                 {
2680                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2681                         // once all the damage events of this frame have been processed with normal size
2682                         this.maxs.z = 5;
2683                         setsize(this, this.mins, this.maxs);
2684                 }
2685                 DrownPlayer(this);
2686                 UpdateChatBubble(this);
2687                 if (CS(this).impulse) ImpulseCommands(this);
2688                 if (game_stopped)
2689                 {
2690                         CSQCMODEL_AUTOUPDATE(this);
2691                         return;
2692                 }
2693                 GetPressedKeys(this);
2694         }
2695
2696         if (this.waypointsprite_attachedforcarrier) {
2697                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2698                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2699         }
2700
2701         CSQCMODEL_AUTOUPDATE(this);
2702 }
2703
2704 /**
2705  * message "": do not say, just test flood control
2706  * return value:
2707  *   1 = accept
2708  *   0 = reject
2709  *  -1 = fake accept
2710  */
2711 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2712 {
2713         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2714                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2715
2716         if (source)
2717                 msgin = formatmessage(source, msgin);
2718
2719         string colorstr;
2720         if (!(IS_PLAYER(source) || source.caplayer))
2721                 colorstr = "^0"; // black for spectators
2722         else if(teamplay)
2723                 colorstr = Team_ColorCode(source.team);
2724         else
2725         {
2726                 colorstr = "";
2727                 teamsay = false;
2728         }
2729
2730         if (!source) {
2731                 colorstr = "";
2732                 teamsay = false;
2733         }
2734
2735         if(msgin != "")
2736                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2737
2738         /*
2739          * using bprint solves this... me stupid
2740         // how can we prevent the message from appearing in a listen server?
2741         // for now, just give "say" back and only handle say_team
2742         if(!teamsay)
2743         {
2744                 clientcommand(source, strcat("say ", msgin));
2745                 return;
2746         }
2747         */
2748
2749         string namestr = "";
2750         if (source)
2751                 namestr = playername(source, autocvar_g_chat_teamcolors);
2752
2753         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2754
2755         string msgstr = "", cmsgstr = "";
2756         string privatemsgprefix = string_null;
2757         int privatemsgprefixlen = 0;
2758         if (msgin != "")
2759         {
2760                 bool found_me = false;
2761                 if(strstrofs(msgin, "/me", 0) >= 0)
2762                 {
2763                         string newmsgin = "";
2764                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2765                         FOREACH_WORD(msgin, true,
2766                         {
2767                                 if(strdecolorize(it) == "/me")
2768                                 {
2769                                         found_me = true;
2770                                         newmsgin = cons(newmsgin, newnamestr);
2771                                 }
2772                                 else
2773                                         newmsgin = cons(newmsgin, it);
2774                         });
2775                         msgin = newmsgin;
2776                 }
2777
2778                 if(privatesay)
2779                 {
2780                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2781                         privatemsgprefixlen = strlen(msgstr);
2782                         msgstr = strcat(msgstr, msgin);
2783                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2784                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2785                 }
2786                 else if(teamsay)
2787                 {
2788                         if(found_me)
2789                         {
2790                                 //msgin = strreplace("/me", "", msgin);
2791                                 //msgin = substring(msgin, 3, strlen(msgin));
2792                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2793                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2794                         }
2795                         else
2796                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2797                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2798                 }
2799                 else
2800                 {
2801                         if(found_me)
2802                         {
2803                                 //msgin = strreplace("/me", "", msgin);
2804                                 //msgin = substring(msgin, 3, strlen(msgin));
2805                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2806                                 msgstr = strcat("\{1}^4* ^7", msgin);
2807                         }
2808                         else {
2809                                 msgstr = "\{1}";
2810                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2811                                 msgstr = strcat(msgstr, msgin);
2812                         }
2813                         cmsgstr = "";
2814                 }
2815                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2816         }
2817
2818         string fullmsgstr = msgstr;
2819         string fullcmsgstr = cmsgstr;
2820
2821         // FLOOD CONTROL
2822         int flood = 0;
2823         var .float flood_field = floodcontrol_chat;
2824         if(floodcontrol && source)
2825         {
2826                 float flood_spl;
2827                 float flood_burst;
2828                 float flood_lmax;
2829                 float lines;
2830                 if(privatesay)
2831                 {
2832                         flood_spl = autocvar_g_chat_flood_spl_tell;
2833                         flood_burst = autocvar_g_chat_flood_burst_tell;
2834                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2835                         flood_field = floodcontrol_chattell;
2836                 }
2837                 else if(teamsay)
2838                 {
2839                         flood_spl = autocvar_g_chat_flood_spl_team;
2840                         flood_burst = autocvar_g_chat_flood_burst_team;
2841                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2842                         flood_field = floodcontrol_chatteam;
2843                 }
2844                 else
2845                 {
2846                         flood_spl = autocvar_g_chat_flood_spl;
2847                         flood_burst = autocvar_g_chat_flood_burst;
2848                         flood_lmax = autocvar_g_chat_flood_lmax;
2849                         flood_field = floodcontrol_chat;
2850                 }
2851                 flood_burst = max(0, flood_burst - 1);
2852                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2853
2854                 // do flood control for the default line size
2855                 if(msgstr != "")
2856                 {
2857                         getWrappedLine_remaining = msgstr;
2858                         msgstr = "";
2859                         lines = 0;
2860                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2861                         {
2862                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2863                                 ++lines;
2864                         }
2865                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2866
2867                         if(getWrappedLine_remaining != "")
2868                         {
2869                                 msgstr = strcat(msgstr, "\n");
2870                                 flood = 2;
2871                         }
2872
2873                         if (time >= source.(flood_field))
2874                         {
2875                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2876                         }
2877                         else
2878                         {
2879                                 flood = 1;
2880                                 msgstr = fullmsgstr;
2881                         }
2882                 }
2883                 else
2884                 {
2885                         if (time >= source.(flood_field))
2886                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2887                         else
2888                                 flood = 1;
2889                 }
2890
2891                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2892                         source.(flood_field) = flood = 0;
2893         }
2894
2895         string sourcemsgstr, sourcecmsgstr;
2896         if(flood == 2) // cannot happen for empty msgstr
2897         {
2898                 if(autocvar_g_chat_flood_notify_flooder)
2899                 {
2900                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2901                         sourcecmsgstr = "";
2902                 }
2903                 else
2904                 {
2905                         sourcemsgstr = fullmsgstr;
2906                         sourcecmsgstr = fullcmsgstr;
2907                 }
2908                 cmsgstr = "";
2909         }
2910         else
2911         {
2912                 sourcemsgstr = msgstr;
2913                 sourcecmsgstr = cmsgstr;
2914         }
2915
2916         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2917         {
2918                 if (!game_stopped)
2919                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2920                         teamsay = -1; // spectators
2921         }
2922
2923         if(flood)
2924                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2925
2926         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2927         if(privatesay)
2928                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2929
2930         int ret;
2931         if(source && CS(source).muted)
2932         {
2933                 // always fake the message
2934                 ret = -1;
2935         }
2936         else if(flood == 1)
2937         {
2938                 if (autocvar_g_chat_flood_notify_flooder)
2939                 {
2940                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2941                         ret = 0;
2942                 }
2943                 else
2944                         ret = -1;
2945         }
2946         else
2947         {
2948                 ret = 1;
2949         }
2950
2951         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2952         {
2953                 if (!game_stopped)
2954                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2955                         ret = -1; // just hide the message completely
2956         }
2957
2958         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2959         ret = M_ARGV(1, int);
2960
2961         string event_log_msg = "";
2962
2963         if(sourcemsgstr != "" && ret != 0)
2964         {
2965                 if(ret < 0) // faked message, because the player is muted
2966                 {
2967                         sprint(source, sourcemsgstr);
2968                         if(sourcecmsgstr != "" && !privatesay)
2969                                 centerprint(source, sourcecmsgstr);
2970                 }
2971                 else if(privatesay) // private message, between 2 people only
2972                 {
2973                         sprint(source, sourcemsgstr);
2974                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2975                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2976                         {
2977                                 sprint(privatesay, msgstr);
2978                                 if(cmsgstr != "")
2979                                         centerprint(privatesay, cmsgstr);
2980                         }
2981                 }
2982                 else if ( teamsay && CS(source).active_minigame )
2983                 {
2984                         sprint(source, sourcemsgstr);
2985                         dedicated_print(msgstr); // send to server console too
2986                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2987                                 sprint(it, msgstr);
2988                         });
2989                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
2990
2991                 }
2992                 else if(teamsay > 0) // team message, only sent to team mates
2993                 {
2994                         sprint(source, sourcemsgstr);
2995                         dedicated_print(msgstr); // send to server console too
2996                         if(sourcecmsgstr != "")
2997                                 centerprint(source, sourcecmsgstr);
2998                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2999                                 sprint(it, msgstr);
3000                                 if(cmsgstr != "")
3001                                         centerprint(it, cmsgstr);
3002                         });
3003                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3004                 }
3005                 else if(teamsay < 0) // spectator message, only sent to spectators
3006                 {
3007                         sprint(source, sourcemsgstr);
3008                         dedicated_print(msgstr); // send to server console too
3009                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3010                                 sprint(it, msgstr);
3011                         });
3012                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3013                 }
3014                 else
3015                 {
3016                         if (source) {
3017                                 sprint(source, sourcemsgstr);
3018                                 dedicated_print(msgstr); // send to server console too
3019                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3020                         }
3021                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3022                                 sprint(it, msgstr);
3023                         });
3024                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3025                 }
3026         }
3027
3028         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3029                 GameLogEcho(event_log_msg);
3030         }
3031
3032         return ret;
3033 }
3034
3035 // hack to copy the button fields from the client entity to the Client State
3036 void PM_UpdateButtons(entity this, entity store)
3037 {
3038         if(this.impulse)
3039                 store.impulse = this.impulse;
3040         this.impulse = 0;
3041
3042         bool typing = this.buttonchat || this.button12;
3043
3044         store.button0 = (typing) ? 0 : this.button0;
3045         //button1?!
3046         store.button2 = (typing) ? 0 : this.button2;
3047         store.button3 = (typing) ? 0 : this.button3;
3048         store.button4 = this.button4;
3049         store.button5 = (typing) ? 0 : this.button5;
3050         store.button6 = this.button6;
3051         store.button7 = this.button7;
3052         store.button8 = this.button8;
3053         store.button9 = this.button9;
3054         store.button10 = this.button10;
3055         store.button11 = this.button11;
3056         store.button12 = this.button12;
3057         store.button13 = this.button13;
3058         store.button14 = this.button14;
3059         store.button15 = this.button15;
3060         store.button16 = this.button16;
3061         store.buttonuse = this.buttonuse;
3062         store.buttonchat = this.buttonchat;
3063
3064         store.cursor_active = this.cursor_active;
3065         store.cursor_screen = this.cursor_screen;
3066         store.cursor_trace_start = this.cursor_trace_start;
3067         store.cursor_trace_endpos = this.cursor_trace_endpos;
3068         store.cursor_trace_ent = this.cursor_trace_ent;
3069
3070         store.ping = this.ping;
3071         store.ping_packetloss = this.ping_packetloss;
3072         store.ping_movementloss = this.ping_movementloss;
3073
3074         store.v_angle = this.v_angle;
3075         store.movement = (typing) ? '0 0 0' : this.movement;
3076 }
3077
3078 NET_HANDLE(fpsreport, bool)
3079 {
3080         int fps = ReadShort();
3081         PlayerScore_Set(sender, SP_FPS, fps);
3082         return true;
3083 }