qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24 #include "scores_rules.qh"
  25
  26 #include "bot/api.qh"
  27
  28 #include "../common/ent_cs.qh"
  29 #include "../common/wepent.qh"
  30 #include <common/state.qh>
  31
  32 #include <common/effects/qc/globalsound.qh>
  33
  34 #include "../common/triggers/func/conveyor.qh"
  35 #include "../common/triggers/teleporters.qh"
  36
  37 #include "../common/vehicles/all.qh"
  38
  39 #include "weapons/hitplot.qh"
  40 #include "weapons/weaponsystem.qh"
  41
  42 #include "../common/net_notice.qh"
  43 #include "../common/net_linked.qh"
  44 #include "../common/physics/player.qh"
  45
  46 #include "../common/items/_mod.qh"
  47
  48 #include "../common/mutators/mutator/waypoints/all.qh"
  49
  50 #include "../common/triggers/subs.qh"
  51 #include "../common/triggers/triggers.qh"
  52 #include "../common/triggers/trigger/secret.qh"
  53
  54 #include "../common/minigames/sv_minigames.qh"
  55
  56 #include "../common/items/inventory.qh"
  57
  58 #include "../common/monsters/sv_monsters.qh"
  59
  60 #include "../lib/warpzone/server.qh"
  61
  62 STATIC_METHOD(Client, Add, void(Client this, int _team))
  63 {
  64     ClientConnect(this);
  65     TRANSMUTE(Player, this);
  66     this.frame = 12; // 7
  67     this.team = _team;
  68     PutClientInServer(this);
  69 }
  70
  71 void PutObserverInServer(entity this);
  72
  73 STATIC_METHOD(Client, Remove, void(Client this))
  74 {
  75     TRANSMUTE(Observer, this);
  76     PutClientInServer(this);
  77     ClientDisconnect(this);
  78 }
  79
  80 void send_CSQC_teamnagger() {
  81         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  82 }
  83
  84 int CountSpectators(entity player, entity to)
  85 {
  86         if(!player) { return 0; } // not sure how, but best to be safe
  87
  88         int spec_count = 0;
  89
  90         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  91         {
  92                 spec_count++;
  93         });
  94
  95         return spec_count;
  96 }
  97
  98 void WriteSpectators(entity player, entity to)
  99 {
 100         if(!player) { return; } // not sure how, but best to be safe
 101
 102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 103         {
 104                 WriteByte(MSG_ENTITY, num_for_edict(it));
 105         });
 106 }
 107
 108 bool ClientData_Send(entity this, entity to, int sf)
 109 {
 110         assert(to == this.owner, return false);
 111
 112         entity e = to;
 113         if (IS_SPEC(e)) e = e.enemy;
 114
 115         sf = 0;
 116         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 117         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 118         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 119         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 120
 121         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 122         WriteByte(MSG_ENTITY, sf);
 123
 124         if (sf & BIT(1))
 125                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 126
 127         if(sf & BIT(4))
 128         {
 129                 float specs = CountSpectators(e, to);
 130                 WriteByte(MSG_ENTITY, specs);
 131                 WriteSpectators(e, to);
 132         }
 133
 134         return true;
 135 }
 136
 137 void ClientData_Attach(entity this)
 138 {
 139         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 140         CS(this).clientdata.drawonlytoclient = this;
 141         CS(this).clientdata.owner = this;
 142 }
 143
 144 void ClientData_Detach(entity this)
 145 {
 146         delete(CS(this).clientdata);
 147         CS(this).clientdata = NULL;
 148 }
 149
 150 void ClientData_Touch(entity e)
 151 {
 152         CS(e).clientdata.SendFlags = 1;
 153
 154         // make it spectatable
 155         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 156 }
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = vec2(spot.angles);
 230         this.fixangle = true;
 231         // offset it so that the spectator spawns higher off the ground, looks better this way
 232         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 233         if (IS_REAL_CLIENT(this))
 234         {
 235             msg_entity = this;
 236             WriteByte(MSG_ONE, SVC_SETVIEW);
 237             WriteEntity(MSG_ONE, this);
 238         }
 239         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 240         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 241         if(!autocvar_g_debug_globalsounds)
 242         {
 243                 // needed for player sounds
 244                 this.model = "";
 245                 FixPlayermodel(this);
 246         }
 247         setmodel(this, MDL_Null);
 248         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 249         this.view_ofs = '0 0 0';
 250     }
 251
 252     RemoveGrapplingHooks(this);
 253         Portal_ClearAll(this);
 254         Unfreeze(this);
 255         SetSpectatee(this, NULL);
 256
 257         if (this.alivetime)
 258         {
 259                 if (!warmup_stage)
 260                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 261                 this.alivetime = 0;
 262         }
 263
 264         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 265
 266         WaypointSprite_PlayerDead(this);
 267
 268         if (mutator_returnvalue) {
 269             // mutator prevents resetting teams+score
 270         } else {
 271                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 272         this.frags = FRAGS_SPECTATOR;
 273         PlayerScore_Clear(this);  // clear scores when needed
 274     }
 275
 276         if (CS(this).killcount != FRAGS_SPECTATOR)
 277         {
 278                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 279                 if(!game_stopped)
 280                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 281                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 282
 283                 if(!CS(this).just_joined)
 284                         LogTeamchange(this.playerid, -1, 4);
 285                 else
 286                         CS(this).just_joined = false;
 287         }
 288
 289         accuracy_resend(this);
 290
 291         CS(this).spectatortime = time;
 292         if(this.bot_attack)
 293                 IL_REMOVE(g_bot_targets, this);
 294         this.bot_attack = false;
 295     this.hud = HUD_NORMAL;
 296         TRANSMUTE(Observer, this);
 297         this.iscreature = false;
 298         this.teleportable = TELEPORT_SIMPLE;
 299         if(this.damagedbycontents)
 300                 IL_REMOVE(g_damagedbycontents, this);
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revive_progress = 0;
 334         this.revival_time = 0;
 335
 336         this.items = 0;
 337         this.weapons = '0 0 0';
 338         this.drawonlytoclient = this;
 339
 340         this.weaponmodel = "";
 341         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 342         {
 343                 this.weaponentities[slot] = NULL;
 344         }
 345         this.exteriorweaponentity = NULL;
 346         CS(this).killcount = FRAGS_SPECTATOR;
 347         this.velocity = '0 0 0';
 348         this.avelocity = '0 0 0';
 349         this.punchangle = '0 0 0';
 350         this.punchvector = '0 0 0';
 351         this.oldvelocity = this.velocity;
 352         this.fire_endtime = -1;
 353         this.event_damage = func_null;
 354
 355         for(int slot = 0; slot < MAX_AXH; ++slot)
 356         {
 357                 entity axh = this.(AuxiliaryXhair[slot]);
 358                 this.(AuxiliaryXhair[slot]) = NULL;
 359
 360                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 361                         delete(axh);
 362         }
 363 }
 364
 365 int player_getspecies(entity this)
 366 {
 367         get_model_parameters(this.model, this.skin);
 368         int s = get_model_parameters_species;
 369         get_model_parameters(string_null, 0);
 370         if (s < 0) return SPECIES_HUMAN;
 371         return s;
 372 }
 373
 374 .float model_randomizer;
 375 void FixPlayermodel(entity player)
 376 {
 377         string defaultmodel = "";
 378         int defaultskin = 0;
 379         if(autocvar_sv_defaultcharacter)
 380         {
 381                 if(teamplay)
 382                 {
 383                         switch(player.team)
 384                         {
 385                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 386                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 387                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 388                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 389                         }
 390                 }
 391
 392                 if(defaultmodel == "")
 393                 {
 394                         defaultmodel = autocvar_sv_defaultplayermodel;
 395                         defaultskin = autocvar_sv_defaultplayerskin;
 396                 }
 397
 398                 int n = tokenize_console(defaultmodel);
 399                 if(n > 0)
 400                 {
 401                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 402                         // However, do NOT randomize if the player-selected model is in the list.
 403                         for (int i = 0; i < n; ++i)
 404                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 405                                         defaultmodel = argv(i);
 406                 }
 407
 408                 int i = strstrofs(defaultmodel, ":", 0);
 409                 if(i >= 0)
 410                 {
 411                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 412                         defaultmodel = substring(defaultmodel, 0, i);
 413                 }
 414         }
 415         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(!defaultskin)
 429                         defaultskin = autocvar_sv_defaultplayerskin;
 430         }
 431
 432         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 433         defaultmodel = M_ARGV(0, string);
 434         defaultskin = M_ARGV(1, int);
 435
 436         bool chmdl = false;
 437         int oldskin;
 438         if(defaultmodel != "")
 439         {
 440                 if (defaultmodel != player.model)
 441                 {
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, defaultmodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 oldskin = player.skin;
 450                 player.skin = defaultskin;
 451         } else {
 452                 if (player.playermodel != player.model || player.playermodel == "")
 453                 {
 454                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 455                         vector m1 = player.mins;
 456                         vector m2 = player.maxs;
 457                         setplayermodel (player, player.playermodel);
 458                         setsize (player, m1, m2);
 459                         chmdl = true;
 460                 }
 461
 462                 if(!autocvar_sv_defaultcharacterskin)
 463                 {
 464                         oldskin = player.skin;
 465                         player.skin = stof(player.playerskin);
 466                 }
 467                 else
 468                 {
 469                         oldskin = player.skin;
 470                         player.skin = defaultskin;
 471                 }
 472         }
 473
 474         if(chmdl || oldskin != player.skin) // model or skin has changed
 475         {
 476                 player.species = player_getspecies(player); // update species
 477                 if(!autocvar_g_debug_globalsounds)
 478                         UpdatePlayerSounds(player); // update skin sounds
 479         }
 480
 481         if(!teamplay)
 482                 if(strlen(autocvar_sv_defaultplayercolors))
 483                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 484                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 485 }
 486
 487 void PutPlayerInServer(entity this)
 488 {
 489         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 490
 491         PlayerState_attach(this);
 492         accuracy_resend(this);
 493
 494         if (this.team < 0)
 495                 JoinBestTeam(this, false, true);
 496
 497         entity spot = SelectSpawnPoint(this, false);
 498         if (!spot) {
 499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 500                 return; // spawn failed
 501         }
 502
 503         TRANSMUTE(Player, this);
 504
 505         CS(this).wasplayer = true;
 506         this.iscreature = true;
 507         this.teleportable = TELEPORT_NORMAL;
 508         if(!this.damagedbycontents)
 509                 IL_PUSH(g_damagedbycontents, this);
 510         this.damagedbycontents = true;
 511         set_movetype(this, MOVETYPE_WALK);
 512         this.solid = SOLID_SLIDEBOX;
 513         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 514         if (autocvar_g_playerclip_collisions)
 515                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 516         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 517                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 518         this.frags = FRAGS_PLAYER;
 519         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 520         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 521         if (autocvar__notarget)
 522                 this.flags |= FL_NOTARGET;
 523         this.takedamage = DAMAGE_AIM;
 524         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 525         this.dmg = 2; // WTF
 526
 527         if (warmup_stage) {
 528                 this.ammo_shells = warmup_start_ammo_shells;
 529                 this.ammo_nails = warmup_start_ammo_nails;
 530                 this.ammo_rockets = warmup_start_ammo_rockets;
 531                 this.ammo_cells = warmup_start_ammo_cells;
 532                 this.ammo_plasma = warmup_start_ammo_plasma;
 533                 this.ammo_fuel = warmup_start_ammo_fuel;
 534                 this.health = warmup_start_health;
 535                 this.armorvalue = warmup_start_armorvalue;
 536                 this.weapons = WARMUP_START_WEAPONS;
 537         } else {
 538                 this.ammo_shells = start_ammo_shells;
 539                 this.ammo_nails = start_ammo_nails;
 540                 this.ammo_rockets = start_ammo_rockets;
 541                 this.ammo_cells = start_ammo_cells;
 542                 this.ammo_plasma = start_ammo_plasma;
 543                 this.ammo_fuel = start_ammo_fuel;
 544                 this.health = start_health;
 545                 this.armorvalue = start_armorvalue;
 546                 this.weapons = start_weapons;
 547                 GivePlayerRandomWeapons(this, random_start_weapons_count,
 548                         cvar_string("g_random_start_weapons"), random_start_shells,
 549                         random_start_bullets, random_start_rockets, random_start_cells,
 550                         random_start_plasma);
 551         }
 552         SetSpectatee_status(this, 0);
 553
 554         PS(this).dual_weapons = '0 0 0';
 555
 556         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 557
 558         this.items = start_items;
 559
 560         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 561         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 562         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 563         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 564         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 565         // extend the pause of rotting if client was reset at the beginning of the countdown
 566         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 567                 float f = game_starttime - time;
 568                 this.spawnshieldtime += f;
 569                 this.pauserotarmor_finished += f;
 570                 this.pauserothealth_finished += f;
 571                 this.pauseregen_finished += f;
 572         }
 573         this.damageforcescale = 2;
 574         this.death_time = 0;
 575         this.respawn_flags = 0;
 576         this.respawn_time = 0;
 577         this.stat_respawn_time = 0;
 578         this.scale = autocvar_sv_player_scale;
 579         this.fade_time = 0;
 580         this.pain_frame = 0;
 581         this.pain_finished = 0;
 582         this.pushltime = 0;
 583         setthink(this, func_null); // players have no think function
 584         this.nextthink = 0;
 585         this.dmg_team = 0;
 586         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 587
 588         this.deadflag = DEAD_NO;
 589
 590         this.angles = spot.angles;
 591         this.angles_z = 0; // never spawn tilted even if the spot says to
 592         if (IS_BOT_CLIENT(this))
 593                 this.v_angle = this.angles;
 594         this.fixangle = true; // turn this way immediately
 595         this.oldvelocity = this.velocity = '0 0 0';
 596         this.avelocity = '0 0 0';
 597         this.punchangle = '0 0 0';
 598         this.punchvector = '0 0 0';
 599
 600         this.strength_finished = 0;
 601         this.invincible_finished = 0;
 602         this.fire_endtime = -1;
 603         this.revive_progress = 0;
 604         this.revival_time = 0;
 605         this.air_finished = time + 12;
 606
 607         entity spawnevent = new_pure(spawnevent);
 608         spawnevent.owner = this;
 609         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 610
 611         // Cut off any still running player sounds.
 612         stopsound(this, CH_PLAYER_SINGLE);
 613
 614         this.model = "";
 615         FixPlayermodel(this);
 616         this.drawonlytoclient = NULL;
 617
 618         this.viewloc = NULL;
 619
 620         this.crouch = false;
 621         this.view_ofs = STAT(PL_VIEW_OFS, this);
 622         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 623         this.spawnorigin = spot.origin;
 624         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 625         // don't reset back to last position, even if new position is stuck in solid
 626         this.oldorigin = this.origin;
 627         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 628         if(this.conveyor)
 629                 IL_REMOVE(g_conveyed, this);
 630         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 631         this.hud = HUD_NORMAL;
 632
 633         this.event_damage = PlayerDamage;
 634
 635         if(!this.bot_attack)
 636                 IL_PUSH(g_bot_targets, this);
 637         this.bot_attack = true;
 638         if(!this.monster_attack)
 639                 IL_PUSH(g_monster_targets, this);
 640         this.monster_attack = true;
 641         navigation_dynamicgoal_init(this, false);
 642
 643         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 644
 645         if (CS(this).killcount == FRAGS_SPECTATOR) {
 646                 PlayerScore_Clear(this);
 647                 CS(this).killcount = 0;
 648         }
 649
 650         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 651         {
 652                 .entity weaponentity = weaponentities[slot];
 653                 entity oldwep = this.(weaponentity);
 654                 CL_SpawnWeaponentity(this, weaponentity);
 655                 if(oldwep && oldwep.owner == this)
 656                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 657         }
 658         this.alpha = default_player_alpha;
 659         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 660         this.exteriorweaponentity.alpha = default_weapon_alpha;
 661
 662         this.speedrunning = false;
 663
 664         target_voicescript_clear(this);
 665
 666         // reset fields the weapons may use
 667         FOREACH(Weapons, true, {
 668                 it.wr_resetplayer(it, this);
 669                         // reload all reloadable weapons
 670                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 671                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 672                         {
 673                                 .entity weaponentity = weaponentities[slot];
 674                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 675                         }
 676                 }
 677         });
 678
 679         {
 680                 string s = spot.target;
 681                 spot.target = string_null;
 682                 SUB_UseTargets(spot, this, NULL);
 683                 spot.target = s;
 684         }
 685
 686         Unfreeze(this);
 687
 688         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 689
 690         if (autocvar_spawn_debug)
 691         {
 692                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 693                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 694         }
 695
 696         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 697         {
 698                 .entity weaponentity = weaponentities[slot];
 699                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 700                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 701                 else
 702                         this.(weaponentity).m_switchweapon = WEP_Null;
 703                 this.(weaponentity).m_weapon = WEP_Null;
 704                 this.(weaponentity).weaponname = "";
 705                 this.(weaponentity).m_switchingweapon = WEP_Null;
 706                 this.(weaponentity).cnt = -1;
 707         }
 708
 709         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 710
 711         if (!warmup_stage && !this.alivetime)
 712                 this.alivetime = time;
 713
 714         antilag_clear(this, CS(this));
 715 }
 716
 717 /** Called when a client spawns in the server */
 718 void PutClientInServer(entity this)
 719 {
 720         if (IS_BOT_CLIENT(this)) {
 721                 TRANSMUTE(Player, this);
 722         } else if (IS_REAL_CLIENT(this)) {
 723                 msg_entity = this;
 724                 WriteByte(MSG_ONE, SVC_SETVIEW);
 725                 WriteEntity(MSG_ONE, this);
 726         }
 727         if (game_stopped)
 728                 TRANSMUTE(Observer, this);
 729
 730         SetSpectatee(this, NULL);
 731
 732         // reset player keys
 733         if(PS(this))
 734                 PS(this).itemkeys = 0;
 735
 736         MUTATOR_CALLHOOK(PutClientInServer, this);
 737
 738         if (IS_OBSERVER(this)) {
 739                 PutObserverInServer(this);
 740         } else if (IS_PLAYER(this)) {
 741                 PutPlayerInServer(this);
 742         }
 743 }
 744
 745 void ClientInit_misc(entity this);
 746
 747 // TODO do we need all these fields, or should we stop autodetecting runtime
 748 // changes and just have a console command to update this?
 749 bool ClientInit_SendEntity(entity this, entity to, int sf)
 750 {
 751         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 752         return = true;
 753         msg_entity = to;
 754         // MSG_INIT replacement
 755         // TODO: make easier to use
 756         Registry_send_all();
 757         W_PROP_reload(MSG_ONE, to);
 758         ClientInit_misc(this);
 759         MUTATOR_CALLHOOK(Ent_Init);
 760 }
 761 void ClientInit_misc(entity this)
 762 {
 763         int channel = MSG_ONE;
 764         WriteHeader(channel, ENT_CLIENT_INIT);
 765         WriteByte(channel, g_nexball_meter_period * 32);
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 768         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 769         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 772         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 773         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 774
 775         if(sv_foginterval && world.fog != "")
 776                 WriteString(channel, world.fog);
 777         else
 778                 WriteString(channel, "");
 779         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 780         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 781         WriteByte(channel, serverflags);
 782         WriteCoord(channel, autocvar_g_trueaim_minrange);
 783 }
 784
 785 void ClientInit_CheckUpdate(entity this)
 786 {
 787         this.nextthink = time;
 788         if(this.count != autocvar_g_balance_armor_blockpercent)
 789         {
 790                 this.count = autocvar_g_balance_armor_blockpercent;
 791                 this.SendFlags |= 1;
 792         }
 793         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 794         {
 795                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 796                 this.SendFlags |= 1;
 797         }
 798 }
 799
 800 void ClientInit_Spawn()
 801 {
 802         entity e = new_pure(clientinit);
 803         setthink(e, ClientInit_CheckUpdate);
 804         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 805
 806         ClientInit_CheckUpdate(e);
 807 }
 808
 809 /*
 810 =============
 811 SetNewParms
 812 =============
 813 */
 814 void SetNewParms ()
 815 {
 816         // initialize parms for a new player
 817         parm1 = -(86400 * 366);
 818
 819         MUTATOR_CALLHOOK(SetNewParms);
 820 }
 821
 822 /*
 823 =============
 824 SetChangeParms
 825 =============
 826 */
 827 void SetChangeParms (entity this)
 828 {
 829         // save parms for level change
 830         parm1 = CS(this).parm_idlesince - time;
 831
 832         MUTATOR_CALLHOOK(SetChangeParms);
 833 }
 834
 835 /*
 836 =============
 837 DecodeLevelParms
 838 =============
 839 */
 840 void DecodeLevelParms(entity this)
 841 {
 842         // load parms
 843         CS(this).parm_idlesince = parm1;
 844         if (CS(this).parm_idlesince == -(86400 * 366))
 845                 CS(this).parm_idlesince = time;
 846
 847         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 848         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 849
 850         MUTATOR_CALLHOOK(DecodeLevelParms);
 851 }
 852
 853 /*
 854 =============
 855 ClientKill
 856
 857 Called when a client types 'kill' in the console
 858 =============
 859 */
 860
 861 .float clientkill_nexttime;
 862 void ClientKill_Now_TeamChange(entity this)
 863 {
 864         if(CS(this).killindicator_teamchange == -1)
 865         {
 866                 JoinBestTeam( this, false, true );
 867         }
 868         else if(CS(this).killindicator_teamchange == -2)
 869         {
 870                 if(blockSpectators)
 871                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 872                 PutObserverInServer(this);
 873         }
 874         else
 875                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 876         CS(this).killindicator_teamchange = 0;
 877 }
 878
 879 void ClientKill_Now(entity this)
 880 {
 881         if(this.vehicle)
 882         {
 883             vehicles_exit(this.vehicle, VHEF_RELEASE);
 884             if(!CS(this).killindicator_teamchange)
 885             {
 886             this.vehicle_health = -1;
 887             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 888             }
 889         }
 890
 891         if(this.killindicator && !wasfreed(this.killindicator))
 892                 delete(this.killindicator);
 893
 894         this.killindicator = NULL;
 895
 896         if(CS(this).killindicator_teamchange)
 897                 ClientKill_Now_TeamChange(this);
 898
 899         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 900                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 901
 902         // now I am sure the player IS dead
 903 }
 904 void KillIndicator_Think(entity this)
 905 {
 906         if (game_stopped)
 907         {
 908                 this.owner.killindicator = NULL;
 909                 delete(this);
 910                 return;
 911         }
 912
 913         if (this.owner.alpha < 0 && !this.owner.vehicle)
 914         {
 915                 this.owner.killindicator = NULL;
 916                 delete(this);
 917                 return;
 918         }
 919
 920         if(this.cnt <= 0)
 921         {
 922                 ClientKill_Now(this.owner);
 923                 return;
 924         }
 925     else if(this.health == 1) // health == 1 means that it's silent
 926     {
 927         this.nextthink = time + 1;
 928         this.cnt -= 1;
 929     }
 930         else
 931         {
 932                 if(this.cnt <= 10)
 933                         setmodel(this, MDL_NUM(this.cnt));
 934                 if(IS_REAL_CLIENT(this.owner))
 935                 {
 936                         if(this.cnt <= 10)
 937                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 938                 }
 939                 this.nextthink = time + 1;
 940                 this.cnt -= 1;
 941         }
 942 }
 943
 944 float clientkilltime;
 945 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 946 {
 947         float killtime;
 948         float starttime;
 949
 950         if (game_stopped)
 951                 return;
 952
 953         killtime = autocvar_g_balance_kill_delay;
 954
 955     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 956         return;
 957     killtime = M_ARGV(1, float);
 958
 959         CS(this).killindicator_teamchange = targetteam;
 960
 961     if(!this.killindicator)
 962         {
 963                 if(!IS_DEAD(this))
 964                 {
 965                         killtime = max(killtime, this.clientkill_nexttime - time);
 966                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 967                 }
 968
 969                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 970                 {
 971                         ClientKill_Now(this);
 972                 }
 973                 else
 974                 {
 975                         starttime = max(time, clientkilltime);
 976
 977                         this.killindicator = spawn();
 978                         this.killindicator.owner = this;
 979                         this.killindicator.scale = 0.5;
 980                         setattachment(this.killindicator, this, "");
 981                         setorigin(this.killindicator, '0 0 52');
 982                         setthink(this.killindicator, KillIndicator_Think);
 983                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 984                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 985                         this.killindicator.cnt = ceil(killtime);
 986                         this.killindicator.count = bound(0, ceil(killtime), 10);
 987                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 988
 989                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 990                         {
 991                                 it.killindicator = spawn();
 992                                 it.killindicator.owner = it;
 993                                 it.killindicator.scale = 0.5;
 994                                 setattachment(it.killindicator, it, "");
 995                                 setorigin(it.killindicator, '0 0 52');
 996                                 setthink(it.killindicator, KillIndicator_Think);
 997                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 998                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 999                                 it.killindicator.cnt = ceil(killtime);
1000                         });
1001                         this.lip = 0;
1002                 }
1003         }
1004         if(this.killindicator)
1005         {
1006                 if(targetteam == 0) // just die
1007                 {
1008                         this.killindicator.colormod = '0 0 0';
1009                         if(IS_REAL_CLIENT(this))
1010                         if(this.killindicator.cnt > 0)
1011                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1012                 }
1013                 else if(targetteam == -1) // auto
1014                 {
1015                         this.killindicator.colormod = '0 1 0';
1016                         if(IS_REAL_CLIENT(this))
1017                         if(this.killindicator.cnt > 0)
1018                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1019                 }
1020                 else if(targetteam == -2) // spectate
1021                 {
1022                         this.killindicator.colormod = '0.5 0.5 0.5';
1023                         if(IS_REAL_CLIENT(this))
1024                         if(this.killindicator.cnt > 0)
1025                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1026                 }
1027                 else
1028                 {
1029                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1030                         if(IS_REAL_CLIENT(this))
1031                         if(this.killindicator.cnt > 0)
1032                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1033                 }
1034         }
1035
1036 }
1037
1038 void ClientKill (entity this)
1039 {
1040         if(game_stopped) return;
1041         if(this.player_blocked) return;
1042         if(STAT(FROZEN, this)) return;
1043
1044         ClientKill_TeamChange(this, 0);
1045 }
1046
1047 void FixClientCvars(entity e)
1048 {
1049         // send prediction settings to the client
1050         stuffcmd(e, "\nin_bindmap 0 0\n");
1051         if(autocvar_g_antilag == 3) // client side hitscan
1052                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1053         if(autocvar_sv_gentle)
1054                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1055
1056         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1057         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1058
1059         MUTATOR_CALLHOOK(FixClientCvars, e);
1060 }
1061
1062 bool findinlist_abbrev(string tofind, string list)
1063 {
1064         if(list == "" || tofind == "")
1065                 return false; // empty list or search, just return
1066
1067         // this function allows abbreviated strings!
1068         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1069         {
1070                 return true;
1071         });
1072
1073         return false;
1074 }
1075
1076 bool PlayerInIPList(entity p, string iplist)
1077 {
1078         // some safety checks (never allow local?)
1079         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1080                 return false;
1081
1082         return findinlist_abbrev(p.netaddress, iplist);
1083 }
1084
1085 bool PlayerInIDList(entity p, string idlist)
1086 {
1087         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1088         if(!p.crypto_idfp)
1089                 return false;
1090
1091         return findinlist_abbrev(p.crypto_idfp, idlist);
1092 }
1093
1094 bool PlayerInList(entity player, string list)
1095 {
1096         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1097 }
1098
1099 #ifdef DP_EXT_PRECONNECT
1100 /*
1101 =============
1102 ClientPreConnect
1103
1104 Called once (not at each match start) when a client begins a connection to the server
1105 =============
1106 */
1107 void ClientPreConnect(entity this)
1108 {
1109         if(autocvar_sv_eventlog)
1110         {
1111                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1112                         this.playerid,
1113                         etof(this),
1114                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1115                 ));
1116         }
1117 }
1118 #endif
1119
1120 /**
1121 =============
1122 ClientConnect
1123
1124 Called when a client connects to the server
1125 =============
1126 */
1127 void ClientConnect(entity this)
1128 {
1129         if (Ban_MaybeEnforceBanOnce(this)) return;
1130         assert(!IS_CLIENT(this), return);
1131         this.flags |= FL_CLIENT;
1132         assert(player_count >= 0, player_count = 0);
1133
1134 #ifdef WATERMARK
1135         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1136 #endif
1137         TRANSMUTE(Client, this);
1138         CS(this).version_nagtime = time + 10 + random() * 10;
1139
1140         // identify the right forced team
1141         if (autocvar_g_campaign)
1142         {
1143                 if (IS_REAL_CLIENT(this)) // only players, not bots
1144                 {
1145                         switch (autocvar_g_campaign_forceteam)
1146                         {
1147                                 case 1: this.team_forced = NUM_TEAM_1; break;
1148                                 case 2: this.team_forced = NUM_TEAM_2; break;
1149                                 case 3: this.team_forced = NUM_TEAM_3; break;
1150                                 case 4: this.team_forced = NUM_TEAM_4; break;
1151                                 default: this.team_forced = 0;
1152                         }
1153                 }
1154         }
1155         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1156         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1157         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1158         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1159         else switch (autocvar_g_forced_team_otherwise)
1160         {
1161                 default: this.team_forced = 0; break;
1162                 case "red": this.team_forced = NUM_TEAM_1; break;
1163                 case "blue": this.team_forced = NUM_TEAM_2; break;
1164                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1165                 case "pink": this.team_forced = NUM_TEAM_4; break;
1166                 case "spectate":
1167                 case "spectator":
1168                         this.team_forced = -1;
1169                         break;
1170         }
1171         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1172
1173     {
1174         int id = this.playerid;
1175         this.playerid = 0; // silent
1176             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1177             this.playerid = id;
1178     }
1179
1180         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1181                 TRANSMUTE(Observer, this);
1182         } else {
1183                 if (!teamplay || autocvar_g_balance_teams) {
1184                         TRANSMUTE(Player, this);
1185                         campaign_bots_may_start = true;
1186                 } else {
1187                         TRANSMUTE(Observer, this); // do it anyway
1188                 }
1189         }
1190
1191         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1192
1193         // always track bots, don't ask for cl_allow_uidtracking
1194         if (IS_BOT_CLIENT(this))
1195                 PlayerStats_GameReport_AddPlayer(this);
1196         else
1197                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1198
1199         if (autocvar_sv_eventlog)
1200                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1201
1202         LogTeamchange(this.playerid, this.team, 1);
1203
1204         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1205
1206         CS(this).netname_previous = strzone(this.netname);
1207
1208         if(teamplay && IS_PLAYER(this))
1209                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1210         else
1211                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1212
1213         stuffcmd(this, clientstuff, "\n");
1214         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1215
1216         FixClientCvars(this);
1217
1218         // get version info from player
1219         stuffcmd(this, "cmd clientversion $gameversion\n");
1220
1221         // notify about available teams
1222         if (teamplay)
1223         {
1224                 CheckAllowedTeams(this);
1225                 int t = 0;
1226                 if (c1 >= 0) t |= BIT(0);
1227                 if (c2 >= 0) t |= BIT(1);
1228                 if (c3 >= 0) t |= BIT(2);
1229                 if (c4 >= 0) t |= BIT(3);
1230                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1231         }
1232         else
1233         {
1234                 stuffcmd(this, "set _teams_available 0\n");
1235         }
1236
1237         bot_relinkplayerlist();
1238
1239         CS(this).spectatortime = time;
1240         if (blockSpectators)
1241         {
1242                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1243         }
1244
1245         CS(this).jointime = time;
1246
1247         if (IS_REAL_CLIENT(this))
1248         {
1249                 if (g_weaponarena_weapons == WEPSET(TUBA))
1250                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1251         }
1252
1253         if (!sv_foginterval && world.fog != "")
1254                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1255
1256         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1257                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1258                         send_CSQC_teamnagger();
1259
1260         CSQCMODEL_AUTOINIT(this);
1261
1262         CS(this).model_randomizer = random();
1263
1264         if (IS_REAL_CLIENT(this))
1265                 sv_notice_join(this);
1266
1267         // update physics stats (players can spawn before physics runs)
1268         Physics_UpdateStats(this);
1269
1270         IL_EACH(g_initforplayer, it.init_for_player, {
1271                 it.init_for_player(it, this);
1272         });
1273
1274         MUTATOR_CALLHOOK(ClientConnect, this);
1275
1276         if (IS_REAL_CLIENT(this))
1277         {
1278                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1279                 {
1280                         CS(this).motd_actived_time = -1;
1281                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1282                 }
1283         }
1284 }
1285 /*
1286 =============
1287 ClientDisconnect
1288
1289 Called when a client disconnects from the server
1290 =============
1291 */
1292 .entity chatbubbleentity;
1293 void ReadyCount();
1294 void ClientDisconnect(entity this)
1295 {
1296         assert(IS_CLIENT(this), return);
1297
1298         PlayerStats_GameReport_FinalizePlayer(this);
1299         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1300         if (CS(this).active_minigame) part_minigame(this);
1301         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1302
1303         if (autocvar_sv_eventlog)
1304                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1305
1306         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1307
1308         if(IS_SPEC(this))
1309                 SetSpectatee(this, NULL);
1310
1311     MUTATOR_CALLHOOK(ClientDisconnect, this);
1312
1313         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1314         ClientState_detach(this);
1315
1316         Portal_ClearAll(this);
1317
1318         Unfreeze(this);
1319
1320         RemoveGrapplingHooks(this);
1321
1322         // Here, everything has been done that requires this player to be a client.
1323
1324         this.flags &= ~FL_CLIENT;
1325
1326         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1327         if (this.killindicator) delete(this.killindicator);
1328
1329         WaypointSprite_PlayerGone(this);
1330
1331         bot_relinkplayerlist();
1332
1333         if (this.clientstatus) strunzone(this.clientstatus);
1334         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1335         if (this.personal) delete(this.personal);
1336
1337         this.playerid = 0;
1338         ReadyCount();
1339         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1340
1341         ONREMOVE(this);
1342 }
1343
1344 void ChatBubbleThink(entity this)
1345 {
1346         this.nextthink = time;
1347         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1348         {
1349                 if(this.owner) // but why can that ever be NULL?
1350                         this.owner.chatbubbleentity = NULL;
1351                 delete(this);
1352                 return;
1353         }
1354
1355         this.mdl = "";
1356
1357         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1358         {
1359                 if ( CS(this.owner).active_minigame )
1360                         this.mdl = "models/sprites/minigame_busy.iqm";
1361                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1362                         this.mdl = "models/misc/chatbubble.spr";
1363         }
1364
1365         if ( this.model != this.mdl )
1366                 _setmodel(this, this.mdl);
1367
1368 }
1369
1370 void UpdateChatBubble(entity this)
1371 {
1372         if (this.alpha < 0)
1373                 return;
1374         // spawn a chatbubble entity if needed
1375         if (!this.chatbubbleentity)
1376         {
1377                 this.chatbubbleentity = new(chatbubbleentity);
1378                 this.chatbubbleentity.owner = this;
1379                 this.chatbubbleentity.exteriormodeltoclient = this;
1380                 setthink(this.chatbubbleentity, ChatBubbleThink);
1381                 this.chatbubbleentity.nextthink = time;
1382                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1383                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1384                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1385                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1386                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1387                 //this.chatbubbleentity.model = "";
1388                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1389         }
1390 }
1391
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = this.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) this.colormod = '0 0 0';
1401         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1406         else this.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(entity this)
1410 {
1411         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1412         {
1413                 this.solid = SOLID_NOT;
1414                 this.takedamage = DAMAGE_NO;
1415                 set_movetype(this, MOVETYPE_FLY);
1416                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1417                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1418                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1419                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1420                 if(autocvar_g_respawn_ghosts_maxtime)
1421                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1422         }
1423
1424         CopyBody(this, 1);
1425
1426         this.effects |= EF_NODRAW; // prevent another CopyBody
1427         PutClientInServer(this);
1428 }
1429
1430 void play_countdown(entity this, float finished, Sound samp)
1431 {
1432     TC(Sound, samp);
1433         if(IS_REAL_CLIENT(this))
1434                 if(floor(finished - time - frametime) != floor(finished - time))
1435                         if(finished - time < 6)
1436                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1437 }
1438
1439 void player_powerups(entity this)
1440 {
1441         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1442         int items_prev = this.items;
1443
1444         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1445                 this.modelflags |= MF_ROCKET;
1446         else
1447                 this.modelflags &= ~MF_ROCKET;
1448
1449         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1450
1451         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1452                 return;
1453
1454         Fire_ApplyDamage(this);
1455         Fire_ApplyEffect(this);
1456
1457         if (!g_instagib)
1458         {
1459                 if (this.items & ITEM_Strength.m_itemid)
1460                 {
1461                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1462                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1463                         if (time > this.strength_finished)
1464                         {
1465                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1466                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1468                         }
1469                 }
1470                 else
1471                 {
1472                         if (time < this.strength_finished)
1473                         {
1474                                 this.items = this.items | ITEM_Strength.m_itemid;
1475                                 if(!g_cts)
1476                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1478                         }
1479                 }
1480                 if (this.items & ITEM_Shield.m_itemid)
1481                 {
1482                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1483                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1484                         if (time > this.invincible_finished)
1485                         {
1486                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1487                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1488                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1489                         }
1490                 }
1491                 else
1492                 {
1493                         if (time < this.invincible_finished)
1494                         {
1495                                 this.items = this.items | ITEM_Shield.m_itemid;
1496                                 if(!g_cts)
1497                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1498                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1499                         }
1500                 }
1501                 if (this.items & IT_SUPERWEAPON)
1502                 {
1503                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1504                         {
1505                                 this.superweapons_finished = 0;
1506                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1507                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1509                         }
1510                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1511                         {
1512                                 // don't let them run out
1513                         }
1514                         else
1515                         {
1516                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1517                                 if (time > this.superweapons_finished)
1518                                 {
1519                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1520                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1521                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1522                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1523                                 }
1524                         }
1525                 }
1526                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1527                 {
1528                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1529                         {
1530                                 this.items = this.items | IT_SUPERWEAPON;
1531                                 if(!g_cts)
1532                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1534                         }
1535                         else
1536                         {
1537                                 this.superweapons_finished = 0;
1538                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1539                         }
1540                 }
1541                 else
1542                 {
1543                         this.superweapons_finished = 0;
1544                 }
1545         }
1546
1547         if(autocvar_g_nodepthtestplayers)
1548                 this.effects = this.effects | EF_NODEPTHTEST;
1549
1550         if(autocvar_g_fullbrightplayers)
1551                 this.effects = this.effects | EF_FULLBRIGHT;
1552
1553         if (time >= game_starttime)
1554         if (time < this.spawnshieldtime)
1555                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1556
1557         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1558 }
1559
1560 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1561 {
1562         if(current > stable)
1563                 return current;
1564         else if(current > stable - 0.25) // when close enough, "snap"
1565                 return stable;
1566         else
1567                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1568 }
1569
1570 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1571 {
1572         if(current < stable)
1573                 return current;
1574         else if(current < stable + 0.25) // when close enough, "snap"
1575                 return stable;
1576         else
1577                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1578 }
1579
1580 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1581 {
1582         if(current > rotstable)
1583         {
1584                 if(rotframetime > 0)
1585                 {
1586                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1587                         current = max(rotstable, current - rotlinear * rotframetime);
1588                 }
1589         }
1590         else if(current < regenstable)
1591         {
1592                 if(regenframetime > 0)
1593                 {
1594                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1595                         current = min(regenstable, current + regenlinear * regenframetime);
1596                 }
1597         }
1598
1599         if(current > limit)
1600                 current = limit;
1601
1602         return current;
1603 }
1604
1605 void player_regen(entity this)
1606 {
1607         float max_mod, regen_mod, rot_mod, limit_mod;
1608         max_mod = regen_mod = rot_mod = limit_mod = 1;
1609
1610         float regen_health = autocvar_g_balance_health_regen;
1611         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1612         float regen_health_rot = autocvar_g_balance_health_rot;
1613         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1614         float regen_health_stable = autocvar_g_balance_health_regenstable;
1615         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1616         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1617                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1618         max_mod = M_ARGV(1, float);
1619         regen_mod = M_ARGV(2, float);
1620         rot_mod = M_ARGV(3, float);
1621         limit_mod = M_ARGV(4, float);
1622         regen_health = M_ARGV(5, float);
1623         regen_health_linear = M_ARGV(6, float);
1624         regen_health_rot = M_ARGV(7, float);
1625         regen_health_rotlinear = M_ARGV(8, float);
1626         regen_health_stable = M_ARGV(9, float);
1627         regen_health_rotstable = M_ARGV(10, float);
1628
1629         if(!mutator_returnvalue)
1630         if(!STAT(FROZEN, this))
1631         {
1632                 float mina, maxa, limith, limita;
1633                 maxa = autocvar_g_balance_armor_rotstable;
1634                 mina = autocvar_g_balance_armor_regenstable;
1635                 limith = GetResourceLimit(RESOURCE_HEALTH);
1636                 limita = GetResourceLimit(RESOURCE_ARMOR);
1637
1638                 regen_health_rotstable = regen_health_rotstable * max_mod;
1639                 regen_health_stable = regen_health_stable * max_mod;
1640                 limith = limith * limit_mod;
1641                 limita = limita * limit_mod;
1642
1643                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1644                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1645         }
1646
1647         // if player rotted to death...  die!
1648         // check this outside above checks, as player may still be able to rot to death
1649         if(this.health < 1)
1650         {
1651                 if(this.vehicle)
1652                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1653                 if(this.event_damage)
1654                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1655         }
1656
1657         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1658         {
1659                 float minf, maxf, limitf;
1660
1661                 maxf = autocvar_g_balance_fuel_rotstable;
1662                 minf = autocvar_g_balance_fuel_regenstable;
1663                 limitf = GetResourceLimit(RESOURCE_FUEL);
1664
1665                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1666         }
1667         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1668         // TODO: Remove this hack when all code uses GivePlayerHealth and
1669         // GivePlayerArmor.
1670         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1671         {
1672                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1673         }
1674         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1675         {
1676                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1677         }
1678         // End hack.
1679 }
1680
1681 bool zoomstate_set;
1682 void SetZoomState(entity this, float newzoom)
1683 {
1684         if(newzoom != CS(this).zoomstate)
1685         {
1686                 CS(this).zoomstate = newzoom;
1687                 ClientData_Touch(this);
1688         }
1689         zoomstate_set = true;
1690 }
1691
1692 void GetPressedKeys(entity this)
1693 {
1694         MUTATOR_CALLHOOK(GetPressedKeys, this);
1695         int keys = STAT(PRESSED_KEYS, this);
1696         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1697         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1698         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1699         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1700
1701         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1702         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1703         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1704         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1705         CS(this).pressedkeys = keys; // store for other users
1706
1707         STAT(PRESSED_KEYS, this) = keys;
1708 }
1709
1710 /*
1711 ======================
1712 spectate mode routines
1713 ======================
1714 */
1715
1716 void SpectateCopy(entity this, entity spectatee)
1717 {
1718     TC(Client, this); TC(Client, spectatee);
1719
1720         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1721         PS(this) = PS(spectatee);
1722         this.armortype = spectatee.armortype;
1723         this.armorvalue = spectatee.armorvalue;
1724         this.ammo_cells = spectatee.ammo_cells;
1725         this.ammo_plasma = spectatee.ammo_plasma;
1726         this.ammo_shells = spectatee.ammo_shells;
1727         this.ammo_nails = spectatee.ammo_nails;
1728         this.ammo_rockets = spectatee.ammo_rockets;
1729         this.ammo_fuel = spectatee.ammo_fuel;
1730         this.clip_load = spectatee.clip_load;
1731         this.clip_size = spectatee.clip_size;
1732         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1733         this.health = spectatee.health;
1734         CS(this).impulse = 0;
1735         this.items = spectatee.items;
1736         this.last_pickup = spectatee.last_pickup;
1737         this.hit_time = spectatee.hit_time;
1738         this.strength_finished = spectatee.strength_finished;
1739         this.invincible_finished = spectatee.invincible_finished;
1740         this.superweapons_finished = spectatee.superweapons_finished;
1741         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1742         this.weapons = spectatee.weapons;
1743         this.vortex_charge = spectatee.vortex_charge;
1744         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1745         this.hagar_load = spectatee.hagar_load;
1746         this.arc_heat_percent = spectatee.arc_heat_percent;
1747         this.minelayer_mines = spectatee.minelayer_mines;
1748         this.punchangle = spectatee.punchangle;
1749         this.view_ofs = spectatee.view_ofs;
1750         this.velocity = spectatee.velocity;
1751         this.dmg_take = spectatee.dmg_take;
1752         this.dmg_save = spectatee.dmg_save;
1753         this.dmg_inflictor = spectatee.dmg_inflictor;
1754         this.v_angle = spectatee.v_angle;
1755         this.angles = spectatee.v_angle;
1756         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1757         this.revive_progress = spectatee.revive_progress;
1758         this.viewloc = spectatee.viewloc;
1759         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1760                 this.fixangle = true;
1761         setorigin(this, spectatee.origin);
1762         setsize(this, spectatee.mins, spectatee.maxs);
1763         SetZoomState(this, CS(spectatee).zoomstate);
1764
1765         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1766         {
1767                 .entity weaponentity = weaponentities[slot];
1768                 this.(weaponentity) = spectatee.(weaponentity);
1769         }
1770
1771         for(int slot = 0; slot < MAX_AXH; ++slot)
1772         {
1773                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1774         }
1775
1776     anticheat_spectatecopy(this, spectatee);
1777         this.hud = spectatee.hud;
1778         if(spectatee.vehicle)
1779     {
1780         this.angles = spectatee.v_angle;
1781
1782         //this.fixangle = false;
1783         //this.velocity = spectatee.vehicle.velocity;
1784         this.vehicle_health = spectatee.vehicle_health;
1785         this.vehicle_shield = spectatee.vehicle_shield;
1786         this.vehicle_energy = spectatee.vehicle_energy;
1787         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1788         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1789         this.vehicle_reload1 = spectatee.vehicle_reload1;
1790         this.vehicle_reload2 = spectatee.vehicle_reload2;
1791
1792         //msg_entity = this;
1793
1794        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1795             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1796            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1797            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1798
1799         //WriteByte (MSG_ONE, SVC_SETVIEW);
1800         //    WriteEntity(MSG_ONE, this);
1801         //makevectors(spectatee.v_angle);
1802         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1803     }
1804 }
1805
1806 bool SpectateUpdate(entity this)
1807 {
1808         if(!this.enemy)
1809                 return false;
1810
1811         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1812         {
1813                 SetSpectatee(this, NULL);
1814                 return false;
1815         }
1816
1817         SpectateCopy(this, this.enemy);
1818
1819         return true;
1820 }
1821
1822 bool SpectateSet(entity this)
1823 {
1824         if(!IS_PLAYER(this.enemy))
1825                 return false;
1826
1827         ClientData_Touch(this.enemy);
1828
1829         msg_entity = this;
1830         WriteByte(MSG_ONE, SVC_SETVIEW);
1831         WriteEntity(MSG_ONE, this.enemy);
1832         set_movetype(this, MOVETYPE_NONE);
1833         accuracy_resend(this);
1834
1835         if(!SpectateUpdate(this))
1836                 PutObserverInServer(this);
1837
1838         return true;
1839 }
1840
1841 void SetSpectatee_status(entity this, int spectatee_num)
1842 {
1843         int oldspectatee_status = CS(this).spectatee_status;
1844         CS(this).spectatee_status = spectatee_num;
1845
1846         if (CS(this).spectatee_status != oldspectatee_status)
1847         {
1848                 ClientData_Touch(this);
1849                 if (g_race || g_cts) race_InitSpectator();
1850         }
1851 }
1852
1853 void SetSpectatee(entity this, entity spectatee)
1854 {
1855         if(IS_BOT_CLIENT(this))
1856                 return; // bots abuse .enemy, this code is useless to them
1857
1858         entity old_spectatee = this.enemy;
1859
1860         this.enemy = spectatee;
1861
1862         // WEAPONTODO
1863         // these are required to fix the spectator bug with arc
1864         if(old_spectatee)
1865         {
1866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1867                 {
1868                         .entity weaponentity = weaponentities[slot];
1869                         if(old_spectatee.(weaponentity).arc_beam)
1870                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1871                 }
1872         }
1873         if(this.enemy)
1874         {
1875                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1876                 {
1877                         .entity weaponentity = weaponentities[slot];
1878                         if(this.enemy.(weaponentity).arc_beam)
1879                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1880                 }
1881         }
1882
1883         if (this.enemy)
1884                 SetSpectatee_status(this, etof(this.enemy));
1885
1886         // needed to update spectator list
1887         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1888 }
1889
1890 bool Spectate(entity this, entity pl)
1891 {
1892         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1893                 return false;
1894         pl = M_ARGV(1, entity);
1895
1896         SetSpectatee(this, pl);
1897         return SpectateSet(this);
1898 }
1899
1900 bool SpectateNext(entity this)
1901 {
1902         entity ent = find(this.enemy, classname, STR_PLAYER);
1903
1904         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1905                 ent = M_ARGV(1, entity);
1906         else if (!ent)
1907                 ent = find(ent, classname, STR_PLAYER);
1908
1909         if(ent) { SetSpectatee(this, ent); }
1910
1911         return SpectateSet(this);
1912 }
1913
1914 bool SpectatePrev(entity this)
1915 {
1916         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1917         entity ent = findchain(classname, STR_PLAYER);
1918         if (!ent) // no player
1919                 return false;
1920
1921         entity first = ent;
1922         // skip players until current spectated player
1923         if(this.enemy)
1924         while(ent && ent != this.enemy)
1925                 ent = ent.chain;
1926
1927         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1928         {
1929                 case MUT_SPECPREV_FOUND:
1930                     ent = M_ARGV(1, entity);
1931                     break;
1932                 case MUT_SPECPREV_RETURN:
1933                     return true;
1934                 case MUT_SPECPREV_CONTINUE:
1935                 default:
1936                 {
1937                         if(ent.chain)
1938                                 ent = ent.chain;
1939                         else
1940                                 ent = first;
1941                         break;
1942                 }
1943         }
1944
1945         SetSpectatee(this, ent);
1946         return SpectateSet(this);
1947 }
1948
1949 /*
1950 =============
1951 ShowRespawnCountdown()
1952
1953 Update a respawn countdown display.
1954 =============
1955 */
1956 void ShowRespawnCountdown(entity this)
1957 {
1958         float number;
1959         if(!IS_DEAD(this)) // just respawned?
1960                 return;
1961         else
1962         {
1963                 number = ceil(this.respawn_time - time);
1964                 if(number <= 0)
1965                         return;
1966                 if(number <= this.respawn_countdown)
1967                 {
1968                         this.respawn_countdown = number - 1;
1969                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1970                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1971                 }
1972         }
1973 }
1974
1975 .bool team_selected;
1976 bool ShowTeamSelection(entity this)
1977 {
1978         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1979                 return false;
1980         stuffcmd(this, "menu_showteamselect\n");
1981         return true;
1982 }
1983 void Join(entity this)
1984 {
1985         TRANSMUTE(Player, this);
1986
1987         if(!this.team_selected)
1988         if(autocvar_g_campaign || autocvar_g_balance_teams)
1989                 JoinBestTeam(this, false, true);
1990
1991         if(autocvar_g_campaign)
1992                 campaign_bots_may_start = true;
1993
1994         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1995
1996         PutClientInServer(this);
1997
1998         if(IS_PLAYER(this))
1999         if(teamplay && this.team != -1)
2000                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2001         else
2002                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2003         this.team_selected = false;
2004 }
2005
2006 /**
2007  * Determines whether the player is allowed to join. This depends on cvar
2008  * g_maxplayers, if it isn't used this function always return true, otherwise
2009  * it checks whether the number of currently playing players exceeds g_maxplayers.
2010  * @return int number of free slots for players, 0 if none
2011  */
2012 int nJoinAllowed(entity this, entity ignore)
2013 {
2014         if(!ignore)
2015         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2016         // so report 0 free slots if restricted
2017         {
2018                 if(autocvar_g_forced_team_otherwise == "spectate")
2019                         return 0;
2020                 if(autocvar_g_forced_team_otherwise == "spectator")
2021                         return 0;
2022         }
2023
2024         if(this && this.team_forced < 0)
2025                 return 0; // forced spectators can never join
2026
2027         // TODO simplify this
2028         int totalClients = 0;
2029         int currentlyPlaying = 0;
2030         FOREACH_CLIENT(true, {
2031                 if(it != ignore)
2032                         ++totalClients;
2033                 if(IS_REAL_CLIENT(it))
2034                 if(IS_PLAYER(it) || it.caplayer)
2035                         ++currentlyPlaying;
2036         });
2037
2038         float free_slots = 0;
2039         if (!autocvar_g_maxplayers)
2040                 free_slots = maxclients - totalClients;
2041         else if(currentlyPlaying < autocvar_g_maxplayers)
2042                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2043
2044         static float join_prevent_msg_time = 0;
2045         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2046         {
2047                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2048                 join_prevent_msg_time = time + 3;
2049         }
2050
2051         return free_slots;
2052 }
2053
2054 /**
2055  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2056  * g_maxplayers_spectator_blocktime seconds
2057  */
2058 void checkSpectatorBlock(entity this)
2059 {
2060         if(IS_SPEC(this) || IS_OBSERVER(this))
2061         if(!this.caplayer)
2062         if(IS_REAL_CLIENT(this))
2063         {
2064                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2065                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2066                         dropclient(this);
2067                 }
2068         }
2069 }
2070
2071 void PrintWelcomeMessage(entity this)
2072 {
2073         if(CS(this).motd_actived_time == 0)
2074         {
2075                 if (autocvar_g_campaign) {
2076                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2077                                 CS(this).motd_actived_time = time;
2078                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2079                         }
2080                 } else {
2081                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2082                                 CS(this).motd_actived_time = time;
2083                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2084                         }
2085                 }
2086         }
2087         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2088         {
2089                 if (autocvar_g_campaign) {
2090                         if (PHYS_INPUT_BUTTON_INFO(this))
2091                                 CS(this).motd_actived_time = time;
2092                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2093                                 CS(this).motd_actived_time = 0;
2094                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2095                         }
2096                 } else {
2097                         if (PHYS_INPUT_BUTTON_INFO(this))
2098                                 CS(this).motd_actived_time = time;
2099                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2100                                 CS(this).motd_actived_time = 0;
2101                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2102                         }
2103                 }
2104         }
2105         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2106         {
2107                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2108                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2109                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2110                 {
2111                         // instanctly hide MOTD
2112                         CS(this).motd_actived_time = 0;
2113                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2114                 }
2115         }
2116 }
2117
2118 bool joinAllowed(entity this)
2119 {
2120         if (CS(this).version_mismatch) return false;
2121         if (!nJoinAllowed(this, this)) return false;
2122         if (teamplay && lockteams) return false;
2123         if (ShowTeamSelection(this)) return false;
2124         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2125         return true;
2126 }
2127
2128 .int items_added;
2129 bool PlayerThink(entity this)
2130 {
2131         if (game_stopped || intermission_running) {
2132                 this.modelflags &= ~MF_ROCKET;
2133                 if(intermission_running)
2134                         IntermissionThink(this);
2135                 return false;
2136         }
2137
2138         if (timeout_status == TIMEOUT_ACTIVE) {
2139         // don't allow the player to turn around while game is paused
2140                 // FIXME turn this into CSQC stuff
2141                 this.v_angle = this.lastV_angle;
2142                 this.angles = this.lastV_angle;
2143                 this.fixangle = true;
2144         }
2145
2146         if (frametime) player_powerups(this);
2147
2148         if (IS_DEAD(this)) {
2149                 if (this.personal && g_race_qualifying) {
2150                         if (time > this.respawn_time) {
2151                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2152                                 respawn(this);
2153                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2154                         }
2155                 } else {
2156                         if (frametime) player_anim(this);
2157
2158                         if (this.respawn_flags & RESPAWN_DENY)
2159                         {
2160                                 STAT(RESPAWN_TIME, this) = 0;
2161                                 return false;
2162                         }
2163
2164                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2165
2166                         switch(this.deadflag)
2167                         {
2168                                 case DEAD_DYING:
2169                                 {
2170                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2171                                                 this.deadflag = DEAD_RESPAWNING;
2172                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2173                                                 this.deadflag = DEAD_DEAD;
2174                                         break;
2175                                 }
2176                                 case DEAD_DEAD:
2177                                 {
2178                                         if (button_pressed)
2179                                                 this.deadflag = DEAD_RESPAWNABLE;
2180                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2181                                                 this.deadflag = DEAD_RESPAWNING;
2182                                         break;
2183                                 }
2184                                 case DEAD_RESPAWNABLE:
2185                                 {
2186                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2187                                                 this.deadflag = DEAD_RESPAWNING;
2188                                         break;
2189                                 }
2190                                 case DEAD_RESPAWNING:
2191                                 {
2192                                         if (time > this.respawn_time)
2193                                         {
2194                                                 this.respawn_time = time + 1; // only retry once a second
2195                                                 this.respawn_time_max = this.respawn_time;
2196                                                 respawn(this);
2197                                         }
2198                                         break;
2199                                 }
2200                         }
2201
2202                         ShowRespawnCountdown(this);
2203
2204                         if (this.respawn_flags & RESPAWN_SILENT)
2205                                 STAT(RESPAWN_TIME, this) = 0;
2206                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2207                         {
2208                                 if (time < this.respawn_time)
2209                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2210                                 else if (this.deadflag != DEAD_RESPAWNING)
2211                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2212                         }
2213                         else
2214                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2215                 }
2216
2217                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2218                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2219                         STAT(RESPAWN_TIME, this) *= -1;
2220
2221                 return false;
2222         }
2223
2224         bool have_hook = false;
2225         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2226         {
2227                 .entity weaponentity = weaponentities[slot];
2228                 if(this.(weaponentity).hook.state)
2229                 {
2230                         have_hook = true;
2231                         break;
2232                 }
2233         }
2234         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2235         if (have_hook) {
2236                 do_crouch = false;
2237         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2238                 do_crouch = false;
2239         } else if (this.vehicle) {
2240                 do_crouch = false;
2241         } else if (STAT(FROZEN, this)) {
2242                 do_crouch = false;
2243     }
2244
2245         if (do_crouch) {
2246                 if (!this.crouch) {
2247                         this.crouch = true;
2248                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2249                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2250                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2251                 }
2252         } else if (this.crouch) {
2253         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2254         if (!trace_startsolid) {
2255             this.crouch = false;
2256             this.view_ofs = STAT(PL_VIEW_OFS, this);
2257             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2258         }
2259         }
2260
2261         FixPlayermodel(this);
2262
2263         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2264         //if(frametime)
2265         {
2266                 this.items &= ~this.items_added;
2267
2268                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2269                 {
2270                         .entity weaponentity = weaponentities[slot];
2271                         W_WeaponFrame(this, weaponentity);
2272
2273                         if(slot == 0)
2274                         {
2275                                 this.clip_load = this.(weaponentity).clip_load;
2276                                 this.clip_size = this.(weaponentity).clip_size;
2277                         }
2278                 }
2279
2280                 this.items_added = 0;
2281                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2282             this.items_added |= IT_FUEL;
2283
2284                 this.items |= this.items_added;
2285         }
2286
2287         player_regen(this);
2288
2289         // WEAPONTODO: Add a weapon request for this
2290         // rot vortex charge to the charge limit
2291         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2292         {
2293                 .entity weaponentity = weaponentities[slot];
2294                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2295                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2296         }
2297
2298         if (frametime) player_anim(this);
2299
2300         // secret status
2301         secrets_setstatus(this);
2302
2303         // monsters status
2304         monsters_setstatus(this);
2305
2306         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2307
2308         return true;
2309 }
2310
2311 void ObserverThink(entity this)
2312 {
2313         if ( CS(this).impulse )
2314         {
2315                 MinigameImpulse(this, CS(this).impulse);
2316                 CS(this).impulse = 0;
2317         }
2318
2319         if (this.flags & FL_JUMPRELEASED) {
2320                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2321                         this.flags &= ~FL_JUMPRELEASED;
2322                         this.flags |= FL_SPAWNING;
2323                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2324                         this.flags &= ~FL_JUMPRELEASED;
2325                         if(SpectateNext(this)) {
2326                                 TRANSMUTE(Spectator, this);
2327                         }
2328                 } else {
2329                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2330                         set_movetype(this, preferred_movetype);
2331                 }
2332         } else {
2333                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2334                         this.flags |= FL_JUMPRELEASED;
2335                         if(this.flags & FL_SPAWNING)
2336                         {
2337                                 this.flags &= ~FL_SPAWNING;
2338                                 Join(this);
2339                                 return;
2340                         }
2341                 }
2342         }
2343 }
2344
2345 void SpectatorThink(entity this)
2346 {
2347         if ( CS(this).impulse )
2348         {
2349                 if(MinigameImpulse(this, CS(this).impulse))
2350                         CS(this).impulse = 0;
2351
2352                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2353                 {
2354                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2355                         CS(this).impulse = 0;
2356                         return;
2357                 }
2358         }
2359
2360         if (this.flags & FL_JUMPRELEASED) {
2361                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2362                         this.flags &= ~FL_JUMPRELEASED;
2363                         this.flags |= FL_SPAWNING;
2364                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2365                         this.flags &= ~FL_JUMPRELEASED;
2366                         if(SpectateNext(this)) {
2367                                 TRANSMUTE(Spectator, this);
2368                         } else {
2369                                 TRANSMUTE(Observer, this);
2370                                 PutClientInServer(this);
2371                         }
2372                         CS(this).impulse = 0;
2373                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2374                         this.flags &= ~FL_JUMPRELEASED;
2375                         if(SpectatePrev(this)) {
2376                                 TRANSMUTE(Spectator, this);
2377                         } else {
2378                                 TRANSMUTE(Observer, this);
2379                                 PutClientInServer(this);
2380                         }
2381                         CS(this).impulse = 0;
2382                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         TRANSMUTE(Observer, this);
2385                         PutClientInServer(this);
2386                 } else {
2387                         if(!SpectateUpdate(this))
2388                                 PutObserverInServer(this);
2389                 }
2390         } else {
2391                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2392                         this.flags |= FL_JUMPRELEASED;
2393                         if(this.flags & FL_SPAWNING)
2394                         {
2395                                 this.flags &= ~FL_SPAWNING;
2396                                 Join(this);
2397                                 return;
2398                         }
2399                 }
2400                 if(!SpectateUpdate(this))
2401                         PutObserverInServer(this);
2402         }
2403
2404         this.flags |= FL_CLIENT | FL_NOTARGET;
2405 }
2406
2407 void vehicles_enter (entity pl, entity veh);
2408 void PlayerUseKey(entity this)
2409 {
2410         if (!IS_PLAYER(this))
2411                 return;
2412
2413         if(this.vehicle)
2414         {
2415                 if(!game_stopped)
2416                 {
2417                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2418                         return;
2419                 }
2420         }
2421         else if(autocvar_g_vehicles_enter)
2422         {
2423                 if(!STAT(FROZEN, this))
2424                 if(!IS_DEAD(this))
2425                 if(!game_stopped)
2426                 {
2427                         entity head, closest_target = NULL;
2428                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2429
2430                         while(head) // find the closest acceptable target to enter
2431                         {
2432                                 if(IS_VEHICLE(head))
2433                                 if(!IS_DEAD(head))
2434                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2435                                 if(head.takedamage != DAMAGE_NO)
2436                                 {
2437                                         if(closest_target)
2438                                         {
2439                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2440                                                 { closest_target = head; }
2441                                         }
2442                                         else { closest_target = head; }
2443                                 }
2444
2445                                 head = head.chain;
2446                         }
2447
2448                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2449                 }
2450         }
2451
2452         // a use key was pressed; call handlers
2453         MUTATOR_CALLHOOK(PlayerUseKey, this);
2454 }
2455
2456
2457 /*
2458 =============
2459 PlayerPreThink
2460
2461 Called every frame for each client before the physics are run
2462 =============
2463 */
2464 .float last_vehiclecheck;
2465 void PlayerPreThink (entity this)
2466 {
2467         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2468         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2469
2470         WarpZone_PlayerPhysics_FixVAngle(this);
2471
2472         if (frametime) {
2473                 // physics frames: update anticheat stuff
2474                 anticheat_prethink(this);
2475         }
2476
2477         if (blockSpectators && frametime) {
2478                 // WORKAROUND: only use dropclient in server frames (frametime set).
2479                 // Never use it in cl_movement frames (frametime zero).
2480                 checkSpectatorBlock(this);
2481     }
2482
2483         zoomstate_set = false;
2484
2485         // Check for nameless players
2486         if (isInvisibleString(this.netname)) {
2487                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2488                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2489         }
2490         if (this.netname != CS(this).netname_previous) {
2491                 if (autocvar_sv_eventlog) {
2492                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2493         }
2494                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2495                 CS(this).netname_previous = strzone(this.netname);
2496         }
2497
2498         // version nagging
2499         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2500         CS(this).version_nagtime = 0;
2501         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2502             // git client
2503         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2504             // git server
2505             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2506         } else {
2507             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2508             if (r < 0) { // old client
2509                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2510             } else if (r > 0) { // old server
2511                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2512             }
2513         }
2514     }
2515
2516         // GOD MODE info
2517         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2518         {
2519                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2520                 this.max_armorvalue = 0;
2521         }
2522
2523         if(IS_PLAYER(this))
2524         {
2525                 if (STAT(FROZEN, this) == 2)
2526                 {
2527                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2528                         this.health = max(1, this.revive_progress * start_health);
2529                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2530
2531                         if (this.revive_progress >= 1)
2532                                 Unfreeze(this);
2533                 }
2534                 else if (STAT(FROZEN, this) == 3)
2535                 {
2536                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2537                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2538
2539                         if (this.health < 1)
2540                         {
2541                                 if (this.vehicle)
2542                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2543                                 if(this.event_damage)
2544                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2545                         }
2546                         else if (this.revive_progress <= 0)
2547                                 Unfreeze(this);
2548                 }
2549         }
2550
2551         MUTATOR_CALLHOOK(PlayerPreThink, this);
2552
2553         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2554         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2555         {
2556                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2557                 {
2558                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2559                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2560                         {
2561                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2562                         }
2563                         else if(!it.owner)
2564                         {
2565                                 if(!it.team || SAME_TEAM(this, it))
2566                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2567                                 else if(autocvar_g_vehicles_steal)
2568                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2569                         }
2570                 });
2571
2572                 this.last_vehiclecheck = time + 1;
2573         }
2574
2575         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2576         {
2577                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2578                         PlayerUseKey(this);
2579                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2580         }
2581
2582         if (IS_REAL_CLIENT(this))
2583                 PrintWelcomeMessage(this);
2584
2585         if (IS_PLAYER(this)) {
2586                 if(!PlayerThink(this))
2587                         return;
2588         }
2589         else if (game_stopped || intermission_running) {
2590                 if(intermission_running)
2591                         IntermissionThink(this);
2592                 return;
2593         }
2594         else if (IS_OBSERVER(this)) {
2595                 ObserverThink(this);
2596         }
2597         else if (IS_SPEC(this)) {
2598                 SpectatorThink(this);
2599         }
2600
2601         // WEAPONTODO: Add weapon request for this
2602         if (!zoomstate_set) {
2603                 bool wep_zoomed = false;
2604                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2605                 {
2606                         .entity weaponentity = weaponentities[slot];
2607                         Weapon thiswep = this.(weaponentity).m_weapon;
2608                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2609                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2610                 }
2611                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2612     }
2613
2614         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2615         {
2616                 CS(this).teamkill_soundtime = 0;
2617
2618                 entity e = CS(this).teamkill_soundsource;
2619                 entity oldpusher = e.pusher;
2620                 e.pusher = this;
2621                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2622                 e.pusher = oldpusher;
2623         }
2624
2625         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2626                 CS(this).taunt_soundtime = 0;
2627                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2628         }
2629
2630         target_voicescript_next(this);
2631
2632         // WEAPONTODO: Move into weaponsystem somehow
2633         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2634         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2635         {
2636                 .entity weaponentity = weaponentities[slot];
2637                 if(this.(weaponentity).m_weapon == WEP_Null)
2638                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2639         }
2640 }
2641
2642 void DrownPlayer(entity this)
2643 {
2644         if(IS_DEAD(this))
2645                 return;
2646
2647         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2648         {
2649                 if(this.air_finished < time)
2650                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2651                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2652                 this.dmg = 2;
2653         }
2654         else if (this.air_finished < time)
2655         {       // drown!
2656                 if (this.pain_finished < time)
2657                 {
2658                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2659                         this.pain_finished = time + 0.5;
2660                 }
2661         }
2662 }
2663
2664 .bool move_qcphysics;
2665
2666 void Player_Physics(entity this)
2667 {
2668         set_movetype(this, this.move_movetype);
2669
2670         if(!this.move_qcphysics)
2671                 return;
2672
2673         if(!frametime && !CS(this).pm_frametime)
2674                 return;
2675
2676         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2677
2678         CS(this).pm_frametime = 0;
2679 }
2680
2681 /*
2682 =============
2683 PlayerPostThink
2684
2685 Called every frame for each client after the physics are run
2686 =============
2687 */
2688 void PlayerPostThink (entity this)
2689 {
2690         Player_Physics(this);
2691
2692         if (sv_maxidle > 0)
2693         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2694         if (IS_REAL_CLIENT(this))
2695         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2696         {
2697                 int totalClients = 0;
2698                 if(sv_maxidle_slots > 0)
2699                 {
2700                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2701                         {
2702                                 ++totalClients;
2703                         });
2704                 }
2705
2706                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2707                 { /* do nothing */ }
2708                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2709                 {
2710                         if (CS(this).idlekick_lasttimeleft)
2711                         {
2712                                 CS(this).idlekick_lasttimeleft = 0;
2713                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2714                         }
2715                 }
2716                 else
2717                 {
2718                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2719                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2720                                 if (!CS(this).idlekick_lasttimeleft)
2721                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2722                         }
2723                         if (timeleft <= 0) {
2724                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2725                                 dropclient(this);
2726                                 return;
2727                         }
2728                         else if (timeleft <= 10) {
2729                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2730                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2731                 }
2732                                 CS(this).idlekick_lasttimeleft = timeleft;
2733                         }
2734                 }
2735         }
2736
2737         CheatFrame(this);
2738
2739         if (game_stopped)
2740         {
2741                 this.solid = SOLID_NOT;
2742                 this.takedamage = DAMAGE_NO;
2743                 set_movetype(this, MOVETYPE_NONE);
2744         }
2745
2746         if (IS_PLAYER(this)) {
2747                 DrownPlayer(this);
2748                 UpdateChatBubble(this);
2749                 if (CS(this).impulse) ImpulseCommands(this);
2750                 if (game_stopped)
2751                 {
2752                         CSQCMODEL_AUTOUPDATE(this);
2753                         return;
2754                 }
2755                 GetPressedKeys(this);
2756         }
2757
2758         if (this.waypointsprite_attachedforcarrier) {
2759             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2760                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2761     }
2762
2763         playerdemo_write(this);
2764
2765         CSQCMODEL_AUTOUPDATE(this);
2766 }
2767
2768 // hack to copy the button fields from the client entity to the Client State
2769 void PM_UpdateButtons(entity this, entity store)
2770 {
2771         if(this.impulse)
2772                 store.impulse = this.impulse;
2773         this.impulse = 0;
2774
2775         store.button0 = this.button0;
2776         store.button2 = this.button2;
2777         store.button3 = this.button3;
2778         store.button4 = this.button4;
2779         store.button5 = this.button5;
2780         store.button6 = this.button6;
2781         store.button7 = this.button7;
2782         store.button8 = this.button8;
2783         store.button9 = this.button9;
2784         store.button10 = this.button10;
2785         store.button11 = this.button11;
2786         store.button12 = this.button12;
2787         store.button13 = this.button13;
2788         store.button14 = this.button14;
2789         store.button15 = this.button15;
2790         store.button16 = this.button16;
2791         store.buttonuse = this.buttonuse;
2792         store.buttonchat = this.buttonchat;
2793
2794         store.cursor_active = this.cursor_active;
2795         store.cursor_screen = this.cursor_screen;
2796         store.cursor_trace_start = this.cursor_trace_start;
2797         store.cursor_trace_endpos = this.cursor_trace_endpos;
2798         store.cursor_trace_ent = this.cursor_trace_ent;
2799
2800         store.ping = this.ping;
2801         store.ping_packetloss = this.ping_packetloss;
2802         store.ping_movementloss = this.ping_movementloss;
2803
2804         store.v_angle = this.v_angle;
2805         store.movement = this.movement;
2806 }