Added random start weapons.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "playerdemo.qh"
14 #include "spawnpoints.qh"
15 #include "g_damage.qh"
16 #include "g_hook.qh"
17 #include "command/common.qh"
18 #include "cheats.qh"
19 #include "g_world.qh"
20 #include "race.qh"
21 #include "antilag.qh"
22 #include "campaign.qh"
23 #include "command/common.qh"
24 #include "scores_rules.qh"
25
26 #include "bot/api.qh"
27
28 #include "../common/ent_cs.qh"
29 #include "../common/wepent.qh"
30 #include <common/state.qh>
31
32 #include <common/effects/qc/globalsound.qh>
33
34 #include "../common/triggers/func/conveyor.qh"
35 #include "../common/triggers/teleporters.qh"
36
37 #include "../common/vehicles/all.qh"
38
39 #include "weapons/hitplot.qh"
40 #include "weapons/weaponsystem.qh"
41
42 #include "../common/net_notice.qh"
43 #include "../common/net_linked.qh"
44 #include "../common/physics/player.qh"
45
46 #include "../common/items/_mod.qh"
47
48 #include "../common/mutators/mutator/waypoints/all.qh"
49
50 #include "../common/triggers/subs.qh"
51 #include "../common/triggers/triggers.qh"
52 #include "../common/triggers/trigger/secret.qh"
53
54 #include "../common/minigames/sv_minigames.qh"
55
56 #include "../common/items/inventory.qh"
57
58 #include "../common/monsters/sv_monsters.qh"
59
60 #include "../lib/warpzone/server.qh"
61
62 STATIC_METHOD(Client, Add, void(Client this, int _team))
63 {
64     ClientConnect(this);
65     TRANSMUTE(Player, this);
66     this.frame = 12; // 7
67     this.team = _team;
68     PutClientInServer(this);
69 }
70
71 void PutObserverInServer(entity this);
72
73 STATIC_METHOD(Client, Remove, void(Client this))
74 {
75     TRANSMUTE(Observer, this);
76     PutClientInServer(this);
77     ClientDisconnect(this);
78 }
79
80 void send_CSQC_teamnagger() {
81         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
82 }
83
84 int CountSpectators(entity player, entity to)
85 {
86         if(!player) { return 0; } // not sure how, but best to be safe
87
88         int spec_count = 0;
89
90         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
91         {
92                 spec_count++;
93         });
94
95         return spec_count;
96 }
97
98 void WriteSpectators(entity player, entity to)
99 {
100         if(!player) { return; } // not sure how, but best to be safe
101
102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
103         {
104                 WriteByte(MSG_ENTITY, num_for_edict(it));
105         });
106 }
107
108 bool ClientData_Send(entity this, entity to, int sf)
109 {
110         assert(to == this.owner, return false);
111
112         entity e = to;
113         if (IS_SPEC(e)) e = e.enemy;
114
115         sf = 0;
116         if (CS(e).race_completed)       sf |= 1; // forced scoreboard
117         if (CS(to).spectatee_status)    sf |= 2; // spectator ent number follows
118         if (CS(e).zoomstate)            sf |= 4; // zoomed
119         if (autocvar_sv_showspectators) sf |= 16; // show spectators
120
121         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
122         WriteByte(MSG_ENTITY, sf);
123
124         if (sf & 2)
125         {
126                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
127         }
128
129         if(sf & 16)
130         {
131                 float specs = CountSpectators(e, to);
132                 WriteByte(MSG_ENTITY, specs);
133                 WriteSpectators(e, to);
134         }
135
136         return true;
137 }
138
139 void ClientData_Attach(entity this)
140 {
141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
142         CS(this).clientdata.drawonlytoclient = this;
143         CS(this).clientdata.owner = this;
144 }
145
146 void ClientData_Detach(entity this)
147 {
148         delete(CS(this).clientdata);
149         CS(this).clientdata = NULL;
150 }
151
152 void ClientData_Touch(entity e)
153 {
154         CS(e).clientdata.SendFlags = 1;
155
156         // make it spectatable
157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
158 }
159
160 void SetSpectatee(entity this, entity spectatee);
161 void SetSpectatee_status(entity this, int spectatee_num);
162
163
164 /*
165 =============
166 CheckPlayerModel
167
168 Checks if the argument string can be a valid playermodel.
169 Returns a valid one in doubt.
170 =============
171 */
172 string FallbackPlayerModel;
173 string CheckPlayerModel(string plyermodel) {
174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
175         {
176                 // note: we cannot summon Don Strunzone here, some player may
177                 // still have the model string set. In case anyone manages how
178                 // to change a cvar default, we'll have a small leak here.
179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
180         }
181         // only in right path
182         if( substring(plyermodel,0,14) != "models/player/")
183                 return FallbackPlayerModel;
184         // only good file extensions
185         if(substring(plyermodel,-4,4) != ".zym")
186         if(substring(plyermodel,-4,4) != ".dpm")
187         if(substring(plyermodel,-4,4) != ".iqm")
188         if(substring(plyermodel,-4,4) != ".md3")
189         if(substring(plyermodel,-4,4) != ".psk")
190                 return FallbackPlayerModel;
191         // forbid the LOD models
192         if(substring(plyermodel, -9,5) == "_lod1")
193                 return FallbackPlayerModel;
194         if(substring(plyermodel, -9,5) == "_lod2")
195                 return FallbackPlayerModel;
196         if(plyermodel != strtolower(plyermodel))
197                 return FallbackPlayerModel;
198         // also, restrict to server models
199         if(autocvar_sv_servermodelsonly)
200         {
201                 if(!fexists(plyermodel))
202                         return FallbackPlayerModel;
203         }
204         return plyermodel;
205 }
206
207 void setplayermodel(entity e, string modelname)
208 {
209         precache_model(modelname);
210         _setmodel(e, modelname);
211         player_setupanimsformodel(e);
212         if(!autocvar_g_debug_globalsounds)
213                 UpdatePlayerSounds(e);
214 }
215
216 void FixPlayermodel(entity player);
217 /** putting a client as observer in the server */
218 void PutObserverInServer(entity this)
219 {
220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
221         PlayerState_detach(this);
222
223         if (IS_PLAYER(this) && this.health >= 1) {
224         // despawn effect
225                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
226     }
227
228     {
229         entity spot = SelectSpawnPoint(this, true);
230         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
231         this.angles = vec2(spot.angles);
232         this.fixangle = true;
233         // offset it so that the spectator spawns higher off the ground, looks better this way
234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
235         if (IS_REAL_CLIENT(this))
236         {
237             msg_entity = this;
238             WriteByte(MSG_ONE, SVC_SETVIEW);
239             WriteEntity(MSG_ONE, this);
240         }
241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
243         if(!autocvar_g_debug_globalsounds)
244         {
245                 // needed for player sounds
246                 this.model = "";
247                 FixPlayermodel(this);
248         }
249         setmodel(this, MDL_Null);
250         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
251         this.view_ofs = '0 0 0';
252     }
253
254     RemoveGrapplingHooks(this);
255         Portal_ClearAll(this);
256         Unfreeze(this);
257         SetSpectatee(this, NULL);
258
259         if (this.alivetime)
260         {
261                 if (!warmup_stage)
262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
263                 this.alivetime = 0;
264         }
265
266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
267
268         WaypointSprite_PlayerDead(this);
269
270         if (mutator_returnvalue) {
271             // mutator prevents resetting teams+score
272         } else {
273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
274         this.frags = FRAGS_SPECTATOR;
275         PlayerScore_Clear(this);  // clear scores when needed
276     }
277
278         if (CS(this).killcount != FRAGS_SPECTATOR)
279         {
280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
281                 if(!game_stopped)
282                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
284
285                 if(!CS(this).just_joined)
286                         LogTeamchange(this.playerid, -1, 4);
287                 else
288                         CS(this).just_joined = false;
289         }
290
291         accuracy_resend(this);
292
293         CS(this).spectatortime = time;
294         if(this.bot_attack)
295                 IL_REMOVE(g_bot_targets, this);
296         this.bot_attack = false;
297     this.hud = HUD_NORMAL;
298         TRANSMUTE(Observer, this);
299         this.iscreature = false;
300         this.teleportable = TELEPORT_SIMPLE;
301         if(this.damagedbycontents)
302                 IL_REMOVE(g_damagedbycontents, this);
303         this.damagedbycontents = false;
304         this.health = FRAGS_SPECTATOR;
305         SetSpectatee_status(this, etof(this));
306         this.takedamage = DAMAGE_NO;
307         this.solid = SOLID_NOT;
308         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
309         this.flags = FL_CLIENT | FL_NOTARGET;
310         this.armorvalue = 666;
311         this.effects = 0;
312         this.armorvalue = autocvar_g_balance_armor_start;
313         this.pauserotarmor_finished = 0;
314         this.pauserothealth_finished = 0;
315         this.pauseregen_finished = 0;
316         this.damageforcescale = 0;
317         this.death_time = 0;
318         this.respawn_flags = 0;
319         this.respawn_time = 0;
320         this.stat_respawn_time = 0;
321         this.alpha = 0;
322         this.scale = 0;
323         this.fade_time = 0;
324         this.pain_frame = 0;
325         this.pain_finished = 0;
326         this.strength_finished = 0;
327         this.invincible_finished = 0;
328         this.superweapons_finished = 0;
329         this.pushltime = 0;
330         this.istypefrag = 0;
331         setthink(this, func_null);
332         this.nextthink = 0;
333         this.deadflag = DEAD_NO;
334         this.crouch = false;
335         this.revive_progress = 0;
336         this.revival_time = 0;
337
338         this.items = 0;
339         this.weapons = '0 0 0';
340         this.drawonlytoclient = this;
341
342         this.weaponmodel = "";
343         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
344         {
345                 this.weaponentities[slot] = NULL;
346         }
347         this.exteriorweaponentity = NULL;
348         CS(this).killcount = FRAGS_SPECTATOR;
349         this.velocity = '0 0 0';
350         this.avelocity = '0 0 0';
351         this.punchangle = '0 0 0';
352         this.punchvector = '0 0 0';
353         this.oldvelocity = this.velocity;
354         this.fire_endtime = -1;
355         this.event_damage = func_null;
356
357         for(int slot = 0; slot < MAX_AXH; ++slot)
358         {
359                 entity axh = this.(AuxiliaryXhair[slot]);
360                 this.(AuxiliaryXhair[slot]) = NULL;
361
362                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
363                         delete(axh);
364         }
365 }
366
367 int player_getspecies(entity this)
368 {
369         get_model_parameters(this.model, this.skin);
370         int s = get_model_parameters_species;
371         get_model_parameters(string_null, 0);
372         if (s < 0) return SPECIES_HUMAN;
373         return s;
374 }
375
376 .float model_randomizer;
377 void FixPlayermodel(entity player)
378 {
379         string defaultmodel = "";
380         int defaultskin = 0;
381         if(autocvar_sv_defaultcharacter)
382         {
383                 if(teamplay)
384                 {
385                         switch(player.team)
386                         {
387                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
388                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
389                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
390                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
391                         }
392                 }
393
394                 if(defaultmodel == "")
395                 {
396                         defaultmodel = autocvar_sv_defaultplayermodel;
397                         defaultskin = autocvar_sv_defaultplayerskin;
398                 }
399
400                 int n = tokenize_console(defaultmodel);
401                 if(n > 0)
402                 {
403                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
404                         // However, do NOT randomize if the player-selected model is in the list.
405                         for (int i = 0; i < n; ++i)
406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
407                                         defaultmodel = argv(i);
408                 }
409
410                 int i = strstrofs(defaultmodel, ":", 0);
411                 if(i >= 0)
412                 {
413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
414                         defaultmodel = substring(defaultmodel, 0, i);
415                 }
416         }
417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
418         {
419                 if(teamplay)
420                 {
421                         switch(player.team)
422                         {
423                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
424                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
425                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
426                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
427                         }
428                 }
429
430                 if(!defaultskin)
431                         defaultskin = autocvar_sv_defaultplayerskin;
432         }
433
434         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
435         defaultmodel = M_ARGV(0, string);
436         defaultskin = M_ARGV(1, int);
437
438         bool chmdl = false;
439         int oldskin;
440         if(defaultmodel != "")
441         {
442                 if (defaultmodel != player.model)
443                 {
444                         vector m1 = player.mins;
445                         vector m2 = player.maxs;
446                         setplayermodel (player, defaultmodel);
447                         setsize (player, m1, m2);
448                         chmdl = true;
449                 }
450
451                 oldskin = player.skin;
452                 player.skin = defaultskin;
453         } else {
454                 if (player.playermodel != player.model || player.playermodel == "")
455                 {
456                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
457                         vector m1 = player.mins;
458                         vector m2 = player.maxs;
459                         setplayermodel (player, player.playermodel);
460                         setsize (player, m1, m2);
461                         chmdl = true;
462                 }
463
464                 if(!autocvar_sv_defaultcharacterskin)
465                 {
466                         oldskin = player.skin;
467                         player.skin = stof(player.playerskin);
468                 }
469                 else
470                 {
471                         oldskin = player.skin;
472                         player.skin = defaultskin;
473                 }
474         }
475
476         if(chmdl || oldskin != player.skin) // model or skin has changed
477         {
478                 player.species = player_getspecies(player); // update species
479                 if(!autocvar_g_debug_globalsounds)
480                         UpdatePlayerSounds(player); // update skin sounds
481         }
482
483         if(!teamplay)
484                 if(strlen(autocvar_sv_defaultplayercolors))
485                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
486                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
487 }
488
489 void PutPlayerInServer(entity this)
490 {
491         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
492
493         PlayerState_attach(this);
494         accuracy_resend(this);
495
496         if (this.team < 0)
497                 JoinBestTeam(this, false, true);
498
499         entity spot = SelectSpawnPoint(this, false);
500         if (!spot) {
501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
502                 return; // spawn failed
503         }
504
505         TRANSMUTE(Player, this);
506
507         CS(this).wasplayer = true;
508         this.iscreature = true;
509         this.teleportable = TELEPORT_NORMAL;
510         if(!this.damagedbycontents)
511                 IL_PUSH(g_damagedbycontents, this);
512         this.damagedbycontents = true;
513         set_movetype(this, MOVETYPE_WALK);
514         this.solid = SOLID_SLIDEBOX;
515         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
516         if (autocvar_g_playerclip_collisions)
517                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
518         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
519                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
520         this.frags = FRAGS_PLAYER;
521         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
522         this.flags = FL_CLIENT | FL_PICKUPITEMS;
523         if (autocvar__notarget)
524                 this.flags |= FL_NOTARGET;
525         this.takedamage = DAMAGE_AIM;
526         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
527         this.dmg = 2; // WTF
528
529         if (warmup_stage) {
530                 this.ammo_shells = warmup_start_ammo_shells;
531                 this.ammo_nails = warmup_start_ammo_nails;
532                 this.ammo_rockets = warmup_start_ammo_rockets;
533                 this.ammo_cells = warmup_start_ammo_cells;
534                 this.ammo_plasma = warmup_start_ammo_plasma;
535                 this.ammo_fuel = warmup_start_ammo_fuel;
536                 this.health = warmup_start_health;
537                 this.armorvalue = warmup_start_armorvalue;
538                 this.weapons = WARMUP_START_WEAPONS;
539         } else {
540                 this.ammo_shells = start_ammo_shells;
541                 this.ammo_nails = start_ammo_nails;
542                 this.ammo_rockets = start_ammo_rockets;
543                 this.ammo_cells = start_ammo_cells;
544                 this.ammo_plasma = start_ammo_plasma;
545                 this.ammo_fuel = start_ammo_fuel;
546                 this.health = start_health;
547                 this.armorvalue = start_armorvalue;
548                 this.weapons = start_weapons;
549                 GivePlayerRandomWeapons(this, num_random_start_weapons,
550                         cvar_string("g_random_start_weapons"), random_start_shells,
551                         random_start_bullets, random_start_rockets, random_start_cells,
552                         random_start_plasma);
553         }
554         SetSpectatee_status(this, 0);
555
556         PS(this).dual_weapons = '0 0 0';
557
558         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
559
560         this.items = start_items;
561
562         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
563         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
564         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
565         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
566         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
567         // extend the pause of rotting if client was reset at the beginning of the countdown
568         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
569                 float f = game_starttime - time;
570                 this.spawnshieldtime += f;
571                 this.pauserotarmor_finished += f;
572                 this.pauserothealth_finished += f;
573                 this.pauseregen_finished += f;
574         }
575         this.damageforcescale = 2;
576         this.death_time = 0;
577         this.respawn_flags = 0;
578         this.respawn_time = 0;
579         this.stat_respawn_time = 0;
580         this.scale = autocvar_sv_player_scale;
581         this.fade_time = 0;
582         this.pain_frame = 0;
583         this.pain_finished = 0;
584         this.pushltime = 0;
585         setthink(this, func_null); // players have no think function
586         this.nextthink = 0;
587         this.dmg_team = 0;
588         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
589
590         this.deadflag = DEAD_NO;
591
592         this.angles = spot.angles;
593         this.angles_z = 0; // never spawn tilted even if the spot says to
594         if (IS_BOT_CLIENT(this))
595                 this.v_angle = this.angles;
596         this.fixangle = true; // turn this way immediately
597         this.oldvelocity = this.velocity = '0 0 0';
598         this.avelocity = '0 0 0';
599         this.punchangle = '0 0 0';
600         this.punchvector = '0 0 0';
601
602         this.strength_finished = 0;
603         this.invincible_finished = 0;
604         this.fire_endtime = -1;
605         this.revive_progress = 0;
606         this.revival_time = 0;
607         this.air_finished = time + 12;
608
609         entity spawnevent = new_pure(spawnevent);
610         spawnevent.owner = this;
611         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
612
613         // Cut off any still running player sounds.
614         stopsound(this, CH_PLAYER_SINGLE);
615
616         this.model = "";
617         FixPlayermodel(this);
618         this.drawonlytoclient = NULL;
619
620         this.viewloc = NULL;
621
622         this.crouch = false;
623         this.view_ofs = STAT(PL_VIEW_OFS, this);
624         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
625         this.spawnorigin = spot.origin;
626         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
627         // don't reset back to last position, even if new position is stuck in solid
628         this.oldorigin = this.origin;
629         this.lastteleporttime = time; // prevent insane speeds due to changing origin
630         if(this.conveyor)
631                 IL_REMOVE(g_conveyed, this);
632         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
633         this.hud = HUD_NORMAL;
634
635         this.event_damage = PlayerDamage;
636
637         if(!this.bot_attack)
638                 IL_PUSH(g_bot_targets, this);
639         this.bot_attack = true;
640         if(!this.monster_attack)
641                 IL_PUSH(g_monster_targets, this);
642         this.monster_attack = true;
643         navigation_dynamicgoal_init(this, false);
644
645         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
646
647         if (CS(this).killcount == FRAGS_SPECTATOR) {
648                 PlayerScore_Clear(this);
649                 CS(this).killcount = 0;
650         }
651
652         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
653         {
654                 .entity weaponentity = weaponentities[slot];
655                 entity oldwep = this.(weaponentity);
656                 CL_SpawnWeaponentity(this, weaponentity);
657                 if(oldwep && oldwep.owner == this)
658                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
659         }
660         this.alpha = default_player_alpha;
661         this.colormod = '1 1 1' * autocvar_g_player_brightness;
662         this.exteriorweaponentity.alpha = default_weapon_alpha;
663
664         this.speedrunning = false;
665
666         target_voicescript_clear(this);
667
668         // reset fields the weapons may use
669         FOREACH(Weapons, true, {
670                 it.wr_resetplayer(it, this);
671                         // reload all reloadable weapons
672                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
673                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
674                         {
675                                 .entity weaponentity = weaponentities[slot];
676                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
677                         }
678                 }
679         });
680
681         {
682                 string s = spot.target;
683                 spot.target = string_null;
684                 SUB_UseTargets(spot, this, NULL);
685                 spot.target = s;
686         }
687
688         Unfreeze(this);
689
690         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
691
692         if (autocvar_spawn_debug)
693         {
694                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
695                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
696         }
697
698         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
699         {
700                 .entity weaponentity = weaponentities[slot];
701                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
702                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
703                 else
704                         this.(weaponentity).m_switchweapon = WEP_Null;
705                 this.(weaponentity).m_weapon = WEP_Null;
706                 this.(weaponentity).weaponname = "";
707                 this.(weaponentity).m_switchingweapon = WEP_Null;
708                 this.(weaponentity).cnt = -1;
709         }
710
711         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
712
713         if (!warmup_stage && !this.alivetime)
714                 this.alivetime = time;
715
716         antilag_clear(this, CS(this));
717 }
718
719 /** Called when a client spawns in the server */
720 void PutClientInServer(entity this)
721 {
722         if (IS_BOT_CLIENT(this)) {
723                 TRANSMUTE(Player, this);
724         } else if (IS_REAL_CLIENT(this)) {
725                 msg_entity = this;
726                 WriteByte(MSG_ONE, SVC_SETVIEW);
727                 WriteEntity(MSG_ONE, this);
728         }
729         if (game_stopped)
730                 TRANSMUTE(Observer, this);
731
732         SetSpectatee(this, NULL);
733
734         // reset player keys
735         if(PS(this))
736                 PS(this).itemkeys = 0;
737
738         MUTATOR_CALLHOOK(PutClientInServer, this);
739
740         if (IS_OBSERVER(this)) {
741                 PutObserverInServer(this);
742         } else if (IS_PLAYER(this)) {
743                 PutPlayerInServer(this);
744         }
745 }
746
747 void ClientInit_misc(entity this);
748
749 // TODO do we need all these fields, or should we stop autodetecting runtime
750 // changes and just have a console command to update this?
751 bool ClientInit_SendEntity(entity this, entity to, int sf)
752 {
753         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
754         return = true;
755         msg_entity = to;
756         // MSG_INIT replacement
757         // TODO: make easier to use
758         Registry_send_all();
759         W_PROP_reload(MSG_ONE, to);
760         ClientInit_misc(this);
761         MUTATOR_CALLHOOK(Ent_Init);
762 }
763 void ClientInit_misc(entity this)
764 {
765         int channel = MSG_ONE;
766         WriteHeader(channel, ENT_CLIENT_INIT);
767         WriteByte(channel, g_nexball_meter_period * 32);
768         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
769         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
770         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
771         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
772         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
773         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
774         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
775         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
776
777         if(sv_foginterval && world.fog != "")
778                 WriteString(channel, world.fog);
779         else
780                 WriteString(channel, "");
781         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
782         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
783         WriteByte(channel, serverflags);
784         WriteCoord(channel, autocvar_g_trueaim_minrange);
785 }
786
787 void ClientInit_CheckUpdate(entity this)
788 {
789         this.nextthink = time;
790         if(this.count != autocvar_g_balance_armor_blockpercent)
791         {
792                 this.count = autocvar_g_balance_armor_blockpercent;
793                 this.SendFlags |= 1;
794         }
795         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
796         {
797                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
798                 this.SendFlags |= 1;
799         }
800 }
801
802 void ClientInit_Spawn()
803 {
804         entity e = new_pure(clientinit);
805         setthink(e, ClientInit_CheckUpdate);
806         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
807
808         ClientInit_CheckUpdate(e);
809 }
810
811 /*
812 =============
813 SetNewParms
814 =============
815 */
816 void SetNewParms ()
817 {
818         // initialize parms for a new player
819         parm1 = -(86400 * 366);
820
821         MUTATOR_CALLHOOK(SetNewParms);
822 }
823
824 /*
825 =============
826 SetChangeParms
827 =============
828 */
829 void SetChangeParms (entity this)
830 {
831         // save parms for level change
832         parm1 = CS(this).parm_idlesince - time;
833
834         MUTATOR_CALLHOOK(SetChangeParms);
835 }
836
837 /*
838 =============
839 DecodeLevelParms
840 =============
841 */
842 void DecodeLevelParms(entity this)
843 {
844         // load parms
845         CS(this).parm_idlesince = parm1;
846         if (CS(this).parm_idlesince == -(86400 * 366))
847                 CS(this).parm_idlesince = time;
848
849         // whatever happens, allow 60 seconds of idling directly after connect for map loading
850         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
851
852         MUTATOR_CALLHOOK(DecodeLevelParms);
853 }
854
855 /*
856 =============
857 ClientKill
858
859 Called when a client types 'kill' in the console
860 =============
861 */
862
863 .float clientkill_nexttime;
864 void ClientKill_Now_TeamChange(entity this)
865 {
866         if(CS(this).killindicator_teamchange == -1)
867         {
868                 JoinBestTeam( this, false, true );
869         }
870         else if(CS(this).killindicator_teamchange == -2)
871         {
872                 if(blockSpectators)
873                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
874                 PutObserverInServer(this);
875         }
876         else
877                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
878         CS(this).killindicator_teamchange = 0;
879 }
880
881 void ClientKill_Now(entity this)
882 {
883         if(this.vehicle)
884         {
885             vehicles_exit(this.vehicle, VHEF_RELEASE);
886             if(!CS(this).killindicator_teamchange)
887             {
888             this.vehicle_health = -1;
889             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
890             }
891         }
892
893         if(this.killindicator && !wasfreed(this.killindicator))
894                 delete(this.killindicator);
895
896         this.killindicator = NULL;
897
898         if(CS(this).killindicator_teamchange)
899                 ClientKill_Now_TeamChange(this);
900
901         if(!IS_SPEC(this) && !IS_OBSERVER(this))
902                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
903
904         // now I am sure the player IS dead
905 }
906 void KillIndicator_Think(entity this)
907 {
908         if (game_stopped)
909         {
910                 this.owner.killindicator = NULL;
911                 delete(this);
912                 return;
913         }
914
915         if (this.owner.alpha < 0 && !this.owner.vehicle)
916         {
917                 this.owner.killindicator = NULL;
918                 delete(this);
919                 return;
920         }
921
922         if(this.cnt <= 0)
923         {
924                 ClientKill_Now(this.owner);
925                 return;
926         }
927     else if(this.health == 1) // health == 1 means that it's silent
928     {
929         this.nextthink = time + 1;
930         this.cnt -= 1;
931     }
932         else
933         {
934                 if(this.cnt <= 10)
935                         setmodel(this, MDL_NUM(this.cnt));
936                 if(IS_REAL_CLIENT(this.owner))
937                 {
938                         if(this.cnt <= 10)
939                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
940                 }
941                 this.nextthink = time + 1;
942                 this.cnt -= 1;
943         }
944 }
945
946 float clientkilltime;
947 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
948 {
949         float killtime;
950         float starttime;
951
952         if (game_stopped)
953                 return;
954
955         killtime = autocvar_g_balance_kill_delay;
956
957     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
958         return;
959     killtime = M_ARGV(1, float);
960
961         CS(this).killindicator_teamchange = targetteam;
962
963     if(!this.killindicator)
964         {
965                 if(!IS_DEAD(this))
966                 {
967                         killtime = max(killtime, this.clientkill_nexttime - time);
968                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
969                 }
970
971                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
972                 {
973                         ClientKill_Now(this);
974                 }
975                 else
976                 {
977                         starttime = max(time, clientkilltime);
978
979                         this.killindicator = spawn();
980                         this.killindicator.owner = this;
981                         this.killindicator.scale = 0.5;
982                         setattachment(this.killindicator, this, "");
983                         setorigin(this.killindicator, '0 0 52');
984                         setthink(this.killindicator, KillIndicator_Think);
985                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
986                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
987                         this.killindicator.cnt = ceil(killtime);
988                         this.killindicator.count = bound(0, ceil(killtime), 10);
989                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
990
991                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
992                         {
993                                 it.killindicator = spawn();
994                                 it.killindicator.owner = it;
995                                 it.killindicator.scale = 0.5;
996                                 setattachment(it.killindicator, it, "");
997                                 setorigin(it.killindicator, '0 0 52');
998                                 setthink(it.killindicator, KillIndicator_Think);
999                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1000                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1001                                 it.killindicator.cnt = ceil(killtime);
1002                         });
1003                         this.lip = 0;
1004                 }
1005         }
1006         if(this.killindicator)
1007         {
1008                 if(targetteam == 0) // just die
1009                 {
1010                         this.killindicator.colormod = '0 0 0';
1011                         if(IS_REAL_CLIENT(this))
1012                         if(this.killindicator.cnt > 0)
1013                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1014                 }
1015                 else if(targetteam == -1) // auto
1016                 {
1017                         this.killindicator.colormod = '0 1 0';
1018                         if(IS_REAL_CLIENT(this))
1019                         if(this.killindicator.cnt > 0)
1020                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1021                 }
1022                 else if(targetteam == -2) // spectate
1023                 {
1024                         this.killindicator.colormod = '0.5 0.5 0.5';
1025                         if(IS_REAL_CLIENT(this))
1026                         if(this.killindicator.cnt > 0)
1027                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1028                 }
1029                 else
1030                 {
1031                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1032                         if(IS_REAL_CLIENT(this))
1033                         if(this.killindicator.cnt > 0)
1034                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1035                 }
1036         }
1037
1038 }
1039
1040 void ClientKill (entity this)
1041 {
1042         if(game_stopped) return;
1043         if(this.player_blocked) return;
1044         if(STAT(FROZEN, this)) return;
1045
1046         ClientKill_TeamChange(this, 0);
1047 }
1048
1049 void FixClientCvars(entity e)
1050 {
1051         // send prediction settings to the client
1052         stuffcmd(e, "\nin_bindmap 0 0\n");
1053         if(autocvar_g_antilag == 3) // client side hitscan
1054                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1055         if(autocvar_sv_gentle)
1056                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1057
1058         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1059         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1060
1061         MUTATOR_CALLHOOK(FixClientCvars, e);
1062 }
1063
1064 bool findinlist_abbrev(string tofind, string list)
1065 {
1066         if(list == "" || tofind == "")
1067                 return false; // empty list or search, just return
1068
1069         // this function allows abbreviated strings!
1070         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1071         {
1072                 return true;
1073         });
1074
1075         return false;
1076 }
1077
1078 bool PlayerInIPList(entity p, string iplist)
1079 {
1080         // some safety checks (never allow local?)
1081         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1082                 return false;
1083
1084         return findinlist_abbrev(p.netaddress, iplist);
1085 }
1086
1087 bool PlayerInIDList(entity p, string idlist)
1088 {
1089         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1090         if(!p.crypto_idfp)
1091                 return false;
1092
1093         return findinlist_abbrev(p.crypto_idfp, idlist);
1094 }
1095
1096 bool PlayerInList(entity player, string list)
1097 {
1098         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1099 }
1100
1101 #ifdef DP_EXT_PRECONNECT
1102 /*
1103 =============
1104 ClientPreConnect
1105
1106 Called once (not at each match start) when a client begins a connection to the server
1107 =============
1108 */
1109 void ClientPreConnect(entity this)
1110 {
1111         if(autocvar_sv_eventlog)
1112         {
1113                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1114                         this.playerid,
1115                         etof(this),
1116                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1117                 ));
1118         }
1119 }
1120 #endif
1121
1122 /**
1123 =============
1124 ClientConnect
1125
1126 Called when a client connects to the server
1127 =============
1128 */
1129 void ClientConnect(entity this)
1130 {
1131         if (Ban_MaybeEnforceBanOnce(this)) return;
1132         assert(!IS_CLIENT(this), return);
1133         this.flags |= FL_CLIENT;
1134         assert(player_count >= 0, player_count = 0);
1135
1136 #ifdef WATERMARK
1137         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1138 #endif
1139         TRANSMUTE(Client, this);
1140         CS(this).version_nagtime = time + 10 + random() * 10;
1141
1142         // identify the right forced team
1143         if (autocvar_g_campaign)
1144         {
1145                 if (IS_REAL_CLIENT(this)) // only players, not bots
1146                 {
1147                         switch (autocvar_g_campaign_forceteam)
1148                         {
1149                                 case 1: this.team_forced = NUM_TEAM_1; break;
1150                                 case 2: this.team_forced = NUM_TEAM_2; break;
1151                                 case 3: this.team_forced = NUM_TEAM_3; break;
1152                                 case 4: this.team_forced = NUM_TEAM_4; break;
1153                                 default: this.team_forced = 0;
1154                         }
1155                 }
1156         }
1157         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1158         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1159         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1160         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1161         else switch (autocvar_g_forced_team_otherwise)
1162         {
1163                 default: this.team_forced = 0; break;
1164                 case "red": this.team_forced = NUM_TEAM_1; break;
1165                 case "blue": this.team_forced = NUM_TEAM_2; break;
1166                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1167                 case "pink": this.team_forced = NUM_TEAM_4; break;
1168                 case "spectate":
1169                 case "spectator":
1170                         this.team_forced = -1;
1171                         break;
1172         }
1173         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1174
1175     {
1176         int id = this.playerid;
1177         this.playerid = 0; // silent
1178             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1179             this.playerid = id;
1180     }
1181
1182         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1183                 TRANSMUTE(Observer, this);
1184         } else {
1185                 if (!teamplay || autocvar_g_balance_teams) {
1186                         TRANSMUTE(Player, this);
1187                         campaign_bots_may_start = true;
1188                 } else {
1189                         TRANSMUTE(Observer, this); // do it anyway
1190                 }
1191         }
1192
1193         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1194
1195         // always track bots, don't ask for cl_allow_uidtracking
1196     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1197
1198         if (autocvar_sv_eventlog)
1199                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1200
1201         LogTeamchange(this.playerid, this.team, 1);
1202
1203         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1204
1205         CS(this).netname_previous = strzone(this.netname);
1206
1207         if(teamplay && IS_PLAYER(this))
1208                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1209         else
1210                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1211
1212         stuffcmd(this, clientstuff, "\n");
1213         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1214
1215         FixClientCvars(this);
1216
1217         // get version info from player
1218         stuffcmd(this, "cmd clientversion $gameversion\n");
1219
1220         // notify about available teams
1221         if (teamplay)
1222         {
1223                 CheckAllowedTeams(this);
1224                 int t = 0;
1225                 if (c1 >= 0) t |= BIT(0);
1226                 if (c2 >= 0) t |= BIT(1);
1227                 if (c3 >= 0) t |= BIT(2);
1228                 if (c4 >= 0) t |= BIT(3);
1229                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1230         }
1231         else
1232         {
1233                 stuffcmd(this, "set _teams_available 0\n");
1234         }
1235
1236         bot_relinkplayerlist();
1237
1238         CS(this).spectatortime = time;
1239         if (blockSpectators)
1240         {
1241                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1242         }
1243
1244         CS(this).jointime = time;
1245         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1246
1247         if (IS_REAL_CLIENT(this))
1248         {
1249                 if (g_weaponarena_weapons == WEPSET(TUBA))
1250                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1251         }
1252
1253         if (!sv_foginterval && world.fog != "")
1254                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1255
1256         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1257                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1258                         send_CSQC_teamnagger();
1259
1260         CSQCMODEL_AUTOINIT(this);
1261
1262         CS(this).model_randomizer = random();
1263
1264         if (IS_REAL_CLIENT(this))
1265                 sv_notice_join(this);
1266
1267         // update physics stats (players can spawn before physics runs)
1268         Physics_UpdateStats(this);
1269
1270         IL_EACH(g_initforplayer, it.init_for_player, {
1271                 it.init_for_player(it, this);
1272         });
1273
1274         MUTATOR_CALLHOOK(ClientConnect, this);
1275
1276         if (IS_REAL_CLIENT(this))
1277         {
1278                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1279                 {
1280                         CS(this).motd_actived_time = -1;
1281                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1282                 }
1283         }
1284 }
1285 /*
1286 =============
1287 ClientDisconnect
1288
1289 Called when a client disconnects from the server
1290 =============
1291 */
1292 .entity chatbubbleentity;
1293 void ReadyCount();
1294 void ClientDisconnect(entity this)
1295 {
1296         assert(IS_CLIENT(this), return);
1297
1298         PlayerStats_GameReport_FinalizePlayer(this);
1299         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1300         if (CS(this).active_minigame) part_minigame(this);
1301         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1302
1303         if (autocvar_sv_eventlog)
1304                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1305
1306         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1307
1308         if(IS_SPEC(this))
1309                 SetSpectatee(this, NULL);
1310
1311     MUTATOR_CALLHOOK(ClientDisconnect, this);
1312
1313         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1314         ClientState_detach(this);
1315
1316         Portal_ClearAll(this);
1317
1318         Unfreeze(this);
1319
1320         RemoveGrapplingHooks(this);
1321
1322         // Here, everything has been done that requires this player to be a client.
1323
1324         this.flags &= ~FL_CLIENT;
1325
1326         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1327         if (this.killindicator) delete(this.killindicator);
1328
1329         WaypointSprite_PlayerGone(this);
1330
1331         bot_relinkplayerlist();
1332
1333         if (this.clientstatus) strunzone(this.clientstatus);
1334         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1335         if (this.personal) delete(this.personal);
1336
1337         this.playerid = 0;
1338         ReadyCount();
1339         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1340
1341         ONREMOVE(this);
1342 }
1343
1344 void ChatBubbleThink(entity this)
1345 {
1346         this.nextthink = time;
1347         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1348         {
1349                 if(this.owner) // but why can that ever be NULL?
1350                         this.owner.chatbubbleentity = NULL;
1351                 delete(this);
1352                 return;
1353         }
1354
1355         this.mdl = "";
1356
1357         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1358         {
1359                 if ( CS(this.owner).active_minigame )
1360                         this.mdl = "models/sprites/minigame_busy.iqm";
1361                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1362                         this.mdl = "models/misc/chatbubble.spr";
1363         }
1364
1365         if ( this.model != this.mdl )
1366                 _setmodel(this, this.mdl);
1367
1368 }
1369
1370 void UpdateChatBubble(entity this)
1371 {
1372         if (this.alpha < 0)
1373                 return;
1374         // spawn a chatbubble entity if needed
1375         if (!this.chatbubbleentity)
1376         {
1377                 this.chatbubbleentity = new(chatbubbleentity);
1378                 this.chatbubbleentity.owner = this;
1379                 this.chatbubbleentity.exteriormodeltoclient = this;
1380                 setthink(this.chatbubbleentity, ChatBubbleThink);
1381                 this.chatbubbleentity.nextthink = time;
1382                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1383                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1384                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1385                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1386                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1387                 //this.chatbubbleentity.model = "";
1388                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1389         }
1390 }
1391
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = this.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) this.colormod = '0 0 0';
1401         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1406         else this.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(entity this)
1410 {
1411         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1412         {
1413                 this.solid = SOLID_NOT;
1414                 this.takedamage = DAMAGE_NO;
1415                 set_movetype(this, MOVETYPE_FLY);
1416                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1417                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1418                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1419                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1420                 if(autocvar_g_respawn_ghosts_maxtime)
1421                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1422         }
1423
1424         CopyBody(this, 1);
1425
1426         this.effects |= EF_NODRAW; // prevent another CopyBody
1427         PutClientInServer(this);
1428 }
1429
1430 void play_countdown(entity this, float finished, Sound samp)
1431 {
1432     TC(Sound, samp);
1433         if(IS_REAL_CLIENT(this))
1434                 if(floor(finished - time - frametime) != floor(finished - time))
1435                         if(finished - time < 6)
1436                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1437 }
1438
1439 void player_powerups(entity this)
1440 {
1441         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1442         int items_prev = this.items;
1443
1444         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1445                 this.modelflags |= MF_ROCKET;
1446         else
1447                 this.modelflags &= ~MF_ROCKET;
1448
1449         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1450
1451         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1452                 return;
1453
1454         Fire_ApplyDamage(this);
1455         Fire_ApplyEffect(this);
1456
1457         if (!g_instagib)
1458         {
1459                 if (this.items & ITEM_Strength.m_itemid)
1460                 {
1461                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1462                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1463                         if (time > this.strength_finished)
1464                         {
1465                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1466                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1468                         }
1469                 }
1470                 else
1471                 {
1472                         if (time < this.strength_finished)
1473                         {
1474                                 this.items = this.items | ITEM_Strength.m_itemid;
1475                                 if(!g_cts)
1476                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1478                         }
1479                 }
1480                 if (this.items & ITEM_Shield.m_itemid)
1481                 {
1482                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1483                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1484                         if (time > this.invincible_finished)
1485                         {
1486                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1487                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1488                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1489                         }
1490                 }
1491                 else
1492                 {
1493                         if (time < this.invincible_finished)
1494                         {
1495                                 this.items = this.items | ITEM_Shield.m_itemid;
1496                                 if(!g_cts)
1497                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1498                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1499                         }
1500                 }
1501                 if (this.items & IT_SUPERWEAPON)
1502                 {
1503                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1504                         {
1505                                 this.superweapons_finished = 0;
1506                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1507                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1509                         }
1510                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1511                         {
1512                                 // don't let them run out
1513                         }
1514                         else
1515                         {
1516                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1517                                 if (time > this.superweapons_finished)
1518                                 {
1519                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1520                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1521                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1522                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1523                                 }
1524                         }
1525                 }
1526                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1527                 {
1528                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1529                         {
1530                                 this.items = this.items | IT_SUPERWEAPON;
1531                                 if(!g_cts)
1532                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1534                         }
1535                         else
1536                         {
1537                                 this.superweapons_finished = 0;
1538                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1539                         }
1540                 }
1541                 else
1542                 {
1543                         this.superweapons_finished = 0;
1544                 }
1545         }
1546
1547         if(autocvar_g_nodepthtestplayers)
1548                 this.effects = this.effects | EF_NODEPTHTEST;
1549
1550         if(autocvar_g_fullbrightplayers)
1551                 this.effects = this.effects | EF_FULLBRIGHT;
1552
1553         if (time >= game_starttime)
1554         if (time < this.spawnshieldtime)
1555                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1556
1557         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1558 }
1559
1560 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1561 {
1562         if(current > stable)
1563                 return current;
1564         else if(current > stable - 0.25) // when close enough, "snap"
1565                 return stable;
1566         else
1567                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1568 }
1569
1570 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1571 {
1572         if(current < stable)
1573                 return current;
1574         else if(current < stable + 0.25) // when close enough, "snap"
1575                 return stable;
1576         else
1577                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1578 }
1579
1580 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1581 {
1582         if(current > rotstable)
1583         {
1584                 if(rotframetime > 0)
1585                 {
1586                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1587                         current = max(rotstable, current - rotlinear * rotframetime);
1588                 }
1589         }
1590         else if(current < regenstable)
1591         {
1592                 if(regenframetime > 0)
1593                 {
1594                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1595                         current = min(regenstable, current + regenlinear * regenframetime);
1596                 }
1597         }
1598
1599         if(current > limit)
1600                 current = limit;
1601
1602         return current;
1603 }
1604
1605 void player_regen(entity this)
1606 {
1607         float max_mod, regen_mod, rot_mod, limit_mod;
1608         max_mod = regen_mod = rot_mod = limit_mod = 1;
1609
1610         float regen_health = autocvar_g_balance_health_regen;
1611         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1612         float regen_health_rot = autocvar_g_balance_health_rot;
1613         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1614         float regen_health_stable = autocvar_g_balance_health_regenstable;
1615         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1616         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1617                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1618         max_mod = M_ARGV(1, float);
1619         regen_mod = M_ARGV(2, float);
1620         rot_mod = M_ARGV(3, float);
1621         limit_mod = M_ARGV(4, float);
1622         regen_health = M_ARGV(5, float);
1623         regen_health_linear = M_ARGV(6, float);
1624         regen_health_rot = M_ARGV(7, float);
1625         regen_health_rotlinear = M_ARGV(8, float);
1626         regen_health_stable = M_ARGV(9, float);
1627         regen_health_rotstable = M_ARGV(10, float);
1628
1629
1630         if(!mutator_returnvalue)
1631         if(!STAT(FROZEN, this))
1632         {
1633                 float mina, maxa, limith, limita;
1634                 maxa = autocvar_g_balance_armor_rotstable;
1635                 mina = autocvar_g_balance_armor_regenstable;
1636                 limith = autocvar_g_balance_health_limit;
1637                 limita = autocvar_g_balance_armor_limit;
1638
1639                 regen_health_rotstable = regen_health_rotstable * max_mod;
1640                 regen_health_stable = regen_health_stable * max_mod;
1641                 limith = limith * limit_mod;
1642                 limita = limita * limit_mod;
1643
1644                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1645                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1646         }
1647
1648         // if player rotted to death...  die!
1649         // check this outside above checks, as player may still be able to rot to death
1650         if(this.health < 1)
1651         {
1652                 if(this.vehicle)
1653                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1654                 if(this.event_damage)
1655                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1656         }
1657
1658         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1659         {
1660                 float minf, maxf, limitf;
1661
1662                 maxf = autocvar_g_balance_fuel_rotstable;
1663                 minf = autocvar_g_balance_fuel_regenstable;
1664                 limitf = autocvar_g_balance_fuel_limit;
1665
1666                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1667         }
1668 }
1669
1670 bool zoomstate_set;
1671 void SetZoomState(entity this, float newzoom)
1672 {
1673         if(newzoom != CS(this).zoomstate)
1674         {
1675                 CS(this).zoomstate = newzoom;
1676                 ClientData_Touch(this);
1677         }
1678         zoomstate_set = true;
1679 }
1680
1681 void GetPressedKeys(entity this)
1682 {
1683         MUTATOR_CALLHOOK(GetPressedKeys, this);
1684         int keys = STAT(PRESSED_KEYS, this);
1685         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1686         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1687         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1688         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1689
1690         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1691         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1692         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1693         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1694         CS(this).pressedkeys = keys; // store for other users
1695
1696         STAT(PRESSED_KEYS, this) = keys;
1697 }
1698
1699 /*
1700 ======================
1701 spectate mode routines
1702 ======================
1703 */
1704
1705 void SpectateCopy(entity this, entity spectatee)
1706 {
1707     TC(Client, this); TC(Client, spectatee);
1708
1709         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1710         PS(this) = PS(spectatee);
1711         this.armortype = spectatee.armortype;
1712         this.armorvalue = spectatee.armorvalue;
1713         this.ammo_cells = spectatee.ammo_cells;
1714         this.ammo_plasma = spectatee.ammo_plasma;
1715         this.ammo_shells = spectatee.ammo_shells;
1716         this.ammo_nails = spectatee.ammo_nails;
1717         this.ammo_rockets = spectatee.ammo_rockets;
1718         this.ammo_fuel = spectatee.ammo_fuel;
1719         this.clip_load = spectatee.clip_load;
1720         this.clip_size = spectatee.clip_size;
1721         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1722         this.health = spectatee.health;
1723         CS(this).impulse = 0;
1724         this.items = spectatee.items;
1725         this.last_pickup = spectatee.last_pickup;
1726         this.hit_time = spectatee.hit_time;
1727         this.strength_finished = spectatee.strength_finished;
1728         this.invincible_finished = spectatee.invincible_finished;
1729         this.superweapons_finished = spectatee.superweapons_finished;
1730         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1731         this.weapons = spectatee.weapons;
1732         this.vortex_charge = spectatee.vortex_charge;
1733         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1734         this.hagar_load = spectatee.hagar_load;
1735         this.arc_heat_percent = spectatee.arc_heat_percent;
1736         this.minelayer_mines = spectatee.minelayer_mines;
1737         this.punchangle = spectatee.punchangle;
1738         this.view_ofs = spectatee.view_ofs;
1739         this.velocity = spectatee.velocity;
1740         this.dmg_take = spectatee.dmg_take;
1741         this.dmg_save = spectatee.dmg_save;
1742         this.dmg_inflictor = spectatee.dmg_inflictor;
1743         this.v_angle = spectatee.v_angle;
1744         this.angles = spectatee.v_angle;
1745         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1746         this.revive_progress = spectatee.revive_progress;
1747         this.viewloc = spectatee.viewloc;
1748         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1749                 this.fixangle = true;
1750         setorigin(this, spectatee.origin);
1751         setsize(this, spectatee.mins, spectatee.maxs);
1752         SetZoomState(this, CS(spectatee).zoomstate);
1753
1754         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1755         {
1756                 .entity weaponentity = weaponentities[slot];
1757                 this.(weaponentity) = spectatee.(weaponentity);
1758         }
1759
1760         for(int slot = 0; slot < MAX_AXH; ++slot)
1761         {
1762                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1763         }
1764
1765     anticheat_spectatecopy(this, spectatee);
1766         this.hud = spectatee.hud;
1767         if(spectatee.vehicle)
1768     {
1769         this.angles = spectatee.v_angle;
1770
1771         //this.fixangle = false;
1772         //this.velocity = spectatee.vehicle.velocity;
1773         this.vehicle_health = spectatee.vehicle_health;
1774         this.vehicle_shield = spectatee.vehicle_shield;
1775         this.vehicle_energy = spectatee.vehicle_energy;
1776         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1777         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1778         this.vehicle_reload1 = spectatee.vehicle_reload1;
1779         this.vehicle_reload2 = spectatee.vehicle_reload2;
1780
1781         //msg_entity = this;
1782
1783        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1784             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1785            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1786            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1787
1788         //WriteByte (MSG_ONE, SVC_SETVIEW);
1789         //    WriteEntity(MSG_ONE, this);
1790         //makevectors(spectatee.v_angle);
1791         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1792     }
1793 }
1794
1795 bool SpectateUpdate(entity this)
1796 {
1797         if(!this.enemy)
1798                 return false;
1799
1800         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1801         {
1802                 SetSpectatee(this, NULL);
1803                 return false;
1804         }
1805
1806         SpectateCopy(this, this.enemy);
1807
1808         return true;
1809 }
1810
1811 bool SpectateSet(entity this)
1812 {
1813         if(!IS_PLAYER(this.enemy))
1814                 return false;
1815
1816         ClientData_Touch(this.enemy);
1817
1818         msg_entity = this;
1819         WriteByte(MSG_ONE, SVC_SETVIEW);
1820         WriteEntity(MSG_ONE, this.enemy);
1821         set_movetype(this, MOVETYPE_NONE);
1822         accuracy_resend(this);
1823
1824         if(!SpectateUpdate(this))
1825                 PutObserverInServer(this);
1826
1827         return true;
1828 }
1829
1830 void SetSpectatee_status(entity this, int spectatee_num)
1831 {
1832         int oldspectatee_status = CS(this).spectatee_status;
1833         CS(this).spectatee_status = spectatee_num;
1834
1835         if (CS(this).spectatee_status != oldspectatee_status)
1836         {
1837                 ClientData_Touch(this);
1838                 if (g_race || g_cts) race_InitSpectator();
1839         }
1840 }
1841
1842 void SetSpectatee(entity this, entity spectatee)
1843 {
1844         if(IS_BOT_CLIENT(this))
1845                 return; // bots abuse .enemy, this code is useless to them
1846
1847         entity old_spectatee = this.enemy;
1848
1849         this.enemy = spectatee;
1850
1851         // WEAPONTODO
1852         // these are required to fix the spectator bug with arc
1853         if(old_spectatee)
1854         {
1855                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1856                 {
1857                         .entity weaponentity = weaponentities[slot];
1858                         if(old_spectatee.(weaponentity).arc_beam)
1859                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1860                 }
1861         }
1862         if(this.enemy)
1863         {
1864                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1865                 {
1866                         .entity weaponentity = weaponentities[slot];
1867                         if(this.enemy.(weaponentity).arc_beam)
1868                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1869                 }
1870         }
1871
1872         if (this.enemy)
1873                 SetSpectatee_status(this, etof(this.enemy));
1874
1875         // needed to update spectator list
1876         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1877 }
1878
1879 bool Spectate(entity this, entity pl)
1880 {
1881         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1882                 return false;
1883         pl = M_ARGV(1, entity);
1884
1885         SetSpectatee(this, pl);
1886         return SpectateSet(this);
1887 }
1888
1889 bool SpectateNext(entity this)
1890 {
1891         entity ent = find(this.enemy, classname, STR_PLAYER);
1892
1893         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1894                 ent = M_ARGV(1, entity);
1895         else if (!ent)
1896                 ent = find(ent, classname, STR_PLAYER);
1897
1898         if(ent) { SetSpectatee(this, ent); }
1899
1900         return SpectateSet(this);
1901 }
1902
1903 bool SpectatePrev(entity this)
1904 {
1905         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1906         entity ent = findchain(classname, STR_PLAYER);
1907         if (!ent) // no player
1908                 return false;
1909
1910         entity first = ent;
1911         // skip players until current spectated player
1912         if(this.enemy)
1913         while(ent && ent != this.enemy)
1914                 ent = ent.chain;
1915
1916         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1917         {
1918                 case MUT_SPECPREV_FOUND:
1919                     ent = M_ARGV(1, entity);
1920                     break;
1921                 case MUT_SPECPREV_RETURN:
1922                     return true;
1923                 case MUT_SPECPREV_CONTINUE:
1924                 default:
1925                 {
1926                         if(ent.chain)
1927                                 ent = ent.chain;
1928                         else
1929                                 ent = first;
1930                         break;
1931                 }
1932         }
1933
1934         SetSpectatee(this, ent);
1935         return SpectateSet(this);
1936 }
1937
1938 /*
1939 =============
1940 ShowRespawnCountdown()
1941
1942 Update a respawn countdown display.
1943 =============
1944 */
1945 void ShowRespawnCountdown(entity this)
1946 {
1947         float number;
1948         if(!IS_DEAD(this)) // just respawned?
1949                 return;
1950         else
1951         {
1952                 number = ceil(this.respawn_time - time);
1953                 if(number <= 0)
1954                         return;
1955                 if(number <= this.respawn_countdown)
1956                 {
1957                         this.respawn_countdown = number - 1;
1958                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1959                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1960                 }
1961         }
1962 }
1963
1964 .bool team_selected;
1965 bool ShowTeamSelection(entity this)
1966 {
1967         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1968                 return false;
1969         stuffcmd(this, "menu_showteamselect\n");
1970         return true;
1971 }
1972 void Join(entity this)
1973 {
1974         TRANSMUTE(Player, this);
1975
1976         if(!this.team_selected)
1977         if(autocvar_g_campaign || autocvar_g_balance_teams)
1978                 JoinBestTeam(this, false, true);
1979
1980         if(autocvar_g_campaign)
1981                 campaign_bots_may_start = true;
1982
1983         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1984
1985         PutClientInServer(this);
1986
1987         if(IS_PLAYER(this))
1988         if(teamplay && this.team != -1)
1989                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1990         else
1991                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1992         this.team_selected = false;
1993 }
1994
1995 /**
1996  * Determines whether the player is allowed to join. This depends on cvar
1997  * g_maxplayers, if it isn't used this function always return true, otherwise
1998  * it checks whether the number of currently playing players exceeds g_maxplayers.
1999  * @return int number of free slots for players, 0 if none
2000  */
2001 int nJoinAllowed(entity this, entity ignore)
2002 {
2003         if(!ignore)
2004         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2005         // so report 0 free slots if restricted
2006         {
2007                 if(autocvar_g_forced_team_otherwise == "spectate")
2008                         return 0;
2009                 if(autocvar_g_forced_team_otherwise == "spectator")
2010                         return 0;
2011         }
2012
2013         if(this && this.team_forced < 0)
2014                 return 0; // forced spectators can never join
2015
2016         // TODO simplify this
2017         int totalClients = 0;
2018         int currentlyPlaying = 0;
2019         FOREACH_CLIENT(true, {
2020                 if(it != ignore)
2021                         ++totalClients;
2022                 if(IS_REAL_CLIENT(it))
2023                 if(IS_PLAYER(it) || it.caplayer)
2024                         ++currentlyPlaying;
2025         });
2026
2027         float free_slots = 0;
2028         if (!autocvar_g_maxplayers)
2029                 free_slots = maxclients - totalClients;
2030         else if(currentlyPlaying < autocvar_g_maxplayers)
2031                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2032
2033         static float join_prevent_msg_time = 0;
2034         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2035         {
2036                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2037                 join_prevent_msg_time = time + 3;
2038         }
2039
2040         return free_slots;
2041 }
2042
2043 /**
2044  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2045  * g_maxplayers_spectator_blocktime seconds
2046  */
2047 void checkSpectatorBlock(entity this)
2048 {
2049         if(IS_SPEC(this) || IS_OBSERVER(this))
2050         if(!this.caplayer)
2051         if(IS_REAL_CLIENT(this))
2052         {
2053                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2054                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2055                         dropclient(this);
2056                 }
2057         }
2058 }
2059
2060 void PrintWelcomeMessage(entity this)
2061 {
2062         if(CS(this).motd_actived_time == 0)
2063         {
2064                 if (autocvar_g_campaign) {
2065                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2066                                 CS(this).motd_actived_time = time;
2067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2068                         }
2069                 } else {
2070                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2071                                 CS(this).motd_actived_time = time;
2072                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2073                         }
2074                 }
2075         }
2076         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2077         {
2078                 if (autocvar_g_campaign) {
2079                         if (PHYS_INPUT_BUTTON_INFO(this))
2080                                 CS(this).motd_actived_time = time;
2081                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2082                                 CS(this).motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                         }
2085                 } else {
2086                         if (PHYS_INPUT_BUTTON_INFO(this))
2087                                 CS(this).motd_actived_time = time;
2088                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2089                                 CS(this).motd_actived_time = 0;
2090                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2091                         }
2092                 }
2093         }
2094         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2095         {
2096                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2097                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2098                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2099                 {
2100                         // instanctly hide MOTD
2101                         CS(this).motd_actived_time = 0;
2102                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2103                 }
2104         }
2105 }
2106
2107 bool joinAllowed(entity this)
2108 {
2109         if (CS(this).version_mismatch) return false;
2110         if (!nJoinAllowed(this, this)) return false;
2111         if (teamplay && lockteams) return false;
2112         if (ShowTeamSelection(this)) return false;
2113         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2114         return true;
2115 }
2116
2117 .int items_added;
2118 bool PlayerThink(entity this)
2119 {
2120         if (game_stopped || intermission_running) {
2121                 this.modelflags &= ~MF_ROCKET;
2122                 if(intermission_running)
2123                         IntermissionThink(this);
2124                 return false;
2125         }
2126
2127         if (timeout_status == TIMEOUT_ACTIVE) {
2128         // don't allow the player to turn around while game is paused
2129                 // FIXME turn this into CSQC stuff
2130                 this.v_angle = this.lastV_angle;
2131                 this.angles = this.lastV_angle;
2132                 this.fixangle = true;
2133         }
2134
2135         if (frametime) player_powerups(this);
2136
2137         if (IS_DEAD(this)) {
2138                 if (this.personal && g_race_qualifying) {
2139                         if (time > this.respawn_time) {
2140                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2141                                 respawn(this);
2142                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2143                         }
2144                 } else {
2145                         if (frametime) player_anim(this);
2146
2147                         if (this.respawn_flags & RESPAWN_DENY)
2148                         {
2149                                 STAT(RESPAWN_TIME, this) = 0;
2150                                 return false;
2151                         }
2152
2153                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2154
2155                         switch(this.deadflag)
2156                         {
2157                                 case DEAD_DYING:
2158                                 {
2159                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2160                                                 this.deadflag = DEAD_RESPAWNING;
2161                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2162                                                 this.deadflag = DEAD_DEAD;
2163                                         break;
2164                                 }
2165                                 case DEAD_DEAD:
2166                                 {
2167                                         if (button_pressed)
2168                                                 this.deadflag = DEAD_RESPAWNABLE;
2169                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2170                                                 this.deadflag = DEAD_RESPAWNING;
2171                                         break;
2172                                 }
2173                                 case DEAD_RESPAWNABLE:
2174                                 {
2175                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2176                                                 this.deadflag = DEAD_RESPAWNING;
2177                                         break;
2178                                 }
2179                                 case DEAD_RESPAWNING:
2180                                 {
2181                                         if (time > this.respawn_time)
2182                                         {
2183                                                 this.respawn_time = time + 1; // only retry once a second
2184                                                 this.respawn_time_max = this.respawn_time;
2185                                                 respawn(this);
2186                                         }
2187                                         break;
2188                                 }
2189                         }
2190
2191                         ShowRespawnCountdown(this);
2192
2193                         if (this.respawn_flags & RESPAWN_SILENT)
2194                                 STAT(RESPAWN_TIME, this) = 0;
2195                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2196                         {
2197                                 if (time < this.respawn_time)
2198                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2199                                 else if (this.deadflag != DEAD_RESPAWNING)
2200                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2201                         }
2202                         else
2203                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2204                 }
2205
2206                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2207                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2208                         STAT(RESPAWN_TIME, this) *= -1;
2209
2210                 return false;
2211         }
2212
2213         bool have_hook = false;
2214         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2215         {
2216                 .entity weaponentity = weaponentities[slot];
2217                 if(this.(weaponentity).hook.state)
2218                 {
2219                         have_hook = true;
2220                         break;
2221                 }
2222         }
2223         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2224         if (have_hook) {
2225                 do_crouch = false;
2226         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2227                 do_crouch = false;
2228         } else if (this.vehicle) {
2229                 do_crouch = false;
2230         } else if (STAT(FROZEN, this)) {
2231                 do_crouch = false;
2232     }
2233
2234         if (do_crouch) {
2235                 if (!this.crouch) {
2236                         this.crouch = true;
2237                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2238                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2239                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2240                 }
2241         } else if (this.crouch) {
2242         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2243         if (!trace_startsolid) {
2244             this.crouch = false;
2245             this.view_ofs = STAT(PL_VIEW_OFS, this);
2246             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2247         }
2248         }
2249
2250         FixPlayermodel(this);
2251
2252         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2253         //if(frametime)
2254         {
2255                 this.items &= ~this.items_added;
2256
2257                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2258                 {
2259                         .entity weaponentity = weaponentities[slot];
2260                         W_WeaponFrame(this, weaponentity);
2261
2262                         if(slot == 0)
2263                         {
2264                                 this.clip_load = this.(weaponentity).clip_load;
2265                                 this.clip_size = this.(weaponentity).clip_size;
2266                         }
2267                 }
2268
2269                 this.items_added = 0;
2270                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2271             this.items_added |= IT_FUEL;
2272
2273                 this.items |= this.items_added;
2274         }
2275
2276         player_regen(this);
2277
2278         // WEAPONTODO: Add a weapon request for this
2279         // rot vortex charge to the charge limit
2280         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2281         {
2282                 .entity weaponentity = weaponentities[slot];
2283                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2284                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2285         }
2286
2287         if (frametime) player_anim(this);
2288
2289         // secret status
2290         secrets_setstatus(this);
2291
2292         // monsters status
2293         monsters_setstatus(this);
2294
2295         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2296
2297         return true;
2298 }
2299
2300 void ObserverThink(entity this)
2301 {
2302         if ( CS(this).impulse )
2303         {
2304                 MinigameImpulse(this, CS(this).impulse);
2305                 CS(this).impulse = 0;
2306         }
2307
2308         if (this.flags & FL_JUMPRELEASED) {
2309                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2310                         this.flags &= ~FL_JUMPRELEASED;
2311                         this.flags |= FL_SPAWNING;
2312                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2313                         this.flags &= ~FL_JUMPRELEASED;
2314                         if(SpectateNext(this)) {
2315                                 TRANSMUTE(Spectator, this);
2316                         }
2317                 } else {
2318                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2319                         set_movetype(this, preferred_movetype);
2320                 }
2321         } else {
2322                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2323                         this.flags |= FL_JUMPRELEASED;
2324                         if(this.flags & FL_SPAWNING)
2325                         {
2326                                 this.flags &= ~FL_SPAWNING;
2327                                 Join(this);
2328                                 return;
2329                         }
2330                 }
2331         }
2332 }
2333
2334 void SpectatorThink(entity this)
2335 {
2336         if ( CS(this).impulse )
2337         {
2338                 if(MinigameImpulse(this, CS(this).impulse))
2339                         CS(this).impulse = 0;
2340
2341                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2342                 {
2343                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2344                         CS(this).impulse = 0;
2345                         return;
2346                 }
2347         }
2348
2349         if (this.flags & FL_JUMPRELEASED) {
2350                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2351                         this.flags &= ~FL_JUMPRELEASED;
2352                         this.flags |= FL_SPAWNING;
2353                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2354                         this.flags &= ~FL_JUMPRELEASED;
2355                         if(SpectateNext(this)) {
2356                                 TRANSMUTE(Spectator, this);
2357                         } else {
2358                                 TRANSMUTE(Observer, this);
2359                                 PutClientInServer(this);
2360                         }
2361                         CS(this).impulse = 0;
2362                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2363                         this.flags &= ~FL_JUMPRELEASED;
2364                         if(SpectatePrev(this)) {
2365                                 TRANSMUTE(Spectator, this);
2366                         } else {
2367                                 TRANSMUTE(Observer, this);
2368                                 PutClientInServer(this);
2369                         }
2370                         CS(this).impulse = 0;
2371                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2372                         this.flags &= ~FL_JUMPRELEASED;
2373                         TRANSMUTE(Observer, this);
2374                         PutClientInServer(this);
2375                 } else {
2376                         if(!SpectateUpdate(this))
2377                                 PutObserverInServer(this);
2378                 }
2379         } else {
2380                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2381                         this.flags |= FL_JUMPRELEASED;
2382                         if(this.flags & FL_SPAWNING)
2383                         {
2384                                 this.flags &= ~FL_SPAWNING;
2385                                 Join(this);
2386                                 return;
2387                         }
2388                 }
2389                 if(!SpectateUpdate(this))
2390                         PutObserverInServer(this);
2391         }
2392
2393         this.flags |= FL_CLIENT | FL_NOTARGET;
2394 }
2395
2396 void vehicles_enter (entity pl, entity veh);
2397 void PlayerUseKey(entity this)
2398 {
2399         if (!IS_PLAYER(this))
2400                 return;
2401
2402         if(this.vehicle)
2403         {
2404                 if(!game_stopped)
2405                 {
2406                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2407                         return;
2408                 }
2409         }
2410         else if(autocvar_g_vehicles_enter)
2411         {
2412                 if(!STAT(FROZEN, this))
2413                 if(!IS_DEAD(this))
2414                 if(!game_stopped)
2415                 {
2416                         entity head, closest_target = NULL;
2417                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2418
2419                         while(head) // find the closest acceptable target to enter
2420                         {
2421                                 if(IS_VEHICLE(head))
2422                                 if(!IS_DEAD(head))
2423                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2424                                 if(head.takedamage != DAMAGE_NO)
2425                                 {
2426                                         if(closest_target)
2427                                         {
2428                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2429                                                 { closest_target = head; }
2430                                         }
2431                                         else { closest_target = head; }
2432                                 }
2433
2434                                 head = head.chain;
2435                         }
2436
2437                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2438                 }
2439         }
2440
2441         // a use key was pressed; call handlers
2442         MUTATOR_CALLHOOK(PlayerUseKey, this);
2443 }
2444
2445
2446 /*
2447 =============
2448 PlayerPreThink
2449
2450 Called every frame for each client before the physics are run
2451 =============
2452 */
2453 .float last_vehiclecheck;
2454 void PlayerPreThink (entity this)
2455 {
2456         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2457         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2458
2459         WarpZone_PlayerPhysics_FixVAngle(this);
2460
2461         if (frametime) {
2462                 // physics frames: update anticheat stuff
2463                 anticheat_prethink(this);
2464         }
2465
2466         if (blockSpectators && frametime) {
2467                 // WORKAROUND: only use dropclient in server frames (frametime set).
2468                 // Never use it in cl_movement frames (frametime zero).
2469                 checkSpectatorBlock(this);
2470     }
2471
2472         zoomstate_set = false;
2473
2474         // Check for nameless players
2475         if (isInvisibleString(this.netname)) {
2476                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2477                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2478         }
2479         if (this.netname != CS(this).netname_previous) {
2480                 if (autocvar_sv_eventlog) {
2481                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2482         }
2483                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2484                 CS(this).netname_previous = strzone(this.netname);
2485         }
2486
2487         // version nagging
2488         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2489         CS(this).version_nagtime = 0;
2490         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2491             // git client
2492         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2493             // git server
2494             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2495         } else {
2496             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2497             if (r < 0) { // old client
2498                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2499             } else if (r > 0) { // old server
2500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2501             }
2502         }
2503     }
2504
2505         // GOD MODE info
2506         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2507         {
2508                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2509                 this.max_armorvalue = 0;
2510         }
2511
2512         if(IS_PLAYER(this))
2513         {
2514                 if (STAT(FROZEN, this) == 2)
2515                 {
2516                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2517                         this.health = max(1, this.revive_progress * start_health);
2518                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2519
2520                         if (this.revive_progress >= 1)
2521                                 Unfreeze(this);
2522                 }
2523                 else if (STAT(FROZEN, this) == 3)
2524                 {
2525                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2526                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2527
2528                         if (this.health < 1)
2529                         {
2530                                 if (this.vehicle)
2531                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2532                                 if(this.event_damage)
2533                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2534                         }
2535                         else if (this.revive_progress <= 0)
2536                                 Unfreeze(this);
2537                 }
2538         }
2539
2540         MUTATOR_CALLHOOK(PlayerPreThink, this);
2541
2542         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2543         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2544         {
2545                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2546                 {
2547                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2548                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2549                         {
2550                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2551                         }
2552                         else if(!it.owner)
2553                         {
2554                                 if(!it.team || SAME_TEAM(this, it))
2555                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2556                                 else if(autocvar_g_vehicles_steal)
2557                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2558                         }
2559                 });
2560
2561                 this.last_vehiclecheck = time + 1;
2562         }
2563
2564         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2565         {
2566                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2567                         PlayerUseKey(this);
2568                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2569         }
2570
2571         if (IS_REAL_CLIENT(this))
2572                 PrintWelcomeMessage(this);
2573
2574         if (IS_PLAYER(this)) {
2575                 if(!PlayerThink(this))
2576                         return;
2577         }
2578         else if (game_stopped || intermission_running) {
2579                 if(intermission_running)
2580                         IntermissionThink(this);
2581                 return;
2582         }
2583         else if (IS_OBSERVER(this)) {
2584                 ObserverThink(this);
2585         }
2586         else if (IS_SPEC(this)) {
2587                 SpectatorThink(this);
2588         }
2589
2590         // WEAPONTODO: Add weapon request for this
2591         if (!zoomstate_set) {
2592                 bool wep_zoomed = false;
2593                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2594                 {
2595                         .entity weaponentity = weaponentities[slot];
2596                         Weapon thiswep = this.(weaponentity).m_weapon;
2597                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2598                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2599                 }
2600                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2601     }
2602
2603         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2604         {
2605                 CS(this).teamkill_soundtime = 0;
2606
2607                 entity e = CS(this).teamkill_soundsource;
2608                 entity oldpusher = e.pusher;
2609                 e.pusher = this;
2610                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2611                 e.pusher = oldpusher;
2612         }
2613
2614         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2615                 CS(this).taunt_soundtime = 0;
2616                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2617         }
2618
2619         target_voicescript_next(this);
2620
2621         // WEAPONTODO: Move into weaponsystem somehow
2622         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2623         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2624         {
2625                 .entity weaponentity = weaponentities[slot];
2626                 if(this.(weaponentity).m_weapon == WEP_Null)
2627                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2628         }
2629 }
2630
2631 void DrownPlayer(entity this)
2632 {
2633         if(IS_DEAD(this))
2634                 return;
2635
2636         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2637         {
2638                 if(this.air_finished < time)
2639                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2640                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2641                 this.dmg = 2;
2642         }
2643         else if (this.air_finished < time)
2644         {       // drown!
2645                 if (this.pain_finished < time)
2646                 {
2647                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2648                         this.pain_finished = time + 0.5;
2649                 }
2650         }
2651 }
2652
2653 .bool move_qcphysics;
2654
2655 void Player_Physics(entity this)
2656 {
2657         set_movetype(this, this.move_movetype);
2658
2659         if(!this.move_qcphysics)
2660                 return;
2661
2662         if(!frametime && !CS(this).pm_frametime)
2663                 return;
2664
2665         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2666
2667         CS(this).pm_frametime = 0;
2668 }
2669
2670 /*
2671 =============
2672 PlayerPostThink
2673
2674 Called every frame for each client after the physics are run
2675 =============
2676 */
2677 void PlayerPostThink (entity this)
2678 {
2679         Player_Physics(this);
2680
2681         if (sv_maxidle > 0)
2682         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2683         if (IS_REAL_CLIENT(this))
2684         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2685         {
2686                 int totalClients = 0;
2687                 if(sv_maxidle_slots > 0)
2688                 {
2689                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2690                         {
2691                                 ++totalClients;
2692                         });
2693                 }
2694
2695                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2696                 { /* do nothing */ }
2697                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2698                 {
2699                         if (CS(this).idlekick_lasttimeleft)
2700                         {
2701                                 CS(this).idlekick_lasttimeleft = 0;
2702                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2703                         }
2704                 }
2705                 else
2706                 {
2707                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2708                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2709                                 if (!CS(this).idlekick_lasttimeleft)
2710                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2711                         }
2712                         if (timeleft <= 0) {
2713                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2714                                 dropclient(this);
2715                                 return;
2716                         }
2717                         else if (timeleft <= 10) {
2718                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2719                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2720                 }
2721                                 CS(this).idlekick_lasttimeleft = timeleft;
2722                         }
2723                 }
2724         }
2725
2726         CheatFrame(this);
2727
2728         if (game_stopped)
2729         {
2730                 this.solid = SOLID_NOT;
2731                 this.takedamage = DAMAGE_NO;
2732                 set_movetype(this, MOVETYPE_NONE);
2733         }
2734
2735         if (IS_PLAYER(this)) {
2736                 DrownPlayer(this);
2737                 UpdateChatBubble(this);
2738                 if (CS(this).impulse) ImpulseCommands(this);
2739                 if (game_stopped)
2740                 {
2741                         CSQCMODEL_AUTOUPDATE(this);
2742                         return;
2743                 }
2744                 GetPressedKeys(this);
2745         }
2746
2747         if (this.waypointsprite_attachedforcarrier) {
2748             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2749                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2750     }
2751
2752         playerdemo_write(this);
2753
2754         CSQCMODEL_AUTOUPDATE(this);
2755 }
2756
2757 // hack to copy the button fields from the client entity to the Client State
2758 void PM_UpdateButtons(entity this, entity store)
2759 {
2760         if(this.impulse)
2761                 store.impulse = this.impulse;
2762         this.impulse = 0;
2763
2764         store.button0 = this.button0;
2765         store.button2 = this.button2;
2766         store.button3 = this.button3;
2767         store.button4 = this.button4;
2768         store.button5 = this.button5;
2769         store.button6 = this.button6;
2770         store.button7 = this.button7;
2771         store.button8 = this.button8;
2772         store.button9 = this.button9;
2773         store.button10 = this.button10;
2774         store.button11 = this.button11;
2775         store.button12 = this.button12;
2776         store.button13 = this.button13;
2777         store.button14 = this.button14;
2778         store.button15 = this.button15;
2779         store.button16 = this.button16;
2780         store.buttonuse = this.buttonuse;
2781         store.buttonchat = this.buttonchat;
2782
2783         store.cursor_active = this.cursor_active;
2784         store.cursor_screen = this.cursor_screen;
2785         store.cursor_trace_start = this.cursor_trace_start;
2786         store.cursor_trace_endpos = this.cursor_trace_endpos;
2787         store.cursor_trace_ent = this.cursor_trace_ent;
2788
2789         store.ping = this.ping;
2790         store.ping_packetloss = this.ping_packetloss;
2791         store.ping_movementloss = this.ping_movementloss;
2792
2793         store.v_angle = this.v_angle;
2794         store.movement = this.movement;
2795 }