3a99e31ded5d44003bdeba1f36df6bf52083a39a
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "clientkill.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28
29 #include "bot/api.qh"
30
31 #include "../common/ent_cs.qh"
32 #include "../common/wepent.qh"
33 #include <common/state.qh>
34
35 #include "compat/quake3.qh"
36
37 #include <common/effects/qc/globalsound.qh>
38
39 #include "../common/mapobjects/func/conveyor.qh"
40 #include "../common/mapobjects/teleporters.qh"
41 #include "../common/mapobjects/target/spawnpoint.qh"
42 #include <common/mapobjects/trigger/counter.qh>
43 #include <common/mapobjects/trigger/swamp.qh>
44
45 #include "../common/vehicles/all.qh"
46
47 #include "weapons/hitplot.qh"
48 #include "weapons/weaponsystem.qh"
49
50 #include "../common/net_notice.qh"
51 #include "../common/net_linked.qh"
52 #include "../common/physics/player.qh"
53
54 #include <common/vehicles/sv_vehicles.qh>
55
56 #include "../common/items/_mod.qh"
57
58 #include "../common/mutators/mutator/waypoints/all.qh"
59 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
60 #include <common/gamemodes/_mod.qh>
61
62 #include "../common/mapobjects/subs.qh"
63 #include "../common/mapobjects/triggers.qh"
64 #include "../common/mapobjects/trigger/secret.qh"
65
66 #include "../common/minigames/sv_minigames.qh"
67
68 #include "../common/items/inventory.qh"
69
70 #include "../common/monsters/sv_monsters.qh"
71
72 #include "../lib/warpzone/server.qh"
73
74 #include <common/mutators/mutator/overkill/oknex.qh>
75
76 STATIC_METHOD(Client, Add, void(Client this, int _team))
77 {
78     ClientConnect(this);
79     TRANSMUTE(Player, this);
80     this.frame = 12; // 7
81     this.team = _team;
82     PutClientInServer(this);
83 }
84
85 STATIC_METHOD(Client, Remove, void(Client this))
86 {
87     TRANSMUTE(Observer, this);
88     PutClientInServer(this);
89     ClientDisconnect(this);
90 }
91
92 void send_CSQC_teamnagger() {
93         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
94 }
95
96 int CountSpectators(entity player, entity to)
97 {
98         if(!player) { return 0; } // not sure how, but best to be safe
99
100         int spec_count = 0;
101
102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
103         {
104                 spec_count++;
105         });
106
107         return spec_count;
108 }
109
110 void WriteSpectators(entity player, entity to)
111 {
112         if(!player) { return; } // not sure how, but best to be safe
113
114         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
115         {
116                 WriteByte(MSG_ENTITY, num_for_edict(it));
117         });
118 }
119
120 bool ClientData_Send(entity this, entity to, int sf)
121 {
122         assert(to == this.owner, return false);
123
124         entity e = to;
125         if (IS_SPEC(e)) e = e.enemy;
126
127         sf = 0;
128         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
129         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
130         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
131         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
132
133         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
134         WriteByte(MSG_ENTITY, sf);
135
136         if (sf & BIT(1))
137                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
138
139         if(sf & BIT(4))
140         {
141                 float specs = CountSpectators(e, to);
142                 WriteByte(MSG_ENTITY, specs);
143                 WriteSpectators(e, to);
144         }
145
146         return true;
147 }
148
149 void ClientData_Attach(entity this)
150 {
151         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
152         CS(this).clientdata.drawonlytoclient = this;
153         CS(this).clientdata.owner = this;
154 }
155
156 void ClientData_Detach(entity this)
157 {
158         delete(CS(this).clientdata);
159         CS(this).clientdata = NULL;
160 }
161
162 void ClientData_Touch(entity e)
163 {
164         entity cd = CS(e).clientdata;
165         if (cd) { cd.SendFlags = 1; }
166
167         // make it spectatable
168         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
169         {
170                 entity cd = CS(it).clientdata;
171                 if (cd) { cd.SendFlags = 1; }
172         });
173 }
174
175
176 /*
177 =============
178 CheckPlayerModel
179
180 Checks if the argument string can be a valid playermodel.
181 Returns a valid one in doubt.
182 =============
183 */
184 string FallbackPlayerModel;
185 string CheckPlayerModel(string plyermodel) {
186         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
187         {
188                 // note: we cannot summon Don Strunzone here, some player may
189                 // still have the model string set. In case anyone manages how
190                 // to change a cvar default, we'll have a small leak here.
191                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
192         }
193         // only in right path
194         if( substring(plyermodel,0,14) != "models/player/")
195                 return FallbackPlayerModel;
196         // only good file extensions
197         if(substring(plyermodel,-4,4) != ".zym")
198         if(substring(plyermodel,-4,4) != ".dpm")
199         if(substring(plyermodel,-4,4) != ".iqm")
200         if(substring(plyermodel,-4,4) != ".md3")
201         if(substring(plyermodel,-4,4) != ".psk")
202                 return FallbackPlayerModel;
203         // forbid the LOD models
204         if(substring(plyermodel, -9,5) == "_lod1")
205                 return FallbackPlayerModel;
206         if(substring(plyermodel, -9,5) == "_lod2")
207                 return FallbackPlayerModel;
208         if(plyermodel != strtolower(plyermodel))
209                 return FallbackPlayerModel;
210         // also, restrict to server models
211         if(autocvar_sv_servermodelsonly)
212         {
213                 if(!fexists(plyermodel))
214                         return FallbackPlayerModel;
215         }
216         return plyermodel;
217 }
218
219 void setplayermodel(entity e, string modelname)
220 {
221         precache_model(modelname);
222         _setmodel(e, modelname);
223         player_setupanimsformodel(e);
224         if(!autocvar_g_debug_globalsounds)
225                 UpdatePlayerSounds(e);
226 }
227
228 /** putting a client as observer in the server */
229 void PutObserverInServer(entity this)
230 {
231     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
232         PlayerState_detach(this);
233
234         if (IS_PLAYER(this))
235         {
236                 if(GetResource(this, RES_HEALTH) >= 1)
237                 {
238                         // despawn effect
239                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
240                 }
241
242                 // was a player, recount votes and ready status
243                 if(IS_REAL_CLIENT(this))
244                 {
245                         if (vote_called) { VoteCount(false); }
246                         ReadyCount();
247                 }
248     }
249
250     {
251         entity spot = SelectSpawnPoint(this, true);
252         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
253         this.angles = vec2(spot.angles);
254         this.fixangle = true;
255         // offset it so that the spectator spawns higher off the ground, looks better this way
256         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
257         if (IS_REAL_CLIENT(this))
258         {
259             msg_entity = this;
260             WriteByte(MSG_ONE, SVC_SETVIEW);
261             WriteEntity(MSG_ONE, this);
262         }
263         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
264         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
265         if(!autocvar_g_debug_globalsounds)
266         {
267                 // needed for player sounds
268                 this.model = "";
269                 FixPlayermodel(this);
270         }
271         setmodel(this, MDL_Null);
272         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
273         this.view_ofs = '0 0 0';
274     }
275
276     RemoveGrapplingHooks(this);
277         Portal_ClearAll(this);
278         Unfreeze(this, false);
279         SetSpectatee(this, NULL);
280
281         if (this.alivetime)
282         {
283                 if (!warmup_stage)
284                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
285                 this.alivetime = 0;
286         }
287
288         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
289
290         WaypointSprite_PlayerDead(this);
291
292         if (CS(this).killcount != FRAGS_SPECTATOR)
293         {
294                 if(!game_stopped)
295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
297         }
298
299         accuracy_resend(this);
300
301         CS(this).spectatortime = time;
302         if(this.bot_attack)
303                 IL_REMOVE(g_bot_targets, this);
304         this.bot_attack = false;
305         if(this.monster_attack)
306                 IL_REMOVE(g_monster_targets, this);
307         this.monster_attack = false;
308     STAT(HUD, this) = HUD_NORMAL;
309         TRANSMUTE(Observer, this);
310         this.iscreature = false;
311         this.teleportable = TELEPORT_SIMPLE;
312         if(this.damagedbycontents)
313                 IL_REMOVE(g_damagedbycontents, this);
314         this.damagedbycontents = false;
315         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
316         SetSpectatee_status(this, etof(this));
317         this.takedamage = DAMAGE_NO;
318         this.solid = SOLID_NOT;
319         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
320         this.flags = FL_CLIENT | FL_NOTARGET;
321         this.effects = 0;
322         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
323         this.pauserotarmor_finished = 0;
324         this.pauserothealth_finished = 0;
325         this.pauseregen_finished = 0;
326         this.damageforcescale = 0;
327         this.death_time = 0;
328         this.respawn_flags = 0;
329         this.respawn_time = 0;
330         STAT(RESPAWN_TIME, this) = 0;
331         this.alpha = 0;
332         this.scale = 0;
333         this.fade_time = 0;
334         this.pain_frame = 0;
335         this.pain_finished = 0;
336         this.strength_finished = 0;
337         this.invincible_finished = 0;
338         this.superweapons_finished = 0;
339         //this.dphitcontentsmask = 0;
340         this.dphitcontentsmask = DPCONTENTS_SOLID;
341         if (autocvar_g_playerclip_collisions)
342                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
343         this.pushltime = 0;
344         this.istypefrag = 0;
345         setthink(this, func_null);
346         this.nextthink = 0;
347         this.deadflag = DEAD_NO;
348         this.crouch = false;
349         STAT(REVIVE_PROGRESS, this) = 0;
350         this.revival_time = 0;
351         this.draggable = drag_undraggable;
352
353         this.items = 0;
354         STAT(WEAPONS, this) = '0 0 0';
355         this.drawonlytoclient = this;
356
357         this.viewloc = NULL;
358
359         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
360
361         this.weaponmodel = "";
362         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
363         {
364                 this.weaponentities[slot] = NULL;
365         }
366         this.exteriorweaponentity = NULL;
367         CS(this).killcount = FRAGS_SPECTATOR;
368         this.velocity = '0 0 0';
369         this.avelocity = '0 0 0';
370         this.punchangle = '0 0 0';
371         this.punchvector = '0 0 0';
372         this.oldvelocity = this.velocity;
373         this.fire_endtime = -1;
374         this.event_damage = func_null;
375         this.event_heal = func_null;
376
377         for(int slot = 0; slot < MAX_AXH; ++slot)
378         {
379                 entity axh = this.(AuxiliaryXhair[slot]);
380                 this.(AuxiliaryXhair[slot]) = NULL;
381
382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
383                         delete(axh);
384         }
385
386         if (mutator_returnvalue)
387         {
388                 // mutator prevents resetting teams+score
389         }
390         else
391         {
392                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
393                 this.frags = FRAGS_SPECTATOR;
394         }
395         if (CS(this).just_joined)
396                 CS(this).just_joined = false;
397 }
398
399 int player_getspecies(entity this)
400 {
401         get_model_parameters(this.model, this.skin);
402         int s = get_model_parameters_species;
403         get_model_parameters(string_null, 0);
404         if (s < 0) return SPECIES_HUMAN;
405         return s;
406 }
407
408 .float model_randomizer;
409 void FixPlayermodel(entity player)
410 {
411         string defaultmodel = "";
412         int defaultskin = 0;
413         if(autocvar_sv_defaultcharacter)
414         {
415                 if(teamplay)
416                 {
417                         switch(player.team)
418                         {
419                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
420                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
421                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
422                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
423                         }
424                 }
425
426                 if(defaultmodel == "")
427                 {
428                         defaultmodel = autocvar_sv_defaultplayermodel;
429                         defaultskin = autocvar_sv_defaultplayerskin;
430                 }
431
432                 int n = tokenize_console(defaultmodel);
433                 if(n > 0)
434                 {
435                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
436                         // However, do NOT randomize if the player-selected model is in the list.
437                         for (int i = 0; i < n; ++i)
438                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
439                                         defaultmodel = argv(i);
440                 }
441
442                 int i = strstrofs(defaultmodel, ":", 0);
443                 if(i >= 0)
444                 {
445                         defaultskin = stof(substring(defaultmodel, i+1, -1));
446                         defaultmodel = substring(defaultmodel, 0, i);
447                 }
448         }
449         if(autocvar_sv_defaultcharacterskin && !defaultskin)
450         {
451                 if(teamplay)
452                 {
453                         switch(player.team)
454                         {
455                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
456                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
457                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
458                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
459                         }
460                 }
461
462                 if(!defaultskin)
463                         defaultskin = autocvar_sv_defaultplayerskin;
464         }
465
466         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
467         defaultmodel = M_ARGV(0, string);
468         defaultskin = M_ARGV(1, int);
469
470         bool chmdl = false;
471         int oldskin;
472         if(defaultmodel != "")
473         {
474                 if (defaultmodel != player.model)
475                 {
476                         vector m1 = player.mins;
477                         vector m2 = player.maxs;
478                         setplayermodel (player, defaultmodel);
479                         setsize (player, m1, m2);
480                         chmdl = true;
481                 }
482
483                 oldskin = player.skin;
484                 player.skin = defaultskin;
485         } else {
486                 if (player.playermodel != player.model || player.playermodel == "")
487                 {
488                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
489                         vector m1 = player.mins;
490                         vector m2 = player.maxs;
491                         setplayermodel (player, player.playermodel);
492                         setsize (player, m1, m2);
493                         chmdl = true;
494                 }
495
496                 if(!autocvar_sv_defaultcharacterskin)
497                 {
498                         oldskin = player.skin;
499                         player.skin = stof(player.playerskin);
500                 }
501                 else
502                 {
503                         oldskin = player.skin;
504                         player.skin = defaultskin;
505                 }
506         }
507
508         if(chmdl || oldskin != player.skin) // model or skin has changed
509         {
510                 player.species = player_getspecies(player); // update species
511                 if(!autocvar_g_debug_globalsounds)
512                         UpdatePlayerSounds(player); // update skin sounds
513         }
514
515         if(!teamplay)
516                 if(strlen(autocvar_sv_defaultplayercolors))
517                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
518                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
519 }
520
521 void PutPlayerInServer(entity this)
522 {
523         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
524
525         PlayerState_attach(this);
526         accuracy_resend(this);
527
528         if (this.team < 0)
529                 TeamBalance_JoinBestTeam(this);
530
531         entity spot = SelectSpawnPoint(this, false);
532         if (!spot) {
533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
534                 return; // spawn failed
535         }
536
537         TRANSMUTE(Player, this);
538
539         CS(this).wasplayer = true;
540         this.iscreature = true;
541         this.teleportable = TELEPORT_NORMAL;
542         if(!this.damagedbycontents)
543                 IL_PUSH(g_damagedbycontents, this);
544         this.damagedbycontents = true;
545         set_movetype(this, MOVETYPE_WALK);
546         this.solid = SOLID_SLIDEBOX;
547         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
548         if (autocvar_g_playerclip_collisions)
549                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
550         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
551                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
552         this.frags = FRAGS_PLAYER;
553         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
554         this.flags = FL_CLIENT | FL_PICKUPITEMS;
555         if (autocvar__notarget)
556                 this.flags |= FL_NOTARGET;
557         this.takedamage = DAMAGE_AIM;
558         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
559
560         if (warmup_stage) {
561                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
562                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
563                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
564                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
565                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
566                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
567                 SetResource(this, RES_HEALTH, warmup_start_health);
568                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
569                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
570         } else {
571                 SetResource(this, RES_SHELLS, start_ammo_shells);
572                 SetResource(this, RES_BULLETS, start_ammo_nails);
573                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
574                 SetResource(this, RES_CELLS, start_ammo_cells);
575                 SetResource(this, RES_PLASMA, start_ammo_plasma);
576                 SetResource(this, RES_FUEL, start_ammo_fuel);
577                 SetResource(this, RES_HEALTH, start_health);
578                 SetResource(this, RES_ARMOR, start_armorvalue);
579                 STAT(WEAPONS, this) = start_weapons;
580                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
581                 {
582                         GiveRandomWeapons(this, random_start_weapons_count,
583                                 autocvar_g_random_start_weapons, random_start_ammo);
584                 }
585         }
586         SetSpectatee_status(this, 0);
587
588         PS(this).dual_weapons = '0 0 0';
589
590         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
591
592         this.items = start_items;
593
594         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
595         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
596         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
597         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
598         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
599         if (!sv_ready_restart_after_countdown && time < game_starttime)
600         {
601                 float f = game_starttime - time;
602                 this.spawnshieldtime += f;
603                 this.pauserotarmor_finished += f;
604                 this.pauserothealth_finished += f;
605                 this.pauseregen_finished += f;
606         }
607
608         this.damageforcescale = autocvar_g_player_damageforcescale;
609         this.death_time = 0;
610         this.respawn_flags = 0;
611         this.respawn_time = 0;
612         STAT(RESPAWN_TIME, this) = 0;
613         this.scale = autocvar_sv_player_scale;
614         this.fade_time = 0;
615         this.pain_frame = 0;
616         this.pain_finished = 0;
617         this.pushltime = 0;
618         setthink(this, func_null); // players have no think function
619         this.nextthink = 0;
620         this.dmg_team = 0;
621         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
622
623         this.deadflag = DEAD_NO;
624
625         this.angles = spot.angles;
626         this.angles_z = 0; // never spawn tilted even if the spot says to
627         if (IS_BOT_CLIENT(this))
628         {
629                 this.v_angle = this.angles;
630                 bot_aim_reset(this);
631         }
632         this.fixangle = true; // turn this way immediately
633         this.oldvelocity = this.velocity = '0 0 0';
634         this.avelocity = '0 0 0';
635         this.punchangle = '0 0 0';
636         this.punchvector = '0 0 0';
637
638         this.strength_finished = 0;
639         this.invincible_finished = 0;
640         this.fire_endtime = -1;
641         STAT(REVIVE_PROGRESS, this) = 0;
642         this.revival_time = 0;
643
644         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
645         STAT(BUFFS, this) = 0;
646         STAT(BUFF_TIME, this) = 0;
647
648         this.air_finished = time + 12;
649         this.waterlevel = WATERLEVEL_NONE;
650         this.watertype = CONTENT_EMPTY;
651
652         entity spawnevent = new_pure(spawnevent);
653         spawnevent.owner = this;
654         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
655
656         // Cut off any still running player sounds.
657         stopsound(this, CH_PLAYER_SINGLE);
658
659         this.model = "";
660         FixPlayermodel(this);
661         this.drawonlytoclient = NULL;
662
663         this.viewloc = NULL;
664
665         for(int slot = 0; slot < MAX_AXH; ++slot)
666         {
667                 entity axh = this.(AuxiliaryXhair[slot]);
668                 this.(AuxiliaryXhair[slot]) = NULL;
669
670                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
671                         delete(axh);
672         }
673
674         this.spawnpoint_targ = NULL;
675
676         this.crouch = false;
677         this.view_ofs = STAT(PL_VIEW_OFS, this);
678         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
679         this.spawnorigin = spot.origin;
680         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
681         // don't reset back to last position, even if new position is stuck in solid
682         this.oldorigin = this.origin;
683         if(this.conveyor)
684                 IL_REMOVE(g_conveyed, this);
685         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
686         if(this.swampslug)
687                 delete(this.swampslug);
688         this.in_swamp = false;
689         STAT(HUD, this) = HUD_NORMAL;
690
691         this.event_damage = PlayerDamage;
692         this.event_heal = PlayerHeal;
693
694         this.draggable = func_null;
695
696         if(!this.bot_attack)
697                 IL_PUSH(g_bot_targets, this);
698         this.bot_attack = true;
699         if(!this.monster_attack)
700                 IL_PUSH(g_monster_targets, this);
701         this.monster_attack = true;
702         navigation_dynamicgoal_init(this, false);
703
704         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
705
706         // player was spectator
707         if (CS(this).killcount == FRAGS_SPECTATOR) {
708                 PlayerScore_Clear(this);
709                 CS(this).killcount = 0;
710                 CS(this).startplaytime = time;
711         }
712
713         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
714         {
715                 .entity weaponentity = weaponentities[slot];
716                 entity oldwep = this.(weaponentity);
717                 CL_SpawnWeaponentity(this, weaponentity);
718                 if(oldwep && oldwep.owner == this)
719                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
720         }
721         this.alpha = default_player_alpha;
722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
723         this.exteriorweaponentity.alpha = default_weapon_alpha;
724
725         this.speedrunning = false;
726
727         this.counter_cnt = 0;
728         this.fragsfilter_cnt = 0;
729
730         target_voicescript_clear(this);
731
732         // reset fields the weapons may use
733         FOREACH(Weapons, true, {
734                 it.wr_resetplayer(it, this);
735                         // reload all reloadable weapons
736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
738                         {
739                                 .entity weaponentity = weaponentities[slot];
740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
741                         }
742                 }
743         });
744
745         {
746                 string s = spot.target;
747                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
748                         spot.target = string_null;
749                 SUB_UseTargets(spot, this, NULL);
750                 if(g_assault || g_race)
751                         spot.target = s;
752         }
753
754         Unfreeze(this, false);
755
756         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
757
758         if (autocvar_spawn_debug)
759         {
760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
762         }
763
764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
765         {
766                 .entity weaponentity = weaponentities[slot];
767                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
768                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
769                 else
770                         this.(weaponentity).m_switchweapon = WEP_Null;
771                 this.(weaponentity).m_weapon = WEP_Null;
772                 this.(weaponentity).weaponname = "";
773                 this.(weaponentity).m_switchingweapon = WEP_Null;
774                 this.(weaponentity).cnt = -1;
775         }
776
777         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
778
779         if (CS(this).impulse) ImpulseCommands(this);
780
781         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
782         {
783                 .entity weaponentity = weaponentities[slot];
784                 W_WeaponFrame(this, weaponentity);
785         }
786
787         if (!warmup_stage && !this.alivetime)
788                 this.alivetime = time;
789
790         antilag_clear(this, CS(this));
791 }
792
793 /** Called when a client spawns in the server */
794 void PutClientInServer(entity this)
795 {
796         if (IS_BOT_CLIENT(this)) {
797                 TRANSMUTE(Player, this);
798         } else if (IS_REAL_CLIENT(this)) {
799                 msg_entity = this;
800                 WriteByte(MSG_ONE, SVC_SETVIEW);
801                 WriteEntity(MSG_ONE, this);
802         }
803         if (game_stopped)
804                 TRANSMUTE(Observer, this);
805
806         SetSpectatee(this, NULL);
807
808         // reset player keys
809         if(PS(this))
810                 PS(this).itemkeys = 0;
811
812         MUTATOR_CALLHOOK(PutClientInServer, this);
813
814         if (IS_OBSERVER(this)) {
815                 PutObserverInServer(this);
816         } else if (IS_PLAYER(this)) {
817                 PutPlayerInServer(this);
818         }
819 }
820
821 // TODO do we need all these fields, or should we stop autodetecting runtime
822 // changes and just have a console command to update this?
823 bool ClientInit_SendEntity(entity this, entity to, int sf)
824 {
825         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
826         return = true;
827         msg_entity = to;
828         // MSG_INIT replacement
829         // TODO: make easier to use
830         Registry_send_all();
831         W_PROP_reload(MSG_ONE, to);
832         ClientInit_misc(this);
833         MUTATOR_CALLHOOK(Ent_Init);
834 }
835 void ClientInit_misc(entity this)
836 {
837         int channel = MSG_ONE;
838         WriteHeader(channel, ENT_CLIENT_INIT);
839         WriteByte(channel, g_nexball_meter_period * 32);
840         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
844         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
848
849         if(sv_foginterval && world.fog != "")
850                 WriteString(channel, world.fog);
851         else
852                 WriteString(channel, "");
853         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
854         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
855         WriteByte(channel, serverflags);
856         WriteCoord(channel, autocvar_g_trueaim_minrange);
857 }
858
859 void ClientInit_CheckUpdate(entity this)
860 {
861         this.nextthink = time;
862         if(this.count != autocvar_g_balance_armor_blockpercent)
863         {
864                 this.count = autocvar_g_balance_armor_blockpercent;
865                 this.SendFlags |= 1;
866         }
867         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
868         {
869                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
870                 this.SendFlags |= 1;
871         }
872 }
873
874 void ClientInit_Spawn()
875 {
876         entity e = new_pure(clientinit);
877         setthink(e, ClientInit_CheckUpdate);
878         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
879
880         ClientInit_CheckUpdate(e);
881 }
882
883 /*
884 =============
885 SetNewParms
886 =============
887 */
888 void SetNewParms ()
889 {
890         // initialize parms for a new player
891         parm1 = -(86400 * 366);
892
893         MUTATOR_CALLHOOK(SetNewParms);
894 }
895
896 /*
897 =============
898 SetChangeParms
899 =============
900 */
901 void SetChangeParms (entity this)
902 {
903         // save parms for level change
904         parm1 = CS(this).parm_idlesince - time;
905
906         MUTATOR_CALLHOOK(SetChangeParms);
907 }
908
909 /*
910 =============
911 DecodeLevelParms
912 =============
913 */
914 void DecodeLevelParms(entity this)
915 {
916         // load parms
917         CS(this).parm_idlesince = parm1;
918         if (CS(this).parm_idlesince == -(86400 * 366))
919                 CS(this).parm_idlesince = time;
920
921         // whatever happens, allow 60 seconds of idling directly after connect for map loading
922         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
923
924         MUTATOR_CALLHOOK(DecodeLevelParms);
925 }
926
927 void FixClientCvars(entity e)
928 {
929         // send prediction settings to the client
930         stuffcmd(e, "\nin_bindmap 0 0\n");
931         if(autocvar_g_antilag == 3) // client side hitscan
932                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
933         if(autocvar_sv_gentle)
934                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
935
936         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
937         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
938
939         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
940
941         MUTATOR_CALLHOOK(FixClientCvars, e);
942 }
943
944 bool findinlist_abbrev(string tofind, string list)
945 {
946         if(list == "" || tofind == "")
947                 return false; // empty list or search, just return
948
949         // this function allows abbreviated strings!
950         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
951         {
952                 return true;
953         });
954
955         return false;
956 }
957
958 bool PlayerInIPList(entity p, string iplist)
959 {
960         // some safety checks (never allow local?)
961         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
962                 return false;
963
964         return findinlist_abbrev(p.netaddress, iplist);
965 }
966
967 bool PlayerInIDList(entity p, string idlist)
968 {
969         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
970         if(!p.crypto_idfp)
971                 return false;
972
973         return findinlist_abbrev(p.crypto_idfp, idlist);
974 }
975
976 bool PlayerInList(entity player, string list)
977 {
978         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
979 }
980
981 #ifdef DP_EXT_PRECONNECT
982 /*
983 =============
984 ClientPreConnect
985
986 Called once (not at each match start) when a client begins a connection to the server
987 =============
988 */
989 void ClientPreConnect(entity this)
990 {
991         if(autocvar_sv_eventlog)
992         {
993                 GameLogEcho(sprintf(":connect:%d:%d:%s",
994                         this.playerid,
995                         etof(this),
996                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
997                 ));
998         }
999 }
1000 #endif
1001
1002 string GetClientVersionMessage(entity this)
1003 {
1004         if (CS(this).version_mismatch) {
1005                 if(CS(this).version < autocvar_gameversion) {
1006                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1007                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1008                 } else {
1009                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1010                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1011                 }
1012         } else {
1013                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1014         }
1015 }
1016
1017 string getwelcomemessage(entity this)
1018 {
1019         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1020         string modifications = M_ARGV(0, string);
1021
1022         if(g_weaponarena)
1023         {
1024                 if(g_weaponarena_random)
1025                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1026                 else
1027                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1028         }
1029         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1030                 modifications = strcat(modifications, ", No start weapons");
1031         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1032                 modifications = strcat(modifications, ", Low gravity");
1033         if(g_weapon_stay && !g_cts)
1034                 modifications = strcat(modifications, ", Weapons stay");
1035         if(g_jetpack)
1036                 modifications = strcat(modifications, ", Jet pack");
1037         if(autocvar_g_powerups == 0)
1038                 modifications = strcat(modifications, ", No powerups");
1039         if(autocvar_g_powerups > 0)
1040                 modifications = strcat(modifications, ", Powerups");
1041         modifications = substring(modifications, 2, strlen(modifications) - 2);
1042
1043         string versionmessage = GetClientVersionMessage(this);
1044         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1045
1046         if(modifications != "")
1047                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1048
1049         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1050         {
1051                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1052                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1053         }
1054
1055         if (cache_mutatormsg != "") {
1056                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1057         }
1058
1059         string mutator_msg = "";
1060         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1061         mutator_msg = M_ARGV(0, string);
1062
1063         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1064
1065         string motd = autocvar_sv_motd;
1066         if (motd != "") {
1067                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1068         }
1069         return s;
1070 }
1071
1072 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1073
1074 /**
1075 =============
1076 ClientConnect
1077
1078 Called when a client connects to the server
1079 =============
1080 */
1081 void ClientConnect(entity this)
1082 {
1083         if (Ban_MaybeEnforceBanOnce(this)) return;
1084         assert(!IS_CLIENT(this), return);
1085         this.flags |= FL_CLIENT;
1086         assert(player_count >= 0, player_count = 0);
1087
1088 #ifdef WATERMARK
1089         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1090 #endif
1091         TRANSMUTE(Client, this);
1092         CS(this).version_nagtime = time + 10 + random() * 10;
1093
1094         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1095
1096         bot_clientconnect(this);
1097
1098         Player_DetermineForcedTeam(this);
1099
1100         TRANSMUTE(Observer, this);
1101
1102         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1103
1104         // always track bots, don't ask for cl_allow_uidtracking
1105         if (IS_BOT_CLIENT(this))
1106                 PlayerStats_GameReport_AddPlayer(this);
1107         else
1108                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1109
1110         if (autocvar_sv_eventlog)
1111                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1112
1113         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1114
1115         stuffcmd(this, clientstuff, "\n");
1116         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1117
1118         FixClientCvars(this);
1119
1120         // get version info from player
1121         stuffcmd(this, "cmd clientversion $gameversion\n");
1122
1123         // notify about available teams
1124         if (teamplay)
1125         {
1126                 entity balance = TeamBalance_CheckAllowedTeams(this);
1127                 int t = TeamBalance_GetAllowedTeams(balance);
1128                 TeamBalance_Destroy(balance);
1129                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1130         }
1131         else
1132         {
1133                 stuffcmd(this, "set _teams_available 0\n");
1134         }
1135
1136         bot_relinkplayerlist();
1137
1138         CS(this).spectatortime = time;
1139         if (blockSpectators)
1140         {
1141                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1142         }
1143
1144         CS(this).jointime = time;
1145
1146         if (IS_REAL_CLIENT(this))
1147         {
1148                 if (g_weaponarena_weapons == WEPSET(TUBA))
1149                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1150         }
1151
1152         if (!sv_foginterval && world.fog != "")
1153                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1154
1155         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1156                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1157                         send_CSQC_teamnagger();
1158
1159         CSQCMODEL_AUTOINIT(this);
1160
1161         CS(this).model_randomizer = random();
1162
1163         if (IS_REAL_CLIENT(this))
1164                 sv_notice_join(this);
1165
1166         this.move_qcphysics = autocvar_sv_qcphysics;
1167
1168         // update physics stats (players can spawn before physics runs)
1169         Physics_UpdateStats(this);
1170
1171         IL_EACH(g_initforplayer, it.init_for_player, {
1172                 it.init_for_player(it, this);
1173         });
1174
1175         Handicap_Initialize(this);
1176
1177         MUTATOR_CALLHOOK(ClientConnect, this);
1178
1179         if (IS_REAL_CLIENT(this))
1180         {
1181                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1182                 {
1183                         CS(this).motd_actived_time = -1;
1184                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1185                 }
1186         }
1187 }
1188 /*
1189 =============
1190 ClientDisconnect
1191
1192 Called when a client disconnects from the server
1193 =============
1194 */
1195 .entity chatbubbleentity;
1196 void ClientDisconnect(entity this)
1197 {
1198         assert(IS_CLIENT(this), return);
1199
1200         PlayerStats_GameReport_FinalizePlayer(this);
1201         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1202         if (CS(this).active_minigame) part_minigame(this);
1203         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1204
1205         if (autocvar_sv_eventlog)
1206                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1207
1208         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1209
1210         if(IS_SPEC(this))
1211                 SetSpectatee(this, NULL);
1212
1213     MUTATOR_CALLHOOK(ClientDisconnect, this);
1214
1215         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1216         strfree(CS(this).weaponorder_byimpulse);
1217         ClientState_detach(this);
1218
1219         Portal_ClearAll(this);
1220
1221         Unfreeze(this, false);
1222
1223         RemoveGrapplingHooks(this);
1224
1225         // Here, everything has been done that requires this player to be a client.
1226
1227         this.flags &= ~FL_CLIENT;
1228
1229         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1230         if (this.killindicator) delete(this.killindicator);
1231
1232         WaypointSprite_PlayerGone(this);
1233
1234         bot_relinkplayerlist();
1235
1236         strfree(this.clientstatus);
1237         if (this.personal) delete(this.personal);
1238
1239         this.playerid = 0;
1240         ReadyCount();
1241         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1242
1243         ONREMOVE(this);
1244 }
1245
1246 void ChatBubbleThink(entity this)
1247 {
1248         this.nextthink = time;
1249         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1250         {
1251                 if(this.owner) // but why can that ever be NULL?
1252                         this.owner.chatbubbleentity = NULL;
1253                 delete(this);
1254                 return;
1255         }
1256
1257         this.mdl = "";
1258
1259         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1260         {
1261                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1262                         this.mdl = "models/sprites/minigame_busy.iqm";
1263                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1264                         this.mdl = "models/misc/chatbubble.spr";
1265         }
1266
1267         if ( this.model != this.mdl )
1268                 _setmodel(this, this.mdl);
1269
1270 }
1271
1272 void UpdateChatBubble(entity this)
1273 {
1274         if (this.alpha < 0)
1275                 return;
1276         // spawn a chatbubble entity if needed
1277         if (!this.chatbubbleentity)
1278         {
1279                 this.chatbubbleentity = new(chatbubbleentity);
1280                 this.chatbubbleentity.owner = this;
1281                 this.chatbubbleentity.exteriormodeltoclient = this;
1282                 setthink(this.chatbubbleentity, ChatBubbleThink);
1283                 this.chatbubbleentity.nextthink = time;
1284                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1285                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1286                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1287                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1288                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1289                 //this.chatbubbleentity.model = "";
1290                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1291         }
1292 }
1293
1294
1295 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1296 // added to the model skins
1297 /*void UpdateColorModHack()
1298 {
1299         float c;
1300         c = this.clientcolors & 15;
1301         // LordHavoc: only bothering to support white, green, red, yellow, blue
1302              if (!teamplay) this.colormod = '0 0 0';
1303         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1304         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1305         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1306         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1307         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1308         else this.colormod = '1 1 1';
1309 }*/
1310
1311 void respawn(entity this)
1312 {
1313         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1314         {
1315                 this.solid = SOLID_NOT;
1316                 this.takedamage = DAMAGE_NO;
1317                 set_movetype(this, MOVETYPE_FLY);
1318                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1319                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1320                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1321                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1322                 if(autocvar_g_respawn_ghosts_maxtime)
1323                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1324         }
1325
1326         CopyBody(this, 1);
1327
1328         this.effects |= EF_NODRAW; // prevent another CopyBody
1329         PutClientInServer(this);
1330 }
1331
1332 ERASEABLE
1333 void PrintToChat(entity client, string text)
1334 {
1335         text = strcat("\{1}^7", text, "\n");
1336         sprint(client, text);
1337 }
1338
1339 ERASEABLE
1340 void DebugPrintToChat(entity client, string text)
1341 {
1342         if (autocvar_developer)
1343         {
1344                 PrintToChat(client, text);
1345         }
1346 }
1347
1348 ERASEABLE
1349 void PrintToChatAll(string text)
1350 {
1351         text = strcat("\{1}^7", text, "\n");
1352         bprint(text);
1353 }
1354
1355 ERASEABLE
1356 void DebugPrintToChatAll(string text)
1357 {
1358         if (autocvar_developer)
1359         {
1360                 PrintToChatAll(text);
1361         }
1362 }
1363
1364 ERASEABLE
1365 void PrintToChatTeam(int team_num, string text)
1366 {
1367         text = strcat("\{1}^7", text, "\n");
1368         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1369         {
1370                 if (it.team == team_num)
1371                 {
1372                         sprint(it, text);
1373                 }
1374         });
1375 }
1376
1377 ERASEABLE
1378 void DebugPrintToChatTeam(int team_num, string text)
1379 {
1380         if (autocvar_developer)
1381         {
1382                 PrintToChatTeam(team_num, text);
1383         }
1384 }
1385
1386 void play_countdown(entity this, float finished, Sound samp)
1387 {
1388         TC(Sound, samp);
1389         if(IS_REAL_CLIENT(this))
1390                 if(floor(finished - time - frametime) != floor(finished - time))
1391                         if(finished - time < 6)
1392                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1393 }
1394
1395 void player_powerups(entity this)
1396 {
1397         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1398         int items_prev = this.items;
1399
1400         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1401                 this.modelflags |= MF_ROCKET;
1402         else
1403                 this.modelflags &= ~MF_ROCKET;
1404
1405         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1406
1407         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1408                 return;
1409
1410         Fire_ApplyDamage(this);
1411         Fire_ApplyEffect(this);
1412
1413         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1414         {
1415                 if (this.items & ITEM_Strength.m_itemid)
1416                 {
1417                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1418                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1419                         if (time > this.strength_finished)
1420                         {
1421                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1422                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1424                         }
1425                 }
1426                 else
1427                 {
1428                         if (time < this.strength_finished)
1429                         {
1430                                 this.items = this.items | ITEM_Strength.m_itemid;
1431                                 if(!g_cts)
1432                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1433                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1434                         }
1435                 }
1436                 if (this.items & ITEM_Shield.m_itemid)
1437                 {
1438                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1439                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > this.invincible_finished)
1441                         {
1442                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1443                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1444                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < this.invincible_finished)
1450                         {
1451                                 this.items = this.items | ITEM_Shield.m_itemid;
1452                                 if(!g_cts)
1453                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1455                         }
1456                 }
1457                 if (this.items & IT_SUPERWEAPON)
1458                 {
1459                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1460                         {
1461                                 this.superweapons_finished = 0;
1462                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1463                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1465                         }
1466                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1467                         {
1468                                 // don't let them run out
1469                         }
1470                         else
1471                         {
1472                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1473                                 if (time > this.superweapons_finished)
1474                                 {
1475                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1477                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1478                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1479                                 }
1480                         }
1481                 }
1482                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1483                 {
1484                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1485                         {
1486                                 this.items = this.items | IT_SUPERWEAPON;
1487                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1488                                 {
1489                                         if(!g_cts)
1490                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                                 }
1493                         }
1494                         else
1495                         {
1496                                 this.superweapons_finished = 0;
1497                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1498                         }
1499                 }
1500                 else
1501                 {
1502                         this.superweapons_finished = 0;
1503                 }
1504         }
1505
1506         if(autocvar_g_nodepthtestplayers)
1507                 this.effects = this.effects | EF_NODEPTHTEST;
1508
1509         if(autocvar_g_fullbrightplayers)
1510                 this.effects = this.effects | EF_FULLBRIGHT;
1511
1512         if (time >= game_starttime)
1513         if (time < this.spawnshieldtime)
1514                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1515
1516         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1517 }
1518
1519 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1520 {
1521         if(current > stable)
1522                 return current;
1523         else if(current > stable - 0.25) // when close enough, "snap"
1524                 return stable;
1525         else
1526                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1527 }
1528
1529 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1530 {
1531         if(current < stable)
1532                 return current;
1533         else if(current < stable + 0.25) // when close enough, "snap"
1534                 return stable;
1535         else
1536                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1537 }
1538
1539 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1540 {
1541         if(current > rotstable)
1542         {
1543                 if(rotframetime > 0)
1544                 {
1545                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1546                         current = max(rotstable, current - rotlinear * rotframetime);
1547                 }
1548         }
1549         else if(current < regenstable)
1550         {
1551                 if(regenframetime > 0)
1552                 {
1553                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1554                         current = min(regenstable, current + regenlinear * regenframetime);
1555                 }
1556         }
1557
1558         if(current > limit)
1559                 current = limit;
1560
1561         return current;
1562 }
1563
1564 void player_regen(entity this)
1565 {
1566         float max_mod, regen_mod, rot_mod, limit_mod;
1567         max_mod = regen_mod = rot_mod = limit_mod = 1;
1568
1569         float regen_health = autocvar_g_balance_health_regen;
1570         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1571         float regen_health_rot = autocvar_g_balance_health_rot;
1572         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1573         float regen_health_stable = autocvar_g_balance_health_regenstable;
1574         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1575         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1576                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1577         max_mod = M_ARGV(1, float);
1578         regen_mod = M_ARGV(2, float);
1579         rot_mod = M_ARGV(3, float);
1580         limit_mod = M_ARGV(4, float);
1581         regen_health = M_ARGV(5, float);
1582         regen_health_linear = M_ARGV(6, float);
1583         regen_health_rot = M_ARGV(7, float);
1584         regen_health_rotlinear = M_ARGV(8, float);
1585         regen_health_stable = M_ARGV(9, float);
1586         regen_health_rotstable = M_ARGV(10, float);
1587
1588         if(!mutator_returnvalue)
1589         if(!STAT(FROZEN, this))
1590         {
1591                 float mina, maxa, limith, limita;
1592                 maxa = autocvar_g_balance_armor_rotstable;
1593                 mina = autocvar_g_balance_armor_regenstable;
1594                 limith = GetResourceLimit(this, RES_HEALTH);
1595                 limita = GetResourceLimit(this, RES_ARMOR);
1596
1597                 regen_health_rotstable = regen_health_rotstable * max_mod;
1598                 regen_health_stable = regen_health_stable * max_mod;
1599                 limith = limith * limit_mod;
1600                 limita = limita * limit_mod;
1601
1602                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 
1603                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1604                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1605                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1606                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1607                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1608         }
1609
1610         // if player rotted to death...  die!
1611         // check this outside above checks, as player may still be able to rot to death
1612         if(GetResource(this, RES_HEALTH) < 1)
1613         {
1614                 if(this.vehicle)
1615                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1616                 if(this.event_damage)
1617                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1618         }
1619
1620         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1621         {
1622                 float minf, maxf, limitf;
1623
1624                 maxf = autocvar_g_balance_fuel_rotstable;
1625                 minf = autocvar_g_balance_fuel_regenstable;
1626                 limitf = GetResourceLimit(this, RES_FUEL);
1627
1628                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, 
1629                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1630                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1631         }
1632 }
1633
1634 bool zoomstate_set;
1635 void SetZoomState(entity this, float newzoom)
1636 {
1637         if(newzoom != CS(this).zoomstate)
1638         {
1639                 CS(this).zoomstate = newzoom;
1640                 ClientData_Touch(this);
1641         }
1642         zoomstate_set = true;
1643 }
1644
1645 void GetPressedKeys(entity this)
1646 {
1647         MUTATOR_CALLHOOK(GetPressedKeys, this);
1648         int keys = STAT(PRESSED_KEYS, this);
1649         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1650         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1651         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1652         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1653
1654         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1655         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1656         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1657         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1658         CS(this).pressedkeys = keys; // store for other users
1659
1660         STAT(PRESSED_KEYS, this) = keys;
1661 }
1662
1663 /*
1664 ======================
1665 spectate mode routines
1666 ======================
1667 */
1668
1669 void SpectateCopy(entity this, entity spectatee)
1670 {
1671         TC(Client, this); TC(Client, spectatee);
1672
1673         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1674         PS(this) = PS(spectatee);
1675         this.armortype = spectatee.armortype;
1676         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1677         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1678         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1679         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1680         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1681         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1682         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1683         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1684         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1685         CS(this).impulse = 0;
1686         this.items = spectatee.items;
1687         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1688         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1689         this.strength_finished = spectatee.strength_finished;
1690         this.invincible_finished = spectatee.invincible_finished;
1691         this.superweapons_finished = spectatee.superweapons_finished;
1692         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1693         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1694         this.punchangle = spectatee.punchangle;
1695         this.view_ofs = spectatee.view_ofs;
1696         this.velocity = spectatee.velocity;
1697         this.dmg_take = spectatee.dmg_take;
1698         this.dmg_save = spectatee.dmg_save;
1699         this.dmg_inflictor = spectatee.dmg_inflictor;
1700         this.v_angle = spectatee.v_angle;
1701         this.angles = spectatee.v_angle;
1702         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1703         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1704         this.viewloc = spectatee.viewloc;
1705         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1706                 this.fixangle = true;
1707         setorigin(this, spectatee.origin);
1708         setsize(this, spectatee.mins, spectatee.maxs);
1709         SetZoomState(this, CS(spectatee).zoomstate);
1710
1711     anticheat_spectatecopy(this, spectatee);
1712         STAT(HUD, this) = STAT(HUD, spectatee);
1713         if(spectatee.vehicle)
1714     {
1715         this.angles = spectatee.v_angle;
1716
1717         //this.fixangle = false;
1718         //this.velocity = spectatee.vehicle.velocity;
1719         this.vehicle_health = spectatee.vehicle_health;
1720         this.vehicle_shield = spectatee.vehicle_shield;
1721         this.vehicle_energy = spectatee.vehicle_energy;
1722         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1723         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1724         this.vehicle_reload1 = spectatee.vehicle_reload1;
1725         this.vehicle_reload2 = spectatee.vehicle_reload2;
1726
1727         //msg_entity = this;
1728
1729        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1730             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1731            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1732            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1733
1734         //WriteByte (MSG_ONE, SVC_SETVIEW);
1735         //    WriteEntity(MSG_ONE, this);
1736         //makevectors(spectatee.v_angle);
1737         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1738     }
1739 }
1740
1741 bool SpectateUpdate(entity this)
1742 {
1743         if(!this.enemy)
1744                 return false;
1745
1746         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1747         {
1748                 SetSpectatee(this, NULL);
1749                 return false;
1750         }
1751
1752         SpectateCopy(this, this.enemy);
1753
1754         return true;
1755 }
1756
1757 bool SpectateSet(entity this)
1758 {
1759         if(!IS_PLAYER(this.enemy))
1760                 return false;
1761
1762         ClientData_Touch(this.enemy);
1763
1764         msg_entity = this;
1765         WriteByte(MSG_ONE, SVC_SETVIEW);
1766         WriteEntity(MSG_ONE, this.enemy);
1767         set_movetype(this, MOVETYPE_NONE);
1768         accuracy_resend(this);
1769
1770         if(!SpectateUpdate(this))
1771                 PutObserverInServer(this);
1772
1773         return true;
1774 }
1775
1776 void SetSpectatee_status(entity this, int spectatee_num)
1777 {
1778         int oldspectatee_status = CS(this).spectatee_status;
1779         CS(this).spectatee_status = spectatee_num;
1780
1781         if (CS(this).spectatee_status != oldspectatee_status)
1782         {
1783                 ClientData_Touch(this);
1784                 if (g_race || g_cts) race_InitSpectator();
1785         }
1786 }
1787
1788 void SetSpectatee(entity this, entity spectatee)
1789 {
1790         if(IS_BOT_CLIENT(this))
1791                 return; // bots abuse .enemy, this code is useless to them
1792
1793         entity old_spectatee = this.enemy;
1794
1795         this.enemy = spectatee;
1796
1797         // WEAPONTODO
1798         // these are required to fix the spectator bug with arc
1799         if(old_spectatee)
1800         {
1801                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1802                 {
1803                         .entity weaponentity = weaponentities[slot];
1804                         if(old_spectatee.(weaponentity).arc_beam)
1805                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1806                 }
1807         }
1808         if(this.enemy)
1809         {
1810                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1811                 {
1812                         .entity weaponentity = weaponentities[slot];
1813                         if(this.enemy.(weaponentity).arc_beam)
1814                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1815                 }
1816         }
1817
1818         if (this.enemy)
1819                 SetSpectatee_status(this, etof(this.enemy));
1820
1821         // needed to update spectator list
1822         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1823 }
1824
1825 bool Spectate(entity this, entity pl)
1826 {
1827         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1828                 return false;
1829         pl = M_ARGV(1, entity);
1830
1831         SetSpectatee(this, pl);
1832         return SpectateSet(this);
1833 }
1834
1835 bool SpectateNext(entity this)
1836 {
1837         entity ent = find(this.enemy, classname, STR_PLAYER);
1838
1839         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1840                 ent = M_ARGV(1, entity);
1841         else if (!ent)
1842                 ent = find(ent, classname, STR_PLAYER);
1843
1844         if(ent) { SetSpectatee(this, ent); }
1845
1846         return SpectateSet(this);
1847 }
1848
1849 bool SpectatePrev(entity this)
1850 {
1851         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1852         entity ent = findchain(classname, STR_PLAYER);
1853         if (!ent) // no player
1854                 return false;
1855
1856         entity first = ent;
1857         // skip players until current spectated player
1858         if(this.enemy)
1859         while(ent && ent != this.enemy)
1860                 ent = ent.chain;
1861
1862         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1863         {
1864                 case MUT_SPECPREV_FOUND:
1865                     ent = M_ARGV(1, entity);
1866                     break;
1867                 case MUT_SPECPREV_RETURN:
1868                     return true;
1869                 case MUT_SPECPREV_CONTINUE:
1870                 default:
1871                 {
1872                         if(ent.chain)
1873                                 ent = ent.chain;
1874                         else
1875                                 ent = first;
1876                         break;
1877                 }
1878         }
1879
1880         SetSpectatee(this, ent);
1881         return SpectateSet(this);
1882 }
1883
1884 /*
1885 =============
1886 ShowRespawnCountdown()
1887
1888 Update a respawn countdown display.
1889 =============
1890 */
1891 void ShowRespawnCountdown(entity this)
1892 {
1893         float number;
1894         if(!IS_DEAD(this)) // just respawned?
1895                 return;
1896         else
1897         {
1898                 number = ceil(this.respawn_time - time);
1899                 if(number <= 0)
1900                         return;
1901                 if(number <= this.respawn_countdown)
1902                 {
1903                         this.respawn_countdown = number - 1;
1904                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1905                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1906                 }
1907         }
1908 }
1909
1910 .bool team_selected;
1911 bool ShowTeamSelection(entity this)
1912 {
1913         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1914                 return false;
1915         stuffcmd(this, "menu_showteamselect\n");
1916         return true;
1917 }
1918 void Join(entity this)
1919 {
1920         TRANSMUTE(Player, this);
1921
1922         if(!this.team_selected)
1923         if(autocvar_g_campaign || autocvar_g_balance_teams)
1924                 TeamBalance_JoinBestTeam(this);
1925
1926         if(autocvar_g_campaign)
1927                 campaign_bots_may_start = true;
1928
1929         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1930
1931         PutClientInServer(this);
1932
1933         if(IS_PLAYER(this))
1934         if(teamplay && this.team != -1)
1935         {
1936         }
1937         else
1938                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1939         this.team_selected = false;
1940 }
1941
1942 int GetPlayerLimit()
1943 {
1944         int player_limit = autocvar_g_maxplayers;
1945         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1946         player_limit = M_ARGV(0, int);
1947         return player_limit;
1948 }
1949
1950 /**
1951  * Determines whether the player is allowed to join. This depends on cvar
1952  * g_maxplayers, if it isn't used this function always return true, otherwise
1953  * it checks whether the number of currently playing players exceeds g_maxplayers.
1954  * @return int number of free slots for players, 0 if none
1955  */
1956 int nJoinAllowed(entity this, entity ignore)
1957 {
1958         if(!ignore)
1959         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1960         // so report 0 free slots if restricted
1961         {
1962                 if(autocvar_g_forced_team_otherwise == "spectate")
1963                         return 0;
1964                 if(autocvar_g_forced_team_otherwise == "spectator")
1965                         return 0;
1966         }
1967
1968         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1969                 return 0; // forced spectators can never join
1970
1971         // TODO simplify this
1972         int totalClients = 0;
1973         int currentlyPlaying = 0;
1974         FOREACH_CLIENT(true, {
1975                 if(it != ignore)
1976                         ++totalClients;
1977                 if(IS_REAL_CLIENT(it))
1978                 if(IS_PLAYER(it) || it.caplayer)
1979                         ++currentlyPlaying;
1980         });
1981
1982         int player_limit = GetPlayerLimit();
1983
1984         float free_slots = 0;
1985         if (!player_limit)
1986                 free_slots = maxclients - totalClients;
1987         else if(currentlyPlaying < player_limit)
1988                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1989
1990         static float join_prevent_msg_time = 0;
1991         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1992         {
1993                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1994                 join_prevent_msg_time = time + 3;
1995         }
1996
1997         return free_slots;
1998 }
1999
2000 /**
2001  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2002  * g_maxplayers_spectator_blocktime seconds
2003  */
2004 void checkSpectatorBlock(entity this)
2005 {
2006         if(IS_SPEC(this) || IS_OBSERVER(this))
2007         if(!this.caplayer)
2008         if(IS_REAL_CLIENT(this))
2009         {
2010                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2011                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2012                         dropclient(this);
2013                 }
2014         }
2015 }
2016
2017 void PrintWelcomeMessage(entity this)
2018 {
2019         if(CS(this).motd_actived_time == 0)
2020         {
2021                 if (autocvar_g_campaign) {
2022                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2023                                 CS(this).motd_actived_time = time;
2024                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2025                         }
2026                 } else {
2027                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2028                                 CS(this).motd_actived_time = time;
2029                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2030                         }
2031                 }
2032         }
2033         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2034         {
2035                 if (autocvar_g_campaign) {
2036                         if (PHYS_INPUT_BUTTON_INFO(this))
2037                                 CS(this).motd_actived_time = time;
2038                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2039                                 CS(this).motd_actived_time = 0;
2040                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2041                         }
2042                 } else {
2043                         if (PHYS_INPUT_BUTTON_INFO(this))
2044                                 CS(this).motd_actived_time = time;
2045                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2046                                 CS(this).motd_actived_time = 0;
2047                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2048                         }
2049                 }
2050         }
2051         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2052         {
2053                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2054                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2055                 else if (CS(this).motd_actived_time == -2)
2056                 {
2057                         // instantly hide MOTD
2058                         CS(this).motd_actived_time = 0;
2059                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2060                 }
2061                 else if (IS_PLAYER(this) || IS_SPEC(this))
2062                 {
2063                         // FIXME occasionally for some reason MOTD never goes away
2064                         // delay MOTD removal a little bit in the hope it fixes this bug
2065                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2066                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2067                         else //if (CS(this).motd_actived_time < -2)
2068                                 CS(this).motd_actived_time++;
2069                 }
2070         }
2071 }
2072
2073 const int MIN_SPEC_TIME = 1;
2074 bool joinAllowed(entity this)
2075 {
2076         if (CS(this).version_mismatch) return false;
2077         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2078         if (!nJoinAllowed(this, this)) return false;
2079         if (teamplay && lockteams) return false;
2080         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2081         if (ShowTeamSelection(this)) return false;
2082         return true;
2083 }
2084
2085 .int items_added;
2086 .string shootfromfixedorigin;
2087 bool PlayerThink(entity this)
2088 {
2089         if (game_stopped || intermission_running) {
2090                 this.modelflags &= ~MF_ROCKET;
2091                 if(intermission_running)
2092                         IntermissionThink(this);
2093                 return false;
2094         }
2095
2096         if (timeout_status == TIMEOUT_ACTIVE) {
2097         // don't allow the player to turn around while game is paused
2098                 // FIXME turn this into CSQC stuff
2099                 this.v_angle = this.lastV_angle;
2100                 this.angles = this.lastV_angle;
2101                 this.fixangle = true;
2102         }
2103
2104         if (frametime) player_powerups(this);
2105
2106         if (IS_DEAD(this)) {
2107                 if (this.personal && g_race_qualifying) {
2108                         if (time > this.respawn_time) {
2109                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2110                                 respawn(this);
2111                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2112                         }
2113                 } else {
2114                         if (frametime) player_anim(this);
2115
2116                         if (this.respawn_flags & RESPAWN_DENY)
2117                         {
2118                                 STAT(RESPAWN_TIME, this) = 0;
2119                                 return false;
2120                         }
2121
2122                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2123
2124                         switch(this.deadflag)
2125                         {
2126                                 case DEAD_DYING:
2127                                 {
2128                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2129                                                 this.deadflag = DEAD_RESPAWNING;
2130                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2131                                                 this.deadflag = DEAD_DEAD;
2132                                         break;
2133                                 }
2134                                 case DEAD_DEAD:
2135                                 {
2136                                         if (button_pressed)
2137                                                 this.deadflag = DEAD_RESPAWNABLE;
2138                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2139                                                 this.deadflag = DEAD_RESPAWNING;
2140                                         break;
2141                                 }
2142                                 case DEAD_RESPAWNABLE:
2143                                 {
2144                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2145                                                 this.deadflag = DEAD_RESPAWNING;
2146                                         break;
2147                                 }
2148                                 case DEAD_RESPAWNING:
2149                                 {
2150                                         if (time > this.respawn_time)
2151                                         {
2152                                                 this.respawn_time = time + 1; // only retry once a second
2153                                                 this.respawn_time_max = this.respawn_time;
2154                                                 respawn(this);
2155                                         }
2156                                         break;
2157                                 }
2158                         }
2159
2160                         ShowRespawnCountdown(this);
2161
2162                         if (this.respawn_flags & RESPAWN_SILENT)
2163                                 STAT(RESPAWN_TIME, this) = 0;
2164                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2165                         {
2166                                 if (time < this.respawn_time)
2167                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2168                                 else if (this.deadflag != DEAD_RESPAWNING)
2169                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2170                         }
2171                         else
2172                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2173                 }
2174
2175                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2176                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2177                         STAT(RESPAWN_TIME, this) *= -1;
2178
2179                 return false;
2180         }
2181
2182         FixPlayermodel(this);
2183
2184         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2185                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2186                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2187         }
2188
2189         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2190         //if(frametime)
2191         {
2192                 this.items &= ~this.items_added;
2193
2194                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2195                 {
2196                         .entity weaponentity = weaponentities[slot];
2197                         W_WeaponFrame(this, weaponentity);
2198                 }
2199
2200                 this.items_added = 0;
2201                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2202             this.items_added |= IT_FUEL;
2203
2204                 this.items |= this.items_added;
2205         }
2206
2207         player_regen(this);
2208
2209         // WEAPONTODO: Add a weapon request for this
2210         // rot vortex charge to the charge limit
2211         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2212         {
2213                 .entity weaponentity = weaponentities[slot];
2214                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2215                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2216         }
2217
2218         if (frametime) player_anim(this);
2219
2220         // secret status
2221         secrets_setstatus(this);
2222
2223         // monsters status
2224         monsters_setstatus(this);
2225
2226         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2227
2228         return true;
2229 }
2230
2231 .bool would_spectate;
2232 void ObserverThink(entity this)
2233 {
2234         if ( CS(this).impulse )
2235         {
2236                 MinigameImpulse(this, CS(this).impulse);
2237                 CS(this).impulse = 0;
2238         }
2239
2240         if (this.flags & FL_JUMPRELEASED) {
2241                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2242                         this.flags &= ~FL_JUMPRELEASED;
2243                         this.flags |= FL_SPAWNING;
2244                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2245                         this.flags &= ~FL_JUMPRELEASED;
2246                         if(SpectateNext(this)) {
2247                                 TRANSMUTE(Spectator, this);
2248                         }
2249                 } else {
2250                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2251                         set_movetype(this, preferred_movetype);
2252                 }
2253         } else {
2254                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2255                         this.flags |= FL_JUMPRELEASED;
2256                         if(this.flags & FL_SPAWNING)
2257                         {
2258                                 this.flags &= ~FL_SPAWNING;
2259                                 Join(this);
2260                                 return;
2261                         }
2262                 }
2263         }
2264 }
2265
2266 void SpectatorThink(entity this)
2267 {
2268         if ( CS(this).impulse )
2269         {
2270                 if(MinigameImpulse(this, CS(this).impulse))
2271                         CS(this).impulse = 0;
2272
2273                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2274                 {
2275                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2276                         CS(this).impulse = 0;
2277                         return;
2278                 }
2279         }
2280
2281         if (this.flags & FL_JUMPRELEASED) {
2282                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2283                         this.flags &= ~FL_JUMPRELEASED;
2284                         this.flags |= FL_SPAWNING;
2285                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2286                         this.flags &= ~FL_JUMPRELEASED;
2287                         if(SpectateNext(this)) {
2288                                 TRANSMUTE(Spectator, this);
2289                         } else {
2290                                 TRANSMUTE(Observer, this);
2291                                 PutClientInServer(this);
2292                         }
2293                         CS(this).impulse = 0;
2294                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2295                         this.flags &= ~FL_JUMPRELEASED;
2296                         if(SpectatePrev(this)) {
2297                                 TRANSMUTE(Spectator, this);
2298                         } else {
2299                                 TRANSMUTE(Observer, this);
2300                                 PutClientInServer(this);
2301                         }
2302                         CS(this).impulse = 0;
2303                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2304                         this.would_spectate = false;
2305                         this.flags &= ~FL_JUMPRELEASED;
2306                         TRANSMUTE(Observer, this);
2307                         PutClientInServer(this);
2308                 } else {
2309                         if(!SpectateUpdate(this))
2310                         {
2311                                 if(!SpectateNext(this))
2312                                 {
2313                                         PutObserverInServer(this);
2314                                         this.would_spectate = true;
2315                                 }
2316                         }
2317                 }
2318         } else {
2319                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2320                         this.flags |= FL_JUMPRELEASED;
2321                         if(this.flags & FL_SPAWNING)
2322                         {
2323                                 this.flags &= ~FL_SPAWNING;
2324                                 Join(this);
2325                                 return;
2326                         }
2327                 }
2328                 if(!SpectateUpdate(this))
2329                         PutObserverInServer(this);
2330         }
2331
2332         this.flags |= FL_CLIENT | FL_NOTARGET;
2333 }
2334
2335 void PlayerUseKey(entity this)
2336 {
2337         if (!IS_PLAYER(this))
2338                 return;
2339
2340         if(this.vehicle)
2341         {
2342                 if(!game_stopped)
2343                 {
2344                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2345                         return;
2346                 }
2347         }
2348         else if(autocvar_g_vehicles_enter)
2349         {
2350                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2351                 {
2352                         entity head, closest_target = NULL;
2353                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2354
2355                         while(head) // find the closest acceptable target to enter
2356                         {
2357                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2358                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2359                                 {
2360                                         if(closest_target)
2361                                         {
2362                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2363                                                 { closest_target = head; }
2364                                         }
2365                                         else { closest_target = head; }
2366                                 }
2367
2368                                 head = head.chain;
2369                         }
2370
2371                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2372                 }
2373         }
2374
2375         // a use key was pressed; call handlers
2376         MUTATOR_CALLHOOK(PlayerUseKey, this);
2377 }
2378
2379
2380 /*
2381 =============
2382 PlayerPreThink
2383
2384 Called every frame for each client before the physics are run
2385 =============
2386 */
2387 .float last_vehiclecheck;
2388 void PlayerPreThink (entity this)
2389 {
2390         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2391         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2392
2393         WarpZone_PlayerPhysics_FixVAngle(this);
2394
2395         if (frametime) {
2396                 // physics frames: update anticheat stuff
2397                 anticheat_prethink(this);
2398         }
2399
2400         if (blockSpectators && frametime) {
2401                 // WORKAROUND: only use dropclient in server frames (frametime set).
2402                 // Never use it in cl_movement frames (frametime zero).
2403                 checkSpectatorBlock(this);
2404         }
2405
2406         zoomstate_set = false;
2407
2408         // Check for nameless players
2409         if (this.netname == "" || this.netname != CS(this).netname_previous)
2410         {
2411                 bool assume_unchanged = (CS(this).netname_previous == "");
2412                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2413                 {
2414                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2415                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2416                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2417                         assume_unchanged = false;
2418                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2419                 }
2420                 if (isInvisibleString(this.netname))
2421                 {
2422                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2423                         sprint(this, "Warning: invisible names are not allowed.\n");
2424                         assume_unchanged = false;
2425                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2426                 }
2427                 if (!assume_unchanged && autocvar_sv_eventlog)
2428                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2429                 strcpy(CS(this).netname_previous, this.netname);
2430         }
2431
2432         // version nagging
2433         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2434         CS(this).version_nagtime = 0;
2435         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2436             // git client
2437         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2438             // git server
2439             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2440         } else {
2441             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2442             if (r < 0) { // old client
2443                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2444             } else if (r > 0) { // old server
2445                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2446             }
2447         }
2448     }
2449
2450         // GOD MODE info
2451         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2452         {
2453                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2454                 this.max_armorvalue = 0;
2455         }
2456
2457         if(IS_PLAYER(this))
2458         {
2459                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2460                 {
2461                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2462                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2463                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2464
2465                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2466                                 Unfreeze(this, false);
2467                 }
2468                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2469                 {
2470                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2471                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2472
2473                         if (GetResource(this, RES_HEALTH) < 1)
2474                         {
2475                                 if (this.vehicle)
2476                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2477                                 if(this.event_damage)
2478                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2479                         }
2480                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2481                                 Unfreeze(this, false);
2482                 }
2483         }
2484
2485         MUTATOR_CALLHOOK(PlayerPreThink, this);
2486
2487         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2488         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2489         {
2490                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2491                 {
2492                         if(!it.owner)
2493                         {
2494                                 if(!it.team || SAME_TEAM(this, it))
2495                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2496                                 else if(autocvar_g_vehicles_steal)
2497                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2498                         }
2499                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2500                         {
2501                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2502                         }
2503                 });
2504
2505                 this.last_vehiclecheck = time + 1;
2506         }
2507
2508         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2509         {
2510                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2511                         PlayerUseKey(this);
2512                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2513         }
2514
2515         if (IS_REAL_CLIENT(this))
2516                 PrintWelcomeMessage(this);
2517
2518         if (IS_PLAYER(this)) {
2519                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2520                         error("Client can't be spawned as player on connection!");
2521                 if(!PlayerThink(this))
2522                         return;
2523         }
2524         else if (game_stopped || intermission_running) {
2525                 if(intermission_running)
2526                         IntermissionThink(this);
2527                 return;
2528         }
2529         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2530         {
2531                 CS(this).autojoin_checked = true;
2532                 // don't do this in ClientConnect
2533                 // many things can go wrong if a client is spawned as player on connection
2534                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2535                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2536                                 && (!teamplay || autocvar_g_balance_teams)))
2537                 {
2538                         campaign_bots_may_start = true;
2539                         Join(this);
2540                         return;
2541                 }
2542         }
2543         else if (IS_OBSERVER(this)) {
2544                 ObserverThink(this);
2545         }
2546         else if (IS_SPEC(this)) {
2547                 SpectatorThink(this);
2548         }
2549
2550         // WEAPONTODO: Add weapon request for this
2551         if (!zoomstate_set) {
2552                 bool wep_zoomed = false;
2553                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2554                 {
2555                         .entity weaponentity = weaponentities[slot];
2556                         Weapon thiswep = this.(weaponentity).m_weapon;
2557                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2558                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2559                 }
2560                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2561     }
2562
2563         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2564         {
2565                 CS(this).teamkill_soundtime = 0;
2566
2567                 entity e = CS(this).teamkill_soundsource;
2568                 entity oldpusher = e.pusher;
2569                 e.pusher = this;
2570                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2571                 e.pusher = oldpusher;
2572         }
2573
2574         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2575                 CS(this).taunt_soundtime = 0;
2576                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2577         }
2578
2579         target_voicescript_next(this);
2580
2581         // WEAPONTODO: Move into weaponsystem somehow
2582         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2583         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2584         {
2585                 .entity weaponentity = weaponentities[slot];
2586                 if(this.(weaponentity).m_weapon == WEP_Null)
2587                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2588         }
2589 }
2590
2591 void DrownPlayer(entity this)
2592 {
2593         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2594                 return;
2595
2596         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2597         {
2598                 if(this.air_finished < time)
2599                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2600                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2601         }
2602         else if (this.air_finished < time)
2603         {       // drown!
2604                 if (this.pain_finished < time)
2605                 {
2606                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2607                         this.pain_finished = time + 0.5;
2608                 }
2609         }
2610 }
2611
2612 .bool move_qcphysics;
2613
2614 void Player_Physics(entity this)
2615 {
2616         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2617
2618         if(!this.move_qcphysics)
2619                 return;
2620
2621         if(!frametime && !CS(this).pm_frametime)
2622                 return;
2623
2624         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2625
2626         CS(this).pm_frametime = 0;
2627 }
2628
2629 /*
2630 =============
2631 PlayerPostThink
2632
2633 Called every frame for each client after the physics are run
2634 =============
2635 */
2636 void PlayerPostThink (entity this)
2637 {
2638         Player_Physics(this);
2639
2640         if (sv_maxidle > 0)
2641         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2642         if (IS_REAL_CLIENT(this))
2643         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2644         {
2645                 int totalClients = 0;
2646                 if(sv_maxidle_slots > 0)
2647                 {
2648                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2649                         {
2650                                 ++totalClients;
2651                         });
2652                 }
2653
2654                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2655                 { /* do nothing */ }
2656                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2657                 {
2658                         if (CS(this).idlekick_lasttimeleft)
2659                         {
2660                                 CS(this).idlekick_lasttimeleft = 0;
2661                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2662                         }
2663                 }
2664                 else
2665                 {
2666                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2667                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2668                                 if (!CS(this).idlekick_lasttimeleft)
2669                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2670                         }
2671                         if (timeleft <= 0) {
2672                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2673                                 dropclient(this);
2674                                 return;
2675                         }
2676                         else if (timeleft <= 10) {
2677                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2678                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2679                 }
2680                                 CS(this).idlekick_lasttimeleft = timeleft;
2681                         }
2682                 }
2683         }
2684
2685         CheatFrame(this);
2686
2687         if (game_stopped)
2688         {
2689                 this.solid = SOLID_NOT;
2690                 this.takedamage = DAMAGE_NO;
2691                 set_movetype(this, MOVETYPE_NONE);
2692         }
2693
2694         if (IS_PLAYER(this)) {
2695                 if(this.death_time == time && IS_DEAD(this))
2696                 {
2697                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2698                         // once all the damage events of this frame have been processed with normal size
2699                         this.maxs.z = 5;
2700                         setsize(this, this.mins, this.maxs);
2701                 }
2702                 DrownPlayer(this);
2703                 UpdateChatBubble(this);
2704                 if (CS(this).impulse) ImpulseCommands(this);
2705                 if (game_stopped)
2706                 {
2707                         CSQCMODEL_AUTOUPDATE(this);
2708                         return;
2709                 }
2710                 GetPressedKeys(this);
2711         }
2712
2713         if (this.waypointsprite_attachedforcarrier) {
2714                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2715                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2716         }
2717
2718         CSQCMODEL_AUTOUPDATE(this);
2719 }
2720
2721 /**
2722  * message "": do not say, just test flood control
2723  * return value:
2724  *   1 = accept
2725  *   0 = reject
2726  *  -1 = fake accept
2727  */
2728 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2729 {
2730         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2731                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2732
2733         if (source)
2734                 msgin = formatmessage(source, msgin);
2735
2736         string colorstr;
2737         if (!(IS_PLAYER(source) || source.caplayer))
2738                 colorstr = "^0"; // black for spectators
2739         else if(teamplay)
2740                 colorstr = Team_ColorCode(source.team);
2741         else
2742         {
2743                 colorstr = "";
2744                 teamsay = false;
2745         }
2746
2747         if (!source) {
2748                 colorstr = "";
2749                 teamsay = false;
2750         }
2751
2752         if(msgin != "")
2753                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2754
2755         /*
2756          * using bprint solves this... me stupid
2757         // how can we prevent the message from appearing in a listen server?
2758         // for now, just give "say" back and only handle say_team
2759         if(!teamsay)
2760         {
2761                 clientcommand(source, strcat("say ", msgin));
2762                 return;
2763         }
2764         */
2765
2766         string namestr = "";
2767         if (source)
2768                 namestr = playername(source, autocvar_g_chat_teamcolors);
2769
2770         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2771
2772         string msgstr = "", cmsgstr = "";
2773         string privatemsgprefix = string_null;
2774         int privatemsgprefixlen = 0;
2775         if (msgin != "")
2776         {
2777                 bool found_me = false;
2778                 if(strstrofs(msgin, "/me", 0) >= 0)
2779                 {
2780                         string newmsgin = "";
2781                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2782                         FOREACH_WORD(msgin, true,
2783                         {
2784                                 if(strdecolorize(it) == "/me")
2785                                 {
2786                                         found_me = true;
2787                                         newmsgin = cons(newmsgin, newnamestr);
2788                                 }
2789                                 else
2790                                         newmsgin = cons(newmsgin, it);
2791                         });
2792                         msgin = newmsgin;
2793                 }
2794
2795                 if(privatesay)
2796                 {
2797                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2798                         privatemsgprefixlen = strlen(msgstr);
2799                         msgstr = strcat(msgstr, msgin);
2800                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2801                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2802                 }
2803                 else if(teamsay)
2804                 {
2805                         if(found_me)
2806                         {
2807                                 //msgin = strreplace("/me", "", msgin);
2808                                 //msgin = substring(msgin, 3, strlen(msgin));
2809                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2810                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2811                         }
2812                         else
2813                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2814                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2815                 }
2816                 else
2817                 {
2818                         if(found_me)
2819                         {
2820                                 //msgin = strreplace("/me", "", msgin);
2821                                 //msgin = substring(msgin, 3, strlen(msgin));
2822                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2823                                 msgstr = strcat("\{1}^4* ^7", msgin);
2824                         }
2825                         else {
2826                                 msgstr = "\{1}";
2827                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2828                                 msgstr = strcat(msgstr, msgin);
2829                         }
2830                         cmsgstr = "";
2831                 }
2832                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2833         }
2834
2835         string fullmsgstr = msgstr;
2836         string fullcmsgstr = cmsgstr;
2837
2838         // FLOOD CONTROL
2839         int flood = 0;
2840         var .float flood_field = floodcontrol_chat;
2841         if(floodcontrol && source)
2842         {
2843                 float flood_spl;
2844                 float flood_burst;
2845                 float flood_lmax;
2846                 float lines;
2847                 if(privatesay)
2848                 {
2849                         flood_spl = autocvar_g_chat_flood_spl_tell;
2850                         flood_burst = autocvar_g_chat_flood_burst_tell;
2851                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2852                         flood_field = floodcontrol_chattell;
2853                 }
2854                 else if(teamsay)
2855                 {
2856                         flood_spl = autocvar_g_chat_flood_spl_team;
2857                         flood_burst = autocvar_g_chat_flood_burst_team;
2858                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2859                         flood_field = floodcontrol_chatteam;
2860                 }
2861                 else
2862                 {
2863                         flood_spl = autocvar_g_chat_flood_spl;
2864                         flood_burst = autocvar_g_chat_flood_burst;
2865                         flood_lmax = autocvar_g_chat_flood_lmax;
2866                         flood_field = floodcontrol_chat;
2867                 }
2868                 flood_burst = max(0, flood_burst - 1);
2869                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2870
2871                 // do flood control for the default line size
2872                 if(msgstr != "")
2873                 {
2874                         getWrappedLine_remaining = msgstr;
2875                         msgstr = "";
2876                         lines = 0;
2877                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2878                         {
2879                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2880                                 ++lines;
2881                         }
2882                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2883
2884                         if(getWrappedLine_remaining != "")
2885                         {
2886                                 msgstr = strcat(msgstr, "\n");
2887                                 flood = 2;
2888                         }
2889
2890                         if (time >= source.(flood_field))
2891                         {
2892                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2893                         }
2894                         else
2895                         {
2896                                 flood = 1;
2897                                 msgstr = fullmsgstr;
2898                         }
2899                 }
2900                 else
2901                 {
2902                         if (time >= source.(flood_field))
2903                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2904                         else
2905                                 flood = 1;
2906                 }
2907
2908                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2909                         source.(flood_field) = flood = 0;
2910         }
2911
2912         string sourcemsgstr, sourcecmsgstr;
2913         if(flood == 2) // cannot happen for empty msgstr
2914         {
2915                 if(autocvar_g_chat_flood_notify_flooder)
2916                 {
2917                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2918                         sourcecmsgstr = "";
2919                 }
2920                 else
2921                 {
2922                         sourcemsgstr = fullmsgstr;
2923                         sourcecmsgstr = fullcmsgstr;
2924                 }
2925                 cmsgstr = "";
2926         }
2927         else
2928         {
2929                 sourcemsgstr = msgstr;
2930                 sourcecmsgstr = cmsgstr;
2931         }
2932
2933         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2934         {
2935                 if (!game_stopped)
2936                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2937                         teamsay = -1; // spectators
2938         }
2939
2940         if(flood)
2941                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2942
2943         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2944         if(privatesay)
2945                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2946
2947         int ret;
2948         if(source && CS(source).muted)
2949         {
2950                 // always fake the message
2951                 ret = -1;
2952         }
2953         else if(flood == 1)
2954         {
2955                 if (autocvar_g_chat_flood_notify_flooder)
2956                 {
2957                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2958                         ret = 0;
2959                 }
2960                 else
2961                         ret = -1;
2962         }
2963         else
2964         {
2965                 ret = 1;
2966         }
2967
2968         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2969         {
2970                 if (!game_stopped)
2971                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2972                         ret = -1; // just hide the message completely
2973         }
2974
2975         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2976         ret = M_ARGV(1, int);
2977
2978         string event_log_msg = "";
2979
2980         if(sourcemsgstr != "" && ret != 0)
2981         {
2982                 if(ret < 0) // faked message, because the player is muted
2983                 {
2984                         sprint(source, sourcemsgstr);
2985                         if(sourcecmsgstr != "" && !privatesay)
2986                                 centerprint(source, sourcecmsgstr);
2987                 }
2988                 else if(privatesay) // private message, between 2 people only
2989                 {
2990                         sprint(source, sourcemsgstr);
2991                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2992                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2993                         {
2994                                 sprint(privatesay, msgstr);
2995                                 if(cmsgstr != "")
2996                                         centerprint(privatesay, cmsgstr);
2997                         }
2998                 }
2999                 else if ( teamsay && CS(source).active_minigame )
3000                 {
3001                         sprint(source, sourcemsgstr);
3002                         dedicated_print(msgstr); // send to server console too
3003                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3004                                 sprint(it, msgstr);
3005                         });
3006                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3007
3008                 }
3009                 else if(teamsay > 0) // team message, only sent to team mates
3010                 {
3011                         sprint(source, sourcemsgstr);
3012                         dedicated_print(msgstr); // send to server console too
3013                         if(sourcecmsgstr != "")
3014                                 centerprint(source, sourcecmsgstr);
3015                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3016                                 sprint(it, msgstr);
3017                                 if(cmsgstr != "")
3018                                         centerprint(it, cmsgstr);
3019                         });
3020                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3021                 }
3022                 else if(teamsay < 0) // spectator message, only sent to spectators
3023                 {
3024                         sprint(source, sourcemsgstr);
3025                         dedicated_print(msgstr); // send to server console too
3026                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3027                                 sprint(it, msgstr);
3028                         });
3029                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3030                 }
3031                 else
3032                 {
3033                         if (source) {
3034                                 sprint(source, sourcemsgstr);
3035                                 dedicated_print(msgstr); // send to server console too
3036                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3037                         }
3038                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3039                                 sprint(it, msgstr);
3040                         });
3041                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3042                 }
3043         }
3044
3045         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3046                 GameLogEcho(event_log_msg);
3047         }
3048
3049         return ret;
3050 }
3051
3052 // hack to copy the button fields from the client entity to the Client State
3053 void PM_UpdateButtons(entity this, entity store)
3054 {
3055         if(this.impulse)
3056                 store.impulse = this.impulse;
3057         this.impulse = 0;
3058
3059         bool typing = this.buttonchat || this.button12;
3060
3061         store.button0 = (typing) ? 0 : this.button0;
3062         //button1?!
3063         store.button2 = (typing) ? 0 : this.button2;
3064         store.button3 = (typing) ? 0 : this.button3;
3065         store.button4 = this.button4;
3066         store.button5 = (typing) ? 0 : this.button5;
3067         store.button6 = this.button6;
3068         store.button7 = this.button7;
3069         store.button8 = this.button8;
3070         store.button9 = this.button9;
3071         store.button10 = this.button10;
3072         store.button11 = this.button11;
3073         store.button12 = this.button12;
3074         store.button13 = this.button13;
3075         store.button14 = this.button14;
3076         store.button15 = this.button15;
3077         store.button16 = this.button16;
3078         store.buttonuse = this.buttonuse;
3079         store.buttonchat = this.buttonchat;
3080
3081         store.cursor_active = this.cursor_active;
3082         store.cursor_screen = this.cursor_screen;
3083         store.cursor_trace_start = this.cursor_trace_start;
3084         store.cursor_trace_endpos = this.cursor_trace_endpos;
3085         store.cursor_trace_ent = this.cursor_trace_ent;
3086
3087         store.ping = this.ping;
3088         store.ping_packetloss = this.ping_packetloss;
3089         store.ping_movementloss = this.ping_movementloss;
3090
3091         store.v_angle = this.v_angle;
3092         store.movement = (typing) ? '0 0 0' : this.movement;
3093 }
3094
3095 NET_HANDLE(fpsreport, bool)
3096 {
3097         int fps = ReadShort();
3098         PlayerScore_Set(sender, SP_FPS, fps);
3099         return true;
3100 }