3b48e5c1cfa38c7270cd43adc0b44171176c6809
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include <common/state.qh>
27
28 #include <common/effects/qc/globalsound.qh>
29
30 #include "../common/triggers/func/conveyor.qh"
31 #include "../common/triggers/teleporters.qh"
32
33 #include "../common/vehicles/all.qh"
34
35 #include "weapons/hitplot.qh"
36 #include "weapons/weaponsystem.qh"
37
38 #include "../common/net_notice.qh"
39 #include "../common/net_linked.qh"
40 #include "../common/physics/player.qh"
41
42 #include "../common/items/_mod.qh"
43
44 #include "../common/mutators/mutator/waypoints/all.qh"
45
46 #include "../common/triggers/subs.qh"
47 #include "../common/triggers/triggers.qh"
48 #include "../common/triggers/trigger/secret.qh"
49
50 #include "../common/minigames/sv_minigames.qh"
51
52 #include "../common/items/inventory.qh"
53
54 #include "../common/monsters/sv_monsters.qh"
55
56 #include "../lib/warpzone/server.qh"
57
58 STATIC_METHOD(Client, Add, void(Client this, int _team))
59 {
60     ClientConnect(this);
61     TRANSMUTE(Player, this);
62     this.frame = 12; // 7
63     this.team = _team;
64     PutClientInServer(this);
65 }
66
67 void PutObserverInServer(entity this);
68
69 STATIC_METHOD(Client, Remove, void(Client this))
70 {
71     TRANSMUTE(Observer, this);
72     PutClientInServer(this);
73     ClientDisconnect(this);
74 }
75
76 void send_CSQC_teamnagger() {
77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
78 }
79
80 int CountSpectators(entity player, entity to)
81 {
82         if(!player) { return 0; } // not sure how, but best to be safe
83
84         int spec_count = 0;
85
86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
87         {
88                 spec_count++;
89         });
90
91         return spec_count;
92 }
93
94 void WriteSpectators(entity player, entity to)
95 {
96         if(!player) { return; } // not sure how, but best to be safe
97
98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
99         {
100                 WriteByte(MSG_ENTITY, num_for_edict(it));
101         });
102 }
103
104 bool ClientData_Send(entity this, entity to, int sf)
105 {
106         assert(to == this.owner, return false);
107
108         entity e = to;
109         if (IS_SPEC(e)) e = e.enemy;
110
111         sf = 0;
112         if (e.race_completed)       sf |= 1; // forced scoreboard
113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
114         if (e.zoomstate)            sf |= 4; // zoomed
115         if (e.porto_v_angle_held)   sf |= 8; // angles held
116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
117
118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
119         WriteByte(MSG_ENTITY, sf);
120
121         if (sf & 2)
122         {
123                 WriteByte(MSG_ENTITY, to.spectatee_status);
124         }
125         if (sf & 8)
126         {
127                 WriteAngle(MSG_ENTITY, e.v_angle.x);
128                 WriteAngle(MSG_ENTITY, e.v_angle.y);
129         }
130
131         if(sf & 16)
132         {
133                 float specs = CountSpectators(e, to);
134                 WriteByte(MSG_ENTITY, specs);
135                 WriteSpectators(e, to);
136         }
137
138         return true;
139 }
140
141 void ClientData_Attach(entity this)
142 {
143         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
144         this.clientdata.drawonlytoclient = this;
145         this.clientdata.owner = this;
146 }
147
148 void ClientData_Detach(entity this)
149 {
150         delete(this.clientdata);
151         this.clientdata = NULL;
152 }
153
154 void ClientData_Touch(entity e)
155 {
156         e.clientdata.SendFlags = 1;
157
158         // make it spectatable
159         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
160 }
161
162 .string netname_previous;
163
164 void SetSpectatee(entity this, entity spectatee);
165 void SetSpectatee_status(entity this, int spectatee_num);
166
167
168 /*
169 =============
170 CheckPlayerModel
171
172 Checks if the argument string can be a valid playermodel.
173 Returns a valid one in doubt.
174 =============
175 */
176 string FallbackPlayerModel;
177 string CheckPlayerModel(string plyermodel) {
178         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
179         {
180                 // note: we cannot summon Don Strunzone here, some player may
181                 // still have the model string set. In case anyone manages how
182                 // to change a cvar default, we'll have a small leak here.
183                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
184         }
185         // only in right path
186         if( substring(plyermodel,0,14) != "models/player/")
187                 return FallbackPlayerModel;
188         // only good file extensions
189         if(substring(plyermodel,-4,4) != ".zym")
190         if(substring(plyermodel,-4,4) != ".dpm")
191         if(substring(plyermodel,-4,4) != ".iqm")
192         if(substring(plyermodel,-4,4) != ".md3")
193         if(substring(plyermodel,-4,4) != ".psk")
194                 return FallbackPlayerModel;
195         // forbid the LOD models
196         if(substring(plyermodel, -9,5) == "_lod1")
197                 return FallbackPlayerModel;
198         if(substring(plyermodel, -9,5) == "_lod2")
199                 return FallbackPlayerModel;
200         if(plyermodel != strtolower(plyermodel))
201                 return FallbackPlayerModel;
202         // also, restrict to server models
203         if(autocvar_sv_servermodelsonly)
204         {
205                 if(!fexists(plyermodel))
206                         return FallbackPlayerModel;
207         }
208         return plyermodel;
209 }
210
211 void setplayermodel(entity e, string modelname)
212 {
213         precache_model(modelname);
214         _setmodel(e, modelname);
215         player_setupanimsformodel(e);
216         if(!autocvar_g_debug_globalsounds)
217                 UpdatePlayerSounds(e);
218 }
219
220 void FixPlayermodel(entity player);
221 /** putting a client as observer in the server */
222 void PutObserverInServer(entity this)
223 {
224     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
225         PlayerState_detach(this);
226
227         if (IS_PLAYER(this) && this.health >= 1) {
228         // despawn effect
229                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
230     }
231
232     {
233         entity spot = SelectSpawnPoint(this, true);
234         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
235         this.angles = spot.angles;
236         this.angles_z = 0;
237         this.fixangle = true;
238         // offset it so that the spectator spawns higher off the ground, looks better this way
239         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
240         this.prevorigin = this.origin;
241         if (IS_REAL_CLIENT(this))
242         {
243             msg_entity = this;
244             WriteByte(MSG_ONE, SVC_SETVIEW);
245             WriteEntity(MSG_ONE, this);
246         }
247         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
248         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
249         if(!autocvar_g_debug_globalsounds)
250         {
251                 // needed for player sounds
252                 this.model = "";
253                 FixPlayermodel(this);
254         }
255         setmodel(this, MDL_Null);
256         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
257         this.view_ofs = '0 0 0';
258     }
259
260     RemoveGrapplingHook(this);
261         Portal_ClearAll(this);
262         Unfreeze(this);
263         SetSpectatee(this, NULL);
264
265         if (this.alivetime)
266         {
267                 if (!warmup_stage)
268                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
269                 this.alivetime = 0;
270         }
271
272         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
273
274         WaypointSprite_PlayerDead(this);
275
276         if (mutator_returnvalue) {
277             // mutator prevents resetting teams+score
278         } else {
279                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
280         this.frags = FRAGS_SPECTATOR;
281         PlayerScore_Clear(this);  // clear scores when needed
282     }
283
284         if (this.killcount != FRAGS_SPECTATOR)
285         {
286                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
287                 if(!intermission_running)
288                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
289                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
290
291                 if(this.just_joined == false) {
292                         LogTeamchange(this.playerid, -1, 4);
293                 } else
294                         this.just_joined = false;
295         }
296
297         accuracy_resend(this);
298
299         this.spectatortime = time;
300         if(this.bot_attack)
301                 IL_REMOVE(g_bot_targets, this);
302         this.bot_attack = false;
303     this.hud = HUD_NORMAL;
304         TRANSMUTE(Observer, this);
305         this.iscreature = false;
306         this.teleportable = TELEPORT_SIMPLE;
307         if(this.damagedbycontents)
308                 IL_REMOVE(g_damagedbycontents, this);
309         this.damagedbycontents = false;
310         this.health = FRAGS_SPECTATOR;
311         SetSpectatee_status(this, etof(this));
312         this.takedamage = DAMAGE_NO;
313         this.solid = SOLID_NOT;
314         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
315         this.flags = FL_CLIENT | FL_NOTARGET;
316         this.armorvalue = 666;
317         this.effects = 0;
318         this.armorvalue = autocvar_g_balance_armor_start;
319         this.pauserotarmor_finished = 0;
320         this.pauserothealth_finished = 0;
321         this.pauseregen_finished = 0;
322         this.damageforcescale = 0;
323         this.death_time = 0;
324         this.respawn_flags = 0;
325         this.respawn_time = 0;
326         this.stat_respawn_time = 0;
327         this.alpha = 0;
328         this.scale = 0;
329         this.fade_time = 0;
330         this.pain_frame = 0;
331         this.pain_finished = 0;
332         this.strength_finished = 0;
333         this.invincible_finished = 0;
334         this.superweapons_finished = 0;
335         this.pushltime = 0;
336         this.istypefrag = 0;
337         setthink(this, func_null);
338         this.nextthink = 0;
339         this.hook_time = 0;
340         this.deadflag = DEAD_NO;
341         this.crouch = false;
342         this.revival_time = 0;
343
344         this.items = 0;
345         this.weapons = '0 0 0';
346         this.drawonlytoclient = this;
347
348         this.weaponname = "";
349         this.weaponmodel = "";
350         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
351         {
352                 this.weaponentities[slot] = NULL;
353         }
354         this.exteriorweaponentity = NULL;
355         this.killcount = FRAGS_SPECTATOR;
356         this.velocity = '0 0 0';
357         this.avelocity = '0 0 0';
358         this.punchangle = '0 0 0';
359         this.punchvector = '0 0 0';
360         this.oldvelocity = this.velocity;
361         this.fire_endtime = -1;
362         this.event_damage = func_null;
363
364         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
365         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
366         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
367 }
368
369 int player_getspecies(entity this)
370 {
371         get_model_parameters(this.model, this.skin);
372         int s = get_model_parameters_species;
373         get_model_parameters(string_null, 0);
374         if (s < 0) return SPECIES_HUMAN;
375         return s;
376 }
377
378 .float model_randomizer;
379 void FixPlayermodel(entity player)
380 {
381         string defaultmodel = "";
382         int defaultskin = 0;
383         if(autocvar_sv_defaultcharacter)
384         {
385                 if(teamplay)
386                 {
387                         string s = Static_Team_ColorName_Lower(player.team);
388                         if (s != "neutral")
389                         {
390                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
391                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
392                         }
393                 }
394
395                 if(defaultmodel == "")
396                 {
397                         defaultmodel = autocvar_sv_defaultplayermodel;
398                         defaultskin = autocvar_sv_defaultplayerskin;
399                 }
400
401                 int n = tokenize_console(defaultmodel);
402                 if(n > 0)
403                 {
404                         defaultmodel = argv(floor(n * player.model_randomizer));
405                         // However, do NOT randomize if the player-selected model is in the list.
406                         for (int i = 0; i < n; ++i)
407                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
408                                         defaultmodel = argv(i);
409                 }
410
411                 int i = strstrofs(defaultmodel, ":", 0);
412                 if(i >= 0)
413                 {
414                         defaultskin = stof(substring(defaultmodel, i+1, -1));
415                         defaultmodel = substring(defaultmodel, 0, i);
416                 }
417         }
418         if(autocvar_sv_defaultcharacterskin && !defaultskin)
419         {
420                 if(teamplay)
421                 {
422                         string s = Static_Team_ColorName_Lower(player.team);
423                         if (s != "neutral")
424                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
425                 }
426
427                 if(!defaultskin)
428                         defaultskin = autocvar_sv_defaultplayerskin;
429         }
430
431         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
432         defaultmodel = M_ARGV(0, string);
433         defaultskin = M_ARGV(1, int);
434
435         bool chmdl = false;
436         int oldskin;
437         if(defaultmodel != "")
438         {
439                 if (defaultmodel != player.model)
440                 {
441                         vector m1 = player.mins;
442                         vector m2 = player.maxs;
443                         setplayermodel (player, defaultmodel);
444                         setsize (player, m1, m2);
445                         chmdl = true;
446                 }
447
448                 oldskin = player.skin;
449                 player.skin = defaultskin;
450         } else {
451                 if (player.playermodel != player.model || player.playermodel == "")
452                 {
453                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
454                         vector m1 = player.mins;
455                         vector m2 = player.maxs;
456                         setplayermodel (player, player.playermodel);
457                         setsize (player, m1, m2);
458                         chmdl = true;
459                 }
460
461                 if(!autocvar_sv_defaultcharacterskin)
462                 {
463                         oldskin = player.skin;
464                         player.skin = stof(player.playerskin);
465                 }
466                 else
467                 {
468                         oldskin = player.skin;
469                         player.skin = defaultskin;
470                 }
471         }
472
473         if(chmdl || oldskin != player.skin) // model or skin has changed
474         {
475                 player.species = player_getspecies(player); // update species
476                 if(!autocvar_g_debug_globalsounds)
477                         UpdatePlayerSounds(player); // update skin sounds
478         }
479
480         if(!teamplay)
481                 if(strlen(autocvar_sv_defaultplayercolors))
482                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
483                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
484 }
485
486
487 /** Called when a client spawns in the server */
488 void PutClientInServer(entity this)
489 {
490         if (IS_BOT_CLIENT(this)) {
491                 TRANSMUTE(Player, this);
492         } else if (IS_REAL_CLIENT(this)) {
493                 msg_entity = this;
494                 WriteByte(MSG_ONE, SVC_SETVIEW);
495                 WriteEntity(MSG_ONE, this);
496         }
497         if (gameover) {
498                 TRANSMUTE(Observer, this);
499         }
500
501         SetSpectatee(this, NULL);
502
503         // reset player keys
504         this.itemkeys = 0;
505
506         MUTATOR_CALLHOOK(PutClientInServer, this);
507
508         if (IS_OBSERVER(this)) {
509                 PutObserverInServer(this);
510         } else if (IS_PLAYER(this)) {
511                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
512
513                 PlayerState_attach(this);
514                 accuracy_resend(this);
515
516                 if (this.team < 0)
517                         JoinBestTeam(this, false, true);
518
519                 entity spot = SelectSpawnPoint(this, false);
520                 if (!spot) {
521                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
522                         return; // spawn failed
523                 }
524
525                 TRANSMUTE(Player, this);
526
527                 this.wasplayer = true;
528                 this.iscreature = true;
529                 this.teleportable = TELEPORT_NORMAL;
530                 if(!this.damagedbycontents)
531                         IL_PUSH(g_damagedbycontents, this);
532                 this.damagedbycontents = true;
533                 set_movetype(this, MOVETYPE_WALK);
534                 this.solid = SOLID_SLIDEBOX;
535                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
536                 if (autocvar_g_playerclip_collisions)
537                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
538                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
539                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
540                 this.frags = FRAGS_PLAYER;
541                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
542                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
543                 if (autocvar__notarget)
544                         this.flags |= FL_NOTARGET;
545                 this.takedamage = DAMAGE_AIM;
546                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
547                 this.dmg = 2; // WTF
548
549                 if (warmup_stage) {
550                         this.ammo_shells = warmup_start_ammo_shells;
551                         this.ammo_nails = warmup_start_ammo_nails;
552                         this.ammo_rockets = warmup_start_ammo_rockets;
553                         this.ammo_cells = warmup_start_ammo_cells;
554                         this.ammo_plasma = warmup_start_ammo_plasma;
555                         this.ammo_fuel = warmup_start_ammo_fuel;
556                         this.health = warmup_start_health;
557                         this.armorvalue = warmup_start_armorvalue;
558                         this.weapons = WARMUP_START_WEAPONS;
559                 } else {
560                         this.ammo_shells = start_ammo_shells;
561                         this.ammo_nails = start_ammo_nails;
562                         this.ammo_rockets = start_ammo_rockets;
563                         this.ammo_cells = start_ammo_cells;
564                         this.ammo_plasma = start_ammo_plasma;
565                         this.ammo_fuel = start_ammo_fuel;
566                         this.health = start_health;
567                         this.armorvalue = start_armorvalue;
568                         this.weapons = start_weapons;
569                 }
570                 SetSpectatee_status(this, 0);
571
572                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
573
574                 this.items = start_items;
575
576                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
577                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
578                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
579                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
580                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
581                 // extend the pause of rotting if client was reset at the beginning of the countdown
582                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
583                         float f = game_starttime - time;
584                         this.spawnshieldtime += f;
585                         this.pauserotarmor_finished += f;
586                         this.pauserothealth_finished += f;
587                         this.pauseregen_finished += f;
588                 }
589                 this.damageforcescale = 2;
590                 this.death_time = 0;
591                 this.respawn_flags = 0;
592                 this.respawn_time = 0;
593                 this.stat_respawn_time = 0;
594                 this.scale = autocvar_sv_player_scale;
595                 this.fade_time = 0;
596                 this.pain_frame = 0;
597                 this.pain_finished = 0;
598                 this.pushltime = 0;
599                 setthink(this, func_null); // players have no think function
600                 this.nextthink = 0;
601                 this.dmg_team = 0;
602                 this.ballistics_density = autocvar_g_ballistics_density_player;
603
604                 this.deadflag = DEAD_NO;
605
606                 this.angles = spot.angles;
607                 this.angles_z = 0; // never spawn tilted even if the spot says to
608                 if (IS_BOT_CLIENT(this))
609                         this.v_angle = this.angles;
610                 this.fixangle = true; // turn this way immediately
611                 this.oldvelocity = this.velocity = '0 0 0';
612                 this.avelocity = '0 0 0';
613                 this.punchangle = '0 0 0';
614                 this.punchvector = '0 0 0';
615
616                 this.strength_finished = 0;
617                 this.invincible_finished = 0;
618                 this.fire_endtime = -1;
619                 this.revival_time = 0;
620                 this.air_finished = time + 12;
621
622                 entity spawnevent = new_pure(spawnevent);
623                 spawnevent.owner = this;
624                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
625
626                 // Cut off any still running player sounds.
627                 stopsound(this, CH_PLAYER_SINGLE);
628
629                 this.model = "";
630                 FixPlayermodel(this);
631                 this.drawonlytoclient = NULL;
632
633                 this.viewloc = NULL;
634
635                 this.crouch = false;
636                 this.view_ofs = STAT(PL_VIEW_OFS, this);
637                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
638                 this.spawnorigin = spot.origin;
639                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
640                 // don't reset back to last position, even if new position is stuck in solid
641                 this.oldorigin = this.origin;
642                 this.prevorigin = this.origin;
643                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
644                 if(this.conveyor)
645                         IL_REMOVE(g_conveyed, this);
646                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
647                 this.hud = HUD_NORMAL;
648
649                 this.event_damage = PlayerDamage;
650
651                 if(!this.bot_attack)
652                         IL_PUSH(g_bot_targets, this);
653                 this.bot_attack = true;
654                 this.monster_attack = true;
655
656                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
657
658                 if (this.killcount == FRAGS_SPECTATOR) {
659                         PlayerScore_Clear(this);
660                         this.killcount = 0;
661                 }
662
663                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
664                 {
665                         CL_SpawnWeaponentity(this, weaponentities[slot]);
666                 }
667                 this.alpha = default_player_alpha;
668                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
669                 this.exteriorweaponentity.alpha = default_weapon_alpha;
670
671                 this.speedrunning = false;
672
673                 target_voicescript_clear(this);
674
675                 // reset fields the weapons may use
676                 FOREACH(Weapons, true, LAMBDA(
677                         it.wr_resetplayer(it, this);
678                         // reload all reloadable weapons
679                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
680                                 this.weapon_load[it.m_id] = it.reloading_ammo;
681                         }
682                 ));
683
684                 {
685                         string s = spot.target;
686                         spot.target = string_null;
687                         SUB_UseTargets(spot, this, NULL);
688                         spot.target = s;
689                 }
690
691                 Unfreeze(this);
692
693                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
694
695                 if (autocvar_spawn_debug)
696                 {
697                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
698                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
699                 }
700
701                 PS(this).m_switchweapon = w_getbestweapon(this);
702                 this.cnt = -1; // W_LastWeapon will not complain
703                 PS(this).m_weapon = WEP_Null;
704                 this.weaponname = "";
705                 PS(this).m_switchingweapon = WEP_Null;
706
707                 if (!warmup_stage && !this.alivetime)
708                         this.alivetime = time;
709
710                 antilag_clear(this, CS(this));
711         }
712 }
713
714 void ClientInit_misc(entity this);
715
716 // TODO do we need all these fields, or should we stop autodetecting runtime
717 // changes and just have a console command to update this?
718 bool ClientInit_SendEntity(entity this, entity to, int sf)
719 {
720         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
721         return = true;
722         msg_entity = to;
723         // MSG_INIT replacement
724         // TODO: make easier to use
725         Registry_send_all();
726         W_PROP_reload(MSG_ONE, to);
727         ClientInit_misc(this);
728         MUTATOR_CALLHOOK(Ent_Init);
729 }
730 void ClientInit_misc(entity this)
731 {
732         int channel = MSG_ONE;
733         WriteHeader(channel, ENT_CLIENT_INIT);
734         WriteByte(channel, g_nexball_meter_period * 32);
735         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
736         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
737         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
738         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
739         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
740         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
741         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
742         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
743
744         if(sv_foginterval && world.fog != "")
745                 WriteString(channel, world.fog);
746         else
747                 WriteString(channel, "");
748         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
749         WriteByte(channel, serverflags);
750         WriteCoord(channel, autocvar_g_trueaim_minrange);
751 }
752
753 void ClientInit_CheckUpdate(entity this)
754 {
755         this.nextthink = time;
756         if(this.count != autocvar_g_balance_armor_blockpercent)
757         {
758                 this.count = autocvar_g_balance_armor_blockpercent;
759                 this.SendFlags |= 1;
760         }
761 }
762
763 void ClientInit_Spawn()
764 {
765         entity e = new_pure(clientinit);
766         setthink(e, ClientInit_CheckUpdate);
767         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
768
769         ClientInit_CheckUpdate(e);
770 }
771
772 /*
773 =============
774 SetNewParms
775 =============
776 */
777 void SetNewParms ()
778 {
779         // initialize parms for a new player
780         parm1 = -(86400 * 366);
781
782         MUTATOR_CALLHOOK(SetNewParms);
783 }
784
785 /*
786 =============
787 SetChangeParms
788 =============
789 */
790 void SetChangeParms (entity this)
791 {
792         // save parms for level change
793         parm1 = this.parm_idlesince - time;
794
795         MUTATOR_CALLHOOK(SetChangeParms);
796 }
797
798 /*
799 =============
800 DecodeLevelParms
801 =============
802 */
803 void DecodeLevelParms(entity this)
804 {
805         // load parms
806         this.parm_idlesince = parm1;
807         if (this.parm_idlesince == -(86400 * 366))
808                 this.parm_idlesince = time;
809
810         // whatever happens, allow 60 seconds of idling directly after connect for map loading
811         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
812
813         MUTATOR_CALLHOOK(DecodeLevelParms);
814 }
815
816 /*
817 =============
818 ClientKill
819
820 Called when a client types 'kill' in the console
821 =============
822 */
823
824 .float clientkill_nexttime;
825 void ClientKill_Now_TeamChange(entity this)
826 {
827         if(this.killindicator_teamchange == -1)
828         {
829                 JoinBestTeam( this, false, true );
830         }
831         else if(this.killindicator_teamchange == -2)
832         {
833                 if(blockSpectators)
834                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
835                 PutObserverInServer(this);
836         }
837         else
838                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
839         this.killindicator_teamchange = 0;
840 }
841
842 void ClientKill_Now(entity this)
843 {
844         if(this.vehicle)
845         {
846             vehicles_exit(this.vehicle, VHEF_RELEASE);
847             if(!this.killindicator_teamchange)
848             {
849             this.vehicle_health = -1;
850             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
851             }
852         }
853
854         if(this.killindicator && !wasfreed(this.killindicator))
855                 delete(this.killindicator);
856
857         this.killindicator = NULL;
858
859         if(this.killindicator_teamchange)
860                 ClientKill_Now_TeamChange(this);
861
862         if(!IS_SPEC(this) && !IS_OBSERVER(this))
863                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
864
865         // now I am sure the player IS dead
866 }
867 void KillIndicator_Think(entity this)
868 {
869         if (gameover)
870         {
871                 this.owner.killindicator = NULL;
872                 delete(this);
873                 return;
874         }
875
876         if (this.owner.alpha < 0 && !this.owner.vehicle)
877         {
878                 this.owner.killindicator = NULL;
879                 delete(this);
880                 return;
881         }
882
883         if(this.cnt <= 0)
884         {
885                 ClientKill_Now(this.owner);
886                 return;
887         }
888     else if(g_cts && this.health == 1) // health == 1 means that it's silent
889     {
890         this.nextthink = time + 1;
891         this.cnt -= 1;
892     }
893         else
894         {
895                 if(this.cnt <= 10)
896                         setmodel(this, MDL_NUM(this.cnt));
897                 if(IS_REAL_CLIENT(this.owner))
898                 {
899                         if(this.cnt <= 10)
900                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
901                 }
902                 this.nextthink = time + 1;
903                 this.cnt -= 1;
904         }
905 }
906
907 float clientkilltime;
908 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
909 {
910         float killtime;
911         float starttime;
912
913         if (gameover)
914                 return;
915
916         killtime = autocvar_g_balance_kill_delay;
917
918         if(g_race_qualifying || g_cts)
919                 killtime = 0;
920
921     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
922         return;
923
924         this.killindicator_teamchange = targetteam;
925
926     if(!this.killindicator)
927         {
928                 if(!IS_DEAD(this))
929                 {
930                         killtime = max(killtime, this.clientkill_nexttime - time);
931                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
932                 }
933
934                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
935                 {
936                         ClientKill_Now(this);
937                 }
938                 else
939                 {
940                         starttime = max(time, clientkilltime);
941
942                         this.killindicator = spawn();
943                         this.killindicator.owner = this;
944                         this.killindicator.scale = 0.5;
945                         setattachment(this.killindicator, this, "");
946                         setorigin(this.killindicator, '0 0 52');
947                         setthink(this.killindicator, KillIndicator_Think);
948                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
949                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
950                         this.killindicator.cnt = ceil(killtime);
951                         this.killindicator.count = bound(0, ceil(killtime), 10);
952                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
953
954                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
955                         {
956                                 it.killindicator = spawn();
957                                 it.killindicator.owner = it;
958                                 it.killindicator.scale = 0.5;
959                                 setattachment(it.killindicator, it, "");
960                                 setorigin(it.killindicator, '0 0 52');
961                                 setthink(it.killindicator, KillIndicator_Think);
962                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
963                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
964                                 it.killindicator.cnt = ceil(killtime);
965                         });
966                         this.lip = 0;
967                 }
968         }
969         if(this.killindicator)
970         {
971                 if(targetteam == 0) // just die
972                 {
973                         this.killindicator.colormod = '0 0 0';
974                         if(IS_REAL_CLIENT(this))
975                         if(this.killindicator.cnt > 0)
976                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
977                 }
978                 else if(targetteam == -1) // auto
979                 {
980                         this.killindicator.colormod = '0 1 0';
981                         if(IS_REAL_CLIENT(this))
982                         if(this.killindicator.cnt > 0)
983                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
984                 }
985                 else if(targetteam == -2) // spectate
986                 {
987                         this.killindicator.colormod = '0.5 0.5 0.5';
988                         if(IS_REAL_CLIENT(this))
989                         if(this.killindicator.cnt > 0)
990                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
991                 }
992                 else
993                 {
994                         this.killindicator.colormod = Team_ColorRGB(targetteam);
995                         if(IS_REAL_CLIENT(this))
996                         if(this.killindicator.cnt > 0)
997                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
998                 }
999         }
1000
1001 }
1002
1003 void ClientKill (entity this)
1004 {
1005         if(gameover) return;
1006         if(this.player_blocked) return;
1007         if(STAT(FROZEN, this)) return;
1008
1009         ClientKill_TeamChange(this, 0);
1010 }
1011
1012 void FixClientCvars(entity e)
1013 {
1014         // send prediction settings to the client
1015         stuffcmd(e, "\nin_bindmap 0 0\n");
1016         if(autocvar_g_antilag == 3) // client side hitscan
1017                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1018         if(autocvar_sv_gentle)
1019                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1020
1021         MUTATOR_CALLHOOK(FixClientCvars, e);
1022 }
1023
1024 float PlayerInIDList(entity p, string idlist)
1025 {
1026         float n, i;
1027         string s;
1028
1029         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1030         if (!p.crypto_idfp)
1031                 return 0;
1032
1033         // this function allows abbreviated player IDs too!
1034         n = tokenize_console(idlist);
1035         for(i = 0; i < n; ++i)
1036         {
1037                 s = argv(i);
1038                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1039                         return 1;
1040         }
1041
1042         return 0;
1043 }
1044
1045 #ifdef DP_EXT_PRECONNECT
1046 /*
1047 =============
1048 ClientPreConnect
1049
1050 Called once (not at each match start) when a client begins a connection to the server
1051 =============
1052 */
1053 void ClientPreConnect ()
1054 {ENGINE_EVENT();
1055         if(autocvar_sv_eventlog)
1056         {
1057                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1058                         this.playerid,
1059                         etof(this),
1060                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1061                 ));
1062         }
1063 }
1064 #endif
1065
1066 /**
1067 =============
1068 ClientConnect
1069
1070 Called when a client connects to the server
1071 =============
1072 */
1073 void ClientConnect(entity this)
1074 {
1075         if (Ban_MaybeEnforceBanOnce(this)) return;
1076         assert(!IS_CLIENT(this), return);
1077         this.flags |= FL_CLIENT;
1078         assert(player_count >= 0, player_count = 0);
1079
1080 #ifdef WATERMARK
1081         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1082 #endif
1083         this.version_nagtime = time + 10 + random() * 10;
1084         TRANSMUTE(Client, this);
1085
1086         // identify the right forced team
1087         if (autocvar_g_campaign)
1088         {
1089                 if (IS_REAL_CLIENT(this)) // only players, not bots
1090                 {
1091                         switch (autocvar_g_campaign_forceteam)
1092                         {
1093                                 case 1: this.team_forced = NUM_TEAM_1; break;
1094                                 case 2: this.team_forced = NUM_TEAM_2; break;
1095                                 case 3: this.team_forced = NUM_TEAM_3; break;
1096                                 case 4: this.team_forced = NUM_TEAM_4; break;
1097                                 default: this.team_forced = 0;
1098                         }
1099                 }
1100         }
1101         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1102         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1103         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1104         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1105         else switch (autocvar_g_forced_team_otherwise)
1106         {
1107                 default: this.team_forced = 0; break;
1108                 case "red": this.team_forced = NUM_TEAM_1; break;
1109                 case "blue": this.team_forced = NUM_TEAM_2; break;
1110                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1111                 case "pink": this.team_forced = NUM_TEAM_4; break;
1112                 case "spectate":
1113                 case "spectator":
1114                         this.team_forced = -1;
1115                         break;
1116         }
1117         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1118
1119     {
1120         int id = this.playerid;
1121         this.playerid = 0; // silent
1122             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1123             this.playerid = id;
1124     }
1125
1126         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1127                 TRANSMUTE(Observer, this);
1128         } else {
1129                 if (!teamplay || autocvar_g_balance_teams) {
1130                         TRANSMUTE(Player, this);
1131                         campaign_bots_may_start = true;
1132                 } else {
1133                         TRANSMUTE(Observer, this); // do it anyway
1134                 }
1135         }
1136
1137         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1138
1139         // always track bots, don't ask for cl_allow_uidtracking
1140     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1141
1142         if (autocvar_sv_eventlog)
1143                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1144
1145         LogTeamchange(this.playerid, this.team, 1);
1146
1147         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1148
1149         this.netname_previous = strzone(this.netname);
1150
1151         if(teamplay && IS_PLAYER(this))
1152                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1153         else
1154                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1155
1156         stuffcmd(this, clientstuff, "\n");
1157         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1158
1159         FixClientCvars(this);
1160
1161         // get version info from player
1162         stuffcmd(this, "cmd clientversion $gameversion\n");
1163
1164         // notify about available teams
1165         if (teamplay)
1166         {
1167                 CheckAllowedTeams(this);
1168                 int t = 0;
1169                 if (c1 >= 0) t |= BIT(0);
1170                 if (c2 >= 0) t |= BIT(1);
1171                 if (c3 >= 0) t |= BIT(2);
1172                 if (c4 >= 0) t |= BIT(3);
1173                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1174         }
1175         else
1176         {
1177                 stuffcmd(this, "set _teams_available 0\n");
1178         }
1179
1180         bot_relinkplayerlist();
1181
1182         this.spectatortime = time;
1183         if (blockSpectators)
1184         {
1185                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1186         }
1187
1188         this.jointime = time;
1189         this.allowed_timeouts = autocvar_sv_timeout_number;
1190
1191         if (IS_REAL_CLIENT(this))
1192         {
1193                 if (!autocvar_g_campaign)
1194                 {
1195                         this.motd_actived_time = -1;
1196                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1197                 }
1198
1199                 if (g_weaponarena_weapons == WEPSET(TUBA))
1200                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1201         }
1202
1203         if (!sv_foginterval && world.fog != "")
1204                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1205
1206         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1207                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1208                         send_CSQC_teamnagger();
1209
1210         CSQCMODEL_AUTOINIT(this);
1211
1212         this.model_randomizer = random();
1213
1214         if (IS_REAL_CLIENT(this))
1215                 sv_notice_join(this);
1216
1217         // update physics stats (players can spawn before physics runs)
1218         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1219
1220         IL_EACH(g_initforplayer, it.init_for_player, {
1221                 it.init_for_player(it, this);
1222         });
1223
1224         MUTATOR_CALLHOOK(ClientConnect, this);
1225 }
1226 /*
1227 =============
1228 ClientDisconnect
1229
1230 Called when a client disconnects from the server
1231 =============
1232 */
1233 .entity chatbubbleentity;
1234 void ReadyCount();
1235 void ClientDisconnect(entity this)
1236 {
1237         assert(IS_CLIENT(this), return);
1238
1239         PlayerStats_GameReport_FinalizePlayer(this);
1240         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1241         if (this.active_minigame) part_minigame(this);
1242         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1243
1244         if (autocvar_sv_eventlog)
1245                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1246
1247         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1248
1249         SetSpectatee(this, NULL);
1250
1251     MUTATOR_CALLHOOK(ClientDisconnect, this);
1252
1253         ClientState_detach(this);
1254
1255         Portal_ClearAll(this);
1256
1257         Unfreeze(this);
1258
1259         RemoveGrapplingHook(this);
1260
1261         // Here, everything has been done that requires this player to be a client.
1262
1263         this.flags &= ~FL_CLIENT;
1264
1265         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1266         if (this.killindicator) delete(this.killindicator);
1267
1268         WaypointSprite_PlayerGone(this);
1269
1270         bot_relinkplayerlist();
1271
1272         if (this.netname_previous) strunzone(this.netname_previous);
1273         if (this.clientstatus) strunzone(this.clientstatus);
1274         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1275         if (this.personal) delete(this.personal);
1276
1277         this.playerid = 0;
1278         ReadyCount();
1279         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1280
1281         ONREMOVE(this);
1282 }
1283
1284 void ChatBubbleThink(entity this)
1285 {
1286         this.nextthink = time;
1287         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1288         {
1289                 if(this.owner) // but why can that ever be NULL?
1290                         this.owner.chatbubbleentity = NULL;
1291                 delete(this);
1292                 return;
1293         }
1294
1295         this.mdl = "";
1296
1297         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1298         {
1299                 if ( this.owner.active_minigame )
1300                         this.mdl = "models/sprites/minigame_busy.iqm";
1301                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1302                         this.mdl = "models/misc/chatbubble.spr";
1303         }
1304
1305         if ( this.model != this.mdl )
1306                 _setmodel(this, this.mdl);
1307
1308 }
1309
1310 void UpdateChatBubble(entity this)
1311 {
1312         if (this.alpha < 0)
1313                 return;
1314         // spawn a chatbubble entity if needed
1315         if (!this.chatbubbleentity)
1316         {
1317                 this.chatbubbleentity = new(chatbubbleentity);
1318                 this.chatbubbleentity.owner = this;
1319                 this.chatbubbleentity.exteriormodeltoclient = this;
1320                 setthink(this.chatbubbleentity, ChatBubbleThink);
1321                 this.chatbubbleentity.nextthink = time;
1322                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1323                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1324                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1325                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1326                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1327                 //this.chatbubbleentity.model = "";
1328                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1329         }
1330 }
1331
1332
1333 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1334 // added to the model skins
1335 /*void UpdateColorModHack()
1336 {
1337         float c;
1338         c = this.clientcolors & 15;
1339         // LordHavoc: only bothering to support white, green, red, yellow, blue
1340              if (!teamplay) this.colormod = '0 0 0';
1341         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1342         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1343         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1344         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1345         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1346         else this.colormod = '1 1 1';
1347 }*/
1348
1349 void respawn(entity this)
1350 {
1351         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1352         {
1353                 this.solid = SOLID_NOT;
1354                 this.takedamage = DAMAGE_NO;
1355                 set_movetype(this, MOVETYPE_FLY);
1356                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1357                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1358                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1359                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1360                 if(autocvar_g_respawn_ghosts_maxtime)
1361                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1362         }
1363
1364         CopyBody(this, 1);
1365
1366         this.effects |= EF_NODRAW; // prevent another CopyBody
1367         PutClientInServer(this);
1368 }
1369
1370 void play_countdown(entity this, float finished, Sound samp)
1371 {
1372     TC(Sound, samp);
1373         if(IS_REAL_CLIENT(this))
1374                 if(floor(finished - time - frametime) != floor(finished - time))
1375                         if(finished - time < 6)
1376                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1377 }
1378
1379 void player_powerups(entity this)
1380 {
1381         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1382         int items_prev = this.items;
1383
1384         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1385                 this.modelflags |= MF_ROCKET;
1386         else
1387                 this.modelflags &= ~MF_ROCKET;
1388
1389         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1390
1391         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1392                 return;
1393
1394         Fire_ApplyDamage(this);
1395         Fire_ApplyEffect(this);
1396
1397         if (!g_instagib)
1398         {
1399                 if (this.items & ITEM_Strength.m_itemid)
1400                 {
1401                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1402                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1403                         if (time > this.strength_finished)
1404                         {
1405                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1406                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1407                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1408                         }
1409                 }
1410                 else
1411                 {
1412                         if (time < this.strength_finished)
1413                         {
1414                                 this.items = this.items | ITEM_Strength.m_itemid;
1415                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1416                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1417                         }
1418                 }
1419                 if (this.items & ITEM_Shield.m_itemid)
1420                 {
1421                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1422                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1423                         if (time > this.invincible_finished)
1424                         {
1425                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1426                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1427                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1428                         }
1429                 }
1430                 else
1431                 {
1432                         if (time < this.invincible_finished)
1433                         {
1434                                 this.items = this.items | ITEM_Shield.m_itemid;
1435                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1437                         }
1438                 }
1439                 if (this.items & IT_SUPERWEAPON)
1440                 {
1441                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1442                         {
1443                                 this.superweapons_finished = 0;
1444                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1445                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1447                         }
1448                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1449                         {
1450                                 // don't let them run out
1451                         }
1452                         else
1453                         {
1454                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1455                                 if (time > this.superweapons_finished)
1456                                 {
1457                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1458                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1459                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1460                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1461                                 }
1462                         }
1463                 }
1464                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1465                 {
1466                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1467                         {
1468                                 this.items = this.items | IT_SUPERWEAPON;
1469                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1470                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1471                         }
1472                         else
1473                         {
1474                                 this.superweapons_finished = 0;
1475                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1476                         }
1477                 }
1478                 else
1479                 {
1480                         this.superweapons_finished = 0;
1481                 }
1482         }
1483
1484         if(autocvar_g_nodepthtestplayers)
1485                 this.effects = this.effects | EF_NODEPTHTEST;
1486
1487         if(autocvar_g_fullbrightplayers)
1488                 this.effects = this.effects | EF_FULLBRIGHT;
1489
1490         if (time >= game_starttime)
1491         if (time < this.spawnshieldtime)
1492                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1493
1494         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1495 }
1496
1497 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1498 {
1499         if(current > stable)
1500                 return current;
1501         else if(current > stable - 0.25) // when close enough, "snap"
1502                 return stable;
1503         else
1504                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1505 }
1506
1507 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1508 {
1509         if(current < stable)
1510                 return current;
1511         else if(current < stable + 0.25) // when close enough, "snap"
1512                 return stable;
1513         else
1514                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1515 }
1516
1517 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1518 {
1519         if(current > rotstable)
1520         {
1521                 if(rotframetime > 0)
1522                 {
1523                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1524                         current = max(rotstable, current - rotlinear * rotframetime);
1525                 }
1526         }
1527         else if(current < regenstable)
1528         {
1529                 if(regenframetime > 0)
1530                 {
1531                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1532                         current = min(regenstable, current + regenlinear * regenframetime);
1533                 }
1534         }
1535
1536         if(current > limit)
1537                 current = limit;
1538
1539         return current;
1540 }
1541
1542 void player_regen(entity this)
1543 {
1544         float max_mod, regen_mod, rot_mod, limit_mod;
1545         max_mod = regen_mod = rot_mod = limit_mod = 1;
1546
1547         float regen_health = autocvar_g_balance_health_regen;
1548         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1549         float regen_health_rot = autocvar_g_balance_health_rot;
1550         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1551         float regen_health_stable = autocvar_g_balance_health_regenstable;
1552         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1553         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1554                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1555         max_mod = M_ARGV(1, float);
1556         regen_mod = M_ARGV(2, float);
1557         rot_mod = M_ARGV(3, float);
1558         limit_mod = M_ARGV(4, float);
1559         regen_health = M_ARGV(5, float);
1560         regen_health_linear = M_ARGV(6, float);
1561         regen_health_rot = M_ARGV(7, float);
1562         regen_health_rotlinear = M_ARGV(8, float);
1563         regen_health_stable = M_ARGV(9, float);
1564         regen_health_rotstable = M_ARGV(10, float);
1565
1566
1567         if(!mutator_returnvalue)
1568         if(!STAT(FROZEN, this))
1569         {
1570                 float mina, maxa, limith, limita;
1571                 maxa = autocvar_g_balance_armor_rotstable;
1572                 mina = autocvar_g_balance_armor_regenstable;
1573                 limith = autocvar_g_balance_health_limit;
1574                 limita = autocvar_g_balance_armor_limit;
1575
1576                 regen_health_rotstable = regen_health_rotstable * max_mod;
1577                 regen_health_stable = regen_health_stable * max_mod;
1578                 limith = limith * limit_mod;
1579                 limita = limita * limit_mod;
1580
1581                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1582                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1583         }
1584
1585         // if player rotted to death...  die!
1586         // check this outside above checks, as player may still be able to rot to death
1587         if(this.health < 1)
1588         {
1589                 if(this.vehicle)
1590                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1591                 if(this.event_damage)
1592                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1593         }
1594
1595         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1596         {
1597                 float minf, maxf, limitf;
1598
1599                 maxf = autocvar_g_balance_fuel_rotstable;
1600                 minf = autocvar_g_balance_fuel_regenstable;
1601                 limitf = autocvar_g_balance_fuel_limit;
1602
1603                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1604         }
1605 }
1606
1607 bool zoomstate_set;
1608 void SetZoomState(entity this, float newzoom)
1609 {
1610         if(newzoom != this.zoomstate)
1611         {
1612                 this.zoomstate = newzoom;
1613                 ClientData_Touch(this);
1614         }
1615         zoomstate_set = true;
1616 }
1617
1618 void GetPressedKeys(entity this)
1619 {
1620         MUTATOR_CALLHOOK(GetPressedKeys, this);
1621         int keys = STAT(PRESSED_KEYS, this);
1622         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1623         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1624         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1625         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1626
1627         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1628         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1629         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1630         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1631         this.pressedkeys = keys; // store for other users
1632
1633         STAT(PRESSED_KEYS, this) = keys;
1634 }
1635
1636 /*
1637 ======================
1638 spectate mode routines
1639 ======================
1640 */
1641
1642 void SpectateCopy(entity this, entity spectatee)
1643 {
1644     TC(Client, this); TC(Client, spectatee);
1645
1646         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1647         PS(this) = PS(spectatee);
1648         this.armortype = spectatee.armortype;
1649         this.armorvalue = spectatee.armorvalue;
1650         this.ammo_cells = spectatee.ammo_cells;
1651         this.ammo_plasma = spectatee.ammo_plasma;
1652         this.ammo_shells = spectatee.ammo_shells;
1653         this.ammo_nails = spectatee.ammo_nails;
1654         this.ammo_rockets = spectatee.ammo_rockets;
1655         this.ammo_fuel = spectatee.ammo_fuel;
1656         this.clip_load = spectatee.clip_load;
1657         this.clip_size = spectatee.clip_size;
1658         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1659         this.health = spectatee.health;
1660         this.impulse = 0;
1661         this.items = spectatee.items;
1662         this.last_pickup = spectatee.last_pickup;
1663         this.hit_time = spectatee.hit_time;
1664         this.strength_finished = spectatee.strength_finished;
1665         this.invincible_finished = spectatee.invincible_finished;
1666         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1667         this.weapons = spectatee.weapons;
1668         this.vortex_charge = spectatee.vortex_charge;
1669         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1670         this.hagar_load = spectatee.hagar_load;
1671         this.arc_heat_percent = spectatee.arc_heat_percent;
1672         this.minelayer_mines = spectatee.minelayer_mines;
1673         this.punchangle = spectatee.punchangle;
1674         this.view_ofs = spectatee.view_ofs;
1675         this.velocity = spectatee.velocity;
1676         this.dmg_take = spectatee.dmg_take;
1677         this.dmg_save = spectatee.dmg_save;
1678         this.dmg_inflictor = spectatee.dmg_inflictor;
1679         this.v_angle = spectatee.v_angle;
1680         this.angles = spectatee.v_angle;
1681         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1682         this.revive_progress = spectatee.revive_progress;
1683         this.viewloc = spectatee.viewloc;
1684         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1685                 this.fixangle = true;
1686         setorigin(this, spectatee.origin);
1687         setsize(this, spectatee.mins, spectatee.maxs);
1688         SetZoomState(this, spectatee.zoomstate);
1689
1690     anticheat_spectatecopy(this, spectatee);
1691         this.hud = spectatee.hud;
1692         if(spectatee.vehicle)
1693     {
1694         this.angles = spectatee.v_angle;
1695
1696         //this.fixangle = false;
1697         //this.velocity = spectatee.vehicle.velocity;
1698         this.vehicle_health = spectatee.vehicle_health;
1699         this.vehicle_shield = spectatee.vehicle_shield;
1700         this.vehicle_energy = spectatee.vehicle_energy;
1701         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1702         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1703         this.vehicle_reload1 = spectatee.vehicle_reload1;
1704         this.vehicle_reload2 = spectatee.vehicle_reload2;
1705
1706         //msg_entity = this;
1707
1708        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1709             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1710            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1711            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1712
1713         //WriteByte (MSG_ONE, SVC_SETVIEW);
1714         //    WriteEntity(MSG_ONE, this);
1715         //makevectors(spectatee.v_angle);
1716         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1717     }
1718 }
1719
1720 bool SpectateUpdate(entity this)
1721 {
1722         if(!this.enemy)
1723                 return false;
1724
1725         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1726         {
1727                 SetSpectatee(this, NULL);
1728                 return false;
1729         }
1730
1731         SpectateCopy(this, this.enemy);
1732
1733         return true;
1734 }
1735
1736 bool SpectateSet(entity this)
1737 {
1738         if(!IS_PLAYER(this.enemy))
1739                 return false;
1740
1741         ClientData_Touch(this.enemy);
1742
1743         msg_entity = this;
1744         WriteByte(MSG_ONE, SVC_SETVIEW);
1745         WriteEntity(MSG_ONE, this.enemy);
1746         set_movetype(this, MOVETYPE_NONE);
1747         accuracy_resend(this);
1748
1749         if(!SpectateUpdate(this))
1750                 PutObserverInServer(this);
1751
1752         return true;
1753 }
1754
1755 void SetSpectatee_status(entity this, int spectatee_num)
1756 {
1757         int oldspectatee_status = this.spectatee_status;
1758         this.spectatee_status = spectatee_num;
1759
1760         if (this.spectatee_status != oldspectatee_status)
1761         {
1762                 ClientData_Touch(this);
1763                 if (g_race || g_cts) race_InitSpectator();
1764         }
1765 }
1766
1767 void SetSpectatee(entity this, entity spectatee)
1768 {
1769         entity old_spectatee = this.enemy;
1770
1771         this.enemy = spectatee;
1772
1773         // WEAPONTODO
1774         // these are required to fix the spectator bug with arc
1775         if(old_spectatee)
1776         {
1777                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1778                 {
1779                         .entity weaponentity = weaponentities[slot];
1780                         if(old_spectatee.(weaponentity).arc_beam)
1781                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1782                 }
1783         }
1784         if(this.enemy)
1785         {
1786                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1787                 {
1788                         .entity weaponentity = weaponentities[slot];
1789                         if(this.enemy.(weaponentity).arc_beam)
1790                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1791                 }
1792         }
1793
1794         if (this.enemy)
1795                 SetSpectatee_status(this, etof(this.enemy));
1796
1797         // needed to update spectator list
1798         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1799 }
1800
1801 bool Spectate(entity this, entity pl)
1802 {
1803         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1804                 return false;
1805         pl = M_ARGV(1, entity);
1806
1807         SetSpectatee(this, pl);
1808         return SpectateSet(this);
1809 }
1810
1811 bool SpectateNext(entity this)
1812 {
1813         entity ent = find(this.enemy, classname, STR_PLAYER);
1814
1815         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1816                 ent = M_ARGV(1, entity);
1817         else if (!ent)
1818                 ent = find(ent, classname, STR_PLAYER);
1819
1820         if(ent) { SetSpectatee(this, ent); }
1821
1822         return SpectateSet(this);
1823 }
1824
1825 bool SpectatePrev(entity this)
1826 {
1827         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1828         entity ent = findchain(classname, STR_PLAYER);
1829         if (!ent) // no player
1830                 return false;
1831
1832         entity first = ent;
1833         // skip players until current spectated player
1834         if(this.enemy)
1835         while(ent && ent != this.enemy)
1836                 ent = ent.chain;
1837
1838         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1839         {
1840                 case MUT_SPECPREV_FOUND:
1841                     ent = M_ARGV(1, entity);
1842                     break;
1843                 case MUT_SPECPREV_RETURN:
1844                     return true;
1845                 case MUT_SPECPREV_CONTINUE:
1846                 default:
1847                 {
1848                         if(ent.chain)
1849                                 ent = ent.chain;
1850                         else
1851                                 ent = first;
1852                         break;
1853                 }
1854         }
1855
1856         SetSpectatee(this, ent);
1857         return SpectateSet(this);
1858 }
1859
1860 /*
1861 =============
1862 ShowRespawnCountdown()
1863
1864 Update a respawn countdown display.
1865 =============
1866 */
1867 void ShowRespawnCountdown(entity this)
1868 {
1869         float number;
1870         if(!IS_DEAD(this)) // just respawned?
1871                 return;
1872         else
1873         {
1874                 number = ceil(this.respawn_time - time);
1875                 if(number <= 0)
1876                         return;
1877                 if(number <= this.respawn_countdown)
1878                 {
1879                         this.respawn_countdown = number - 1;
1880                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1881                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1882                 }
1883         }
1884 }
1885
1886 .bool team_selected;
1887 bool ShowTeamSelection(entity this)
1888 {
1889         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1890                 return false;
1891         stuffcmd(this, "menu_showteamselect\n");
1892         return true;
1893 }
1894 void Join(entity this)
1895 {
1896         TRANSMUTE(Player, this);
1897
1898         if(!this.team_selected)
1899         if(autocvar_g_campaign || autocvar_g_balance_teams)
1900                 JoinBestTeam(this, false, true);
1901
1902         if(autocvar_g_campaign)
1903                 campaign_bots_may_start = true;
1904
1905         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1906
1907         PutClientInServer(this);
1908
1909         if(teamplay && this.team != -1)
1910                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1911         else
1912                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1913         this.team_selected = false;
1914 }
1915
1916 /**
1917  * Determines whether the player is allowed to join. This depends on cvar
1918  * g_maxplayers, if it isn't used this function always return true, otherwise
1919  * it checks whether the number of currently playing players exceeds g_maxplayers.
1920  * @return int number of free slots for players, 0 if none
1921  */
1922 int nJoinAllowed(entity this, entity ignore)
1923 {
1924         if(!ignore)
1925         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1926         // so report 0 free slots if restricted
1927         {
1928                 if(autocvar_g_forced_team_otherwise == "spectate")
1929                         return 0;
1930                 if(autocvar_g_forced_team_otherwise == "spectator")
1931                         return 0;
1932         }
1933
1934         if(this && this.team_forced < 0)
1935                 return 0; // forced spectators can never join
1936
1937         // TODO simplify this
1938         int totalClients = 0;
1939         int currentlyPlaying = 0;
1940         FOREACH_CLIENT(true, LAMBDA(
1941                 if(it != ignore)
1942                         ++totalClients;
1943                 if(IS_REAL_CLIENT(it))
1944                 if(IS_PLAYER(it) || it.caplayer)
1945                         ++currentlyPlaying;
1946         ));
1947
1948         float free_slots = 0;
1949         if (!autocvar_g_maxplayers)
1950                 free_slots = maxclients - totalClients;
1951         else if(currentlyPlaying < autocvar_g_maxplayers)
1952                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1953
1954         static float join_prevent_msg_time = 0;
1955         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1956         {
1957                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1958                 join_prevent_msg_time = time + 3;
1959         }
1960
1961         return free_slots;
1962 }
1963
1964 /**
1965  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1966  * g_maxplayers_spectator_blocktime seconds
1967  */
1968 void checkSpectatorBlock(entity this)
1969 {
1970         if(IS_SPEC(this) || IS_OBSERVER(this))
1971         if(!this.caplayer)
1972         if(IS_REAL_CLIENT(this))
1973         {
1974                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1975                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1976                         dropclient(this);
1977                 }
1978         }
1979 }
1980
1981 void PrintWelcomeMessage(entity this)
1982 {
1983         if(this.motd_actived_time == 0)
1984         {
1985                 if (autocvar_g_campaign) {
1986                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1987                                 this.motd_actived_time = time;
1988                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1989                         }
1990                 } else {
1991                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1992                                 this.motd_actived_time = time;
1993                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1994                         }
1995                 }
1996         }
1997         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if (PHYS_INPUT_BUTTON_INFO(this))
2001                                 this.motd_actived_time = time;
2002                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2003                                 this.motd_actived_time = 0;
2004                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2005                         }
2006                 } else {
2007                         if (PHYS_INPUT_BUTTON_INFO(this))
2008                                 this.motd_actived_time = time;
2009                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2010                                 this.motd_actived_time = 0;
2011                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2012                         }
2013                 }
2014         }
2015         else //if(this.motd_actived_time < 0) // just connected, motd is active
2016         {
2017                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2018                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2019                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2020                 {
2021                         // instanctly hide MOTD
2022                         this.motd_actived_time = 0;
2023                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2024                 }
2025         }
2026 }
2027
2028 bool joinAllowed(entity this)
2029 {
2030         if (this.version_mismatch) return false;
2031         if (!nJoinAllowed(this, this)) return false;
2032         if (teamplay && lockteams) return false;
2033         if (ShowTeamSelection(this)) return false;
2034         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2035         return true;
2036 }
2037
2038 void ObserverThink(entity this)
2039 {
2040         if ( this.impulse )
2041         {
2042                 MinigameImpulse(this, this.impulse);
2043                 this.impulse = 0;
2044         }
2045
2046         if (this.flags & FL_JUMPRELEASED) {
2047                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2048                         this.flags &= ~FL_JUMPRELEASED;
2049                         this.flags |= FL_SPAWNING;
2050                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2051                         this.flags &= ~FL_JUMPRELEASED;
2052                         if(SpectateNext(this)) {
2053                                 TRANSMUTE(Spectator, this);
2054                         }
2055                 } else {
2056                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2057                         set_movetype(this, preferred_movetype);
2058                 }
2059         } else {
2060                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2061                         this.flags |= FL_JUMPRELEASED;
2062                         if(this.flags & FL_SPAWNING)
2063                         {
2064                                 this.flags &= ~FL_SPAWNING;
2065                                 Join(this);
2066                                 return;
2067                         }
2068                 }
2069         }
2070 }
2071
2072 void SpectatorThink(entity this)
2073 {
2074         if ( this.impulse )
2075         {
2076                 if(MinigameImpulse(this, this.impulse))
2077                         this.impulse = 0;
2078
2079                 if (this.impulse == IMP_weapon_drop.impulse)
2080                 {
2081                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2082                         this.impulse = 0;
2083                         return;
2084                 }
2085         }
2086
2087         if (this.flags & FL_JUMPRELEASED) {
2088                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2089                         this.flags &= ~FL_JUMPRELEASED;
2090                         this.flags |= FL_SPAWNING;
2091                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2092                         this.flags &= ~FL_JUMPRELEASED;
2093                         if(SpectateNext(this)) {
2094                                 TRANSMUTE(Spectator, this);
2095                         } else {
2096                                 TRANSMUTE(Observer, this);
2097                                 PutClientInServer(this);
2098                         }
2099                         this.impulse = 0;
2100                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2101                         this.flags &= ~FL_JUMPRELEASED;
2102                         if(SpectatePrev(this)) {
2103                                 TRANSMUTE(Spectator, this);
2104                         } else {
2105                                 TRANSMUTE(Observer, this);
2106                                 PutClientInServer(this);
2107                         }
2108                         this.impulse = 0;
2109                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2110                         this.flags &= ~FL_JUMPRELEASED;
2111                         TRANSMUTE(Observer, this);
2112                         PutClientInServer(this);
2113                 } else {
2114                         if(!SpectateUpdate(this))
2115                                 PutObserverInServer(this);
2116                 }
2117         } else {
2118                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2119                         this.flags |= FL_JUMPRELEASED;
2120                         if(this.flags & FL_SPAWNING)
2121                         {
2122                                 this.flags &= ~FL_SPAWNING;
2123                                 Join(this);
2124                                 return;
2125                         }
2126                 }
2127                 if(!SpectateUpdate(this))
2128                         PutObserverInServer(this);
2129         }
2130
2131         this.flags |= FL_CLIENT | FL_NOTARGET;
2132 }
2133
2134 void vehicles_enter (entity pl, entity veh);
2135 void PlayerUseKey(entity this)
2136 {
2137         if (!IS_PLAYER(this))
2138                 return;
2139
2140         if(this.vehicle)
2141         {
2142                 if(!gameover)
2143                 {
2144                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2145                         return;
2146                 }
2147         }
2148         else if(autocvar_g_vehicles_enter)
2149         {
2150                 if(!STAT(FROZEN, this))
2151                 if(!IS_DEAD(this))
2152                 if(!gameover)
2153                 {
2154                         entity head, closest_target = NULL;
2155                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2156
2157                         while(head) // find the closest acceptable target to enter
2158                         {
2159                                 if(IS_VEHICLE(head))
2160                                 if(!IS_DEAD(head))
2161                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2162                                 if(head.takedamage != DAMAGE_NO)
2163                                 {
2164                                         if(closest_target)
2165                                         {
2166                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2167                                                 { closest_target = head; }
2168                                         }
2169                                         else { closest_target = head; }
2170                                 }
2171
2172                                 head = head.chain;
2173                         }
2174
2175                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2176                 }
2177         }
2178
2179         // a use key was pressed; call handlers
2180         MUTATOR_CALLHOOK(PlayerUseKey, this);
2181 }
2182
2183
2184 /*
2185 =============
2186 PlayerPreThink
2187
2188 Called every frame for each client before the physics are run
2189 =============
2190 */
2191 .float usekeypressed;
2192 .float last_vehiclecheck;
2193 .int items_added;
2194 void PlayerPreThink (entity this)
2195 {
2196         WarpZone_PlayerPhysics_FixVAngle(this);
2197
2198     STAT(GAMESTARTTIME, this) = game_starttime;
2199         STAT(ROUNDSTARTTIME, this) = round_starttime;
2200         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2201         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2202
2203         STAT(WEAPONSINMAP, this) = weaponsInMap;
2204
2205         if (frametime) {
2206                 // physics frames: update anticheat stuff
2207                 anticheat_prethink(this);
2208         }
2209
2210         if (blockSpectators && frametime) {
2211                 // WORKAROUND: only use dropclient in server frames (frametime set).
2212                 // Never use it in cl_movement frames (frametime zero).
2213                 checkSpectatorBlock(this);
2214     }
2215
2216         zoomstate_set = false;
2217
2218         // Check for nameless players
2219         if (isInvisibleString(this.netname)) {
2220                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2221                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2222         }
2223         if (this.netname != this.netname_previous) {
2224                 if (autocvar_sv_eventlog) {
2225                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2226         }
2227                 if (this.netname_previous) strunzone(this.netname_previous);
2228                 this.netname_previous = strzone(this.netname);
2229         }
2230
2231         // version nagging
2232         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2233         this.version_nagtime = 0;
2234         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2235             // git client
2236         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2237             // git server
2238             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2239         } else {
2240             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2241             if (r < 0) { // old client
2242                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2243             } else if (r > 0) { // old server
2244                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2245             }
2246         }
2247     }
2248
2249         // GOD MODE info
2250         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2251         {
2252                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2253                 this.max_armorvalue = 0;
2254         }
2255
2256         if (STAT(FROZEN, this) == 2)
2257         {
2258                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2259                 this.health = max(1, this.revive_progress * start_health);
2260                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2261
2262                 if (this.revive_progress >= 1)
2263                         Unfreeze(this);
2264         }
2265         else if (STAT(FROZEN, this) == 3)
2266         {
2267                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2268                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2269
2270                 if (this.health < 1)
2271                 {
2272                         if (this.vehicle)
2273                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2274                         if(this.event_damage)
2275                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2276                 }
2277                 else if (this.revive_progress <= 0)
2278                         Unfreeze(this);
2279         }
2280
2281         MUTATOR_CALLHOOK(PlayerPreThink, this);
2282
2283         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2284         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2285         {
2286                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2287                 {
2288                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2289                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2290                         {
2291                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2292                         }
2293                         else if(!it.owner)
2294                         {
2295                                 if(!it.team || SAME_TEAM(this, it))
2296                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2297                                 else if(autocvar_g_vehicles_steal)
2298                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2299                         }
2300                 });
2301
2302                 this.last_vehiclecheck = time + 1;
2303         }
2304
2305         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2306         {
2307                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2308                         PlayerUseKey(this);
2309                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2310         }
2311
2312         if (IS_REAL_CLIENT(this))
2313                 PrintWelcomeMessage(this);
2314
2315         if (IS_PLAYER(this)) {
2316                 CheckRules_Player(this);
2317
2318                 if (intermission_running) {
2319                         IntermissionThink(this);
2320                         return;
2321                 }
2322
2323                 if (timeout_status == TIMEOUT_ACTIVE) {
2324             // don't allow the player to turn around while game is paused
2325                         // FIXME turn this into CSQC stuff
2326                         this.v_angle = this.lastV_angle;
2327                         this.angles = this.lastV_angle;
2328                         this.fixangle = true;
2329                 }
2330
2331                 if (frametime) player_powerups(this);
2332
2333                 if (IS_DEAD(this)) {
2334                         if (this.personal && g_race_qualifying) {
2335                                 if (time > this.respawn_time) {
2336                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2337                                         respawn(this);
2338                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2339                                 }
2340                         } else {
2341                                 if (frametime) player_anim(this);
2342                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2343
2344                                 switch(this.deadflag)
2345                                 {
2346                                         case DEAD_DYING:
2347                                         {
2348                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2349                                                         this.deadflag = DEAD_RESPAWNING;
2350                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2351                                                         this.deadflag = DEAD_DEAD;
2352                                                 break;
2353                                         }
2354                                         case DEAD_DEAD:
2355                                         {
2356                                                 if (button_pressed)
2357                                                         this.deadflag = DEAD_RESPAWNABLE;
2358                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2359                                                         this.deadflag = DEAD_RESPAWNING;
2360                                                 break;
2361                                         }
2362                                         case DEAD_RESPAWNABLE:
2363                                         {
2364                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2365                                                         this.deadflag = DEAD_RESPAWNING;
2366                                                 break;
2367                                         }
2368                                         case DEAD_RESPAWNING:
2369                                         {
2370                                                 if (time > this.respawn_time)
2371                                                 {
2372                                                         this.respawn_time = time + 1; // only retry once a second
2373                                                         this.respawn_time_max = this.respawn_time;
2374                                                         respawn(this);
2375                                                 }
2376                                                 break;
2377                                         }
2378                                 }
2379
2380                                 ShowRespawnCountdown(this);
2381
2382                                 if (this.respawn_flags & RESPAWN_SILENT)
2383                                         STAT(RESPAWN_TIME, this) = 0;
2384                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2385                                 {
2386                                         if (time < this.respawn_time)
2387                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2388                                         else if (this.deadflag != DEAD_RESPAWNING)
2389                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2390                                 }
2391                                 else
2392                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2393                         }
2394
2395                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2396                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2397                                 STAT(RESPAWN_TIME, this) *= -1;
2398
2399                         return;
2400                 }
2401
2402                 this.prevorigin = this.origin;
2403
2404                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2405                 if (this.hook.state) {
2406                         do_crouch = false;
2407                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2408                         do_crouch = false;
2409                 } else if (this.vehicle) {
2410                         do_crouch = false;
2411                 } else if (STAT(FROZEN, this)) {
2412                         do_crouch = false;
2413         }
2414
2415                 if (do_crouch) {
2416                         if (!this.crouch) {
2417                                 this.crouch = true;
2418                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2419                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2420                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2421                         }
2422                 } else if (this.crouch) {
2423             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2424             if (!trace_startsolid) {
2425                 this.crouch = false;
2426                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2427                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2428             }
2429                 }
2430
2431                 FixPlayermodel(this);
2432
2433                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2434                 //if(frametime)
2435                 {
2436                         this.items &= ~this.items_added;
2437
2438                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2439                         //{
2440                                 //.entity weaponentity = weaponentities[slot];
2441                                 //W_WeaponFrame(this, weaponentity);
2442                         //}
2443                         .entity weaponentity = weaponentities[0]; // TODO
2444                         W_WeaponFrame(this, weaponentity);
2445
2446                         this.items_added = 0;
2447                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2448                 this.items_added |= IT_FUEL;
2449
2450                         this.items |= this.items_added;
2451                 }
2452
2453                 player_regen(this);
2454
2455                 // WEAPONTODO: Add a weapon request for this
2456                 // rot vortex charge to the charge limit
2457                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2458                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2459
2460                 if (frametime) player_anim(this);
2461
2462                 // secret status
2463                 secrets_setstatus(this);
2464
2465                 // monsters status
2466                 monsters_setstatus(this);
2467
2468                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2469         }
2470         else if (gameover) {
2471                 if (intermission_running) IntermissionThink(this);
2472                 return;
2473         }
2474         else if (IS_OBSERVER(this)) {
2475                 ObserverThink(this);
2476         }
2477         else if (IS_SPEC(this)) {
2478                 SpectatorThink(this);
2479         }
2480
2481         // WEAPONTODO: Add weapon request for this
2482         if (!zoomstate_set) {
2483                 SetZoomState(this,
2484                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2485                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2486                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2487                 );
2488     }
2489
2490         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2491         {
2492                 this.teamkill_soundtime = 0;
2493
2494                 entity e = this.teamkill_soundsource;
2495                 entity oldpusher = e.pusher;
2496                 e.pusher = this;
2497                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2498                 e.pusher = oldpusher;
2499         }
2500
2501         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2502                 this.taunt_soundtime = 0;
2503                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2504         }
2505
2506         target_voicescript_next(this);
2507
2508         // WEAPONTODO: Move into weaponsystem somehow
2509         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2510         if (PS(this).m_weapon == WEP_Null)
2511                 this.clip_load = this.clip_size = 0;
2512 }
2513
2514 void DrownPlayer(entity this)
2515 {
2516         if(IS_DEAD(this))
2517                 return;
2518
2519         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2520         {
2521                 if(this.air_finished < time)
2522                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2523                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2524                 this.dmg = 2;
2525         }
2526         else if (this.air_finished < time)
2527         {       // drown!
2528                 if (this.pain_finished < time)
2529                 {
2530                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2531                         this.pain_finished = time + 0.5;
2532                 }
2533         }
2534 }
2535
2536 .bool move_qcphysics;
2537
2538 void Player_Physics(entity this)
2539 {
2540         set_movetype(this, this.move_movetype);
2541
2542         if(!this.move_qcphysics)
2543                 return;
2544
2545         if(!frametime && !this.pm_frametime)
2546                 return;
2547
2548         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2549
2550         this.pm_frametime = 0;
2551 }
2552
2553 /*
2554 =============
2555 PlayerPostThink
2556
2557 Called every frame for each client after the physics are run
2558 =============
2559 */
2560 .float idlekick_lasttimeleft;
2561 void PlayerPostThink (entity this)
2562 {
2563         Player_Physics(this);
2564
2565         if (sv_maxidle > 0)
2566         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2567         if (IS_REAL_CLIENT(this))
2568         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2569         {
2570                 int totalClients = 0;
2571                 if(sv_maxidle_slots > 0)
2572                 {
2573                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2574                         {
2575                                 ++totalClients;
2576                         });
2577                 }
2578
2579                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2580                 { /* do nothing */ }
2581                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2582                 {
2583                         if (this.idlekick_lasttimeleft)
2584                         {
2585                                 this.idlekick_lasttimeleft = 0;
2586                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2587                         }
2588                 }
2589                 else
2590                 {
2591                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2592                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2593                                 if (!this.idlekick_lasttimeleft)
2594                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2595                         }
2596                         if (timeleft <= 0) {
2597                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2598                                 dropclient(this);
2599                                 return;
2600                         }
2601                         else if (timeleft <= 10) {
2602                                 if (timeleft != this.idlekick_lasttimeleft) {
2603                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2604                 }
2605                                 this.idlekick_lasttimeleft = timeleft;
2606                         }
2607                 }
2608         }
2609
2610         CheatFrame(this);
2611
2612         //CheckPlayerJump();
2613
2614         if (IS_PLAYER(this)) {
2615                 DrownPlayer(this);
2616                 CheckRules_Player(this);
2617                 UpdateChatBubble(this);
2618                 if (this.impulse) ImpulseCommands(this);
2619                 if (intermission_running) return; // intermission or finale
2620                 GetPressedKeys(this);
2621         }
2622
2623         if (this.waypointsprite_attachedforcarrier) {
2624             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2625                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2626     }
2627
2628         playerdemo_write(this);
2629
2630         CSQCMODEL_AUTOUPDATE(this);
2631 }